SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24 use SL::DB::Shipto;
  25 use SL::DB::Translation;
  26
  27 use SL::Helper::CreatePDF qw(:all);
  28 use SL::Helper::PrintOptions;
  29 use SL::Helper::ShippedQty;
  30 use SL::Helper::UserPreferences::PositionsScrollbar;
  31 use SL::Helper::UserPreferences::UpdatePositions;
  32
  33 use SL::Controller::Helper::GetModels;
  34
  35 use List::Util qw(first sum0);
  36 use List::UtilsBy qw(sort_by uniq_by);
  37 use List::MoreUtils qw(any none pairwise first_index);
  38 use English qw(-no_match_vars);
  39 use File::Spec;
  40 use Cwd;
  41 use Sort::Naturally;
  42
  43 use Rose::Object::MakeMethods::Generic
  44 (
  45  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  46  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors search_cvpartnumber show_update_button) ],
  47 );
  48
  49
  50 # safety
  51 __PACKAGE__->run_before('check_auth');
  52
  53 __PACKAGE__->run_before('recalc',
  54                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  55                                      print send_email) ]);
  56
  57 __PACKAGE__->run_before('get_unalterable_data',
  58                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  59                                      print send_email) ]);
  60
  61 #
  62 # actions
  63 #
  64
  65 # add a new order
  66 sub action_add {
  67   my ($self) = @_;
  68
  69   $self->order->transdate(DateTime->now_local());
  70   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  71                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  72   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  73
  74
  75   $self->pre_render();
  76   $self->render(
  77     'order/form',
  78     title => $self->get_title_for('add'),
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 # edit an existing order
  84 sub action_edit {
  85   my ($self) = @_;
  86
  87   if ($::form->{id}) {
  88     $self->load_order;
  89
  90   } else {
  91     # this is to edit an order from an unsaved order object
  92
  93     # set item ids to new fake id, to identify them as new items
  94     foreach my $item (@{$self->order->items_sorted}) {
  95       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  96     }
  97     # trigger rendering values for second row/longdescription as hidden,
  98     # because they are loaded only on demand. So we need to keep the values
  99     # from the source.
 100     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
 101     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 102   }
 103
 104   $self->recalc();
 105   $self->pre_render();
 106   $self->render(
 107     'order/form',
 108     title => $self->get_title_for('edit'),
 109     %{$self->{template_args}}
 110   );
 111 }
 112
 113 # edit a collective order (consisting of one or more existing orders)
 114 sub action_edit_collective {
 115   my ($self) = @_;
 116
 117   # collect order ids
 118   my @multi_ids = map {
 119     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 120   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 121
 122   # fall back to add if no ids are given
 123   if (scalar @multi_ids == 0) {
 124     $self->action_add();
 125     return;
 126   }
 127
 128   # fall back to save as new if only one id is given
 129   if (scalar @multi_ids == 1) {
 130     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 131     $self->action_save_as_new();
 132     return;
 133   }
 134
 135   # make new order from given orders
 136   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 137   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 138   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 139
 140   $self->action_edit();
 141 }
 142
 143 # delete the order
 144 sub action_delete {
 145   my ($self) = @_;
 146
 147   my $errors = $self->delete();
 148
 149   if (scalar @{ $errors }) {
 150     $self->js->flash('error', $_) foreach @{ $errors };
 151     return $self->js->render();
 152   }
 153
 154   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 155            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 156            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 157            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 158            : '';
 159   flash_later('info', $text);
 160
 161   my @redirect_params = (
 162     action => 'add',
 163     type   => $self->type,
 164   );
 165
 166   $self->redirect_to(@redirect_params);
 167 }
 168
 169 # save the order
 170 sub action_save {
 171   my ($self) = @_;
 172
 173   my $errors = $self->save();
 174
 175   if (scalar @{ $errors }) {
 176     $self->js->flash('error', $_) foreach @{ $errors };
 177     return $self->js->render();
 178   }
 179
 180   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 181            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 182            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 183            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 184            : '';
 185   flash_later('info', $text);
 186
 187   my @redirect_params = (
 188     action => 'edit',
 189     type   => $self->type,
 190     id     => $self->order->id,
 191   );
 192
 193   $self->redirect_to(@redirect_params);
 194 }
 195
 196 # save the order as new document an open it for edit
 197 sub action_save_as_new {
 198   my ($self) = @_;
 199
 200   my $order = $self->order;
 201
 202   if (!$order->id) {
 203     $self->js->flash('error', t8('This object has not been saved yet.'));
 204     return $self->js->render();
 205   }
 206
 207   # load order from db to check if values changed
 208   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 209
 210   my %new_attrs;
 211   # Lets assign a new number if the user hasn't changed the previous one.
 212   # If it has been changed manually then use it as-is.
 213   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 214                         ? ''
 215                         : trim($order->number);
 216
 217   # Clear transdate unless changed
 218   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 219                         ? DateTime->today_local
 220                         : $order->transdate;
 221
 222   # Set new reqdate unless changed
 223   if ($order->reqdate == $saved_order->reqdate) {
 224     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 225                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 226     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 227   } else {
 228     $new_attrs{reqdate} = $order->reqdate;
 229   }
 230
 231   # Update employee
 232   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 233
 234   # Create new record from current one
 235   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 236
 237   # no linked records on save as new
 238   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 239
 240   # save
 241   $self->action_save();
 242 }
 243
 244 # print the order
 245 #
 246 # This is called if "print" is pressed in the print dialog.
 247 # If PDF creation was requested and succeeded, the pdf is offered for download
 248 # via send_file (which uses ajax in this case).
 249 sub action_print {
 250   my ($self) = @_;
 251
 252   my $errors = $self->save();
 253
 254   if (scalar @{ $errors }) {
 255     $self->js->flash('error', $_) foreach @{ $errors };
 256     return $self->js->render();
 257   }
 258
 259   $self->js_reset_order_and_item_ids_after_save;
 260
 261   my $format      = $::form->{print_options}->{format};
 262   my $media       = $::form->{print_options}->{media};
 263   my $formname    = $::form->{print_options}->{formname};
 264   my $copies      = $::form->{print_options}->{copies};
 265   my $groupitems  = $::form->{print_options}->{groupitems};
 266
 267   # only pdf and opendocument by now
 268   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 269     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 270   }
 271
 272   # only screen or printer by now
 273   if (none { $media eq $_ } qw(screen printer)) {
 274     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 275   }
 276
 277   # create a form for generate_attachment_filename
 278   my $form   = Form->new;
 279   $form->{$self->nr_key()}  = $self->order->number;
 280   $form->{type}             = $self->type;
 281   $form->{format}           = $format;
 282   $form->{formname}         = $formname;
 283   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 284   my $pdf_filename          = $form->generate_attachment_filename();
 285
 286   my $pdf;
 287   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 288                                                    formname   => $formname,
 289                                                    language   => $self->order->language,
 290                                                    groupitems => $groupitems });
 291   if (scalar @errors) {
 292     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 293   }
 294
 295   if ($media eq 'screen') {
 296     # screen/download
 297     $self->js->flash('info', t8('The PDF has been created'));
 298     $self->send_file(
 299       \$pdf,
 300       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 301       name         => $pdf_filename,
 302       js_no_render => 1,
 303     );
 304
 305   } elsif ($media eq 'printer') {
 306     # printer
 307     my $printer_id = $::form->{print_options}->{printer_id};
 308     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 309       copies  => $copies,
 310       content => $pdf,
 311     );
 312
 313     $self->js->flash('info', t8('The PDF has been printed'));
 314   }
 315
 316   # copy file to webdav folder
 317   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 318     my $webdav = SL::Webdav->new(
 319       type     => $self->type,
 320       number   => $self->order->number,
 321     );
 322     my $webdav_file = SL::Webdav::File->new(
 323       webdav   => $webdav,
 324       filename => $pdf_filename,
 325     );
 326     eval {
 327       $webdav_file->store(data => \$pdf);
 328       1;
 329     } or do {
 330       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 331     }
 332   }
 333   if ($self->order->number && $::instance_conf->get_doc_storage) {
 334     eval {
 335       SL::File->save(object_id     => $self->order->id,
 336                      object_type   => $self->type,
 337                      mime_type     => 'application/pdf',
 338                      source        => 'created',
 339                      file_type     => 'document',
 340                      file_name     => $pdf_filename,
 341                      file_contents => $pdf);
 342       1;
 343     } or do {
 344       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 345     }
 346   }
 347   $self->js->render;
 348 }
 349
 350 # open the email dialog
 351 sub action_save_and_show_email_dialog {
 352   my ($self) = @_;
 353
 354   my $errors = $self->save();
 355
 356   if (scalar @{ $errors }) {
 357     $self->js->flash('error', $_) foreach @{ $errors };
 358     return $self->js->render();
 359   }
 360
 361   my $cv_method = $self->cv;
 362
 363   if (!$self->order->$cv_method) {
 364     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 365                     ->render($self);
 366   }
 367
 368   my $email_form;
 369   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 370   $email_form->{to} ||= $self->order->$cv_method->email;
 371   $email_form->{cc}   = $self->order->$cv_method->cc;
 372   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 373   # Todo: get addresses from shipto, if any
 374
 375   my $form = Form->new;
 376   $form->{$self->nr_key()}  = $self->order->number;
 377   $form->{cusordnumber}     = $self->order->cusordnumber;
 378   $form->{formname}         = $self->type;
 379   $form->{type}             = $self->type;
 380   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 381   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 382   $form->{format}           = 'pdf';
 383
 384   $email_form->{subject}             = $form->generate_email_subject();
 385   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 386   $email_form->{message}             = $form->generate_email_body();
 387   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 388
 389   my %files = $self->get_files_for_email_dialog();
 390   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 391                                   email_form  => $email_form,
 392                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 393                                   FILES       => \%files,
 394                                   is_customer => $self->cv eq 'customer',
 395   );
 396
 397   $self->js
 398       ->run('kivi.Order.show_email_dialog', $dialog_html)
 399       ->reinit_widgets
 400       ->render($self);
 401 }
 402
 403 # send email
 404 #
 405 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 406 sub action_send_email {
 407   my ($self) = @_;
 408
 409   my $errors = $self->save();
 410
 411   if (scalar @{ $errors }) {
 412     $self->js->run('kivi.Order.close_email_dialog');
 413     $self->js->flash('error', $_) foreach @{ $errors };
 414     return $self->js->render();
 415   }
 416
 417   $self->js_reset_order_and_item_ids_after_save;
 418
 419   my $email_form  = delete $::form->{email_form};
 420   my %field_names = (to => 'email');
 421
 422   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 423
 424   # for Form::cleanup which may be called in Form::send_email
 425   $::form->{cwd}    = getcwd();
 426   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 427
 428   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 429   $::form->{media}  = 'email';
 430
 431   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 432     my $pdf;
 433     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 434                                                     format     => $::form->{print_options}->{format},
 435                                                     formname   => $::form->{print_options}->{formname},
 436                                                     language   => $self->order->language,
 437                                                     groupitems => $::form->{print_options}->{groupitems}});
 438     if (scalar @errors) {
 439       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 440     }
 441
 442     my $sfile = SL::SessionFile::Random->new(mode => "w");
 443     $sfile->fh->print($pdf);
 444     $sfile->fh->close;
 445
 446     $::form->{tmpfile} = $sfile->file_name;
 447     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 448   }
 449
 450   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 451   $::form->send_email(\%::myconfig, 'pdf');
 452
 453   # internal notes
 454   my $intnotes = $self->order->intnotes;
 455   $intnotes   .= "\n\n" if $self->order->intnotes;
 456   $intnotes   .= t8('[email]')                                                                                        . "\n";
 457   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 458   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 459   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 460   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 461   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 462   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 463
 464   $self->order->update_attributes(intnotes => $intnotes);
 465
 466   flash_later('info', t8('The email has been sent.'));
 467
 468   my @redirect_params = (
 469     action => 'edit',
 470     type   => $self->type,
 471     id     => $self->order->id,
 472   );
 473
 474   $self->redirect_to(@redirect_params);
 475 }
 476
 477 # open the periodic invoices config dialog
 478 #
 479 # If there are values in the form (i.e. dialog was opened before),
 480 # then use this values. Create new ones, else.
 481 sub action_show_periodic_invoices_config_dialog {
 482   my ($self) = @_;
 483
 484   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 485   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 486   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 487                                                    order_value_periodicity => 'p', # = same as periodicity
 488                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 489                                                    extend_automatically_by => 12,
 490                                                    active                  => 1,
 491                                                    email_subject           => GenericTranslations->get(
 492                                                                                 language_id      => $::form->{language_id},
 493                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 494                                                    email_body              => GenericTranslations->get(
 495                                                                                 language_id      => $::form->{language_id},
 496                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 497   );
 498   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 499   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 500
 501   $::form->get_lists(printers => "ALL_PRINTERS",
 502                      charts   => { key       => 'ALL_CHARTS',
 503                                    transdate => 'current_date' });
 504
 505   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 506
 507   if ($::form->{customer_id}) {
 508     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 509     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 510   }
 511
 512   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 513                 popup_dialog             => 1,
 514                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 515                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 516                 config                   => $config,
 517                 %$::form);
 518 }
 519
 520 # assign the values of the periodic invoices config dialog
 521 # as yaml in the hidden tag and set the status.
 522 sub action_assign_periodic_invoices_config {
 523   my ($self) = @_;
 524
 525   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 526
 527   my $config = { active                     => $::form->{active}       ? 1 : 0,
 528                  terminated                 => $::form->{terminated}   ? 1 : 0,
 529                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 530                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 531                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 532                  start_date_as_date         => $::form->{start_date_as_date},
 533                  end_date_as_date           => $::form->{end_date_as_date},
 534                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 535                  print                      => $::form->{print}      ? 1                         : 0,
 536                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 537                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 538                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 539                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 540                  send_email                 => $::form->{send_email} ? 1 : 0,
 541                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 542                  email_recipient_address    => $::form->{email_recipient_address},
 543                  email_sender               => $::form->{email_sender},
 544                  email_subject              => $::form->{email_subject},
 545                  email_body                 => $::form->{email_body},
 546                };
 547
 548   my $periodic_invoices_config = SL::YAML::Dump($config);
 549
 550   my $status = $self->get_periodic_invoices_status($config);
 551
 552   $self->js
 553     ->remove('#order_periodic_invoices_config')
 554     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 555     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 556     ->html('#periodic_invoices_status', $status)
 557     ->flash('info', t8('The periodic invoices config has been assigned.'))
 558     ->render($self);
 559 }
 560
 561 sub action_get_has_active_periodic_invoices {
 562   my ($self) = @_;
 563
 564   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 565   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 566
 567   my $has_active_periodic_invoices =
 568        $self->type eq sales_order_type()
 569     && $config
 570     && $config->active
 571     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 572     && $config->get_previous_billed_period_start_date;
 573
 574   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 575 }
 576
 577 # save the order and redirect to the frontend subroutine for a new
 578 # delivery order
 579 sub action_save_and_delivery_order {
 580   my ($self) = @_;
 581
 582   my $errors = $self->save();
 583
 584   if (scalar @{ $errors }) {
 585     $self->js->flash('error', $_) foreach @{ $errors };
 586     return $self->js->render();
 587   }
 588
 589   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 590            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 591            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 592            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 593            : '';
 594   flash_later('info', $text);
 595
 596   my @redirect_params = (
 597     controller => 'oe.pl',
 598     action     => 'oe_delivery_order_from_order',
 599     id         => $self->order->id,
 600   );
 601
 602   $self->redirect_to(@redirect_params);
 603 }
 604
 605 # save the order and redirect to the frontend subroutine for a new
 606 # invoice
 607 sub action_save_and_invoice {
 608   my ($self) = @_;
 609
 610   my $errors = $self->save();
 611
 612   if (scalar @{ $errors }) {
 613     $self->js->flash('error', $_) foreach @{ $errors };
 614     return $self->js->render();
 615   }
 616
 617   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 618            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 619            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 620            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 621            : '';
 622   flash_later('info', $text);
 623
 624   my @redirect_params = (
 625     controller => 'oe.pl',
 626     action     => 'oe_invoice_from_order',
 627     id         => $self->order->id,
 628   );
 629
 630   $self->redirect_to(@redirect_params);
 631 }
 632
 633 # workflow from sales quotation to sales order
 634 sub action_sales_order {
 635   $_[0]->workflow_sales_or_purchase_order();
 636 }
 637
 638 # workflow from rfq to purchase order
 639 sub action_purchase_order {
 640   $_[0]->workflow_sales_or_purchase_order();
 641 }
 642
 643 # workflow from purchase order to ap transaction
 644 sub action_save_and_ap_transaction {
 645   my ($self) = @_;
 646
 647   my $errors = $self->save();
 648
 649   if (scalar @{ $errors }) {
 650     $self->js->flash('error', $_) foreach @{ $errors };
 651     return $self->js->render();
 652   }
 653
 654   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 655            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 656            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 657            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 658            : '';
 659   flash_later('info', $text);
 660
 661   my @redirect_params = (
 662     controller => 'ap.pl',
 663     action     => 'add_from_purchase_order',
 664     id         => $self->order->id,
 665   );
 666
 667   $self->redirect_to(@redirect_params);
 668 }
 669
 670 # set form elements in respect to a changed customer or vendor
 671 #
 672 # This action is called on an change of the customer/vendor picker.
 673 sub action_customer_vendor_changed {
 674   my ($self) = @_;
 675
 676   setup_order_from_cv($self->order);
 677   $self->recalc();
 678
 679   my $cv_method = $self->cv;
 680
 681   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 682     $self->js->show('#cp_row');
 683   } else {
 684     $self->js->hide('#cp_row');
 685   }
 686
 687   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 688     $self->js->show('#shipto_selection');
 689   } else {
 690     $self->js->hide('#shipto_selection');
 691   }
 692
 693   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 694
 695   $self->js
 696     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 697     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 698     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 699     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 700     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 701     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 702     ->val(        '#order_currency_id',      $self->order->currency_id)
 703     ->val(        '#order_payment_id',       $self->order->payment_id)
 704     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 705     ->val(        '#order_intnotes',         $self->order->intnotes)
 706     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 707     ->focus(      '#order_' . $self->cv . '_id')
 708     ->run('kivi.Order.update_exchangerate');
 709
 710   $self->js_redisplay_amounts_and_taxes;
 711   $self->js_redisplay_cvpartnumbers;
 712   $self->js->render();
 713 }
 714
 715 # open the dialog for customer/vendor details
 716 sub action_show_customer_vendor_details_dialog {
 717   my ($self) = @_;
 718
 719   my $is_customer = 'customer' eq $::form->{vc};
 720   my $cv;
 721   if ($is_customer) {
 722     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 723   } else {
 724     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 725   }
 726
 727   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 728   $details{discount_as_percent} = $cv->discount_as_percent;
 729   $details{creditlimt}          = $cv->creditlimit_as_number;
 730   $details{business}            = $cv->business->description      if $cv->business;
 731   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 732   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 733   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 734   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 735
 736   foreach my $entry (@{ $cv->shipto }) {
 737     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 738   }
 739   foreach my $entry (@{ $cv->contacts }) {
 740     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 741   }
 742
 743   $_[0]->render('common/show_vc_details', { layout => 0 },
 744                 is_customer => $is_customer,
 745                 %details);
 746
 747 }
 748
 749 # called if a unit in an existing item row is changed
 750 sub action_unit_changed {
 751   my ($self) = @_;
 752
 753   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 754   my $item = $self->order->items_sorted->[$idx];
 755
 756   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 757   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 758
 759   $self->recalc();
 760
 761   $self->js
 762     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 763   $self->js_redisplay_line_values;
 764   $self->js_redisplay_amounts_and_taxes;
 765   $self->js->render();
 766 }
 767
 768 # add an item row for a new item entered in the input row
 769 sub action_add_item {
 770   my ($self) = @_;
 771
 772   my $form_attr = $::form->{add_item};
 773
 774   return unless $form_attr->{parts_id};
 775
 776   my $item = new_item($self->order, $form_attr);
 777
 778   $self->order->add_items($item);
 779
 780   $self->recalc();
 781
 782   $self->get_item_cvpartnumber($item);
 783
 784   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 785   my $row_as_html = $self->p->render('order/tabs/_row',
 786                                      ITEM => $item,
 787                                      ID   => $item_id,
 788                                      SELF => $self,
 789   );
 790
 791   if ($::form->{insert_before_item_id}) {
 792     $self->js
 793       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 794   } else {
 795     $self->js
 796       ->append('#row_table_id', $row_as_html);
 797   }
 798
 799   if ( $item->part->is_assortment ) {
 800     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 801     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 802       my $attr = { parts_id => $assortment_item->parts_id,
 803                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 804                    unit     => $assortment_item->unit,
 805                    description => $assortment_item->part->description,
 806                  };
 807       my $item = new_item($self->order, $attr);
 808
 809       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 810       $item->discount(1) unless $assortment_item->charge;
 811
 812       $self->order->add_items( $item );
 813       $self->recalc();
 814       $self->get_item_cvpartnumber($item);
 815       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 816       my $row_as_html = $self->p->render('order/tabs/_row',
 817                                          ITEM => $item,
 818                                          ID   => $item_id,
 819                                          SELF => $self,
 820       );
 821       if ($::form->{insert_before_item_id}) {
 822         $self->js
 823           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 824       } else {
 825         $self->js
 826           ->append('#row_table_id', $row_as_html);
 827       }
 828     };
 829   };
 830
 831   $self->js
 832     ->val('.add_item_input', '')
 833     ->run('kivi.Order.init_row_handlers')
 834     ->run('kivi.Order.renumber_positions')
 835     ->focus('#add_item_parts_id_name');
 836
 837   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 838
 839   $self->js_redisplay_amounts_and_taxes;
 840   $self->js->render();
 841 }
 842
 843 # open the dialog for entering multiple items at once
 844 sub action_show_multi_items_dialog {
 845   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 846                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 847 }
 848
 849 # update the filter results in the multi item dialog
 850 sub action_multi_items_update_result {
 851   my $max_count = 100;
 852
 853   $::form->{multi_items}->{filter}->{obsolete} = 0;
 854
 855   my $count = $_[0]->multi_items_models->count;
 856
 857   if ($count == 0) {
 858     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 859     $_[0]->render($text, { layout => 0 });
 860   } elsif ($count > $max_count) {
 861     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 862     $_[0]->render($text, { layout => 0 });
 863   } else {
 864     my $multi_items = $_[0]->multi_items_models->get;
 865     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 866                   multi_items => $multi_items);
 867   }
 868 }
 869
 870 # add item rows for multiple items at once
 871 sub action_add_multi_items {
 872   my ($self) = @_;
 873
 874   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 875   return $self->js->render() unless scalar @form_attr;
 876
 877   my @items;
 878   foreach my $attr (@form_attr) {
 879     my $item = new_item($self->order, $attr);
 880     push @items, $item;
 881     if ( $item->part->is_assortment ) {
 882       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 883         my $attr = { parts_id => $assortment_item->parts_id,
 884                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 885                      unit     => $assortment_item->unit,
 886                      description => $assortment_item->part->description,
 887                    };
 888         my $item = new_item($self->order, $attr);
 889
 890         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 891         $item->discount(1) unless $assortment_item->charge;
 892         push @items, $item;
 893       }
 894     }
 895   }
 896   $self->order->add_items(@items);
 897
 898   $self->recalc();
 899
 900   foreach my $item (@items) {
 901     $self->get_item_cvpartnumber($item);
 902     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 903     my $row_as_html = $self->p->render('order/tabs/_row',
 904                                        ITEM => $item,
 905                                        ID   => $item_id,
 906                                        SELF => $self,
 907     );
 908
 909     if ($::form->{insert_before_item_id}) {
 910       $self->js
 911         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 912     } else {
 913       $self->js
 914         ->append('#row_table_id', $row_as_html);
 915     }
 916   }
 917
 918   $self->js
 919     ->run('kivi.Order.close_multi_items_dialog')
 920     ->run('kivi.Order.init_row_handlers')
 921     ->run('kivi.Order.renumber_positions')
 922     ->focus('#add_item_parts_id_name');
 923
 924   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 925
 926   $self->js_redisplay_amounts_and_taxes;
 927   $self->js->render();
 928 }
 929
 930 # recalculate all linetotals, amounts and taxes and redisplay them
 931 sub action_recalc_amounts_and_taxes {
 932   my ($self) = @_;
 933
 934   $self->recalc();
 935
 936   $self->js_redisplay_line_values;
 937   $self->js_redisplay_amounts_and_taxes;
 938   $self->js->render();
 939 }
 940
 941 sub action_update_exchangerate {
 942   my ($self) = @_;
 943
 944   my $data = {
 945     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 946     currency_name => $self->order->currency->name,
 947     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 948   };
 949
 950   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 951 }
 952
 953 # redisplay item rows if they are sorted by an attribute
 954 sub action_reorder_items {
 955   my ($self) = @_;
 956
 957   my %sort_keys = (
 958     partnumber   => sub { $_[0]->part->partnumber },
 959     description  => sub { $_[0]->description },
 960     qty          => sub { $_[0]->qty },
 961     sellprice    => sub { $_[0]->sellprice },
 962     discount     => sub { $_[0]->discount },
 963     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 964   );
 965
 966   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 967
 968   my $method = $sort_keys{$::form->{order_by}};
 969   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 970   if ($::form->{sort_dir}) {
 971     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 972       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 973     } else {
 974       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 975     }
 976   } else {
 977     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 978       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 979     } else {
 980       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 981     }
 982   }
 983   $self->js
 984     ->run('kivi.Order.redisplay_items', \@to_sort)
 985     ->render;
 986 }
 987
 988 # show the popup to choose a price/discount source
 989 sub action_price_popup {
 990   my ($self) = @_;
 991
 992   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 993   my $item = $self->order->items_sorted->[$idx];
 994
 995   $self->render_price_dialog($item);
 996 }
 997
 998 # get the longdescription for an item if the dialog to enter/change the
 999 # longdescription was opened and the longdescription is empty
