SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::HTML::Util;
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::AdditionalBillingAddress;
  18 use SL::DB::AuthUser;
  19 use SL::DB::History;
  20 use SL::DB::Order;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28 use SL::DB::RecordLink;
  29 use SL::DB::RequirementSpec;
  30 use SL::DB::Shipto;
  31 use SL::DB::Translation;
  32
  33 use SL::Helper::CreatePDF qw(:all);
  34 use SL::Helper::PrintOptions;
  35 use SL::Helper::ShippedQty;
  36 use SL::Helper::UserPreferences::DisplayPreferences;
  37 use SL::Helper::UserPreferences::PositionsScrollbar;
  38 use SL::Helper::UserPreferences::UpdatePositions;
  39
  40 use SL::Controller::Helper::GetModels;
  41
  42 use List::Util qw(first sum0);
  43 use List::UtilsBy qw(sort_by uniq_by);
  44 use List::MoreUtils qw(any none pairwise first_index);
  45 use English qw(-no_match_vars);
  46 use File::Spec;
  47 use Cwd;
  48 use Sort::Naturally;
  49
  50 use Rose::Object::MakeMethods::Generic
  51 (
  52  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  53  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  54 );
  55
  56
  57 # safety
  58 __PACKAGE__->run_before('check_auth');
  59
  60 __PACKAGE__->run_before('check_auth_for_edit',
  61                         except => [ qw(edit show_customer_vendor_details_dialog price_popup load_second_rows) ]);
  62
  63 __PACKAGE__->run_before('recalc',
  64                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  65                                      print send_email) ]);
  66
  67 __PACKAGE__->run_before('get_unalterable_data',
  68                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  69                                      print send_email) ]);
  70
  71 #
  72 # actions
  73 #
  74
  75 # add a new order
  76 sub action_add {
  77   my ($self) = @_;
  78
  79   $self->order->transdate(DateTime->now_local());
  80   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  81                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  82
  83   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  84       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  85       && (!$self->order->reqdate)) {
  86     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  87   }
  88
  89
  90   $self->pre_render();
  91   $self->render(
  92     'order/form',
  93     title => $self->get_title_for('add'),
  94     %{$self->{template_args}}
  95   );
  96 }
  97
  98 # edit an existing order
  99 sub action_edit {
 100   my ($self) = @_;
 101
 102   if ($::form->{id}) {
 103     $self->load_order;
 104
 105   } else {
 106     # this is to edit an order from an unsaved order object
 107
 108     # set item ids to new fake id, to identify them as new items
 109     foreach my $item (@{$self->order->items_sorted}) {
 110       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 111     }
 112     # trigger rendering values for second row as hidden, because they
 113     # are loaded only on demand. So we need to keep the values from
 114     # the source.
 115     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 116   }
 117
 118   $self->recalc();
 119   $self->pre_render();
 120   $self->render(
 121     'order/form',
 122     title => $self->get_title_for('edit'),
 123     %{$self->{template_args}}
 124   );
 125 }
 126
 127 # edit a collective order (consisting of one or more existing orders)
 128 sub action_edit_collective {
 129   my ($self) = @_;
 130
 131   # collect order ids
 132   my @multi_ids = map {
 133     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 134   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 135
 136   # fall back to add if no ids are given
 137   if (scalar @multi_ids == 0) {
 138     $self->action_add();
 139     return;
 140   }
 141
 142   # fall back to save as new if only one id is given
 143   if (scalar @multi_ids == 1) {
 144     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 145     $self->action_save_as_new();
 146     return;
 147   }
 148
 149   # make new order from given orders
 150   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 151   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 152   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 153
 154   $self->action_edit();
 155 }
 156
 157 # delete the order
 158 sub action_delete {
 159   my ($self) = @_;
 160
 161   my $errors = $self->delete();
 162
 163   if (scalar @{ $errors }) {
 164     $self->js->flash('error', $_) foreach @{ $errors };
 165     return $self->js->render();
 166   }
 167
 168   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 169            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 170            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 171            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 172            : '';
 173   flash_later('info', $text);
 174
 175   my @redirect_params = (
 176     action => 'add',
 177     type   => $self->type,
 178   );
 179
 180   $self->redirect_to(@redirect_params);
 181 }
 182
 183 # save the order
 184 sub action_save {
 185   my ($self) = @_;
 186
 187   my $errors = $self->save();
 188
 189   if (scalar @{ $errors }) {
 190     $self->js->flash('error', $_) foreach @{ $errors };
 191     return $self->js->render();
 192   }
 193
 194   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 195            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 196            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 197            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 198            : '';
 199   flash_later('info', $text);
 200
 201   my @redirect_params;
 202   if ($::form->{back_to_caller}) {
 203     @redirect_params = $::form->{callback} ? ($::form->{callback})
 204                                            : (controller => 'LoginScreen', action => 'user_login');
 205
 206   } else {
 207     @redirect_params = (
 208       action   => 'edit',
 209       type     => $self->type,
 210       id       => $self->order->id,
 211       callback => $::form->{callback},
 212     );
 213   }
 214
 215   $self->redirect_to(@redirect_params);
 216 }
 217
 218 # save the order as new document an open it for edit
 219 sub action_save_as_new {
 220   my ($self) = @_;
 221
 222   my $order = $self->order;
 223
 224   if (!$order->id) {
 225     $self->js->flash('error', t8('This object has not been saved yet.'));
 226     return $self->js->render();
 227   }
 228
 229   # load order from db to check if values changed
 230   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 231
 232   my %new_attrs;
 233   # Lets assign a new number if the user hasn't changed the previous one.
 234   # If it has been changed manually then use it as-is.
 235   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 236                         ? ''
 237                         : trim($order->number);
 238
 239   # Clear transdate unless changed
 240   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 241                         ? DateTime->today_local
 242                         : $order->transdate;
 243
 244   # Set new reqdate unless changed if it is enabled in client config
 245   if ($order->reqdate == $saved_order->reqdate) {
 246     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 247                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 248
 249     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 250         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 251       $new_attrs{reqdate} = '';
 252     } else {
 253       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 254     }
 255   } else {
 256     $new_attrs{reqdate} = $order->reqdate;
 257   }
 258
 259   # Update employee
 260   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 261
 262   # Warn on obsolete items
 263   my @obsolete_positions = map { $_->position } grep { $_->part->obsolete } @{ $order->items_sorted };
 264   flash_later('warning', t8('This record containts obsolete items at position #1', join ', ', @obsolete_positions)) if @obsolete_positions;
 265
 266   # Create new record from current one
 267   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 268
 269   # no linked records on save as new
 270   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 271
 272   # save
 273   $self->action_save();
 274 }
 275
 276 # print the order
 277 #
 278 # This is called if "print" is pressed in the print dialog.
 279 # If PDF creation was requested and succeeded, the pdf is offered for download
 280 # via send_file (which uses ajax in this case).
 281 sub action_print {
 282   my ($self) = @_;
 283
 284   my $errors = $self->save();
 285
 286   if (scalar @{ $errors }) {
 287     $self->js->flash('error', $_) foreach @{ $errors };
 288     return $self->js->render();
 289   }
 290
 291   $self->js_reset_order_and_item_ids_after_save;
 292
 293   my $format      = $::form->{print_options}->{format};
 294   my $media       = $::form->{print_options}->{media};
 295   my $formname    = $::form->{print_options}->{formname};
 296   my $copies      = $::form->{print_options}->{copies};
 297   my $groupitems  = $::form->{print_options}->{groupitems};
 298   my $printer_id  = $::form->{print_options}->{printer_id};
 299
 300   # only PDF, OpenDocument & HTML for now
 301   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 302     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 303   }
 304
 305   # only screen or printer by now
 306   if (none { $media eq $_ } qw(screen printer)) {
 307     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 308   }
 309
 310   # create a form for generate_attachment_filename
 311   my $form   = Form->new;
 312   $form->{$self->nr_key()}  = $self->order->number;
 313   $form->{type}             = $self->type;
 314   $form->{format}           = $format;
 315   $form->{formname}         = $formname;
 316   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 317   my $doc_filename          = $form->generate_attachment_filename();
 318
 319   my $doc;
 320   my @errors = $self->generate_doc(\$doc, { media      => $media,
 321                                             format     => $format,
 322                                             formname   => $formname,
 323                                             language   => $self->order->language,
 324                                             printer_id => $printer_id,
 325                                             groupitems => $groupitems });
 326   if (scalar @errors) {
 327     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 328   }
 329
 330   if ($media eq 'screen') {
 331     # screen/download
 332     $self->js->flash('info', t8('The document has been created.'));
 333     $self->send_file(
 334       \$doc,
 335       type         => SL::MIME->mime_type_from_ext($doc_filename),
 336       name         => $doc_filename,
 337       js_no_render => 1,
 338     );
 339
 340   } elsif ($media eq 'printer') {
 341     # printer
 342     my $printer_id = $::form->{print_options}->{printer_id};
 343     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 344       copies  => $copies,
 345       content => $doc,
 346     );
 347
 348     $self->js->flash('info', t8('The document has been printed.'));
 349   }
 350
 351   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 352   if (scalar @warnings) {
 353     $self->js->flash('warning', $_) for @warnings;
 354   }
 355
 356   $self->save_history('PRINTED');
 357
 358   $self->js
 359     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 360     ->render;
 361 }
 362 sub action_preview_pdf {
 363   my ($self) = @_;
 364
 365   my $errors = $self->save();
 366   if (scalar @{ $errors }) {
 367     $self->js->flash('error', $_) foreach @{ $errors };
 368     return $self->js->render();
 369   }
 370
 371   $self->js_reset_order_and_item_ids_after_save;
 372
 373   my $format      = 'pdf';
 374   my $media       = 'screen';
 375   my $formname    = $self->type;
 376
 377   # only pdf
 378   # create a form for generate_attachment_filename
 379   my $form   = Form->new;
 380   $form->{$self->nr_key()}  = $self->order->number;
 381   $form->{type}             = $self->type;
 382   $form->{format}           = $format;
 383   $form->{formname}         = $formname;
 384   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 385   my $pdf_filename          = $form->generate_attachment_filename();
 386
 387   my $pdf;
 388   my @errors = $self->generate_doc(\$pdf, { media      => $media,
 389                                             format     => $format,
 390                                             formname   => $formname,
 391                                             language   => $self->order->language,
 392                                           });
 393   if (scalar @errors) {
 394     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 395   }
 396   $self->save_history('PREVIEWED');
 397   $self->js->flash('info', t8('The PDF has been previewed'));
 398   # screen/download
 399   $self->send_file(
 400     \$pdf,
 401     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 402     name         => $pdf_filename,
 403     js_no_render => 0,
 404   );
 405 }
 406
 407 # open the email dialog
 408 sub action_save_and_show_email_dialog {
 409   my ($self) = @_;
 410
 411   my $errors = $self->save();
 412
 413   if (scalar @{ $errors }) {
 414     $self->js->flash('error', $_) foreach @{ $errors };
 415     return $self->js->render();
 416   }
 417
 418   my $cv_method = $self->cv;
 419
 420   if (!$self->order->$cv_method) {
 421     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 422                     ->render($self);
 423   }
 424
 425   my $email_form;
 426   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 427   $email_form->{to} ||= $self->order->$cv_method->email;
 428   $email_form->{cc}   = $self->order->$cv_method->cc;
 429   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 430   # Todo: get addresses from shipto, if any
 431
 432   my $form = Form->new;
 433   $form->{$self->nr_key()}  = $self->order->number;
 434   $form->{cusordnumber}     = $self->order->cusordnumber;
 435   $form->{formname}         = $self->type;
 436   $form->{type}             = $self->type;
 437   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 438   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 439   $form->{format}           = 'pdf';
 440   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 441
 442   $email_form->{subject}             = $form->generate_email_subject();
 443   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 444   $email_form->{message}             = $form->generate_email_body();
 445   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 446
 447   my %files = $self->get_files_for_email_dialog();
 448
 449   my @employees_with_email = grep {
 450     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 451     $user && !!trim($user->get_config_value('email'));
 452   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 453
 454
 455   my $all_partner_email_addresses = $self->order->customervendor->get_all_email_addresses();
 456
 457   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 458                                   email_form    => $email_form,
 459                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 460                                   FILES         => \%files,
 461                                   is_customer   => $self->cv eq 'customer',
 462                                   ALL_EMPLOYEES => \@employees_with_email,
 463                                   ALL_PARTNER_EMAIL_ADDRESSES => $all_partner_email_addresses,
 464   );
 465
 466   $self->js
 467       ->run('kivi.Order.show_email_dialog', $dialog_html)
 468       ->reinit_widgets
 469       ->render($self);
 470 }
 471
 472 # send email
 473 #
 474 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 475 sub action_send_email {
 476   my ($self) = @_;
 477
 478   my $errors = $self->save();
 479
 480   if (scalar @{ $errors }) {
 481     $self->js->run('kivi.Order.close_email_dialog');
 482     $self->js->flash('error', $_) foreach @{ $errors };
 483     return $self->js->render();
 484   }
 485
 486   $self->js_reset_order_and_item_ids_after_save;
 487
 488   my $email_form  = delete $::form->{email_form};
 489
 490   if ($email_form->{additional_to}) {
 491     $email_form->{to} = join ', ', grep { $_ } $email_form->{to}, @{$email_form->{additional_to}};
 492     delete $email_form->{additional_to};
 493   }
 494
 495   my %field_names = (to => 'email');
 496
 497   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 498
 499   # for Form::cleanup which may be called in Form::send_email
 500   $::form->{cwd}    = getcwd();
 501   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 502
 503   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 504   $::form->{media}  = 'email';
 505
 506   $::form->{attachment_policy} //= '';
 507
 508   # Is an old file version available?
 509   my $attfile;
 510   if ($::form->{attachment_policy} eq 'old_file') {
 511     $attfile = SL::File->get_all(object_id     => $self->order->id,
 512                                  object_type   => $self->type,
 513                                  file_type     => 'document',
 514                                  print_variant => $::form->{formname});
 515   }
 516
 517   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 518     my $doc;
 519     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 520                                              format     => $::form->{print_options}->{format},
 521                                              formname   => $::form->{print_options}->{formname},
 522                                              language   => $self->order->language,
 523                                              printer_id => $::form->{print_options}->{printer_id},
 524                                              groupitems => $::form->{print_options}->{groupitems}});
 525     if (scalar @errors) {
 526       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 527     }
 528
 529     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 530     if (scalar @warnings) {
 531       flash_later('warning', $_) for @warnings;
 532     }
 533
 534     my $sfile = SL::SessionFile::Random->new(mode => "w");
 535     $sfile->fh->print($doc);
 536     $sfile->fh->close;
 537
 538     $::form->{tmpfile} = $sfile->file_name;
 539     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 540   }
 541
 542   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 543   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 544
 545   # internal notes unless no email journal
 546   unless ($::instance_conf->get_email_journal) {
 547     my $intnotes = $self->order->intnotes;
 548     $intnotes   .= "\n\n" if $self->order->intnotes;
 549     $intnotes   .= t8('[email]')                                                                                        . "\n";
 550     $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 551     $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 552     $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 553     $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 554     $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 555     $intnotes   .= t8('Message')    . ": " . SL::HTML::Util->strip($::form->{message});
 556
 557     $self->order->update_attributes(intnotes => $intnotes);
 558   }
 559
 560   $self->save_history('MAILED');
 561
 562   flash_later('info', t8('The email has been sent.'));
 563
 564   my @redirect_params = (
 565     action => 'edit',
 566     type   => $self->type,
 567     id     => $self->order->id,
 568   );
 569
 570   $self->redirect_to(@redirect_params);
 571 }
 572
 573 # open the periodic invoices config dialog
 574 #
 575 # If there are values in the form (i.e. dialog was opened before),
 576 # then use this values. Create new ones, else.
 577 sub action_show_periodic_invoices_config_dialog {
 578   my ($self) = @_;
 579
 580   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 581   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 582   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 583                                                    order_value_periodicity => 'p', # = same as periodicity
 584                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 585                                                    extend_automatically_by => 12,
 586                                                    active                  => 1,
 587                                                    email_subject           => GenericTranslations->get(
 588                                                                                 language_id      => $::form->{language_id},
 589                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 590                                                    email_body              => GenericTranslations->get(
 591                                                                                 language_id      => $::form->{language_id},
 592                                                                                 translation_type => "salutation_general")
 593                                                                             . GenericTranslations->get(
 594                                                                                 language_id      => $::form->{language_id},
 595                                                                                 translation_type => "salutation_punctuation_mark") . "\n\n"
 596                                                                             . GenericTranslations->get(
 597                                                                                 language_id      => $::form->{language_id},
 598                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 599   );
 600   # for older configs, replace email preset text if not yet set.
 601   $config->email_subject(GenericTranslations->get(
 602                                               language_id      => $::form->{language_id},
 603                                               translation_type =>"preset_text_periodic_invoices_email_subject")
 604                         ) unless $config->email_subject;
 605
 606   $config->email_body(GenericTranslations->get(
 607                                               language_id      => $::form->{language_id},
 608                                               translation_type => "salutation_general")
 609                     . GenericTranslations->get(
 610                                               language_id      => $::form->{language_id},
 611                                               translation_type => "salutation_punctuation_mark") . "\n\n"
 612                     . GenericTranslations->get(
 613                                               language_id      => $::form->{language_id},
 614                                               translation_type =>"preset_text_periodic_invoices_email_body")
 615                      ) unless $config->email_body;
 616
 617   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 618   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 619
 620   $::form->get_lists(printers => "ALL_PRINTERS",
 621                      charts   => { key       => 'ALL_CHARTS',
 622                                    transdate => 'current_date' });
 623
 624   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 625
 626   if ($::form->{customer_id}) {
 627     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 628     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 629     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 630     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 631     $config->send_email(0) if $::form->{postal_invoice};
 632   }
 633
 634   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 635                 popup_dialog             => 1,
 636                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 637                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 638                 config                   => $config,
 639                 %$::form);
 640 }
 641
 642 # assign the values of the periodic invoices config dialog
 643 # as yaml in the hidden tag and set the status.
 644 sub action_assign_periodic_invoices_config {
 645   my ($self) = @_;
 646
 647   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 648
 649   my $config = { active                     => $::form->{active}       ? 1 : 0,
 650                  terminated                 => $::form->{terminated}   ? 1 : 0,
 651                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 652                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 653                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 654                  start_date_as_date         => $::form->{start_date_as_date},
 655                  end_date_as_date           => $::form->{end_date_as_date},
 656                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 657                  print                      => $::form->{print}      ? 1                         : 0,
 658                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 659                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 660                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 661                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 662                  send_email                 => $::form->{send_email} ? 1 : 0,
 663                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 664                  email_recipient_address    => $::form->{email_recipient_address},
 665                  email_sender               => $::form->{email_sender},
 666                  email_subject              => $::form->{email_subject},
 667                  email_body                 => $::form->{email_body},
 668                };
 669
 670   my $periodic_invoices_config = SL::YAML::Dump($config);
 671
 672   my $status = $self->get_periodic_invoices_status($config);
 673
 674   $self->js
 675     ->remove('#order_periodic_invoices_config')
 676     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 677     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 678     ->html('#periodic_invoices_status', $status)
 679     ->flash('info', t8('The periodic invoices config has been assigned.'))
 680     ->render($self);
 681 }
 682
 683 sub action_get_has_active_periodic_invoices {
 684   my ($self) = @_;
 685
 686   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 687   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 688
 689   my $has_active_periodic_invoices =
 690        $self->type eq sales_order_type()
 691     && $config
 692     && $config->active
 693     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 694     && $config->get_previous_billed_period_start_date;
 695
 696   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 697 }
 698
 699 # save the order and redirect to the frontend subroutine for a new
 700 # delivery order
 701 sub action_save_and_delivery_order {
 702   my ($self) = @_;
 703
 704   $self->save_and_redirect_to(
 705     controller => 'oe.pl',
 706     action     => 'oe_delivery_order_from_order',
 707   );
 708 }
 709
 710 sub action_save_and_supplier_delivery_order {
 711   my ($self) = @_;
 712
 713   $self->save_and_redirect_to(
 714     controller => 'controller.pl',
 715     action     => 'DeliveryOrder/add_from_order',
 716     type       => 'supplier_delivery_order',
 717   );
 718 }
 719
 720 # save the order and redirect to the frontend subroutine for a new
 721 # invoice
 722 sub action_save_and_invoice {
 723   my ($self) = @_;
 724
 725   $self->save_and_redirect_to(
 726     controller => 'oe.pl',
 727     action     => 'oe_invoice_from_order',
 728   );
 729 }
 730
 731 sub action_save_and_invoice_for_advance_payment {
 732   my ($self) = @_;
 733
 734   $self->save_and_redirect_to(
 735     controller       => 'oe.pl',
 736     action           => 'oe_invoice_from_order',
 737     new_invoice_type => 'invoice_for_advance_payment',
 738   );
 739 }
 740
 741 sub action_save_and_final_invoice {
 742   my ($self) = @_;
 743
 744   $self->save_and_redirect_to(
 745     controller       => 'oe.pl',
 746     action           => 'oe_invoice_from_order',
 747     new_invoice_type => 'final_invoice',
 748   );
 749 }
 750
 751 # workflow from sales order to sales quotation
 752 sub action_sales_quotation {
 753   $_[0]->workflow_sales_or_request_for_quotation();
 754 }
 755
 756 # workflow from sales order to sales quotation
 757 sub action_request_for_quotation {
 758   $_[0]->workflow_sales_or_request_for_quotation();
 759 }
 760
 761 # workflow from sales quotation to sales order
 762 sub action_sales_order {
 763   $_[0]->workflow_sales_or_purchase_order();
 764 }
 765
 766 # workflow from rfq to purchase order
 767 sub action_purchase_order {
 768   $_[0]->workflow_sales_or_purchase_order();
 769 }
 770
 771 # workflow from purchase order to ap transaction
 772 sub action_save_and_ap_transaction {
 773   my ($self) = @_;
 774
 775   $self->save_and_redirect_to(
 776     controller => 'ap.pl',
 777     action     => 'add_from_purchase_order',
 778   );
 779 }
 780
 781 # set form elements in respect to a changed customer or vendor
 782 #
 783 # This action is called on an change of the customer/vendor picker.
 784 sub action_customer_vendor_changed {
 785   my ($self) = @_;
 786
 787   setup_order_from_cv($self->order);
 788   $self->recalc();
 789
 790   my $cv_method = $self->cv;
 791
 792   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 793     $self->js->show('#cp_row');
 794   } else {
 795     $self->js->hide('#cp_row');
 796   }
 797
 798   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 799     $self->js->show('#shipto_selection');
 800   } else {
 801     $self->js->hide('#shipto_selection');
 802   }
 803
 804   if ($cv_method eq 'customer') {
 805     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 806     $self->js->$show_hide('#billing_address_row');
 807   }
 808
 809   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 810
 811   $self->js
 812     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 813     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 814     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 815     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 816     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 817     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 818     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 819     ->val(        '#order_currency_id',        $self->order->currency_id)
 820     ->val(        '#order_payment_id',         $self->order->payment_id)
 821     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 822     ->val(        '#order_intnotes',           $self->order->intnotes)
 823     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 824     ->focus(      '#order_' . $self->cv . '_id')
 825     ->run('kivi.Order.update_exchangerate');
 826
 827   $self->js_redisplay_amounts_and_taxes;
 828   $self->js_redisplay_cvpartnumbers;
 829   $self->js->render();
 830 }
 831
 832 # open the dialog for customer/vendor details
 833 sub action_show_customer_vendor_details_dialog {
 834   my ($self) = @_;
 835
 836   my $is_customer = 'customer' eq $::form->{vc};
 837   my $cv;
 838   if ($is_customer) {
 839     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 840   } else {
 841     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 842   }
 843
 844   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 845   $details{discount_as_percent} = $cv->discount_as_percent;
 846   $details{creditlimt}          = $cv->creditlimit_as_number;
 847   $details{business}            = $cv->business->description      if $cv->business;
 848   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 849   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 850   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 851   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 852
 853   if ($is_customer) {
 854     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 855       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 856     }
 857   }
 858   foreach my $entry (@{ $cv->shipto }) {
 859     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 860   }
 861   foreach my $entry (@{ $cv->contacts }) {
 862     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 863   }
 864
 865   $_[0]->render('common/show_vc_details', { layout => 0 },
 866                 is_customer => $is_customer,
 867                 %details);
 868
 869 }
 870
 871 # called if a unit in an existing item row is changed
 872 sub action_unit_changed {
 873   my ($self) = @_;
 874
 875   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 876   my $item = $self->order->items_sorted->[$idx];
 877
 878   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 879   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 880
 881   $self->recalc();
 882
 883   $self->js
 884     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 885   $self->js_redisplay_line_values;
 886   $self->js_redisplay_amounts_and_taxes;
 887   $self->js->render();
 888 }
 889
 890 # update item input row when a part ist picked
 891 sub action_update_item_input_row {
 892   my ($self) = @_;
 893
 894   delete $::form->{add_item}->{$_} for qw(create_part_type sellprice_as_number discount_as_percent);
 895
 896   my $form_attr = $::form->{add_item};
 897
 898   return unless $form_attr->{parts_id};
 899
 900   my $record       = $self->order;
 901   my $item         = SL::DB::OrderItem->new(%$form_attr);
 902   my $part         = SL::DB::Part->new(id => $::form->{add_item}->{parts_id})->load;
 903   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 904
 905   $item->unit($part->unit);
 906
 907   my $price_src;
 908   if ( $part->is_assortment ) {
 909     # add assortment items with price 0, as the components carry the price
 910     $price_src = $price_source->price_from_source("");
 911     $price_src->price(0);
 912   } elsif (defined $item->sellprice) {
 913     $price_src = $price_source->price_from_source("");
 914     $price_src->price($item->sellprice);
 915   } else {
 916     $price_src = $price_source->best_price
 917                ? $price_source->best_price
 918                : $price_source->price_from_source("");
 919     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
 920     $price_src->price(0) if !$price_source->best_price;
 921   }
 922
 923   my $discount_src;
 924   if (defined $item->discount) {
 925     $discount_src = $price_source->discount_from_source("");
 926     $discount_src->discount($item->discount);
 927   } else {
 928     $discount_src = $price_source->best_discount
 929                   ? $price_source->best_discount
 930                   : $price_source->discount_from_source("");
 931     $discount_src->discount(0) if !$price_source->best_discount;
 932   }
 933
 934   $self->js
 935     ->val     ('#add_item_unit',                $item->unit)
 936     ->val     ('#add_item_description',         $part->description)
 937     ->val     ('#add_item_sellprice_as_number', '')
 938     ->attr    ('#add_item_sellprice_as_number', 'placeholder', $price_src->price_as_number)
 939     ->attr    ('#add_item_sellprice_as_number', 'title',       $price_src->source_description)
 940     ->val     ('#add_item_discount_as_percent', '')
 941     ->attr    ('#add_item_discount_as_percent', 'placeholder', $discount_src->discount_as_percent)
 942     ->attr    ('#add_item_discount_as_percent', 'title',       $discount_src->source_description)
 943     ->render;
 944 }
 945
 946 # add an item row for a new item entered in the input row
 947 sub action_add_item {
 948   my ($self) = @_;
 949
 950   delete $::form->{add_item}->{create_part_type};
 951
 952   my $form_attr = $::form->{add_item};
 953
 954   return unless $form_attr->{parts_id};
 955
 956   my $item = new_item($self->order, $form_attr);
 957
 958   $self->order->add_items($item);
 959
 960   $self->recalc();
 961
 962   $self->get_item_cvpartnumber($item);
 963
 964   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 965   my $row_as_html = $self->p->render('order/tabs/_row',
 966                                      ITEM => $item,
 967                                      ID   => $item_id,
 968                                      SELF => $self,
 969   );
 970
 971   if ($::form->{insert_before_item_id}) {
 972     $self->js
 973       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 974   } else {
 975     $self->js
 976       ->append('#row_table_id', $row_as_html);
 977   }
 978
 979   if ( $item->part->is_assortment ) {
 980     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 981     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 982       my $attr = { parts_id => $assortment_item->parts_id,
 983                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 984                    unit     => $assortment_item->unit,
 985                    description => $assortment_item->part->description,
 986                  };
 987       my $item = new_item($self->order, $attr);
 988
 989       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 990       $item->discount(1) unless $assortment_item->charge;
 991
 992       $self->order->add_items( $item );
 993       $self->recalc();
 994       $self->get_item_cvpartnumber($item);
 995       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 996       my $row_as_html = $self->p->render('order/tabs/_row',
 997                                          ITEM => $item,
 998                                          ID   => $item_id,
 999                                          SELF => $self,
1000       );
1001       if ($::form->{insert_before_item_id}) {
1002         $self->js
1003           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
1004       } else {
1005         $self->js
1006           ->append('#row_table_id', $row_as_html);
1007       }
1008     };
1009   };
1010
1011   $self->js
1012     ->val('.add_item_input', '')
1013     ->attr('.add_item_input', 'placeholder', '')
1014     ->attr('.add_item_input', 'title', '')
1015     ->run('kivi.Order.init_row_handlers')
1016     ->run('kivi.Order.renumber_positions')
1017     ->focus('#add_item_parts_id_name');
1018
1019   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
1020
1021   $self->js_redisplay_amounts_and_taxes;
1022   $self->js->render();
1023 }
1024
1025 # add item rows for multiple items at once
1026 sub action_add_multi_items {
1027   my ($self) = @_;
1028
1029   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
1030   return $self->js->render() unless scalar @form_attr;
1031
1032   my @items;
1033   foreach my $attr (@form_attr) {
1034     my $item = new_item($self->order, $attr);
1035     push @items, $item;
1036     if ( $item->part->is_assortment ) {
1037       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
1038         my $attr = { parts_id => $assortment_item->parts_id,
1039                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
1040                      unit     => $assortment_item->unit,
1041                      description => $assortment_item->part->description,
1042                    };
1043         my $item = new_item($self->order, $attr);
1044
1045         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
1046         $item->discount(1) unless $assortment_item->charge;
1047         push @items, $item;
1048       }
1049     }
1050   }
1051   $self->order->add_items(@items);
1052
1053   $self->recalc();
1054
1055   foreach my $item (@items) {
1056     $self->get_item_cvpartnumber($item);
1057     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1058     my $row_as_html = $self->p->render('order/tabs/_row',
1059                                        ITEM => $item,
1060                                        ID   => $item_id,
1061                                        SELF => $self,
1062     );
1063
1064     if ($::form->{insert_before_item_id}) {
1065       $self->js
1066         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
1067     } else {
1068       $self->js
1069         ->append('#row_table_id', $row_as_html);
1070     }
1071   }
1072
1073   $self->js
1074     ->run('kivi.Part.close_picker_dialogs')
1075     ->run('kivi.Order.init_row_handlers')
1076     ->run('kivi.Order.renumber_positions')
1077     ->focus('#add_item_parts_id_name');
1078
1079   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
1080
1081   $self->js_redisplay_amounts_and_taxes;
1082   $self->js->render();
1083 }
1084
1085 # recalculate all linetotals, amounts and taxes and redisplay them
1086 sub action_recalc_amounts_and_taxes {
1087   my ($self) = @_;
1088
1089   $self->recalc();
1090
1091   $self->js_redisplay_line_values;
1092   $self->js_redisplay_amounts_and_taxes;
1093   $self->js->render();
1094 }
1095
1096 sub action_update_exchangerate {
1097   my ($self) = @_;
1098
1099   my $data = {
1100     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
1101     currency_name => $self->order->currency->name,
1102     exchangerate  => $self->order->daily_exchangerate_as_null_number,
1103   };
1104
1105   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
1106 }
1107
1108 # redisplay item rows if they are sorted by an attribute
1109 sub action_reorder_items {
1110   my ($self) = @_;
1111
1112   my %sort_keys = (
1113     partnumber   => sub { $_[0]->part->partnumber },
1114     description  => sub { $_[0]->description },
1115     qty          => sub { $_[0]->qty },
1116     sellprice    => sub { $_[0]->sellprice },
1117     discount     => sub { $_[0]->discount },
1118     cvpartnumber => sub { $_[0]->{cvpartnumber} },
1119   );
1120
1121   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1122
1123   my $method = $sort_keys{$::form->{order_by}};
1124   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
1125   if ($::form->{sort_dir}) {
1126     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1127       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
1128     } else {
1129       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
1130     }
1131   } else {
1132     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1133       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
1134     } else {
1135       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
1136     }
1137   }
1138   $self->js
1139     ->run('kivi.Order.redisplay_items', \@to_sort)
1140     ->render;
1141 }
1142
1143 # show the popup to choose a price/discount source
1144 sub action_price_popup {
1145   my ($self) = @_;
1146
1147   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1148   my $item = $self->order->items_sorted->[$idx];
1149
1150   $self->render_price_dialog($item);
1151 }
1152
1153 # save the order in a session variable and redirect to the part controller
1154 sub action_create_part {
1155   my ($self) = @_;
1156
1157   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1158
1159   my $callback     = $self->url_for(
1160     action       => 'return_from_create_part',
1161     type         => $self->type, # type is needed for check_auth on return
1162     previousform => $previousform,
1163   );
1164
1165   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1166
1167   my @redirect_params = (
1168     controller    => 'Part',
1169     action        => 'add',
1170     part_type     => $::form->{add_item}->{create_part_type},
1171     callback      => $callback,
1172     inline_create => 1,
1173   );
1174
1175   $self->redirect_to(@redirect_params);
1176 }
1177
1178 sub action_return_from_create_part {
1179   my ($self) = @_;
1180
1181   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1182
1183   $::auth->restore_form_from_session(delete $::form->{previousform});
1184
1185   # set item ids to new fake id, to identify them as new items
1186   foreach my $item (@{$self->order->items_sorted}) {
1187     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1188   }
1189
1190   $self->recalc();
1191   $self->get_unalterable_data();
1192   $self->pre_render();
1193
1194   # trigger rendering values for second row/longdescription as hidden,
1195   # because they are loaded only on demand. So we need to keep the values
1196   # from the source.
1197   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1198   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1199
1200   $self->render(
1201     'order/form',
1202     title => $self->get_title_for('edit'),
1203     %{$self->{template_args}}
1204   );
1205
1206 }
1207
1208 # load the second row for one or more items
1209 #
1210 # This action gets the html code for all items second rows by rendering a template for
1211 # the second row and sets the html code via client js.
1212 sub action_load_second_rows {
1213   my ($self) = @_;
1214
1215   $self->recalc() if $self->order->is_sales; # for margin calculation
1216
1217   foreach my $item_id (@{ $::form->{item_ids} }) {
1218     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1219     my $item = $self->order->items_sorted->[$idx];
1220
1221     $self->js_load_second_row($item, $item_id, 0);
1222   }
1223
1224   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1225
1226   $self->js->render();
1227 }
1228
1229 # update description, notes and sellprice from master data
1230 sub action_update_row_from_master_data {
1231   my ($self) = @_;
1232
1233   foreach my $item_id (@{ $::form->{item_ids} }) {
1234     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1235     my $item  = $self->order->items_sorted->[$idx];
1236     my $texts = get_part_texts($item->part, $self->order->language_id);
1237
1238     $item->description($texts->{description});
1239     $item->longdescription($texts->{longdescription});
1240
1241     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1242
1243     my $price_src;
1244     if ($item->part->is_assortment) {
1245     # add assortment items with price 0, as the components carry the price
1246       $price_src = $price_source->price_from_source("");
1247       $price_src->price(0);
1248     } else {
1249       $price_src = $price_source->best_price
1250                  ? $price_source->best_price
1251                  : $price_source->price_from_source("");
1252       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1253       $price_src->price(0) if !$price_source->best_price;
1254     }
1255
1256
1257     $item->sellprice($price_src->price);
1258     $item->active_price_source($price_src);
1259
1260     $self->js
1261       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1262       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1263       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1264       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1265
1266     if ($self->search_cvpartnumber) {
1267       $self->get_item_cvpartnumber($item);
1268       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1269     }
1270   }
1271
1272   $self->recalc();
1273   $self->js_redisplay_line_values;
1274   $self->js_redisplay_amounts_and_taxes;
1275
1276   $self->js->render();
1277 }
1278
1279 sub js_load_second_row {
1280   my ($self, $item, $item_id, $do_parse) = @_;
1281
1282   if ($do_parse) {
1283     # Parse values from form (they are formated while rendering (template)).
1284     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1285     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1286     foreach my $var (@{ $item->cvars_by_config }) {
1287       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1288     }
1289     $item->parse_custom_variable_values;
1290   }
1291
1292   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1293
1294   $self->js
1295     ->html('#second_row_' . $item_id, $row_as_html)
1296     ->data('#second_row_' . $item_id, 'loaded', 1);
1297 }
1298
1299 sub js_redisplay_line_values {
1300   my ($self) = @_;
1301
1302   my $is_sales = $self->order->is_sales;
1303
1304   # sales orders with margins
1305   my @data;
1306   if ($is_sales) {
1307     @data = map {
1308       [
1309        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1310        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1311        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1312       ]} @{ $self->order->items_sorted };
1313   } else {
1314     @data = map {
1315       [
1316        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1317       ]} @{ $self->order->items_sorted };
1318   }
1319
1320   $self->js
1321     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1322 }
1323
1324 sub js_redisplay_amounts_and_taxes {
1325   my ($self) = @_;
1326
1327   if (scalar @{ $self->{taxes} }) {
1328     $self->js->show('#taxincluded_row_id');
1329   } else {
1330     $self->js->hide('#taxincluded_row_id');
1331   }
1332
1333   if ($self->order->taxincluded) {
1334     $self->js->hide('#subtotal_row_id');
1335   } else {
1336     $self->js->show('#subtotal_row_id');
1337   }
1338
1339   if ($self->order->is_sales) {
1340     my $is_neg = $self->order->marge_total < 0;
1341     $self->js
1342       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1343       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1344       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1345       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1346       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1347       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1348       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1349       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1350   }
1351
1352   $self->js
1353     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1354     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1355     ->remove('.tax_row')
1356     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1357 }
1358
1359 sub js_redisplay_cvpartnumbers {
1360   my ($self) = @_;
1361
1362   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1363
1364   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1365
1366   $self->js
1367     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1368 }
1369
1370 sub js_reset_order_and_item_ids_after_save {
1371   my ($self) = @_;
1372
1373   $self->js
1374     ->val('#id', $self->order->id)
1375     ->val('#converted_from_oe_id', '')
1376     ->val('#order_' . $self->nr_key(), $self->order->number);
1377
1378   my $idx = 0;
1379   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1380     next if !$self->order->items_sorted->[$idx]->id;
1381     next if $form_item_id !~ m{^new};
1382     $self->js
1383       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1384       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1385       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1386   } continue {
1387     $idx++;
1388   }
1389   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1390 }
1391
1392 #
1393 # helpers
1394 #
1395
1396 sub init_valid_types {
1397   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1398 }
1399
1400 sub init_type {
1401   my ($self) = @_;
1402
1403   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1404     die "Not a valid type for order";
1405   }
1406
1407   $self->type($::form->{type});
1408 }
1409
1410 sub init_cv {
1411   my ($self) = @_;
1412
1413   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1414          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1415          : die "Not a valid type for order";
1416
1417   return $cv;
1418 }
1419
1420 sub init_search_cvpartnumber {
1421   my ($self) = @_;
1422
1423   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1424   my $search_cvpartnumber;
1425   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1426   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1427
1428   return $search_cvpartnumber;
1429 }
1430
1431 sub init_show_update_button {
1432   my ($self) = @_;
1433
1434   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1435 }
1436
1437 sub init_p {
1438   SL::Presenter->get;
1439 }
1440
1441 sub init_order {
1442   $_[0]->make_order;
1443 }
1444
1445 sub init_all_price_factors {
1446   SL::DB::Manager::PriceFactor->get_all;
1447 }
1448
1449 sub init_part_picker_classification_ids {
1450   my ($self)    = @_;
1451   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1452
1453   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1454 }
1455
1456 sub check_auth {
1457   my ($self) = @_;
1458
1459   my $right_for = { map { $_ => $_.'_edit' . ' | ' . $_.'_view' } @{$self->valid_types} };
1460
1461   my $right   = $right_for->{ $self->type };
1462   $right    ||= 'DOES_NOT_EXIST';
1463
1464   $::auth->assert($right);
1465 }
1466
1467 sub check_auth_for_edit {
1468   my ($self) = @_;
1469
1470   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1471
1472   my $right   = $right_for->{ $self->type };
1473   $right    ||= 'DOES_NOT_EXIST';
1474
1475   $::auth->assert($right);
1476 }
1477
1478 # build the selection box for contacts
1479 #
1480 # Needed, if customer/vendor changed.
1481 sub build_contact_select {
1482   my ($self) = @_;
1483
1484   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1485     value_key  => 'cp_id',
1486     title_key  => 'full_name_dep',
1487     default    => $self->order->cp_id,
1488     with_empty => 1,
1489     style      => 'width: 300px',
1490   );
1491 }
1492
1493 # build the selection box for the additional billing address
1494 #
1495 # Needed, if customer/vendor changed.
1496 sub build_billing_address_select {
1497   my ($self) = @_;
1498
1499   return '' if $self->cv ne 'customer';
1500
1501   select_tag('order.billing_address_id',
1502              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1503              value_key  => 'id',
1504              title_key  => 'displayable_id',
1505              default    => $self->order->billing_address_id,
1506              with_empty => 0,
1507              style      => 'width: 300px',
1508   );
1509 }
1510
1511 # build the selection box for shiptos
1512 #
1513 # Needed, if customer/vendor changed.
1514 sub build_shipto_select {
1515   my ($self) = @_;
1516
1517   select_tag('order.shipto_id',
1518              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1519              value_key  => 'shipto_id',
1520              title_key  => 'displayable_id',
1521              default    => $self->order->shipto_id,
1522              with_empty => 0,
1523              style      => 'width: 300px',
1524   );
1525 }
1526
1527 # build the inputs for the cusom shipto dialog
1528 #
1529 # Needed, if customer/vendor changed.
1530 sub build_shipto_inputs {
1531   my ($self) = @_;
1532
1533   my $content = $self->p->render('common/_ship_to_dialog',
1534                                  vc_obj      => $self->order->customervendor,
1535                                  cs_obj      => $self->order->custom_shipto,
1536                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1537                                  id_selector => '#order_shipto_id');
1538
1539   div_tag($content, id => 'shipto_inputs');
1540 }
1541
1542 # render the info line for business
1543 #
1544 # Needed, if customer/vendor changed.
1545 sub build_business_info_row
1546 {
1547   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1548 }
1549
1550 # build the rows for displaying taxes
1551 #
1552 # Called if amounts where recalculated and redisplayed.
1553 sub build_tax_rows {
1554   my ($self) = @_;
1555
1556   my $rows_as_html;
1557   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1558     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1559   }
1560   return $rows_as_html;
1561 }
1562
1563
1564 sub render_price_dialog {
1565   my ($self, $record_item) = @_;
1566
1567   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1568
1569   $self->js
1570     ->run(
1571       'kivi.io.price_chooser_dialog',
1572       t8('Available Prices'),
1573       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1574     )
1575     ->reinit_widgets;
1576
1577 #   if (@errors) {
1578 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1579 #     $self->js->show('#dialog_flash_error');
1580 #   }
1581
1582   $self->js->render;
1583 }
1584
1585 sub load_order {
1586   my ($self) = @_;
1587
1588   return if !$::form->{id};
1589
1590   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1591
1592   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1593   # You need a custom shipto object to call cvars_by_config to get the cvars.
1594   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1595
1596   return $self->order;
1597 }
1598
1599 # load or create a new order object
1600 #
1601 # And assign changes from the form to this object.
1602 # If the order is loaded from db, check if items are deleted in the form,
1603 # remove them form the object and collect them for removing from db on saving.
1604 # Then create/update items from form (via make_item) and add them.
1605 sub make_order {
1606   my ($self) = @_;
1607
1608   # add_items adds items to an order with no items for saving, but they cannot
1609   # be retrieved via items until the order is saved. Adding empty items to new
1610   # order here solves this problem.
1611   my $order;
1612   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1613   $order ||= SL::DB::Order->new(orderitems  => [],
1614                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1615                                 currency_id => $::instance_conf->get_currency_id(),);
1616
1617   my $cv_id_method = $self->cv . '_id';
1618   if (!$::form->{id} && $::form->{$cv_id_method}) {
1619     $order->$cv_id_method($::form->{$cv_id_method});
1620     setup_order_from_cv($order);
1621   }
1622
1623   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1624   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1625
1626   $order->assign_attributes(%{$::form->{order}});
1627
1628   $self->setup_custom_shipto_from_form($order, $::form);
1629
1630   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1631     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1632     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1633   }
1634
1635   # remove deleted items
1636   $self->item_ids_to_delete([]);
1637   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1638     my $item = $order->orderitems->[$idx];
1639     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1640       splice @{$order->orderitems}, $idx, 1;
1641       push @{$self->item_ids_to_delete}, $item->id;
1642     }
1643   }
1644
1645   my @items;
1646   my $pos = 1;
1647   foreach my $form_attr (@{$form_orderitems}) {
1648     my $item = make_item($order, $form_attr);
1649     $item->position($pos);
1650     push @items, $item;
1651     $pos++;
1652   }
1653   $order->add_items(grep {!$_->id} @items);
1654
1655   return $order;
1656 }
1657
1658 # create or update items from form
1659 #
1660 # Make item objects from form values. For items already existing read from db.
1661 # Create a new item else. And assign attributes.
1662 sub make_item {
1663   my ($record, $attr) = @_;
1664
1665   my $item;
1666   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1667
1668   my $is_new = !$item;
1669
1670   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1671   # they cannot be retrieved via custom_variables until the order/orderitem is
1672   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1673   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1674
1675   $item->assign_attributes(%$attr);
1676
1677   if ($is_new) {
1678     my $texts = get_part_texts($item->part, $record->language_id);
1679     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1680     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1681     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1682   }
1683
1684   return $item;
1685 }
1686
1687 # create a new item
1688 #
1689 # This is used to add one item
1690 sub new_item {
1691   my ($record, $attr) = @_;
1692
1693   my $item = SL::DB::OrderItem->new;
1694
1695   # Remove attributes where the user left or set the inputs empty.
1696   # So these attributes will be undefined and we can distinguish them
1697   # from zero later on.
1698   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1699     delete $attr->{$_} if $attr->{$_} eq '';
1700   }
1701
1702   $item->assign_attributes(%$attr);
1703
1704   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1705   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1706
1707   $item->qty(1.0)          if !$item->qty;
1708   $item->unit($part->unit) if !$item->unit;
1709
1710   my $price_src;
1711   if ( $part->is_assortment ) {
1712     # add assortment items with price 0, as the components carry the price
1713     $price_src = $price_source->price_from_source("");
1714     $price_src->price(0);
1715   } elsif (defined $item->sellprice) {
1716     $price_src = $price_source->price_from_source("");
1717     $price_src->price($item->sellprice);
1718   } else {
1719     $price_src = $price_source->best_price
1720                ? $price_source->best_price
1721                : $price_source->price_from_source("");
1722     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1723     $price_src->price(0) if !$price_source->best_price;
1724   }
1725
1726   my $discount_src;
1727   if (defined $item->discount) {
1728     $discount_src = $price_source->discount_from_source("");
1729     $discount_src->discount($item->discount);
1730   } else {
1731     $discount_src = $price_source->best_discount
1732                   ? $price_source->best_discount
1733                   : $price_source->discount_from_source("");
1734     $discount_src->discount(0) if !$price_source->best_discount;
1735   }
1736
1737   my %new_attr;
1738   $new_attr{part}                   = $part;
1739   $new_attr{description}            = $part->description     if ! $item->description;
1740   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1741   $new_attr{sellprice}              = $price_src->price;
1742   $new_attr{discount}               = $discount_src->discount;
1743   $new_attr{active_price_source}    = $price_src;
1744   $new_attr{active_discount_source} = $discount_src;
1745   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1746   $new_attr{project_id}             = $record->globalproject_id;
1747   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1748
1749   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1750   # they cannot be retrieved via custom_variables until the order/orderitem is
1751   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1752   $new_attr{custom_variables} = [];
1753
1754   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1755
1756   $item->assign_attributes(%new_attr, %{ $texts });
1757
1758   return $item;
1759 }
1760
1761 sub setup_order_from_cv {
1762   my ($order) = @_;
1763
1764   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id language_id));
1765
1766   $order->intnotes($order->customervendor->notes);
1767
1768   return if !$order->is_sales;
1769
1770   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1771   $order->taxincluded(defined($order->customer->taxincluded_checked)
1772                       ? $order->customer->taxincluded_checked
1773                       : $::myconfig{taxincluded_checked});
1774
1775   my $address = $order->customer->default_billing_address;;
1776   $order->billing_address_id($address ? $address->id : undef);
1777 }
1778
1779 # setup custom shipto from form
1780 #
1781 # The dialog returns form variables starting with 'shipto' and cvars starting
1782 # with 'shiptocvar_'.
1783 # Mark it to be deleted if a shipto from master data is selected
1784 # (i.e. order has a shipto).
1785 # Else, update or create a new custom shipto. If the fields are empty, it
1786 # will not be saved on save.
1787 sub setup_custom_shipto_from_form {
1788   my ($self, $order, $form) = @_;
1789
1790   if ($order->shipto) {
1791     $self->is_custom_shipto_to_delete(1);
1792   } else {
1793     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1794
1795     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1796     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1797
1798     $custom_shipto->assign_attributes(%$shipto_attrs);
1799     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1800   }
1801 }
1802
1803 # recalculate prices and taxes
1804 #
1805 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1806 sub recalc {
1807   my ($self) = @_;
1808
1809   my %pat = $self->order->calculate_prices_and_taxes();
1810
1811   $self->{taxes} = [];
1812   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1813     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1814
1815     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1816                                 netamount => $netamount,
1817                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1818   }
1819   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1820 }
1821
1822 # get data for saving, printing, ..., that is not changed in the form
1823 #
1824 # Only cvars for now.
1825 sub get_unalterable_data {
1826   my ($self) = @_;
1827
1828   foreach my $item (@{ $self->order->items }) {
1829     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1830     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1831     foreach my $var (@{ $item->cvars_by_config }) {
1832       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1833     }
1834     $item->parse_custom_variable_values;
1835   }
1836 }
1837
1838 # delete the order
1839 #
1840 # And remove related files in the spool directory
1841 sub delete {
1842   my ($self) = @_;
1843
1844   my $errors = [];
1845   my $db     = $self->order->db;
1846
1847   $db->with_transaction(
1848     sub {
1849       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1850       $self->order->delete;
1851       my $spool = $::lx_office_conf{paths}->{spool};
1852       unlink map { "$spool/$_" } @spoolfiles if $spool;
1853
1854       $self->save_history('DELETED');
1855
1856       1;
1857   }) || push(@{$errors}, $db->error);
1858
1859   return $errors;
1860 }
1861
1862 # save the order
1863 #
1864 # And delete items that are deleted in the form.
1865 sub save {
1866   my ($self) = @_;
1867
1868   my $errors = [];
1869   my $db     = $self->order->db;
1870
1871   $db->with_transaction(sub {
1872     # delete custom shipto if it is to be deleted or if it is empty
1873     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1874       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1875       $self->order->custom_shipto(undef);
1876     }
1877
1878     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1879     $self->order->save(cascade => 1);
1880
1881     # link records
1882     if ($::form->{converted_from_oe_id}) {
1883       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1884
1885       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1886         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1887         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1888         $src->link_to_record($self->order);
1889       }
1890       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1891         my $idx = 0;
1892         foreach (@{ $self->order->items_sorted }) {
1893           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1894           next if !$from_id;
1895           SL::DB::RecordLink->new(from_table => 'orderitems',
1896                                   from_id    => $from_id,
1897                                   to_table   => 'orderitems',
1898                                   to_id      => $_->id
1899           )->save;
1900           $idx++;
1901         }
1902       }
1903
1904       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1905     }
1906
1907     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1908
1909     $self->save_history('SAVED');
1910
1911     1;
1912   }) || push(@{$errors}, $db->error);
1913
1914   return $errors;
1915 }
1916
1917 sub workflow_sales_or_request_for_quotation {
1918   my ($self) = @_;
1919
1920   # always save
1921   my $errors = $self->save();
1922
1923   if (scalar @{ $errors }) {
1924     $self->js->flash('error', $_) for @{ $errors };
1925     return $self->js->render();
1926   }
1927
1928   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1929
1930   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1931   delete $::form->{id};
1932
1933   # no linked records from order to quotations
1934   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
1935
1936   # set item ids to new fake id, to identify them as new items
1937   foreach my $item (@{$self->order->items_sorted}) {
1938     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1939   }
1940
1941   # change form type
1942   $::form->{type} = $destination_type;
1943   $self->type($self->init_type);
1944   $self->cv  ($self->init_cv);
1945   $self->check_auth;
1946
1947   $self->recalc();
1948   $self->get_unalterable_data();
1949   $self->pre_render();
1950
1951   # trigger rendering values for second row as hidden, because they
1952   # are loaded only on demand. So we need to keep the values from the
1953   # source.
1954   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1955
1956   $self->render(
1957     'order/form',
1958     title => $self->get_title_for('edit'),
1959     %{$self->{template_args}}
1960   );
1961 }
1962
1963 sub workflow_sales_or_purchase_order {
1964   my ($self) = @_;
1965
1966   # always save
1967   my $errors = $self->save();
1968
1969   if (scalar @{ $errors }) {
1970     $self->js->flash('error', $_) foreach @{ $errors };
1971     return $self->js->render();
1972   }
1973
1974   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1975                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1976                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1977                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1978                        : '';
1979
1980   # check for direct delivery
1981   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1982   my $custom_shipto;
1983   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1984       && $::form->{use_shipto} && $self->order->shipto) {
1985     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1986   }
1987
1988   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1989   $self->{converted_from_oe_id} = delete $::form->{id};
1990
1991   # set item ids to new fake id, to identify them as new items
1992   foreach my $item (@{$self->order->items_sorted}) {
1993     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1994   }
1995
1996   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1997     if ($::form->{use_shipto}) {
1998       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1999     } else {
2000       # remove any custom shipto if not wanted
2001       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
2002     }
2003   }
2004
2005   # change form type
2006   $::form->{type} = $destination_type;
2007   $self->type($self->init_type);
2008   $self->cv  ($self->init_cv);
2009   $self->check_auth;
2010
2011   $self->recalc();
2012   $self->get_unalterable_data();
2013   $self->pre_render();
2014
2015   # trigger rendering values for second row as hidden, because they
2016   # are loaded only on demand. So we need to keep the values from the
2017   # source.
2018   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
2019
2020   $self->render(
2021     'order/form',
2022     title => $self->get_title_for('edit'),
2023     %{$self->{template_args}}
2024   );
2025 }
2026
2027
2028 sub pre_render {
2029   my ($self) = @_;
2030
2031   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
2032   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
2033   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
2034   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted( query => [ or => [ obsolete => 0, id => $self->order->language_id ] ] );
2035   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
2036                                                                                               deleted => 0 ] ],
2037                                                                            sort_by => 'name');
2038   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
2039                                                                                               deleted => 0 ] ],
2040                                                                            sort_by => 'name');
2041   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
2042                                                                                                         obsolete => 0 ] ]);
2043   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
2044   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
2045   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
2046   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
2047   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
2048
2049   my $print_form = Form->new('');
2050   $print_form->{type}        = $self->type;
2051   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
2052   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
2053     form => $print_form,
2054     options => {dialog_name_prefix => 'print_options.',
2055                 show_headers       => 1,
2056                 no_queue           => 1,
2057                 no_postscript      => 1,
2058                 no_opendocument    => 0,
2059                 no_html            => 0},
2060   );
2061
2062   foreach my $item (@{$self->order->orderitems}) {
2063     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
2064     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
2065     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
2066   }
2067
2068   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
2069     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
2070     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
2071     # the value from db, which can be set manually or is set when linked delivery orders are saved.
2072     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
2073   }
2074
2075   if ($self->order->number && $::instance_conf->get_webdav) {
2076     my $webdav = SL::Webdav->new(
2077       type     => $self->type,
2078       number   => $self->order->number,
2079     );
2080     my @all_objects = $webdav->get_all_objects;
2081     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
2082                                                     type => t8('File'),
2083                                                     link => File::Spec->catfile($_->full_filedescriptor),
2084                                                 } } @all_objects;
2085   }
2086
2087   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
2088       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
2089     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
2090   }
2091   $self->{template_args}->{longdescription_dialog_size_percentage} = SL::Helper::UserPreferences::DisplayPreferences->new()->get_longdescription_dialog_size_percentage();
2092
2093   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
2094
2095   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
2096                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
2097   $self->setup_edit_action_bar;
2098 }
2099
2100 sub setup_edit_action_bar {
2101   my ($self, %params) = @_;
2102
2103   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
2104                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
2105                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
2106
2107   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
2108   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
2109
2110   my $has_invoice_for_advance_payment;
2111   if ($self->order->id && $self->type eq sales_order_type()) {
2112     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2113     $has_invoice_for_advance_payment = any {'SL::DB::Invoice' eq ref $_ && "invoice_for_advance_payment" eq $_->type} @$lr;
2114   }
2115
2116   my $has_final_invoice;
2117   if ($self->order->id && $self->type eq sales_order_type()) {
2118     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2119     $has_final_invoice               = any {'SL::DB::Invoice' eq ref $_ && "final_invoice" eq $_->type} @$lr;
2120   }
2121
2122   my $right_for         = { map { $_ => $_.'_edit' } @{$self->valid_types} };
2123   my $right             = $right_for->{ $self->type };
2124   $right              ||= 'DOES_NOT_EXIST';
2125   my $may_edit_create   = $::auth->assert($right, 'may fail');
2126
2127   for my $bar ($::request->layout->get('actionbar')) {
2128     $bar->add(
2129       combobox => [
2130         action => [
2131           t8('Save'),
2132           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2133                                                     $::instance_conf->get_order_warn_no_deliverydate,
2134           ],
2135           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2136                          @req_trans_cost_art, @req_cusordnumber,
2137           ],
2138           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2139         ],
2140         action => [
2141           t8('Save and Close'),
2142           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2143                                                     $::instance_conf->get_order_warn_no_deliverydate,
2144                                                     1
2145           ],
2146           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2147                          @req_trans_cost_art, @req_cusordnumber,
2148           ],
2149           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2150         ],
2151         action => [
2152           t8('Save as new'),
2153           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
2154           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2155                          @req_trans_cost_art, @req_cusordnumber,
2156           ],
2157           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.')
2158                      : !$self->order->id ? t8('This object has not been saved yet.')
2159                      :                     undef,
2160         ],
2161       ], # end of combobox "Save"
2162
2163       combobox => [
2164         action => [
2165           t8('Workflow'),
2166         ],
2167         action => [
2168           t8('Save and Quotation'),
2169           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
2170           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2171           only_if  => (any { $self->type eq $_ } (sales_order_type())),
2172           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2173         ],
2174         action => [
2175           t8('Save and RFQ'),
2176           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
2177           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
2178           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2179         ],
2180         action => [
2181           t8('Save and Sales Order'),
2182           submit   => [ '#order_form', { action => "Order/sales_order" } ],
2183           checks   => [ @req_trans_cost_art ],
2184           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
2185           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2186         ],
2187         action => [
2188           t8('Save and Purchase Order'),
2189           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
2190           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2191           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2192           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2193         ],
2194         action => [
2195           t8('Save and Delivery Order'),
2196           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2197                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2198                                                                                                                         ],
2199           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2200                          @req_trans_cost_art, @req_cusordnumber,
2201           ],
2202           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())),
2203           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2204         ],
2205         action => [
2206           t8('Save and Supplier Delivery Order'),
2207           call      => [ 'kivi.Order.save', 'save_and_supplier_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2208                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2209                                                                                                                         ],
2210           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2211                          @req_trans_cost_art, @req_cusordnumber,
2212           ],
2213           only_if   => (any { $self->type eq $_ } (purchase_order_type())),
2214           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2215         ],
2216         action => [
2217           t8('Save and Invoice'),
2218           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2219           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2220                          @req_trans_cost_art, @req_cusordnumber,
2221           ],
2222           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2223         ],
2224         action => [
2225           ($has_invoice_for_advance_payment ? t8('Save and Further Invoice for Advance Payment') : t8('Save and Invoice for Advance Payment')),
2226           call      => [ 'kivi.Order.save', 'save_and_invoice_for_advance_payment', $::instance_conf->get_order_warn_duplicate_parts ],
2227           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2228                          @req_trans_cost_art, @req_cusordnumber,
2229           ],
2230           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2231                      : $has_final_invoice ? t8('This order has already a final invoice.')
2232                      :                      undef,
2233           only_if   => (any { $self->type eq $_ } (sales_order_type())),
2234         ],
2235         action => [
2236           t8('Save and Final Invoice'),
2237           call      => [ 'kivi.Order.save', 'save_and_final_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2238           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2239                          @req_trans_cost_art, @req_cusordnumber,
2240           ],
2241           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2242                      : $has_final_invoice ? t8('This order has already a final invoice.')
2243                      :                      undef,
2244           only_if   => (any { $self->type eq $_ } (sales_order_type())) && $has_invoice_for_advance_payment,
2245         ],
2246         action => [
2247           t8('Save and AP Transaction'),
2248           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2249           only_if   => (any { $self->type eq $_ } (purchase_order_type())),
2250           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2251         ],
2252
2253       ], # end of combobox "Workflow"
2254
2255       combobox => [
2256         action => [
2257           t8('Export'),
2258         ],
2259         action => [
2260           t8('Save and preview PDF'),
2261           call     => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2262                                                           $::instance_conf->get_order_warn_no_deliverydate,
2263                       ],
2264           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2265           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2266         ],
2267         action => [
2268           t8('Save and print'),
2269           call     => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2270                                                          $::instance_conf->get_order_warn_no_deliverydate,
2271                       ],
2272           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2273           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2274         ],
2275         action => [
2276           t8('Save and E-mail'),
2277           id       => 'save_and_email_action',
2278           call     => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2279                                                                          $::instance_conf->get_order_warn_no_deliverydate,
2280                       ],
2281           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2282                     : !$self->order->id  ? t8('This object has not been saved yet.')
2283                     :                      undef,
2284         ],
2285         action => [
2286           t8('Download attachments of all parts'),
2287           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2288           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2289           only_if  => $::instance_conf->get_doc_storage,
2290         ],
2291       ], # end of combobox "Export"
2292
2293       action => [
2294         t8('Delete'),
2295         call     => [ 'kivi.Order.delete_order' ],
2296         confirm  => $::locale->text('Do you really want to delete this object?'),
2297         disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2298                   : !$self->order->id  ? t8('This object has not been saved yet.')
2299                   :                      undef,
2300         only_if  => $deletion_allowed,
2301       ],
2302
2303       combobox => [
2304         action => [
2305           t8('more')
2306         ],
2307         action => [
2308           t8('History'),
2309           call     => [ 'set_history_window', $self->order->id, 'id' ],
2310           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2311         ],
2312         action => [
2313           t8('Follow-Up'),
2314           call     => [ 'kivi.Order.follow_up_window' ],
2315           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2316           only_if  => $::auth->assert('productivity', 1),
2317         ],
2318       ], # end of combobox "more"
2319     );
2320   }
2321 }
2322
2323 sub generate_doc {
2324   my ($self, $doc_ref, $params) = @_;
2325
2326   my $order  = $self->order;
2327   my @errors = ();
2328
2329   my $print_form = Form->new('');
2330   $print_form->{type}        = $order->type;
2331   $print_form->{formname}    = $params->{formname} || $order->type;
2332   $print_form->{format}      = $params->{format}   || 'pdf';
2333   $print_form->{media}       = $params->{media}    || 'file';
2334   $print_form->{groupitems}  = $params->{groupitems};
2335   $print_form->{printer_id}  = $params->{printer_id};
2336   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2337
2338   $order->language($params->{language});
2339   $order->flatten_to_form($print_form, format_amounts => 1);
2340
2341   my $template_ext;
2342   my $template_type;
2343   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2344     $template_ext  = 'odt';
2345     $template_type = 'OpenDocument';
2346   } elsif ($print_form->{format} =~ m{html}i) {
2347     $template_ext  = 'html';
2348     $template_type = 'HTML';
2349   }
2350
2351   # search for the template
2352   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2353     name        => $print_form->{formname},
2354     extension   => $template_ext,
2355     email       => $print_form->{media} eq 'email',
2356     language    => $params->{language},
2357     printer_id  => $print_form->{printer_id},
2358   );
2359
2360   if (!defined $template_file) {
2361     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2362   }
2363
2364   return @errors if scalar @errors;
2365
2366   $print_form->throw_on_error(sub {
2367     eval {
2368       $print_form->prepare_for_printing;
2369
2370       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2371         format        => $print_form->{format},
2372         template_type => $template_type,
2373         template      => $template_file,
2374         variables     => $print_form,
2375         variable_content_types => {
2376           longdescription => 'html',
2377           partnotes       => 'html',
2378           notes           => 'html',
2379           $::form->get_variable_content_types_for_cvars,
2380         },
2381       );
2382       1;
2383     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2384   });
2385
2386   return @errors;
2387 }
2388
2389 sub get_files_for_email_dialog {
2390   my ($self) = @_;
2391
2392   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2393
2394   return %files if !$::instance_conf->get_doc_storage;
2395
2396   if ($self->order->id) {
2397     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2398     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2399     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2400     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2401   }
2402
2403   my @parts =
2404     uniq_by { $_->{id} }
2405     map {
2406       +{ id         => $_->part->id,
2407          partnumber => $_->part->partnumber }
2408     } @{$self->order->items_sorted};
2409
2410   foreach my $part (@parts) {
2411     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2412     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2413   }
2414
2415   foreach my $key (keys %files) {
2416     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2417   }
2418
2419   return %files;
2420 }
2421
2422 sub make_periodic_invoices_config_from_yaml {
2423   my ($yaml_config) = @_;
2424
2425   return if !$yaml_config;
2426   my $attr = SL::YAML::Load($yaml_config);
2427   return if 'HASH' ne ref $attr;
2428   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2429 }
2430
2431
2432 sub get_periodic_invoices_status {
2433   my ($self, $config) = @_;
2434
2435   return                      if $self->type ne sales_order_type();
2436   return t8('not configured') if !$config;
2437
2438   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2439              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2440              :                                                     die "Cannot get status of periodic invoices config";
2441
2442   return $active ? t8('active') : t8('inactive');
2443 }
2444
2445 sub get_title_for {
2446   my ($self, $action) = @_;
2447
2448   return '' if none { lc($action)} qw(add edit);
2449
2450   # for locales:
2451   # $::locale->text("Add Sales Order");
2452   # $::locale->text("Add Purchase Order");
2453   # $::locale->text("Add Quotation");
2454   # $::locale->text("Add Request for Quotation");
2455   # $::locale->text("Edit Sales Order");
2456   # $::locale->text("Edit Purchase Order");
2457   # $::locale->text("Edit Quotation");
2458   # $::locale->text("Edit Request for Quotation");
2459
2460   $action = ucfirst(lc($action));
2461   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2462        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2463        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2464        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2465        : '';
2466 }
2467
2468 sub get_item_cvpartnumber {
2469   my ($self, $item) = @_;
2470
2471   return if !$self->search_cvpartnumber;
2472   return if !$self->order->customervendor;
2473
2474   if ($self->cv eq 'vendor') {
2475     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2476     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2477   } elsif ($self->cv eq 'customer') {
2478     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2479     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2480   }
2481 }
2482
2483 sub get_part_texts {
2484   my ($part_or_id, $language_or_id, %defaults) = @_;
2485
2486   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2487   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2488   my $texts       = {
2489     description     => $defaults{description}     // $part->description,
2490     longdescription => $defaults{longdescription} // $part->notes,
2491   };
2492
2493   return $texts unless $language_id;
2494
2495   my $translation = SL::DB::Manager::Translation->get_first(
2496     where => [
2497       parts_id    => $part->id,
2498       language_id => $language_id,
2499     ]);
2500
2501   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2502   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2503
2504   return $texts;
2505 }
2506
2507 sub sales_order_type {
2508   'sales_order';
2509 }
2510
2511 sub purchase_order_type {
2512   'purchase_order';
2513 }
2514
2515 sub sales_quotation_type {
2516   'sales_quotation';
2517 }
2518
2519 sub request_quotation_type {
2520   'request_quotation';
2521 }
2522
2523 sub nr_key {
2524   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2525        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2526        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2527        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2528        : '';
2529 }
2530
2531 sub save_and_redirect_to {
2532   my ($self, %params) = @_;
2533
2534   my $errors = $self->save();
2535
2536   if (scalar @{ $errors }) {
2537     $self->js->flash('error', $_) foreach @{ $errors };
2538     return $self->js->render();
2539   }
2540
2541   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2542            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2543            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2544            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2545            : '';
2546   flash_later('info', $text);
2547
2548   $self->redirect_to(%params, id => $self->order->id);
2549 }
2550
2551 sub save_history {
2552   my ($self, $addition) = @_;
2553
2554   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2555   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2556
2557   SL::DB::History->new(
2558     trans_id    => $self->order->id,
2559     employee_id => SL::DB::Manager::Employee->current->id,
2560     what_done   => $self->order->type,
2561     snumbers    => $snumbers,
2562     addition    => $addition,
2563   )->save;
2564 }
2565
2566 sub store_doc_to_webdav_and_filemanagement {
2567   my ($self, $content, $filename, $variant) = @_;
2568
2569   my $order = $self->order;
2570   my @errors;
2571
2572   # copy file to webdav folder
2573   if ($order->number && $::instance_conf->get_webdav_documents) {
2574     my $webdav = SL::Webdav->new(
2575       type     => $order->type,
2576       number   => $order->number,
2577     );
2578     my $webdav_file = SL::Webdav::File->new(
2579       webdav   => $webdav,
2580       filename => $filename,
2581     );
2582     eval {
2583       $webdav_file->store(data => \$content);
2584       1;
2585     } or do {
2586       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2587     };
2588   }
2589   if ($order->id && $::instance_conf->get_doc_storage) {
2590     eval {
2591       SL::File->save(object_id     => $order->id,
2592                      object_type   => $order->type,
2593                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2594                      source        => 'created',
2595                      file_type     => 'document',
2596                      file_name     => $filename,
2597                      file_contents => $content,
2598                      print_variant => $variant);
2599       1;
2600     } or do {
2601       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2602     };
2603   }
2604
2605   return @errors;
2606 }
2607
2608 sub link_requirement_specs_linking_to_created_from_objects {
2609   my ($self, @converted_from_oe_ids) = @_;
2610
2611   return unless @converted_from_oe_ids;
2612
2613   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2614   foreach my $rs_order (@{ $rs_orders }) {
2615     SL::DB::RequirementSpecOrder->new(
2616       order_id            => $self->order->id,
2617       requirement_spec_id => $rs_order->requirement_spec_id,
2618       version_id          => $rs_order->version_id,
2619     )->save;
2620   }
2621 }
2622
2623 sub set_project_in_linked_requirement_specs {
2624   my ($self) = @_;
2625
2626   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2627   foreach my $rs_order (@{ $rs_orders }) {
2628     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2629
2630     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2631   }
2632 }
2633
2634 1;
2635
2636 __END__
2637
2638 =encoding utf-8
2639
2640 =head1 NAME
2641
2642 SL::Controller::Order - controller for orders
2643
2644 =head1 SYNOPSIS
2645
2646 This is a new form to enter orders, completely rewritten with the use
2647 of controller and java script techniques.
2648
2649 The aim is to provide the user a better experience and a faster workflow. Also
2650 the code should be more readable, more reliable and better to maintain.
2651
2652 =head2 Key Features
2653
2654 =over 4
2655
2656 =item *
2657
2658 One input row, so that input happens every time at the same place.
2659
2660 =item *
2661
2662 Use of pickers where possible.
2663
2664 =item *
2665
2666 Possibility to enter more than one item at once.
2667
2668 =item *
2669
2670 Item list in a scrollable area, so that the workflow buttons stay at
2671 the bottom.
2672
2673 =item *
2674
2675 Reordering item rows with drag and drop is possible. Sorting item rows is
2676 possible (by partnumber, description, qty, sellprice and discount for now).
2677
2678 =item *
2679
2680 No C<update> is necessary. All entries and calculations are managed
2681 with ajax-calls and the page only reloads on C<save>.
2682
2683 =item *
2684
2685 User can see changes immediately, because of the use of java script
2686 and ajax.
2687
2688 =back
2689
2690 =head1 CODE
2691
2692 =head2 Layout
2693
2694 =over 4
2695
2696 =item * C<SL/Controller/Order.pm>
2697
2698 the controller
2699
2700 =item * C<template/webpages/order/form.html>
2701
2702 main form
2703
2704 =item * C<template/webpages/order/tabs/basic_data.html>
2705
2706 Main tab for basic_data.
2707
2708 This is the only tab here for now. "linked records" and "webdav" tabs are
2709 reused from generic code.
2710
2711 =over 4
2712
2713 =item * C<template/webpages/order/tabs/_business_info_row.html>
2714
2715 For displaying information on business type
2716
2717 =item * C<template/webpages/order/tabs/_item_input.html>
2718
2719 The input line for items
2720
2721 =item * C<template/webpages/order/tabs/_row.html>
2722
2723 One row for already entered items
2724
2725 =item * C<template/webpages/order/tabs/_tax_row.html>
2726
2727 Displaying tax information
2728
2729 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2730
2731 Dialog for selecting price and discount sources
2732
2733 =back
2734
2735 =item * C<js/kivi.Order.js>
2736
2737 java script functions
2738
2739 =back
2740
2741 =head1 TODO
2742
2743 =over 4
2744
2745 =item * testing
2746
2747 =item * price sources: little symbols showing better price / better discount
2748
2749 =item * select units in input row?
2750
2751 =item * check for direct delivery (workflow sales order -> purchase order)
2752
2753 =item * access rights
2754
2755 =item * display weights
2756
2757 =item * mtime check
2758
2759 =item * optional client/user behaviour
2760
2761 (transactions has to be set - department has to be set -
2762  force project if enabled in client config)
2763
2764 =back
2765
2766 =head1 KNOWN BUGS AND CAVEATS
2767
2768 =over 4
2769
2770 =item *
2771
2772 No indication that <shift>-up/down expands/collapses second row.
2773
2774 =item *
2775
2776 Table header is not sticky in the scrolling area.
2777
2778 =item *
2779
2780 Sorting does not include C<position>, neither does reordering.
2781
2782 This behavior was implemented intentionally. But we can discuss, which behavior
2783 should be implemented.
2784
2785 =back
2786
2787 =head1 To discuss / Nice to have
2788
2789 =over 4
2790
2791 =item *
2792
2793 How to expand/collapse second row. Now it can be done clicking the icon or
2794 <shift>-up/down.
2795
2796 =item *
2797
2798 This controller uses a (changed) copy of the template for the PriceSource
2799 dialog. Maybe there could be used one code source.
2800
2801 =item *
2802
2803 Rounding-differences between this controller (PriceTaxCalculator) and the old
2804 form. This is not only a problem here, but also in all parts using the PTC.
2805 There exists a ticket and a patch. This patch should be testet.
2806
2807 =item *
2808
2809 An indicator, if the actual inputs are saved (like in an
2810 editor or on text processing application).
2811
2812 =item *
2813
2814 A warning when leaving the page without saveing unchanged inputs.
2815
2816
2817 =back
2818
2819 =head1 AUTHOR
2820
2821 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2822
2823 =cut