SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24 use SL::DB::Shipto;
  25
  26 use SL::Helper::CreatePDF qw(:all);
  27 use SL::Helper::PrintOptions;
  28 use SL::Helper::ShippedQty;
  29 use SL::Helper::UserPreferences::PositionsScrollbar;
  30 use SL::Helper::UserPreferences::UpdatePositions;
  31
  32 use SL::Controller::Helper::GetModels;
  33
  34 use List::Util qw(first sum0);
  35 use List::UtilsBy qw(sort_by uniq_by);
  36 use List::MoreUtils qw(any none pairwise first_index);
  37 use English qw(-no_match_vars);
  38 use File::Spec;
  39 use Cwd;
  40 use Sort::Naturally;
  41
  42 use Rose::Object::MakeMethods::Generic
  43 (
  44  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  45  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors search_cvpartnumber show_update_button) ],
  46 );
  47
  48
  49 # safety
  50 __PACKAGE__->run_before('check_auth');
  51
  52 __PACKAGE__->run_before('recalc',
  53                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  54                                      print send_email) ]);
  55
  56 __PACKAGE__->run_before('get_unalterable_data',
  57                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  58                                      print send_email) ]);
  59
  60 #
  61 # actions
  62 #
  63
  64 # add a new order
  65 sub action_add {
  66   my ($self) = @_;
  67
  68   $self->order->transdate(DateTime->now_local());
  69   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  70                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  71   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  72
  73
  74   $self->pre_render();
  75   $self->render(
  76     'order/form',
  77     title => $self->get_title_for('add'),
  78     %{$self->{template_args}}
  79   );
  80 }
  81
  82 # edit an existing order
  83 sub action_edit {
  84   my ($self) = @_;
  85
  86   if ($::form->{id}) {
  87     $self->load_order;
  88
  89   } else {
  90     # this is to edit an order from an unsaved order object
  91
  92     # set item ids to new fake id, to identify them as new items
  93     foreach my $item (@{$self->order->items_sorted}) {
  94       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  95     }
  96     # trigger rendering values for second row/longdescription as hidden,
  97     # because they are loaded only on demand. So we need to keep the values
  98     # from the source.
  99     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
 100     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 101   }
 102
 103   $self->recalc();
 104   $self->pre_render();
 105   $self->render(
 106     'order/form',
 107     title => $self->get_title_for('edit'),
 108     %{$self->{template_args}}
 109   );
 110 }
 111
 112 # edit a collective order (consisting of one or more existing orders)
 113 sub action_edit_collective {
 114   my ($self) = @_;
 115
 116   # collect order ids
 117   my @multi_ids = map {
 118     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 119   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 120
 121   # fall back to add if no ids are given
 122   if (scalar @multi_ids == 0) {
 123     $self->action_add();
 124     return;
 125   }
 126
 127   # fall back to save as new if only one id is given
 128   if (scalar @multi_ids == 1) {
 129     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 130     $self->action_save_as_new();
 131     return;
 132   }
 133
 134   # make new order from given orders
 135   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 136   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 137   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 138
 139   $self->action_edit();
 140 }
 141
 142 # delete the order
 143 sub action_delete {
 144   my ($self) = @_;
 145
 146   my $errors = $self->delete();
 147
 148   if (scalar @{ $errors }) {
 149     $self->js->flash('error', $_) foreach @{ $errors };
 150     return $self->js->render();
 151   }
 152
 153   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 154            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 155            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 156            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 157            : '';
 158   flash_later('info', $text);
 159
 160   my @redirect_params = (
 161     action => 'add',
 162     type   => $self->type,
 163   );
 164
 165   $self->redirect_to(@redirect_params);
 166 }
 167
 168 # save the order
 169 sub action_save {
 170   my ($self) = @_;
 171
 172   my $errors = $self->save();
 173
 174   if (scalar @{ $errors }) {
 175     $self->js->flash('error', $_) foreach @{ $errors };
 176     return $self->js->render();
 177   }
 178
 179   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 180            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 181            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 182            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 183            : '';
 184   flash_later('info', $text);
 185
 186   my @redirect_params = (
 187     action => 'edit',
 188     type   => $self->type,
 189     id     => $self->order->id,
 190   );
 191
 192   $self->redirect_to(@redirect_params);
 193 }
 194
 195 # save the order as new document an open it for edit
 196 sub action_save_as_new {
 197   my ($self) = @_;
 198
 199   my $order = $self->order;
 200
 201   if (!$order->id) {
 202     $self->js->flash('error', t8('This object has not been saved yet.'));
 203     return $self->js->render();
 204   }
 205
 206   # load order from db to check if values changed
 207   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 208
 209   my %new_attrs;
 210   # Lets assign a new number if the user hasn't changed the previous one.
 211   # If it has been changed manually then use it as-is.
 212   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 213                         ? ''
 214                         : trim($order->number);
 215
 216   # Clear transdate unless changed
 217   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 218                         ? DateTime->today_local
 219                         : $order->transdate;
 220
 221   # Set new reqdate unless changed
 222   if ($order->reqdate == $saved_order->reqdate) {
 223     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 224                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 225     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 226   } else {
 227     $new_attrs{reqdate} = $order->reqdate;
 228   }
 229
 230   # Update employee
 231   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 232
 233   # Create new record from current one
 234   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 235
 236   # no linked records on save as new
 237   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 238
 239   # save
 240   $self->action_save();
 241 }
 242
 243 # print the order
 244 #
 245 # This is called if "print" is pressed in the print dialog.
 246 # If PDF creation was requested and succeeded, the pdf is offered for download
 247 # via send_file (which uses ajax in this case).
 248 sub action_print {
 249   my ($self) = @_;
 250
 251   my $errors = $self->save();
 252
 253   if (scalar @{ $errors }) {
 254     $self->js->flash('error', $_) foreach @{ $errors };
 255     return $self->js->render();
 256   }
 257
 258   $self->js_reset_order_and_item_ids_after_save;
 259
 260   my $format      = $::form->{print_options}->{format};
 261   my $media       = $::form->{print_options}->{media};
 262   my $formname    = $::form->{print_options}->{formname};
 263   my $copies      = $::form->{print_options}->{copies};
 264   my $groupitems  = $::form->{print_options}->{groupitems};
 265
 266   # only pdf and opendocument by now
 267   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 268     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 269   }
 270
 271   # only screen or printer by now
 272   if (none { $media eq $_ } qw(screen printer)) {
 273     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 274   }
 275
 276   my $language;
 277   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 278
 279   # create a form for generate_attachment_filename
 280   my $form   = Form->new;
 281   $form->{$self->nr_key()}  = $self->order->number;
 282   $form->{type}             = $self->type;
 283   $form->{format}           = $format;
 284   $form->{formname}         = $formname;
 285   $form->{language}         = '_' . $language->template_code if $language;
 286   my $pdf_filename          = $form->generate_attachment_filename();
 287
 288   my $pdf;
 289   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 290                                                    formname   => $formname,
 291                                                    language   => $language,
 292                                                    groupitems => $groupitems });
 293   if (scalar @errors) {
 294     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 295   }
 296
 297   if ($media eq 'screen') {
 298     # screen/download
 299     $self->js->flash('info', t8('The PDF has been created'));
 300     $self->send_file(
 301       \$pdf,
 302       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 303       name         => $pdf_filename,
 304       js_no_render => 1,
 305     );
 306
 307   } elsif ($media eq 'printer') {
 308     # printer
 309     my $printer_id = $::form->{print_options}->{printer_id};
 310     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 311       copies  => $copies,
 312       content => $pdf,
 313     );
 314
 315     $self->js->flash('info', t8('The PDF has been printed'));
 316   }
 317
 318   # copy file to webdav folder
 319   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 320     my $webdav = SL::Webdav->new(
 321       type     => $self->type,
 322       number   => $self->order->number,
 323     );
 324     my $webdav_file = SL::Webdav::File->new(
 325       webdav   => $webdav,
 326       filename => $pdf_filename,
 327     );
 328     eval {
 329       $webdav_file->store(data => \$pdf);
 330       1;
 331     } or do {
 332       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 333     }
 334   }
 335   if ($self->order->number && $::instance_conf->get_doc_storage) {
 336     eval {
 337       SL::File->save(object_id     => $self->order->id,
 338                      object_type   => $self->type,
 339                      mime_type     => 'application/pdf',
 340                      source        => 'created',
 341                      file_type     => 'document',
 342                      file_name     => $pdf_filename,
 343                      file_contents => $pdf);
 344       1;
 345     } or do {
 346       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 347     }
 348   }
 349   $self->js->render;
 350 }
 351
 352 # open the email dialog
 353 sub action_show_email_dialog {
 354   my ($self) = @_;
 355
 356   my $cv_method = $self->cv;
 357
 358   if (!$self->order->$cv_method) {
 359     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 360                     ->render($self);
 361   }
 362
 363   my $email_form;
 364   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 365   $email_form->{to} ||= $self->order->$cv_method->email;
 366   $email_form->{cc}   = $self->order->$cv_method->cc;
 367   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 368   # Todo: get addresses from shipto, if any
 369
 370   my $form = Form->new;
 371   $form->{$self->nr_key()}  = $self->order->number;
 372   $form->{formname}         = $self->type;
 373   $form->{type}             = $self->type;
 374   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 375   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 376   $form->{format}           = 'pdf';
 377
 378   $email_form->{subject}             = $form->generate_email_subject();
 379   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 380   $email_form->{message}             = $form->generate_email_body();
 381   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 382
 383   my %files = $self->get_files_for_email_dialog();
 384   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 385                                   email_form  => $email_form,
 386                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 387                                   FILES       => \%files,
 388                                   is_customer => $self->cv eq 'customer',
 389   );
 390
 391   $self->js
 392       ->run('kivi.Order.show_email_dialog', $dialog_html)
 393       ->reinit_widgets
 394       ->render($self);
 395 }
 396
 397 # send email
 398 #
 399 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 400 sub action_send_email {
 401   my ($self) = @_;
 402
 403   my $errors = $self->save();
 404
 405   if (scalar @{ $errors }) {
 406     $self->js->run('kivi.Order.close_email_dialog');
 407     $self->js->flash('error', $_) foreach @{ $errors };
 408     return $self->js->render();
 409   }
 410
 411   $self->js_reset_order_and_item_ids_after_save;
 412
 413   my $email_form  = delete $::form->{email_form};
 414   my %field_names = (to => 'email');
 415
 416   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 417
 418   # for Form::cleanup which may be called in Form::send_email
 419   $::form->{cwd}    = getcwd();
 420   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 421
 422   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 423   $::form->{media}  = 'email';
 424
 425   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 426     my $language;
 427     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 428
 429     my $pdf;
 430     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 431                                                     format     => $::form->{print_options}->{format},
 432                                                     formname   => $::form->{print_options}->{formname},
 433                                                     language   => $language,
 434                                                     groupitems => $::form->{print_options}->{groupitems}});
 435     if (scalar @errors) {
 436       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 437     }
 438
 439     my $sfile = SL::SessionFile::Random->new(mode => "w");
 440     $sfile->fh->print($pdf);
 441     $sfile->fh->close;
 442
 443     $::form->{tmpfile} = $sfile->file_name;
 444     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 445   }
 446
 447   $::form->send_email(\%::myconfig, 'pdf');
 448
 449   # internal notes
 450   my $intnotes = $self->order->intnotes;
 451   $intnotes   .= "\n\n" if $self->order->intnotes;
 452   $intnotes   .= t8('[email]')                                                                                        . "\n";
 453   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 454   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 455   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 456   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 457   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 458   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 459
 460   $self->order->update_attributes(intnotes => $intnotes);
 461
 462   $self->js
 463       ->val('#order_intnotes', $intnotes)
 464       ->run('kivi.Order.close_email_dialog')
 465       ->flash('info', t8('The email has been sent.'))
 466       ->render($self);
 467 }
 468
 469 # open the periodic invoices config dialog
 470 #
 471 # If there are values in the form (i.e. dialog was opened before),
 472 # then use this values. Create new ones, else.
 473 sub action_show_periodic_invoices_config_dialog {
 474   my ($self) = @_;
 475
 476   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 477   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 478   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 479                                                    order_value_periodicity => 'p', # = same as periodicity
 480                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 481                                                    extend_automatically_by => 12,
 482                                                    active                  => 1,
 483                                                    email_subject           => GenericTranslations->get(
 484                                                                                 language_id      => $::form->{language_id},
 485                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 486                                                    email_body              => GenericTranslations->get(
 487                                                                                 language_id      => $::form->{language_id},
 488                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 489   );
 490   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 491   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 492
 493   $::form->get_lists(printers => "ALL_PRINTERS",
 494                      charts   => { key       => 'ALL_CHARTS',
 495                                    transdate => 'current_date' });
 496
 497   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 498
 499   if ($::form->{customer_id}) {
 500     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 501     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 502   }
 503
 504   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 505                 popup_dialog             => 1,
 506                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 507                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 508                 config                   => $config,
 509                 %$::form);
 510 }
 511
 512 # assign the values of the periodic invoices config dialog
 513 # as yaml in the hidden tag and set the status.
 514 sub action_assign_periodic_invoices_config {
 515   my ($self) = @_;
 516
 517   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 518
 519   my $config = { active                     => $::form->{active}       ? 1 : 0,
 520                  terminated                 => $::form->{terminated}   ? 1 : 0,
 521                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 522                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 523                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 524                  start_date_as_date         => $::form->{start_date_as_date},
 525                  end_date_as_date           => $::form->{end_date_as_date},
 526                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 527                  print                      => $::form->{print}      ? 1                         : 0,
 528                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 529                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 530                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 531                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 532                  send_email                 => $::form->{send_email} ? 1 : 0,
 533                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 534                  email_recipient_address    => $::form->{email_recipient_address},
 535                  email_sender               => $::form->{email_sender},
 536                  email_subject              => $::form->{email_subject},
 537                  email_body                 => $::form->{email_body},
 538                };
 539
 540   my $periodic_invoices_config = SL::YAML::Dump($config);
 541
 542   my $status = $self->get_periodic_invoices_status($config);
 543
 544   $self->js
 545     ->remove('#order_periodic_invoices_config')
 546     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 547     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 548     ->html('#periodic_invoices_status', $status)
 549     ->flash('info', t8('The periodic invoices config has been assigned.'))
 550     ->render($self);
 551 }
 552
 553 sub action_get_has_active_periodic_invoices {
 554   my ($self) = @_;
 555
 556   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 557   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 558
 559   my $has_active_periodic_invoices =
 560        $self->type eq sales_order_type()
 561     && $config
 562     && $config->active
 563     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 564     && $config->get_previous_billed_period_start_date;
 565
 566   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 567 }
 568
 569 # save the order and redirect to the frontend subroutine for a new
 570 # delivery order
 571 sub action_save_and_delivery_order {
 572   my ($self) = @_;
 573
 574   my $errors = $self->save();
 575
 576   if (scalar @{ $errors }) {
 577     $self->js->flash('error', $_) foreach @{ $errors };
 578     return $self->js->render();
 579   }
 580
 581   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 582            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 583            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 584            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 585            : '';
 586   flash_later('info', $text);
 587
 588   my @redirect_params = (
 589     controller => 'oe.pl',
 590     action     => 'oe_delivery_order_from_order',
 591     id         => $self->order->id,
 592   );
 593
 594   $self->redirect_to(@redirect_params);
 595 }
 596
 597 # save the order and redirect to the frontend subroutine for a new
 598 # invoice
 599 sub action_save_and_invoice {
 600   my ($self) = @_;
 601
 602   my $errors = $self->save();
 603
 604   if (scalar @{ $errors }) {
 605     $self->js->flash('error', $_) foreach @{ $errors };
 606     return $self->js->render();
 607   }
 608
 609   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 610            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 611            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 612            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 613            : '';
 614   flash_later('info', $text);
 615
 616   my @redirect_params = (
 617     controller => 'oe.pl',
 618     action     => 'oe_invoice_from_order',
 619     id         => $self->order->id,
 620   );
 621
 622   $self->redirect_to(@redirect_params);
 623 }
 624
 625 # workflow from sales quotation to sales order
 626 sub action_sales_order {
 627   $_[0]->workflow_sales_or_purchase_order();
 628 }
 629
 630 # workflow from rfq to purchase order
 631 sub action_purchase_order {
 632   $_[0]->workflow_sales_or_purchase_order();
 633 }
 634
 635 # workflow from purchase order to ap transaction
 636 sub action_save_and_ap_transaction {
 637   my ($self) = @_;
 638
 639   my $errors = $self->save();
 640
 641   if (scalar @{ $errors }) {
 642     $self->js->flash('error', $_) foreach @{ $errors };
 643     return $self->js->render();
 644   }
 645
 646   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 647            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 648            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 649            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 650            : '';
 651   flash_later('info', $text);
 652
 653   my @redirect_params = (
 654     controller => 'ap.pl',
 655     action     => 'add_from_purchase_order',
 656     id         => $self->order->id,
 657   );
 658
 659   $self->redirect_to(@redirect_params);
 660 }
 661
 662 # set form elements in respect to a changed customer or vendor
 663 #
 664 # This action is called on an change of the customer/vendor picker.
 665 sub action_customer_vendor_changed {
 666   my ($self) = @_;
 667
 668   setup_order_from_cv($self->order);
 669   $self->recalc();
 670
 671   my $cv_method = $self->cv;
 672
 673   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 674     $self->js->show('#cp_row');
 675   } else {
 676     $self->js->hide('#cp_row');
 677   }
 678
 679   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 680     $self->js->show('#shipto_selection');
 681   } else {
 682     $self->js->hide('#shipto_selection');
 683   }
 684
 685   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 686
 687   $self->js
 688     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 689     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 690     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 691     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 692     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 693     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 694     ->val(        '#order_currency_id',      $self->order->currency_id)
 695     ->val(        '#order_payment_id',       $self->order->payment_id)
 696     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 697     ->val(        '#order_intnotes',         $self->order->intnotes)
 698     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 699     ->focus(      '#order_' . $self->cv . '_id')
 700     ->run('kivi.Order.update_exchangerate');
 701
 702   $self->js_redisplay_amounts_and_taxes;
 703   $self->js_redisplay_cvpartnumbers;
 704   $self->js->render();
 705 }
 706
 707 # open the dialog for customer/vendor details
 708 sub action_show_customer_vendor_details_dialog {
 709   my ($self) = @_;
 710
 711   my $is_customer = 'customer' eq $::form->{vc};
 712   my $cv;
 713   if ($is_customer) {
 714     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 715   } else {
 716     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 717   }
 718
 719   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 720   $details{discount_as_percent} = $cv->discount_as_percent;
 721   $details{creditlimt}          = $cv->creditlimit_as_number;
 722   $details{business}            = $cv->business->description      if $cv->business;
 723   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 724   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 725   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 726   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 727
 728   foreach my $entry (@{ $cv->shipto }) {
 729     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 730   }
 731   foreach my $entry (@{ $cv->contacts }) {
 732     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 733   }
 734
 735   $_[0]->render('common/show_vc_details', { layout => 0 },
 736                 is_customer => $is_customer,
 737                 %details);
 738
 739 }
 740
 741 # called if a unit in an existing item row is changed
 742 sub action_unit_changed {
 743   my ($self) = @_;
 744
 745   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 746   my $item = $self->order->items_sorted->[$idx];
 747
 748   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 749   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 750
 751   $self->recalc();
 752
 753   $self->js
 754     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 755   $self->js_redisplay_line_values;
 756   $self->js_redisplay_amounts_and_taxes;
 757   $self->js->render();
 758 }
 759
 760 # add an item row for a new item entered in the input row
 761 sub action_add_item {
 762   my ($self) = @_;
 763
 764   my $form_attr = $::form->{add_item};
 765
 766   return unless $form_attr->{parts_id};
 767
 768   my $item = new_item($self->order, $form_attr);
 769
 770   $self->order->add_items($item);
 771
 772   $self->recalc();
 773
 774   $self->get_item_cvpartnumber($item);
 775
 776   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 777   my $row_as_html = $self->p->render('order/tabs/_row',
 778                                      ITEM => $item,
 779                                      ID   => $item_id,
 780                                      SELF => $self,
 781   );
 782
 783   if ($::form->{insert_before_item_id}) {
 784     $self->js
 785       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 786   } else {
 787     $self->js
 788       ->append('#row_table_id', $row_as_html);
 789   }
 790
 791   if ( $item->part->is_assortment ) {
 792     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 793     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 794       my $attr = { parts_id => $assortment_item->parts_id,
 795                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 796                    unit     => $assortment_item->unit,
 797                    description => $assortment_item->part->description,
 798                  };
 799       my $item = new_item($self->order, $attr);
 800
 801       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 802       $item->discount(1) unless $assortment_item->charge;
 803
 804       $self->order->add_items( $item );
 805       $self->recalc();
 806       $self->get_item_cvpartnumber($item);
 807       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 808       my $row_as_html = $self->p->render('order/tabs/_row',
 809                                          ITEM => $item,
 810                                          ID   => $item_id,
 811                                          SELF => $self,
 812       );
 813       if ($::form->{insert_before_item_id}) {
 814         $self->js
 815           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 816       } else {
 817         $self->js
 818           ->append('#row_table_id', $row_as_html);
 819       }
 820     };
 821   };
 822
 823   $self->js
 824     ->val('.add_item_input', '')
 825     ->run('kivi.Order.init_row_handlers')
 826     ->run('kivi.Order.renumber_positions')
 827     ->focus('#add_item_parts_id_name');
 828
 829   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 830
 831   $self->js_redisplay_amounts_and_taxes;
 832   $self->js->render();
 833 }
 834
 835 # open the dialog for entering multiple items at once
 836 sub action_show_multi_items_dialog {
 837   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 838                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 839 }
 840
 841 # update the filter results in the multi item dialog
 842 sub action_multi_items_update_result {
 843   my $max_count = 100;
 844
 845   $::form->{multi_items}->{filter}->{obsolete} = 0;
 846
 847   my $count = $_[0]->multi_items_models->count;
 848
 849   if ($count == 0) {
 850     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 851     $_[0]->render($text, { layout => 0 });
 852   } elsif ($count > $max_count) {
 853     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 854     $_[0]->render($text, { layout => 0 });
 855   } else {
 856     my $multi_items = $_[0]->multi_items_models->get;
 857     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 858                   multi_items => $multi_items);
 859   }
 860 }
 861
 862 # add item rows for multiple items at once
 863 sub action_add_multi_items {
 864   my ($self) = @_;
 865
 866   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 867   return $self->js->render() unless scalar @form_attr;
 868
 869   my @items;
 870   foreach my $attr (@form_attr) {
 871     my $item = new_item($self->order, $attr);
 872     push @items, $item;
 873     if ( $item->part->is_assortment ) {
 874       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 875         my $attr = { parts_id => $assortment_item->parts_id,
 876                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 877                      unit     => $assortment_item->unit,
 878                      description => $assortment_item->part->description,
 879                    };
 880         my $item = new_item($self->order, $attr);
 881
 882         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 883         $item->discount(1) unless $assortment_item->charge;
 884         push @items, $item;
 885       }
 886     }
 887   }
 888   $self->order->add_items(@items);
 889
 890   $self->recalc();
 891
 892   foreach my $item (@items) {
 893     $self->get_item_cvpartnumber($item);
 894     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 895     my $row_as_html = $self->p->render('order/tabs/_row',
 896                                        ITEM => $item,
 897                                        ID   => $item_id,
 898                                        SELF => $self,
 899     );
 900
 901     if ($::form->{insert_before_item_id}) {
 902       $self->js
 903         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 904     } else {
 905       $self->js
 906         ->append('#row_table_id', $row_as_html);
 907     }
 908   }
 909
 910   $self->js
 911     ->run('kivi.Order.close_multi_items_dialog')
 912     ->run('kivi.Order.init_row_handlers')
 913     ->run('kivi.Order.renumber_positions')
 914     ->focus('#add_item_parts_id_name');
 915
 916   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 917
 918   $self->js_redisplay_amounts_and_taxes;
 919   $self->js->render();
 920 }
 921
 922 # recalculate all linetotals, amounts and taxes and redisplay them
 923 sub action_recalc_amounts_and_taxes {
 924   my ($self) = @_;
 925
 926   $self->recalc();
 927
 928   $self->js_redisplay_line_values;
 929   $self->js_redisplay_amounts_and_taxes;
 930   $self->js->render();
 931 }
 932
 933 sub action_update_exchangerate {
 934   my ($self) = @_;
 935
 936   my $data = {
 937     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 938     currency_name => $self->order->currency->name,
 939     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 940   };
 941
 942   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 943 }
 944
 945 # redisplay item rows if they are sorted by an attribute
 946 sub action_reorder_items {
 947   my ($self) = @_;
 948
 949   my %sort_keys = (
 950     partnumber   => sub { $_[0]->part->partnumber },
 951     description  => sub { $_[0]->description },
 952     qty          => sub { $_[0]->qty },
 953     sellprice    => sub { $_[0]->sellprice },
 954     discount     => sub { $_[0]->discount },
 955     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 956   );
 957
 958   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 959
 960   my $method = $sort_keys{$::form->{order_by}};
 961   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 962   if ($::form->{sort_dir}) {
 963     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 964       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 965     } else {
 966       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 967     }
 968   } else {
 969     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 970       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 971     } else {
 972       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 973     }
 974   }
 975   $self->js
 976     ->run('kivi.Order.redisplay_items', \@to_sort)
 977     ->render;
 978 }
 979
 980 # show the popup to choose a price/discount source
 981 sub action_price_popup {
 982   my ($self) = @_;
 983
 984   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 985   my $item = $self->order->items_sorted->[$idx];
 986
 987   $self->render_price_dialog($item);
 988 }
 989
 990 # get the longdescription for an item if the dialog to enter/change the
 991 # longdescription was opened and the longdescription is empty
 992 #
 993 # If this item is new, get the longdescription from Part.
 994 # Otherwise get it from OrderItem.
 995 sub action_get_item_longdescription {
 996   my $longdescription;
 997
 998   if ($::form->{item_id}) {
 999     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
1000   } elsif ($::form->{parts_id}) {
1001     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
1002   }
1003   $_[0]->render(\ $longdescription, { type => 'text' });
1004 }
1005
1006 # load the second row for one or more items
1007 #
1008 # This action gets the html code for all items second rows by rendering a template for
1009 # the second row and sets the html code via client js.
1010 sub action_load_second_rows {
1011   my ($self) = @_;
1012
1013   $self->recalc() if $self->order->is_sales; # for margin calculation
1014
1015   foreach my $item_id (@{ $::form->{item_ids} }) {
1016     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1017     my $item = $self->order->items_sorted->[$idx];
1018
1019     $self->js_load_second_row($item, $item_id, 0);
1020   }
1021
1022   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1023
1024   $self->js->render();
1025 }
1026
1027 # update description, notes and sellprice from master data
1028 sub action_update_row_from_master_data {
1029   my ($self) = @_;
1030
1031   foreach my $item_id (@{ $::form->{item_ids} }) {
1032     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1033     my $item = $self->order->items_sorted->[$idx];
1034
1035     $item->description($item->part->description);
1036     $item->longdescription($item->part->notes);
1037
1038     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1039
1040     my $price_src;
1041     if ($item->part->is_assortment) {
1042     # add assortment items with price 0, as the components carry the price
1043       $price_src = $price_source->price_from_source("");
1044       $price_src->price(0);
1045     } else {
1046       $price_src = $price_source->best_price
1047                  ? $price_source->best_price
1048                  : $price_source->price_from_source("");
1049       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1050       $price_src->price(0) if !$price_source->best_price;
1051     }
1052
1053
1054     $item->sellprice($price_src->price);
1055     $item->active_price_source($price_src);
1056
1057     $self->js
1058       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1059       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1060       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1061       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1062
1063     if ($self->search_cvpartnumber) {
1064       $self->get_item_cvpartnumber($item);
1065       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1066     }
1067   }
1068
1069   $self->recalc();
1070   $self->js_redisplay_line_values;
1071   $self->js_redisplay_amounts_and_taxes;
1072
1073   $self->js->render();
1074 }
1075
1076 sub js_load_second_row {
1077   my ($self, $item, $item_id, $do_parse) = @_;
1078
1079   if ($do_parse) {
1080     # Parse values from form (they are formated while rendering (template)).
1081     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1082     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1083     foreach my $var (@{ $item->cvars_by_config }) {
1084       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1085     }
1086     $item->parse_custom_variable_values;
1087   }
1088
1089   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1090
1091   $self->js
1092     ->html('#second_row_' . $item_id, $row_as_html)
1093     ->data('#second_row_' . $item_id, 'loaded', 1);
1094 }
1095
1096 sub js_redisplay_line_values {
1097   my ($self) = @_;
1098
1099   my $is_sales = $self->order->is_sales;
1100
1101   # sales orders with margins
1102   my @data;
1103   if ($is_sales) {
1104     @data = map {
1105       [
1106        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1107        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1108        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1109       ]} @{ $self->order->items_sorted };
1110   } else {
1111     @data = map {
1112       [
1113        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1114       ]} @{ $self->order->items_sorted };
1115   }
1116
1117   $self->js
1118     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1119 }
1120
1121 sub js_redisplay_amounts_and_taxes {
1122   my ($self) = @_;
1123
1124   if (scalar @{ $self->{taxes} }) {
1125     $self->js->show('#taxincluded_row_id');
1126   } else {
1127     $self->js->hide('#taxincluded_row_id');
1128   }
1129
1130   if ($self->order->taxincluded) {
1131     $self->js->hide('#subtotal_row_id');
1132   } else {
1133     $self->js->show('#subtotal_row_id');
1134   }
1135
1136   if ($self->order->is_sales) {
1137     my $is_neg = $self->order->marge_total < 0;
1138     $self->js
1139       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1140       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1141       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1142       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1143       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1144       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1145       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1146       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1147   }
1148
1149   $self->js
1150     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1151     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1152     ->remove('.tax_row')
1153     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1154 }
1155
1156 sub js_redisplay_cvpartnumbers {
1157   my ($self) = @_;
1158
1159   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1160
1161   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1162
1163   $self->js
1164     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1165 }
1166
1167 sub js_reset_order_and_item_ids_after_save {
1168   my ($self) = @_;
1169
1170   $self->js
1171     ->val('#id', $self->order->id)
1172     ->val('#converted_from_oe_id', '')
1173     ->val('#order_' . $self->nr_key(), $self->order->number);
1174
1175   my $idx = 0;
1176   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1177     next if !$self->order->items_sorted->[$idx]->id;
1178     next if $form_item_id !~ m{^new};
1179     $self->js
1180       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1181       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1182       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1183   } continue {
1184     $idx++;
1185   }
1186   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1187 }
1188
1189 #
1190 # helpers
1191 #
1192
1193 sub init_valid_types {
1194   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1195 }
1196
1197 sub init_type {
1198   my ($self) = @_;
1199
1200   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1201     die "Not a valid type for order";
1202   }
1203
1204   $self->type($::form->{type});
1205 }
1206
1207 sub init_cv {
1208   my ($self) = @_;
1209
1210   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1211          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1212          : die "Not a valid type for order";
1213
1214   return $cv;
1215 }
1216
1217 sub init_search_cvpartnumber {
1218   my ($self) = @_;
1219
1220   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1221   my $search_cvpartnumber;
1222   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1223   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1224
1225   return $search_cvpartnumber;
1226 }
1227
1228 sub init_show_update_button {
1229   my ($self) = @_;
1230
1231   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1232 }
1233
1234 sub init_p {
1235   SL::Presenter->get;
1236 }
1237
1238 sub init_order {
1239   $_[0]->make_order;
1240 }
1241
1242 # model used to filter/display the parts in the multi-items dialog
1243 sub init_multi_items_models {
1244   SL::Controller::Helper::GetModels->new(
1245     controller     => $_[0],
1246     model          => 'Part',
1247     with_objects   => [ qw(unit_obj) ],
1248     disable_plugin => 'paginated',
1249     source         => $::form->{multi_items},
1250     sorted         => {
1251       _default    => {
1252         by  => 'partnumber',
1253         dir => 1,
1254       },
1255       partnumber  => t8('Partnumber'),
1256       description => t8('Description')}
1257   );
1258 }
1259
1260 sub init_all_price_factors {
1261   SL::DB::Manager::PriceFactor->get_all;
1262 }
1263
1264 sub check_auth {
1265   my ($self) = @_;
1266
1267   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1268
1269   my $right   = $right_for->{ $self->type };
1270   $right    ||= 'DOES_NOT_EXIST';
1271
1272   $::auth->assert($right);
1273 }
1274
1275 # build the selection box for contacts
1276 #
1277 # Needed, if customer/vendor changed.
1278 sub build_contact_select {
1279   my ($self) = @_;
1280
1281   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1282     value_key  => 'cp_id',
1283     title_key  => 'full_name_dep',
1284     default    => $self->order->cp_id,
1285     with_empty => 1,
1286     style      => 'width: 300px',
1287   );
1288 }
1289
1290 # build the selection box for shiptos
1291 #
1292 # Needed, if customer/vendor changed.
1293 sub build_shipto_select {
1294   my ($self) = @_;
1295
1296   select_tag('order.shipto_id',
1297              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1298              value_key  => 'shipto_id',
1299              title_key  => 'displayable_id',
1300              default    => $self->order->shipto_id,
1301              with_empty => 0,
1302              style      => 'width: 300px',
1303   );
1304 }
1305
1306 # build the inputs for the cusom shipto dialog
1307 #
1308 # Needed, if customer/vendor changed.
1309 sub build_shipto_inputs {
1310   my ($self) = @_;
1311
1312   my $content = $self->p->render('common/_ship_to_dialog',
1313                                  vc_obj      => $self->order->customervendor,
1314                                  cs_obj      => $self->order->custom_shipto,
1315                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1316                                  id_selector => '#order_shipto_id');
1317
1318   div_tag($content, id => 'shipto_inputs');
1319 }
1320
1321 # render the info line for business
1322 #
1323 # Needed, if customer/vendor changed.
1324 sub build_business_info_row
1325 {
1326   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1327 }
1328
1329 # build the rows for displaying taxes
1330 #
1331 # Called if amounts where recalculated and redisplayed.
1332 sub build_tax_rows {
1333   my ($self) = @_;
1334
1335   my $rows_as_html;
1336   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1337     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1338   }
1339   return $rows_as_html;
1340 }
1341
1342
1343 sub render_price_dialog {
1344   my ($self, $record_item) = @_;
1345
1346   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1347
1348   $self->js
1349     ->run(
1350       'kivi.io.price_chooser_dialog',
1351       t8('Available Prices'),
1352       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1353     )
1354     ->reinit_widgets;
1355
1356 #   if (@errors) {
1357 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1358 #     $self->js->show('#dialog_flash_error');
1359 #   }
1360
1361   $self->js->render;
1362 }
1363
1364 sub load_order {
1365   my ($self) = @_;
1366
1367   return if !$::form->{id};
1368
1369   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1370
1371   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1372   # You need a custom shipto object to call cvars_by_config to get the cvars.
1373   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1374
1375   return $self->order;
1376 }
1377
1378 # load or create a new order object
1379 #
1380 # And assign changes from the form to this object.
1381 # If the order is loaded from db, check if items are deleted in the form,
1382 # remove them form the object and collect them for removing from db on saving.
1383 # Then create/update items from form (via make_item) and add them.
1384 sub make_order {
1385   my ($self) = @_;
1386
1387   # add_items adds items to an order with no items for saving, but they cannot
1388   # be retrieved via items until the order is saved. Adding empty items to new
1389   # order here solves this problem.
1390   my $order;
1391   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1392   $order ||= SL::DB::Order->new(orderitems  => [],
1393                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1394                                 currency_id => $::instance_conf->get_currency_id(),);
1395
1396   my $cv_id_method = $self->cv . '_id';
1397   if (!$::form->{id} && $::form->{$cv_id_method}) {
1398     $order->$cv_id_method($::form->{$cv_id_method});
1399     setup_order_from_cv($order);
1400   }
1401
1402   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1403   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1404
1405   $order->assign_attributes(%{$::form->{order}});
1406
1407   $self->setup_custom_shipto_from_form($order, $::form);
1408
1409   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1410     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1411     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1412   }
1413
1414   # remove deleted items
1415   $self->item_ids_to_delete([]);
1416   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1417     my $item = $order->orderitems->[$idx];
1418     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1419       splice @{$order->orderitems}, $idx, 1;
1420       push @{$self->item_ids_to_delete}, $item->id;
1421     }
1422   }
1423
1424   my @items;
1425   my $pos = 1;
1426   foreach my $form_attr (@{$form_orderitems}) {
1427     my $item = make_item($order, $form_attr);
1428     $item->position($pos);
1429     push @items, $item;
1430     $pos++;
1431   }
1432   $order->add_items(grep {!$_->id} @items);
1433
1434   return $order;
1435 }
1436
1437 # create or update items from form
1438 #
1439 # Make item objects from form values. For items already existing read from db.
1440 # Create a new item else. And assign attributes.
1441 sub make_item {
1442   my ($record, $attr) = @_;
1443
1444   my $item;
1445   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1446
1447   my $is_new = !$item;
1448
1449   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1450   # they cannot be retrieved via custom_variables until the order/orderitem is
1451   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1452   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1453
1454   $item->assign_attributes(%$attr);
1455   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1456   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1457   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1458
1459   return $item;
1460 }
1461
1462 # create a new item
1463 #
1464 # This is used to add one item
1465 sub new_item {
1466   my ($record, $attr) = @_;
1467
1468   my $item = SL::DB::OrderItem->new;
1469
1470   # Remove attributes where the user left or set the inputs empty.
1471   # So these attributes will be undefined and we can distinguish them
1472   # from zero later on.
1473   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1474     delete $attr->{$_} if $attr->{$_} eq '';
1475   }
1476
1477   $item->assign_attributes(%$attr);
1478
1479   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1480   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1481
1482   $item->unit($part->unit) if !$item->unit;
1483
1484   my $price_src;
1485   if ( $part->is_assortment ) {
1486     # add assortment items with price 0, as the components carry the price
1487     $price_src = $price_source->price_from_source("");
1488     $price_src->price(0);
1489   } elsif (defined $item->sellprice) {
1490     $price_src = $price_source->price_from_source("");
1491     $price_src->price($item->sellprice);
1492   } else {
1493     $price_src = $price_source->best_price
1494                ? $price_source->best_price
1495                : $price_source->price_from_source("");
1496     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1497     $price_src->price(0) if !$price_source->best_price;
1498   }
1499
1500   my $discount_src;
1501   if (defined $item->discount) {
1502     $discount_src = $price_source->discount_from_source("");
1503     $discount_src->discount($item->discount);
1504   } else {
1505     $discount_src = $price_source->best_discount
1506                   ? $price_source->best_discount
1507                   : $price_source->discount_from_source("");
1508     $discount_src->discount(0) if !$price_source->best_discount;
1509   }
1510
1511   my %new_attr;
1512   $new_attr{part}                   = $part;
1513   $new_attr{description}            = $part->description     if ! $item->description;
1514   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1515   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1516   $new_attr{sellprice}              = $price_src->price;
1517   $new_attr{discount}               = $discount_src->discount;
1518   $new_attr{active_price_source}    = $price_src;
1519   $new_attr{active_discount_source} = $discount_src;
1520   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1521   $new_attr{project_id}             = $record->globalproject_id;
1522   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1523
1524   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1525   # they cannot be retrieved via custom_variables until the order/orderitem is
1526   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1527   $new_attr{custom_variables} = [];
1528
1529   $item->assign_attributes(%new_attr);
1530
1531   return $item;
1532 }
1533
1534 sub setup_order_from_cv {
1535   my ($order) = @_;
1536
1537   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1538
1539   $order->intnotes($order->customervendor->notes);
1540
1541   if ($order->is_sales) {
1542     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1543     $order->taxincluded(defined($order->customer->taxincluded_checked)
1544                         ? $order->customer->taxincluded_checked
1545                         : $::myconfig{taxincluded_checked});
1546   }
1547
1548 }
1549
1550 # setup custom shipto from form
1551 #
1552 # The dialog returns form variables starting with 'shipto' and cvars starting
1553 # with 'shiptocvar_'.
1554 # Mark it to be deleted if a shipto from master data is selected
1555 # (i.e. order has a shipto).
1556 # Else, update or create a new custom shipto. If the fields are empty, it
1557 # will not be saved on save.
1558 sub setup_custom_shipto_from_form {
1559   my ($self, $order, $form) = @_;
1560
1561   if ($order->shipto) {
1562     $self->is_custom_shipto_to_delete(1);
1563   } else {
1564     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1565
1566     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1567     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1568
1569     $custom_shipto->assign_attributes(%$shipto_attrs);
1570     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1571   }
1572 }
1573
1574 # recalculate prices and taxes
1575 #
1576 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1577 sub recalc {
1578   my ($self) = @_;
1579
1580   my %pat = $self->order->calculate_prices_and_taxes();
1581
1582   $self->{taxes} = [];
1583   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1584     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1585
1586     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1587                                 netamount => $netamount,
1588                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1589   }
1590   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1591 }
1592
1593 # get data for saving, printing, ..., that is not changed in the form
1594 #
1595 # Only cvars for now.
1596 sub get_unalterable_data {
1597   my ($self) = @_;
1598
1599   foreach my $item (@{ $self->order->items }) {
1600     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1601     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1602     foreach my $var (@{ $item->cvars_by_config }) {
1603       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1604     }
1605     $item->parse_custom_variable_values;
1606   }
1607 }
1608
1609 # delete the order
1610 #
1611 # And remove related files in the spool directory
1612 sub delete {
1613   my ($self) = @_;
1614
1615   my $errors = [];
1616   my $db     = $self->order->db;
1617
1618   $db->with_transaction(
1619     sub {
1620       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1621       $self->order->delete;
1622       my $spool = $::lx_office_conf{paths}->{spool};
1623       unlink map { "$spool/$_" } @spoolfiles if $spool;
1624
1625       1;
1626   }) || push(@{$errors}, $db->error);
1627
1628   return $errors;
1629 }
1630
1631 # save the order
1632 #
1633 # And delete items that are deleted in the form.
1634 sub save {
1635   my ($self) = @_;
1636
1637   my $errors = [];
1638   my $db     = $self->order->db;
1639
1640   $db->with_transaction(sub {
1641     # delete custom shipto if it is to be deleted or if it is empty
1642     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1643       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1644       $self->order->custom_shipto(undef);
1645     }
1646
1647     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1648     $self->order->save(cascade => 1);
1649
1650     # link records
1651     if ($::form->{converted_from_oe_id}) {
1652       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1653       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1654         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1655         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1656         $src->link_to_record($self->order);
1657       }
1658       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1659         my $idx = 0;
1660         foreach (@{ $self->order->items_sorted }) {
1661           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1662           next if !$from_id;
1663           SL::DB::RecordLink->new(from_table => 'orderitems',
1664                                   from_id    => $from_id,
1665                                   to_table   => 'orderitems',
1666                                   to_id      => $_->id
1667           )->save;
1668           $idx++;
1669         }
1670       }
1671     }
1672     1;
1673   }) || push(@{$errors}, $db->error);
1674
1675   return $errors;
1676 }
1677
1678 sub workflow_sales_or_purchase_order {
1679   my ($self) = @_;
1680
1681   # always save
1682   my $errors = $self->save();
1683
1684   if (scalar @{ $errors }) {
1685     $self->js->flash('error', $_) foreach @{ $errors };
1686     return $self->js->render();
1687   }
1688
1689   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1690                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1691                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1692                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1693                        : '';
1694
1695   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1696   $self->{converted_from_oe_id} = delete $::form->{id};
1697
1698   # set item ids to new fake id, to identify them as new items
1699   foreach my $item (@{$self->order->items_sorted}) {
1700     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1701   }
1702
1703   # change form type
1704   $::form->{type} = $destination_type;
1705   $self->type($self->init_type);
1706   $self->cv  ($self->init_cv);
1707   $self->check_auth;
1708
1709   $self->recalc();
1710   $self->get_unalterable_data();
1711   $self->pre_render();
1712
1713   # trigger rendering values for second row/longdescription as hidden,
1714   # because they are loaded only on demand. So we need to keep the values
1715   # from the source.
1716   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1717   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1718
1719   $self->render(
1720     'order/form',
1721     title => $self->get_title_for('edit'),
1722     %{$self->{template_args}}
1723   );
1724 }
1725
1726
1727 sub pre_render {
1728   my ($self) = @_;
1729
1730   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1731   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1732   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1733   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1734                                                                                               deleted => 0 ] ],
1735                                                                            sort_by => 'name');
1736   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1737                                                                                               deleted => 0 ] ],
1738                                                                            sort_by => 'name');
1739   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1740                                                                                                         obsolete => 0 ] ]);
1741   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1742   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1743   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1744   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1745   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1746
1747   my $print_form = Form->new('');
1748   $print_form->{type}        = $self->type;
1749   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1750   $print_form->{languages}   = SL::DB::Manager::Language->get_all_sorted;
1751   $print_form->{language_id} = $self->order->language_id;
1752   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1753     form => $print_form,
1754     options => {dialog_name_prefix => 'print_options.',
1755                 show_headers       => 1,
1756                 no_queue           => 1,
1757                 no_postscript      => 1,
1758                 no_opendocument    => 0,
1759                 no_html            => 1},
1760   );
1761
1762   foreach my $item (@{$self->order->orderitems}) {
1763     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1764     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1765     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1766   }
1767
1768   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1769     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1770     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1771   }
1772
1773   if ($self->order->number && $::instance_conf->get_webdav) {
1774     my $webdav = SL::Webdav->new(
1775       type     => $self->type,
1776       number   => $self->order->number,
1777     );
1778     my @all_objects = $webdav->get_all_objects;
1779     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1780                                                     type => t8('File'),
1781                                                     link => File::Spec->catfile($_->full_filedescriptor),
1782                                                 } } @all_objects;
1783   }
1784
1785   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1786
1787   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1788                                                          edit_periodic_invoices_config calculate_qty kivi.Validator);
1789   $self->setup_edit_action_bar;
1790 }
1791
1792 sub setup_edit_action_bar {
1793   my ($self, %params) = @_;
1794
1795   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1796                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1797                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1798
1799   for my $bar ($::request->layout->get('actionbar')) {
1800     $bar->add(
1801       combobox => [
1802         action => [
1803           t8('Save'),
1804           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1805                                                     $::instance_conf->get_order_warn_no_deliverydate,
1806                                                                                                       ],
1807           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1808         ],
1809         action => [
1810           t8('Save as new'),
1811           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1812           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1813           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1814         ],
1815       ], # end of combobox "Save"
1816
1817       combobox => [
1818         action => [
1819           t8('Workflow'),
1820         ],
1821         action => [
1822           t8('Save and Sales Order'),
1823           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1824           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1825           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1826         ],
1827         action => [
1828           t8('Save and Purchase Order'),
1829           submit   => [ '#order_form', { action => "Order/purchase_order" } ],
1830           only_if  => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1831           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1832         ],
1833         action => [
1834           t8('Save and Delivery Order'),
1835           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1836                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1837                                                                                                                         ],
1838           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1839           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1840         ],
1841         action => [
1842           t8('Save and Invoice'),
1843           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1844           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1845         ],
1846         action => [
1847           t8('Save and AP Transaction'),
1848           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1849           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1850         ],
1851
1852       ], # end of combobox "Workflow"
1853
1854       combobox => [
1855         action => [
1856           t8('Export'),
1857         ],
1858         action => [
1859           t8('Save and print'),
1860           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1861         ],
1862         action => [
1863           t8('Save and E-mail'),
1864           call => [ 'kivi.Order.email', $::instance_conf->get_order_warn_duplicate_parts ],
1865         ],
1866         action => [
1867           t8('Download attachments of all parts'),
1868           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1869           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1870           only_if  => $::instance_conf->get_doc_storage,
1871         ],
1872       ], # end of combobox "Export"
1873
1874       action => [
1875         t8('Delete'),
1876         call     => [ 'kivi.Order.delete_order' ],
1877         confirm  => $::locale->text('Do you really want to delete this object?'),
1878         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1879         only_if  => $deletion_allowed,
1880       ],
1881     );
1882   }
1883 }
1884
1885 sub generate_pdf {
1886   my ($order, $pdf_ref, $params) = @_;
1887
1888   my @errors = ();
1889
1890   my $print_form = Form->new('');
1891   $print_form->{type}        = $order->type;
1892   $print_form->{formname}    = $params->{formname} || $order->type;
1893   $print_form->{format}      = $params->{format}   || 'pdf';
1894   $print_form->{media}       = $params->{media}    || 'file';
1895   $print_form->{groupitems}  = $params->{groupitems};
1896   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1897
1898   $order->language($params->{language});
1899   $order->flatten_to_form($print_form, format_amounts => 1);
1900
1901   my $template_ext;
1902   my $template_type;
1903   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1904     $template_ext  = 'odt';
1905     $template_type = 'OpenDocument';
1906   }
1907
1908   # search for the template
1909   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1910     name        => $print_form->{formname},
1911     extension   => $template_ext,
1912     email       => $print_form->{media} eq 'email',
1913     language    => $params->{language},
1914     printer_id  => $print_form->{printer_id},  # todo
1915   );
1916
1917   if (!defined $template_file) {
1918     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1919   }
1920
1921   return @errors if scalar @errors;
1922
1923   $print_form->throw_on_error(sub {
1924     eval {
1925       $print_form->prepare_for_printing;
1926
1927       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1928         format        => $print_form->{format},
1929         template_type => $template_type,
1930         template      => $template_file,
1931         variables     => $print_form,
1932         variable_content_types => {
1933           longdescription => 'html',
1934           partnotes       => 'html',
1935           notes           => 'html',
1936         },
1937       );
1938       1;
1939     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1940   });
1941
1942   return @errors;
1943 }
1944
1945 sub get_files_for_email_dialog {
1946   my ($self) = @_;
1947
1948   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1949
1950   return %files if !$::instance_conf->get_doc_storage;
1951
1952   if ($self->order->id) {
1953     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1954     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1955     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1956   }
1957
1958   my @parts =
1959     uniq_by { $_->{id} }
1960     map {
1961       +{ id         => $_->part->id,
1962          partnumber => $_->part->partnumber }
1963     } @{$self->order->items_sorted};
1964
1965   foreach my $part (@parts) {
1966     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1967     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1968   }
1969
1970   foreach my $key (keys %files) {
1971     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1972   }
1973
1974   return %files;
1975 }
1976
1977 sub make_periodic_invoices_config_from_yaml {
1978   my ($yaml_config) = @_;
1979
1980   return if !$yaml_config;
1981   my $attr = SL::YAML::Load($yaml_config);
1982   return if 'HASH' ne ref $attr;
1983   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1984 }
1985
1986
1987 sub get_periodic_invoices_status {
1988   my ($self, $config) = @_;
1989
1990   return                      if $self->type ne sales_order_type();
1991   return t8('not configured') if !$config;
1992
1993   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1994              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1995              :                                                     die "Cannot get status of periodic invoices config";
1996
1997   return $active ? t8('active') : t8('inactive');
1998 }
1999
2000 sub get_title_for {
2001   my ($self, $action) = @_;
2002
2003   return '' if none { lc($action)} qw(add edit);
2004
2005   # for locales:
2006   # $::locale->text("Add Sales Order");
2007   # $::locale->text("Add Purchase Order");
2008   # $::locale->text("Add Quotation");
2009   # $::locale->text("Add Request for Quotation");
2010   # $::locale->text("Edit Sales Order");
2011   # $::locale->text("Edit Purchase Order");
2012   # $::locale->text("Edit Quotation");
2013   # $::locale->text("Edit Request for Quotation");
2014
2015   $action = ucfirst(lc($action));
2016   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2017        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2018        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2019        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2020        : '';
2021 }
2022
2023 sub get_item_cvpartnumber {
2024   my ($self, $item) = @_;
2025
2026   return if !$self->search_cvpartnumber;
2027   return if !$self->order->customervendor;
2028
2029   if ($self->cv eq 'vendor') {
2030     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2031     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2032   } elsif ($self->cv eq 'customer') {
2033     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2034     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2035   }
2036 }
2037
2038 sub sales_order_type {
2039   'sales_order';
2040 }
2041
2042 sub purchase_order_type {
2043   'purchase_order';
2044 }
2045
2046 sub sales_quotation_type {
2047   'sales_quotation';
2048 }
2049
2050 sub request_quotation_type {
2051   'request_quotation';
2052 }
2053
2054 sub nr_key {
2055   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2056        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2057        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2058        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2059        : '';
2060 }
2061
2062 1;
2063
2064 __END__
2065
2066 =encoding utf-8
2067
2068 =head1 NAME
2069
2070 SL::Controller::Order - controller for orders
2071
2072 =head1 SYNOPSIS
2073
2074 This is a new form to enter orders, completely rewritten with the use
2075 of controller and java script techniques.
2076
2077 The aim is to provide the user a better experience and a faster workflow. Also
2078 the code should be more readable, more reliable and better to maintain.
2079
2080 =head2 Key Features
2081
2082 =over 4
2083
2084 =item *
2085
2086 One input row, so that input happens every time at the same place.
2087
2088 =item *
2089
2090 Use of pickers where possible.
2091
2092 =item *
2093
2094 Possibility to enter more than one item at once.
2095
2096 =item *
2097
2098 Item list in a scrollable area, so that the workflow buttons stay at
2099 the bottom.
2100
2101 =item *
2102
2103 Reordering item rows with drag and drop is possible. Sorting item rows is
2104 possible (by partnumber, description, qty, sellprice and discount for now).
2105
2106 =item *
2107
2108 No C<update> is necessary. All entries and calculations are managed
2109 with ajax-calls and the page only reloads on C<save>.
2110
2111 =item *
2112
2113 User can see changes immediately, because of the use of java script
2114 and ajax.
2115
2116 =back
2117
2118 =head1 CODE
2119
2120 =head2 Layout
2121
2122 =over 4
2123
2124 =item * C<SL/Controller/Order.pm>
2125
2126 the controller
2127
2128 =item * C<template/webpages/order/form.html>
2129
2130 main form
2131
2132 =item * C<template/webpages/order/tabs/basic_data.html>
2133
2134 Main tab for basic_data.
2135
2136 This is the only tab here for now. "linked records" and "webdav" tabs are
2137 reused from generic code.
2138
2139 =over 4
2140
2141 =item * C<template/webpages/order/tabs/_business_info_row.html>
2142
2143 For displaying information on business type
2144
2145 =item * C<template/webpages/order/tabs/_item_input.html>
2146
2147 The input line for items
2148
2149 =item * C<template/webpages/order/tabs/_row.html>
2150
2151 One row for already entered items
2152
2153 =item * C<template/webpages/order/tabs/_tax_row.html>
2154
2155 Displaying tax information
2156
2157 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
2158
2159 Dialog for entering more than one item at once
2160
2161 =item * C<template/webpages/order/tabs/_multi_items_result.html>
2162
2163 Results for the filter in the multi items dialog
2164
2165 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2166
2167 Dialog for selecting price and discount sources
2168
2169 =back
2170
2171 =item * C<js/kivi.Order.js>
2172
2173 java script functions
2174
2175 =back
2176
2177 =head1 TODO
2178
2179 =over 4
2180
2181 =item * testing
2182
2183 =item * credit limit
2184
2185 =item * more workflows (quotation, rfq)
2186
2187 =item * price sources: little symbols showing better price / better discount
2188
2189 =item * select units in input row?
2190
2191 =item * check for direct delivery (workflow sales order -> purchase order)
2192
2193 =item * language / part translations
2194
2195 =item * access rights
2196
2197 =item * display weights
2198
2199 =item * history
2200
2201 =item * mtime check
2202
2203 =item * optional client/user behaviour
2204
2205 (transactions has to be set - department has to be set -
2206  force project if enabled in client config - transport cost reminder)
2207
2208 =back
2209
2210 =head1 KNOWN BUGS AND CAVEATS
2211
2212 =over 4
2213
2214 =item *
2215
2216 Customer discount is not displayed as a valid discount in price source popup
2217 (this might be a bug in price sources)
2218
2219 (I cannot reproduce this (Bernd))
2220
2221 =item *
2222
2223 No indication that <shift>-up/down expands/collapses second row.
2224
2225 =item *
2226
2227 Inline creation of parts is not currently supported
2228
2229 =item *
2230
2231 Table header is not sticky in the scrolling area.
2232
2233 =item *
2234
2235 Sorting does not include C<position>, neither does reordering.
2236
2237 This behavior was implemented intentionally. But we can discuss, which behavior
2238 should be implemented.
2239
2240 =item *
2241
2242 C<show_multi_items_dialog> does not use the currently inserted string for
2243 filtering.
2244
2245 =back
2246
2247 =head1 To discuss / Nice to have
2248
2249 =over 4
2250
2251 =item *
2252
2253 How to expand/collapse second row. Now it can be done clicking the icon or
2254 <shift>-up/down.
2255
2256 =item *
2257
2258 Possibility to change longdescription in input row?
2259
2260 =item *
2261
2262 Possibility to select PriceSources in input row?
2263
2264 =item *
2265
2266 This controller uses a (changed) copy of the template for the PriceSource
2267 dialog. Maybe there could be used one code source.
2268
2269 =item *
2270
2271 Rounding-differences between this controller (PriceTaxCalculator) and the old
2272 form. This is not only a problem here, but also in all parts using the PTC.
2273 There exists a ticket and a patch. This patch should be testet.
2274
2275 =item *
2276
2277 An indicator, if the actual inputs are saved (like in an
2278 editor or on text processing application).
2279
2280 =item *
2281
2282 A warning when leaving the page without saveing unchanged inputs.
2283
2284
2285 =back
2286
2287 =head1 AUTHOR
2288
2289 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2290
2291 =cut