SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::HTML::Util;
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::AdditionalBillingAddress;
  18 use SL::DB::AuthUser;
  19 use SL::DB::History;
  20 use SL::DB::Order;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28 use SL::DB::RecordLink;
  29 use SL::DB::RequirementSpec;
  30 use SL::DB::Shipto;
  31 use SL::DB::Translation;
  32
  33 use SL::Helper::CreatePDF qw(:all);
  34 use SL::Helper::PrintOptions;
  35 use SL::Helper::ShippedQty;
  36 use SL::Helper::UserPreferences::PositionsScrollbar;
  37 use SL::Helper::UserPreferences::UpdatePositions;
  38
  39 use SL::Controller::Helper::GetModels;
  40
  41 use List::Util qw(first sum0);
  42 use List::UtilsBy qw(sort_by uniq_by);
  43 use List::MoreUtils qw(any none pairwise first_index);
  44 use English qw(-no_match_vars);
  45 use File::Spec;
  46 use Cwd;
  47 use Sort::Naturally;
  48
  49 use Rose::Object::MakeMethods::Generic
  50 (
  51  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  52  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  53 );
  54
  55
  56 # safety
  57 __PACKAGE__->run_before('check_auth');
  58
  59 __PACKAGE__->run_before('recalc',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 __PACKAGE__->run_before('get_unalterable_data',
  64                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  65                                      print send_email) ]);
  66
  67 #
  68 # actions
  69 #
  70
  71 # add a new order
  72 sub action_add {
  73   my ($self) = @_;
  74
  75   $self->order->transdate(DateTime->now_local());
  76   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  77                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  78
  79   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  80       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  81       && (!$self->order->reqdate)) {
  82     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  83   }
  84
  85
  86   $self->pre_render();
  87   $self->render(
  88     'order/form',
  89     title => $self->get_title_for('add'),
  90     %{$self->{template_args}}
  91   );
  92 }
  93
  94 # edit an existing order
  95 sub action_edit {
  96   my ($self) = @_;
  97
  98   if ($::form->{id}) {
  99     $self->load_order;
 100
 101   } else {
 102     # this is to edit an order from an unsaved order object
 103
 104     # set item ids to new fake id, to identify them as new items
 105     foreach my $item (@{$self->order->items_sorted}) {
 106       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 107     }
 108     # trigger rendering values for second row as hidden, because they
 109     # are loaded only on demand. So we need to keep the values from
 110     # the source.
 111     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 112   }
 113
 114   $self->recalc();
 115   $self->pre_render();
 116   $self->render(
 117     'order/form',
 118     title => $self->get_title_for('edit'),
 119     %{$self->{template_args}}
 120   );
 121 }
 122
 123 # edit a collective order (consisting of one or more existing orders)
 124 sub action_edit_collective {
 125   my ($self) = @_;
 126
 127   # collect order ids
 128   my @multi_ids = map {
 129     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 130   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 131
 132   # fall back to add if no ids are given
 133   if (scalar @multi_ids == 0) {
 134     $self->action_add();
 135     return;
 136   }
 137
 138   # fall back to save as new if only one id is given
 139   if (scalar @multi_ids == 1) {
 140     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 141     $self->action_save_as_new();
 142     return;
 143   }
 144
 145   # make new order from given orders
 146   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 147   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 148   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 149
 150   $self->action_edit();
 151 }
 152
 153 # delete the order
 154 sub action_delete {
 155   my ($self) = @_;
 156
 157   my $errors = $self->delete();
 158
 159   if (scalar @{ $errors }) {
 160     $self->js->flash('error', $_) foreach @{ $errors };
 161     return $self->js->render();
 162   }
 163
 164   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 165            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 166            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 167            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 168            : '';
 169   flash_later('info', $text);
 170
 171   my @redirect_params = (
 172     action => 'add',
 173     type   => $self->type,
 174   );
 175
 176   $self->redirect_to(@redirect_params);
 177 }
 178
 179 # save the order
 180 sub action_save {
 181   my ($self) = @_;
 182
 183   my $errors = $self->save();
 184
 185   if (scalar @{ $errors }) {
 186     $self->js->flash('error', $_) foreach @{ $errors };
 187     return $self->js->render();
 188   }
 189
 190   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 191            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 192            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 193            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 194            : '';
 195   flash_later('info', $text);
 196
 197   my @redirect_params = (
 198     action => 'edit',
 199     type   => $self->type,
 200     id     => $self->order->id,
 201   );
 202
 203   $self->redirect_to(@redirect_params);
 204 }
 205
 206 # save the order as new document an open it for edit
 207 sub action_save_as_new {
 208   my ($self) = @_;
 209
 210   my $order = $self->order;
 211
 212   if (!$order->id) {
 213     $self->js->flash('error', t8('This object has not been saved yet.'));
 214     return $self->js->render();
 215   }
 216
 217   # load order from db to check if values changed
 218   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 219
 220   my %new_attrs;
 221   # Lets assign a new number if the user hasn't changed the previous one.
 222   # If it has been changed manually then use it as-is.
 223   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 224                         ? ''
 225                         : trim($order->number);
 226
 227   # Clear transdate unless changed
 228   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 229                         ? DateTime->today_local
 230                         : $order->transdate;
 231
 232   # Set new reqdate unless changed if it is enabled in client config
 233   if ($order->reqdate == $saved_order->reqdate) {
 234     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 235                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 236
 237     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 238         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 239       $new_attrs{reqdate} = '';
 240     } else {
 241       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 242     }
 243   } else {
 244     $new_attrs{reqdate} = $order->reqdate;
 245   }
 246
 247   # Update employee
 248   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 249
 250   # Create new record from current one
 251   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 252
 253   # no linked records on save as new
 254   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 255
 256   # save
 257   $self->action_save();
 258 }
 259
 260 # print the order
 261 #
 262 # This is called if "print" is pressed in the print dialog.
 263 # If PDF creation was requested and succeeded, the pdf is offered for download
 264 # via send_file (which uses ajax in this case).
 265 sub action_print {
 266   my ($self) = @_;
 267
 268   my $errors = $self->save();
 269
 270   if (scalar @{ $errors }) {
 271     $self->js->flash('error', $_) foreach @{ $errors };
 272     return $self->js->render();
 273   }
 274
 275   $self->js_reset_order_and_item_ids_after_save;
 276
 277   my $format      = $::form->{print_options}->{format};
 278   my $media       = $::form->{print_options}->{media};
 279   my $formname    = $::form->{print_options}->{formname};
 280   my $copies      = $::form->{print_options}->{copies};
 281   my $groupitems  = $::form->{print_options}->{groupitems};
 282   my $printer_id  = $::form->{print_options}->{printer_id};
 283
 284   # only PDF, OpenDocument & HTML for now
 285   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 286     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 287   }
 288
 289   # only screen or printer by now
 290   if (none { $media eq $_ } qw(screen printer)) {
 291     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 292   }
 293
 294   # create a form for generate_attachment_filename
 295   my $form   = Form->new;
 296   $form->{$self->nr_key()}  = $self->order->number;
 297   $form->{type}             = $self->type;
 298   $form->{format}           = $format;
 299   $form->{formname}         = $formname;
 300   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 301   my $doc_filename          = $form->generate_attachment_filename();
 302
 303   my $doc;
 304   my @errors = $self->generate_doc(\$doc, { format     => $format,
 305                                             formname   => $formname,
 306                                             language   => $self->order->language,
 307                                             printer_id => $printer_id,
 308                                             groupitems => $groupitems });
 309   if (scalar @errors) {
 310     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 311   }
 312
 313   if ($media eq 'screen') {
 314     # screen/download
 315     $self->js->flash('info', t8('The document has been created.'));
 316     $self->send_file(
 317       \$doc,
 318       type         => SL::MIME->mime_type_from_ext($doc_filename),
 319       name         => $doc_filename,
 320       js_no_render => 1,
 321     );
 322
 323   } elsif ($media eq 'printer') {
 324     # printer
 325     my $printer_id = $::form->{print_options}->{printer_id};
 326     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 327       copies  => $copies,
 328       content => $doc,
 329     );
 330
 331     $self->js->flash('info', t8('The document has been printed.'));
 332   }
 333
 334   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 335   if (scalar @warnings) {
 336     $self->js->flash('warning', $_) for @warnings;
 337   }
 338
 339   $self->save_history('PRINTED');
 340
 341   $self->js
 342     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 343     ->render;
 344 }
 345 sub action_preview_pdf {
 346   my ($self) = @_;
 347
 348   my $errors = $self->save();
 349   if (scalar @{ $errors }) {
 350     $self->js->flash('error', $_) foreach @{ $errors };
 351     return $self->js->render();
 352   }
 353
 354   $self->js_reset_order_and_item_ids_after_save;
 355
 356   my $format      = 'pdf';
 357   my $media       = 'screen';
 358   my $formname    = $self->type;
 359
 360   # only pdf
 361   # create a form for generate_attachment_filename
 362   my $form   = Form->new;
 363   $form->{$self->nr_key()}  = $self->order->number;
 364   $form->{type}             = $self->type;
 365   $form->{format}           = $format;
 366   $form->{formname}         = $formname;
 367   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 368   my $pdf_filename          = $form->generate_attachment_filename();
 369
 370   my $pdf;
 371   my @errors = $self->generate_doc(\$pdf, { format     => $format,
 372                                             formname   => $formname,
 373                                             language   => $self->order->language,
 374                                           });
 375   if (scalar @errors) {
 376     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 377   }
 378   $self->save_history('PREVIEWED');
 379   $self->js->flash('info', t8('The PDF has been previewed'));
 380   # screen/download
 381   $self->send_file(
 382     \$pdf,
 383     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 384     name         => $pdf_filename,
 385     js_no_render => 0,
 386   );
 387 }
 388
 389 # open the email dialog
 390 sub action_save_and_show_email_dialog {
 391   my ($self) = @_;
 392
 393   my $errors = $self->save();
 394
 395   if (scalar @{ $errors }) {
 396     $self->js->flash('error', $_) foreach @{ $errors };
 397     return $self->js->render();
 398   }
 399
 400   my $cv_method = $self->cv;
 401
 402   if (!$self->order->$cv_method) {
 403     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 404                     ->render($self);
 405   }
 406
 407   my $email_form;
 408   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 409   $email_form->{to} ||= $self->order->$cv_method->email;
 410   $email_form->{cc}   = $self->order->$cv_method->cc;
 411   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 412   # Todo: get addresses from shipto, if any
 413
 414   my $form = Form->new;
 415   $form->{$self->nr_key()}  = $self->order->number;
 416   $form->{cusordnumber}     = $self->order->cusordnumber;
 417   $form->{formname}         = $self->type;
 418   $form->{type}             = $self->type;
 419   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 420   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 421   $form->{format}           = 'pdf';
 422   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 423
 424   $email_form->{subject}             = $form->generate_email_subject();
 425   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 426   $email_form->{message}             = $form->generate_email_body();
 427   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 428
 429   my %files = $self->get_files_for_email_dialog();
 430
 431   my @employees_with_email = grep {
 432     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 433     $user && !!trim($user->get_config_value('email'));
 434   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 435
 436   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 437                                   email_form    => $email_form,
 438                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 439                                   FILES         => \%files,
 440                                   is_customer   => $self->cv eq 'customer',
 441                                   ALL_EMPLOYEES => \@employees_with_email,
 442   );
 443
 444   $self->js
 445       ->run('kivi.Order.show_email_dialog', $dialog_html)
 446       ->reinit_widgets
 447       ->render($self);
 448 }
 449
 450 # send email
 451 #
 452 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 453 sub action_send_email {
 454   my ($self) = @_;
 455
 456   my $errors = $self->save();
 457
 458   if (scalar @{ $errors }) {
 459     $self->js->run('kivi.Order.close_email_dialog');
 460     $self->js->flash('error', $_) foreach @{ $errors };
 461     return $self->js->render();
 462   }
 463
 464   $self->js_reset_order_and_item_ids_after_save;
 465
 466   my $email_form  = delete $::form->{email_form};
 467   my %field_names = (to => 'email');
 468
 469   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 470
 471   # for Form::cleanup which may be called in Form::send_email
 472   $::form->{cwd}    = getcwd();
 473   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 474
 475   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 476   $::form->{media}  = 'email';
 477
 478   $::form->{attachment_policy} //= '';
 479
 480   # Is an old file version available?
 481   my $attfile;
 482   if ($::form->{attachment_policy} eq 'old_file') {
 483     $attfile = SL::File->get_all(object_id     => $self->order->id,
 484                                  object_type   => $self->type,
 485                                  file_type     => 'document',
 486                                  print_variant => $::form->{formname});
 487   }
 488
 489   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 490     my $doc;
 491     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 492                                              format     => $::form->{print_options}->{format},
 493                                              formname   => $::form->{print_options}->{formname},
 494                                              language   => $self->order->language,
 495                                              printer_id => $::form->{print_options}->{printer_id},
 496                                              groupitems => $::form->{print_options}->{groupitems}});
 497     if (scalar @errors) {
 498       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 499     }
 500
 501     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 502     if (scalar @warnings) {
 503       flash_later('warning', $_) for @warnings;
 504     }
 505
 506     my $sfile = SL::SessionFile::Random->new(mode => "w");
 507     $sfile->fh->print($doc);
 508     $sfile->fh->close;
 509
 510     $::form->{tmpfile} = $sfile->file_name;
 511     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 512   }
 513
 514   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 515   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 516
 517   # internal notes
 518   my $intnotes = $self->order->intnotes;
 519   $intnotes   .= "\n\n" if $self->order->intnotes;
 520   $intnotes   .= t8('[email]')                                                                                        . "\n";
 521   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 522   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 523   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 524   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 525   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 526   $intnotes   .= t8('Message')    . ": " . SL::HTML::Util->strip($::form->{message});
 527
 528   $self->order->update_attributes(intnotes => $intnotes);
 529
 530   $self->save_history('MAILED');
 531
 532   flash_later('info', t8('The email has been sent.'));
 533
 534   my @redirect_params = (
 535     action => 'edit',
 536     type   => $self->type,
 537     id     => $self->order->id,
 538   );
 539
 540   $self->redirect_to(@redirect_params);
 541 }
 542
 543 # open the periodic invoices config dialog
 544 #
 545 # If there are values in the form (i.e. dialog was opened before),
 546 # then use this values. Create new ones, else.
 547 sub action_show_periodic_invoices_config_dialog {
 548   my ($self) = @_;
 549
 550   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 551   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 552   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 553                                                    order_value_periodicity => 'p', # = same as periodicity
 554                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 555                                                    extend_automatically_by => 12,
 556                                                    active                  => 1,
 557                                                    email_subject           => GenericTranslations->get(
 558                                                                                 language_id      => $::form->{language_id},
 559                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 560                                                    email_body              => GenericTranslations->get(
 561                                                                                 language_id      => $::form->{language_id},
 562                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 563   );
 564   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 565   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 566
 567   $::form->get_lists(printers => "ALL_PRINTERS",
 568                      charts   => { key       => 'ALL_CHARTS',
 569                                    transdate => 'current_date' });
 570
 571   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 572
 573   if ($::form->{customer_id}) {
 574     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 575     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 576     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 577     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 578     $config->send_email(0) if $::form->{postal_invoice};
 579   }
 580
 581   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 582                 popup_dialog             => 1,
 583                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 584                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 585                 config                   => $config,
 586                 %$::form);
 587 }
 588
 589 # assign the values of the periodic invoices config dialog
 590 # as yaml in the hidden tag and set the status.
 591 sub action_assign_periodic_invoices_config {
 592   my ($self) = @_;
 593
 594   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 595
 596   my $config = { active                     => $::form->{active}       ? 1 : 0,
 597                  terminated                 => $::form->{terminated}   ? 1 : 0,
 598                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 599                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 600                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 601                  start_date_as_date         => $::form->{start_date_as_date},
 602                  end_date_as_date           => $::form->{end_date_as_date},
 603                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 604                  print                      => $::form->{print}      ? 1                         : 0,
 605                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 606                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 607                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 608                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 609                  send_email                 => $::form->{send_email} ? 1 : 0,
 610                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 611                  email_recipient_address    => $::form->{email_recipient_address},
 612                  email_sender               => $::form->{email_sender},
 613                  email_subject              => $::form->{email_subject},
 614                  email_body                 => $::form->{email_body},
 615                };
 616
 617   my $periodic_invoices_config = SL::YAML::Dump($config);
 618
 619   my $status = $self->get_periodic_invoices_status($config);
 620
 621   $self->js
 622     ->remove('#order_periodic_invoices_config')
 623     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 624     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 625     ->html('#periodic_invoices_status', $status)
 626     ->flash('info', t8('The periodic invoices config has been assigned.'))
 627     ->render($self);
 628 }
 629
 630 sub action_get_has_active_periodic_invoices {
 631   my ($self) = @_;
 632
 633   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 634   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 635
 636   my $has_active_periodic_invoices =
 637        $self->type eq sales_order_type()
 638     && $config
 639     && $config->active
 640     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 641     && $config->get_previous_billed_period_start_date;
 642
 643   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 644 }
 645
 646 # save the order and redirect to the frontend subroutine for a new
 647 # delivery order
 648 sub action_save_and_delivery_order {
 649   my ($self) = @_;
 650
 651   $self->save_and_redirect_to(
 652     controller => 'oe.pl',
 653     action     => 'oe_delivery_order_from_order',
 654   );
 655 }
 656
 657 # save the order and redirect to the frontend subroutine for a new
 658 # invoice
 659 sub action_save_and_invoice {
 660   my ($self) = @_;
 661
 662   $self->save_and_redirect_to(
 663     controller => 'oe.pl',
 664     action     => 'oe_invoice_from_order',
 665   );
 666 }
 667
 668 # workflow from sales order to sales quotation
 669 sub action_sales_quotation {
 670   $_[0]->workflow_sales_or_request_for_quotation();
 671 }
 672
 673 # workflow from sales order to sales quotation
 674 sub action_request_for_quotation {
 675   $_[0]->workflow_sales_or_request_for_quotation();
 676 }
 677
 678 # workflow from sales quotation to sales order
 679 sub action_sales_order {
 680   $_[0]->workflow_sales_or_purchase_order();
 681 }
 682
 683 # workflow from rfq to purchase order
 684 sub action_purchase_order {
 685   $_[0]->workflow_sales_or_purchase_order();
 686 }
 687
 688 # workflow from purchase order to ap transaction
 689 sub action_save_and_ap_transaction {
 690   my ($self) = @_;
 691
 692   $self->save_and_redirect_to(
 693     controller => 'ap.pl',
 694     action     => 'add_from_purchase_order',
 695   );
 696 }
 697
 698 # set form elements in respect to a changed customer or vendor
 699 #
 700 # This action is called on an change of the customer/vendor picker.
 701 sub action_customer_vendor_changed {
 702   my ($self) = @_;
 703
 704   setup_order_from_cv($self->order);
 705   $self->recalc();
 706
 707   my $cv_method = $self->cv;
 708
 709   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 710     $self->js->show('#cp_row');
 711   } else {
 712     $self->js->hide('#cp_row');
 713   }
 714
 715   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 716     $self->js->show('#shipto_selection');
 717   } else {
 718     $self->js->hide('#shipto_selection');
 719   }
 720
 721   if ($cv_method eq 'customer') {
 722     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 723     $self->js->$show_hide('#billing_address_row');
 724   }
 725
 726   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 727
 728   $self->js
 729     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 730     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 731     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 732     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 733     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 734     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 735     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 736     ->val(        '#order_currency_id',        $self->order->currency_id)
 737     ->val(        '#order_payment_id',         $self->order->payment_id)
 738     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 739     ->val(        '#order_intnotes',           $self->order->intnotes)
 740     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 741     ->focus(      '#order_' . $self->cv . '_id')
 742     ->run('kivi.Order.update_exchangerate');
 743
 744   $self->js_redisplay_amounts_and_taxes;
 745   $self->js_redisplay_cvpartnumbers;
 746   $self->js->render();
 747 }
 748
 749 # open the dialog for customer/vendor details
 750 sub action_show_customer_vendor_details_dialog {
 751   my ($self) = @_;
 752
 753   my $is_customer = 'customer' eq $::form->{vc};
 754   my $cv;
 755   if ($is_customer) {
 756     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 757   } else {
 758     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 759   }
 760
 761   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 762   $details{discount_as_percent} = $cv->discount_as_percent;
 763   $details{creditlimt}          = $cv->creditlimit_as_number;
 764   $details{business}            = $cv->business->description      if $cv->business;
 765   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 766   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 767   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 768   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 769
 770   if ($is_customer) {
 771     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 772       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 773     }
 774   }
 775   foreach my $entry (@{ $cv->shipto }) {
 776     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 777   }
 778   foreach my $entry (@{ $cv->contacts }) {
 779     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 780   }
 781
 782   $_[0]->render('common/show_vc_details', { layout => 0 },
 783                 is_customer => $is_customer,
 784                 %details);
 785
 786 }
 787
 788 # called if a unit in an existing item row is changed
 789 sub action_unit_changed {
 790   my ($self) = @_;
 791
 792   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 793   my $item = $self->order->items_sorted->[$idx];
 794
 795   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 796   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 797
 798   $self->recalc();
 799
 800   $self->js
 801     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 802   $self->js_redisplay_line_values;
 803   $self->js_redisplay_amounts_and_taxes;
 804   $self->js->render();
 805 }
 806
 807 # add an item row for a new item entered in the input row
 808 sub action_add_item {
 809   my ($self) = @_;
 810
 811   delete $::form->{add_item}->{create_part_type};
 812
 813   my $form_attr = $::form->{add_item};
 814
 815   return unless $form_attr->{parts_id};
 816
 817   my $item = new_item($self->order, $form_attr);
 818
 819   $self->order->add_items($item);
 820
 821   $self->recalc();
 822
 823   $self->get_item_cvpartnumber($item);
 824
 825   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 826   my $row_as_html = $self->p->render('order/tabs/_row',
 827                                      ITEM => $item,
 828                                      ID   => $item_id,
 829                                      SELF => $self,
 830   );
 831
 832   if ($::form->{insert_before_item_id}) {
 833     $self->js
 834       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 835   } else {
 836     $self->js
 837       ->append('#row_table_id', $row_as_html);
 838   }
 839
 840   if ( $item->part->is_assortment ) {
 841     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 842     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 843       my $attr = { parts_id => $assortment_item->parts_id,
 844                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 845                    unit     => $assortment_item->unit,
 846                    description => $assortment_item->part->description,
 847                  };
 848       my $item = new_item($self->order, $attr);
 849
 850       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 851       $item->discount(1) unless $assortment_item->charge;
 852
 853       $self->order->add_items( $item );
 854       $self->recalc();
 855       $self->get_item_cvpartnumber($item);
 856       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 857       my $row_as_html = $self->p->render('order/tabs/_row',
 858                                          ITEM => $item,
 859                                          ID   => $item_id,
 860                                          SELF => $self,
 861       );
 862       if ($::form->{insert_before_item_id}) {
 863         $self->js
 864           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 865       } else {
 866         $self->js
 867           ->append('#row_table_id', $row_as_html);
 868       }
 869     };
 870   };
 871
 872   $self->js
 873     ->val('.add_item_input', '')
 874     ->run('kivi.Order.init_row_handlers')
 875     ->run('kivi.Order.renumber_positions')
 876     ->focus('#add_item_parts_id_name');
 877
 878   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 879
 880   $self->js_redisplay_amounts_and_taxes;
 881   $self->js->render();
 882 }
 883
 884 # add item rows for multiple items at once
 885 sub action_add_multi_items {
 886   my ($self) = @_;
 887
 888   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 889   return $self->js->render() unless scalar @form_attr;
 890
 891   my @items;
 892   foreach my $attr (@form_attr) {
 893     my $item = new_item($self->order, $attr);
 894     push @items, $item;
 895     if ( $item->part->is_assortment ) {
 896       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 897         my $attr = { parts_id => $assortment_item->parts_id,
 898                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 899                      unit     => $assortment_item->unit,
 900                      description => $assortment_item->part->description,
 901                    };
 902         my $item = new_item($self->order, $attr);
 903
 904         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 905         $item->discount(1) unless $assortment_item->charge;
 906         push @items, $item;
 907       }
 908     }
 909   }
 910   $self->order->add_items(@items);
 911
 912   $self->recalc();
 913
 914   foreach my $item (@items) {
 915     $self->get_item_cvpartnumber($item);
 916     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 917     my $row_as_html = $self->p->render('order/tabs/_row',
 918                                        ITEM => $item,
 919                                        ID   => $item_id,
 920                                        SELF => $self,
 921     );
 922
 923     if ($::form->{insert_before_item_id}) {
 924       $self->js
 925         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 926     } else {
 927       $self->js
 928         ->append('#row_table_id', $row_as_html);
 929     }
 930   }
 931
 932   $self->js
 933     ->run('kivi.Part.close_picker_dialogs')
 934     ->run('kivi.Order.init_row_handlers')
 935     ->run('kivi.Order.renumber_positions')
 936     ->focus('#add_item_parts_id_name');
 937
 938   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 939
 940   $self->js_redisplay_amounts_and_taxes;
 941   $self->js->render();
 942 }
 943
 944 # recalculate all linetotals, amounts and taxes and redisplay them
 945 sub action_recalc_amounts_and_taxes {
 946   my ($self) = @_;
 947
 948   $self->recalc();
 949
 950   $self->js_redisplay_line_values;
 951   $self->js_redisplay_amounts_and_taxes;
 952   $self->js->render();
 953 }
 954
 955 sub action_update_exchangerate {
 956   my ($self) = @_;
 957
 958   my $data = {
 959     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 960     currency_name => $self->order->currency->name,
 961     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 962   };
 963
 964   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 965 }
 966
 967 # redisplay item rows if they are sorted by an attribute
 968 sub action_reorder_items {
 969   my ($self) = @_;
 970
 971   my %sort_keys = (
 972     partnumber   => sub { $_[0]->part->partnumber },
 973     description  => sub { $_[0]->description },
 974     qty          => sub { $_[0]->qty },
 975     sellprice    => sub { $_[0]->sellprice },
 976     discount     => sub { $_[0]->discount },
 977     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 978   );
 979
 980   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 981
 982   my $method = $sort_keys{$::form->{order_by}};
 983   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 984   if ($::form->{sort_dir}) {
 985     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 986       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 987     } else {
 988       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 989     }
 990   } else {
 991     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 992       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 993     } else {
 994       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 995     }
 996   }
 997   $self->js
 998     ->run('kivi.Order.redisplay_items', \@to_sort)
 999     ->render;
