SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24
  25 use SL::Helper::CreatePDF qw(:all);
  26 use SL::Helper::PrintOptions;
  27 use SL::Helper::ShippedQty;
  28 use SL::Helper::UserPreferences::PositionsScrollbar;
  29 use SL::Helper::UserPreferences::UpdatePositions;
  30
  31 use SL::Controller::Helper::GetModels;
  32
  33 use List::Util qw(first sum0);
  34 use List::UtilsBy qw(sort_by uniq_by);
  35 use List::MoreUtils qw(any none pairwise first_index);
  36 use English qw(-no_match_vars);
  37 use File::Spec;
  38 use Cwd;
  39 use Sort::Naturally;
  40
  41 use Rose::Object::MakeMethods::Generic
  42 (
  43  scalar => [ qw(item_ids_to_delete) ],
  44  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors search_cvpartnumber show_update_button) ],
  45 );
  46
  47
  48 # safety
  49 __PACKAGE__->run_before('check_auth');
  50
  51 __PACKAGE__->run_before('recalc',
  52                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  53                                      print send_email) ]);
  54
  55 __PACKAGE__->run_before('get_unalterable_data',
  56                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  57                                      print send_email) ]);
  58
  59 #
  60 # actions
  61 #
  62
  63 # add a new order
  64 sub action_add {
  65   my ($self) = @_;
  66
  67   $self->order->transdate(DateTime->now_local());
  68   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  69                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  70   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  71
  72
  73   $self->pre_render();
  74   $self->render(
  75     'order/form',
  76     title => $self->get_title_for('add'),
  77     %{$self->{template_args}}
  78   );
  79 }
  80
  81 # edit an existing order
  82 sub action_edit {
  83   my ($self) = @_;
  84
  85   if ($::form->{id}) {
  86     $self->load_order;
  87
  88   } else {
  89     # this is to edit an order from an unsaved order object
  90
  91     # set item ids to new fake id, to identify them as new items
  92     foreach my $item (@{$self->order->items_sorted}) {
  93       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  94     }
  95     # trigger rendering values for second row/longdescription as hidden,
  96     # because they are loaded only on demand. So we need to keep the values
  97     # from the source.
  98     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
  99     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 100   }
 101
 102   $self->recalc();
 103   $self->pre_render();
 104   $self->render(
 105     'order/form',
 106     title => $self->get_title_for('edit'),
 107     %{$self->{template_args}}
 108   );
 109 }
 110
 111 # edit a collective order (consisting of one or more existing orders)
 112 sub action_edit_collective {
 113   my ($self) = @_;
 114
 115   # collect order ids
 116   my @multi_ids = map {
 117     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 118   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 119
 120   # fall back to add if no ids are given
 121   if (scalar @multi_ids == 0) {
 122     $self->action_add();
 123     return;
 124   }
 125
 126   # fall back to save as new if only one id is given
 127   if (scalar @multi_ids == 1) {
 128     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 129     $self->action_save_as_new();
 130     return;
 131   }
 132
 133   # make new order from given orders
 134   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 135   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 136   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 137
 138   $self->action_edit();
 139 }
 140
 141 # delete the order
 142 sub action_delete {
 143   my ($self) = @_;
 144
 145   my $errors = $self->delete();
 146
 147   if (scalar @{ $errors }) {
 148     $self->js->flash('error', $_) foreach @{ $errors };
 149     return $self->js->render();
 150   }
 151
 152   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 153            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 154            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 155            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 156            : '';
 157   flash_later('info', $text);
 158
 159   my @redirect_params = (
 160     action => 'add',
 161     type   => $self->type,
 162   );
 163
 164   $self->redirect_to(@redirect_params);
 165 }
 166
 167 # save the order
 168 sub action_save {
 169   my ($self) = @_;
 170
 171   my $errors = $self->save();
 172
 173   if (scalar @{ $errors }) {
 174     $self->js->flash('error', $_) foreach @{ $errors };
 175     return $self->js->render();
 176   }
 177
 178   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 179            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 180            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 181            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 182            : '';
 183   flash_later('info', $text);
 184
 185   my @redirect_params = (
 186     action => 'edit',
 187     type   => $self->type,
 188     id     => $self->order->id,
 189   );
 190
 191   $self->redirect_to(@redirect_params);
 192 }
 193
 194 # save the order as new document an open it for edit
 195 sub action_save_as_new {
 196   my ($self) = @_;
 197
 198   my $order = $self->order;
 199
 200   if (!$order->id) {
 201     $self->js->flash('error', t8('This object has not been saved yet.'));
 202     return $self->js->render();
 203   }
 204
 205   # load order from db to check if values changed
 206   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 207
 208   my %new_attrs;
 209   # Lets assign a new number if the user hasn't changed the previous one.
 210   # If it has been changed manually then use it as-is.
 211   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 212                         ? ''
 213                         : trim($order->number);
 214
 215   # Clear transdate unless changed
 216   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 217                         ? DateTime->today_local
 218                         : $order->transdate;
 219
 220   # Set new reqdate unless changed
 221   if ($order->reqdate == $saved_order->reqdate) {
 222     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 223                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 224     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 225   } else {
 226     $new_attrs{reqdate} = $order->reqdate;
 227   }
 228
 229   # Update employee
 230   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 231
 232   # Create new record from current one
 233   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 234
 235   # no linked records on save as new
 236   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 237
 238   # save
 239   $self->action_save();
 240 }
 241
 242 # print the order
 243 #
 244 # This is called if "print" is pressed in the print dialog.
 245 # If PDF creation was requested and succeeded, the pdf is offered for download
 246 # via send_file (which uses ajax in this case).
 247 sub action_print {
 248   my ($self) = @_;
 249
 250   my $errors = $self->save();
 251
 252   if (scalar @{ $errors }) {
 253     $self->js->flash('error', $_) foreach @{ $errors };
 254     return $self->js->render();
 255   }
 256
 257   $self->js_reset_order_and_item_ids_after_save;
 258
 259   my $format      = $::form->{print_options}->{format};
 260   my $media       = $::form->{print_options}->{media};
 261   my $formname    = $::form->{print_options}->{formname};
 262   my $copies      = $::form->{print_options}->{copies};
 263   my $groupitems  = $::form->{print_options}->{groupitems};
 264
 265   # only pdf and opendocument by now
 266   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 267     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 268   }
 269
 270   # only screen or printer by now
 271   if (none { $media eq $_ } qw(screen printer)) {
 272     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 273   }
 274
 275   my $language;
 276   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 277
 278   # create a form for generate_attachment_filename
 279   my $form   = Form->new;
 280   $form->{$self->nr_key()}  = $self->order->number;
 281   $form->{type}             = $self->type;
 282   $form->{format}           = $format;
 283   $form->{formname}         = $formname;
 284   $form->{language}         = '_' . $language->template_code if $language;
 285   my $pdf_filename          = $form->generate_attachment_filename();
 286
 287   my $pdf;
 288   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 289                                                    formname   => $formname,
 290                                                    language   => $language,
 291                                                    groupitems => $groupitems });
 292   if (scalar @errors) {
 293     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 294   }
 295
 296   if ($media eq 'screen') {
 297     # screen/download
 298     $self->js->flash('info', t8('The PDF has been created'));
 299     $self->send_file(
 300       \$pdf,
 301       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 302       name         => $pdf_filename,
 303       js_no_render => 1,
 304     );
 305
 306   } elsif ($media eq 'printer') {
 307     # printer
 308     my $printer_id = $::form->{print_options}->{printer_id};
 309     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 310       copies  => $copies,
 311       content => $pdf,
 312     );
 313
 314     $self->js->flash('info', t8('The PDF has been printed'));
 315   }
 316
 317   # copy file to webdav folder
 318   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 319     my $webdav = SL::Webdav->new(
 320       type     => $self->type,
 321       number   => $self->order->number,
 322     );
 323     my $webdav_file = SL::Webdav::File->new(
 324       webdav   => $webdav,
 325       filename => $pdf_filename,
 326     );
 327     eval {
 328       $webdav_file->store(data => \$pdf);
 329       1;
 330     } or do {
 331       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 332     }
 333   }
 334   if ($self->order->number && $::instance_conf->get_doc_storage) {
 335     eval {
 336       SL::File->save(object_id     => $self->order->id,
 337                      object_type   => $self->type,
 338                      mime_type     => 'application/pdf',
 339                      source        => 'created',
 340                      file_type     => 'document',
 341                      file_name     => $pdf_filename,
 342                      file_contents => $pdf);
 343       1;
 344     } or do {
 345       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 346     }
 347   }
 348   $self->js->render;
 349 }
 350
 351 # open the email dialog
 352 sub action_show_email_dialog {
 353   my ($self) = @_;
 354
 355   my $cv_method = $self->cv;
 356
 357   if (!$self->order->$cv_method) {
 358     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 359                     ->render($self);
 360   }
 361
 362   my $email_form;
 363   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 364   $email_form->{to} ||= $self->order->$cv_method->email;
 365   $email_form->{cc}   = $self->order->$cv_method->cc;
 366   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 367   # Todo: get addresses from shipto, if any
 368
 369   my $form = Form->new;
 370   $form->{$self->nr_key()}  = $self->order->number;
 371   $form->{formname}         = $self->type;
 372   $form->{type}             = $self->type;
 373   $form->{language}         = 'de';
 374   $form->{format}           = 'pdf';
 375
 376   $email_form->{subject}             = $form->generate_email_subject();
 377   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 378   $email_form->{message}             = $form->generate_email_body();
 379   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 380
 381   my %files = $self->get_files_for_email_dialog();
 382   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 383                                   email_form  => $email_form,
 384                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 385                                   FILES       => \%files,
 386                                   is_customer => $self->cv eq 'customer',
 387   );
 388
 389   $self->js
 390       ->run('kivi.Order.show_email_dialog', $dialog_html)
 391       ->reinit_widgets
 392       ->render($self);
 393 }
 394
 395 # send email
 396 #
 397 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 398 sub action_send_email {
 399   my ($self) = @_;
 400
 401   my $errors = $self->save();
 402
 403   if (scalar @{ $errors }) {
 404     $self->js->run('kivi.Order.close_email_dialog');
 405     $self->js->flash('error', $_) foreach @{ $errors };
 406     return $self->js->render();
 407   }
 408
 409   $self->js_reset_order_and_item_ids_after_save;
 410
 411   my $email_form  = delete $::form->{email_form};
 412   my %field_names = (to => 'email');
 413
 414   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 415
 416   # for Form::cleanup which may be called in Form::send_email
 417   $::form->{cwd}    = getcwd();
 418   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 419
 420   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 421   $::form->{media}  = 'email';
 422
 423   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 424     my $language;
 425     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 426
 427     my $pdf;
 428     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 429                                                     format     => $::form->{print_options}->{format},
 430                                                     formname   => $::form->{print_options}->{formname},
 431                                                     language   => $language,
 432                                                     groupitems => $::form->{print_options}->{groupitems}});
 433     if (scalar @errors) {
 434       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 435     }
 436
 437     my $sfile = SL::SessionFile::Random->new(mode => "w");
 438     $sfile->fh->print($pdf);
 439     $sfile->fh->close;
 440
 441     $::form->{tmpfile} = $sfile->file_name;
 442     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 443   }
 444
 445   $::form->send_email(\%::myconfig, 'pdf');
 446
 447   # internal notes
 448   my $intnotes = $self->order->intnotes;
 449   $intnotes   .= "\n\n" if $self->order->intnotes;
 450   $intnotes   .= t8('[email]')                                                                                        . "\n";
 451   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 452   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 453   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 454   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 455   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 456   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 457
 458   $self->order->update_attributes(intnotes => $intnotes);
 459
 460   $self->js
 461       ->val('#order_intnotes', $intnotes)
 462       ->run('kivi.Order.close_email_dialog')
 463       ->flash('info', t8('The email has been sent.'))
 464       ->render($self);
 465 }
 466
 467 # open the periodic invoices config dialog
 468 #
 469 # If there are values in the form (i.e. dialog was opened before),
 470 # then use this values. Create new ones, else.
 471 sub action_show_periodic_invoices_config_dialog {
 472   my ($self) = @_;
 473
 474   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 475   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 476   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 477                                                    order_value_periodicity => 'p', # = same as periodicity
 478                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 479                                                    extend_automatically_by => 12,
 480                                                    active                  => 1,
 481                                                    email_subject           => GenericTranslations->get(
 482                                                                                 language_id      => $::form->{language_id},
 483                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 484                                                    email_body              => GenericTranslations->get(
 485                                                                                 language_id      => $::form->{language_id},
 486                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 487   );
 488   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 489   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 490
 491   $::form->get_lists(printers => "ALL_PRINTERS",
 492                      charts   => { key       => 'ALL_CHARTS',
 493                                    transdate => 'current_date' });
 494
 495   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 496
 497   if ($::form->{customer_id}) {
 498     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 499     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 500   }
 501
 502   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 503                 popup_dialog             => 1,
 504                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 505                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 506                 config                   => $config,
 507                 %$::form);
 508 }
 509
 510 # assign the values of the periodic invoices config dialog
 511 # as yaml in the hidden tag and set the status.
 512 sub action_assign_periodic_invoices_config {
 513   my ($self) = @_;
 514
 515   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 516
 517   my $config = { active                     => $::form->{active}       ? 1 : 0,
 518                  terminated                 => $::form->{terminated}   ? 1 : 0,
 519                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 520                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 521                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 522                  start_date_as_date         => $::form->{start_date_as_date},
 523                  end_date_as_date           => $::form->{end_date_as_date},
 524                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 525                  print                      => $::form->{print}      ? 1                         : 0,
 526                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 527                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 528                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 529                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 530                  send_email                 => $::form->{send_email} ? 1 : 0,
 531                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 532                  email_recipient_address    => $::form->{email_recipient_address},
 533                  email_sender               => $::form->{email_sender},
 534                  email_subject              => $::form->{email_subject},
 535                  email_body                 => $::form->{email_body},
 536                };
 537
 538   my $periodic_invoices_config = SL::YAML::Dump($config);
 539
 540   my $status = $self->get_periodic_invoices_status($config);
 541
 542   $self->js
 543     ->remove('#order_periodic_invoices_config')
 544     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 545     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 546     ->html('#periodic_invoices_status', $status)
 547     ->flash('info', t8('The periodic invoices config has been assigned.'))
 548     ->render($self);
 549 }
 550
 551 sub action_get_has_active_periodic_invoices {
 552   my ($self) = @_;
 553
 554   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 555   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 556
 557   my $has_active_periodic_invoices =
 558        $self->type eq sales_order_type()
 559     && $config
 560     && $config->active
 561     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 562     && $config->get_previous_billed_period_start_date;
 563
 564   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 565 }
 566
 567 # save the order and redirect to the frontend subroutine for a new
 568 # delivery order
 569 sub action_save_and_delivery_order {
 570   my ($self) = @_;
 571
 572   my $errors = $self->save();
 573
 574   if (scalar @{ $errors }) {
 575     $self->js->flash('error', $_) foreach @{ $errors };
 576     return $self->js->render();
 577   }
 578
 579   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 580            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 581            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 582            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 583            : '';
 584   flash_later('info', $text);
 585
 586   my @redirect_params = (
 587     controller => 'oe.pl',
 588     action     => 'oe_delivery_order_from_order',
 589     id         => $self->order->id,
 590   );
 591
 592   $self->redirect_to(@redirect_params);
 593 }
 594
 595 # save the order and redirect to the frontend subroutine for a new
 596 # invoice
 597 sub action_save_and_invoice {
 598   my ($self) = @_;
 599
 600   my $errors = $self->save();
 601
 602   if (scalar @{ $errors }) {
 603     $self->js->flash('error', $_) foreach @{ $errors };
 604     return $self->js->render();
 605   }
 606
 607   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 608            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 609            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 610            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 611            : '';
 612   flash_later('info', $text);
 613
 614   my @redirect_params = (
 615     controller => 'oe.pl',
 616     action     => 'oe_invoice_from_order',
 617     id         => $self->order->id,
 618   );
 619
 620   $self->redirect_to(@redirect_params);
 621 }
 622
 623 # workflow from sales quotation to sales order
 624 sub action_sales_order {
 625   $_[0]->workflow_sales_or_purchase_order();
 626 }
 627
 628 # workflow from rfq to purchase order
 629 sub action_purchase_order {
 630   $_[0]->workflow_sales_or_purchase_order();
 631 }
 632
 633 # workflow from purchase order to ap transaction
 634 sub action_save_and_ap_transaction {
 635   my ($self) = @_;
 636
 637   my $errors = $self->save();
 638
 639   if (scalar @{ $errors }) {
 640     $self->js->flash('error', $_) foreach @{ $errors };
 641     return $self->js->render();
 642   }
 643
 644   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 645            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 646            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 647            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 648            : '';
 649   flash_later('info', $text);
 650
 651   my @redirect_params = (
 652     controller => 'ap.pl',
 653     action     => 'add_from_purchase_order',
 654     id         => $self->order->id,
 655   );
 656
 657   $self->redirect_to(@redirect_params);
 658 }
 659
 660 # set form elements in respect to a changed customer or vendor
 661 #
 662 # This action is called on an change of the customer/vendor picker.
 663 sub action_customer_vendor_changed {
 664   my ($self) = @_;
 665
 666   setup_order_from_cv($self->order);
 667   $self->recalc();
 668
 669   my $cv_method = $self->cv;
 670
 671   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 672     $self->js->show('#cp_row');
 673   } else {
 674     $self->js->hide('#cp_row');
 675   }
 676
 677   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 678     $self->js->show('#shipto_row');
 679   } else {
 680     $self->js->hide('#shipto_row');
 681   }
 682
 683   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 684
 685   $self->js
 686     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 687     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 688     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 689     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 690     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 691     ->val(        '#order_payment_id',       $self->order->payment_id)
 692     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 693     ->val(        '#order_intnotes',         $self->order->intnotes)
 694     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 695     ->focus(      '#order_' . $self->cv . '_id');
 696
 697   $self->js_redisplay_amounts_and_taxes;
 698   $self->js_redisplay_cvpartnumbers;
 699   $self->js->render();
 700 }
 701
 702 # open the dialog for customer/vendor details
 703 sub action_show_customer_vendor_details_dialog {
 704   my ($self) = @_;
 705
 706   my $is_customer = 'customer' eq $::form->{vc};
 707   my $cv;
 708   if ($is_customer) {
 709     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 710   } else {
 711     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 712   }
 713
 714   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 715   $details{discount_as_percent} = $cv->discount_as_percent;
 716   $details{creditlimt}          = $cv->creditlimit_as_number;
 717   $details{business}            = $cv->business->description      if $cv->business;
 718   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 719   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 720   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 721   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 722
 723   foreach my $entry (@{ $cv->shipto }) {
 724     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 725   }
 726   foreach my $entry (@{ $cv->contacts }) {
 727     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 728   }
 729
 730   $_[0]->render('common/show_vc_details', { layout => 0 },
 731                 is_customer => $is_customer,
 732                 %details);
 733
 734 }
 735
 736 # called if a unit in an existing item row is changed
 737 sub action_unit_changed {
 738   my ($self) = @_;
 739
 740   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 741   my $item = $self->order->items_sorted->[$idx];
 742
 743   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 744   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 745
 746   $self->recalc();
 747
 748   $self->js
 749     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 750   $self->js_redisplay_line_values;
 751   $self->js_redisplay_amounts_and_taxes;
 752   $self->js->render();
 753 }
 754
 755 # add an item row for a new item entered in the input row
 756 sub action_add_item {
 757   my ($self) = @_;
 758
 759   my $form_attr = $::form->{add_item};
 760
 761   return unless $form_attr->{parts_id};
 762
 763   my $item = new_item($self->order, $form_attr);
 764
 765   $self->order->add_items($item);
 766
 767   $self->recalc();
 768
 769   $self->get_item_cvpartnumber($item);
 770
 771   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 772   my $row_as_html = $self->p->render('order/tabs/_row',
 773                                      ITEM => $item,
 774                                      ID   => $item_id,
 775                                      SELF => $self,
 776   );
 777
 778   if ($::form->{insert_before_item_id}) {
 779     $self->js
 780       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 781   } else {
 782     $self->js
 783       ->append('#row_table_id', $row_as_html);
 784   }
 785
 786   if ( $item->part->is_assortment ) {
 787     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 788     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 789       my $attr = { parts_id => $assortment_item->parts_id,
 790                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 791                    unit     => $assortment_item->unit,
 792                    description => $assortment_item->part->description,
 793                  };
 794       my $item = new_item($self->order, $attr);
 795
 796       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 797       $item->discount(1) unless $assortment_item->charge;
 798
 799       $self->order->add_items( $item );
 800       $self->recalc();
 801       $self->get_item_cvpartnumber($item);
 802       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 803       my $row_as_html = $self->p->render('order/tabs/_row',
 804                                          ITEM => $item,
 805                                          ID   => $item_id,
 806                                          SELF => $self,
 807       );
 808       if ($::form->{insert_before_item_id}) {
 809         $self->js
 810           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 811       } else {
 812         $self->js
 813           ->append('#row_table_id', $row_as_html);
 814       }
 815     };
 816   };
 817
 818   $self->js
 819     ->val('.add_item_input', '')
 820     ->run('kivi.Order.init_row_handlers')
 821     ->run('kivi.Order.renumber_positions')
 822     ->focus('#add_item_parts_id_name');
 823
 824   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 825
 826   $self->js_redisplay_amounts_and_taxes;
 827   $self->js->render();
 828 }
 829
 830 # open the dialog for entering multiple items at once
 831 sub action_show_multi_items_dialog {
 832   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 833                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 834 }
 835
 836 # update the filter results in the multi item dialog
 837 sub action_multi_items_update_result {
 838   my $max_count = 100;
 839
 840   $::form->{multi_items}->{filter}->{obsolete} = 0;
 841
 842   my $count = $_[0]->multi_items_models->count;
 843
 844   if ($count == 0) {
 845     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 846     $_[0]->render($text, { layout => 0 });
 847   } elsif ($count > $max_count) {
 848     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 849     $_[0]->render($text, { layout => 0 });
 850   } else {
 851     my $multi_items = $_[0]->multi_items_models->get;
 852     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 853                   multi_items => $multi_items);
 854   }
 855 }
 856
 857 # add item rows for multiple items at once
 858 sub action_add_multi_items {
 859   my ($self) = @_;
 860
 861   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 862   return $self->js->render() unless scalar @form_attr;
 863
 864   my @items;
 865   foreach my $attr (@form_attr) {
 866     my $item = new_item($self->order, $attr);
 867     push @items, $item;
 868     if ( $item->part->is_assortment ) {
 869       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 870         my $attr = { parts_id => $assortment_item->parts_id,
 871                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 872                      unit     => $assortment_item->unit,
 873                      description => $assortment_item->part->description,
 874                    };
 875         my $item = new_item($self->order, $attr);
 876
 877         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 878         $item->discount(1) unless $assortment_item->charge;
 879         push @items, $item;
 880       }
 881     }
 882   }
 883   $self->order->add_items(@items);
 884
 885   $self->recalc();
 886
 887   foreach my $item (@items) {
 888     $self->get_item_cvpartnumber($item);
 889     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 890     my $row_as_html = $self->p->render('order/tabs/_row',
 891                                        ITEM => $item,
 892                                        ID   => $item_id,
 893                                        SELF => $self,
 894     );
 895
 896     if ($::form->{insert_before_item_id}) {
 897       $self->js
 898         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 899     } else {
 900       $self->js
 901         ->append('#row_table_id', $row_as_html);
 902     }
 903   }
 904
 905   $self->js
 906     ->run('kivi.Order.close_multi_items_dialog')
 907     ->run('kivi.Order.init_row_handlers')
 908     ->run('kivi.Order.renumber_positions')
 909     ->focus('#add_item_parts_id_name');
 910
 911   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 912
 913   $self->js_redisplay_amounts_and_taxes;
 914   $self->js->render();
 915 }
 916
 917 # recalculate all linetotals, amounts and taxes and redisplay them
 918 sub action_recalc_amounts_and_taxes {
 919   my ($self) = @_;
 920
 921   $self->recalc();
 922
 923   $self->js_redisplay_line_values;
 924   $self->js_redisplay_amounts_and_taxes;
 925   $self->js->render();
 926 }
 927
 928 # redisplay item rows if they are sorted by an attribute
 929 sub action_reorder_items {
 930   my ($self) = @_;
 931
 932   my %sort_keys = (
 933     partnumber   => sub { $_[0]->part->partnumber },
 934     description  => sub { $_[0]->description },
 935     qty          => sub { $_[0]->qty },
 936     sellprice    => sub { $_[0]->sellprice },
 937     discount     => sub { $_[0]->discount },
 938     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 939   );
 940
 941   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 942
 943   my $method = $sort_keys{$::form->{order_by}};
 944   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 945   if ($::form->{sort_dir}) {
 946     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 947       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 948     } else {
 949       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 950     }
 951   } else {
 952     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 953       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 954     } else {
 955       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 956     }
 957   }
 958   $self->js
 959     ->run('kivi.Order.redisplay_items', \@to_sort)
 960     ->render;
 961 }
 962
 963 # show the popup to choose a price/discount source
 964 sub action_price_popup {
 965   my ($self) = @_;
 966
 967   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 968   my $item = $self->order->items_sorted->[$idx];
 969
 970   $self->render_price_dialog($item);
 971 }
 972
 973 # get the longdescription for an item if the dialog to enter/change the
 974 # longdescription was opened and the longdescription is empty
 975 #
 976 # If this item is new, get the longdescription from Part.
 977 # Otherwise get it from OrderItem.
 978 sub action_get_item_longdescription {
 979   my $longdescription;
 980
 981   if ($::form->{item_id}) {
 982     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 983   } elsif ($::form->{parts_id}) {
 984     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 985   }
 986   $_[0]->render(\ $longdescription, { type => 'text' });
 987 }
 988
 989 # load the second row for one or more items
 990 #
 991 # This action gets the html code for all items second rows by rendering a template for
 992 # the second row and sets the html code via client js.
 993 sub action_load_second_rows {
 994   my ($self) = @_;
 995
 996   $self->recalc() if $self->order->is_sales; # for margin calculation
 997
 998   foreach my $item_id (@{ $::form->{item_ids} }) {
 999     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1000     my $item = $self->order->items_sorted->[$idx];
1001
1002     $self->js_load_second_row($item, $item_id, 0);
1003   }
1004
1005   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1006
1007   $self->js->render();
1008 }
1009
1010 # update description, notes and sellprice from master data
1011 sub action_update_row_from_master_data {
1012   my ($self) = @_;
1013
1014   foreach my $item_id (@{ $::form->{item_ids} }) {
1015     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1016     my $item = $self->order->items_sorted->[$idx];
1017
1018     $item->description($item->part->description);
1019     $item->longdescription($item->part->notes);
1020
1021     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1022
1023     my $price_src;
1024     if ($item->part->is_assortment) {
1025     # add assortment items with price 0, as the components carry the price
1026       $price_src = $price_source->price_from_source("");
1027       $price_src->price(0);
1028     } else {
1029       $price_src = $price_source->best_price
1030                  ? $price_source->best_price
1031                  : $price_source->price_from_source("");
1032       $price_src->price(0) if !$price_source->best_price;
1033     }
1034
1035     $item->sellprice($price_src->price);
1036     $item->active_price_source($price_src);
1037
1038     $self->js
1039       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1040       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1041       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1042       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1043
1044     if ($self->search_cvpartnumber) {
1045       $self->get_item_cvpartnumber($item);
1046       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1047     }
1048   }
1049
1050   $self->recalc();
1051   $self->js_redisplay_line_values;
1052   $self->js_redisplay_amounts_and_taxes;
1053
1054   $self->js->render();
1055 }
1056
1057 sub js_load_second_row {
1058   my ($self, $item, $item_id, $do_parse) = @_;
1059
1060   if ($do_parse) {
1061     # Parse values from form (they are formated while rendering (template)).
1062     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1063     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1064     foreach my $var (@{ $item->cvars_by_config }) {
1065       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1066     }
1067     $item->parse_custom_variable_values;
1068   }
1069
1070   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1071
1072   $self->js
1073     ->html('#second_row_' . $item_id, $row_as_html)
1074     ->data('#second_row_' . $item_id, 'loaded', 1);
1075 }
1076
1077 sub js_redisplay_line_values {
1078   my ($self) = @_;
1079
1080   my $is_sales = $self->order->is_sales;
1081
1082   # sales orders with margins
1083   my @data;
1084   if ($is_sales) {
1085     @data = map {
1086       [
1087        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1088        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1089        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1090       ]} @{ $self->order->items_sorted };
1091   } else {
1092     @data = map {
1093       [
1094        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1095       ]} @{ $self->order->items_sorted };
1096   }
1097
1098   $self->js
1099     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1100 }
1101
1102 sub js_redisplay_amounts_and_taxes {
1103   my ($self) = @_;
1104
1105   if (scalar @{ $self->{taxes} }) {
1106     $self->js->show('#taxincluded_row_id');
1107   } else {
1108     $self->js->hide('#taxincluded_row_id');
1109   }
1110
1111   if ($self->order->taxincluded) {
1112     $self->js->hide('#subtotal_row_id');
1113   } else {
1114     $self->js->show('#subtotal_row_id');
1115   }
1116
1117   if ($self->order->is_sales) {
1118     my $is_neg = $self->order->marge_total < 0;
1119     $self->js
1120       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1121       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1122       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1123       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1124       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1125       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1126       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1127       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1128   }
1129
1130   $self->js
1131     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1132     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1133     ->remove('.tax_row')
1134     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1135 }
1136
1137 sub js_redisplay_cvpartnumbers {
1138   my ($self) = @_;
1139
1140   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1141
1142   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1143
1144   $self->js
1145     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1146 }
1147
1148 sub js_reset_order_and_item_ids_after_save {
1149   my ($self) = @_;
1150
1151   $self->js
1152     ->val('#id', $self->order->id)
1153     ->val('#converted_from_oe_id', '')
1154     ->val('#order_' . $self->nr_key(), $self->order->number);
1155
1156   my $idx = 0;
1157   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1158     next if !$self->order->items_sorted->[$idx]->id;
1159     next if $form_item_id !~ m{^new};
1160     $self->js
1161       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1162       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1163       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1164   } continue {
1165     $idx++;
1166   }
1167   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1168 }
1169
1170 #
1171 # helpers
1172 #
1173
1174 sub init_valid_types {
1175   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1176 }
1177
1178 sub init_type {
1179   my ($self) = @_;
1180
1181   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1182     die "Not a valid type for order";
1183   }
1184
1185   $self->type($::form->{type});
1186 }
1187
1188 sub init_cv {
1189   my ($self) = @_;
1190
1191   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1192          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1193          : die "Not a valid type for order";
1194
1195   return $cv;
1196 }
1197
1198 sub init_search_cvpartnumber {
1199   my ($self) = @_;
1200
1201   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1202   my $search_cvpartnumber;
1203   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1204   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1205
1206   return $search_cvpartnumber;
1207 }
1208
1209 sub init_show_update_button {
1210   my ($self) = @_;
1211
1212   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1213 }
1214
1215 sub init_p {
1216   SL::Presenter->get;
1217 }
1218
1219 sub init_order {
1220   $_[0]->make_order;
1221 }
1222
1223 # model used to filter/display the parts in the multi-items dialog
1224 sub init_multi_items_models {
1225   SL::Controller::Helper::GetModels->new(
1226     controller     => $_[0],
1227     model          => 'Part',
1228     with_objects   => [ qw(unit_obj) ],
1229     disable_plugin => 'paginated',
1230     source         => $::form->{multi_items},
1231     sorted         => {
1232       _default    => {
1233         by  => 'partnumber',
1234         dir => 1,
1235       },
1236       partnumber  => t8('Partnumber'),
1237       description => t8('Description')}
1238   );
1239 }
1240
1241 sub init_all_price_factors {
1242   SL::DB::Manager::PriceFactor->get_all;
1243 }
1244
1245 sub check_auth {
1246   my ($self) = @_;
1247
1248   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1249
1250   my $right   = $right_for->{ $self->type };
1251   $right    ||= 'DOES_NOT_EXIST';
1252
1253   $::auth->assert($right);
1254 }
1255
1256 # build the selection box for contacts
1257 #
1258 # Needed, if customer/vendor changed.
1259 sub build_contact_select {
1260   my ($self) = @_;
1261
1262   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1263     value_key  => 'cp_id',
1264     title_key  => 'full_name_dep',
1265     default    => $self->order->cp_id,
1266     with_empty => 1,
1267     style      => 'width: 300px',
1268   );
1269 }
1270
1271 # build the selection box for shiptos
1272 #
1273 # Needed, if customer/vendor changed.
1274 sub build_shipto_select {
1275   my ($self) = @_;
1276
1277   select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
1278     value_key  => 'shipto_id',
1279     title_key  => 'displayable_id',
1280     default    => $self->order->shipto_id,
1281     with_empty => 1,
1282     style      => 'width: 300px',
1283   );
1284 }
1285
1286 # render the info line for business
1287 #
1288 # Needed, if customer/vendor changed.
1289 sub build_business_info_row
1290 {
1291   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1292 }
1293
1294 # build the rows for displaying taxes
1295 #
1296 # Called if amounts where recalculated and redisplayed.
1297 sub build_tax_rows {
1298   my ($self) = @_;
1299
1300   my $rows_as_html;
1301   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1302     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1303   }
1304   return $rows_as_html;
1305 }
1306
1307
1308 sub render_price_dialog {
1309   my ($self, $record_item) = @_;
1310
1311   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1312
1313   $self->js
1314     ->run(
1315       'kivi.io.price_chooser_dialog',
1316       t8('Available Prices'),
1317       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1318     )
1319     ->reinit_widgets;
1320
1321 #   if (@errors) {
1322 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1323 #     $self->js->show('#dialog_flash_error');
1324 #   }
1325
1326   $self->js->render;
1327 }
1328
1329 sub load_order {
1330   my ($self) = @_;
1331
1332   return if !$::form->{id};
1333
1334   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1335 }
1336
1337 # load or create a new order object
1338 #
1339 # And assign changes from the form to this object.
1340 # If the order is loaded from db, check if items are deleted in the form,
1341 # remove them form the object and collect them for removing from db on saving.
1342 # Then create/update items from form (via make_item) and add them.
1343 sub make_order {
1344   my ($self) = @_;
1345
1346   # add_items adds items to an order with no items for saving, but they cannot
1347   # be retrieved via items until the order is saved. Adding empty items to new
1348   # order here solves this problem.
1349   my $order;
1350   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1351   $order ||= SL::DB::Order->new(orderitems => [],
1352                                 quotation  => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())));
1353
1354   my $cv_id_method = $self->cv . '_id';
1355   if (!$::form->{id} && $::form->{$cv_id_method}) {
1356     $order->$cv_id_method($::form->{$cv_id_method});
1357     setup_order_from_cv($order);
1358   }
1359
1360   my $form_orderitems               = delete $::form->{order}->{orderitems};
1361   my $form_periodic_invoices_config = delete $::form->{order}->{periodic_invoices_config};
1362
1363   $order->assign_attributes(%{$::form->{order}});
1364
1365   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1366     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1367     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1368   }
1369
1370   # remove deleted items
1371   $self->item_ids_to_delete([]);
1372   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1373     my $item = $order->orderitems->[$idx];
1374     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1375       splice @{$order->orderitems}, $idx, 1;
1376       push @{$self->item_ids_to_delete}, $item->id;
1377     }
1378   }
1379
1380   my @items;
1381   my $pos = 1;
1382   foreach my $form_attr (@{$form_orderitems}) {
1383     my $item = make_item($order, $form_attr);
1384     $item->position($pos);
1385     push @items, $item;
1386     $pos++;
1387   }
1388   $order->add_items(grep {!$_->id} @items);
1389
1390   return $order;
1391 }
1392
1393 # create or update items from form
1394 #
1395 # Make item objects from form values. For items already existing read from db.
1396 # Create a new item else. And assign attributes.
1397 sub make_item {
1398   my ($record, $attr) = @_;
1399
1400   my $item;
1401   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1402
1403   my $is_new = !$item;
1404
1405   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1406   # they cannot be retrieved via custom_variables until the order/orderitem is
1407   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1408   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1409
1410   $item->assign_attributes(%$attr);
1411   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1412   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1413   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1414
1415   return $item;
1416 }
1417
1418 # create a new item
1419 #
1420 # This is used to add one item
1421 sub new_item {
1422   my ($record, $attr) = @_;
1423
1424   my $item = SL::DB::OrderItem->new;
1425
1426   # Remove attributes where the user left or set the inputs empty.
1427   # So these attributes will be undefined and we can distinguish them
1428   # from zero later on.
1429   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1430     delete $attr->{$_} if $attr->{$_} eq '';
1431   }
1432
1433   $item->assign_attributes(%$attr);
1434
1435   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1436   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1437
1438   $item->unit($part->unit) if !$item->unit;
1439
1440   my $price_src;
1441   if ( $part->is_assortment ) {
1442     # add assortment items with price 0, as the components carry the price
1443     $price_src = $price_source->price_from_source("");
1444     $price_src->price(0);
1445   } elsif (defined $item->sellprice) {
1446     $price_src = $price_source->price_from_source("");
1447     $price_src->price($item->sellprice);
1448   } else {
1449     $price_src = $price_source->best_price
1450            ? $price_source->best_price
1451            : $price_source->price_from_source("");
1452     $price_src->price(0) if !$price_source->best_price;
1453   }
1454
1455   my $discount_src;
1456   if (defined $item->discount) {
1457     $discount_src = $price_source->discount_from_source("");
1458     $discount_src->discount($item->discount);
1459   } else {
1460     $discount_src = $price_source->best_discount
1461                   ? $price_source->best_discount
1462                   : $price_source->discount_from_source("");
1463     $discount_src->discount(0) if !$price_source->best_discount;
1464   }
1465
1466   my %new_attr;
1467   $new_attr{part}                   = $part;
1468   $new_attr{description}            = $part->description     if ! $item->description;
1469   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1470   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1471   $new_attr{sellprice}              = $price_src->price;
1472   $new_attr{discount}               = $discount_src->discount;
1473   $new_attr{active_price_source}    = $price_src;
1474   $new_attr{active_discount_source} = $discount_src;
1475   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1476   $new_attr{project_id}             = $record->globalproject_id;
1477   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1478
1479   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1480   # they cannot be retrieved via custom_variables until the order/orderitem is
1481   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1482   $new_attr{custom_variables} = [];
1483
1484   $item->assign_attributes(%new_attr);
1485
1486   return $item;
1487 }
1488
1489 sub setup_order_from_cv {
1490   my ($order) = @_;
1491
1492   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id));
1493
1494   $order->intnotes($order->customervendor->notes);
1495
1496   if ($order->is_sales) {
1497     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1498     $order->taxincluded(defined($order->customer->taxincluded_checked)
1499                         ? $order->customer->taxincluded_checked
1500                         : $::myconfig{taxincluded_checked});
1501   }
1502
1503 }
1504
1505 # recalculate prices and taxes
1506 #
1507 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1508 sub recalc {
1509   my ($self) = @_;
1510
1511   # bb: todo: currency later
1512   $self->order->currency_id($::instance_conf->get_currency_id());
1513
1514   my %pat = $self->order->calculate_prices_and_taxes();
1515
1516   $self->{taxes} = [];
1517   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1518     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1519
1520     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1521                                 netamount => $netamount,
1522                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1523   }
1524   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1525 }
1526
1527 # get data for saving, printing, ..., that is not changed in the form
1528 #
1529 # Only cvars for now.
1530 sub get_unalterable_data {
1531   my ($self) = @_;
1532
1533   foreach my $item (@{ $self->order->items }) {
1534     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1535     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1536     foreach my $var (@{ $item->cvars_by_config }) {
1537       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1538     }
1539     $item->parse_custom_variable_values;
1540   }
1541 }
1542
1543 # delete the order
1544 #
1545 # And remove related files in the spool directory
1546 sub delete {
1547   my ($self) = @_;
1548
1549   my $errors = [];
1550   my $db     = $self->order->db;
1551
1552   $db->with_transaction(
1553     sub {
1554       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1555       $self->order->delete;
1556       my $spool = $::lx_office_conf{paths}->{spool};
1557       unlink map { "$spool/$_" } @spoolfiles if $spool;
1558
1559       1;
1560   }) || push(@{$errors}, $db->error);
1561
1562   return $errors;
1563 }
1564
1565 # save the order
1566 #
1567 # And delete items that are deleted in the form.
1568 sub save {
1569   my ($self) = @_;
1570
1571   my $errors = [];
1572   my $db     = $self->order->db;
1573
1574   $db->with_transaction(sub {
1575     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1576     $self->order->save(cascade => 1);
1577
1578     # link records
1579     if ($::form->{converted_from_oe_id}) {
1580       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1581       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1582         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1583         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1584         $src->link_to_record($self->order);
1585       }
1586       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1587         my $idx = 0;
1588         foreach (@{ $self->order->items_sorted }) {
1589           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1590           next if !$from_id;
1591           SL::DB::RecordLink->new(from_table => 'orderitems',
1592                                   from_id    => $from_id,
1593                                   to_table   => 'orderitems',
1594                                   to_id      => $_->id
1595           )->save;
1596           $idx++;
1597         }
1598       }
1599     }
1600     1;
1601   }) || push(@{$errors}, $db->error);
1602
1603   return $errors;
1604 }
1605
1606 sub workflow_sales_or_purchase_order {
1607   my ($self) = @_;
1608
1609   # always save
1610   my $errors = $self->save();
1611
1612   if (scalar @{ $errors }) {
1613     $self->js->flash('error', $_) foreach @{ $errors };
1614     return $self->js->render();
1615   }
1616
1617   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1618                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1619                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1620                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1621                        : '';
1622
1623   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1624   $self->{converted_from_oe_id} = delete $::form->{id};
1625
1626   # set item ids to new fake id, to identify them as new items
1627   foreach my $item (@{$self->order->items_sorted}) {
1628     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1629   }
1630
1631   # change form type
1632   $::form->{type} = $destination_type;
1633   $self->type($self->init_type);
1634   $self->cv  ($self->init_cv);
1635   $self->check_auth;
1636
1637   $self->recalc();
1638   $self->get_unalterable_data();
1639   $self->pre_render();
1640
1641   # trigger rendering values for second row/longdescription as hidden,
1642   # because they are loaded only on demand. So we need to keep the values
1643   # from the source.
1644   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1645   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1646
1647   $self->render(
1648     'order/form',
1649     title => $self->get_title_for('edit'),
1650     %{$self->{template_args}}
1651   );
1652 }
1653
1654
1655 sub pre_render {
1656   my ($self) = @_;
1657
1658   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1659   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1660   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1661                                                                                               deleted => 0 ] ],
1662                                                                            sort_by => 'name');
1663   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1664                                                                                               deleted => 0 ] ],
1665                                                                            sort_by => 'name');
1666   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1667                                                                                                         obsolete => 0 ] ]);
1668   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1669   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1670   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1671   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1672   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1673
1674   my $print_form = Form->new('');
1675   $print_form->{type}        = $self->type;
1676   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1677   $print_form->{languages}   = SL::DB::Manager::Language->get_all_sorted;
1678   $print_form->{language_id} = $self->order->language_id;
1679   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1680     form => $print_form,
1681     options => {dialog_name_prefix => 'print_options.',
1682                 show_headers       => 1,
1683                 no_queue           => 1,
1684                 no_postscript      => 1,
1685                 no_opendocument    => 0,
1686                 no_html            => 1},
1687   );
1688
1689   foreach my $item (@{$self->order->orderitems}) {
1690     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1691     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1692     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1693   }
1694
1695   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1696     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1697     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1698   }
1699
1700   if ($self->order->number && $::instance_conf->get_webdav) {
1701     my $webdav = SL::Webdav->new(
1702       type     => $self->type,
1703       number   => $self->order->number,
1704     );
1705     my @all_objects = $webdav->get_all_objects;
1706     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1707                                                     type => t8('File'),
1708                                                     link => File::Spec->catfile($_->full_filedescriptor),
1709                                                 } } @all_objects;
1710   }
1711
1712   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1713
1714   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery edit_periodic_invoices_config calculate_qty);
1715   $self->setup_edit_action_bar;
1716 }
1717
1718 sub setup_edit_action_bar {
1719   my ($self, %params) = @_;
1720
1721   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1722                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1723                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1724
1725   for my $bar ($::request->layout->get('actionbar')) {
1726     $bar->add(
1727       combobox => [
1728         action => [
1729           t8('Save'),
1730           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1731                                                     $::instance_conf->get_order_warn_no_deliverydate,
1732                                                                                                       ],
1733           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1734         ],
1735         action => [
1736           t8('Save as new'),
1737           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1738           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1739           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1740         ],
1741       ], # end of combobox "Save"
1742
1743       combobox => [
1744         action => [
1745           t8('Workflow'),
1746         ],
1747         action => [
1748           t8('Save and Sales Order'),
1749           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1750           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1751           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1752         ],
1753         action => [
1754           t8('Save and Purchase Order'),
1755           submit   => [ '#order_form', { action => "Order/purchase_order" } ],
1756           only_if  => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1757           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1758         ],
1759         action => [
1760           t8('Save and Delivery Order'),
1761           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1762                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1763                                                                                                                         ],
1764           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1765           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1766         ],
1767         action => [
1768           t8('Save and Invoice'),
1769           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1770           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1771         ],
1772         action => [
1773           t8('Save and AP Transaction'),
1774           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1775           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1776         ],
1777
1778       ], # end of combobox "Workflow"
1779
1780       combobox => [
1781         action => [
1782           t8('Export'),
1783         ],
1784         action => [
1785           t8('Save and print'),
1786           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1787         ],
1788         action => [
1789           t8('Save and E-mail'),
1790           call => [ 'kivi.Order.email', $::instance_conf->get_order_warn_duplicate_parts ],
1791         ],
1792         action => [
1793           t8('Download attachments of all parts'),
1794           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1795           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1796           only_if  => $::instance_conf->get_doc_storage,
1797         ],
1798       ], # end of combobox "Export"
1799
1800       action => [
1801         t8('Delete'),
1802         call     => [ 'kivi.Order.delete_order' ],
1803         confirm  => $::locale->text('Do you really want to delete this object?'),
1804         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1805         only_if  => $deletion_allowed,
1806       ],
1807     );
1808   }
1809 }
1810
1811 sub generate_pdf {
1812   my ($order, $pdf_ref, $params) = @_;
1813
1814   my @errors = ();
1815
1816   my $print_form = Form->new('');
1817   $print_form->{type}        = $order->type;
1818   $print_form->{formname}    = $params->{formname} || $order->type;
1819   $print_form->{format}      = $params->{format}   || 'pdf';
1820   $print_form->{media}       = $params->{media}    || 'file';
1821   $print_form->{groupitems}  = $params->{groupitems};
1822   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1823
1824   $order->language($params->{language});
1825   $order->flatten_to_form($print_form, format_amounts => 1);
1826
1827   my $template_ext;
1828   my $template_type;
1829   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1830     $template_ext  = 'odt';
1831     $template_type = 'OpenDocument';
1832   }
1833
1834   # search for the template
1835   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1836     name        => $print_form->{formname},
1837     extension   => $template_ext,
1838     email       => $print_form->{media} eq 'email',
1839     language    => $params->{language},
1840     printer_id  => $print_form->{printer_id},  # todo
1841   );
1842
1843   if (!defined $template_file) {
1844     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1845   }
1846
1847   return @errors if scalar @errors;
1848
1849   $print_form->throw_on_error(sub {
1850     eval {
1851       $print_form->prepare_for_printing;
1852
1853       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1854         format        => $print_form->{format},
1855         template_type => $template_type,
1856         template      => $template_file,
1857         variables     => $print_form,
1858         variable_content_types => {
1859           longdescription => 'html',
1860           partnotes       => 'html',
1861           notes           => 'html',
1862         },
1863       );
1864       1;
1865     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1866   });
1867
1868   return @errors;
1869 }
1870
1871 sub get_files_for_email_dialog {
1872   my ($self) = @_;
1873
1874   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1875
1876   return %files if !$::instance_conf->get_doc_storage;
1877
1878   if ($self->order->id) {
1879     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1880     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1881     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1882   }
1883
1884   my @parts =
1885     uniq_by { $_->{id} }
1886     map {
1887       +{ id         => $_->part->id,
1888          partnumber => $_->part->partnumber }
1889     } @{$self->order->items_sorted};
1890
1891   foreach my $part (@parts) {
1892     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1893     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1894   }
1895
1896   foreach my $key (keys %files) {
1897     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1898   }
1899
1900   return %files;
1901 }
1902
1903 sub make_periodic_invoices_config_from_yaml {
1904   my ($yaml_config) = @_;
1905
1906   return if !$yaml_config;
1907   my $attr = SL::YAML::Load($yaml_config);
1908   return if 'HASH' ne ref $attr;
1909   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1910 }
1911
1912
1913 sub get_periodic_invoices_status {
1914   my ($self, $config) = @_;
1915
1916   return                      if $self->type ne sales_order_type();
1917   return t8('not configured') if !$config;
1918
1919   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1920              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1921              :                                                     die "Cannot get status of periodic invoices config";
1922
1923   return $active ? t8('active') : t8('inactive');
1924 }
1925
1926 sub get_title_for {
1927   my ($self, $action) = @_;
1928
1929   return '' if none { lc($action)} qw(add edit);
1930
1931   # for locales:
1932   # $::locale->text("Add Sales Order");
1933   # $::locale->text("Add Purchase Order");
1934   # $::locale->text("Add Quotation");
1935   # $::locale->text("Add Request for Quotation");
1936   # $::locale->text("Edit Sales Order");
1937   # $::locale->text("Edit Purchase Order");
1938   # $::locale->text("Edit Quotation");
1939   # $::locale->text("Edit Request for Quotation");
1940
1941   $action = ucfirst(lc($action));
1942   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
1943        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
1944        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
1945        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
1946        : '';
1947 }
1948
1949 sub get_item_cvpartnumber {
1950   my ($self, $item) = @_;
1951
1952   return if !$self->search_cvpartnumber;
1953   return if !$self->order->customervendor;
1954
1955   if ($self->cv eq 'vendor') {
1956     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
1957     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
1958   } elsif ($self->cv eq 'customer') {
1959     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
1960     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
1961   }
1962 }
1963
1964 sub sales_order_type {
1965   'sales_order';
1966 }
1967
1968 sub purchase_order_type {
1969   'purchase_order';
1970 }
1971
1972 sub sales_quotation_type {
1973   'sales_quotation';
1974 }
1975
1976 sub request_quotation_type {
1977   'request_quotation';
1978 }
1979
1980 sub nr_key {
1981   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
1982        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
1983        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
1984        : $_[0]->type eq request_quotation_type() ? 'quonumber'
1985        : '';
1986 }
1987
1988 1;
1989
1990 __END__
1991
1992 =encoding utf-8
1993
1994 =head1 NAME
1995
1996 SL::Controller::Order - controller for orders
1997
1998 =head1 SYNOPSIS
1999
2000 This is a new form to enter orders, completely rewritten with the use
2001 of controller and java script techniques.
2002
2003 The aim is to provide the user a better experience and a faster workflow. Also
2004 the code should be more readable, more reliable and better to maintain.
2005
2006 =head2 Key Features
2007
2008 =over 4
2009
2010 =item *
2011
2012 One input row, so that input happens every time at the same place.
2013
2014 =item *
2015
2016 Use of pickers where possible.
2017
2018 =item *
2019
2020 Possibility to enter more than one item at once.
2021
2022 =item *
2023
2024 Item list in a scrollable area, so that the workflow buttons stay at
2025 the bottom.
2026
2027 =item *
2028
2029 Reordering item rows with drag and drop is possible. Sorting item rows is
2030 possible (by partnumber, description, qty, sellprice and discount for now).
2031
2032 =item *
2033
2034 No C<update> is necessary. All entries and calculations are managed
2035 with ajax-calls and the page only reloads on C<save>.
2036
2037 =item *
2038
2039 User can see changes immediately, because of the use of java script
2040 and ajax.
2041
2042 =back
2043
2044 =head1 CODE
2045
2046 =head2 Layout
2047
2048 =over 4
2049
2050 =item * C<SL/Controller/Order.pm>
2051
2052 the controller
2053
2054 =item * C<template/webpages/order/form.html>
2055
2056 main form
2057
2058 =item * C<template/webpages/order/tabs/basic_data.html>
2059
2060 Main tab for basic_data.
2061
2062 This is the only tab here for now. "linked records" and "webdav" tabs are
2063 reused from generic code.
2064
2065 =over 4
2066
2067 =item * C<template/webpages/order/tabs/_business_info_row.html>
2068
2069 For displaying information on business type
2070
2071 =item * C<template/webpages/order/tabs/_item_input.html>
2072
2073 The input line for items
2074
2075 =item * C<template/webpages/order/tabs/_row.html>
2076
2077 One row for already entered items
2078
2079 =item * C<template/webpages/order/tabs/_tax_row.html>
2080
2081 Displaying tax information
2082
2083 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
2084
2085 Dialog for entering more than one item at once
2086
2087 =item * C<template/webpages/order/tabs/_multi_items_result.html>
2088
2089 Results for the filter in the multi items dialog
2090
2091 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2092
2093 Dialog for selecting price and discount sources
2094
2095 =back
2096
2097 =item * C<js/kivi.Order.js>
2098
2099 java script functions
2100
2101 =back
2102
2103 =head1 TODO
2104
2105 =over 4
2106
2107 =item * testing
2108
2109 =item * currency
2110
2111 =item * credit limit
2112
2113 =item * more workflows (quotation, rfq)
2114
2115 =item * price sources: little symbols showing better price / better discount
2116
2117 =item * select units in input row?
2118
2119 =item * custom shipto address
2120
2121 =item * check for direct delivery (workflow sales order -> purchase order)
2122
2123 =item * language / part translations
2124
2125 =item * access rights
2126
2127 =item * display weights
2128
2129 =item * history
2130
2131 =item * mtime check
2132
2133 =item * optional client/user behaviour
2134
2135 (transactions has to be set - department has to be set -
2136  force project if enabled in client config - transport cost reminder)
2137
2138 =back
2139
2140 =head1 KNOWN BUGS AND CAVEATS
2141
2142 =over 4
2143
2144 =item *
2145
2146 Customer discount is not displayed as a valid discount in price source popup
2147 (this might be a bug in price sources)
2148
2149 (I cannot reproduce this (Bernd))
2150
2151 =item *
2152
2153 No indication that <shift>-up/down expands/collapses second row.
2154
2155 =item *
2156
2157 Inline creation of parts is not currently supported
2158
2159 =item *
2160
2161 Table header is not sticky in the scrolling area.
2162
2163 =item *
2164
2165 Sorting does not include C<position>, neither does reordering.
2166
2167 This behavior was implemented intentionally. But we can discuss, which behavior
2168 should be implemented.
2169
2170 =item *
2171
2172 C<show_multi_items_dialog> does not use the currently inserted string for
2173 filtering.
2174
2175 =back
2176
2177 =head1 To discuss / Nice to have
2178
2179 =over 4
2180
2181 =item *
2182
2183 How to expand/collapse second row. Now it can be done clicking the icon or
2184 <shift>-up/down.
2185
2186 =item *
2187
2188 Possibility to change longdescription in input row?
2189
2190 =item *
2191
2192 Possibility to select PriceSources in input row?
2193
2194 =item *
2195
2196 This controller uses a (changed) copy of the template for the PriceSource
2197 dialog. Maybe there could be used one code source.
2198
2199 =item *
2200
2201 Rounding-differences between this controller (PriceTaxCalculator) and the old
2202 form. This is not only a problem here, but also in all parts using the PTC.
2203 There exists a ticket and a patch. This patch should be testet.
2204
2205 =item *
2206
2207 An indicator, if the actual inputs are saved (like in an
2208 editor or on text processing application).
2209
2210 =item *
2211
2212 A warning when leaving the page without saveing unchanged inputs.
2213
2214
2215 =back
2216
2217 =head1 AUTHOR
2218
2219 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2220
2221 =cut