SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::History;
  17 use SL::DB::Order;
  18 use SL::DB::Default;
  19 use SL::DB::Unit;
  20 use SL::DB::Part;
  21 use SL::DB::PartClassification;
  22 use SL::DB::PartsGroup;
  23 use SL::DB::Printer;
  24 use SL::DB::Language;
  25 use SL::DB::RecordLink;
  26 use SL::DB::Shipto;
  27 use SL::DB::Translation;
  28
  29 use SL::Helper::CreatePDF qw(:all);
  30 use SL::Helper::PrintOptions;
  31 use SL::Helper::ShippedQty;
  32 use SL::Helper::UserPreferences::PositionsScrollbar;
  33 use SL::Helper::UserPreferences::UpdatePositions;
  34
  35 use SL::Controller::Helper::GetModels;
  36
  37 use List::Util qw(first sum0);
  38 use List::UtilsBy qw(sort_by uniq_by);
  39 use List::MoreUtils qw(any none pairwise first_index);
  40 use English qw(-no_match_vars);
  41 use File::Spec;
  42 use Cwd;
  43 use Sort::Naturally;
  44
  45 use Rose::Object::MakeMethods::Generic
  46 (
  47  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  48  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  49 );
  50
  51
  52 # safety
  53 __PACKAGE__->run_before('check_auth');
  54
  55 __PACKAGE__->run_before('recalc',
  56                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  57                                      print send_email) ]);
  58
  59 __PACKAGE__->run_before('get_unalterable_data',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 #
  64 # actions
  65 #
  66
  67 # add a new order
  68 sub action_add {
  69   my ($self) = @_;
  70
  71   $self->order->transdate(DateTime->now_local());
  72   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  73                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  74   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  75
  76
  77   $self->pre_render();
  78   $self->render(
  79     'order/form',
  80     title => $self->get_title_for('add'),
  81     %{$self->{template_args}}
  82   );
  83 }
  84
  85 # edit an existing order
  86 sub action_edit {
  87   my ($self) = @_;
  88
  89   if ($::form->{id}) {
  90     $self->load_order;
  91
  92   } else {
  93     # this is to edit an order from an unsaved order object
  94
  95     # set item ids to new fake id, to identify them as new items
  96     foreach my $item (@{$self->order->items_sorted}) {
  97       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  98     }
  99     # trigger rendering values for second row as hidden, because they
 100     # are loaded only on demand. So we need to keep the values from
 101     # the source.
 102     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 103   }
 104
 105   $self->recalc();
 106   $self->pre_render();
 107   $self->render(
 108     'order/form',
 109     title => $self->get_title_for('edit'),
 110     %{$self->{template_args}}
 111   );
 112 }
 113
 114 # edit a collective order (consisting of one or more existing orders)
 115 sub action_edit_collective {
 116   my ($self) = @_;
 117
 118   # collect order ids
 119   my @multi_ids = map {
 120     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 121   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 122
 123   # fall back to add if no ids are given
 124   if (scalar @multi_ids == 0) {
 125     $self->action_add();
 126     return;
 127   }
 128
 129   # fall back to save as new if only one id is given
 130   if (scalar @multi_ids == 1) {
 131     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 132     $self->action_save_as_new();
 133     return;
 134   }
 135
 136   # make new order from given orders
 137   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 138   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 139   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 140
 141   $self->action_edit();
 142 }
 143
 144 # delete the order
 145 sub action_delete {
 146   my ($self) = @_;
 147
 148   my $errors = $self->delete();
 149
 150   if (scalar @{ $errors }) {
 151     $self->js->flash('error', $_) foreach @{ $errors };
 152     return $self->js->render();
 153   }
 154
 155   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 156            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 157            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 158            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 159            : '';
 160   flash_later('info', $text);
 161
 162   my @redirect_params = (
 163     action => 'add',
 164     type   => $self->type,
 165   );
 166
 167   $self->redirect_to(@redirect_params);
 168 }
 169
 170 # save the order
 171 sub action_save {
 172   my ($self) = @_;
 173
 174   my $errors = $self->save();
 175
 176   if (scalar @{ $errors }) {
 177     $self->js->flash('error', $_) foreach @{ $errors };
 178     return $self->js->render();
 179   }
 180
 181   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 182            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 183            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 184            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 185            : '';
 186   flash_later('info', $text);
 187
 188   my @redirect_params = (
 189     action => 'edit',
 190     type   => $self->type,
 191     id     => $self->order->id,
 192   );
 193
 194   $self->redirect_to(@redirect_params);
 195 }
 196
 197 # save the order as new document an open it for edit
 198 sub action_save_as_new {
 199   my ($self) = @_;
 200
 201   my $order = $self->order;
 202
 203   if (!$order->id) {
 204     $self->js->flash('error', t8('This object has not been saved yet.'));
 205     return $self->js->render();
 206   }
 207
 208   # load order from db to check if values changed
 209   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 210
 211   my %new_attrs;
 212   # Lets assign a new number if the user hasn't changed the previous one.
 213   # If it has been changed manually then use it as-is.
 214   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 215                         ? ''
 216                         : trim($order->number);
 217
 218   # Clear transdate unless changed
 219   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 220                         ? DateTime->today_local
 221                         : $order->transdate;
 222
 223   # Set new reqdate unless changed
 224   if ($order->reqdate == $saved_order->reqdate) {
 225     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 226                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 227     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 228   } else {
 229     $new_attrs{reqdate} = $order->reqdate;
 230   }
 231
 232   # Update employee
 233   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 234
 235   # Create new record from current one
 236   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 237
 238   # no linked records on save as new
 239   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 240
 241   # save
 242   $self->action_save();
 243 }
 244
 245 # print the order
 246 #
 247 # This is called if "print" is pressed in the print dialog.
 248 # If PDF creation was requested and succeeded, the pdf is offered for download
 249 # via send_file (which uses ajax in this case).
 250 sub action_print {
 251   my ($self) = @_;
 252
 253   my $errors = $self->save();
 254
 255   if (scalar @{ $errors }) {
 256     $self->js->flash('error', $_) foreach @{ $errors };
 257     return $self->js->render();
 258   }
 259
 260   $self->js_reset_order_and_item_ids_after_save;
 261
 262   my $format      = $::form->{print_options}->{format};
 263   my $media       = $::form->{print_options}->{media};
 264   my $formname    = $::form->{print_options}->{formname};
 265   my $copies      = $::form->{print_options}->{copies};
 266   my $groupitems  = $::form->{print_options}->{groupitems};
 267   my $printer_id  = $::form->{print_options}->{printer_id};
 268
 269   # only pdf and opendocument by now
 270   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 271     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 272   }
 273
 274   # only screen or printer by now
 275   if (none { $media eq $_ } qw(screen printer)) {
 276     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 277   }
 278
 279   # create a form for generate_attachment_filename
 280   my $form   = Form->new;
 281   $form->{$self->nr_key()}  = $self->order->number;
 282   $form->{type}             = $self->type;
 283   $form->{format}           = $format;
 284   $form->{formname}         = $formname;
 285   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 286   my $pdf_filename          = $form->generate_attachment_filename();
 287
 288   my $pdf;
 289   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 290                                                    formname   => $formname,
 291                                                    language   => $self->order->language,
 292                                                    printer_id => $printer_id,
 293                                                    groupitems => $groupitems });
 294   if (scalar @errors) {
 295     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 296   }
 297
 298   if ($media eq 'screen') {
 299     # screen/download
 300     $self->js->flash('info', t8('The PDF has been created'));
 301     $self->send_file(
 302       \$pdf,
 303       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 304       name         => $pdf_filename,
 305       js_no_render => 1,
 306     );
 307
 308   } elsif ($media eq 'printer') {
 309     # printer
 310     my $printer_id = $::form->{print_options}->{printer_id};
 311     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 312       copies  => $copies,
 313       content => $pdf,
 314     );
 315
 316     $self->js->flash('info', t8('The PDF has been printed'));
 317   }
 318
 319   my @warnings = store_pdf_to_webdav_and_filemanegement($self->order, $pdf, $pdf_filename);
 320   if (scalar @warnings) {
 321     $self->js->flash('warning', $_) for @warnings;
 322   }
 323
 324   $self->save_history('PRINTED');
 325
 326   $self->js
 327     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 328     ->render;
 329 }
 330
 331 # open the email dialog
 332 sub action_save_and_show_email_dialog {
 333   my ($self) = @_;
 334
 335   my $errors = $self->save();
 336
 337   if (scalar @{ $errors }) {
 338     $self->js->flash('error', $_) foreach @{ $errors };
 339     return $self->js->render();
 340   }
 341
 342   my $cv_method = $self->cv;
 343
 344   if (!$self->order->$cv_method) {
 345     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 346                     ->render($self);
 347   }
 348
 349   my $email_form;
 350   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 351   $email_form->{to} ||= $self->order->$cv_method->email;
 352   $email_form->{cc}   = $self->order->$cv_method->cc;
 353   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 354   # Todo: get addresses from shipto, if any
 355
 356   my $form = Form->new;
 357   $form->{$self->nr_key()}  = $self->order->number;
 358   $form->{cusordnumber}     = $self->order->cusordnumber;
 359   $form->{formname}         = $self->type;
 360   $form->{type}             = $self->type;
 361   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 362   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 363   $form->{format}           = 'pdf';
 364
 365   $email_form->{subject}             = $form->generate_email_subject();
 366   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 367   $email_form->{message}             = $form->generate_email_body();
 368   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 369
 370   my %files = $self->get_files_for_email_dialog();
 371   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 372                                   email_form  => $email_form,
 373                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 374                                   FILES       => \%files,
 375                                   is_customer => $self->cv eq 'customer',
 376   );
 377
 378   $self->js
 379       ->run('kivi.Order.show_email_dialog', $dialog_html)
 380       ->reinit_widgets
 381       ->render($self);
 382 }
 383
 384 # send email
 385 #
 386 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 387 sub action_send_email {
 388   my ($self) = @_;
 389
 390   my $errors = $self->save();
 391
 392   if (scalar @{ $errors }) {
 393     $self->js->run('kivi.Order.close_email_dialog');
 394     $self->js->flash('error', $_) foreach @{ $errors };
 395     return $self->js->render();
 396   }
 397
 398   $self->js_reset_order_and_item_ids_after_save;
 399
 400   my $email_form  = delete $::form->{email_form};
 401   my %field_names = (to => 'email');
 402
 403   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 404
 405   # for Form::cleanup which may be called in Form::send_email
 406   $::form->{cwd}    = getcwd();
 407   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 408
 409   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 410   $::form->{media}  = 'email';
 411
 412   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 413     my $pdf;
 414     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 415                                                     format     => $::form->{print_options}->{format},
 416                                                     formname   => $::form->{print_options}->{formname},
 417                                                     language   => $self->order->language,
 418                                                     printer_id => $::form->{print_options}->{printer_id},
 419                                                     groupitems => $::form->{print_options}->{groupitems}});
 420     if (scalar @errors) {
 421       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 422     }
 423
 424     my @warnings = store_pdf_to_webdav_and_filemanegement($self->order, $pdf, $::form->{attachment_filename});
 425     if (scalar @warnings) {
 426       flash_later('warning', $_) for @warnings;
 427     }
 428
 429     my $sfile = SL::SessionFile::Random->new(mode => "w");
 430     $sfile->fh->print($pdf);
 431     $sfile->fh->close;
 432
 433     $::form->{tmpfile} = $sfile->file_name;
 434     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 435   }
 436
 437   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 438   $::form->send_email(\%::myconfig, 'pdf');
 439
 440   # internal notes
 441   my $intnotes = $self->order->intnotes;
 442   $intnotes   .= "\n\n" if $self->order->intnotes;
 443   $intnotes   .= t8('[email]')                                                                                        . "\n";
 444   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 445   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 446   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 447   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 448   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 449   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 450
 451   $self->order->update_attributes(intnotes => $intnotes);
 452
 453   $self->save_history('MAILED');
 454
 455   flash_later('info', t8('The email has been sent.'));
 456
 457   my @redirect_params = (
 458     action => 'edit',
 459     type   => $self->type,
 460     id     => $self->order->id,
 461   );
 462
 463   $self->redirect_to(@redirect_params);
 464 }
 465
 466 # open the periodic invoices config dialog
 467 #
 468 # If there are values in the form (i.e. dialog was opened before),
 469 # then use this values. Create new ones, else.
 470 sub action_show_periodic_invoices_config_dialog {
 471   my ($self) = @_;
 472
 473   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 474   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 475   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 476                                                    order_value_periodicity => 'p', # = same as periodicity
 477                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 478                                                    extend_automatically_by => 12,
 479                                                    active                  => 1,
 480                                                    email_subject           => GenericTranslations->get(
 481                                                                                 language_id      => $::form->{language_id},
 482                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 483                                                    email_body              => GenericTranslations->get(
 484                                                                                 language_id      => $::form->{language_id},
 485                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 486   );
 487   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 488   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 489
 490   $::form->get_lists(printers => "ALL_PRINTERS",
 491                      charts   => { key       => 'ALL_CHARTS',
 492                                    transdate => 'current_date' });
 493
 494   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 495
 496   if ($::form->{customer_id}) {
 497     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 498     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 499   }
 500
 501   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 502                 popup_dialog             => 1,
 503                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 504                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 505                 config                   => $config,
 506                 %$::form);
 507 }
 508
 509 # assign the values of the periodic invoices config dialog
 510 # as yaml in the hidden tag and set the status.
 511 sub action_assign_periodic_invoices_config {
 512   my ($self) = @_;
 513
 514   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 515
 516   my $config = { active                     => $::form->{active}       ? 1 : 0,
 517                  terminated                 => $::form->{terminated}   ? 1 : 0,
 518                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 519                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 520                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 521                  start_date_as_date         => $::form->{start_date_as_date},
 522                  end_date_as_date           => $::form->{end_date_as_date},
 523                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 524                  print                      => $::form->{print}      ? 1                         : 0,
 525                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 526                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 527                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 528                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 529                  send_email                 => $::form->{send_email} ? 1 : 0,
 530                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 531                  email_recipient_address    => $::form->{email_recipient_address},
 532                  email_sender               => $::form->{email_sender},
 533                  email_subject              => $::form->{email_subject},
 534                  email_body                 => $::form->{email_body},
 535                };
 536
 537   my $periodic_invoices_config = SL::YAML::Dump($config);
 538
 539   my $status = $self->get_periodic_invoices_status($config);
 540
 541   $self->js
 542     ->remove('#order_periodic_invoices_config')
 543     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 544     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 545     ->html('#periodic_invoices_status', $status)
 546     ->flash('info', t8('The periodic invoices config has been assigned.'))
 547     ->render($self);
 548 }
 549
 550 sub action_get_has_active_periodic_invoices {
 551   my ($self) = @_;
 552
 553   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 554   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 555
 556   my $has_active_periodic_invoices =
 557        $self->type eq sales_order_type()
 558     && $config
 559     && $config->active
 560     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 561     && $config->get_previous_billed_period_start_date;
 562
 563   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 564 }
 565
 566 # save the order and redirect to the frontend subroutine for a new
 567 # delivery order
 568 sub action_save_and_delivery_order {
 569   my ($self) = @_;
 570
 571   $self->save_and_redirect_to(
 572     controller => 'oe.pl',
 573     action     => 'oe_delivery_order_from_order',
 574   );
 575 }
 576
 577 # save the order and redirect to the frontend subroutine for a new
 578 # invoice
 579 sub action_save_and_invoice {
 580   my ($self) = @_;
 581
 582   $self->save_and_redirect_to(
 583     controller => 'oe.pl',
 584     action     => 'oe_invoice_from_order',
 585   );
 586 }
 587
 588 # workflow from sales order to sales quotation
 589 sub action_sales_quotation {
 590   $_[0]->workflow_sales_or_request_for_quotation();
 591 }
 592
 593 # workflow from sales order to sales quotation
 594 sub action_request_for_quotation {
 595   $_[0]->workflow_sales_or_request_for_quotation();
 596 }
 597
 598 # workflow from sales quotation to sales order
 599 sub action_sales_order {
 600   $_[0]->workflow_sales_or_purchase_order();
 601 }
 602
 603 # workflow from rfq to purchase order
 604 sub action_purchase_order {
 605   $_[0]->workflow_sales_or_purchase_order();
 606 }
 607
 608 # workflow from purchase order to ap transaction
 609 sub action_save_and_ap_transaction {
 610   my ($self) = @_;
 611
 612   $self->save_and_redirect_to(
 613     controller => 'ap.pl',
 614     action     => 'add_from_purchase_order',
 615   );
 616 }
 617
 618 # set form elements in respect to a changed customer or vendor
 619 #
 620 # This action is called on an change of the customer/vendor picker.
 621 sub action_customer_vendor_changed {
 622   my ($self) = @_;
 623
 624   setup_order_from_cv($self->order);
 625   $self->recalc();
 626
 627   my $cv_method = $self->cv;
 628
 629   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 630     $self->js->show('#cp_row');
 631   } else {
 632     $self->js->hide('#cp_row');
 633   }
 634
 635   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 636     $self->js->show('#shipto_selection');
 637   } else {
 638     $self->js->hide('#shipto_selection');
 639   }
 640
 641   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 642
 643   $self->js
 644     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 645     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 646     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 647     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 648     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 649     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 650     ->val(        '#order_currency_id',      $self->order->currency_id)
 651     ->val(        '#order_payment_id',       $self->order->payment_id)
 652     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 653     ->val(        '#order_intnotes',         $self->order->intnotes)
 654     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 655     ->focus(      '#order_' . $self->cv . '_id')
 656     ->run('kivi.Order.update_exchangerate');
 657
 658   $self->js_redisplay_amounts_and_taxes;
 659   $self->js_redisplay_cvpartnumbers;
 660   $self->js->render();
 661 }
 662
 663 # open the dialog for customer/vendor details
 664 sub action_show_customer_vendor_details_dialog {
 665   my ($self) = @_;
 666
 667   my $is_customer = 'customer' eq $::form->{vc};
 668   my $cv;
 669   if ($is_customer) {
 670     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 671   } else {
 672     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 673   }
 674
 675   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 676   $details{discount_as_percent} = $cv->discount_as_percent;
 677   $details{creditlimt}          = $cv->creditlimit_as_number;
 678   $details{business}            = $cv->business->description      if $cv->business;
 679   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 680   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 681   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 682   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 683
 684   foreach my $entry (@{ $cv->shipto }) {
 685     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 686   }
 687   foreach my $entry (@{ $cv->contacts }) {
 688     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 689   }
 690
 691   $_[0]->render('common/show_vc_details', { layout => 0 },
 692                 is_customer => $is_customer,
 693                 %details);
 694
 695 }
 696
 697 # called if a unit in an existing item row is changed
 698 sub action_unit_changed {
 699   my ($self) = @_;
 700
 701   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 702   my $item = $self->order->items_sorted->[$idx];
 703
 704   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 705   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 706
 707   $self->recalc();
 708
 709   $self->js
 710     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 711   $self->js_redisplay_line_values;
 712   $self->js_redisplay_amounts_and_taxes;
 713   $self->js->render();
 714 }
 715
 716 # add an item row for a new item entered in the input row
 717 sub action_add_item {
 718   my ($self) = @_;
 719
 720   my $form_attr = $::form->{add_item};
 721
 722   return unless $form_attr->{parts_id};
 723
 724   my $item = new_item($self->order, $form_attr);
 725
 726   $self->order->add_items($item);
 727
 728   $self->recalc();
 729
 730   $self->get_item_cvpartnumber($item);
 731
 732   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 733   my $row_as_html = $self->p->render('order/tabs/_row',
 734                                      ITEM => $item,
 735                                      ID   => $item_id,
 736                                      SELF => $self,
 737   );
 738
 739   if ($::form->{insert_before_item_id}) {
 740     $self->js
 741       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 742   } else {
 743     $self->js
 744       ->append('#row_table_id', $row_as_html);
 745   }
 746
 747   if ( $item->part->is_assortment ) {
 748     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 749     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 750       my $attr = { parts_id => $assortment_item->parts_id,
 751                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 752                    unit     => $assortment_item->unit,
 753                    description => $assortment_item->part->description,
 754                  };
 755       my $item = new_item($self->order, $attr);
 756
 757       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 758       $item->discount(1) unless $assortment_item->charge;
 759
 760       $self->order->add_items( $item );
 761       $self->recalc();
 762       $self->get_item_cvpartnumber($item);
 763       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 764       my $row_as_html = $self->p->render('order/tabs/_row',
 765                                          ITEM => $item,
 766                                          ID   => $item_id,
 767                                          SELF => $self,
 768       );
 769       if ($::form->{insert_before_item_id}) {
 770         $self->js
 771           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 772       } else {
 773         $self->js
 774           ->append('#row_table_id', $row_as_html);
 775       }
 776     };
 777   };
 778
 779   $self->js
 780     ->val('.add_item_input', '')
 781     ->run('kivi.Order.init_row_handlers')
 782     ->run('kivi.Order.renumber_positions')
 783     ->focus('#add_item_parts_id_name');
 784
 785   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 786
 787   $self->js_redisplay_amounts_and_taxes;
 788   $self->js->render();
 789 }
 790
 791 # add item rows for multiple items at once
 792 sub action_add_multi_items {
 793   my ($self) = @_;
 794
 795   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 796   return $self->js->render() unless scalar @form_attr;
 797
 798   my @items;
 799   foreach my $attr (@form_attr) {
 800     my $item = new_item($self->order, $attr);
 801     push @items, $item;
 802     if ( $item->part->is_assortment ) {
 803       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 804         my $attr = { parts_id => $assortment_item->parts_id,
 805                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 806                      unit     => $assortment_item->unit,
 807                      description => $assortment_item->part->description,
 808                    };
 809         my $item = new_item($self->order, $attr);
 810
 811         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 812         $item->discount(1) unless $assortment_item->charge;
 813         push @items, $item;
 814       }
 815     }
 816   }
 817   $self->order->add_items(@items);
 818
 819   $self->recalc();
 820
 821   foreach my $item (@items) {
 822     $self->get_item_cvpartnumber($item);
 823     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 824     my $row_as_html = $self->p->render('order/tabs/_row',
 825                                        ITEM => $item,
 826                                        ID   => $item_id,
 827                                        SELF => $self,
 828     );
 829
 830     if ($::form->{insert_before_item_id}) {
 831       $self->js
 832         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 833     } else {
 834       $self->js
 835         ->append('#row_table_id', $row_as_html);
 836     }
 837   }
 838
 839   $self->js
 840     ->run('kivi.Part.close_picker_dialogs')
 841     ->run('kivi.Order.init_row_handlers')
 842     ->run('kivi.Order.renumber_positions')
 843     ->focus('#add_item_parts_id_name');
 844
 845   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 846
 847   $self->js_redisplay_amounts_and_taxes;
 848   $self->js->render();
 849 }
 850
 851 # recalculate all linetotals, amounts and taxes and redisplay them
 852 sub action_recalc_amounts_and_taxes {
 853   my ($self) = @_;
 854
 855   $self->recalc();
 856
 857   $self->js_redisplay_line_values;
 858   $self->js_redisplay_amounts_and_taxes;
 859   $self->js->render();
 860 }
 861
 862 sub action_update_exchangerate {
 863   my ($self) = @_;
 864
 865   my $data = {
 866     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 867     currency_name => $self->order->currency->name,
 868     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 869   };
 870
 871   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 872 }
 873
 874 # redisplay item rows if they are sorted by an attribute
 875 sub action_reorder_items {
 876   my ($self) = @_;
 877
 878   my %sort_keys = (
 879     partnumber   => sub { $_[0]->part->partnumber },
 880     description  => sub { $_[0]->description },
 881     qty          => sub { $_[0]->qty },
 882     sellprice    => sub { $_[0]->sellprice },
 883     discount     => sub { $_[0]->discount },
 884     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 885   );
 886
 887   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 888
 889   my $method = $sort_keys{$::form->{order_by}};
 890   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 891   if ($::form->{sort_dir}) {
 892     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 893       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 894     } else {
 895       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 896     }
 897   } else {
 898     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 899       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 900     } else {
 901       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 902     }
 903   }
 904   $self->js
 905     ->run('kivi.Order.redisplay_items', \@to_sort)
 906     ->render;
 907 }
 908
 909 # show the popup to choose a price/discount source
 910 sub action_price_popup {
 911   my ($self) = @_;
 912
 913   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 914   my $item = $self->order->items_sorted->[$idx];
 915
 916   $self->render_price_dialog($item);
 917 }
 918
 919 # load the second row for one or more items
 920 #
 921 # This action gets the html code for all items second rows by rendering a template for
 922 # the second row and sets the html code via client js.
 923 sub action_load_second_rows {
 924   my ($self) = @_;
 925
 926   $self->recalc() if $self->order->is_sales; # for margin calculation
 927
 928   foreach my $item_id (@{ $::form->{item_ids} }) {
 929     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 930     my $item = $self->order->items_sorted->[$idx];
 931
 932     $self->js_load_second_row($item, $item_id, 0);
 933   }
 934
 935   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 936
 937   $self->js->render();
 938 }
 939
 940 # update description, notes and sellprice from master data
 941 sub action_update_row_from_master_data {
 942   my ($self) = @_;
 943
 944   foreach my $item_id (@{ $::form->{item_ids} }) {
 945     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 946     my $item  = $self->order->items_sorted->[$idx];
 947     my $texts = get_part_texts($item->part, $self->order->language_id);
 948
 949     $item->description($texts->{description});
 950     $item->longdescription($texts->{longdescription});
 951
 952     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 953
 954     my $price_src;
 955     if ($item->part->is_assortment) {
 956     # add assortment items with price 0, as the components carry the price
 957       $price_src = $price_source->price_from_source("");
 958       $price_src->price(0);
 959     } else {
 960       $price_src = $price_source->best_price
 961                  ? $price_source->best_price
 962                  : $price_source->price_from_source("");
 963       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
 964       $price_src->price(0) if !$price_source->best_price;
 965     }
 966
 967
 968     $item->sellprice($price_src->price);
 969     $item->active_price_source($price_src);
 970
 971     $self->js
 972       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
 973       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
 974       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
 975       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
 976
 977     if ($self->search_cvpartnumber) {
 978       $self->get_item_cvpartnumber($item);
 979       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
 980     }
 981   }
 982
 983   $self->recalc();
 984   $self->js_redisplay_line_values;
 985   $self->js_redisplay_amounts_and_taxes;
 986
 987   $self->js->render();
 988 }
 989
 990 sub js_load_second_row {
 991   my ($self, $item, $item_id, $do_parse) = @_;
 992
 993   if ($do_parse) {
 994     # Parse values from form (they are formated while rendering (template)).
 995     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 996     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
 997     foreach my $var (@{ $item->cvars_by_config }) {
 998       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 999     }
1000     $item->parse_custom_variable_values;
1001   }
1002
1003   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1004
1005   $self->js
1006     ->html('#second_row_' . $item_id, $row_as_html)
1007     ->data('#second_row_' . $item_id, 'loaded', 1);
1008 }
1009
1010 sub js_redisplay_line_values {
1011   my ($self) = @_;
1012
1013   my $is_sales = $self->order->is_sales;
1014
1015   # sales orders with margins
1016   my @data;
1017   if ($is_sales) {
1018     @data = map {
1019       [
1020        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1021        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1022        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1023       ]} @{ $self->order->items_sorted };
1024   } else {
1025     @data = map {
1026       [
1027        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1028       ]} @{ $self->order->items_sorted };
1029   }
1030
1031   $self->js
1032     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1033 }
1034
1035 sub js_redisplay_amounts_and_taxes {
1036   my ($self) = @_;
1037
1038   if (scalar @{ $self->{taxes} }) {
1039     $self->js->show('#taxincluded_row_id');
1040   } else {
1041     $self->js->hide('#taxincluded_row_id');
1042   }
1043
1044   if ($self->order->taxincluded) {
1045     $self->js->hide('#subtotal_row_id');
1046   } else {
1047     $self->js->show('#subtotal_row_id');
1048   }
1049
1050   if ($self->order->is_sales) {
1051     my $is_neg = $self->order->marge_total < 0;
1052     $self->js
1053       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1054       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1055       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1056       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1057       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1058       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1059       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1060       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1061   }
1062
1063   $self->js
1064     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1065     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1066     ->remove('.tax_row')
1067     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1068 }
1069
1070 sub js_redisplay_cvpartnumbers {
1071   my ($self) = @_;
1072
1073   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1074
1075   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1076
1077   $self->js
1078     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1079 }
1080
1081 sub js_reset_order_and_item_ids_after_save {
1082   my ($self) = @_;
1083
1084   $self->js
1085     ->val('#id', $self->order->id)
1086     ->val('#converted_from_oe_id', '')
1087     ->val('#order_' . $self->nr_key(), $self->order->number);
1088
1089   my $idx = 0;
1090   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1091     next if !$self->order->items_sorted->[$idx]->id;
1092     next if $form_item_id !~ m{^new};
1093     $self->js
1094       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1095       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1096       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1097   } continue {
1098     $idx++;
1099   }
1100   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1101 }
1102
1103 #
1104 # helpers
1105 #
1106
1107 sub init_valid_types {
1108   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1109 }
1110
1111 sub init_type {
1112   my ($self) = @_;
1113
1114   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1115     die "Not a valid type for order";
1116   }
1117
1118   $self->type($::form->{type});
1119 }
1120
1121 sub init_cv {
1122   my ($self) = @_;
1123
1124   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1125          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1126          : die "Not a valid type for order";
1127
1128   return $cv;
1129 }
1130
1131 sub init_search_cvpartnumber {
1132   my ($self) = @_;
1133
1134   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1135   my $search_cvpartnumber;
1136   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1137   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1138
1139   return $search_cvpartnumber;
1140 }
1141
1142 sub init_show_update_button {
1143   my ($self) = @_;
1144
1145   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1146 }
1147
1148 sub init_p {
1149   SL::Presenter->get;
1150 }
1151
1152 sub init_order {
1153   $_[0]->make_order;
1154 }
1155
1156 sub init_all_price_factors {
1157   SL::DB::Manager::PriceFactor->get_all;
1158 }
1159
1160 sub init_part_picker_classification_ids {
1161   my ($self)    = @_;
1162   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1163
1164   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1165 }
1166
1167 sub check_auth {
1168   my ($self) = @_;
1169
1170   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1171
1172   my $right   = $right_for->{ $self->type };
1173   $right    ||= 'DOES_NOT_EXIST';
1174
1175   $::auth->assert($right);
1176 }
1177
1178 # build the selection box for contacts
1179 #
1180 # Needed, if customer/vendor changed.
1181 sub build_contact_select {
1182   my ($self) = @_;
1183
1184   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1185     value_key  => 'cp_id',
1186     title_key  => 'full_name_dep',
1187     default    => $self->order->cp_id,
1188     with_empty => 1,
1189     style      => 'width: 300px',
1190   );
1191 }
1192
1193 # build the selection box for shiptos
1194 #
1195 # Needed, if customer/vendor changed.
1196 sub build_shipto_select {
1197   my ($self) = @_;
1198
1199   select_tag('order.shipto_id',
1200              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1201              value_key  => 'shipto_id',
1202              title_key  => 'displayable_id',
1203              default    => $self->order->shipto_id,
1204              with_empty => 0,
1205              style      => 'width: 300px',
1206   );
1207 }
1208
1209 # build the inputs for the cusom shipto dialog
1210 #
1211 # Needed, if customer/vendor changed.
1212 sub build_shipto_inputs {
1213   my ($self) = @_;
1214
1215   my $content = $self->p->render('common/_ship_to_dialog',
1216                                  vc_obj      => $self->order->customervendor,
1217                                  cs_obj      => $self->order->custom_shipto,
1218                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1219                                  id_selector => '#order_shipto_id');
1220
1221   div_tag($content, id => 'shipto_inputs');
1222 }
1223
1224 # render the info line for business
1225 #
1226 # Needed, if customer/vendor changed.
1227 sub build_business_info_row
1228 {
1229   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1230 }
1231
1232 # build the rows for displaying taxes
1233 #
1234 # Called if amounts where recalculated and redisplayed.
1235 sub build_tax_rows {
1236   my ($self) = @_;
1237
1238   my $rows_as_html;
1239   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1240     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1241   }
1242   return $rows_as_html;
1243 }
1244
1245
1246 sub render_price_dialog {
1247   my ($self, $record_item) = @_;
1248
1249   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1250
1251   $self->js
1252     ->run(
1253       'kivi.io.price_chooser_dialog',
1254       t8('Available Prices'),
1255       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1256     )
1257     ->reinit_widgets;
1258
1259 #   if (@errors) {
1260 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1261 #     $self->js->show('#dialog_flash_error');
1262 #   }
1263
1264   $self->js->render;
1265 }
1266
1267 sub load_order {
1268   my ($self) = @_;
1269
1270   return if !$::form->{id};
1271
1272   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1273
1274   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1275   # You need a custom shipto object to call cvars_by_config to get the cvars.
1276   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1277
1278   return $self->order;
1279 }
1280
1281 # load or create a new order object
1282 #
1283 # And assign changes from the form to this object.
1284 # If the order is loaded from db, check if items are deleted in the form,
1285 # remove them form the object and collect them for removing from db on saving.
1286 # Then create/update items from form (via make_item) and add them.
1287 sub make_order {
1288   my ($self) = @_;
1289
1290   # add_items adds items to an order with no items for saving, but they cannot
1291   # be retrieved via items until the order is saved. Adding empty items to new
1292   # order here solves this problem.
1293   my $order;
1294   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1295   $order ||= SL::DB::Order->new(orderitems  => [],
1296                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1297                                 currency_id => $::instance_conf->get_currency_id(),);
1298
1299   my $cv_id_method = $self->cv . '_id';
1300   if (!$::form->{id} && $::form->{$cv_id_method}) {
1301     $order->$cv_id_method($::form->{$cv_id_method});
1302     setup_order_from_cv($order);
1303   }
1304
1305   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1306   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1307
1308   $order->assign_attributes(%{$::form->{order}});
1309
1310   $self->setup_custom_shipto_from_form($order, $::form);
1311
1312   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1313     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1314     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1315   }
1316
1317   # remove deleted items
1318   $self->item_ids_to_delete([]);
1319   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1320     my $item = $order->orderitems->[$idx];
1321     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1322       splice @{$order->orderitems}, $idx, 1;
1323       push @{$self->item_ids_to_delete}, $item->id;
1324     }
1325   }
1326
1327   my @items;
1328   my $pos = 1;
1329   foreach my $form_attr (@{$form_orderitems}) {
1330     my $item = make_item($order, $form_attr);
1331     $item->position($pos);
1332     push @items, $item;
1333     $pos++;
1334   }
1335   $order->add_items(grep {!$_->id} @items);
1336
1337   return $order;
1338 }
1339
1340 # create or update items from form
1341 #
1342 # Make item objects from form values. For items already existing read from db.
1343 # Create a new item else. And assign attributes.
1344 sub make_item {
1345   my ($record, $attr) = @_;
1346
1347   my $item;
1348   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1349
1350   my $is_new = !$item;
1351
1352   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1353   # they cannot be retrieved via custom_variables until the order/orderitem is
1354   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1355   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1356
1357   $item->assign_attributes(%$attr);
1358
1359   if ($is_new) {
1360     my $texts = get_part_texts($item->part, $record->language_id);
1361     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1362     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1363     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1364   }
1365
1366   return $item;
1367 }
1368
1369 # create a new item
1370 #
1371 # This is used to add one item
1372 sub new_item {
1373   my ($record, $attr) = @_;
1374
1375   my $item = SL::DB::OrderItem->new;
1376
1377   # Remove attributes where the user left or set the inputs empty.
1378   # So these attributes will be undefined and we can distinguish them
1379   # from zero later on.
1380   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1381     delete $attr->{$_} if $attr->{$_} eq '';
1382   }
1383
1384   $item->assign_attributes(%$attr);
1385
1386   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1387   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1388
1389   $item->unit($part->unit) if !$item->unit;
1390
1391   my $price_src;
1392   if ( $part->is_assortment ) {
1393     # add assortment items with price 0, as the components carry the price
1394     $price_src = $price_source->price_from_source("");
1395     $price_src->price(0);
1396   } elsif (defined $item->sellprice) {
1397     $price_src = $price_source->price_from_source("");
1398     $price_src->price($item->sellprice);
1399   } else {
1400     $price_src = $price_source->best_price
1401                ? $price_source->best_price
1402                : $price_source->price_from_source("");
1403     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1404     $price_src->price(0) if !$price_source->best_price;
1405   }
1406
1407   my $discount_src;
1408   if (defined $item->discount) {
1409     $discount_src = $price_source->discount_from_source("");
1410     $discount_src->discount($item->discount);
1411   } else {
1412     $discount_src = $price_source->best_discount
1413                   ? $price_source->best_discount
1414                   : $price_source->discount_from_source("");
1415     $discount_src->discount(0) if !$price_source->best_discount;
1416   }
1417
1418   my %new_attr;
1419   $new_attr{part}                   = $part;
1420   $new_attr{description}            = $part->description     if ! $item->description;
1421   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1422   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1423   $new_attr{sellprice}              = $price_src->price;
1424   $new_attr{discount}               = $discount_src->discount;
1425   $new_attr{active_price_source}    = $price_src;
1426   $new_attr{active_discount_source} = $discount_src;
1427   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1428   $new_attr{project_id}             = $record->globalproject_id;
1429   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1430
1431   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1432   # they cannot be retrieved via custom_variables until the order/orderitem is
1433   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1434   $new_attr{custom_variables} = [];
1435
1436   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1437
1438   $item->assign_attributes(%new_attr, %{ $texts });
1439
1440   return $item;
1441 }
1442
1443 sub setup_order_from_cv {
1444   my ($order) = @_;
1445
1446   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1447
1448   $order->intnotes($order->customervendor->notes);
1449
1450   if ($order->is_sales) {
1451     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1452     $order->taxincluded(defined($order->customer->taxincluded_checked)
1453                         ? $order->customer->taxincluded_checked
1454                         : $::myconfig{taxincluded_checked});
1455   }
1456
1457 }
1458
1459 # setup custom shipto from form
1460 #
1461 # The dialog returns form variables starting with 'shipto' and cvars starting
1462 # with 'shiptocvar_'.
1463 # Mark it to be deleted if a shipto from master data is selected
1464 # (i.e. order has a shipto).
1465 # Else, update or create a new custom shipto. If the fields are empty, it
1466 # will not be saved on save.
1467 sub setup_custom_shipto_from_form {
1468   my ($self, $order, $form) = @_;
1469
1470   if ($order->shipto) {
1471     $self->is_custom_shipto_to_delete(1);
1472   } else {
1473     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1474
1475     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1476     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1477
1478     $custom_shipto->assign_attributes(%$shipto_attrs);
1479     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1480   }
1481 }
1482
1483 # recalculate prices and taxes
1484 #
1485 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1486 sub recalc {
1487   my ($self) = @_;
1488
1489   my %pat = $self->order->calculate_prices_and_taxes();
1490
1491   $self->{taxes} = [];
1492   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1493     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1494
1495     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1496                                 netamount => $netamount,
1497                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1498   }
1499   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1500 }
1501
1502 # get data for saving, printing, ..., that is not changed in the form
1503 #
1504 # Only cvars for now.
1505 sub get_unalterable_data {
1506   my ($self) = @_;
1507
1508   foreach my $item (@{ $self->order->items }) {
1509     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1510     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1511     foreach my $var (@{ $item->cvars_by_config }) {
1512       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1513     }
1514     $item->parse_custom_variable_values;
1515   }
1516 }
1517
1518 # delete the order
1519 #
1520 # And remove related files in the spool directory
1521 sub delete {
1522   my ($self) = @_;
1523
1524   my $errors = [];
1525   my $db     = $self->order->db;
1526
1527   $db->with_transaction(
1528     sub {
1529       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1530       $self->order->delete;
1531       my $spool = $::lx_office_conf{paths}->{spool};
1532       unlink map { "$spool/$_" } @spoolfiles if $spool;
1533
1534       $self->save_history('DELETED');
1535
1536       1;
1537   }) || push(@{$errors}, $db->error);
1538
1539   return $errors;
1540 }
1541
1542 # save the order
1543 #
1544 # And delete items that are deleted in the form.
1545 sub save {
1546   my ($self) = @_;
1547
1548   my $errors = [];
1549   my $db     = $self->order->db;
1550
1551   $db->with_transaction(sub {
1552     # delete custom shipto if it is to be deleted or if it is empty
1553     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1554       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1555       $self->order->custom_shipto(undef);
1556     }
1557
1558     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1559     $self->order->save(cascade => 1);
1560
1561     # link records
1562     if ($::form->{converted_from_oe_id}) {
1563       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1564       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1565         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1566         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1567         $src->link_to_record($self->order);
1568       }
1569       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1570         my $idx = 0;
1571         foreach (@{ $self->order->items_sorted }) {
1572           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1573           next if !$from_id;
1574           SL::DB::RecordLink->new(from_table => 'orderitems',
1575                                   from_id    => $from_id,
1576                                   to_table   => 'orderitems',
1577                                   to_id      => $_->id
1578           )->save;
1579           $idx++;
1580         }
1581       }
1582     }
1583
1584     $self->save_history('SAVED');
1585
1586     1;
1587   }) || push(@{$errors}, $db->error);
1588
1589   return $errors;
1590 }
1591
1592 sub workflow_sales_or_request_for_quotation {
1593   my ($self) = @_;
1594
1595   # always save
1596   my $errors = $self->save();
1597
1598   if (scalar @{ $errors }) {
1599     $self->js->flash('error', $_) for @{ $errors };
1600     return $self->js->render();
1601   }
1602
1603   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1604
1605   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1606   $self->{converted_from_oe_id} = delete $::form->{id};
1607
1608   # set item ids to new fake id, to identify them as new items
1609   foreach my $item (@{$self->order->items_sorted}) {
1610     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1611   }
1612
1613   # change form type
1614   $::form->{type} = $destination_type;
1615   $self->type($self->init_type);
1616   $self->cv  ($self->init_cv);
1617   $self->check_auth;
1618
1619   $self->recalc();
1620   $self->get_unalterable_data();
1621   $self->pre_render();
1622
1623   # trigger rendering values for second row as hidden, because they
1624   # are loaded only on demand. So we need to keep the values from the
1625   # source.
1626   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1627
1628   $self->render(
1629     'order/form',
1630     title => $self->get_title_for('edit'),
1631     %{$self->{template_args}}
1632   );
1633 }
1634
1635 sub workflow_sales_or_purchase_order {
1636   my ($self) = @_;
1637
1638   # always save
1639   my $errors = $self->save();
1640
1641   if (scalar @{ $errors }) {
1642     $self->js->flash('error', $_) foreach @{ $errors };
1643     return $self->js->render();
1644   }
1645
1646   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1647                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1648                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1649                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1650                        : '';
1651
1652   # check for direct delivery
1653   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1654   my $custom_shipto;
1655   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1656       && $::form->{use_shipto} && $self->order->shipto) {
1657     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1658   }
1659
1660   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1661   $self->{converted_from_oe_id} = delete $::form->{id};
1662
1663   # set item ids to new fake id, to identify them as new items
1664   foreach my $item (@{$self->order->items_sorted}) {
1665     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1666   }
1667
1668   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1669     if ($::form->{use_shipto}) {
1670       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1671     } else {
1672       # remove any custom shipto if not wanted
1673       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1674     }
1675   }
1676
1677   # change form type
1678   $::form->{type} = $destination_type;
1679   $self->type($self->init_type);
1680   $self->cv  ($self->init_cv);
1681   $self->check_auth;
1682
1683   $self->recalc();
1684   $self->get_unalterable_data();
1685   $self->pre_render();
1686
1687   # trigger rendering values for second row as hidden, because they
1688   # are loaded only on demand. So we need to keep the values from the
1689   # source.
1690   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1691
1692   $self->render(
1693     'order/form',
1694     title => $self->get_title_for('edit'),
1695     %{$self->{template_args}}
1696   );
1697 }
1698
1699
1700 sub pre_render {
1701   my ($self) = @_;
1702
1703   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1704   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1705   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1706   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1707   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1708                                                                                               deleted => 0 ] ],
1709                                                                            sort_by => 'name');
1710   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1711                                                                                               deleted => 0 ] ],
1712                                                                            sort_by => 'name');
1713   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1714                                                                                                         obsolete => 0 ] ]);
1715   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1716   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1717   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1718   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1719   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1720
1721   my $print_form = Form->new('');
1722   $print_form->{type}        = $self->type;
1723   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1724   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1725     form => $print_form,
1726     options => {dialog_name_prefix => 'print_options.',
1727                 show_headers       => 1,
1728                 no_queue           => 1,
1729                 no_postscript      => 1,
1730                 no_opendocument    => 0,
1731                 no_html            => 1},
1732   );
1733
1734   foreach my $item (@{$self->order->orderitems}) {
1735     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1736     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1737     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1738   }
1739
1740   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1741     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1742     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1743   }
1744
1745   if ($self->order->number && $::instance_conf->get_webdav) {
1746     my $webdav = SL::Webdav->new(
1747       type     => $self->type,
1748       number   => $self->order->number,
1749     );
1750     my @all_objects = $webdav->get_all_objects;
1751     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1752                                                     type => t8('File'),
1753                                                     link => File::Spec->catfile($_->full_filedescriptor),
1754                                                 } } @all_objects;
1755   }
1756
1757   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1758
1759   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1760                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up show_history);
1761   $self->setup_edit_action_bar;
1762 }
1763
1764 sub setup_edit_action_bar {
1765   my ($self, %params) = @_;
1766
1767   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1768                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1769                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1770
1771   for my $bar ($::request->layout->get('actionbar')) {
1772     $bar->add(
1773       combobox => [
1774         action => [
1775           t8('Save'),
1776           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1777                                                     $::instance_conf->get_order_warn_no_deliverydate,
1778                                                                                                       ],
1779           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1780         ],
1781         action => [
1782           t8('Save as new'),
1783           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1784           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1785           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1786         ],
1787       ], # end of combobox "Save"
1788
1789       combobox => [
1790         action => [
1791           t8('Workflow'),
1792         ],
1793         action => [
1794           t8('Save and Quotation'),
1795           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1796           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1797         ],
1798         action => [
1799           t8('Save and RFQ'),
1800           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1801           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1802         ],
1803         action => [
1804           t8('Save and Sales Order'),
1805           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1806           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1807         ],
1808         action => [
1809           t8('Save and Purchase Order'),
1810           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1811           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1812         ],
1813         action => [
1814           t8('Save and Delivery Order'),
1815           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1816                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1817                                                                                                                         ],
1818           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1819           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1820         ],
1821         action => [
1822           t8('Save and Invoice'),
1823           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1824           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1825         ],
1826         action => [
1827           t8('Save and AP Transaction'),
1828           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1829           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1830         ],
1831
1832       ], # end of combobox "Workflow"
1833
1834       combobox => [
1835         action => [
1836           t8('Export'),
1837         ],
1838         action => [
1839           t8('Save and print'),
1840           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1841         ],
1842         action => [
1843           t8('Save and E-mail'),
1844           id   => 'save_and_email_action',
1845           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts ],
1846           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1847         ],
1848         action => [
1849           t8('Download attachments of all parts'),
1850           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1851           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1852           only_if  => $::instance_conf->get_doc_storage,
1853         ],
1854       ], # end of combobox "Export"
1855
1856       action => [
1857         t8('Delete'),
1858         call     => [ 'kivi.Order.delete_order' ],
1859         confirm  => $::locale->text('Do you really want to delete this object?'),
1860         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1861         only_if  => $deletion_allowed,
1862       ],
1863
1864       combobox => [
1865         action => [
1866           t8('more')
1867         ],
1868         action => [
1869           t8('Follow-Up'),
1870           call     => [ 'kivi.Order.follow_up_window' ],
1871           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1872           only_if  => $::auth->assert('productivity', 1),
1873         ],
1874         action => [
1875           t8('History'),
1876           call     => [ 'set_history_window', $self->order->id, 'id' ],
1877           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
1878         ],
1879       ], # end of combobox "more"
1880     );
1881   }
1882 }
1883
1884 sub generate_pdf {
1885   my ($order, $pdf_ref, $params) = @_;
1886
1887   my @errors = ();
1888
1889   my $print_form = Form->new('');
1890   $print_form->{type}        = $order->type;
1891   $print_form->{formname}    = $params->{formname} || $order->type;
1892   $print_form->{format}      = $params->{format}   || 'pdf';
1893   $print_form->{media}       = $params->{media}    || 'file';
1894   $print_form->{groupitems}  = $params->{groupitems};
1895   $print_form->{printer_id}  = $params->{printer_id};
1896   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1897
1898   $order->language($params->{language});
1899   $order->flatten_to_form($print_form, format_amounts => 1);
1900
1901   my $template_ext;
1902   my $template_type;
1903   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1904     $template_ext  = 'odt';
1905     $template_type = 'OpenDocument';
1906   }
1907
1908   # search for the template
1909   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1910     name        => $print_form->{formname},
1911     extension   => $template_ext,
1912     email       => $print_form->{media} eq 'email',
1913     language    => $params->{language},
1914     printer_id  => $print_form->{printer_id},
1915   );
1916
1917   if (!defined $template_file) {
1918     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1919   }
1920
1921   return @errors if scalar @errors;
1922
1923   $print_form->throw_on_error(sub {
1924     eval {
1925       $print_form->prepare_for_printing;
1926
1927       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1928         format        => $print_form->{format},
1929         template_type => $template_type,
1930         template      => $template_file,
1931         variables     => $print_form,
1932         variable_content_types => {
1933           longdescription => 'html',
1934           partnotes       => 'html',
1935           notes           => 'html',
1936         },
1937       );
1938       1;
1939     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1940   });
1941
1942   return @errors;
1943 }
1944
1945 sub get_files_for_email_dialog {
1946   my ($self) = @_;
1947
1948   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1949
1950   return %files if !$::instance_conf->get_doc_storage;
1951
1952   if ($self->order->id) {
1953     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1954     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1955     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1956   }
1957
1958   my @parts =
1959     uniq_by { $_->{id} }
1960     map {
1961       +{ id         => $_->part->id,
1962          partnumber => $_->part->partnumber }
1963     } @{$self->order->items_sorted};
1964
1965   foreach my $part (@parts) {
1966     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1967     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1968   }
1969
1970   foreach my $key (keys %files) {
1971     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1972   }
1973
1974   return %files;
1975 }
1976
1977 sub make_periodic_invoices_config_from_yaml {
1978   my ($yaml_config) = @_;
1979
1980   return if !$yaml_config;
1981   my $attr = SL::YAML::Load($yaml_config);
1982   return if 'HASH' ne ref $attr;
1983   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1984 }
1985
1986
1987 sub get_periodic_invoices_status {
1988   my ($self, $config) = @_;
1989
1990   return                      if $self->type ne sales_order_type();
1991   return t8('not configured') if !$config;
1992
1993   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1994              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1995              :                                                     die "Cannot get status of periodic invoices config";
1996
1997   return $active ? t8('active') : t8('inactive');
1998 }
1999
2000 sub get_title_for {
2001   my ($self, $action) = @_;
2002
2003   return '' if none { lc($action)} qw(add edit);
2004
2005   # for locales:
2006   # $::locale->text("Add Sales Order");
2007   # $::locale->text("Add Purchase Order");
2008   # $::locale->text("Add Quotation");
2009   # $::locale->text("Add Request for Quotation");
2010   # $::locale->text("Edit Sales Order");
2011   # $::locale->text("Edit Purchase Order");
2012   # $::locale->text("Edit Quotation");
2013   # $::locale->text("Edit Request for Quotation");
2014
2015   $action = ucfirst(lc($action));
2016   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2017        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2018        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2019        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2020        : '';
2021 }
2022
2023 sub get_item_cvpartnumber {
2024   my ($self, $item) = @_;
2025
2026   return if !$self->search_cvpartnumber;
2027   return if !$self->order->customervendor;
2028
2029   if ($self->cv eq 'vendor') {
2030     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2031     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2032   } elsif ($self->cv eq 'customer') {
2033     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2034     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2035   }
2036 }
2037
2038 sub get_part_texts {
2039   my ($part_or_id, $language_or_id, %defaults) = @_;
2040
2041   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2042   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2043   my $texts       = {
2044     description     => $defaults{description}     // $part->description,
2045     longdescription => $defaults{longdescription} // $part->notes,
2046   };
2047
2048   return $texts unless $language_id;
2049
2050   my $translation = SL::DB::Manager::Translation->get_first(
2051     where => [
2052       parts_id    => $part->id,
2053       language_id => $language_id,
2054     ]);
2055
2056   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2057   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2058
2059   return $texts;
2060 }
2061
2062 sub sales_order_type {
2063   'sales_order';
2064 }
2065
2066 sub purchase_order_type {
2067   'purchase_order';
2068 }
2069
2070 sub sales_quotation_type {
2071   'sales_quotation';
2072 }
2073
2074 sub request_quotation_type {
2075   'request_quotation';
2076 }
2077
2078 sub nr_key {
2079   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2080        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2081        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2082        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2083        : '';
2084 }
2085
2086 sub save_and_redirect_to {
2087   my ($self, %params) = @_;
2088
2089   my $errors = $self->save();
2090
2091   if (scalar @{ $errors }) {
2092     $self->js->flash('error', $_) foreach @{ $errors };
2093     return $self->js->render();
2094   }
2095
2096   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2097            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2098            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2099            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2100            : '';
2101   flash_later('info', $text);
2102
2103   $self->redirect_to(%params, id => $self->order->id);
2104 }
2105
2106 sub save_history {
2107   my ($self, $addition) = @_;
2108
2109   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2110   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2111
2112   SL::DB::History->new(
2113     trans_id    => $self->order->id,
2114     employee_id => SL::DB::Manager::Employee->current->id,
2115     what_done   => $self->order->type,
2116     snumbers    => $snumbers,
2117     addition    => $addition,
2118   )->save;
2119 }
2120
2121 sub store_pdf_to_webdav_and_filemanegement {
2122   my($order, $content, $filename) = @_;
2123
2124   my @errors;
2125
2126   # copy file to webdav folder
2127   if ($order->number && $::instance_conf->get_webdav_documents) {
2128     my $webdav = SL::Webdav->new(
2129       type     => $order->type,
2130       number   => $order->number,
2131     );
2132     my $webdav_file = SL::Webdav::File->new(
2133       webdav   => $webdav,
2134       filename => $filename,
2135     );
2136     eval {
2137       $webdav_file->store(data => \$content);
2138       1;
2139     } or do {
2140       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2141     };
2142   }
2143   if ($order->id && $::instance_conf->get_doc_storage) {
2144     eval {
2145       SL::File->save(object_id     => $order->id,
2146                      object_type   => $order->type,
2147                      mime_type     => 'application/pdf',
2148                      source        => 'created',
2149                      file_type     => 'document',
2150                      file_name     => $filename,
2151                      file_contents => $content);
2152       1;
2153     } or do {
2154       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2155     };
2156   }
2157
2158   return @errors;
2159 }
2160
2161 1;
2162
2163 __END__
2164
2165 =encoding utf-8
2166
2167 =head1 NAME
2168
2169 SL::Controller::Order - controller for orders
2170
2171 =head1 SYNOPSIS
2172
2173 This is a new form to enter orders, completely rewritten with the use
2174 of controller and java script techniques.
2175
2176 The aim is to provide the user a better experience and a faster workflow. Also
2177 the code should be more readable, more reliable and better to maintain.
2178
2179 =head2 Key Features
2180
2181 =over 4
2182
2183 =item *
2184
2185 One input row, so that input happens every time at the same place.
2186
2187 =item *
2188
2189 Use of pickers where possible.
2190
2191 =item *
2192
2193 Possibility to enter more than one item at once.
2194
2195 =item *
2196
2197 Item list in a scrollable area, so that the workflow buttons stay at
2198 the bottom.
2199
2200 =item *
2201
2202 Reordering item rows with drag and drop is possible. Sorting item rows is
2203 possible (by partnumber, description, qty, sellprice and discount for now).
2204
2205 =item *
2206
2207 No C<update> is necessary. All entries and calculations are managed
2208 with ajax-calls and the page only reloads on C<save>.
2209
2210 =item *
2211
2212 User can see changes immediately, because of the use of java script
2213 and ajax.
2214
2215 =back
2216
2217 =head1 CODE
2218
2219 =head2 Layout
2220
2221 =over 4
2222
2223 =item * C<SL/Controller/Order.pm>
2224
2225 the controller
2226
2227 =item * C<template/webpages/order/form.html>
2228
2229 main form
2230
2231 =item * C<template/webpages/order/tabs/basic_data.html>
2232
2233 Main tab for basic_data.
2234
2235 This is the only tab here for now. "linked records" and "webdav" tabs are
2236 reused from generic code.
2237
2238 =over 4
2239
2240 =item * C<template/webpages/order/tabs/_business_info_row.html>
2241
2242 For displaying information on business type
2243
2244 =item * C<template/webpages/order/tabs/_item_input.html>
2245
2246 The input line for items
2247
2248 =item * C<template/webpages/order/tabs/_row.html>
2249
2250 One row for already entered items
2251
2252 =item * C<template/webpages/order/tabs/_tax_row.html>
2253
2254 Displaying tax information
2255
2256 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2257
2258 Dialog for selecting price and discount sources
2259
2260 =back
2261
2262 =item * C<js/kivi.Order.js>
2263
2264 java script functions
2265
2266 =back
2267
2268 =head1 TODO
2269
2270 =over 4
2271
2272 =item * testing
2273
2274 =item * price sources: little symbols showing better price / better discount
2275
2276 =item * select units in input row?
2277
2278 =item * check for direct delivery (workflow sales order -> purchase order)
2279
2280 =item * access rights
2281
2282 =item * display weights
2283
2284 =item * mtime check
2285
2286 =item * optional client/user behaviour
2287
2288 (transactions has to be set - department has to be set -
2289  force project if enabled in client config - transport cost reminder)
2290
2291 =back
2292
2293 =head1 KNOWN BUGS AND CAVEATS
2294
2295 =over 4
2296
2297 =item *
2298
2299 Customer discount is not displayed as a valid discount in price source popup
2300 (this might be a bug in price sources)
2301
2302 (I cannot reproduce this (Bernd))
2303
2304 =item *
2305
2306 No indication that <shift>-up/down expands/collapses second row.
2307
2308 =item *
2309
2310 Inline creation of parts is not currently supported
2311
2312 =item *
2313
2314 Table header is not sticky in the scrolling area.
2315
2316 =item *
2317
2318 Sorting does not include C<position>, neither does reordering.
2319
2320 This behavior was implemented intentionally. But we can discuss, which behavior
2321 should be implemented.
2322
2323 =back
2324
2325 =head1 To discuss / Nice to have
2326
2327 =over 4
2328
2329 =item *
2330
2331 How to expand/collapse second row. Now it can be done clicking the icon or
2332 <shift>-up/down.
2333
2334 =item *
2335
2336 Possibility to select PriceSources in input row?
2337
2338 =item *
2339
2340 This controller uses a (changed) copy of the template for the PriceSource
2341 dialog. Maybe there could be used one code source.
2342
2343 =item *
2344
2345 Rounding-differences between this controller (PriceTaxCalculator) and the old
2346 form. This is not only a problem here, but also in all parts using the PTC.
2347 There exists a ticket and a patch. This patch should be testet.
2348
2349 =item *
2350
2351 An indicator, if the actual inputs are saved (like in an
2352 editor or on text processing application).
2353
2354 =item *
2355
2356 A warning when leaving the page without saveing unchanged inputs.
2357
2358
2359 =back
2360
2361 =head1 AUTHOR
2362
2363 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2364
2365 =cut