1000 }
1001
1002 # show the popup to choose a price/discount source
1003 sub action_price_popup {
1004   my ($self) = @_;
1005
1006   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1007   my $item = $self->order->items_sorted->[$idx];
1008
1009   $self->render_price_dialog($item);
1010 }
1011
1012 # save the order in a session variable and redirect to the part controller
1013 sub action_create_part {
1014   my ($self) = @_;
1015
1016   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1017
1018   my $callback     = $self->url_for(
1019     action       => 'return_from_create_part',
1020     type         => $self->type, # type is needed for check_auth on return
1021     previousform => $previousform,
1022   );
1023
1024   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1025
1026   my @redirect_params = (
1027     controller => 'Part',
1028     action     => 'add',
1029     part_type  => $::form->{add_item}->{create_part_type},
1030     callback   => $callback,
1031     show_abort => 1,
1032   );
1033
1034   $self->redirect_to(@redirect_params);
1035 }
1036
1037 sub action_return_from_create_part {
1038   my ($self) = @_;
1039
1040   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1041
1042   $::auth->restore_form_from_session(delete $::form->{previousform});
1043
1044   # set item ids to new fake id, to identify them as new items
1045   foreach my $item (@{$self->order->items_sorted}) {
1046     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1047   }
1048
1049   $self->recalc();
1050   $self->get_unalterable_data();
1051   $self->pre_render();
1052
1053   # trigger rendering values for second row/longdescription as hidden,
1054   # because they are loaded only on demand. So we need to keep the values
1055   # from the source.
1056   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1057   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1058
1059   $self->render(
1060     'order/form',
1061     title => $self->get_title_for('edit'),
1062     %{$self->{template_args}}
1063   );
1064
1065 }
1066
1067 # load the second row for one or more items
1068 #
1069 # This action gets the html code for all items second rows by rendering a template for
1070 # the second row and sets the html code via client js.
1071 sub action_load_second_rows {
1072   my ($self) = @_;
1073
1074   $self->recalc() if $self->order->is_sales; # for margin calculation
1075
1076   foreach my $item_id (@{ $::form->{item_ids} }) {
1077     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1078     my $item = $self->order->items_sorted->[$idx];
1079
1080     $self->js_load_second_row($item, $item_id, 0);
1081   }
1082
1083   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1084
1085   $self->js->render();
1086 }
1087
1088 # update description, notes and sellprice from master data
1089 sub action_update_row_from_master_data {
1090   my ($self) = @_;
1091
1092   foreach my $item_id (@{ $::form->{item_ids} }) {
1093     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1094     my $item  = $self->order->items_sorted->[$idx];
1095     my $texts = get_part_texts($item->part, $self->order->language_id);
1096
1097     $item->description($texts->{description});
1098     $item->longdescription($texts->{longdescription});
1099
1100     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1101
1102     my $price_src;
1103     if ($item->part->is_assortment) {
1104     # add assortment items with price 0, as the components carry the price
1105       $price_src = $price_source->price_from_source("");
1106       $price_src->price(0);
1107     } else {
1108       $price_src = $price_source->best_price
1109                  ? $price_source->best_price
1110                  : $price_source->price_from_source("");
1111       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1112       $price_src->price(0) if !$price_source->best_price;
1113     }
1114
1115
1116     $item->sellprice($price_src->price);
1117     $item->active_price_source($price_src);
1118
1119     $self->js
1120       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1121       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1122       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1123       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1124
1125     if ($self->search_cvpartnumber) {
1126       $self->get_item_cvpartnumber($item);
1127       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1128     }
1129   }
1130
1131   $self->recalc();
1132   $self->js_redisplay_line_values;
1133   $self->js_redisplay_amounts_and_taxes;
1134
1135   $self->js->render();
1136 }
1137
1138 sub js_load_second_row {
1139   my ($self, $item, $item_id, $do_parse) = @_;
1140
1141   if ($do_parse) {
1142     # Parse values from form (they are formated while rendering (template)).
1143     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1144     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1145     foreach my $var (@{ $item->cvars_by_config }) {
1146       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1147     }
1148     $item->parse_custom_variable_values;
1149   }
1150
1151   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1152
1153   $self->js
1154     ->html('#second_row_' . $item_id, $row_as_html)
1155     ->data('#second_row_' . $item_id, 'loaded', 1);
1156 }
1157
1158 sub js_redisplay_line_values {
1159   my ($self) = @_;
1160
1161   my $is_sales = $self->order->is_sales;
1162
1163   # sales orders with margins
1164   my @data;
1165   if ($is_sales) {
1166     @data = map {
1167       [
1168        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1169        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1170        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1171       ]} @{ $self->order->items_sorted };
1172   } else {
1173     @data = map {
1174       [
1175        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1176       ]} @{ $self->order->items_sorted };
1177   }
1178
1179   $self->js
1180     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1181 }
1182
1183 sub js_redisplay_amounts_and_taxes {
1184   my ($self) = @_;
1185
1186   if (scalar @{ $self->{taxes} }) {
1187     $self->js->show('#taxincluded_row_id');
1188   } else {
1189     $self->js->hide('#taxincluded_row_id');
1190   }
1191
1192   if ($self->order->taxincluded) {
1193     $self->js->hide('#subtotal_row_id');
1194   } else {
1195     $self->js->show('#subtotal_row_id');
1196   }
1197
1198   if ($self->order->is_sales) {
1199     my $is_neg = $self->order->marge_total < 0;
1200     $self->js
1201       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1202       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1203       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1204       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1205       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1206       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1207       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1208       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1209   }
1210
1211   $self->js
1212     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1213     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1214     ->remove('.tax_row')
1215     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1216 }
1217
1218 sub js_redisplay_cvpartnumbers {
1219   my ($self) = @_;
1220
1221   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1222
1223   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1224
1225   $self->js
1226     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1227 }
1228
1229 sub js_reset_order_and_item_ids_after_save {
1230   my ($self) = @_;
1231
1232   $self->js
1233     ->val('#id', $self->order->id)
1234     ->val('#converted_from_oe_id', '')
1235     ->val('#order_' . $self->nr_key(), $self->order->number);
1236
1237   my $idx = 0;
1238   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1239     next if !$self->order->items_sorted->[$idx]->id;
1240     next if $form_item_id !~ m{^new};
1241     $self->js
1242       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1243       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1244       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1245   } continue {
1246     $idx++;
1247   }
1248   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1249 }
1250
1251 #
1252 # helpers
1253 #
1254
1255 sub init_valid_types {
1256   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1257 }
1258
1259 sub init_type {
1260   my ($self) = @_;
1261
1262   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1263     die "Not a valid type for order";
1264   }
1265
1266   $self->type($::form->{type});
1267 }
1268
1269 sub init_cv {
1270   my ($self) = @_;
1271
1272   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1273          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1274          : die "Not a valid type for order";
1275
1276   return $cv;
1277 }
1278
1279 sub init_search_cvpartnumber {
1280   my ($self) = @_;
1281
1282   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1283   my $search_cvpartnumber;
1284   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1285   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1286
1287   return $search_cvpartnumber;
1288 }
1289
1290 sub init_show_update_button {
1291   my ($self) = @_;
1292
1293   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1294 }
1295
1296 sub init_p {
1297   SL::Presenter->get;
1298 }
1299
1300 sub init_order {
1301   $_[0]->make_order;
1302 }
1303
1304 sub init_all_price_factors {
1305   SL::DB::Manager::PriceFactor->get_all;
1306 }
1307
1308 sub init_part_picker_classification_ids {
1309   my ($self)    = @_;
1310   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1311
1312   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1313 }
1314
1315 sub check_auth {
1316   my ($self) = @_;
1317
1318   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1319
1320   my $right   = $right_for->{ $self->type };
1321   $right    ||= 'DOES_NOT_EXIST';
1322
1323   $::auth->assert($right);
1324 }
1325
1326 # build the selection box for contacts
1327 #
1328 # Needed, if customer/vendor changed.
1329 sub build_contact_select {
1330   my ($self) = @_;
1331
1332   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1333     value_key  => 'cp_id',
1334     title_key  => 'full_name_dep',
1335     default    => $self->order->cp_id,
1336     with_empty => 1,
1337     style      => 'width: 300px',
1338   );
1339 }
1340
1341 # build the selection box for the additional billing address
1342 #
1343 # Needed, if customer/vendor changed.
1344 sub build_billing_address_select {
1345   my ($self) = @_;
1346
1347   return '' if $self->cv ne 'customer';
1348
1349   select_tag('order.billing_address_id',
1350              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1351              value_key  => 'id',
1352              title_key  => 'displayable_id',
1353              default    => $self->order->billing_address_id,
1354              with_empty => 0,
1355              style      => 'width: 300px',
1356   );
1357 }
1358
1359 # build the selection box for shiptos
1360 #
1361 # Needed, if customer/vendor changed.
1362 sub build_shipto_select {
1363   my ($self) = @_;
1364
1365   select_tag('order.shipto_id',
1366              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1367              value_key  => 'shipto_id',
1368              title_key  => 'displayable_id',
1369              default    => $self->order->shipto_id,
1370              with_empty => 0,
1371              style      => 'width: 300px',
1372   );
1373 }
1374
1375 # build the inputs for the cusom shipto dialog
1376 #
1377 # Needed, if customer/vendor changed.
1378 sub build_shipto_inputs {
1379   my ($self) = @_;
1380
1381   my $content = $self->p->render('common/_ship_to_dialog',
1382                                  vc_obj      => $self->order->customervendor,
1383                                  cs_obj      => $self->order->custom_shipto,
1384                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1385                                  id_selector => '#order_shipto_id');
1386
1387   div_tag($content, id => 'shipto_inputs');
1388 }
1389
1390 # render the info line for business
1391 #
1392 # Needed, if customer/vendor changed.
1393 sub build_business_info_row
1394 {
1395   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1396 }
1397
1398 # build the rows for displaying taxes
1399 #
1400 # Called if amounts where recalculated and redisplayed.
1401 sub build_tax_rows {
1402   my ($self) = @_;
1403
1404   my $rows_as_html;
1405   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1406     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1407   }
1408   return $rows_as_html;
1409 }
1410
1411
1412 sub render_price_dialog {
1413   my ($self, $record_item) = @_;
1414
1415   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1416
1417   $self->js
1418     ->run(
1419       'kivi.io.price_chooser_dialog',
1420       t8('Available Prices'),
1421       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1422     )
1423     ->reinit_widgets;
1424
1425 #   if (@errors) {
1426 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1427 #     $self->js->show('#dialog_flash_error');
1428 #   }
1429
1430   $self->js->render;
1431 }
1432
1433 sub load_order {
1434   my ($self) = @_;
1435
1436   return if !$::form->{id};
1437
1438   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1439
1440   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1441   # You need a custom shipto object to call cvars_by_config to get the cvars.
1442   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1443
1444   return $self->order;
1445 }
1446
1447 # load or create a new order object
1448 #
1449 # And assign changes from the form to this object.
1450 # If the order is loaded from db, check if items are deleted in the form,
1451 # remove them form the object and collect them for removing from db on saving.
1452 # Then create/update items from form (via make_item) and add them.
1453 sub make_order {
1454   my ($self) = @_;
1455
1456   # add_items adds items to an order with no items for saving, but they cannot
1457   # be retrieved via items until the order is saved. Adding empty items to new
1458   # order here solves this problem.
1459   my $order;
1460   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1461   $order ||= SL::DB::Order->new(orderitems  => [],
1462                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1463                                 currency_id => $::instance_conf->get_currency_id(),);
1464
1465   my $cv_id_method = $self->cv . '_id';
1466   if (!$::form->{id} && $::form->{$cv_id_method}) {
1467     $order->$cv_id_method($::form->{$cv_id_method});
1468     setup_order_from_cv($order);
1469   }
1470
1471   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1472   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1473
1474   $order->assign_attributes(%{$::form->{order}});
1475
1476   $self->setup_custom_shipto_from_form($order, $::form);
1477
1478   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1479     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1480     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1481   }
1482
1483   # remove deleted items
1484   $self->item_ids_to_delete([]);
1485   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1486     my $item = $order->orderitems->[$idx];
1487     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1488       splice @{$order->orderitems}, $idx, 1;
1489       push @{$self->item_ids_to_delete}, $item->id;
1490     }
1491   }
1492
1493   my @items;
1494   my $pos = 1;
1495   foreach my $form_attr (@{$form_orderitems}) {
1496     my $item = make_item($order, $form_attr);
1497     $item->position($pos);
1498     push @items, $item;
1499     $pos++;
1500   }
1501   $order->add_items(grep {!$_->id} @items);
1502
1503   return $order;
1504 }
1505
1506 # create or update items from form
1507 #
1508 # Make item objects from form values. For items already existing read from db.
1509 # Create a new item else. And assign attributes.
1510 sub make_item {
1511   my ($record, $attr) = @_;
1512
1513   my $item;
1514   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1515
1516   my $is_new = !$item;
1517
1518   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1519   # they cannot be retrieved via custom_variables until the order/orderitem is
1520   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1521   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1522
1523   $item->assign_attributes(%$attr);
1524
1525   if ($is_new) {
1526     my $texts = get_part_texts($item->part, $record->language_id);
1527     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1528     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1529     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1530   }
1531
1532   return $item;
1533 }
1534
1535 # create a new item
1536 #
1537 # This is used to add one item
1538 sub new_item {
1539   my ($record, $attr) = @_;
1540
1541   my $item = SL::DB::OrderItem->new;
1542
1543   # Remove attributes where the user left or set the inputs empty.
1544   # So these attributes will be undefined and we can distinguish them
1545   # from zero later on.
1546   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1547     delete $attr->{$_} if $attr->{$_} eq '';
1548   }
1549
1550   $item->assign_attributes(%$attr);
1551
1552   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1553   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1554
1555   $item->unit($part->unit) if !$item->unit;
1556
1557   my $price_src;
1558   if ( $part->is_assortment ) {
1559     # add assortment items with price 0, as the components carry the price
1560     $price_src = $price_source->price_from_source("");
1561     $price_src->price(0);
1562   } elsif (defined $item->sellprice) {
1563     $price_src = $price_source->price_from_source("");
1564     $price_src->price($item->sellprice);
1565   } else {
1566     $price_src = $price_source->best_price
1567                ? $price_source->best_price
1568                : $price_source->price_from_source("");
1569     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1570     $price_src->price(0) if !$price_source->best_price;
1571   }
1572
1573   my $discount_src;
1574   if (defined $item->discount) {
1575     $discount_src = $price_source->discount_from_source("");
1576     $discount_src->discount($item->discount);
1577   } else {
1578     $discount_src = $price_source->best_discount
1579                   ? $price_source->best_discount
1580                   : $price_source->discount_from_source("");
1581     $discount_src->discount(0) if !$price_source->best_discount;
1582   }
1583
1584   my %new_attr;
1585   $new_attr{part}                   = $part;
1586   $new_attr{description}            = $part->description     if ! $item->description;
1587   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1588   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1589   $new_attr{sellprice}              = $price_src->price;
1590   $new_attr{discount}               = $discount_src->discount;
1591   $new_attr{active_price_source}    = $price_src;
1592   $new_attr{active_discount_source} = $discount_src;
1593   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1594   $new_attr{project_id}             = $record->globalproject_id;
1595   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1596
1597   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1598   # they cannot be retrieved via custom_variables until the order/orderitem is
1599   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1600   $new_attr{custom_variables} = [];
1601
1602   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1603
1604   $item->assign_attributes(%new_attr, %{ $texts });
1605
1606   return $item;
1607 }
1608
1609 sub setup_order_from_cv {
1610   my ($order) = @_;
1611
1612   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1613
1614   $order->intnotes($order->customervendor->notes);
1615
1616   return if !$order->is_sales;
1617
1618   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1619   $order->taxincluded(defined($order->customer->taxincluded_checked)
1620                       ? $order->customer->taxincluded_checked
1621                       : $::myconfig{taxincluded_checked});
1622
1623   my $address = $order->customer->default_billing_address;;
1624   $order->billing_address_id($address ? $address->id : undef);
1625 }
1626
1627 # setup custom shipto from form
1628 #
1629 # The dialog returns form variables starting with 'shipto' and cvars starting
1630 # with 'shiptocvar_'.
1631 # Mark it to be deleted if a shipto from master data is selected
1632 # (i.e. order has a shipto).
1633 # Else, update or create a new custom shipto. If the fields are empty, it
1634 # will not be saved on save.
1635 sub setup_custom_shipto_from_form {
1636   my ($self, $order, $form) = @_;
1637
1638   if ($order->shipto) {
1639     $self->is_custom_shipto_to_delete(1);
1640   } else {
1641     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1642
1643     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1644     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1645
1646     $custom_shipto->assign_attributes(%$shipto_attrs);
1647     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1648   }
1649 }
1650
1651 # recalculate prices and taxes
1652 #
1653 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1654 sub recalc {
1655   my ($self) = @_;
1656
1657   my %pat = $self->order->calculate_prices_and_taxes();
1658
1659   $self->{taxes} = [];
1660   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1661     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1662
1663     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1664                                 netamount => $netamount,
1665                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1666   }
1667   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1668 }
1669
1670 # get data for saving, printing, ..., that is not changed in the form
1671 #
1672 # Only cvars for now.
1673 sub get_unalterable_data {
1674   my ($self) = @_;
1675
1676   foreach my $item (@{ $self->order->items }) {
1677     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1678     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1679     foreach my $var (@{ $item->cvars_by_config }) {
1680       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1681     }
1682     $item->parse_custom_variable_values;
1683   }
1684 }
1685
1686 # delete the order
1687 #
1688 # And remove related files in the spool directory
1689 sub delete {
1690   my ($self) = @_;
1691
1692   my $errors = [];
1693   my $db     = $self->order->db;
1694
1695   $db->with_transaction(
1696     sub {
1697       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1698       $self->order->delete;
1699       my $spool = $::lx_office_conf{paths}->{spool};
1700       unlink map { "$spool/$_" } @spoolfiles if $spool;
1701
1702       $self->save_history('DELETED');
1703
1704       1;
1705   }) || push(@{$errors}, $db->error);
1706
1707   return $errors;
1708 }
1709
1710 # save the order
1711 #
1712 # And delete items that are deleted in the form.
1713 sub save {
1714   my ($self) = @_;
1715
1716   my $errors = [];
1717   my $db     = $self->order->db;
1718
1719   $db->with_transaction(sub {
1720     # delete custom shipto if it is to be deleted or if it is empty
1721     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1722       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1723       $self->order->custom_shipto(undef);
1724     }
1725
1726     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1727     $self->order->save(cascade => 1);
1728
1729     # link records
1730     if ($::form->{converted_from_oe_id}) {
1731       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1732
1733       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1734         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1735         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1736         $src->link_to_record($self->order);
1737       }
1738       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1739         my $idx = 0;
1740         foreach (@{ $self->order->items_sorted }) {
1741           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1742           next if !$from_id;
1743           SL::DB::RecordLink->new(from_table => 'orderitems',
1744                                   from_id    => $from_id,
1745                                   to_table   => 'orderitems',
1746                                   to_id      => $_->id
1747           )->save;
1748           $idx++;
1749         }
1750       }
1751
1752       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1753     }
1754
1755     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1756
1757     $self->save_history('SAVED');
1758
1759     1;
1760   }) || push(@{$errors}, $db->error);
1761
1762   return $errors;
1763 }
1764
1765 sub workflow_sales_or_request_for_quotation {
1766   my ($self) = @_;
1767
1768   # always save
1769   my $errors = $self->save();
1770
1771   if (scalar @{ $errors }) {
1772     $self->js->flash('error', $_) for @{ $errors };
1773     return $self->js->render();
1774   }
1775
1776   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1777
1778   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1779   $self->{converted_from_oe_id} = delete $::form->{id};
1780
1781   # set item ids to new fake id, to identify them as new items
1782   foreach my $item (@{$self->order->items_sorted}) {
1783     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1784   }
1785
1786   # change form type
1787   $::form->{type} = $destination_type;
1788   $self->type($self->init_type);
1789   $self->cv  ($self->init_cv);
1790   $self->check_auth;
1791
1792   $self->recalc();
1793   $self->get_unalterable_data();
1794   $self->pre_render();
1795
1796   # trigger rendering values for second row as hidden, because they
1797   # are loaded only on demand. So we need to keep the values from the
1798   # source.
1799   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1800
1801   $self->render(
1802     'order/form',
1803     title => $self->get_title_for('edit'),
1804     %{$self->{template_args}}
1805   );
1806 }
1807
1808 sub workflow_sales_or_purchase_order {
1809   my ($self) = @_;
1810
1811   # always save
1812   my $errors = $self->save();
1813
1814   if (scalar @{ $errors }) {
1815     $self->js->flash('error', $_) foreach @{ $errors };
1816     return $self->js->render();
1817   }
1818
1819   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1820                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1821                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1822                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1823                        : '';
1824
1825   # check for direct delivery
1826   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1827   my $custom_shipto;
1828   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1829       && $::form->{use_shipto} && $self->order->shipto) {
1830     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1831   }
1832
1833   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1834   $self->{converted_from_oe_id} = delete $::form->{id};
1835
1836   # set item ids to new fake id, to identify them as new items
1837   foreach my $item (@{$self->order->items_sorted}) {
1838     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1839   }
1840
1841   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1842     if ($::form->{use_shipto}) {
1843       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1844     } else {
1845       # remove any custom shipto if not wanted
1846       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1847     }
1848   }
1849
1850   # change form type
1851   $::form->{type} = $destination_type;
1852   $self->type($self->init_type);
1853   $self->cv  ($self->init_cv);
1854   $self->check_auth;
1855
1856   $self->recalc();
1857   $self->get_unalterable_data();
1858   $self->pre_render();
1859
1860   # trigger rendering values for second row as hidden, because they
1861   # are loaded only on demand. So we need to keep the values from the
1862   # source.
1863   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1864
1865   $self->render(
1866     'order/form',
1867     title => $self->get_title_for('edit'),
1868     %{$self->{template_args}}
1869   );
1870 }
1871
1872
1873 sub pre_render {
1874   my ($self) = @_;
1875
1876   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1877   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1878   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1879   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1880   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1881                                                                                               deleted => 0 ] ],
1882                                                                            sort_by => 'name');
1883   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1884                                                                                               deleted => 0 ] ],
1885                                                                            sort_by => 'name');
1886   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1887                                                                                                         obsolete => 0 ] ]);
1888   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1889   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1890   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1891   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1892   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1893
1894   my $print_form = Form->new('');
1895   $print_form->{type}        = $self->type;
1896   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1897   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1898     form => $print_form,
1899     options => {dialog_name_prefix => 'print_options.',
1900                 show_headers       => 1,
1901                 no_queue           => 1,
1902                 no_postscript      => 1,
1903                 no_opendocument    => 0,
1904                 no_html            => 0},
1905   );
1906
1907   foreach my $item (@{$self->order->orderitems}) {
1908     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1909     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1910     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1911   }
1912
1913   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1914     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1915     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1916     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1917     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1918   }
1919
1920   if ($self->order->number && $::instance_conf->get_webdav) {
1921     my $webdav = SL::Webdav->new(
1922       type     => $self->type,
1923       number   => $self->order->number,
1924     );
1925     my @all_objects = $webdav->get_all_objects;
1926     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1927                                                     type => t8('File'),
1928                                                     link => File::Spec->catfile($_->full_filedescriptor),
1929                                                 } } @all_objects;
1930   }
1931
1932   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1933       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1934     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1935   }
1936
1937   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1938
1939   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1940                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
1941   $self->setup_edit_action_bar;
1942 }
1943
1944 sub setup_edit_action_bar {
1945   my ($self, %params) = @_;
1946
1947   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1948                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1949                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1950
1951   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
1952   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
1953
1954   for my $bar ($::request->layout->get('actionbar')) {
1955     $bar->add(
1956       combobox => [
1957         action => [
1958           t8('Save'),
1959           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1960                                                     $::instance_conf->get_order_warn_no_deliverydate,
1961           ],
1962           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
1963                          @req_trans_cost_art, @req_cusordnumber,
1964           ],
1965         ],
1966         action => [
1967           t8('Save as new'),
1968           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1969           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1970                          @req_trans_cost_art, @req_cusordnumber,
1971           ],
1972           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1973         ],
1974       ], # end of combobox "Save"
1975
1976       combobox => [
1977         action => [
1978           t8('Workflow'),
1979         ],
1980         action => [
1981           t8('Save and Quotation'),
1982           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1983           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
1984           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1985         ],
1986         action => [
1987           t8('Save and RFQ'),
1988           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1989           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1990         ],
1991         action => [
1992           t8('Save and Sales Order'),
1993           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1994           checks   => [ @req_trans_cost_art ],
1995           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1996         ],
1997         action => [
1998           t8('Save and Purchase Order'),
1999           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
2000           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2001           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2002         ],
2003         action => [
2004           t8('Save and Delivery Order'),
2005           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2006                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2007                                                                                                                         ],
2008           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2009                          @req_trans_cost_art, @req_cusordnumber,
2010           ],
2011           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
2012         ],
2013         action => [
2014           t8('Save and Invoice'),
2015           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2016           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2017                          @req_trans_cost_art, @req_cusordnumber,
2018           ],
2019         ],
2020         action => [
2021           t8('Save and AP Transaction'),
2022           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2023           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
2024         ],
2025
2026       ], # end of combobox "Workflow"
2027
2028       combobox => [
2029         action => [
2030           t8('Export'),
2031         ],
2032         action => [
2033           t8('Save and preview PDF'),
2034           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2035                                                         $::instance_conf->get_order_warn_no_deliverydate,
2036                     ],
2037           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2038         ],
2039         action => [
2040           t8('Save and print'),
2041           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2042                                                        $::instance_conf->get_order_warn_no_deliverydate,
2043                     ],
2044           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2045         ],
2046         action => [
2047           t8('Save and E-mail'),
2048           id   => 'save_and_email_action',
2049           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2050                                                                      $::instance_conf->get_order_warn_no_deliverydate,
2051                   ],
2052           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2053         ],
2054         action => [
2055           t8('Download attachments of all parts'),
2056           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2057           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2058           only_if  => $::instance_conf->get_doc_storage,
2059         ],
2060       ], # end of combobox "Export"
2061
2062       action => [
2063         t8('Delete'),
2064         call     => [ 'kivi.Order.delete_order' ],
2065         confirm  => $::locale->text('Do you really want to delete this object?'),
2066         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2067         only_if  => $deletion_allowed,
2068       ],
2069
2070       combobox => [
2071         action => [
2072           t8('more')
2073         ],
2074         action => [
2075           t8('History'),
2076           call     => [ 'set_history_window', $self->order->id, 'id' ],
2077           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2078         ],
2079         action => [
2080           t8('Follow-Up'),
2081           call     => [ 'kivi.Order.follow_up_window' ],
2082           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2083           only_if  => $::auth->assert('productivity', 1),
2084         ],
2085       ], # end of combobox "more"
2086     );
2087   }
2088 }
2089
2090 sub generate_doc {
2091   my ($self, $doc_ref, $params) = @_;
2092
2093   my $order  = $self->order;
2094   my @errors = ();
2095
2096   my $print_form = Form->new('');
2097   $print_form->{type}        = $order->type;
2098   $print_form->{formname}    = $params->{formname} || $order->type;
2099   $print_form->{format}      = $params->{format}   || 'pdf';
2100   $print_form->{media}       = $params->{media}    || 'file';
2101   $print_form->{groupitems}  = $params->{groupitems};
2102   $print_form->{printer_id}  = $params->{printer_id};
2103   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2104
2105   $order->language($params->{language});
2106   $order->flatten_to_form($print_form, format_amounts => 1);
2107
2108   my $template_ext;
2109   my $template_type;
2110   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2111     $template_ext  = 'odt';
2112     $template_type = 'OpenDocument';
2113   } elsif ($print_form->{format} =~ m{html}i) {
2114     $template_ext  = 'html';
2115     $template_type = 'HTML';
2116   }
2117
2118   # search for the template
2119   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2120     name        => $print_form->{formname},
2121     extension   => $template_ext,
2122     email       => $print_form->{media} eq 'email',
2123     language    => $params->{language},
2124     printer_id  => $print_form->{printer_id},
2125   );
2126
2127   if (!defined $template_file) {
2128     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2129   }
2130
2131   return @errors if scalar @errors;
2132
2133   $print_form->throw_on_error(sub {
2134     eval {
2135       $print_form->prepare_for_printing;
2136
2137       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2138         format        => $print_form->{format},
2139         template_type => $template_type,
2140         template      => $template_file,
2141         variables     => $print_form,
2142         variable_content_types => {
2143           longdescription => 'html',
2144           partnotes       => 'html',
2145           notes           => 'html',
2146           $::form->get_variable_content_types_for_cvars,
2147         },
2148       );
2149       1;
2150     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2151   });
2152
2153   return @errors;
2154 }
2155
2156 sub get_files_for_email_dialog {
2157   my ($self) = @_;
2158
2159   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2160
2161   return %files if !$::instance_conf->get_doc_storage;
2162
2163   if ($self->order->id) {
2164     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2165     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2166     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2167     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2168   }
2169
2170   my @parts =
2171     uniq_by { $_->{id} }
2172     map {
2173       +{ id         => $_->part->id,
2174          partnumber => $_->part->partnumber }
2175     } @{$self->order->items_sorted};
2176
2177   foreach my $part (@parts) {
2178     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2179     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2180   }
2181
2182   foreach my $key (keys %files) {
2183     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2184   }
2185
2186   return %files;
2187 }
2188
2189 sub make_periodic_invoices_config_from_yaml {
2190   my ($yaml_config) = @_;
2191
2192   return if !$yaml_config;
2193   my $attr = SL::YAML::Load($yaml_config);
2194   return if 'HASH' ne ref $attr;
2195   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2196 }
2197
2198
2199 sub get_periodic_invoices_status {
2200   my ($self, $config) = @_;
2201
2202   return                      if $self->type ne sales_order_type();
2203   return t8('not configured') if !$config;
2204
2205   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2206              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2207              :                                                     die "Cannot get status of periodic invoices config";
2208
2209   return $active ? t8('active') : t8('inactive');
2210 }
2211
2212 sub get_title_for {
2213   my ($self, $action) = @_;
2214
2215   return '' if none { lc($action)} qw(add edit);
2216
2217   # for locales:
2218   # $::locale->text("Add Sales Order");
2219   # $::locale->text("Add Purchase Order");
2220   # $::locale->text("Add Quotation");
2221   # $::locale->text("Add Request for Quotation");
2222   # $::locale->text("Edit Sales Order");
2223   # $::locale->text("Edit Purchase Order");
2224   # $::locale->text("Edit Quotation");
2225   # $::locale->text("Edit Request for Quotation");
2226
2227   $action = ucfirst(lc($action));
2228   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2229        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2230        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2231        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2232        : '';
2233 }
2234
2235 sub get_item_cvpartnumber {
2236   my ($self, $item) = @_;
2237
2238   return if !$self->search_cvpartnumber;
2239   return if !$self->order->customervendor;
2240
2241   if ($self->cv eq 'vendor') {
2242     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2243     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2244   } elsif ($self->cv eq 'customer') {
2245     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2246     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2247   }
2248 }
2249
2250 sub get_part_texts {
2251   my ($part_or_id, $language_or_id, %defaults) = @_;
2252
2253   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2254   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2255   my $texts       = {
2256     description     => $defaults{description}     // $part->description,
2257     longdescription => $defaults{longdescription} // $part->notes,
2258   };
2259
2260   return $texts unless $language_id;
2261
2262   my $translation = SL::DB::Manager::Translation->get_first(
2263     where => [
2264       parts_id    => $part->id,
2265       language_id => $language_id,
2266     ]);
2267
2268   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2269   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2270
2271   return $texts;
2272 }
2273
2274 sub sales_order_type {
2275   'sales_order';
2276 }
2277
2278 sub purchase_order_type {
2279   'purchase_order';
2280 }
2281
2282 sub sales_quotation_type {
2283   'sales_quotation';
2284 }
2285
2286 sub request_quotation_type {
2287   'request_quotation';
2288 }
2289
2290 sub nr_key {
2291   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2292        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2293        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2294        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2295        : '';
2296 }
2297
2298 sub save_and_redirect_to {
2299   my ($self, %params) = @_;
2300
2301   my $errors = $self->save();
2302
2303   if (scalar @{ $errors }) {
2304     $self->js->flash('error', $_) foreach @{ $errors };
2305     return $self->js->render();
2306   }
2307
2308   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2309            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2310            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2311            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2312            : '';
2313   flash_later('info', $text);
2314
2315   $self->redirect_to(%params, id => $self->order->id);
2316 }
2317
2318 sub save_history {
2319   my ($self, $addition) = @_;
2320
2321   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2322   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2323
2324   SL::DB::History->new(
2325     trans_id    => $self->order->id,
2326     employee_id => SL::DB::Manager::Employee->current->id,
2327     what_done   => $self->order->type,
2328     snumbers    => $snumbers,
2329     addition    => $addition,
2330   )->save;
2331 }
2332
2333 sub store_doc_to_webdav_and_filemanagement {
2334   my ($self, $content, $filename, $variant) = @_;
2335
2336   my $order = $self->order;
2337   my @errors;
2338
2339   # copy file to webdav folder
2340   if ($order->number && $::instance_conf->get_webdav_documents) {
2341     my $webdav = SL::Webdav->new(
2342       type     => $order->type,
2343       number   => $order->number,
2344     );
2345     my $webdav_file = SL::Webdav::File->new(
2346       webdav   => $webdav,
2347       filename => $filename,
2348     );
2349     eval {
2350       $webdav_file->store(data => \$content);
2351       1;
2352     } or do {
2353       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2354     };
2355   }
2356   if ($order->id && $::instance_conf->get_doc_storage) {
2357     eval {
2358       SL::File->save(object_id     => $order->id,
2359                      object_type   => $order->type,
2360                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2361                      source        => 'created',
2362                      file_type     => 'document',
2363                      file_name     => $filename,
2364                      file_contents => $content,
2365                      print_variant => $variant);
2366       1;
2367     } or do {
2368       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2369     };
2370   }
2371
2372   return @errors;
2373 }
2374
2375 sub link_requirement_specs_linking_to_created_from_objects {
2376   my ($self, @converted_from_oe_ids) = @_;
2377
2378   return unless @converted_from_oe_ids;
2379
2380   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2381   foreach my $rs_order (@{ $rs_orders }) {
2382     SL::DB::RequirementSpecOrder->new(
2383       order_id            => $self->order->id,
2384       requirement_spec_id => $rs_order->requirement_spec_id,
2385       version_id          => $rs_order->version_id,
2386     )->save;
2387   }
2388 }
2389
2390 sub set_project_in_linked_requirement_specs {
2391   my ($self) = @_;
2392
2393   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2394   foreach my $rs_order (@{ $rs_orders }) {
2395     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2396
2397     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2398   }
2399 }
2400
2401 1;
2402
2403 __END__
2404
2405 =encoding utf-8
2406
2407 =head1 NAME
2408
2409 SL::Controller::Order - controller for orders
2410
2411 =head1 SYNOPSIS
2412
2413 This is a new form to enter orders, completely rewritten with the use
2414 of controller and java script techniques.
2415
2416 The aim is to provide the user a better experience and a faster workflow. Also
2417 the code should be more readable, more reliable and better to maintain.
2418
2419 =head2 Key Features
2420
2421 =over 4
2422
2423 =item *
2424
2425 One input row, so that input happens every time at the same place.
2426
2427 =item *
2428
2429 Use of pickers where possible.
2430
2431 =item *
2432
2433 Possibility to enter more than one item at once.
2434
2435 =item *
2436
2437 Item list in a scrollable area, so that the workflow buttons stay at
2438 the bottom.
2439
2440 =item *
2441
2442 Reordering item rows with drag and drop is possible. Sorting item rows is
2443 possible (by partnumber, description, qty, sellprice and discount for now).
2444
2445 =item *
2446
2447 No C<update> is necessary. All entries and calculations are managed
2448 with ajax-calls and the page only reloads on C<save>.
2449
2450 =item *
2451
2452 User can see changes immediately, because of the use of java script
2453 and ajax.
2454
2455 =back
2456
2457 =head1 CODE
2458
2459 =head2 Layout
2460
2461 =over 4
2462
2463 =item * C<SL/Controller/Order.pm>
2464
2465 the controller
2466
2467 =item * C<template/webpages/order/form.html>
2468
2469 main form
2470
2471 =item * C<template/webpages/order/tabs/basic_data.html>
2472
2473 Main tab for basic_data.
2474
2475 This is the only tab here for now. "linked records" and "webdav" tabs are
2476 reused from generic code.
2477
2478 =over 4
2479
2480 =item * C<template/webpages/order/tabs/_business_info_row.html>
2481
2482 For displaying information on business type
2483
2484 =item * C<template/webpages/order/tabs/_item_input.html>
2485
2486 The input line for items
2487
2488 =item * C<template/webpages/order/tabs/_row.html>
2489
2490 One row for already entered items
2491
2492 =item * C<template/webpages/order/tabs/_tax_row.html>
2493
2494 Displaying tax information
2495
2496 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2497
2498 Dialog for selecting price and discount sources
2499
2500 =back
2501
2502 =item * C<js/kivi.Order.js>
2503
2504 java script functions
2505
2506 =back
2507
2508 =head1 TODO
2509
2510 =over 4
2511
2512 =item * testing
2513
2514 =item * price sources: little symbols showing better price / better discount
2515
2516 =item * select units in input row?
2517
2518 =item * check for direct delivery (workflow sales order -> purchase order)
2519
2520 =item * access rights
2521
2522 =item * display weights
2523
2524 =item * mtime check
2525
2526 =item * optional client/user behaviour
2527
2528 (transactions has to be set - department has to be set -
2529  force project if enabled in client config)
2530
2531 =back
2532
2533 =head1 KNOWN BUGS AND CAVEATS
2534
2535 =over 4
2536
2537 =item *
2538
2539 Customer discount is not displayed as a valid discount in price source popup
2540 (this might be a bug in price sources)
2541
2542 (I cannot reproduce this (Bernd))
2543
2544 =item *
2545
2546 No indication that <shift>-up/down expands/collapses second row.
2547
2548 =item *
2549
2550 Inline creation of parts is not currently supported
2551
2552 =item *
2553
2554 Table header is not sticky in the scrolling area.
2555
2556 =item *
2557
2558 Sorting does not include C<position>, neither does reordering.
2559
2560 This behavior was implemented intentionally. But we can discuss, which behavior
2561 should be implemented.
2562
2563 =back
2564
2565 =head1 To discuss / Nice to have
2566
2567 =over 4
2568
2569 =item *
2570
2571 How to expand/collapse second row. Now it can be done clicking the icon or
2572 <shift>-up/down.
2573
2574 =item *
2575
2576 Possibility to select PriceSources in input row?
2577
2578 =item *
2579
2580 This controller uses a (changed) copy of the template for the PriceSource
2581 dialog. Maybe there could be used one code source.
2582
2583 =item *
2584
2585 Rounding-differences between this controller (PriceTaxCalculator) and the old
2586 form. This is not only a problem here, but also in all parts using the PTC.
2587 There exists a ticket and a patch. This patch should be testet.
2588
2589 =item *
2590
2591 An indicator, if the actual inputs are saved (like in an
2592 editor or on text processing application).
2593
2594 =item *
2595
2596 A warning when leaving the page without saveing unchanged inputs.
2597
2598
2599 =back
2600
2601 =head1 AUTHOR
2602
2603 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2604
2605 =cut