SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::HTML::Util;
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::AdditionalBillingAddress;
  18 use SL::DB::AuthUser;
  19 use SL::DB::History;
  20 use SL::DB::Order;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28 use SL::DB::RecordLink;
  29 use SL::DB::RequirementSpec;
  30 use SL::DB::Shipto;
  31 use SL::DB::Translation;
  32
  33 use SL::Helper::CreatePDF qw(:all);
  34 use SL::Helper::PrintOptions;
  35 use SL::Helper::ShippedQty;
  36 use SL::Helper::UserPreferences::PositionsScrollbar;
  37 use SL::Helper::UserPreferences::UpdatePositions;
  38
  39 use SL::Controller::Helper::GetModels;
  40
  41 use List::Util qw(first sum0);
  42 use List::UtilsBy qw(sort_by uniq_by);
  43 use List::MoreUtils qw(any none pairwise first_index);
  44 use English qw(-no_match_vars);
  45 use File::Spec;
  46 use Cwd;
  47 use Sort::Naturally;
  48
  49 use Rose::Object::MakeMethods::Generic
  50 (
  51  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  52  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  53 );
  54
  55
  56 # safety
  57 __PACKAGE__->run_before('check_auth');
  58
  59 __PACKAGE__->run_before('recalc',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 __PACKAGE__->run_before('get_unalterable_data',
  64                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  65                                      print send_email) ]);
  66
  67 #
  68 # actions
  69 #
  70
  71 # add a new order
  72 sub action_add {
  73   my ($self) = @_;
  74
  75   $self->order->transdate(DateTime->now_local());
  76   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  77                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  78
  79   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  80       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  81       && (!$self->order->reqdate)) {
  82     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  83   }
  84
  85
  86   $self->pre_render();
  87   $self->render(
  88     'order/form',
  89     title => $self->get_title_for('add'),
  90     %{$self->{template_args}}
  91   );
  92 }
  93
  94 # edit an existing order
  95 sub action_edit {
  96   my ($self) = @_;
  97
  98   if ($::form->{id}) {
  99     $self->load_order;
 100
 101   } else {
 102     # this is to edit an order from an unsaved order object
 103
 104     # set item ids to new fake id, to identify them as new items
 105     foreach my $item (@{$self->order->items_sorted}) {
 106       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 107     }
 108     # trigger rendering values for second row as hidden, because they
 109     # are loaded only on demand. So we need to keep the values from
 110     # the source.
 111     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 112   }
 113
 114   $self->recalc();
 115   $self->pre_render();
 116   $self->render(
 117     'order/form',
 118     title => $self->get_title_for('edit'),
 119     %{$self->{template_args}}
 120   );
 121 }
 122
 123 # edit a collective order (consisting of one or more existing orders)
 124 sub action_edit_collective {
 125   my ($self) = @_;
 126
 127   # collect order ids
 128   my @multi_ids = map {
 129     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 130   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 131
 132   # fall back to add if no ids are given
 133   if (scalar @multi_ids == 0) {
 134     $self->action_add();
 135     return;
 136   }
 137
 138   # fall back to save as new if only one id is given
 139   if (scalar @multi_ids == 1) {
 140     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 141     $self->action_save_as_new();
 142     return;
 143   }
 144
 145   # make new order from given orders
 146   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 147   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 148   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 149
 150   $self->action_edit();
 151 }
 152
 153 # delete the order
 154 sub action_delete {
 155   my ($self) = @_;
 156
 157   my $errors = $self->delete();
 158
 159   if (scalar @{ $errors }) {
 160     $self->js->flash('error', $_) foreach @{ $errors };
 161     return $self->js->render();
 162   }
 163
 164   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 165            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 166            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 167            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 168            : '';
 169   flash_later('info', $text);
 170
 171   my @redirect_params = (
 172     action => 'add',
 173     type   => $self->type,
 174   );
 175
 176   $self->redirect_to(@redirect_params);
 177 }
 178
 179 # save the order
 180 sub action_save {
 181   my ($self) = @_;
 182
 183   my $errors = $self->save();
 184
 185   if (scalar @{ $errors }) {
 186     $self->js->flash('error', $_) foreach @{ $errors };
 187     return $self->js->render();
 188   }
 189
 190   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 191            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 192            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 193            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 194            : '';
 195   flash_later('info', $text);
 196
 197   my @redirect_params = (
 198     action => 'edit',
 199     type   => $self->type,
 200     id     => $self->order->id,
 201   );
 202
 203   $self->redirect_to(@redirect_params);
 204 }
 205
 206 # save the order as new document an open it for edit
 207 sub action_save_as_new {
 208   my ($self) = @_;
 209
 210   my $order = $self->order;
 211
 212   if (!$order->id) {
 213     $self->js->flash('error', t8('This object has not been saved yet.'));
 214     return $self->js->render();
 215   }
 216
 217   # load order from db to check if values changed
 218   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 219
 220   my %new_attrs;
 221   # Lets assign a new number if the user hasn't changed the previous one.
 222   # If it has been changed manually then use it as-is.
 223   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 224                         ? ''
 225                         : trim($order->number);
 226
 227   # Clear transdate unless changed
 228   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 229                         ? DateTime->today_local
 230                         : $order->transdate;
 231
 232   # Set new reqdate unless changed if it is enabled in client config
 233   if ($order->reqdate == $saved_order->reqdate) {
 234     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 235                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 236
 237     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 238         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 239       $new_attrs{reqdate} = '';
 240     } else {
 241       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 242     }
 243   } else {
 244     $new_attrs{reqdate} = $order->reqdate;
 245   }
 246
 247   # Update employee
 248   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 249
 250   # Create new record from current one
 251   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 252
 253   # no linked records on save as new
 254   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 255
 256   # save
 257   $self->action_save();
 258 }
 259
 260 # print the order
 261 #
 262 # This is called if "print" is pressed in the print dialog.
 263 # If PDF creation was requested and succeeded, the pdf is offered for download
 264 # via send_file (which uses ajax in this case).
 265 sub action_print {
 266   my ($self) = @_;
 267
 268   my $errors = $self->save();
 269
 270   if (scalar @{ $errors }) {
 271     $self->js->flash('error', $_) foreach @{ $errors };
 272     return $self->js->render();
 273   }
 274
 275   $self->js_reset_order_and_item_ids_after_save;
 276
 277   my $format      = $::form->{print_options}->{format};
 278   my $media       = $::form->{print_options}->{media};
 279   my $formname    = $::form->{print_options}->{formname};
 280   my $copies      = $::form->{print_options}->{copies};
 281   my $groupitems  = $::form->{print_options}->{groupitems};
 282   my $printer_id  = $::form->{print_options}->{printer_id};
 283
 284   # only PDF, OpenDocument & HTML for now
 285   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 286     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 287   }
 288
 289   # only screen or printer by now
 290   if (none { $media eq $_ } qw(screen printer)) {
 291     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 292   }
 293
 294   # create a form for generate_attachment_filename
 295   my $form   = Form->new;
 296   $form->{$self->nr_key()}  = $self->order->number;
 297   $form->{type}             = $self->type;
 298   $form->{format}           = $format;
 299   $form->{formname}         = $formname;
 300   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 301   my $doc_filename          = $form->generate_attachment_filename();
 302
 303   my $doc;
 304   my @errors = $self->generate_doc(\$doc, { format     => $format,
 305                                             formname   => $formname,
 306                                             language   => $self->order->language,
 307                                             printer_id => $printer_id,
 308                                             groupitems => $groupitems });
 309   if (scalar @errors) {
 310     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 311   }
 312
 313   if ($media eq 'screen') {
 314     # screen/download
 315     $self->js->flash('info', t8('The document has been created.'));
 316     $self->send_file(
 317       \$doc,
 318       type         => SL::MIME->mime_type_from_ext($doc_filename),
 319       name         => $doc_filename,
 320       js_no_render => 1,
 321     );
 322
 323   } elsif ($media eq 'printer') {
 324     # printer
 325     my $printer_id = $::form->{print_options}->{printer_id};
 326     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 327       copies  => $copies,
 328       content => $doc,
 329     );
 330
 331     $self->js->flash('info', t8('The document has been printed.'));
 332   }
 333
 334   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 335   if (scalar @warnings) {
 336     $self->js->flash('warning', $_) for @warnings;
 337   }
 338
 339   $self->save_history('PRINTED');
 340
 341   $self->js
 342     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 343     ->render;
 344 }
 345 sub action_preview_pdf {
 346   my ($self) = @_;
 347
 348   my $errors = $self->save();
 349   if (scalar @{ $errors }) {
 350     $self->js->flash('error', $_) foreach @{ $errors };
 351     return $self->js->render();
 352   }
 353
 354   $self->js_reset_order_and_item_ids_after_save;
 355
 356   my $format      = 'pdf';
 357   my $media       = 'screen';
 358   my $formname    = $self->type;
 359
 360   # only pdf
 361   # create a form for generate_attachment_filename
 362   my $form   = Form->new;
 363   $form->{$self->nr_key()}  = $self->order->number;
 364   $form->{type}             = $self->type;
 365   $form->{format}           = $format;
 366   $form->{formname}         = $formname;
 367   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 368   my $pdf_filename          = $form->generate_attachment_filename();
 369
 370   my $pdf;
 371   my @errors = $self->generate_doc(\$pdf, { format     => $format,
 372                                             formname   => $formname,
 373                                             language   => $self->order->language,
 374                                           });
 375   if (scalar @errors) {
 376     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 377   }
 378   $self->save_history('PREVIEWED');
 379   $self->js->flash('info', t8('The PDF has been previewed'));
 380   # screen/download
 381   $self->send_file(
 382     \$pdf,
 383     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 384     name         => $pdf_filename,
 385     js_no_render => 0,
 386   );
 387 }
 388
 389 # open the email dialog
 390 sub action_save_and_show_email_dialog {
 391   my ($self) = @_;
 392
 393   my $errors = $self->save();
 394
 395   if (scalar @{ $errors }) {
 396     $self->js->flash('error', $_) foreach @{ $errors };
 397     return $self->js->render();
 398   }
 399
 400   my $cv_method = $self->cv;
 401
 402   if (!$self->order->$cv_method) {
 403     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 404                     ->render($self);
 405   }
 406
 407   my $email_form;
 408   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 409   $email_form->{to} ||= $self->order->$cv_method->email;
 410   $email_form->{cc}   = $self->order->$cv_method->cc;
 411   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 412   # Todo: get addresses from shipto, if any
 413
 414   my $form = Form->new;
 415   $form->{$self->nr_key()}  = $self->order->number;
 416   $form->{cusordnumber}     = $self->order->cusordnumber;
 417   $form->{formname}         = $self->type;
 418   $form->{type}             = $self->type;
 419   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 420   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 421   $form->{format}           = 'pdf';
 422   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 423
 424   $email_form->{subject}             = $form->generate_email_subject();
 425   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 426   $email_form->{message}             = $form->generate_email_body();
 427   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 428
 429   my %files = $self->get_files_for_email_dialog();
 430
 431   my @employees_with_email = grep {
 432     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 433     $user && !!trim($user->get_config_value('email'));
 434   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 435
 436   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 437                                   email_form    => $email_form,
 438                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 439                                   FILES         => \%files,
 440                                   is_customer   => $self->cv eq 'customer',
 441                                   ALL_EMPLOYEES => \@employees_with_email,
 442   );
 443
 444   $self->js
 445       ->run('kivi.Order.show_email_dialog', $dialog_html)
 446       ->reinit_widgets
 447       ->render($self);
 448 }
 449
 450 # send email
 451 #
 452 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 453 sub action_send_email {
 454   my ($self) = @_;
 455
 456   my $errors = $self->save();
 457
 458   if (scalar @{ $errors }) {
 459     $self->js->run('kivi.Order.close_email_dialog');
 460     $self->js->flash('error', $_) foreach @{ $errors };
 461     return $self->js->render();
 462   }
 463
 464   $self->js_reset_order_and_item_ids_after_save;
 465
 466   my $email_form  = delete $::form->{email_form};
 467   my %field_names = (to => 'email');
 468
 469   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 470
 471   # for Form::cleanup which may be called in Form::send_email
 472   $::form->{cwd}    = getcwd();
 473   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 474
 475   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 476   $::form->{media}  = 'email';
 477
 478   $::form->{attachment_policy} //= '';
 479
 480   # Is an old file version available?
 481   my $attfile;
 482   if ($::form->{attachment_policy} eq 'old_file') {
 483     $attfile = SL::File->get_all(object_id     => $self->order->id,
 484                                  object_type   => $self->type,
 485                                  file_type     => 'document',
 486                                  print_variant => $::form->{formname});
 487   }
 488
 489   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 490     my $doc;
 491     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 492                                              format     => $::form->{print_options}->{format},
 493                                              formname   => $::form->{print_options}->{formname},
 494                                              language   => $self->order->language,
 495                                              printer_id => $::form->{print_options}->{printer_id},
 496                                              groupitems => $::form->{print_options}->{groupitems}});
 497     if (scalar @errors) {
 498       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 499     }
 500
 501     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 502     if (scalar @warnings) {
 503       flash_later('warning', $_) for @warnings;
 504     }
 505
 506     my $sfile = SL::SessionFile::Random->new(mode => "w");
 507     $sfile->fh->print($doc);
 508     $sfile->fh->close;
 509
 510     $::form->{tmpfile} = $sfile->file_name;
 511     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 512   }
 513
 514   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 515   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 516
 517   # internal notes
 518   my $intnotes = $self->order->intnotes;
 519   $intnotes   .= "\n\n" if $self->order->intnotes;
 520   $intnotes   .= t8('[email]')                                                                                        . "\n";
 521   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 522   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 523   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 524   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 525   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 526   $intnotes   .= t8('Message')    . ": " . SL::HTML::Util->strip($::form->{message});
 527
 528   $self->order->update_attributes(intnotes => $intnotes);
 529
 530   $self->save_history('MAILED');
 531
 532   flash_later('info', t8('The email has been sent.'));
 533
 534   my @redirect_params = (
 535     action => 'edit',
 536     type   => $self->type,
 537     id     => $self->order->id,
 538   );
 539
 540   $self->redirect_to(@redirect_params);
 541 }
 542
 543 # open the periodic invoices config dialog
 544 #
 545 # If there are values in the form (i.e. dialog was opened before),
 546 # then use this values. Create new ones, else.
 547 sub action_show_periodic_invoices_config_dialog {
 548   my ($self) = @_;
 549
 550   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 551   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 552   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 553                                                    order_value_periodicity => 'p', # = same as periodicity
 554                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 555                                                    extend_automatically_by => 12,
 556                                                    active                  => 1,
 557                                                    email_subject           => GenericTranslations->get(
 558                                                                                 language_id      => $::form->{language_id},
 559                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 560                                                    email_body              => GenericTranslations->get(
 561                                                                                 language_id      => $::form->{language_id},
 562                                                                                 translation_type => "salutation_general")
 563                                                                             . GenericTranslations->get(
 564                                                                                 language_id      => $::form->{language_id},
 565                                                                                 translation_type => "salutation_punctuation_mark") . "\n\n"
 566                                                                             . GenericTranslations->get(
 567                                                                                 language_id      => $::form->{language_id},
 568                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 569   );
 570   # for older configs, replace email preset text if not yet set.
 571   $config->email_subject(GenericTranslations->get(
 572                                               language_id      => $::form->{language_id},
 573                                               translation_type =>"preset_text_periodic_invoices_email_subject")
 574                         ) unless $config->email_subject;
 575
 576   $config->email_body(GenericTranslations->get(
 577                                               language_id      => $::form->{language_id},
 578                                               translation_type => "salutation_general")
 579                     . GenericTranslations->get(
 580                                               language_id      => $::form->{language_id},
 581                                               translation_type => "salutation_punctuation_mark") . "\n\n"
 582                     . GenericTranslations->get(
 583                                               language_id      => $::form->{language_id},
 584                                               translation_type =>"preset_text_periodic_invoices_email_body")
 585                      ) unless $config->email_body;
 586
 587   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 588   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 589
 590   $::form->get_lists(printers => "ALL_PRINTERS",
 591                      charts   => { key       => 'ALL_CHARTS',
 592                                    transdate => 'current_date' });
 593
 594   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 595
 596   if ($::form->{customer_id}) {
 597     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 598     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 599     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 600     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 601     $config->send_email(0) if $::form->{postal_invoice};
 602   }
 603
 604   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 605                 popup_dialog             => 1,
 606                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 607                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 608                 config                   => $config,
 609                 %$::form);
 610 }
 611
 612 # assign the values of the periodic invoices config dialog
 613 # as yaml in the hidden tag and set the status.
 614 sub action_assign_periodic_invoices_config {
 615   my ($self) = @_;
 616
 617   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 618
 619   my $config = { active                     => $::form->{active}       ? 1 : 0,
 620                  terminated                 => $::form->{terminated}   ? 1 : 0,
 621                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 622                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 623                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 624                  start_date_as_date         => $::form->{start_date_as_date},
 625                  end_date_as_date           => $::form->{end_date_as_date},
 626                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 627                  print                      => $::form->{print}      ? 1                         : 0,
 628                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 629                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 630                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 631                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 632                  send_email                 => $::form->{send_email} ? 1 : 0,
 633                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 634                  email_recipient_address    => $::form->{email_recipient_address},
 635                  email_sender               => $::form->{email_sender},
 636                  email_subject              => $::form->{email_subject},
 637                  email_body                 => $::form->{email_body},
 638                };
 639
 640   my $periodic_invoices_config = SL::YAML::Dump($config);
 641
 642   my $status = $self->get_periodic_invoices_status($config);
 643
 644   $self->js
 645     ->remove('#order_periodic_invoices_config')
 646     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 647     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 648     ->html('#periodic_invoices_status', $status)
 649     ->flash('info', t8('The periodic invoices config has been assigned.'))
 650     ->render($self);
 651 }
 652
 653 sub action_get_has_active_periodic_invoices {
 654   my ($self) = @_;
 655
 656   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 657   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 658
 659   my $has_active_periodic_invoices =
 660        $self->type eq sales_order_type()
 661     && $config
 662     && $config->active
 663     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 664     && $config->get_previous_billed_period_start_date;
 665
 666   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 667 }
 668
 669 # save the order and redirect to the frontend subroutine for a new
 670 # delivery order
 671 sub action_save_and_delivery_order {
 672   my ($self) = @_;
 673
 674   $self->save_and_redirect_to(
 675     controller => 'oe.pl',
 676     action     => 'oe_delivery_order_from_order',
 677   );
 678 }
 679
 680 # save the order and redirect to the frontend subroutine for a new
 681 # invoice
 682 sub action_save_and_invoice {
 683   my ($self) = @_;
 684
 685   $self->save_and_redirect_to(
 686     controller => 'oe.pl',
 687     action     => 'oe_invoice_from_order',
 688   );
 689 }
 690
 691 # workflow from sales order to sales quotation
 692 sub action_sales_quotation {
 693   $_[0]->workflow_sales_or_request_for_quotation();
 694 }
 695
 696 # workflow from sales order to sales quotation
 697 sub action_request_for_quotation {
 698   $_[0]->workflow_sales_or_request_for_quotation();
 699 }
 700
 701 # workflow from sales quotation to sales order
 702 sub action_sales_order {
 703   $_[0]->workflow_sales_or_purchase_order();
 704 }
 705
 706 # workflow from rfq to purchase order
 707 sub action_purchase_order {
 708   $_[0]->workflow_sales_or_purchase_order();
 709 }
 710
 711 # workflow from purchase order to ap transaction
 712 sub action_save_and_ap_transaction {
 713   my ($self) = @_;
 714
 715   $self->save_and_redirect_to(
 716     controller => 'ap.pl',
 717     action     => 'add_from_purchase_order',
 718   );
 719 }
 720
 721 # set form elements in respect to a changed customer or vendor
 722 #
 723 # This action is called on an change of the customer/vendor picker.
 724 sub action_customer_vendor_changed {
 725   my ($self) = @_;
 726
 727   setup_order_from_cv($self->order);
 728   $self->recalc();
 729
 730   my $cv_method = $self->cv;
 731
 732   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 733     $self->js->show('#cp_row');
 734   } else {
 735     $self->js->hide('#cp_row');
 736   }
 737
 738   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 739     $self->js->show('#shipto_selection');
 740   } else {
 741     $self->js->hide('#shipto_selection');
 742   }
 743
 744   if ($cv_method eq 'customer') {
 745     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 746     $self->js->$show_hide('#billing_address_row');
 747   }
 748
 749   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 750
 751   $self->js
 752     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 753     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 754     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 755     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 756     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 757     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 758     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 759     ->val(        '#order_currency_id',        $self->order->currency_id)
 760     ->val(        '#order_payment_id',         $self->order->payment_id)
 761     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 762     ->val(        '#order_intnotes',           $self->order->intnotes)
 763     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 764     ->focus(      '#order_' . $self->cv . '_id')
 765     ->run('kivi.Order.update_exchangerate');
 766
 767   $self->js_redisplay_amounts_and_taxes;
 768   $self->js_redisplay_cvpartnumbers;
 769   $self->js->render();
 770 }
 771
 772 # open the dialog for customer/vendor details
 773 sub action_show_customer_vendor_details_dialog {
 774   my ($self) = @_;
 775
 776   my $is_customer = 'customer' eq $::form->{vc};
 777   my $cv;
 778   if ($is_customer) {
 779     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 780   } else {
 781     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 782   }
 783
 784   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 785   $details{discount_as_percent} = $cv->discount_as_percent;
 786   $details{creditlimt}          = $cv->creditlimit_as_number;
 787   $details{business}            = $cv->business->description      if $cv->business;
 788   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 789   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 790   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 791   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 792
 793   if ($is_customer) {
 794     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 795       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 796     }
 797   }
 798   foreach my $entry (@{ $cv->shipto }) {
 799     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 800   }
 801   foreach my $entry (@{ $cv->contacts }) {
 802     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 803   }
 804
 805   $_[0]->render('common/show_vc_details', { layout => 0 },
 806                 is_customer => $is_customer,
 807                 %details);
 808
 809 }
 810
 811 # called if a unit in an existing item row is changed
 812 sub action_unit_changed {
 813   my ($self) = @_;
 814
 815   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 816   my $item = $self->order->items_sorted->[$idx];
 817
 818   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 819   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 820
 821   $self->recalc();
 822
 823   $self->js
 824     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 825   $self->js_redisplay_line_values;
 826   $self->js_redisplay_amounts_and_taxes;
 827   $self->js->render();
 828 }
 829
 830 # add an item row for a new item entered in the input row
 831 sub action_add_item {
 832   my ($self) = @_;
 833
 834   delete $::form->{add_item}->{create_part_type};
 835
 836   my $form_attr = $::form->{add_item};
 837
 838   return unless $form_attr->{parts_id};
 839
 840   my $item = new_item($self->order, $form_attr);
 841
 842   $self->order->add_items($item);
 843
 844   $self->recalc();
 845
 846   $self->get_item_cvpartnumber($item);
 847
 848   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 849   my $row_as_html = $self->p->render('order/tabs/_row',
 850                                      ITEM => $item,
 851                                      ID   => $item_id,
 852                                      SELF => $self,
 853   );
 854
 855   if ($::form->{insert_before_item_id}) {
 856     $self->js
 857       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 858   } else {
 859     $self->js
 860       ->append('#row_table_id', $row_as_html);
 861   }
 862
 863   if ( $item->part->is_assortment ) {
 864     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 865     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 866       my $attr = { parts_id => $assortment_item->parts_id,
 867                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 868                    unit     => $assortment_item->unit,
 869                    description => $assortment_item->part->description,
 870                  };
 871       my $item = new_item($self->order, $attr);
 872
 873       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 874       $item->discount(1) unless $assortment_item->charge;
 875
 876       $self->order->add_items( $item );
 877       $self->recalc();
 878       $self->get_item_cvpartnumber($item);
 879       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 880       my $row_as_html = $self->p->render('order/tabs/_row',
 881                                          ITEM => $item,
 882                                          ID   => $item_id,
 883                                          SELF => $self,
 884       );
 885       if ($::form->{insert_before_item_id}) {
 886         $self->js
 887           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 888       } else {
 889         $self->js
 890           ->append('#row_table_id', $row_as_html);
 891       }
 892     };
 893   };
 894
 895   $self->js
 896     ->val('.add_item_input', '')
 897     ->run('kivi.Order.init_row_handlers')
 898     ->run('kivi.Order.renumber_positions')
 899     ->focus('#add_item_parts_id_name');
 900
 901   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 902
 903   $self->js_redisplay_amounts_and_taxes;
 904   $self->js->render();
 905 }
 906
 907 # add item rows for multiple items at once
 908 sub action_add_multi_items {
 909   my ($self) = @_;
 910
 911   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 912   return $self->js->render() unless scalar @form_attr;
 913
 914   my @items;
 915   foreach my $attr (@form_attr) {
 916     my $item = new_item($self->order, $attr);
 917     push @items, $item;
 918     if ( $item->part->is_assortment ) {
 919       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 920         my $attr = { parts_id => $assortment_item->parts_id,
 921                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 922                      unit     => $assortment_item->unit,
 923                      description => $assortment_item->part->description,
 924                    };
 925         my $item = new_item($self->order, $attr);
 926
 927         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 928         $item->discount(1) unless $assortment_item->charge;
 929         push @items, $item;
 930       }
 931     }
 932   }
 933   $self->order->add_items(@items);
 934
 935   $self->recalc();
 936
 937   foreach my $item (@items) {
 938     $self->get_item_cvpartnumber($item);
 939     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 940     my $row_as_html = $self->p->render('order/tabs/_row',
 941                                        ITEM => $item,
 942                                        ID   => $item_id,
 943                                        SELF => $self,
 944     );
 945
 946     if ($::form->{insert_before_item_id}) {
 947       $self->js
 948         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 949     } else {
 950       $self->js
 951         ->append('#row_table_id', $row_as_html);
 952     }
 953   }
 954
 955   $self->js
 956     ->run('kivi.Part.close_picker_dialogs')
 957     ->run('kivi.Order.init_row_handlers')
 958     ->run('kivi.Order.renumber_positions')
 959     ->focus('#add_item_parts_id_name');
 960
 961   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 962
 963   $self->js_redisplay_amounts_and_taxes;
 964   $self->js->render();
 965 }
 966
 967 # recalculate all linetotals, amounts and taxes and redisplay them
 968 sub action_recalc_amounts_and_taxes {
 969   my ($self) = @_;
 970
 971   $self->recalc();
 972
 973   $self->js_redisplay_line_values;
 974   $self->js_redisplay_amounts_and_taxes;
 975   $self->js->render();
 976 }
 977
 978 sub action_update_exchangerate {
 979   my ($self) = @_;
 980
 981   my $data = {
 982     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 983     currency_name => $self->order->currency->name,
 984     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 985   };
 986
 987   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 988 }
 989
 990 # redisplay item rows if they are sorted by an attribute
 991 sub action_reorder_items {
 992   my ($self) = @_;
 993
 994   my %sort_keys = (
 995     partnumber   => sub { $_[0]->part->partnumber },
 996     description  => sub { $_[0]->description },
 997     qty          => sub { $_[0]->qty },
 998     sellprice    => sub { $_[0]->sellprice },
 999     discount     => sub { $_[0]->discount },
1000     cvpartnumber => sub { $_[0]->{cvpartnumber} },
1001   );
1002
1003   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1004
1005   my $method = $sort_keys{$::form->{order_by}};
1006   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
1007   if ($::form->{sort_dir}) {
1008     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1009       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
1010     } else {
1011       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
1012     }
1013   } else {
1014     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1015       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
1016     } else {
1017       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
1018     }
1019   }
1020   $self->js
1021     ->run('kivi.Order.redisplay_items', \@to_sort)
1022     ->render;
1023 }
1024
1025 # show the popup to choose a price/discount source
1026 sub action_price_popup {
1027   my ($self) = @_;
1028
1029   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1030   my $item = $self->order->items_sorted->[$idx];
1031
1032   $self->render_price_dialog($item);
1033 }
1034
1035 # save the order in a session variable and redirect to the part controller
1036 sub action_create_part {
1037   my ($self) = @_;
1038
1039   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1040
1041   my $callback     = $self->url_for(
1042     action       => 'return_from_create_part',
1043     type         => $self->type, # type is needed for check_auth on return
1044     previousform => $previousform,
1045   );
1046
1047   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1048
1049   my @redirect_params = (
1050     controller => 'Part',
1051     action     => 'add',
1052     part_type  => $::form->{add_item}->{create_part_type},
1053     callback   => $callback,
1054     show_abort => 1,
1055   );
1056
1057   $self->redirect_to(@redirect_params);
1058 }
1059
1060 sub action_return_from_create_part {
1061   my ($self) = @_;
1062
1063   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1064
1065   $::auth->restore_form_from_session(delete $::form->{previousform});
1066
1067   # set item ids to new fake id, to identify them as new items
1068   foreach my $item (@{$self->order->items_sorted}) {
1069     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1070   }
1071
1072   $self->recalc();
1073   $self->get_unalterable_data();
1074   $self->pre_render();
1075
1076   # trigger rendering values for second row/longdescription as hidden,
1077   # because they are loaded only on demand. So we need to keep the values
1078   # from the source.
1079   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1080   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1081
1082   $self->render(
1083     'order/form',
1084     title => $self->get_title_for('edit'),
1085     %{$self->{template_args}}
1086   );
1087
1088 }
1089
1090 # load the second row for one or more items
1091 #
1092 # This action gets the html code for all items second rows by rendering a template for
1093 # the second row and sets the html code via client js.
1094 sub action_load_second_rows {
1095   my ($self) = @_;
1096
1097   $self->recalc() if $self->order->is_sales; # for margin calculation
1098
1099   foreach my $item_id (@{ $::form->{item_ids} }) {
1100     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1101     my $item = $self->order->items_sorted->[$idx];
1102
1103     $self->js_load_second_row($item, $item_id, 0);
1104   }
1105
1106   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1107
1108   $self->js->render();
1109 }
1110
1111 # update description, notes and sellprice from master data
1112 sub action_update_row_from_master_data {
1113   my ($self) = @_;
1114
1115   foreach my $item_id (@{ $::form->{item_ids} }) {
1116     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1117     my $item  = $self->order->items_sorted->[$idx];
1118     my $texts = get_part_texts($item->part, $self->order->language_id);
1119
1120     $item->description($texts->{description});
1121     $item->longdescription($texts->{longdescription});
1122
1123     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1124
1125     my $price_src;
1126     if ($item->part->is_assortment) {
1127     # add assortment items with price 0, as the components carry the price
1128       $price_src = $price_source->price_from_source("");
1129       $price_src->price(0);
1130     } else {
1131       $price_src = $price_source->best_price
1132                  ? $price_source->best_price
1133                  : $price_source->price_from_source("");
1134       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1135       $price_src->price(0) if !$price_source->best_price;
1136     }
1137
1138
1139     $item->sellprice($price_src->price);
1140     $item->active_price_source($price_src);
1141
1142     $self->js
1143       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1144       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1145       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1146       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1147
1148     if ($self->search_cvpartnumber) {
1149       $self->get_item_cvpartnumber($item);
1150       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1151     }
1152   }
1153
1154   $self->recalc();
1155   $self->js_redisplay_line_values;
1156   $self->js_redisplay_amounts_and_taxes;
1157
1158   $self->js->render();
1159 }
1160
1161 sub js_load_second_row {
1162   my ($self, $item, $item_id, $do_parse) = @_;
1163
1164   if ($do_parse) {
1165     # Parse values from form (they are formated while rendering (template)).
1166     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1167     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1168     foreach my $var (@{ $item->cvars_by_config }) {
1169       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1170     }
1171     $item->parse_custom_variable_values;
1172   }
1173
1174   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1175
1176   $self->js
1177     ->html('#second_row_' . $item_id, $row_as_html)
1178     ->data('#second_row_' . $item_id, 'loaded', 1);
1179 }
1180
1181 sub js_redisplay_line_values {
1182   my ($self) = @_;
1183
1184   my $is_sales = $self->order->is_sales;
1185
1186   # sales orders with margins
1187   my @data;
1188   if ($is_sales) {
1189     @data = map {
1190       [
1191        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1192        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1193        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1194       ]} @{ $self->order->items_sorted };
1195   } else {
1196     @data = map {
1197       [
1198        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1199       ]} @{ $self->order->items_sorted };
1200   }
1201
1202   $self->js
1203     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1204 }
1205
1206 sub js_redisplay_amounts_and_taxes {
1207   my ($self) = @_;
1208
1209   if (scalar @{ $self->{taxes} }) {
1210     $self->js->show('#taxincluded_row_id');
1211   } else {
1212     $self->js->hide('#taxincluded_row_id');
1213   }
1214
1215   if ($self->order->taxincluded) {
1216     $self->js->hide('#subtotal_row_id');
1217   } else {
1218     $self->js->show('#subtotal_row_id');
1219   }
1220
1221   if ($self->order->is_sales) {
1222     my $is_neg = $self->order->marge_total < 0;
1223     $self->js
1224       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1225       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1226       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1227       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1228       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1229       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1230       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1231       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1232   }
1233
1234   $self->js
1235     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1236     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1237     ->remove('.tax_row')
1238     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1239 }
1240
1241 sub js_redisplay_cvpartnumbers {
1242   my ($self) = @_;
1243
1244   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1245
1246   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1247
1248   $self->js
1249     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1250 }
1251
1252 sub js_reset_order_and_item_ids_after_save {
1253   my ($self) = @_;
1254
1255   $self->js
1256     ->val('#id', $self->order->id)
1257     ->val('#converted_from_oe_id', '')
1258     ->val('#order_' . $self->nr_key(), $self->order->number);
1259
1260   my $idx = 0;
1261   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1262     next if !$self->order->items_sorted->[$idx]->id;
1263     next if $form_item_id !~ m{^new};
1264     $self->js
1265       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1266       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1267       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1268   } continue {
1269     $idx++;
1270   }
1271   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1272 }
1273
1274 #
1275 # helpers
1276 #
1277
1278 sub init_valid_types {
1279   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1280 }
1281
1282 sub init_type {
1283   my ($self) = @_;
1284
1285   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1286     die "Not a valid type for order";
1287   }
1288
1289   $self->type($::form->{type});
1290 }
1291
1292 sub init_cv {
1293   my ($self) = @_;
1294
1295   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1296          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1297          : die "Not a valid type for order";
1298
1299   return $cv;
1300 }
1301
1302 sub init_search_cvpartnumber {
1303   my ($self) = @_;
1304
1305   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1306   my $search_cvpartnumber;
1307   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1308   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1309
1310   return $search_cvpartnumber;
1311 }
1312
1313 sub init_show_update_button {
1314   my ($self) = @_;
1315
1316   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1317 }
1318
1319 sub init_p {
1320   SL::Presenter->get;
1321 }
1322
1323 sub init_order {
1324   $_[0]->make_order;
1325 }
1326
1327 sub init_all_price_factors {
1328   SL::DB::Manager::PriceFactor->get_all;
1329 }
1330
1331 sub init_part_picker_classification_ids {
1332   my ($self)    = @_;
1333   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1334
1335   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1336 }
1337
1338 sub check_auth {
1339   my ($self) = @_;
1340
1341   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1342
1343   my $right   = $right_for->{ $self->type };
1344   $right    ||= 'DOES_NOT_EXIST';
1345
1346   $::auth->assert($right);
1347 }
1348
1349 # build the selection box for contacts
1350 #
1351 # Needed, if customer/vendor changed.
1352 sub build_contact_select {
1353   my ($self) = @_;
1354
1355   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1356     value_key  => 'cp_id',
1357     title_key  => 'full_name_dep',
1358     default    => $self->order->cp_id,
1359     with_empty => 1,
1360     style      => 'width: 300px',
1361   );
1362 }
1363
1364 # build the selection box for the additional billing address
1365 #
1366 # Needed, if customer/vendor changed.
1367 sub build_billing_address_select {
1368   my ($self) = @_;
1369
1370   return '' if $self->cv ne 'customer';
1371
1372   select_tag('order.billing_address_id',
1373              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1374              value_key  => 'id',
1375              title_key  => 'displayable_id',
1376              default    => $self->order->billing_address_id,
1377              with_empty => 0,
1378              style      => 'width: 300px',
1379   );
1380 }
1381
1382 # build the selection box for shiptos
1383 #
1384 # Needed, if customer/vendor changed.
1385 sub build_shipto_select {
1386   my ($self) = @_;
1387
1388   select_tag('order.shipto_id',
1389              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1390              value_key  => 'shipto_id',
1391              title_key  => 'displayable_id',
1392              default    => $self->order->shipto_id,
1393              with_empty => 0,
1394              style      => 'width: 300px',
1395   );
1396 }
1397
1398 # build the inputs for the cusom shipto dialog
1399 #
1400 # Needed, if customer/vendor changed.
1401 sub build_shipto_inputs {
1402   my ($self) = @_;
1403
1404   my $content = $self->p->render('common/_ship_to_dialog',
1405                                  vc_obj      => $self->order->customervendor,
1406                                  cs_obj      => $self->order->custom_shipto,
1407                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1408                                  id_selector => '#order_shipto_id');
1409
1410   div_tag($content, id => 'shipto_inputs');
1411 }
1412
1413 # render the info line for business
1414 #
1415 # Needed, if customer/vendor changed.
1416 sub build_business_info_row
1417 {
1418   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1419 }
1420
1421 # build the rows for displaying taxes
1422 #
1423 # Called if amounts where recalculated and redisplayed.
1424 sub build_tax_rows {
1425   my ($self) = @_;
1426
1427   my $rows_as_html;
1428   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1429     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1430   }
1431   return $rows_as_html;
1432 }
1433
1434
1435 sub render_price_dialog {
1436   my ($self, $record_item) = @_;
1437
1438   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1439
1440   $self->js
1441     ->run(
1442       'kivi.io.price_chooser_dialog',
1443       t8('Available Prices'),
1444       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1445     )
1446     ->reinit_widgets;
1447
1448 #   if (@errors) {
1449 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1450 #     $self->js->show('#dialog_flash_error');
1451 #   }
1452
1453   $self->js->render;
1454 }
1455
1456 sub load_order {
1457   my ($self) = @_;
1458
1459   return if !$::form->{id};
1460
1461   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1462
1463   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1464   # You need a custom shipto object to call cvars_by_config to get the cvars.
1465   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1466
1467   return $self->order;
1468 }
1469
1470 # load or create a new order object
1471 #
1472 # And assign changes from the form to this object.
1473 # If the order is loaded from db, check if items are deleted in the form,
1474 # remove them form the object and collect them for removing from db on saving.
1475 # Then create/update items from form (via make_item) and add them.
1476 sub make_order {
1477   my ($self) = @_;
1478
1479   # add_items adds items to an order with no items for saving, but they cannot
1480   # be retrieved via items until the order is saved. Adding empty items to new
1481   # order here solves this problem.
1482   my $order;
1483   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1484   $order ||= SL::DB::Order->new(orderitems  => [],
1485                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1486                                 currency_id => $::instance_conf->get_currency_id(),);
1487
1488   my $cv_id_method = $self->cv . '_id';
1489   if (!$::form->{id} && $::form->{$cv_id_method}) {
1490     $order->$cv_id_method($::form->{$cv_id_method});
1491     setup_order_from_cv($order);
1492   }
1493
1494   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1495   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1496
1497   $order->assign_attributes(%{$::form->{order}});
1498
1499   $self->setup_custom_shipto_from_form($order, $::form);
1500
1501   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1502     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1503     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1504   }
1505
1506   # remove deleted items
1507   $self->item_ids_to_delete([]);
1508   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1509     my $item = $order->orderitems->[$idx];
1510     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1511       splice @{$order->orderitems}, $idx, 1;
1512       push @{$self->item_ids_to_delete}, $item->id;
1513     }
1514   }
1515
1516   my @items;
1517   my $pos = 1;
1518   foreach my $form_attr (@{$form_orderitems}) {
1519     my $item = make_item($order, $form_attr);
1520     $item->position($pos);
1521     push @items, $item;
1522     $pos++;
1523   }
1524   $order->add_items(grep {!$_->id} @items);
1525
1526   return $order;
1527 }
1528
1529 # create or update items from form
1530 #
1531 # Make item objects from form values. For items already existing read from db.
1532 # Create a new item else. And assign attributes.
1533 sub make_item {
1534   my ($record, $attr) = @_;
1535
1536   my $item;
1537   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1538
1539   my $is_new = !$item;
1540
1541   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1542   # they cannot be retrieved via custom_variables until the order/orderitem is
1543   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1544   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1545
1546   $item->assign_attributes(%$attr);
1547
1548   if ($is_new) {
1549     my $texts = get_part_texts($item->part, $record->language_id);
1550     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1551     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1552     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1553   }
1554
1555   return $item;
1556 }
1557
1558 # create a new item
1559 #
1560 # This is used to add one item
1561 sub new_item {
1562   my ($record, $attr) = @_;
1563
1564   my $item = SL::DB::OrderItem->new;
1565
1566   # Remove attributes where the user left or set the inputs empty.
1567   # So these attributes will be undefined and we can distinguish them
1568   # from zero later on.
1569   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1570     delete $attr->{$_} if $attr->{$_} eq '';
1571   }
1572
1573   $item->assign_attributes(%$attr);
1574
1575   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1576   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1577
1578   $item->unit($part->unit) if !$item->unit;
1579
1580   my $price_src;
1581   if ( $part->is_assortment ) {
1582     # add assortment items with price 0, as the components carry the price
1583     $price_src = $price_source->price_from_source("");
1584     $price_src->price(0);
1585   } elsif (defined $item->sellprice) {
1586     $price_src = $price_source->price_from_source("");
1587     $price_src->price($item->sellprice);
1588   } else {
1589     $price_src = $price_source->best_price
1590                ? $price_source->best_price
1591                : $price_source->price_from_source("");
1592     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1593     $price_src->price(0) if !$price_source->best_price;
1594   }
1595
1596   my $discount_src;
1597   if (defined $item->discount) {
1598     $discount_src = $price_source->discount_from_source("");
1599     $discount_src->discount($item->discount);
1600   } else {
1601     $discount_src = $price_source->best_discount
1602                   ? $price_source->best_discount
1603                   : $price_source->discount_from_source("");
1604     $discount_src->discount(0) if !$price_source->best_discount;
1605   }
1606
1607   my %new_attr;
1608   $new_attr{part}                   = $part;
1609   $new_attr{description}            = $part->description     if ! $item->description;
1610   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1611   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1612   $new_attr{sellprice}              = $price_src->price;
1613   $new_attr{discount}               = $discount_src->discount;
1614   $new_attr{active_price_source}    = $price_src;
1615   $new_attr{active_discount_source} = $discount_src;
1616   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1617   $new_attr{project_id}             = $record->globalproject_id;
1618   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1619
1620   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1621   # they cannot be retrieved via custom_variables until the order/orderitem is
1622   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1623   $new_attr{custom_variables} = [];
1624
1625   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1626
1627   $item->assign_attributes(%new_attr, %{ $texts });
1628
1629   return $item;
1630 }
1631
1632 sub setup_order_from_cv {
1633   my ($order) = @_;
1634
1635   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1636
1637   $order->intnotes($order->customervendor->notes);
1638
1639   return if !$order->is_sales;
1640
1641   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1642   $order->taxincluded(defined($order->customer->taxincluded_checked)
1643                       ? $order->customer->taxincluded_checked
1644                       : $::myconfig{taxincluded_checked});
1645
1646   my $address = $order->customer->default_billing_address;;
1647   $order->billing_address_id($address ? $address->id : undef);
1648 }
1649
1650 # setup custom shipto from form
1651 #
1652 # The dialog returns form variables starting with 'shipto' and cvars starting
1653 # with 'shiptocvar_'.
1654 # Mark it to be deleted if a shipto from master data is selected
1655 # (i.e. order has a shipto).
1656 # Else, update or create a new custom shipto. If the fields are empty, it
1657 # will not be saved on save.
1658 sub setup_custom_shipto_from_form {
1659   my ($self, $order, $form) = @_;
1660
1661   if ($order->shipto) {
1662     $self->is_custom_shipto_to_delete(1);
1663   } else {
1664     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1665
1666     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1667     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1668
1669     $custom_shipto->assign_attributes(%$shipto_attrs);
1670     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1671   }
1672 }
1673
1674 # recalculate prices and taxes
1675 #
1676 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1677 sub recalc {
1678   my ($self) = @_;
1679
1680   my %pat = $self->order->calculate_prices_and_taxes();
1681
1682   $self->{taxes} = [];
1683   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1684     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1685
1686     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1687                                 netamount => $netamount,
1688                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1689   }
1690   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1691 }
1692
1693 # get data for saving, printing, ..., that is not changed in the form
1694 #
1695 # Only cvars for now.
1696 sub get_unalterable_data {
1697   my ($self) = @_;
1698
1699   foreach my $item (@{ $self->order->items }) {
1700     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1701     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1702     foreach my $var (@{ $item->cvars_by_config }) {
1703       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1704     }
1705     $item->parse_custom_variable_values;
1706   }
1707 }
1708
1709 # delete the order
1710 #
1711 # And remove related files in the spool directory
1712 sub delete {
1713   my ($self) = @_;
1714
1715   my $errors = [];
1716   my $db     = $self->order->db;
1717
1718   $db->with_transaction(
1719     sub {
1720       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1721       $self->order->delete;
1722       my $spool = $::lx_office_conf{paths}->{spool};
1723       unlink map { "$spool/$_" } @spoolfiles if $spool;
1724
1725       $self->save_history('DELETED');
1726
1727       1;
1728   }) || push(@{$errors}, $db->error);
1729
1730   return $errors;
1731 }
1732
1733 # save the order
1734 #
1735 # And delete items that are deleted in the form.
1736 sub save {
1737   my ($self) = @_;
1738
1739   my $errors = [];
1740   my $db     = $self->order->db;
1741
1742   $db->with_transaction(sub {
1743     # delete custom shipto if it is to be deleted or if it is empty
1744     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1745       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1746       $self->order->custom_shipto(undef);
1747     }
1748
1749     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1750     $self->order->save(cascade => 1);
1751
1752     # link records
1753     if ($::form->{converted_from_oe_id}) {
1754       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1755
1756       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1757         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1758         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1759         $src->link_to_record($self->order);
1760       }
1761       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1762         my $idx = 0;
1763         foreach (@{ $self->order->items_sorted }) {
1764           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1765           next if !$from_id;
1766           SL::DB::RecordLink->new(from_table => 'orderitems',
1767                                   from_id    => $from_id,
1768                                   to_table   => 'orderitems',
1769                                   to_id      => $_->id
1770           )->save;
1771           $idx++;
1772         }
1773       }
1774
1775       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1776     }
1777
1778     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1779
1780     $self->save_history('SAVED');
1781
1782     1;
1783   }) || push(@{$errors}, $db->error);
1784
1785   return $errors;
1786 }
1787
1788 sub workflow_sales_or_request_for_quotation {
1789   my ($self) = @_;
1790
1791   # always save
1792   my $errors = $self->save();
1793
1794   if (scalar @{ $errors }) {
1795     $self->js->flash('error', $_) for @{ $errors };
1796     return $self->js->render();
1797   }
1798
1799   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1800
1801   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1802   $self->{converted_from_oe_id} = delete $::form->{id};
1803
1804   # set item ids to new fake id, to identify them as new items
1805   foreach my $item (@{$self->order->items_sorted}) {
1806     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1807   }
1808
1809   # change form type
1810   $::form->{type} = $destination_type;
1811   $self->type($self->init_type);
1812   $self->cv  ($self->init_cv);
1813   $self->check_auth;
1814
1815   $self->recalc();
1816   $self->get_unalterable_data();
1817   $self->pre_render();
1818
1819   # trigger rendering values for second row as hidden, because they
1820   # are loaded only on demand. So we need to keep the values from the
1821   # source.
1822   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1823
1824   $self->render(
1825     'order/form',
1826     title => $self->get_title_for('edit'),
1827     %{$self->{template_args}}
1828   );
1829 }
1830
1831 sub workflow_sales_or_purchase_order {
1832   my ($self) = @_;
1833
1834   # always save
1835   my $errors = $self->save();
1836
1837   if (scalar @{ $errors }) {
1838     $self->js->flash('error', $_) foreach @{ $errors };
1839     return $self->js->render();
1840   }
1841
1842   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1843                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1844                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1845                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1846                        : '';
1847
1848   # check for direct delivery
1849   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1850   my $custom_shipto;
1851   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1852       && $::form->{use_shipto} && $self->order->shipto) {
1853     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1854   }
1855
1856   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1857   $self->{converted_from_oe_id} = delete $::form->{id};
1858
1859   # set item ids to new fake id, to identify them as new items
1860   foreach my $item (@{$self->order->items_sorted}) {
1861     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1862   }
1863
1864   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1865     if ($::form->{use_shipto}) {
1866       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1867     } else {
1868       # remove any custom shipto if not wanted
1869       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1870     }
1871   }
1872
1873   # change form type
1874   $::form->{type} = $destination_type;
1875   $self->type($self->init_type);
1876   $self->cv  ($self->init_cv);
1877   $self->check_auth;
1878
1879   $self->recalc();
1880   $self->get_unalterable_data();
1881   $self->pre_render();
1882
1883   # trigger rendering values for second row as hidden, because they
1884   # are loaded only on demand. So we need to keep the values from the
1885   # source.
1886   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1887
1888   $self->render(
1889     'order/form',
1890     title => $self->get_title_for('edit'),
1891     %{$self->{template_args}}
1892   );
1893 }
1894
1895
1896 sub pre_render {
1897   my ($self) = @_;
1898
1899   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1900   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1901   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1902   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1903   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1904                                                                                               deleted => 0 ] ],
1905                                                                            sort_by => 'name');
1906   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1907                                                                                               deleted => 0 ] ],
1908                                                                            sort_by => 'name');
1909   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1910                                                                                                         obsolete => 0 ] ]);
1911   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1912   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1913   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1914   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1915   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1916
1917   my $print_form = Form->new('');
1918   $print_form->{type}        = $self->type;
1919   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1920   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1921     form => $print_form,
1922     options => {dialog_name_prefix => 'print_options.',
1923                 show_headers       => 1,
1924                 no_queue           => 1,
1925                 no_postscript      => 1,
1926                 no_opendocument    => 0,
1927                 no_html            => 0},
1928   );
1929
1930   foreach my $item (@{$self->order->orderitems}) {
1931     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1932     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1933     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1934   }
1935
1936   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1937     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1938     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1939     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1940     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1941   }
1942
1943   if ($self->order->number && $::instance_conf->get_webdav) {
1944     my $webdav = SL::Webdav->new(
1945       type     => $self->type,
1946       number   => $self->order->number,
1947     );
1948     my @all_objects = $webdav->get_all_objects;
1949     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1950                                                     type => t8('File'),
1951                                                     link => File::Spec->catfile($_->full_filedescriptor),
1952                                                 } } @all_objects;
1953   }
1954
1955   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1956       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1957     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1958   }
1959
1960   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1961
1962   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1963                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
1964   $self->setup_edit_action_bar;
1965 }
1966
1967 sub setup_edit_action_bar {
1968   my ($self, %params) = @_;
1969
1970   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1971                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1972                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1973
1974   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
1975   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
1976
1977   for my $bar ($::request->layout->get('actionbar')) {
1978     $bar->add(
1979       combobox => [
1980         action => [
1981           t8('Save'),
1982           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1983                                                     $::instance_conf->get_order_warn_no_deliverydate,
1984           ],
1985           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
1986                          @req_trans_cost_art, @req_cusordnumber,
1987           ],
1988         ],
1989         action => [
1990           t8('Save as new'),
1991           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1992           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1993                          @req_trans_cost_art, @req_cusordnumber,
1994           ],
1995           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1996         ],
1997       ], # end of combobox "Save"
1998
1999       combobox => [
2000         action => [
2001           t8('Workflow'),
2002         ],
2003         action => [
2004           t8('Save and Quotation'),
2005           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
2006           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2007           only_if  => (any { $self->type eq $_ } (sales_order_type())),
2008         ],
2009         action => [
2010           t8('Save and RFQ'),
2011           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
2012           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
2013         ],
2014         action => [
2015           t8('Save and Sales Order'),
2016           submit   => [ '#order_form', { action => "Order/sales_order" } ],
2017           checks   => [ @req_trans_cost_art ],
2018           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
2019         ],
2020         action => [
2021           t8('Save and Purchase Order'),
2022           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
2023           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2024           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2025         ],
2026         action => [
2027           t8('Save and Delivery Order'),
2028           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2029                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2030                                                                                                                         ],
2031           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2032                          @req_trans_cost_art, @req_cusordnumber,
2033           ],
2034           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
2035         ],
2036         action => [
2037           t8('Save and Invoice'),
2038           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2039           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2040                          @req_trans_cost_art, @req_cusordnumber,
2041           ],
2042         ],
2043         action => [
2044           t8('Save and AP Transaction'),
2045           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2046           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
2047         ],
2048
2049       ], # end of combobox "Workflow"
2050
2051       combobox => [
2052         action => [
2053           t8('Export'),
2054         ],
2055         action => [
2056           t8('Save and preview PDF'),
2057           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2058                                                         $::instance_conf->get_order_warn_no_deliverydate,
2059                     ],
2060           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2061         ],
2062         action => [
2063           t8('Save and print'),
2064           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2065                                                        $::instance_conf->get_order_warn_no_deliverydate,
2066                     ],
2067           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2068         ],
2069         action => [
2070           t8('Save and E-mail'),
2071           id   => 'save_and_email_action',
2072           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2073                                                                      $::instance_conf->get_order_warn_no_deliverydate,
2074                   ],
2075           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2076         ],
2077         action => [
2078           t8('Download attachments of all parts'),
2079           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2080           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2081           only_if  => $::instance_conf->get_doc_storage,
2082         ],
2083       ], # end of combobox "Export"
2084
2085       action => [
2086         t8('Delete'),
2087         call     => [ 'kivi.Order.delete_order' ],
2088         confirm  => $::locale->text('Do you really want to delete this object?'),
2089         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2090         only_if  => $deletion_allowed,
2091       ],
2092
2093       combobox => [
2094         action => [
2095           t8('more')
2096         ],
2097         action => [
2098           t8('History'),
2099           call     => [ 'set_history_window', $self->order->id, 'id' ],
2100           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2101         ],
2102         action => [
2103           t8('Follow-Up'),
2104           call     => [ 'kivi.Order.follow_up_window' ],
2105           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2106           only_if  => $::auth->assert('productivity', 1),
2107         ],
2108       ], # end of combobox "more"
2109     );
2110   }
2111 }
2112
2113 sub generate_doc {
2114   my ($self, $doc_ref, $params) = @_;
2115
2116   my $order  = $self->order;
2117   my @errors = ();
2118
2119   my $print_form = Form->new('');
2120   $print_form->{type}        = $order->type;
2121   $print_form->{formname}    = $params->{formname} || $order->type;
2122   $print_form->{format}      = $params->{format}   || 'pdf';
2123   $print_form->{media}       = $params->{media}    || 'file';
2124   $print_form->{groupitems}  = $params->{groupitems};
2125   $print_form->{printer_id}  = $params->{printer_id};
2126   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2127
2128   $order->language($params->{language});
2129   $order->flatten_to_form($print_form, format_amounts => 1);
2130
2131   my $template_ext;
2132   my $template_type;
2133   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2134     $template_ext  = 'odt';
2135     $template_type = 'OpenDocument';
2136   } elsif ($print_form->{format} =~ m{html}i) {
2137     $template_ext  = 'html';
2138     $template_type = 'HTML';
2139   }
2140
2141   # search for the template
2142   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2143     name        => $print_form->{formname},
2144     extension   => $template_ext,
2145     email       => $print_form->{media} eq 'email',
2146     language    => $params->{language},
2147     printer_id  => $print_form->{printer_id},
2148   );
2149
2150   if (!defined $template_file) {
2151     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2152   }
2153
2154   return @errors if scalar @errors;
2155
2156   $print_form->throw_on_error(sub {
2157     eval {
2158       $print_form->prepare_for_printing;
2159
2160       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2161         format        => $print_form->{format},
2162         template_type => $template_type,
2163         template      => $template_file,
2164         variables     => $print_form,
2165         variable_content_types => {
2166           longdescription => 'html',
2167           partnotes       => 'html',
2168           notes           => 'html',
2169           $::form->get_variable_content_types_for_cvars,
2170         },
2171       );
2172       1;
2173     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2174   });
2175
2176   return @errors;
2177 }
2178
2179 sub get_files_for_email_dialog {
2180   my ($self) = @_;
2181
2182   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2183
2184   return %files if !$::instance_conf->get_doc_storage;
2185
2186   if ($self->order->id) {
2187     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2188     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2189     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2190     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2191   }
2192
2193   my @parts =
2194     uniq_by { $_->{id} }
2195     map {
2196       +{ id         => $_->part->id,
2197          partnumber => $_->part->partnumber }
2198     } @{$self->order->items_sorted};
2199
2200   foreach my $part (@parts) {
2201     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2202     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2203   }
2204
2205   foreach my $key (keys %files) {
2206     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2207   }
2208
2209   return %files;
2210 }
2211
2212 sub make_periodic_invoices_config_from_yaml {
2213   my ($yaml_config) = @_;
2214
2215   return if !$yaml_config;
2216   my $attr = SL::YAML::Load($yaml_config);
2217   return if 'HASH' ne ref $attr;
2218   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2219 }
2220
2221
2222 sub get_periodic_invoices_status {
2223   my ($self, $config) = @_;
2224
2225   return                      if $self->type ne sales_order_type();
2226   return t8('not configured') if !$config;
2227
2228   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2229              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2230              :                                                     die "Cannot get status of periodic invoices config";
2231
2232   return $active ? t8('active') : t8('inactive');
2233 }
2234
2235 sub get_title_for {
2236   my ($self, $action) = @_;
2237
2238   return '' if none { lc($action)} qw(add edit);
2239
2240   # for locales:
2241   # $::locale->text("Add Sales Order");
2242   # $::locale->text("Add Purchase Order");
2243   # $::locale->text("Add Quotation");
2244   # $::locale->text("Add Request for Quotation");
2245   # $::locale->text("Edit Sales Order");
2246   # $::locale->text("Edit Purchase Order");
2247   # $::locale->text("Edit Quotation");
2248   # $::locale->text("Edit Request for Quotation");
2249
2250   $action = ucfirst(lc($action));
2251   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2252        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2253        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2254        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2255        : '';
2256 }
2257
2258 sub get_item_cvpartnumber {
2259   my ($self, $item) = @_;
2260
2261   return if !$self->search_cvpartnumber;
2262   return if !$self->order->customervendor;
2263
2264   if ($self->cv eq 'vendor') {
2265     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2266     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2267   } elsif ($self->cv eq 'customer') {
2268     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2269     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2270   }
2271 }
2272
2273 sub get_part_texts {
2274   my ($part_or_id, $language_or_id, %defaults) = @_;
2275
2276   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2277   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2278   my $texts       = {
2279     description     => $defaults{description}     // $part->description,
2280     longdescription => $defaults{longdescription} // $part->notes,
2281   };
2282
2283   return $texts unless $language_id;
2284
2285   my $translation = SL::DB::Manager::Translation->get_first(
2286     where => [
2287       parts_id    => $part->id,
2288       language_id => $language_id,
2289     ]);
2290
2291   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2292   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2293
2294   return $texts;
2295 }
2296
2297 sub sales_order_type {
2298   'sales_order';
2299 }
2300
2301 sub purchase_order_type {
2302   'purchase_order';
2303 }
2304
2305 sub sales_quotation_type {
2306   'sales_quotation';
2307 }
2308
2309 sub request_quotation_type {
2310   'request_quotation';
2311 }
2312
2313 sub nr_key {
2314   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2315        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2316        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2317        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2318        : '';
2319 }
2320
2321 sub save_and_redirect_to {
2322   my ($self, %params) = @_;
2323
2324   my $errors = $self->save();
2325
2326   if (scalar @{ $errors }) {
2327     $self->js->flash('error', $_) foreach @{ $errors };
2328     return $self->js->render();
2329   }
2330
2331   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2332            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2333            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2334            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2335            : '';
2336   flash_later('info', $text);
2337
2338   $self->redirect_to(%params, id => $self->order->id);
2339 }
2340
2341 sub save_history {
2342   my ($self, $addition) = @_;
2343
2344   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2345   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2346
2347   SL::DB::History->new(
2348     trans_id    => $self->order->id,
2349     employee_id => SL::DB::Manager::Employee->current->id,
2350     what_done   => $self->order->type,
2351     snumbers    => $snumbers,
2352     addition    => $addition,
2353   )->save;
2354 }
2355
2356 sub store_doc_to_webdav_and_filemanagement {
2357   my ($self, $content, $filename, $variant) = @_;
2358
2359   my $order = $self->order;
2360   my @errors;
2361
2362   # copy file to webdav folder
2363   if ($order->number && $::instance_conf->get_webdav_documents) {
2364     my $webdav = SL::Webdav->new(
2365       type     => $order->type,
2366       number   => $order->number,
2367     );
2368     my $webdav_file = SL::Webdav::File->new(
2369       webdav   => $webdav,
2370       filename => $filename,
2371     );
2372     eval {
2373       $webdav_file->store(data => \$content);
2374       1;
2375     } or do {
2376       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2377     };
2378   }
2379   if ($order->id && $::instance_conf->get_doc_storage) {
2380     eval {
2381       SL::File->save(object_id     => $order->id,
2382                      object_type   => $order->type,
2383                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2384                      source        => 'created',
2385                      file_type     => 'document',
2386                      file_name     => $filename,
2387                      file_contents => $content,
2388                      print_variant => $variant);
2389       1;
2390     } or do {
2391       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2392     };
2393   }
2394
2395   return @errors;
2396 }
2397
2398 sub link_requirement_specs_linking_to_created_from_objects {
2399   my ($self, @converted_from_oe_ids) = @_;
2400
2401   return unless @converted_from_oe_ids;
2402
2403   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2404   foreach my $rs_order (@{ $rs_orders }) {
2405     SL::DB::RequirementSpecOrder->new(
2406       order_id            => $self->order->id,
2407       requirement_spec_id => $rs_order->requirement_spec_id,
2408       version_id          => $rs_order->version_id,
2409     )->save;
2410   }
2411 }
2412
2413 sub set_project_in_linked_requirement_specs {
2414   my ($self) = @_;
2415
2416   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2417   foreach my $rs_order (@{ $rs_orders }) {
2418     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2419
2420     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2421   }
2422 }
2423
2424 1;
2425
2426 __END__
2427
2428 =encoding utf-8
2429
2430 =head1 NAME
2431
2432 SL::Controller::Order - controller for orders
2433
2434 =head1 SYNOPSIS
2435
2436 This is a new form to enter orders, completely rewritten with the use
2437 of controller and java script techniques.
2438
2439 The aim is to provide the user a better experience and a faster workflow. Also
2440 the code should be more readable, more reliable and better to maintain.
2441
2442 =head2 Key Features
2443
2444 =over 4
2445
2446 =item *
2447
2448 One input row, so that input happens every time at the same place.
2449
2450 =item *
2451
2452 Use of pickers where possible.
2453
2454 =item *
2455
2456 Possibility to enter more than one item at once.
2457
2458 =item *
2459
2460 Item list in a scrollable area, so that the workflow buttons stay at
2461 the bottom.
2462
2463 =item *
2464
2465 Reordering item rows with drag and drop is possible. Sorting item rows is
2466 possible (by partnumber, description, qty, sellprice and discount for now).
2467
2468 =item *
2469
2470 No C<update> is necessary. All entries and calculations are managed
2471 with ajax-calls and the page only reloads on C<save>.
2472
2473 =item *
2474
2475 User can see changes immediately, because of the use of java script
2476 and ajax.
2477
2478 =back
2479
2480 =head1 CODE
2481
2482 =head2 Layout
2483
2484 =over 4
2485
2486 =item * C<SL/Controller/Order.pm>
2487
2488 the controller
2489
2490 =item * C<template/webpages/order/form.html>
2491
2492 main form
2493
2494 =item * C<template/webpages/order/tabs/basic_data.html>
2495
2496 Main tab for basic_data.
2497
2498 This is the only tab here for now. "linked records" and "webdav" tabs are
2499 reused from generic code.
2500
2501 =over 4
2502
2503 =item * C<template/webpages/order/tabs/_business_info_row.html>
2504
2505 For displaying information on business type
2506
2507 =item * C<template/webpages/order/tabs/_item_input.html>
2508
2509 The input line for items
2510
2511 =item * C<template/webpages/order/tabs/_row.html>
2512
2513 One row for already entered items
2514
2515 =item * C<template/webpages/order/tabs/_tax_row.html>
2516
2517 Displaying tax information
2518
2519 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2520
2521 Dialog for selecting price and discount sources
2522
2523 =back
2524
2525 =item * C<js/kivi.Order.js>
2526
2527 java script functions
2528
2529 =back
2530
2531 =head1 TODO
2532
2533 =over 4
2534
2535 =item * testing
2536
2537 =item * price sources: little symbols showing better price / better discount
2538
2539 =item * select units in input row?
2540
2541 =item * check for direct delivery (workflow sales order -> purchase order)
2542
2543 =item * access rights
2544
2545 =item * display weights
2546
2547 =item * mtime check
2548
2549 =item * optional client/user behaviour
2550
2551 (transactions has to be set - department has to be set -
2552  force project if enabled in client config)
2553
2554 =back
2555
2556 =head1 KNOWN BUGS AND CAVEATS
2557
2558 =over 4
2559
2560 =item *
2561
2562 Customer discount is not displayed as a valid discount in price source popup
2563 (this might be a bug in price sources)
2564
2565 (I cannot reproduce this (Bernd))
2566
2567 =item *
2568
2569 No indication that <shift>-up/down expands/collapses second row.
2570
2571 =item *
2572
2573 Inline creation of parts is not currently supported
2574
2575 =item *
2576
2577 Table header is not sticky in the scrolling area.
2578
2579 =item *
2580
2581 Sorting does not include C<position>, neither does reordering.
2582
2583 This behavior was implemented intentionally. But we can discuss, which behavior
2584 should be implemented.
2585
2586 =back
2587
2588 =head1 To discuss / Nice to have
2589
2590 =over 4
2591
2592 =item *
2593
2594 How to expand/collapse second row. Now it can be done clicking the icon or
2595 <shift>-up/down.
2596
2597 =item *
2598
2599 Possibility to select PriceSources in input row?
2600
2601 =item *
2602
2603 This controller uses a (changed) copy of the template for the PriceSource
2604 dialog. Maybe there could be used one code source.
2605
2606 =item *
2607
2608 Rounding-differences between this controller (PriceTaxCalculator) and the old
2609 form. This is not only a problem here, but also in all parts using the PTC.
2610 There exists a ticket and a patch. This patch should be testet.
2611
2612 =item *
2613
2614 An indicator, if the actual inputs are saved (like in an
2615 editor or on text processing application).
2616
2617 =item *
2618
2619 A warning when leaving the page without saveing unchanged inputs.
2620
2621
2622 =back
2623
2624 =head1 AUTHOR
2625
2626 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2627
2628 =cut