SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::AdditionalBillingAddress;
  17 use SL::DB::History;
  18 use SL::DB::Order;
  19 use SL::DB::Default;
  20 use SL::DB::Unit;
  21 use SL::DB::Part;
  22 use SL::DB::PartClassification;
  23 use SL::DB::PartsGroup;
  24 use SL::DB::Printer;
  25 use SL::DB::Language;
  26 use SL::DB::RecordLink;
  27 use SL::DB::RequirementSpec;
  28 use SL::DB::Shipto;
  29 use SL::DB::Translation;
  30
  31 use SL::Helper::CreatePDF qw(:all);
  32 use SL::Helper::PrintOptions;
  33 use SL::Helper::ShippedQty;
  34 use SL::Helper::UserPreferences::PositionsScrollbar;
  35 use SL::Helper::UserPreferences::UpdatePositions;
  36
  37 use SL::Controller::Helper::GetModels;
  38
  39 use List::Util qw(first sum0);
  40 use List::UtilsBy qw(sort_by uniq_by);
  41 use List::MoreUtils qw(any none pairwise first_index);
  42 use English qw(-no_match_vars);
  43 use File::Spec;
  44 use Cwd;
  45 use Sort::Naturally;
  46
  47 use Rose::Object::MakeMethods::Generic
  48 (
  49  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  50  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  51 );
  52
  53
  54 # safety
  55 __PACKAGE__->run_before('check_auth');
  56
  57 __PACKAGE__->run_before('recalc',
  58                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  59                                      print send_email) ]);
  60
  61 __PACKAGE__->run_before('get_unalterable_data',
  62                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  63                                      print send_email) ]);
  64
  65 #
  66 # actions
  67 #
  68
  69 # add a new order
  70 sub action_add {
  71   my ($self) = @_;
  72
  73   $self->order->transdate(DateTime->now_local());
  74   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  75                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  76
  77   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  78       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  79       && (!$self->order->reqdate)) {
  80     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  81   }
  82
  83
  84   $self->pre_render();
  85   $self->render(
  86     'order/form',
  87     title => $self->get_title_for('add'),
  88     %{$self->{template_args}}
  89   );
  90 }
  91
  92 # edit an existing order
  93 sub action_edit {
  94   my ($self) = @_;
  95
  96   if ($::form->{id}) {
  97     $self->load_order;
  98
  99   } else {
 100     # this is to edit an order from an unsaved order object
 101
 102     # set item ids to new fake id, to identify them as new items
 103     foreach my $item (@{$self->order->items_sorted}) {
 104       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 105     }
 106     # trigger rendering values for second row as hidden, because they
 107     # are loaded only on demand. So we need to keep the values from
 108     # the source.
 109     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 110   }
 111
 112   $self->recalc();
 113   $self->pre_render();
 114   $self->render(
 115     'order/form',
 116     title => $self->get_title_for('edit'),
 117     %{$self->{template_args}}
 118   );
 119 }
 120
 121 # edit a collective order (consisting of one or more existing orders)
 122 sub action_edit_collective {
 123   my ($self) = @_;
 124
 125   # collect order ids
 126   my @multi_ids = map {
 127     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 128   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 129
 130   # fall back to add if no ids are given
 131   if (scalar @multi_ids == 0) {
 132     $self->action_add();
 133     return;
 134   }
 135
 136   # fall back to save as new if only one id is given
 137   if (scalar @multi_ids == 1) {
 138     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 139     $self->action_save_as_new();
 140     return;
 141   }
 142
 143   # make new order from given orders
 144   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 145   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 146   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 147
 148   $self->action_edit();
 149 }
 150
 151 # delete the order
 152 sub action_delete {
 153   my ($self) = @_;
 154
 155   my $errors = $self->delete();
 156
 157   if (scalar @{ $errors }) {
 158     $self->js->flash('error', $_) foreach @{ $errors };
 159     return $self->js->render();
 160   }
 161
 162   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 163            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 164            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 165            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 166            : '';
 167   flash_later('info', $text);
 168
 169   my @redirect_params = (
 170     action => 'add',
 171     type   => $self->type,
 172   );
 173
 174   $self->redirect_to(@redirect_params);
 175 }
 176
 177 # save the order
 178 sub action_save {
 179   my ($self) = @_;
 180
 181   my $errors = $self->save();
 182
 183   if (scalar @{ $errors }) {
 184     $self->js->flash('error', $_) foreach @{ $errors };
 185     return $self->js->render();
 186   }
 187
 188   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 189            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 190            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 191            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 192            : '';
 193   flash_later('info', $text);
 194
 195   my @redirect_params = (
 196     action => 'edit',
 197     type   => $self->type,
 198     id     => $self->order->id,
 199   );
 200
 201   $self->redirect_to(@redirect_params);
 202 }
 203
 204 # save the order as new document an open it for edit
 205 sub action_save_as_new {
 206   my ($self) = @_;
 207
 208   my $order = $self->order;
 209
 210   if (!$order->id) {
 211     $self->js->flash('error', t8('This object has not been saved yet.'));
 212     return $self->js->render();
 213   }
 214
 215   # load order from db to check if values changed
 216   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 217
 218   my %new_attrs;
 219   # Lets assign a new number if the user hasn't changed the previous one.
 220   # If it has been changed manually then use it as-is.
 221   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 222                         ? ''
 223                         : trim($order->number);
 224
 225   # Clear transdate unless changed
 226   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 227                         ? DateTime->today_local
 228                         : $order->transdate;
 229
 230   # Set new reqdate unless changed if it is enabled in client config
 231   if ($order->reqdate == $saved_order->reqdate) {
 232     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 233                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 234
 235     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 236         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 237       $new_attrs{reqdate} = '';
 238     } else {
 239       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 240     }
 241   } else {
 242     $new_attrs{reqdate} = $order->reqdate;
 243   }
 244
 245   # Update employee
 246   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 247
 248   # Create new record from current one
 249   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 250
 251   # no linked records on save as new
 252   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 253
 254   # save
 255   $self->action_save();
 256 }
 257
 258 # print the order
 259 #
 260 # This is called if "print" is pressed in the print dialog.
 261 # If PDF creation was requested and succeeded, the pdf is offered for download
 262 # via send_file (which uses ajax in this case).
 263 sub action_print {
 264   my ($self) = @_;
 265
 266   my $errors = $self->save();
 267
 268   if (scalar @{ $errors }) {
 269     $self->js->flash('error', $_) foreach @{ $errors };
 270     return $self->js->render();
 271   }
 272
 273   $self->js_reset_order_and_item_ids_after_save;
 274
 275   my $format      = $::form->{print_options}->{format};
 276   my $media       = $::form->{print_options}->{media};
 277   my $formname    = $::form->{print_options}->{formname};
 278   my $copies      = $::form->{print_options}->{copies};
 279   my $groupitems  = $::form->{print_options}->{groupitems};
 280   my $printer_id  = $::form->{print_options}->{printer_id};
 281
 282   # only pdf and opendocument by now
 283   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 284     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 285   }
 286
 287   # only screen or printer by now
 288   if (none { $media eq $_ } qw(screen printer)) {
 289     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 290   }
 291
 292   # create a form for generate_attachment_filename
 293   my $form   = Form->new;
 294   $form->{$self->nr_key()}  = $self->order->number;
 295   $form->{type}             = $self->type;
 296   $form->{format}           = $format;
 297   $form->{formname}         = $formname;
 298   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 299   my $pdf_filename          = $form->generate_attachment_filename();
 300
 301   my $pdf;
 302   my @errors = $self->generate_pdf(\$pdf, { format     => $format,
 303                                             formname   => $formname,
 304                                             language   => $self->order->language,
 305                                             printer_id => $printer_id,
 306                                             groupitems => $groupitems });
 307   if (scalar @errors) {
 308     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 309   }
 310
 311   if ($media eq 'screen') {
 312     # screen/download
 313     $self->js->flash('info', t8('The PDF has been created'));
 314     $self->send_file(
 315       \$pdf,
 316       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 317       name         => $pdf_filename,
 318       js_no_render => 1,
 319     );
 320
 321   } elsif ($media eq 'printer') {
 322     # printer
 323     my $printer_id = $::form->{print_options}->{printer_id};
 324     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 325       copies  => $copies,
 326       content => $pdf,
 327     );
 328
 329     $self->js->flash('info', t8('The PDF has been printed'));
 330   }
 331
 332   my @warnings = $self->store_pdf_to_webdav_and_filemanagement($pdf, $pdf_filename);
 333   if (scalar @warnings) {
 334     $self->js->flash('warning', $_) for @warnings;
 335   }
 336
 337   $self->save_history('PRINTED');
 338
 339   $self->js
 340     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 341     ->render;
 342 }
 343 sub action_preview_pdf {
 344   my ($self) = @_;
 345
 346   my $errors = $self->save();
 347   if (scalar @{ $errors }) {
 348     $self->js->flash('error', $_) foreach @{ $errors };
 349     return $self->js->render();
 350   }
 351
 352   $self->js_reset_order_and_item_ids_after_save;
 353
 354   my $format      = 'pdf';
 355   my $media       = 'screen';
 356   my $formname    = $self->type;
 357
 358   # only pdf
 359   # create a form for generate_attachment_filename
 360   my $form   = Form->new;
 361   $form->{$self->nr_key()}  = $self->order->number;
 362   $form->{type}             = $self->type;
 363   $form->{format}           = $format;
 364   $form->{formname}         = $formname;
 365   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 366   my $pdf_filename          = $form->generate_attachment_filename();
 367
 368   my $pdf;
 369   my @errors = $self->generate_pdf(\$pdf, { format     => $format,
 370                                             formname   => $formname,
 371                                             language   => $self->order->language,
 372                                           });
 373   if (scalar @errors) {
 374     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 375   }
 376   $self->save_history('PREVIEWED');
 377   $self->js->flash('info', t8('The PDF has been previewed'));
 378   # screen/download
 379   $self->send_file(
 380     \$pdf,
 381     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 382     name         => $pdf_filename,
 383     js_no_render => 0,
 384   );
 385 }
 386
 387 # open the email dialog
 388 sub action_save_and_show_email_dialog {
 389   my ($self) = @_;
 390
 391   my $errors = $self->save();
 392
 393   if (scalar @{ $errors }) {
 394     $self->js->flash('error', $_) foreach @{ $errors };
 395     return $self->js->render();
 396   }
 397
 398   my $cv_method = $self->cv;
 399
 400   if (!$self->order->$cv_method) {
 401     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 402                     ->render($self);
 403   }
 404
 405   my $email_form;
 406   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 407   $email_form->{to} ||= $self->order->$cv_method->email;
 408   $email_form->{cc}   = $self->order->$cv_method->cc;
 409   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 410   # Todo: get addresses from shipto, if any
 411
 412   my $form = Form->new;
 413   $form->{$self->nr_key()}  = $self->order->number;
 414   $form->{cusordnumber}     = $self->order->cusordnumber;
 415   $form->{formname}         = $self->type;
 416   $form->{type}             = $self->type;
 417   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 418   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 419   $form->{format}           = 'pdf';
 420   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 421
 422   $email_form->{subject}             = $form->generate_email_subject();
 423   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 424   $email_form->{message}             = $form->generate_email_body();
 425   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 426
 427   my %files = $self->get_files_for_email_dialog();
 428   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 429   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 430                                   email_form  => $email_form,
 431                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 432                                   FILES       => \%files,
 433                                   is_customer => $self->cv eq 'customer',
 434                                   ALL_EMPLOYEES => $self->{all_employees},
 435   );
 436
 437   $self->js
 438       ->run('kivi.Order.show_email_dialog', $dialog_html)
 439       ->reinit_widgets
 440       ->render($self);
 441 }
 442
 443 # send email
 444 #
 445 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 446 sub action_send_email {
 447   my ($self) = @_;
 448
 449   my $errors = $self->save();
 450
 451   if (scalar @{ $errors }) {
 452     $self->js->run('kivi.Order.close_email_dialog');
 453     $self->js->flash('error', $_) foreach @{ $errors };
 454     return $self->js->render();
 455   }
 456
 457   $self->js_reset_order_and_item_ids_after_save;
 458
 459   my $email_form  = delete $::form->{email_form};
 460   my %field_names = (to => 'email');
 461
 462   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 463
 464   # for Form::cleanup which may be called in Form::send_email
 465   $::form->{cwd}    = getcwd();
 466   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 467
 468   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 469   $::form->{media}  = 'email';
 470
 471   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 472     my $pdf;
 473     my @errors = $self->generate_pdf(\$pdf, {media      => $::form->{media},
 474                                             format     => $::form->{print_options}->{format},
 475                                             formname   => $::form->{print_options}->{formname},
 476                                             language   => $self->order->language,
 477                                             printer_id => $::form->{print_options}->{printer_id},
 478                                             groupitems => $::form->{print_options}->{groupitems}});
 479     if (scalar @errors) {
 480       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 481     }
 482
 483     my @warnings = $self->store_pdf_to_webdav_and_filemanagement($pdf, $::form->{attachment_filename});
 484     if (scalar @warnings) {
 485       flash_later('warning', $_) for @warnings;
 486     }
 487
 488     my $sfile = SL::SessionFile::Random->new(mode => "w");
 489     $sfile->fh->print($pdf);
 490     $sfile->fh->close;
 491
 492     $::form->{tmpfile} = $sfile->file_name;
 493     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 494   }
 495
 496   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 497   $::form->send_email(\%::myconfig, 'pdf');
 498
 499   # internal notes
 500   my $intnotes = $self->order->intnotes;
 501   $intnotes   .= "\n\n" if $self->order->intnotes;
 502   $intnotes   .= t8('[email]')                                                                                        . "\n";
 503   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 504   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 505   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 506   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 507   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 508   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 509
 510   $self->order->update_attributes(intnotes => $intnotes);
 511
 512   $self->save_history('MAILED');
 513
 514   flash_later('info', t8('The email has been sent.'));
 515
 516   my @redirect_params = (
 517     action => 'edit',
 518     type   => $self->type,
 519     id     => $self->order->id,
 520   );
 521
 522   $self->redirect_to(@redirect_params);
 523 }
 524
 525 # open the periodic invoices config dialog
 526 #
 527 # If there are values in the form (i.e. dialog was opened before),
 528 # then use this values. Create new ones, else.
 529 sub action_show_periodic_invoices_config_dialog {
 530   my ($self) = @_;
 531
 532   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 533   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 534   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 535                                                    order_value_periodicity => 'p', # = same as periodicity
 536                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 537                                                    extend_automatically_by => 12,
 538                                                    active                  => 1,
 539                                                    email_subject           => GenericTranslations->get(
 540                                                                                 language_id      => $::form->{language_id},
 541                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 542                                                    email_body              => GenericTranslations->get(
 543                                                                                 language_id      => $::form->{language_id},
 544                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 545   );
 546   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 547   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 548
 549   $::form->get_lists(printers => "ALL_PRINTERS",
 550                      charts   => { key       => 'ALL_CHARTS',
 551                                    transdate => 'current_date' });
 552
 553   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 554
 555   if ($::form->{customer_id}) {
 556     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 557     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 558     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 559     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 560     $config->send_email(0) if $::form->{postal_invoice};
 561   }
 562
 563   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 564                 popup_dialog             => 1,
 565                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 566                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 567                 config                   => $config,
 568                 %$::form);
 569 }
 570
 571 # assign the values of the periodic invoices config dialog
 572 # as yaml in the hidden tag and set the status.
 573 sub action_assign_periodic_invoices_config {
 574   my ($self) = @_;
 575
 576   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 577
 578   my $config = { active                     => $::form->{active}       ? 1 : 0,
 579                  terminated                 => $::form->{terminated}   ? 1 : 0,
 580                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 581                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 582                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 583                  start_date_as_date         => $::form->{start_date_as_date},
 584                  end_date_as_date           => $::form->{end_date_as_date},
 585                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 586                  print                      => $::form->{print}      ? 1                         : 0,
 587                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 588                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 589                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 590                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 591                  send_email                 => $::form->{send_email} ? 1 : 0,
 592                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 593                  email_recipient_address    => $::form->{email_recipient_address},
 594                  email_sender               => $::form->{email_sender},
 595                  email_subject              => $::form->{email_subject},
 596                  email_body                 => $::form->{email_body},
 597                };
 598
 599   my $periodic_invoices_config = SL::YAML::Dump($config);
 600
 601   my $status = $self->get_periodic_invoices_status($config);
 602
 603   $self->js
 604     ->remove('#order_periodic_invoices_config')
 605     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 606     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 607     ->html('#periodic_invoices_status', $status)
 608     ->flash('info', t8('The periodic invoices config has been assigned.'))
 609     ->render($self);
 610 }
 611
 612 sub action_get_has_active_periodic_invoices {
 613   my ($self) = @_;
 614
 615   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 616   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 617
 618   my $has_active_periodic_invoices =
 619        $self->type eq sales_order_type()
 620     && $config
 621     && $config->active
 622     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 623     && $config->get_previous_billed_period_start_date;
 624
 625   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 626 }
 627
 628 # save the order and redirect to the frontend subroutine for a new
 629 # delivery order
 630 sub action_save_and_delivery_order {
 631   my ($self) = @_;
 632
 633   $self->save_and_redirect_to(
 634     controller => 'oe.pl',
 635     action     => 'oe_delivery_order_from_order',
 636   );
 637 }
 638
 639 # save the order and redirect to the frontend subroutine for a new
 640 # invoice
 641 sub action_save_and_invoice {
 642   my ($self) = @_;
 643
 644   $self->save_and_redirect_to(
 645     controller => 'oe.pl',
 646     action     => 'oe_invoice_from_order',
 647   );
 648 }
 649
 650 # workflow from sales order to sales quotation
 651 sub action_sales_quotation {
 652   $_[0]->workflow_sales_or_request_for_quotation();
 653 }
 654
 655 # workflow from sales order to sales quotation
 656 sub action_request_for_quotation {
 657   $_[0]->workflow_sales_or_request_for_quotation();
 658 }
 659
 660 # workflow from sales quotation to sales order
 661 sub action_sales_order {
 662   $_[0]->workflow_sales_or_purchase_order();
 663 }
 664
 665 # workflow from rfq to purchase order
 666 sub action_purchase_order {
 667   $_[0]->workflow_sales_or_purchase_order();
 668 }
 669
 670 # workflow from purchase order to ap transaction
 671 sub action_save_and_ap_transaction {
 672   my ($self) = @_;
 673
 674   $self->save_and_redirect_to(
 675     controller => 'ap.pl',
 676     action     => 'add_from_purchase_order',
 677   );
 678 }
 679
 680 # set form elements in respect to a changed customer or vendor
 681 #
 682 # This action is called on an change of the customer/vendor picker.
 683 sub action_customer_vendor_changed {
 684   my ($self) = @_;
 685
 686   setup_order_from_cv($self->order);
 687   $self->recalc();
 688
 689   my $cv_method = $self->cv;
 690
 691   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 692     $self->js->show('#cp_row');
 693   } else {
 694     $self->js->hide('#cp_row');
 695   }
 696
 697   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 698     $self->js->show('#shipto_selection');
 699   } else {
 700     $self->js->hide('#shipto_selection');
 701   }
 702
 703   if ($cv_method eq 'customer') {
 704     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 705     $self->js->$show_hide('#billing_address_row');
 706   }
 707
 708   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 709
 710   $self->js
 711     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 712     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 713     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 714     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 715     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 716     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 717     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 718     ->val(        '#order_currency_id',        $self->order->currency_id)
 719     ->val(        '#order_payment_id',         $self->order->payment_id)
 720     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 721     ->val(        '#order_intnotes',           $self->order->intnotes)
 722     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 723     ->focus(      '#order_' . $self->cv . '_id')
 724     ->run('kivi.Order.update_exchangerate');
 725
 726   $self->js_redisplay_amounts_and_taxes;
 727   $self->js_redisplay_cvpartnumbers;
 728   $self->js->render();
 729 }
 730
 731 # open the dialog for customer/vendor details
 732 sub action_show_customer_vendor_details_dialog {
 733   my ($self) = @_;
 734
 735   my $is_customer = 'customer' eq $::form->{vc};
 736   my $cv;
 737   if ($is_customer) {
 738     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 739   } else {
 740     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 741   }
 742
 743   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 744   $details{discount_as_percent} = $cv->discount_as_percent;
 745   $details{creditlimt}          = $cv->creditlimit_as_number;
 746   $details{business}            = $cv->business->description      if $cv->business;
 747   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 748   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 749   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 750   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 751
 752   foreach my $entry (@{ $cv->additional_billing_addresses }) {
 753     push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 754   }
 755   foreach my $entry (@{ $cv->shipto }) {
 756     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 757   }
 758   foreach my $entry (@{ $cv->contacts }) {
 759     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 760   }
 761
 762   $_[0]->render('common/show_vc_details', { layout => 0 },
 763                 is_customer => $is_customer,
 764                 %details);
 765
 766 }
 767
 768 # called if a unit in an existing item row is changed
 769 sub action_unit_changed {
 770   my ($self) = @_;
 771
 772   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 773   my $item = $self->order->items_sorted->[$idx];
 774
 775   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 776   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 777
 778   $self->recalc();
 779
 780   $self->js
 781     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 782   $self->js_redisplay_line_values;
 783   $self->js_redisplay_amounts_and_taxes;
 784   $self->js->render();
 785 }
 786
 787 # add an item row for a new item entered in the input row
 788 sub action_add_item {
 789   my ($self) = @_;
 790
 791   delete $::form->{add_item}->{create_part_type};
 792
 793   my $form_attr = $::form->{add_item};
 794
 795   return unless $form_attr->{parts_id};
 796
 797   my $item = new_item($self->order, $form_attr);
 798
 799   $self->order->add_items($item);
 800
 801   $self->recalc();
 802
 803   $self->get_item_cvpartnumber($item);
 804
 805   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 806   my $row_as_html = $self->p->render('order/tabs/_row',
 807                                      ITEM => $item,
 808                                      ID   => $item_id,
 809                                      SELF => $self,
 810   );
 811
 812   if ($::form->{insert_before_item_id}) {
 813     $self->js
 814       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 815   } else {
 816     $self->js
 817       ->append('#row_table_id', $row_as_html);
 818   }
 819
 820   if ( $item->part->is_assortment ) {
 821     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 822     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 823       my $attr = { parts_id => $assortment_item->parts_id,
 824                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 825                    unit     => $assortment_item->unit,
 826                    description => $assortment_item->part->description,
 827                  };
 828       my $item = new_item($self->order, $attr);
 829
 830       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 831       $item->discount(1) unless $assortment_item->charge;
 832
 833       $self->order->add_items( $item );
 834       $self->recalc();
 835       $self->get_item_cvpartnumber($item);
 836       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 837       my $row_as_html = $self->p->render('order/tabs/_row',
 838                                          ITEM => $item,
 839                                          ID   => $item_id,
 840                                          SELF => $self,
 841       );
 842       if ($::form->{insert_before_item_id}) {
 843         $self->js
 844           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 845       } else {
 846         $self->js
 847           ->append('#row_table_id', $row_as_html);
 848       }
 849     };
 850   };
 851
 852   $self->js
 853     ->val('.add_item_input', '')
 854     ->run('kivi.Order.init_row_handlers')
 855     ->run('kivi.Order.renumber_positions')
 856     ->focus('#add_item_parts_id_name');
 857
 858   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 859
 860   $self->js_redisplay_amounts_and_taxes;
 861   $self->js->render();
 862 }
 863
 864 # add item rows for multiple items at once
 865 sub action_add_multi_items {
 866   my ($self) = @_;
 867
 868   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 869   return $self->js->render() unless scalar @form_attr;
 870
 871   my @items;
 872   foreach my $attr (@form_attr) {
 873     my $item = new_item($self->order, $attr);
 874     push @items, $item;
 875     if ( $item->part->is_assortment ) {
 876       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 877         my $attr = { parts_id => $assortment_item->parts_id,
 878                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 879                      unit     => $assortment_item->unit,
 880                      description => $assortment_item->part->description,
 881                    };
 882         my $item = new_item($self->order, $attr);
 883
 884         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 885         $item->discount(1) unless $assortment_item->charge;
 886         push @items, $item;
 887       }
 888     }
 889   }
 890   $self->order->add_items(@items);
 891
 892   $self->recalc();
 893
 894   foreach my $item (@items) {
 895     $self->get_item_cvpartnumber($item);
 896     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 897     my $row_as_html = $self->p->render('order/tabs/_row',
 898                                        ITEM => $item,
 899                                        ID   => $item_id,
 900                                        SELF => $self,
 901     );
 902
 903     if ($::form->{insert_before_item_id}) {
 904       $self->js
 905         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 906     } else {
 907       $self->js
 908         ->append('#row_table_id', $row_as_html);
 909     }
 910   }
 911
 912   $self->js
 913     ->run('kivi.Part.close_picker_dialogs')
 914     ->run('kivi.Order.init_row_handlers')
 915     ->run('kivi.Order.renumber_positions')
 916     ->focus('#add_item_parts_id_name');
 917
 918   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 919
 920   $self->js_redisplay_amounts_and_taxes;
 921   $self->js->render();
 922 }
 923
 924 # recalculate all linetotals, amounts and taxes and redisplay them
 925 sub action_recalc_amounts_and_taxes {
 926   my ($self) = @_;
 927
 928   $self->recalc();
 929
 930   $self->js_redisplay_line_values;
 931   $self->js_redisplay_amounts_and_taxes;
 932   $self->js->render();
 933 }
 934
 935 sub action_update_exchangerate {
 936   my ($self) = @_;
 937
 938   my $data = {
 939     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 940     currency_name => $self->order->currency->name,
 941     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 942   };
 943
 944   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 945 }
 946
 947 # redisplay item rows if they are sorted by an attribute
 948 sub action_reorder_items {
 949   my ($self) = @_;
 950
 951   my %sort_keys = (
 952     partnumber   => sub { $_[0]->part->partnumber },
 953     description  => sub { $_[0]->description },
 954     qty          => sub { $_[0]->qty },
 955     sellprice    => sub { $_[0]->sellprice },
 956     discount     => sub { $_[0]->discount },
 957     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 958   );
 959
 960   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 961
 962   my $method = $sort_keys{$::form->{order_by}};
 963   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 964   if ($::form->{sort_dir}) {
 965     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 966       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 967     } else {
 968       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 969     }
 970   } else {
 971     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 972       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 973     } else {
 974       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 975     }
 976   }
 977   $self->js
 978     ->run('kivi.Order.redisplay_items', \@to_sort)
 979     ->render;
 980 }
 981
 982 # show the popup to choose a price/discount source
 983 sub action_price_popup {
 984   my ($self) = @_;
 985
 986   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 987   my $item = $self->order->items_sorted->[$idx];
 988
 989   $self->render_price_dialog($item);
 990 }
 991
 992 # save the order in a session variable and redirect to the part controller
 993 sub action_create_part {
 994   my ($self) = @_;
 995
 996   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
 997
 998   my $callback     = $self->url_for(
 999     action       => 'return_from_create_part',
1000     type         => $self->type, # type is needed for check_auth on return
1001     previousform => $previousform,
1002   );
1003
1004   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1005
1006   my @redirect_params = (
1007     controller => 'Part',
1008     action     => 'add',
1009     part_type  => $::form->{add_item}->{create_part_type},
1010     callback   => $callback,
1011     show_abort => 1,
1012   );
1013
1014   $self->redirect_to(@redirect_params);
1015 }
1016
1017 sub action_return_from_create_part {
1018   my ($self) = @_;
1019
1020   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1021
1022   $::auth->restore_form_from_session(delete $::form->{previousform});
1023
1024   # set item ids to new fake id, to identify them as new items
1025   foreach my $item (@{$self->order->items_sorted}) {
1026     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1027   }
1028
1029   $self->recalc();
1030   $self->get_unalterable_data();
1031   $self->pre_render();
1032
1033   # trigger rendering values for second row/longdescription as hidden,
1034   # because they are loaded only on demand. So we need to keep the values
1035   # from the source.
1036   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1037   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1038
1039   $self->render(
1040     'order/form',
1041     title => $self->get_title_for('edit'),
1042     %{$self->{template_args}}
1043   );
1044
1045 }
1046
1047 # load the second row for one or more items
1048 #
1049 # This action gets the html code for all items second rows by rendering a template for
1050 # the second row and sets the html code via client js.
1051 sub action_load_second_rows {
1052   my ($self) = @_;
1053
1054   $self->recalc() if $self->order->is_sales; # for margin calculation
1055
1056   foreach my $item_id (@{ $::form->{item_ids} }) {
1057     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1058     my $item = $self->order->items_sorted->[$idx];
1059
1060     $self->js_load_second_row($item, $item_id, 0);
1061   }
1062
1063   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1064
1065   $self->js->render();
1066 }
1067
1068 # update description, notes and sellprice from master data
1069 sub action_update_row_from_master_data {
1070   my ($self) = @_;
1071
1072   foreach my $item_id (@{ $::form->{item_ids} }) {
1073     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1074     my $item  = $self->order->items_sorted->[$idx];
1075     my $texts = get_part_texts($item->part, $self->order->language_id);
1076
1077     $item->description($texts->{description});
1078     $item->longdescription($texts->{longdescription});
1079
1080     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1081
1082     my $price_src;
1083     if ($item->part->is_assortment) {
1084     # add assortment items with price 0, as the components carry the price
1085       $price_src = $price_source->price_from_source("");
1086       $price_src->price(0);
1087     } else {
1088       $price_src = $price_source->best_price
1089                  ? $price_source->best_price
1090                  : $price_source->price_from_source("");
1091       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1092       $price_src->price(0) if !$price_source->best_price;
1093     }
1094
1095
1096     $item->sellprice($price_src->price);
1097     $item->active_price_source($price_src);
1098
1099     $self->js
1100       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1101       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1102       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1103       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1104
1105     if ($self->search_cvpartnumber) {
1106       $self->get_item_cvpartnumber($item);
1107       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1108     }
1109   }
1110
1111   $self->recalc();
1112   $self->js_redisplay_line_values;
1113   $self->js_redisplay_amounts_and_taxes;
1114
1115   $self->js->render();
1116 }
1117
1118 sub js_load_second_row {
1119   my ($self, $item, $item_id, $do_parse) = @_;
1120
1121   if ($do_parse) {
1122     # Parse values from form (they are formated while rendering (template)).
1123     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1124     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1125     foreach my $var (@{ $item->cvars_by_config }) {
1126       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1127     }
1128     $item->parse_custom_variable_values;
1129   }
1130
1131   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1132
1133   $self->js
1134     ->html('#second_row_' . $item_id, $row_as_html)
1135     ->data('#second_row_' . $item_id, 'loaded', 1);
1136 }
1137
1138 sub js_redisplay_line_values {
1139   my ($self) = @_;
1140
1141   my $is_sales = $self->order->is_sales;
1142
1143   # sales orders with margins
1144   my @data;
1145   if ($is_sales) {
1146     @data = map {
1147       [
1148        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1149        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1150        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1151       ]} @{ $self->order->items_sorted };
1152   } else {
1153     @data = map {
1154       [
1155        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1156       ]} @{ $self->order->items_sorted };
1157   }
1158
1159   $self->js
1160     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1161 }
1162
1163 sub js_redisplay_amounts_and_taxes {
1164   my ($self) = @_;
1165
1166   if (scalar @{ $self->{taxes} }) {
1167     $self->js->show('#taxincluded_row_id');
1168   } else {
1169     $self->js->hide('#taxincluded_row_id');
1170   }
1171
1172   if ($self->order->taxincluded) {
1173     $self->js->hide('#subtotal_row_id');
1174   } else {
1175     $self->js->show('#subtotal_row_id');
1176   }
1177
1178   if ($self->order->is_sales) {
1179     my $is_neg = $self->order->marge_total < 0;
1180     $self->js
1181       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1182       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1183       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1184       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1185       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1186       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1187       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1188       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1189   }
1190
1191   $self->js
1192     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1193     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1194     ->remove('.tax_row')
1195     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1196 }
1197
1198 sub js_redisplay_cvpartnumbers {
1199   my ($self) = @_;
1200
1201   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1202
1203   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1204
1205   $self->js
1206     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1207 }
1208
1209 sub js_reset_order_and_item_ids_after_save {
1210   my ($self) = @_;
1211
1212   $self->js
1213     ->val('#id', $self->order->id)
1214     ->val('#converted_from_oe_id', '')
1215     ->val('#order_' . $self->nr_key(), $self->order->number);
1216
1217   my $idx = 0;
1218   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1219     next if !$self->order->items_sorted->[$idx]->id;
1220     next if $form_item_id !~ m{^new};
1221     $self->js
1222       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1223       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1224       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1225   } continue {
1226     $idx++;
1227   }
1228   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1229 }
1230
1231 #
1232 # helpers
1233 #
1234
1235 sub init_valid_types {
1236   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1237 }
1238
1239 sub init_type {
1240   my ($self) = @_;
1241
1242   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1243     die "Not a valid type for order";
1244   }
1245
1246   $self->type($::form->{type});
1247 }
1248
1249 sub init_cv {
1250   my ($self) = @_;
1251
1252   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1253          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1254          : die "Not a valid type for order";
1255
1256   return $cv;
1257 }
1258
1259 sub init_search_cvpartnumber {
1260   my ($self) = @_;
1261
1262   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1263   my $search_cvpartnumber;
1264   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1265   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1266
1267   return $search_cvpartnumber;
1268 }
1269
1270 sub init_show_update_button {
1271   my ($self) = @_;
1272
1273   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1274 }
1275
1276 sub init_p {
1277   SL::Presenter->get;
1278 }
1279
1280 sub init_order {
1281   $_[0]->make_order;
1282 }
1283
1284 sub init_all_price_factors {
1285   SL::DB::Manager::PriceFactor->get_all;
1286 }
1287
1288 sub init_part_picker_classification_ids {
1289   my ($self)    = @_;
1290   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1291
1292   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1293 }
1294
1295 sub check_auth {
1296   my ($self) = @_;
1297
1298   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1299
1300   my $right   = $right_for->{ $self->type };
1301   $right    ||= 'DOES_NOT_EXIST';
1302
1303   $::auth->assert($right);
1304 }
1305
1306 # build the selection box for contacts
1307 #
1308 # Needed, if customer/vendor changed.
1309 sub build_contact_select {
1310   my ($self) = @_;
1311
1312   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1313     value_key  => 'cp_id',
1314     title_key  => 'full_name_dep',
1315     default    => $self->order->cp_id,
1316     with_empty => 1,
1317     style      => 'width: 300px',
1318   );
1319 }
1320
1321 # build the selection box for the additional billing address
1322 #
1323 # Needed, if customer/vendor changed.
1324 sub build_billing_address_select {
1325   my ($self) = @_;
1326
1327   select_tag('order.billing_address_id',
1328              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1329              value_key  => 'id',
1330              title_key  => 'displayable_id',
1331              default    => $self->order->billing_address_id,
1332              with_empty => 0,
1333              style      => 'width: 300px',
1334   );
1335 }
1336
1337 # build the selection box for shiptos
1338 #
1339 # Needed, if customer/vendor changed.
1340 sub build_shipto_select {
1341   my ($self) = @_;
1342
1343   select_tag('order.shipto_id',
1344              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1345              value_key  => 'shipto_id',
1346              title_key  => 'displayable_id',
1347              default    => $self->order->shipto_id,
1348              with_empty => 0,
1349              style      => 'width: 300px',
1350   );
1351 }
1352
1353 # build the inputs for the cusom shipto dialog
1354 #
1355 # Needed, if customer/vendor changed.
1356 sub build_shipto_inputs {
1357   my ($self) = @_;
1358
1359   my $content = $self->p->render('common/_ship_to_dialog',
1360                                  vc_obj      => $self->order->customervendor,
1361                                  cs_obj      => $self->order->custom_shipto,
1362                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1363                                  id_selector => '#order_shipto_id');
1364
1365   div_tag($content, id => 'shipto_inputs');
1366 }
1367
1368 # render the info line for business
1369 #
1370 # Needed, if customer/vendor changed.
1371 sub build_business_info_row
1372 {
1373   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1374 }
1375
1376 # build the rows for displaying taxes
1377 #
1378 # Called if amounts where recalculated and redisplayed.
1379 sub build_tax_rows {
1380   my ($self) = @_;
1381
1382   my $rows_as_html;
1383   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1384     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1385   }
1386   return $rows_as_html;
1387 }
1388
1389
1390 sub render_price_dialog {
1391   my ($self, $record_item) = @_;
1392
1393   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1394
1395   $self->js
1396     ->run(
1397       'kivi.io.price_chooser_dialog',
1398       t8('Available Prices'),
1399       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1400     )
1401     ->reinit_widgets;
1402
1403 #   if (@errors) {
1404 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1405 #     $self->js->show('#dialog_flash_error');
1406 #   }
1407
1408   $self->js->render;
1409 }
1410
1411 sub load_order {
1412   my ($self) = @_;
1413
1414   return if !$::form->{id};
1415
1416   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1417
1418   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1419   # You need a custom shipto object to call cvars_by_config to get the cvars.
1420   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1421
1422   return $self->order;
1423 }
1424
1425 # load or create a new order object
1426 #
1427 # And assign changes from the form to this object.
1428 # If the order is loaded from db, check if items are deleted in the form,
1429 # remove them form the object and collect them for removing from db on saving.
1430 # Then create/update items from form (via make_item) and add them.
1431 sub make_order {
1432   my ($self) = @_;
1433
1434   # add_items adds items to an order with no items for saving, but they cannot
1435   # be retrieved via items until the order is saved. Adding empty items to new
1436   # order here solves this problem.
1437   my $order;
1438   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1439   $order ||= SL::DB::Order->new(orderitems  => [],
1440                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1441                                 currency_id => $::instance_conf->get_currency_id(),);
1442
1443   my $cv_id_method = $self->cv . '_id';
1444   if (!$::form->{id} && $::form->{$cv_id_method}) {
1445     $order->$cv_id_method($::form->{$cv_id_method});
1446     setup_order_from_cv($order);
1447   }
1448
1449   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1450   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1451
1452   $order->assign_attributes(%{$::form->{order}});
1453
1454   $self->setup_custom_shipto_from_form($order, $::form);
1455
1456   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1457     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1458     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1459   }
1460
1461   # remove deleted items
1462   $self->item_ids_to_delete([]);
1463   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1464     my $item = $order->orderitems->[$idx];
1465     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1466       splice @{$order->orderitems}, $idx, 1;
1467       push @{$self->item_ids_to_delete}, $item->id;
1468     }
1469   }
1470
1471   my @items;
1472   my $pos = 1;
1473   foreach my $form_attr (@{$form_orderitems}) {
1474     my $item = make_item($order, $form_attr);
1475     $item->position($pos);
1476     push @items, $item;
1477     $pos++;
1478   }
1479   $order->add_items(grep {!$_->id} @items);
1480
1481   return $order;
1482 }
1483
1484 # create or update items from form
1485 #
1486 # Make item objects from form values. For items already existing read from db.
1487 # Create a new item else. And assign attributes.
1488 sub make_item {
1489   my ($record, $attr) = @_;
1490
1491   my $item;
1492   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1493
1494   my $is_new = !$item;
1495
1496   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1497   # they cannot be retrieved via custom_variables until the order/orderitem is
1498   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1499   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1500
1501   $item->assign_attributes(%$attr);
1502
1503   if ($is_new) {
1504     my $texts = get_part_texts($item->part, $record->language_id);
1505     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1506     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1507     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1508   }
1509
1510   return $item;
1511 }
1512
1513 # create a new item
1514 #
1515 # This is used to add one item
1516 sub new_item {
1517   my ($record, $attr) = @_;
1518
1519   my $item = SL::DB::OrderItem->new;
1520
1521   # Remove attributes where the user left or set the inputs empty.
1522   # So these attributes will be undefined and we can distinguish them
1523   # from zero later on.
1524   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1525     delete $attr->{$_} if $attr->{$_} eq '';
1526   }
1527
1528   $item->assign_attributes(%$attr);
1529
1530   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1531   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1532
1533   $item->unit($part->unit) if !$item->unit;
1534
1535   my $price_src;
1536   if ( $part->is_assortment ) {
1537     # add assortment items with price 0, as the components carry the price
1538     $price_src = $price_source->price_from_source("");
1539     $price_src->price(0);
1540   } elsif (defined $item->sellprice) {
1541     $price_src = $price_source->price_from_source("");
1542     $price_src->price($item->sellprice);
1543   } else {
1544     $price_src = $price_source->best_price
1545                ? $price_source->best_price
1546                : $price_source->price_from_source("");
1547     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1548     $price_src->price(0) if !$price_source->best_price;
1549   }
1550
1551   my $discount_src;
1552   if (defined $item->discount) {
1553     $discount_src = $price_source->discount_from_source("");
1554     $discount_src->discount($item->discount);
1555   } else {
1556     $discount_src = $price_source->best_discount
1557                   ? $price_source->best_discount
1558                   : $price_source->discount_from_source("");
1559     $discount_src->discount(0) if !$price_source->best_discount;
1560   }
1561
1562   my %new_attr;
1563   $new_attr{part}                   = $part;
1564   $new_attr{description}            = $part->description     if ! $item->description;
1565   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1566   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1567   $new_attr{sellprice}              = $price_src->price;
1568   $new_attr{discount}               = $discount_src->discount;
1569   $new_attr{active_price_source}    = $price_src;
1570   $new_attr{active_discount_source} = $discount_src;
1571   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1572   $new_attr{project_id}             = $record->globalproject_id;
1573   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1574
1575   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1576   # they cannot be retrieved via custom_variables until the order/orderitem is
1577   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1578   $new_attr{custom_variables} = [];
1579
1580   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1581
1582   $item->assign_attributes(%new_attr, %{ $texts });
1583
1584   return $item;
1585 }
1586
1587 sub setup_order_from_cv {
1588   my ($order) = @_;
1589
1590   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1591
1592   $order->intnotes($order->customervendor->notes);
1593
1594   return if !$order->is_sales;
1595
1596   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1597   $order->taxincluded(defined($order->customer->taxincluded_checked)
1598                       ? $order->customer->taxincluded_checked
1599                       : $::myconfig{taxincluded_checked});
1600
1601   my $address = $order->customer->default_billing_address;;
1602   $order->billing_address_id($address ? $address->id : undef);
1603 }
1604
1605 # setup custom shipto from form
1606 #
1607 # The dialog returns form variables starting with 'shipto' and cvars starting
1608 # with 'shiptocvar_'.
1609 # Mark it to be deleted if a shipto from master data is selected
1610 # (i.e. order has a shipto).
1611 # Else, update or create a new custom shipto. If the fields are empty, it
1612 # will not be saved on save.
1613 sub setup_custom_shipto_from_form {
1614   my ($self, $order, $form) = @_;
1615
1616   if ($order->shipto) {
1617     $self->is_custom_shipto_to_delete(1);
1618   } else {
1619     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1620
1621     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1622     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1623
1624     $custom_shipto->assign_attributes(%$shipto_attrs);
1625     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1626   }
1627 }
1628
1629 # recalculate prices and taxes
1630 #
1631 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1632 sub recalc {
1633   my ($self) = @_;
1634
1635   my %pat = $self->order->calculate_prices_and_taxes();
1636
1637   $self->{taxes} = [];
1638   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1639     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1640
1641     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1642                                 netamount => $netamount,
1643                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1644   }
1645   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1646 }
1647
1648 # get data for saving, printing, ..., that is not changed in the form
1649 #
1650 # Only cvars for now.
1651 sub get_unalterable_data {
1652   my ($self) = @_;
1653
1654   foreach my $item (@{ $self->order->items }) {
1655     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1656     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1657     foreach my $var (@{ $item->cvars_by_config }) {
1658       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1659     }
1660     $item->parse_custom_variable_values;
1661   }
1662 }
1663
1664 # delete the order
1665 #
1666 # And remove related files in the spool directory
1667 sub delete {
1668   my ($self) = @_;
1669
1670   my $errors = [];
1671   my $db     = $self->order->db;
1672
1673   $db->with_transaction(
1674     sub {
1675       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1676       $self->order->delete;
1677       my $spool = $::lx_office_conf{paths}->{spool};
1678       unlink map { "$spool/$_" } @spoolfiles if $spool;
1679
1680       $self->save_history('DELETED');
1681
1682       1;
1683   }) || push(@{$errors}, $db->error);
1684
1685   return $errors;
1686 }
1687
1688 # save the order
1689 #
1690 # And delete items that are deleted in the form.
1691 sub save {
1692   my ($self) = @_;
1693
1694   my $errors = [];
1695   my $db     = $self->order->db;
1696
1697   $db->with_transaction(sub {
1698     # delete custom shipto if it is to be deleted or if it is empty
1699     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1700       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1701       $self->order->custom_shipto(undef);
1702     }
1703
1704     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1705     $self->order->save(cascade => 1);
1706
1707     # link records
1708     if ($::form->{converted_from_oe_id}) {
1709       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1710
1711       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1712         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1713         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1714         $src->link_to_record($self->order);
1715       }
1716       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1717         my $idx = 0;
1718         foreach (@{ $self->order->items_sorted }) {
1719           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1720           next if !$from_id;
1721           SL::DB::RecordLink->new(from_table => 'orderitems',
1722                                   from_id    => $from_id,
1723                                   to_table   => 'orderitems',
1724                                   to_id      => $_->id
1725           )->save;
1726           $idx++;
1727         }
1728       }
1729
1730       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1731     }
1732
1733     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1734
1735     $self->save_history('SAVED');
1736
1737     1;
1738   }) || push(@{$errors}, $db->error);
1739
1740   return $errors;
1741 }
1742
1743 sub workflow_sales_or_request_for_quotation {
1744   my ($self) = @_;
1745
1746   # always save
1747   my $errors = $self->save();
1748
1749   if (scalar @{ $errors }) {
1750     $self->js->flash('error', $_) for @{ $errors };
1751     return $self->js->render();
1752   }
1753
1754   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1755
1756   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1757   $self->{converted_from_oe_id} = delete $::form->{id};
1758
1759   # set item ids to new fake id, to identify them as new items
1760   foreach my $item (@{$self->order->items_sorted}) {
1761     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1762   }
1763
1764   # change form type
1765   $::form->{type} = $destination_type;
1766   $self->type($self->init_type);
1767   $self->cv  ($self->init_cv);
1768   $self->check_auth;
1769
1770   $self->recalc();
1771   $self->get_unalterable_data();
1772   $self->pre_render();
1773
1774   # trigger rendering values for second row as hidden, because they
1775   # are loaded only on demand. So we need to keep the values from the
1776   # source.
1777   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1778
1779   $self->render(
1780     'order/form',
1781     title => $self->get_title_for('edit'),
1782     %{$self->{template_args}}
1783   );
1784 }
1785
1786 sub workflow_sales_or_purchase_order {
1787   my ($self) = @_;
1788
1789   # always save
1790   my $errors = $self->save();
1791
1792   if (scalar @{ $errors }) {
1793     $self->js->flash('error', $_) foreach @{ $errors };
1794     return $self->js->render();
1795   }
1796
1797   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1798                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1799                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1800                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1801                        : '';
1802
1803   # check for direct delivery
1804   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1805   my $custom_shipto;
1806   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1807       && $::form->{use_shipto} && $self->order->shipto) {
1808     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1809   }
1810
1811   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1812   $self->{converted_from_oe_id} = delete $::form->{id};
1813
1814   # set item ids to new fake id, to identify them as new items
1815   foreach my $item (@{$self->order->items_sorted}) {
1816     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1817   }
1818
1819   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1820     if ($::form->{use_shipto}) {
1821       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1822     } else {
1823       # remove any custom shipto if not wanted
1824       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1825     }
1826   }
1827
1828   # change form type
1829   $::form->{type} = $destination_type;
1830   $self->type($self->init_type);
1831   $self->cv  ($self->init_cv);
1832   $self->check_auth;
1833
1834   $self->recalc();
1835   $self->get_unalterable_data();
1836   $self->pre_render();
1837
1838   # trigger rendering values for second row as hidden, because they
1839   # are loaded only on demand. So we need to keep the values from the
1840   # source.
1841   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1842
1843   $self->render(
1844     'order/form',
1845     title => $self->get_title_for('edit'),
1846     %{$self->{template_args}}
1847   );
1848 }
1849
1850
1851 sub pre_render {
1852   my ($self) = @_;
1853
1854   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1855   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1856   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1857   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1858   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1859                                                                                               deleted => 0 ] ],
1860                                                                            sort_by => 'name');
1861   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1862                                                                                               deleted => 0 ] ],
1863                                                                            sort_by => 'name');
1864   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1865                                                                                                         obsolete => 0 ] ]);
1866   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1867   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1868   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1869   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1870   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1871
1872   my $print_form = Form->new('');
1873   $print_form->{type}        = $self->type;
1874   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1875   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1876     form => $print_form,
1877     options => {dialog_name_prefix => 'print_options.',
1878                 show_headers       => 1,
1879                 no_queue           => 1,
1880                 no_postscript      => 1,
1881                 no_opendocument    => 0,
1882                 no_html            => 1},
1883   );
1884
1885   foreach my $item (@{$self->order->orderitems}) {
1886     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1887     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1888     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1889   }
1890
1891   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1892     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1893     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1894     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1895     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1896   }
1897
1898   if ($self->order->number && $::instance_conf->get_webdav) {
1899     my $webdav = SL::Webdav->new(
1900       type     => $self->type,
1901       number   => $self->order->number,
1902     );
1903     my @all_objects = $webdav->get_all_objects;
1904     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1905                                                     type => t8('File'),
1906                                                     link => File::Spec->catfile($_->full_filedescriptor),
1907                                                 } } @all_objects;
1908   }
1909
1910   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1911       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1912     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1913   }
1914
1915   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1916
1917   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1918                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up show_history);
1919   $self->setup_edit_action_bar;
1920 }
1921
1922 sub setup_edit_action_bar {
1923   my ($self, %params) = @_;
1924
1925   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1926                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1927                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1928
1929   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
1930   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
1931
1932   for my $bar ($::request->layout->get('actionbar')) {
1933     $bar->add(
1934       combobox => [
1935         action => [
1936           t8('Save'),
1937           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1938                                                     $::instance_conf->get_order_warn_no_deliverydate,
1939           ],
1940           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
1941                          @req_trans_cost_art, @req_cusordnumber,
1942           ],
1943         ],
1944         action => [
1945           t8('Save as new'),
1946           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1947           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1948                          @req_trans_cost_art, @req_cusordnumber,
1949           ],
1950           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1951         ],
1952       ], # end of combobox "Save"
1953
1954       combobox => [
1955         action => [
1956           t8('Workflow'),
1957         ],
1958         action => [
1959           t8('Save and Quotation'),
1960           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1961           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
1962           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1963         ],
1964         action => [
1965           t8('Save and RFQ'),
1966           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1967           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1968         ],
1969         action => [
1970           t8('Save and Sales Order'),
1971           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1972           checks   => [ @req_trans_cost_art ],
1973           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1974         ],
1975         action => [
1976           t8('Save and Purchase Order'),
1977           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1978           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
1979           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1980         ],
1981         action => [
1982           t8('Save and Delivery Order'),
1983           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1984                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1985                                                                                                                         ],
1986           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1987                          @req_trans_cost_art, @req_cusordnumber,
1988           ],
1989           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1990         ],
1991         action => [
1992           t8('Save and Invoice'),
1993           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1994           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1995                          @req_trans_cost_art, @req_cusordnumber,
1996           ],
1997         ],
1998         action => [
1999           t8('Save and AP Transaction'),
2000           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2001           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
2002         ],
2003
2004       ], # end of combobox "Workflow"
2005
2006       combobox => [
2007         action => [
2008           t8('Export'),
2009         ],
2010         action => [
2011           t8('Save and preview PDF'),
2012           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2013                                                         $::instance_conf->get_order_warn_no_deliverydate,
2014                     ],
2015           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2016         ],
2017         action => [
2018           t8('Save and print'),
2019           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2020                                                        $::instance_conf->get_order_warn_no_deliverydate,
2021                     ],
2022           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2023         ],
2024         action => [
2025           t8('Save and E-mail'),
2026           id   => 'save_and_email_action',
2027           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2028                                                                      $::instance_conf->get_order_warn_no_deliverydate,
2029                   ],
2030           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2031         ],
2032         action => [
2033           t8('Download attachments of all parts'),
2034           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2035           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2036           only_if  => $::instance_conf->get_doc_storage,
2037         ],
2038       ], # end of combobox "Export"
2039
2040       action => [
2041         t8('Delete'),
2042         call     => [ 'kivi.Order.delete_order' ],
2043         confirm  => $::locale->text('Do you really want to delete this object?'),
2044         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2045         only_if  => $deletion_allowed,
2046       ],
2047
2048       combobox => [
2049         action => [
2050           t8('more')
2051         ],
2052         action => [
2053           t8('History'),
2054           call     => [ 'set_history_window', $self->order->id, 'id' ],
2055           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2056         ],
2057         action => [
2058           t8('Follow-Up'),
2059           call     => [ 'kivi.Order.follow_up_window' ],
2060           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2061           only_if  => $::auth->assert('productivity', 1),
2062         ],
2063       ], # end of combobox "more"
2064     );
2065   }
2066 }
2067
2068 sub generate_pdf {
2069   my ($self, $pdf_ref, $params) = @_;
2070
2071   my $order  = $self->order;
2072   my @errors = ();
2073
2074   my $print_form = Form->new('');
2075   $print_form->{type}        = $order->type;
2076   $print_form->{formname}    = $params->{formname} || $order->type;
2077   $print_form->{format}      = $params->{format}   || 'pdf';
2078   $print_form->{media}       = $params->{media}    || 'file';
2079   $print_form->{groupitems}  = $params->{groupitems};
2080   $print_form->{printer_id}  = $params->{printer_id};
2081   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2082
2083   $order->language($params->{language});
2084   $order->flatten_to_form($print_form, format_amounts => 1);
2085
2086   my $template_ext;
2087   my $template_type;
2088   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2089     $template_ext  = 'odt';
2090     $template_type = 'OpenDocument';
2091   }
2092
2093   # search for the template
2094   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2095     name        => $print_form->{formname},
2096     extension   => $template_ext,
2097     email       => $print_form->{media} eq 'email',
2098     language    => $params->{language},
2099     printer_id  => $print_form->{printer_id},
2100   );
2101
2102   if (!defined $template_file) {
2103     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2104   }
2105
2106   return @errors if scalar @errors;
2107
2108   $print_form->throw_on_error(sub {
2109     eval {
2110       $print_form->prepare_for_printing;
2111
2112       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
2113         format        => $print_form->{format},
2114         template_type => $template_type,
2115         template      => $template_file,
2116         variables     => $print_form,
2117         variable_content_types => {
2118           longdescription => 'html',
2119           partnotes       => 'html',
2120           notes           => 'html',
2121         },
2122       );
2123       1;
2124     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2125   });
2126
2127   return @errors;
2128 }
2129
2130 sub get_files_for_email_dialog {
2131   my ($self) = @_;
2132
2133   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2134
2135   return %files if !$::instance_conf->get_doc_storage;
2136
2137   if ($self->order->id) {
2138     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2139     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2140     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2141     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2142   }
2143
2144   my @parts =
2145     uniq_by { $_->{id} }
2146     map {
2147       +{ id         => $_->part->id,
2148          partnumber => $_->part->partnumber }
2149     } @{$self->order->items_sorted};
2150
2151   foreach my $part (@parts) {
2152     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2153     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2154   }
2155
2156   foreach my $key (keys %files) {
2157     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2158   }
2159
2160   return %files;
2161 }
2162
2163 sub make_periodic_invoices_config_from_yaml {
2164   my ($yaml_config) = @_;
2165
2166   return if !$yaml_config;
2167   my $attr = SL::YAML::Load($yaml_config);
2168   return if 'HASH' ne ref $attr;
2169   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2170 }
2171
2172
2173 sub get_periodic_invoices_status {
2174   my ($self, $config) = @_;
2175
2176   return                      if $self->type ne sales_order_type();
2177   return t8('not configured') if !$config;
2178
2179   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2180              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2181              :                                                     die "Cannot get status of periodic invoices config";
2182
2183   return $active ? t8('active') : t8('inactive');
2184 }
2185
2186 sub get_title_for {
2187   my ($self, $action) = @_;
2188
2189   return '' if none { lc($action)} qw(add edit);
2190
2191   # for locales:
2192   # $::locale->text("Add Sales Order");
2193   # $::locale->text("Add Purchase Order");
2194   # $::locale->text("Add Quotation");
2195   # $::locale->text("Add Request for Quotation");
2196   # $::locale->text("Edit Sales Order");
2197   # $::locale->text("Edit Purchase Order");
2198   # $::locale->text("Edit Quotation");
2199   # $::locale->text("Edit Request for Quotation");
2200
2201   $action = ucfirst(lc($action));
2202   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2203        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2204        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2205        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2206        : '';
2207 }
2208
2209 sub get_item_cvpartnumber {
2210   my ($self, $item) = @_;
2211
2212   return if !$self->search_cvpartnumber;
2213   return if !$self->order->customervendor;
2214
2215   if ($self->cv eq 'vendor') {
2216     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2217     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2218   } elsif ($self->cv eq 'customer') {
2219     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2220     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2221   }
2222 }
2223
2224 sub get_part_texts {
2225   my ($part_or_id, $language_or_id, %defaults) = @_;
2226
2227   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2228   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2229   my $texts       = {
2230     description     => $defaults{description}     // $part->description,
2231     longdescription => $defaults{longdescription} // $part->notes,
2232   };
2233
2234   return $texts unless $language_id;
2235
2236   my $translation = SL::DB::Manager::Translation->get_first(
2237     where => [
2238       parts_id    => $part->id,
2239       language_id => $language_id,
2240     ]);
2241
2242   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2243   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2244
2245   return $texts;
2246 }
2247
2248 sub sales_order_type {
2249   'sales_order';
2250 }
2251
2252 sub purchase_order_type {
2253   'purchase_order';
2254 }
2255
2256 sub sales_quotation_type {
2257   'sales_quotation';
2258 }
2259
2260 sub request_quotation_type {
2261   'request_quotation';
2262 }
2263
2264 sub nr_key {
2265   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2266        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2267        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2268        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2269        : '';
2270 }
2271
2272 sub save_and_redirect_to {
2273   my ($self, %params) = @_;
2274
2275   my $errors = $self->save();
2276
2277   if (scalar @{ $errors }) {
2278     $self->js->flash('error', $_) foreach @{ $errors };
2279     return $self->js->render();
2280   }
2281
2282   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2283            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2284            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2285            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2286            : '';
2287   flash_later('info', $text);
2288
2289   $self->redirect_to(%params, id => $self->order->id);
2290 }
2291
2292 sub save_history {
2293   my ($self, $addition) = @_;
2294
2295   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2296   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2297
2298   SL::DB::History->new(
2299     trans_id    => $self->order->id,
2300     employee_id => SL::DB::Manager::Employee->current->id,
2301     what_done   => $self->order->type,
2302     snumbers    => $snumbers,
2303     addition    => $addition,
2304   )->save;
2305 }
2306
2307 sub store_pdf_to_webdav_and_filemanagement {
2308   my ($self, $content, $filename) = @_;
2309
2310   my $order = $self->order;
2311   my @errors;
2312
2313   # copy file to webdav folder
2314   if ($order->number && $::instance_conf->get_webdav_documents) {
2315     my $webdav = SL::Webdav->new(
2316       type     => $order->type,
2317       number   => $order->number,
2318     );
2319     my $webdav_file = SL::Webdav::File->new(
2320       webdav   => $webdav,
2321       filename => $filename,
2322     );
2323     eval {
2324       $webdav_file->store(data => \$content);
2325       1;
2326     } or do {
2327       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2328     };
2329   }
2330   if ($order->id && $::instance_conf->get_doc_storage) {
2331     eval {
2332       SL::File->save(object_id     => $order->id,
2333                      object_type   => $order->type,
2334                      mime_type     => 'application/pdf',
2335                      source        => 'created',
2336                      file_type     => 'document',
2337                      file_name     => $filename,
2338                      file_contents => $content);
2339       1;
2340     } or do {
2341       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2342     };
2343   }
2344
2345   return @errors;
2346 }
2347
2348 sub link_requirement_specs_linking_to_created_from_objects {
2349   my ($self, @converted_from_oe_ids) = @_;
2350
2351   return unless @converted_from_oe_ids;
2352
2353   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2354   foreach my $rs_order (@{ $rs_orders }) {
2355     SL::DB::RequirementSpecOrder->new(
2356       order_id            => $self->order->id,
2357       requirement_spec_id => $rs_order->requirement_spec_id,
2358       version_id          => $rs_order->version_id,
2359     )->save;
2360   }
2361 }
2362
2363 sub set_project_in_linked_requirement_specs {
2364   my ($self) = @_;
2365
2366   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2367   foreach my $rs_order (@{ $rs_orders }) {
2368     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2369
2370     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2371   }
2372 }
2373
2374 1;
2375
2376 __END__
2377
2378 =encoding utf-8
2379
2380 =head1 NAME
2381
2382 SL::Controller::Order - controller for orders
2383
2384 =head1 SYNOPSIS
2385
2386 This is a new form to enter orders, completely rewritten with the use
2387 of controller and java script techniques.
2388
2389 The aim is to provide the user a better experience and a faster workflow. Also
2390 the code should be more readable, more reliable and better to maintain.
2391
2392 =head2 Key Features
2393
2394 =over 4
2395
2396 =item *
2397
2398 One input row, so that input happens every time at the same place.
2399
2400 =item *
2401
2402 Use of pickers where possible.
2403
2404 =item *
2405
2406 Possibility to enter more than one item at once.
2407
2408 =item *
2409
2410 Item list in a scrollable area, so that the workflow buttons stay at
2411 the bottom.
2412
2413 =item *
2414
2415 Reordering item rows with drag and drop is possible. Sorting item rows is
2416 possible (by partnumber, description, qty, sellprice and discount for now).
2417
2418 =item *
2419
2420 No C<update> is necessary. All entries and calculations are managed
2421 with ajax-calls and the page only reloads on C<save>.
2422
2423 =item *
2424
2425 User can see changes immediately, because of the use of java script
2426 and ajax.
2427
2428 =back
2429
2430 =head1 CODE
2431
2432 =head2 Layout
2433
2434 =over 4
2435
2436 =item * C<SL/Controller/Order.pm>
2437
2438 the controller
2439
2440 =item * C<template/webpages/order/form.html>
2441
2442 main form
2443
2444 =item * C<template/webpages/order/tabs/basic_data.html>
2445
2446 Main tab for basic_data.
2447
2448 This is the only tab here for now. "linked records" and "webdav" tabs are
2449 reused from generic code.
2450
2451 =over 4
2452
2453 =item * C<template/webpages/order/tabs/_business_info_row.html>
2454
2455 For displaying information on business type
2456
2457 =item * C<template/webpages/order/tabs/_item_input.html>
2458
2459 The input line for items
2460
2461 =item * C<template/webpages/order/tabs/_row.html>
2462
2463 One row for already entered items
2464
2465 =item * C<template/webpages/order/tabs/_tax_row.html>
2466
2467 Displaying tax information
2468
2469 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2470
2471 Dialog for selecting price and discount sources
2472
2473 =back
2474
2475 =item * C<js/kivi.Order.js>
2476
2477 java script functions
2478
2479 =back
2480
2481 =head1 TODO
2482
2483 =over 4
2484
2485 =item * testing
2486
2487 =item * price sources: little symbols showing better price / better discount
2488
2489 =item * select units in input row?
2490
2491 =item * check for direct delivery (workflow sales order -> purchase order)
2492
2493 =item * access rights
2494
2495 =item * display weights
2496
2497 =item * mtime check
2498
2499 =item * optional client/user behaviour
2500
2501 (transactions has to be set - department has to be set -
2502  force project if enabled in client config)
2503
2504 =back
2505
2506 =head1 KNOWN BUGS AND CAVEATS
2507
2508 =over 4
2509
2510 =item *
2511
2512 Customer discount is not displayed as a valid discount in price source popup
2513 (this might be a bug in price sources)
2514
2515 (I cannot reproduce this (Bernd))
2516
2517 =item *
2518
2519 No indication that <shift>-up/down expands/collapses second row.
2520
2521 =item *
2522
2523 Inline creation of parts is not currently supported
2524
2525 =item *
2526
2527 Table header is not sticky in the scrolling area.
2528
2529 =item *
2530
2531 Sorting does not include C<position>, neither does reordering.
2532
2533 This behavior was implemented intentionally. But we can discuss, which behavior
2534 should be implemented.
2535
2536 =back
2537
2538 =head1 To discuss / Nice to have
2539
2540 =over 4
2541
2542 =item *
2543
2544 How to expand/collapse second row. Now it can be done clicking the icon or
2545 <shift>-up/down.
2546
2547 =item *
2548
2549 Possibility to select PriceSources in input row?
2550
2551 =item *
2552
2553 This controller uses a (changed) copy of the template for the PriceSource
2554 dialog. Maybe there could be used one code source.
2555
2556 =item *
2557
2558 Rounding-differences between this controller (PriceTaxCalculator) and the old
2559 form. This is not only a problem here, but also in all parts using the PTC.
2560 There exists a ticket and a patch. This patch should be testet.
2561
2562 =item *
2563
2564 An indicator, if the actual inputs are saved (like in an
2565 editor or on text processing application).
2566
2567 =item *
2568
2569 A warning when leaving the page without saveing unchanged inputs.
2570
2571
2572 =back
2573
2574 =head1 AUTHOR
2575
2576 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2577
2578 =cut