1000 #
1001 # If this item is new, get the longdescription from Part.
1002 # Otherwise get it from OrderItem.
1003 sub action_get_item_longdescription {
1004   my $longdescription;
1005
1006   if ($::form->{item_id}) {
1007     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
1008   } elsif ($::form->{parts_id}) {
1009     $longdescription = get_part_texts($::form->{parts_id}, $::form->{language_id})->{longdescription};
1010   }
1011   $_[0]->render(\ $longdescription, { type => 'text' });
1012 }
1013
1014 # load the second row for one or more items
1015 #
1016 # This action gets the html code for all items second rows by rendering a template for
1017 # the second row and sets the html code via client js.
1018 sub action_load_second_rows {
1019   my ($self) = @_;
1020
1021   $self->recalc() if $self->order->is_sales; # for margin calculation
1022
1023   foreach my $item_id (@{ $::form->{item_ids} }) {
1024     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1025     my $item = $self->order->items_sorted->[$idx];
1026
1027     $self->js_load_second_row($item, $item_id, 0);
1028   }
1029
1030   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1031
1032   $self->js->render();
1033 }
1034
1035 # update description, notes and sellprice from master data
1036 sub action_update_row_from_master_data {
1037   my ($self) = @_;
1038
1039   foreach my $item_id (@{ $::form->{item_ids} }) {
1040     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1041     my $item  = $self->order->items_sorted->[$idx];
1042     my $texts = get_part_texts($item->part, $self->order->language_id);
1043
1044     $item->description($texts->{description});
1045     $item->longdescription($texts->{longdescription});
1046
1047     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1048
1049     my $price_src;
1050     if ($item->part->is_assortment) {
1051     # add assortment items with price 0, as the components carry the price
1052       $price_src = $price_source->price_from_source("");
1053       $price_src->price(0);
1054     } else {
1055       $price_src = $price_source->best_price
1056                  ? $price_source->best_price
1057                  : $price_source->price_from_source("");
1058       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1059       $price_src->price(0) if !$price_source->best_price;
1060     }
1061
1062
1063     $item->sellprice($price_src->price);
1064     $item->active_price_source($price_src);
1065
1066     $self->js
1067       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1068       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1069       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1070       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1071
1072     if ($self->search_cvpartnumber) {
1073       $self->get_item_cvpartnumber($item);
1074       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1075     }
1076   }
1077
1078   $self->recalc();
1079   $self->js_redisplay_line_values;
1080   $self->js_redisplay_amounts_and_taxes;
1081
1082   $self->js->render();
1083 }
1084
1085 sub js_load_second_row {
1086   my ($self, $item, $item_id, $do_parse) = @_;
1087
1088   if ($do_parse) {
1089     # Parse values from form (they are formated while rendering (template)).
1090     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1091     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1092     foreach my $var (@{ $item->cvars_by_config }) {
1093       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1094     }
1095     $item->parse_custom_variable_values;
1096   }
1097
1098   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1099
1100   $self->js
1101     ->html('#second_row_' . $item_id, $row_as_html)
1102     ->data('#second_row_' . $item_id, 'loaded', 1);
1103 }
1104
1105 sub js_redisplay_line_values {
1106   my ($self) = @_;
1107
1108   my $is_sales = $self->order->is_sales;
1109
1110   # sales orders with margins
1111   my @data;
1112   if ($is_sales) {
1113     @data = map {
1114       [
1115        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1116        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1117        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1118       ]} @{ $self->order->items_sorted };
1119   } else {
1120     @data = map {
1121       [
1122        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1123       ]} @{ $self->order->items_sorted };
1124   }
1125
1126   $self->js
1127     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1128 }
1129
1130 sub js_redisplay_amounts_and_taxes {
1131   my ($self) = @_;
1132
1133   if (scalar @{ $self->{taxes} }) {
1134     $self->js->show('#taxincluded_row_id');
1135   } else {
1136     $self->js->hide('#taxincluded_row_id');
1137   }
1138
1139   if ($self->order->taxincluded) {
1140     $self->js->hide('#subtotal_row_id');
1141   } else {
1142     $self->js->show('#subtotal_row_id');
1143   }
1144
1145   if ($self->order->is_sales) {
1146     my $is_neg = $self->order->marge_total < 0;
1147     $self->js
1148       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1149       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1150       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1151       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1152       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1153       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1154       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1155       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1156   }
1157
1158   $self->js
1159     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1160     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1161     ->remove('.tax_row')
1162     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1163 }
1164
1165 sub js_redisplay_cvpartnumbers {
1166   my ($self) = @_;
1167
1168   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1169
1170   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1171
1172   $self->js
1173     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1174 }
1175
1176 sub js_reset_order_and_item_ids_after_save {
1177   my ($self) = @_;
1178
1179   $self->js
1180     ->val('#id', $self->order->id)
1181     ->val('#converted_from_oe_id', '')
1182     ->val('#order_' . $self->nr_key(), $self->order->number);
1183
1184   my $idx = 0;
1185   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1186     next if !$self->order->items_sorted->[$idx]->id;
1187     next if $form_item_id !~ m{^new};
1188     $self->js
1189       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1190       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1191       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1192   } continue {
1193     $idx++;
1194   }
1195   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1196 }
1197
1198 #
1199 # helpers
1200 #
1201
1202 sub init_valid_types {
1203   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1204 }
1205
1206 sub init_type {
1207   my ($self) = @_;
1208
1209   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1210     die "Not a valid type for order";
1211   }
1212
1213   $self->type($::form->{type});
1214 }
1215
1216 sub init_cv {
1217   my ($self) = @_;
1218
1219   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1220          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1221          : die "Not a valid type for order";
1222
1223   return $cv;
1224 }
1225
1226 sub init_search_cvpartnumber {
1227   my ($self) = @_;
1228
1229   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1230   my $search_cvpartnumber;
1231   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1232   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1233
1234   return $search_cvpartnumber;
1235 }
1236
1237 sub init_show_update_button {
1238   my ($self) = @_;
1239
1240   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1241 }
1242
1243 sub init_p {
1244   SL::Presenter->get;
1245 }
1246
1247 sub init_order {
1248   $_[0]->make_order;
1249 }
1250
1251 # model used to filter/display the parts in the multi-items dialog
1252 sub init_multi_items_models {
1253   SL::Controller::Helper::GetModels->new(
1254     controller     => $_[0],
1255     model          => 'Part',
1256     with_objects   => [ qw(unit_obj) ],
1257     disable_plugin => 'paginated',
1258     source         => $::form->{multi_items},
1259     sorted         => {
1260       _default    => {
1261         by  => 'partnumber',
1262         dir => 1,
1263       },
1264       partnumber  => t8('Partnumber'),
1265       description => t8('Description')}
1266   );
1267 }
1268
1269 sub init_all_price_factors {
1270   SL::DB::Manager::PriceFactor->get_all;
1271 }
1272
1273 sub check_auth {
1274   my ($self) = @_;
1275
1276   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1277
1278   my $right   = $right_for->{ $self->type };
1279   $right    ||= 'DOES_NOT_EXIST';
1280
1281   $::auth->assert($right);
1282 }
1283
1284 # build the selection box for contacts
1285 #
1286 # Needed, if customer/vendor changed.
1287 sub build_contact_select {
1288   my ($self) = @_;
1289
1290   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1291     value_key  => 'cp_id',
1292     title_key  => 'full_name_dep',
1293     default    => $self->order->cp_id,
1294     with_empty => 1,
1295     style      => 'width: 300px',
1296   );
1297 }
1298
1299 # build the selection box for shiptos
1300 #
1301 # Needed, if customer/vendor changed.
1302 sub build_shipto_select {
1303   my ($self) = @_;
1304
1305   select_tag('order.shipto_id',
1306              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1307              value_key  => 'shipto_id',
1308              title_key  => 'displayable_id',
1309              default    => $self->order->shipto_id,
1310              with_empty => 0,
1311              style      => 'width: 300px',
1312   );
1313 }
1314
1315 # build the inputs for the cusom shipto dialog
1316 #
1317 # Needed, if customer/vendor changed.
1318 sub build_shipto_inputs {
1319   my ($self) = @_;
1320
1321   my $content = $self->p->render('common/_ship_to_dialog',
1322                                  vc_obj      => $self->order->customervendor,
1323                                  cs_obj      => $self->order->custom_shipto,
1324                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1325                                  id_selector => '#order_shipto_id');
1326
1327   div_tag($content, id => 'shipto_inputs');
1328 }
1329
1330 # render the info line for business
1331 #
1332 # Needed, if customer/vendor changed.
1333 sub build_business_info_row
1334 {
1335   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1336 }
1337
1338 # build the rows for displaying taxes
1339 #
1340 # Called if amounts where recalculated and redisplayed.
1341 sub build_tax_rows {
1342   my ($self) = @_;
1343
1344   my $rows_as_html;
1345   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1346     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1347   }
1348   return $rows_as_html;
1349 }
1350
1351
1352 sub render_price_dialog {
1353   my ($self, $record_item) = @_;
1354
1355   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1356
1357   $self->js
1358     ->run(
1359       'kivi.io.price_chooser_dialog',
1360       t8('Available Prices'),
1361       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1362     )
1363     ->reinit_widgets;
1364
1365 #   if (@errors) {
1366 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1367 #     $self->js->show('#dialog_flash_error');
1368 #   }
1369
1370   $self->js->render;
1371 }
1372
1373 sub load_order {
1374   my ($self) = @_;
1375
1376   return if !$::form->{id};
1377
1378   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1379
1380   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1381   # You need a custom shipto object to call cvars_by_config to get the cvars.
1382   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1383
1384   return $self->order;
1385 }
1386
1387 # load or create a new order object
1388 #
1389 # And assign changes from the form to this object.
1390 # If the order is loaded from db, check if items are deleted in the form,
1391 # remove them form the object and collect them for removing from db on saving.
1392 # Then create/update items from form (via make_item) and add them.
1393 sub make_order {
1394   my ($self) = @_;
1395
1396   # add_items adds items to an order with no items for saving, but they cannot
1397   # be retrieved via items until the order is saved. Adding empty items to new
1398   # order here solves this problem.
1399   my $order;
1400   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1401   $order ||= SL::DB::Order->new(orderitems  => [],
1402                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1403                                 currency_id => $::instance_conf->get_currency_id(),);
1404
1405   my $cv_id_method = $self->cv . '_id';
1406   if (!$::form->{id} && $::form->{$cv_id_method}) {
1407     $order->$cv_id_method($::form->{$cv_id_method});
1408     setup_order_from_cv($order);
1409   }
1410
1411   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1412   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1413
1414   $order->assign_attributes(%{$::form->{order}});
1415
1416   $self->setup_custom_shipto_from_form($order, $::form);
1417
1418   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1419     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1420     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1421   }
1422
1423   # remove deleted items
1424   $self->item_ids_to_delete([]);
1425   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1426     my $item = $order->orderitems->[$idx];
1427     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1428       splice @{$order->orderitems}, $idx, 1;
1429       push @{$self->item_ids_to_delete}, $item->id;
1430     }
1431   }
1432
1433   my @items;
1434   my $pos = 1;
1435   foreach my $form_attr (@{$form_orderitems}) {
1436     my $item = make_item($order, $form_attr);
1437     $item->position($pos);
1438     push @items, $item;
1439     $pos++;
1440   }
1441   $order->add_items(grep {!$_->id} @items);
1442
1443   return $order;
1444 }
1445
1446 # create or update items from form
1447 #
1448 # Make item objects from form values. For items already existing read from db.
1449 # Create a new item else. And assign attributes.
1450 sub make_item {
1451   my ($record, $attr) = @_;
1452
1453   my $item;
1454   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1455
1456   my $is_new = !$item;
1457
1458   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1459   # they cannot be retrieved via custom_variables until the order/orderitem is
1460   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1461   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1462
1463   $item->assign_attributes(%$attr);
1464
1465   if ($is_new) {
1466     my $texts = get_part_texts($item->part, $record->language_id);
1467     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1468     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1469     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1470   }
1471
1472   return $item;
1473 }
1474
1475 # create a new item
1476 #
1477 # This is used to add one item
1478 sub new_item {
1479   my ($record, $attr) = @_;
1480
1481   my $item = SL::DB::OrderItem->new;
1482
1483   # Remove attributes where the user left or set the inputs empty.
1484   # So these attributes will be undefined and we can distinguish them
1485   # from zero later on.
1486   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1487     delete $attr->{$_} if $attr->{$_} eq '';
1488   }
1489
1490   $item->assign_attributes(%$attr);
1491
1492   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1493   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1494
1495   $item->unit($part->unit) if !$item->unit;
1496
1497   my $price_src;
1498   if ( $part->is_assortment ) {
1499     # add assortment items with price 0, as the components carry the price
1500     $price_src = $price_source->price_from_source("");
1501     $price_src->price(0);
1502   } elsif (defined $item->sellprice) {
1503     $price_src = $price_source->price_from_source("");
1504     $price_src->price($item->sellprice);
1505   } else {
1506     $price_src = $price_source->best_price
1507                ? $price_source->best_price
1508                : $price_source->price_from_source("");
1509     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1510     $price_src->price(0) if !$price_source->best_price;
1511   }
1512
1513   my $discount_src;
1514   if (defined $item->discount) {
1515     $discount_src = $price_source->discount_from_source("");
1516     $discount_src->discount($item->discount);
1517   } else {
1518     $discount_src = $price_source->best_discount
1519                   ? $price_source->best_discount
1520                   : $price_source->discount_from_source("");
1521     $discount_src->discount(0) if !$price_source->best_discount;
1522   }
1523
1524   my %new_attr;
1525   $new_attr{part}                   = $part;
1526   $new_attr{description}            = $part->description     if ! $item->description;
1527   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1528   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1529   $new_attr{sellprice}              = $price_src->price;
1530   $new_attr{discount}               = $discount_src->discount;
1531   $new_attr{active_price_source}    = $price_src;
1532   $new_attr{active_discount_source} = $discount_src;
1533   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1534   $new_attr{project_id}             = $record->globalproject_id;
1535   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1536
1537   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1538   # they cannot be retrieved via custom_variables until the order/orderitem is
1539   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1540   $new_attr{custom_variables} = [];
1541
1542   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1543
1544   $item->assign_attributes(%new_attr, %{ $texts });
1545
1546   return $item;
1547 }
1548
1549 sub setup_order_from_cv {
1550   my ($order) = @_;
1551
1552   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1553
1554   $order->intnotes($order->customervendor->notes);
1555
1556   if ($order->is_sales) {
1557     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1558     $order->taxincluded(defined($order->customer->taxincluded_checked)
1559                         ? $order->customer->taxincluded_checked
1560                         : $::myconfig{taxincluded_checked});
1561   }
1562
1563 }
1564
1565 # setup custom shipto from form
1566 #
1567 # The dialog returns form variables starting with 'shipto' and cvars starting
1568 # with 'shiptocvar_'.
1569 # Mark it to be deleted if a shipto from master data is selected
1570 # (i.e. order has a shipto).
1571 # Else, update or create a new custom shipto. If the fields are empty, it
1572 # will not be saved on save.
1573 sub setup_custom_shipto_from_form {
1574   my ($self, $order, $form) = @_;
1575
1576   if ($order->shipto) {
1577     $self->is_custom_shipto_to_delete(1);
1578   } else {
1579     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1580
1581     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1582     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1583
1584     $custom_shipto->assign_attributes(%$shipto_attrs);
1585     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1586   }
1587 }
1588
1589 # recalculate prices and taxes
1590 #
1591 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1592 sub recalc {
1593   my ($self) = @_;
1594
1595   my %pat = $self->order->calculate_prices_and_taxes();
1596
1597   $self->{taxes} = [];
1598   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1599     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1600
1601     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1602                                 netamount => $netamount,
1603                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1604   }
1605   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1606 }
1607
1608 # get data for saving, printing, ..., that is not changed in the form
1609 #
1610 # Only cvars for now.
1611 sub get_unalterable_data {
1612   my ($self) = @_;
1613
1614   foreach my $item (@{ $self->order->items }) {
1615     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1616     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1617     foreach my $var (@{ $item->cvars_by_config }) {
1618       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1619     }
1620     $item->parse_custom_variable_values;
1621   }
1622 }
1623
1624 # delete the order
1625 #
1626 # And remove related files in the spool directory
1627 sub delete {
1628   my ($self) = @_;
1629
1630   my $errors = [];
1631   my $db     = $self->order->db;
1632
1633   $db->with_transaction(
1634     sub {
1635       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1636       $self->order->delete;
1637       my $spool = $::lx_office_conf{paths}->{spool};
1638       unlink map { "$spool/$_" } @spoolfiles if $spool;
1639
1640       1;
1641   }) || push(@{$errors}, $db->error);
1642
1643   return $errors;
1644 }
1645
1646 # save the order
1647 #
1648 # And delete items that are deleted in the form.
1649 sub save {
1650   my ($self) = @_;
1651
1652   my $errors = [];
1653   my $db     = $self->order->db;
1654
1655   $db->with_transaction(sub {
1656     # delete custom shipto if it is to be deleted or if it is empty
1657     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1658       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1659       $self->order->custom_shipto(undef);
1660     }
1661
1662     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1663     $self->order->save(cascade => 1);
1664
1665     # link records
1666     if ($::form->{converted_from_oe_id}) {
1667       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1668       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1669         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1670         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1671         $src->link_to_record($self->order);
1672       }
1673       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1674         my $idx = 0;
1675         foreach (@{ $self->order->items_sorted }) {
1676           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1677           next if !$from_id;
1678           SL::DB::RecordLink->new(from_table => 'orderitems',
1679                                   from_id    => $from_id,
1680                                   to_table   => 'orderitems',
1681                                   to_id      => $_->id
1682           )->save;
1683           $idx++;
1684         }
1685       }
1686     }
1687     1;
1688   }) || push(@{$errors}, $db->error);
1689
1690   return $errors;
1691 }
1692
1693 sub workflow_sales_or_purchase_order {
1694   my ($self) = @_;
1695
1696   # always save
1697   my $errors = $self->save();
1698
1699   if (scalar @{ $errors }) {
1700     $self->js->flash('error', $_) foreach @{ $errors };
1701     return $self->js->render();
1702   }
1703
1704   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1705                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1706                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1707                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1708                        : '';
1709
1710   # check for direct delivery
1711   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1712   my $custom_shipto;
1713   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1714       && $::form->{use_shipto} && $self->order->shipto) {
1715     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1716   }
1717
1718   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1719   $self->{converted_from_oe_id} = delete $::form->{id};
1720
1721   # set item ids to new fake id, to identify them as new items
1722   foreach my $item (@{$self->order->items_sorted}) {
1723     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1724   }
1725
1726   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1727     if ($::form->{use_shipto}) {
1728       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1729     } else {
1730       # remove any custom shipto if not wanted
1731       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1732     }
1733   }
1734
1735   # change form type
1736   $::form->{type} = $destination_type;
1737   $self->type($self->init_type);
1738   $self->cv  ($self->init_cv);
1739   $self->check_auth;
1740
1741   $self->recalc();
1742   $self->get_unalterable_data();
1743   $self->pre_render();
1744
1745   # trigger rendering values for second row/longdescription as hidden,
1746   # because they are loaded only on demand. So we need to keep the values
1747   # from the source.
1748   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1749   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1750
1751   $self->render(
1752     'order/form',
1753     title => $self->get_title_for('edit'),
1754     %{$self->{template_args}}
1755   );
1756 }
1757
1758
1759 sub pre_render {
1760   my ($self) = @_;
1761
1762   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1763   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1764   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1765   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1766   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1767                                                                                               deleted => 0 ] ],
1768                                                                            sort_by => 'name');
1769   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1770                                                                                               deleted => 0 ] ],
1771                                                                            sort_by => 'name');
1772   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1773                                                                                                         obsolete => 0 ] ]);
1774   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1775   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1776   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1777   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1778   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1779
1780   my $print_form = Form->new('');
1781   $print_form->{type}        = $self->type;
1782   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1783   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1784     form => $print_form,
1785     options => {dialog_name_prefix => 'print_options.',
1786                 show_headers       => 1,
1787                 no_queue           => 1,
1788                 no_postscript      => 1,
1789                 no_opendocument    => 0,
1790                 no_html            => 1},
1791   );
1792
1793   foreach my $item (@{$self->order->orderitems}) {
1794     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1795     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1796     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1797   }
1798
1799   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1800     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1801     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1802   }
1803
1804   if ($self->order->number && $::instance_conf->get_webdav) {
1805     my $webdav = SL::Webdav->new(
1806       type     => $self->type,
1807       number   => $self->order->number,
1808     );
1809     my @all_objects = $webdav->get_all_objects;
1810     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1811                                                     type => t8('File'),
1812                                                     link => File::Spec->catfile($_->full_filedescriptor),
1813                                                 } } @all_objects;
1814   }
1815
1816   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1817
1818   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1819                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up);
1820   $self->setup_edit_action_bar;
1821 }
1822
1823 sub setup_edit_action_bar {
1824   my ($self, %params) = @_;
1825
1826   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1827                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1828                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1829
1830   for my $bar ($::request->layout->get('actionbar')) {
1831     $bar->add(
1832       combobox => [
1833         action => [
1834           t8('Save'),
1835           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1836                                                     $::instance_conf->get_order_warn_no_deliverydate,
1837                                                                                                       ],
1838           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1839         ],
1840         action => [
1841           t8('Save as new'),
1842           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1843           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1844           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1845         ],
1846       ], # end of combobox "Save"
1847
1848       combobox => [
1849         action => [
1850           t8('Workflow'),
1851         ],
1852         action => [
1853           t8('Save and Sales Order'),
1854           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1855           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1856         ],
1857         action => [
1858           t8('Save and Purchase Order'),
1859           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1860           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1861         ],
1862         action => [
1863           t8('Save and Delivery Order'),
1864           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1865                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1866                                                                                                                         ],
1867           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1868           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1869         ],
1870         action => [
1871           t8('Save and Invoice'),
1872           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1873           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1874         ],
1875         action => [
1876           t8('Save and AP Transaction'),
1877           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1878           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1879         ],
1880
1881       ], # end of combobox "Workflow"
1882
1883       combobox => [
1884         action => [
1885           t8('Export'),
1886         ],
1887         action => [
1888           t8('Save and print'),
1889           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1890         ],
1891         action => [
1892           t8('Save and E-mail'),
1893           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts ],
1894           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1895         ],
1896         action => [
1897           t8('Download attachments of all parts'),
1898           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1899           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1900           only_if  => $::instance_conf->get_doc_storage,
1901         ],
1902       ], # end of combobox "Export"
1903
1904       action => [
1905         t8('Delete'),
1906         call     => [ 'kivi.Order.delete_order' ],
1907         confirm  => $::locale->text('Do you really want to delete this object?'),
1908         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1909         only_if  => $deletion_allowed,
1910       ],
1911
1912       combobox => [
1913         action => [
1914           t8('more')
1915         ],
1916         action => [
1917           t8('Follow-Up'),
1918           call     => [ 'kivi.Order.follow_up_window' ],
1919           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1920           only_if  => $::auth->assert('productivity', 1),
1921         ],
1922       ], # end of combobox "more"
1923     );
1924   }
1925 }
1926
1927 sub generate_pdf {
1928   my ($order, $pdf_ref, $params) = @_;
1929
1930   my @errors = ();
1931
1932   my $print_form = Form->new('');
1933   $print_form->{type}        = $order->type;
1934   $print_form->{formname}    = $params->{formname} || $order->type;
1935   $print_form->{format}      = $params->{format}   || 'pdf';
1936   $print_form->{media}       = $params->{media}    || 'file';
1937   $print_form->{groupitems}  = $params->{groupitems};
1938   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1939
1940   $order->language($params->{language});
1941   $order->flatten_to_form($print_form, format_amounts => 1);
1942
1943   my $template_ext;
1944   my $template_type;
1945   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1946     $template_ext  = 'odt';
1947     $template_type = 'OpenDocument';
1948   }
1949
1950   # search for the template
1951   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1952     name        => $print_form->{formname},
1953     extension   => $template_ext,
1954     email       => $print_form->{media} eq 'email',
1955     language    => $params->{language},
1956     printer_id  => $print_form->{printer_id},  # todo
1957   );
1958
1959   if (!defined $template_file) {
1960     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1961   }
1962
1963   return @errors if scalar @errors;
1964
1965   $print_form->throw_on_error(sub {
1966     eval {
1967       $print_form->prepare_for_printing;
1968
1969       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1970         format        => $print_form->{format},
1971         template_type => $template_type,
1972         template      => $template_file,
1973         variables     => $print_form,
1974         variable_content_types => {
1975           longdescription => 'html',
1976           partnotes       => 'html',
1977           notes           => 'html',
1978         },
1979       );
1980       1;
1981     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1982   });
1983
1984   return @errors;
1985 }
1986
1987 sub get_files_for_email_dialog {
1988   my ($self) = @_;
1989
1990   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1991
1992   return %files if !$::instance_conf->get_doc_storage;
1993
1994   if ($self->order->id) {
1995     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1996     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1997     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1998   }
1999
2000   my @parts =
2001     uniq_by { $_->{id} }
2002     map {
2003       +{ id         => $_->part->id,
2004          partnumber => $_->part->partnumber }
2005     } @{$self->order->items_sorted};
2006
2007   foreach my $part (@parts) {
2008     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2009     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2010   }
2011
2012   foreach my $key (keys %files) {
2013     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2014   }
2015
2016   return %files;
2017 }
2018
2019 sub make_periodic_invoices_config_from_yaml {
2020   my ($yaml_config) = @_;
2021
2022   return if !$yaml_config;
2023   my $attr = SL::YAML::Load($yaml_config);
2024   return if 'HASH' ne ref $attr;
2025   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2026 }
2027
2028
2029 sub get_periodic_invoices_status {
2030   my ($self, $config) = @_;
2031
2032   return                      if $self->type ne sales_order_type();
2033   return t8('not configured') if !$config;
2034
2035   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2036              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2037              :                                                     die "Cannot get status of periodic invoices config";
2038
2039   return $active ? t8('active') : t8('inactive');
2040 }
2041
2042 sub get_title_for {
2043   my ($self, $action) = @_;
2044
2045   return '' if none { lc($action)} qw(add edit);
2046
2047   # for locales:
2048   # $::locale->text("Add Sales Order");
2049   # $::locale->text("Add Purchase Order");
2050   # $::locale->text("Add Quotation");
2051   # $::locale->text("Add Request for Quotation");
2052   # $::locale->text("Edit Sales Order");
2053   # $::locale->text("Edit Purchase Order");
2054   # $::locale->text("Edit Quotation");
2055   # $::locale->text("Edit Request for Quotation");
2056
2057   $action = ucfirst(lc($action));
2058   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2059        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2060        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2061        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2062        : '';
2063 }
2064
2065 sub get_item_cvpartnumber {
2066   my ($self, $item) = @_;
2067
2068   return if !$self->search_cvpartnumber;
2069   return if !$self->order->customervendor;
2070
2071   if ($self->cv eq 'vendor') {
2072     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2073     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2074   } elsif ($self->cv eq 'customer') {
2075     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2076     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2077   }
2078 }
2079
2080 sub get_part_texts {
2081   my ($part_or_id, $language_or_id, %defaults) = @_;
2082
2083   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2084   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2085   my $texts       = {
2086     description     => $defaults{description}     // $part->description,
2087     longdescription => $defaults{longdescription} // $part->notes,
2088   };
2089
2090   return $texts unless $language_id;
2091
2092   my $translation = SL::DB::Manager::Translation->get_first(
2093     where => [
2094       parts_id    => $part->id,
2095       language_id => $language_id,
2096     ]);
2097
2098   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2099   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2100
2101   return $texts;
2102 }
2103
2104 sub sales_order_type {
2105   'sales_order';
2106 }
2107
2108 sub purchase_order_type {
2109   'purchase_order';
2110 }
2111
2112 sub sales_quotation_type {
2113   'sales_quotation';
2114 }
2115
2116 sub request_quotation_type {
2117   'request_quotation';
2118 }
2119
2120 sub nr_key {
2121   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2122        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2123        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2124        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2125        : '';
2126 }
2127
2128 1;
2129
2130 __END__
2131
2132 =encoding utf-8
2133
2134 =head1 NAME
2135
2136 SL::Controller::Order - controller for orders
2137
2138 =head1 SYNOPSIS
2139
2140 This is a new form to enter orders, completely rewritten with the use
2141 of controller and java script techniques.
2142
2143 The aim is to provide the user a better experience and a faster workflow. Also
2144 the code should be more readable, more reliable and better to maintain.
2145
2146 =head2 Key Features
2147
2148 =over 4
2149
2150 =item *
2151
2152 One input row, so that input happens every time at the same place.
2153
2154 =item *
2155
2156 Use of pickers where possible.
2157
2158 =item *
2159
2160 Possibility to enter more than one item at once.
2161
2162 =item *
2163
2164 Item list in a scrollable area, so that the workflow buttons stay at
2165 the bottom.
2166
2167 =item *
2168
2169 Reordering item rows with drag and drop is possible. Sorting item rows is
2170 possible (by partnumber, description, qty, sellprice and discount for now).
2171
2172 =item *
2173
2174 No C<update> is necessary. All entries and calculations are managed
2175 with ajax-calls and the page only reloads on C<save>.
2176
2177 =item *
2178
2179 User can see changes immediately, because of the use of java script
2180 and ajax.
2181
2182 =back
2183
2184 =head1 CODE
2185
2186 =head2 Layout
2187
2188 =over 4
2189
2190 =item * C<SL/Controller/Order.pm>
2191
2192 the controller
2193
2194 =item * C<template/webpages/order/form.html>
2195
2196 main form
2197
2198 =item * C<template/webpages/order/tabs/basic_data.html>
2199
2200 Main tab for basic_data.
2201
2202 This is the only tab here for now. "linked records" and "webdav" tabs are
2203 reused from generic code.
2204
2205 =over 4
2206
2207 =item * C<template/webpages/order/tabs/_business_info_row.html>
2208
2209 For displaying information on business type
2210
2211 =item * C<template/webpages/order/tabs/_item_input.html>
2212
2213 The input line for items
2214
2215 =item * C<template/webpages/order/tabs/_row.html>
2216
2217 One row for already entered items
2218
2219 =item * C<template/webpages/order/tabs/_tax_row.html>
2220
2221 Displaying tax information
2222
2223 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
2224
2225 Dialog for entering more than one item at once
2226
2227 =item * C<template/webpages/order/tabs/_multi_items_result.html>
2228
2229 Results for the filter in the multi items dialog
2230
2231 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2232
2233 Dialog for selecting price and discount sources
2234
2235 =back
2236
2237 =item * C<js/kivi.Order.js>
2238
2239 java script functions
2240
2241 =back
2242
2243 =head1 TODO
2244
2245 =over 4
2246
2247 =item * testing
2248
2249 =item * credit limit
2250
2251 =item * more workflows (quotation, rfq)
2252
2253 =item * price sources: little symbols showing better price / better discount
2254
2255 =item * select units in input row?
2256
2257 =item * check for direct delivery (workflow sales order -> purchase order)
2258
2259 =item * language / part translations
2260
2261 =item * access rights
2262
2263 =item * display weights
2264
2265 =item * history
2266
2267 =item * mtime check
2268
2269 =item * optional client/user behaviour
2270
2271 (transactions has to be set - department has to be set -
2272  force project if enabled in client config - transport cost reminder)
2273
2274 =back
2275
2276 =head1 KNOWN BUGS AND CAVEATS
2277
2278 =over 4
2279
2280 =item *
2281
2282 Customer discount is not displayed as a valid discount in price source popup
2283 (this might be a bug in price sources)
2284
2285 (I cannot reproduce this (Bernd))
2286
2287 =item *
2288
2289 No indication that <shift>-up/down expands/collapses second row.
2290
2291 =item *
2292
2293 Inline creation of parts is not currently supported
2294
2295 =item *
2296
2297 Table header is not sticky in the scrolling area.
2298
2299 =item *
2300
2301 Sorting does not include C<position>, neither does reordering.
2302
2303 This behavior was implemented intentionally. But we can discuss, which behavior
2304 should be implemented.
2305
2306 =item *
2307
2308 C<show_multi_items_dialog> does not use the currently inserted string for
2309 filtering.
2310
2311 =back
2312
2313 =head1 To discuss / Nice to have
2314
2315 =over 4
2316
2317 =item *
2318
2319 How to expand/collapse second row. Now it can be done clicking the icon or
2320 <shift>-up/down.
2321
2322 =item *
2323
2324 Possibility to change longdescription in input row?
2325
2326 =item *
2327
2328 Possibility to select PriceSources in input row?
2329
2330 =item *
2331
2332 This controller uses a (changed) copy of the template for the PriceSource
2333 dialog. Maybe there could be used one code source.
2334
2335 =item *
2336
2337 Rounding-differences between this controller (PriceTaxCalculator) and the old
2338 form. This is not only a problem here, but also in all parts using the PTC.
2339 There exists a ticket and a patch. This patch should be testet.
2340
2341 =item *
2342
2343 An indicator, if the actual inputs are saved (like in an
2344 editor or on text processing application).
2345
2346 =item *
2347
2348 A warning when leaving the page without saveing unchanged inputs.
2349
2350
2351 =back
2352
2353 =head1 AUTHOR
2354
2355 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2356
2357 =cut