SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24 use SL::DB::Shipto;
  25 use SL::DB::Translation;
  26
  27 use SL::Helper::CreatePDF qw(:all);
  28 use SL::Helper::PrintOptions;
  29 use SL::Helper::ShippedQty;
  30 use SL::Helper::UserPreferences::PositionsScrollbar;
  31 use SL::Helper::UserPreferences::UpdatePositions;
  32
  33 use SL::Controller::Helper::GetModels;
  34
  35 use List::Util qw(first sum0);
  36 use List::UtilsBy qw(sort_by uniq_by);
  37 use List::MoreUtils qw(any none pairwise first_index);
  38 use English qw(-no_match_vars);
  39 use File::Spec;
  40 use Cwd;
  41 use Sort::Naturally;
  42
  43 use Rose::Object::MakeMethods::Generic
  44 (
  45  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  46  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors search_cvpartnumber show_update_button) ],
  47 );
  48
  49
  50 # safety
  51 __PACKAGE__->run_before('check_auth');
  52
  53 __PACKAGE__->run_before('recalc',
  54                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  55                                      print send_email) ]);
  56
  57 __PACKAGE__->run_before('get_unalterable_data',
  58                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  59                                      print send_email) ]);
  60
  61 #
  62 # actions
  63 #
  64
  65 # add a new order
  66 sub action_add {
  67   my ($self) = @_;
  68
  69   $self->order->transdate(DateTime->now_local());
  70   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  71                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  72   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  73
  74
  75   $self->pre_render();
  76   $self->render(
  77     'order/form',
  78     title => $self->get_title_for('add'),
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 # edit an existing order
  84 sub action_edit {
  85   my ($self) = @_;
  86
  87   if ($::form->{id}) {
  88     $self->load_order;
  89
  90   } else {
  91     # this is to edit an order from an unsaved order object
  92
  93     # set item ids to new fake id, to identify them as new items
  94     foreach my $item (@{$self->order->items_sorted}) {
  95       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  96     }
  97     # trigger rendering values for second row as hidden, because they
  98     # are loaded only on demand. So we need to keep the values from
  99     # the source.
 100     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 101   }
 102
 103   $self->recalc();
 104   $self->pre_render();
 105   $self->render(
 106     'order/form',
 107     title => $self->get_title_for('edit'),
 108     %{$self->{template_args}}
 109   );
 110 }
 111
 112 # edit a collective order (consisting of one or more existing orders)
 113 sub action_edit_collective {
 114   my ($self) = @_;
 115
 116   # collect order ids
 117   my @multi_ids = map {
 118     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 119   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 120
 121   # fall back to add if no ids are given
 122   if (scalar @multi_ids == 0) {
 123     $self->action_add();
 124     return;
 125   }
 126
 127   # fall back to save as new if only one id is given
 128   if (scalar @multi_ids == 1) {
 129     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 130     $self->action_save_as_new();
 131     return;
 132   }
 133
 134   # make new order from given orders
 135   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 136   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 137   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 138
 139   $self->action_edit();
 140 }
 141
 142 # delete the order
 143 sub action_delete {
 144   my ($self) = @_;
 145
 146   my $errors = $self->delete();
 147
 148   if (scalar @{ $errors }) {
 149     $self->js->flash('error', $_) foreach @{ $errors };
 150     return $self->js->render();
 151   }
 152
 153   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 154            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 155            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 156            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 157            : '';
 158   flash_later('info', $text);
 159
 160   my @redirect_params = (
 161     action => 'add',
 162     type   => $self->type,
 163   );
 164
 165   $self->redirect_to(@redirect_params);
 166 }
 167
 168 # save the order
 169 sub action_save {
 170   my ($self) = @_;
 171
 172   my $errors = $self->save();
 173
 174   if (scalar @{ $errors }) {
 175     $self->js->flash('error', $_) foreach @{ $errors };
 176     return $self->js->render();
 177   }
 178
 179   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 180            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 181            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 182            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 183            : '';
 184   flash_later('info', $text);
 185
 186   my @redirect_params = (
 187     action => 'edit',
 188     type   => $self->type,
 189     id     => $self->order->id,
 190   );
 191
 192   $self->redirect_to(@redirect_params);
 193 }
 194
 195 # save the order as new document an open it for edit
 196 sub action_save_as_new {
 197   my ($self) = @_;
 198
 199   my $order = $self->order;
 200
 201   if (!$order->id) {
 202     $self->js->flash('error', t8('This object has not been saved yet.'));
 203     return $self->js->render();
 204   }
 205
 206   # load order from db to check if values changed
 207   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 208
 209   my %new_attrs;
 210   # Lets assign a new number if the user hasn't changed the previous one.
 211   # If it has been changed manually then use it as-is.
 212   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 213                         ? ''
 214                         : trim($order->number);
 215
 216   # Clear transdate unless changed
 217   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 218                         ? DateTime->today_local
 219                         : $order->transdate;
 220
 221   # Set new reqdate unless changed
 222   if ($order->reqdate == $saved_order->reqdate) {
 223     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 224                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 225     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 226   } else {
 227     $new_attrs{reqdate} = $order->reqdate;
 228   }
 229
 230   # Update employee
 231   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 232
 233   # Create new record from current one
 234   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 235
 236   # no linked records on save as new
 237   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 238
 239   # save
 240   $self->action_save();
 241 }
 242
 243 # print the order
 244 #
 245 # This is called if "print" is pressed in the print dialog.
 246 # If PDF creation was requested and succeeded, the pdf is offered for download
 247 # via send_file (which uses ajax in this case).
 248 sub action_print {
 249   my ($self) = @_;
 250
 251   my $errors = $self->save();
 252
 253   if (scalar @{ $errors }) {
 254     $self->js->flash('error', $_) foreach @{ $errors };
 255     return $self->js->render();
 256   }
 257
 258   $self->js_reset_order_and_item_ids_after_save;
 259
 260   my $format      = $::form->{print_options}->{format};
 261   my $media       = $::form->{print_options}->{media};
 262   my $formname    = $::form->{print_options}->{formname};
 263   my $copies      = $::form->{print_options}->{copies};
 264   my $groupitems  = $::form->{print_options}->{groupitems};
 265
 266   # only pdf and opendocument by now
 267   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 268     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 269   }
 270
 271   # only screen or printer by now
 272   if (none { $media eq $_ } qw(screen printer)) {
 273     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 274   }
 275
 276   # create a form for generate_attachment_filename
 277   my $form   = Form->new;
 278   $form->{$self->nr_key()}  = $self->order->number;
 279   $form->{type}             = $self->type;
 280   $form->{format}           = $format;
 281   $form->{formname}         = $formname;
 282   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 283   my $pdf_filename          = $form->generate_attachment_filename();
 284
 285   my $pdf;
 286   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 287                                                    formname   => $formname,
 288                                                    language   => $self->order->language,
 289                                                    groupitems => $groupitems });
 290   if (scalar @errors) {
 291     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 292   }
 293
 294   if ($media eq 'screen') {
 295     # screen/download
 296     $self->js->flash('info', t8('The PDF has been created'));
 297     $self->send_file(
 298       \$pdf,
 299       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 300       name         => $pdf_filename,
 301       js_no_render => 1,
 302     );
 303
 304   } elsif ($media eq 'printer') {
 305     # printer
 306     my $printer_id = $::form->{print_options}->{printer_id};
 307     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 308       copies  => $copies,
 309       content => $pdf,
 310     );
 311
 312     $self->js->flash('info', t8('The PDF has been printed'));
 313   }
 314
 315   # copy file to webdav folder
 316   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 317     my $webdav = SL::Webdav->new(
 318       type     => $self->type,
 319       number   => $self->order->number,
 320     );
 321     my $webdav_file = SL::Webdav::File->new(
 322       webdav   => $webdav,
 323       filename => $pdf_filename,
 324     );
 325     eval {
 326       $webdav_file->store(data => \$pdf);
 327       1;
 328     } or do {
 329       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 330     }
 331   }
 332   if ($self->order->number && $::instance_conf->get_doc_storage) {
 333     eval {
 334       SL::File->save(object_id     => $self->order->id,
 335                      object_type   => $self->type,
 336                      mime_type     => 'application/pdf',
 337                      source        => 'created',
 338                      file_type     => 'document',
 339                      file_name     => $pdf_filename,
 340                      file_contents => $pdf);
 341       1;
 342     } or do {
 343       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 344     }
 345   }
 346   $self->js->render;
 347 }
 348
 349 # open the email dialog
 350 sub action_save_and_show_email_dialog {
 351   my ($self) = @_;
 352
 353   my $errors = $self->save();
 354
 355   if (scalar @{ $errors }) {
 356     $self->js->flash('error', $_) foreach @{ $errors };
 357     return $self->js->render();
 358   }
 359
 360   my $cv_method = $self->cv;
 361
 362   if (!$self->order->$cv_method) {
 363     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 364                     ->render($self);
 365   }
 366
 367   my $email_form;
 368   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 369   $email_form->{to} ||= $self->order->$cv_method->email;
 370   $email_form->{cc}   = $self->order->$cv_method->cc;
 371   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 372   # Todo: get addresses from shipto, if any
 373
 374   my $form = Form->new;
 375   $form->{$self->nr_key()}  = $self->order->number;
 376   $form->{cusordnumber}     = $self->order->cusordnumber;
 377   $form->{formname}         = $self->type;
 378   $form->{type}             = $self->type;
 379   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 380   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 381   $form->{format}           = 'pdf';
 382
 383   $email_form->{subject}             = $form->generate_email_subject();
 384   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 385   $email_form->{message}             = $form->generate_email_body();
 386   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 387
 388   my %files = $self->get_files_for_email_dialog();
 389   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 390                                   email_form  => $email_form,
 391                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 392                                   FILES       => \%files,
 393                                   is_customer => $self->cv eq 'customer',
 394   );
 395
 396   $self->js
 397       ->run('kivi.Order.show_email_dialog', $dialog_html)
 398       ->reinit_widgets
 399       ->render($self);
 400 }
 401
 402 # send email
 403 #
 404 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 405 sub action_send_email {
 406   my ($self) = @_;
 407
 408   my $errors = $self->save();
 409
 410   if (scalar @{ $errors }) {
 411     $self->js->run('kivi.Order.close_email_dialog');
 412     $self->js->flash('error', $_) foreach @{ $errors };
 413     return $self->js->render();
 414   }
 415
 416   $self->js_reset_order_and_item_ids_after_save;
 417
 418   my $email_form  = delete $::form->{email_form};
 419   my %field_names = (to => 'email');
 420
 421   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 422
 423   # for Form::cleanup which may be called in Form::send_email
 424   $::form->{cwd}    = getcwd();
 425   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 426
 427   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 428   $::form->{media}  = 'email';
 429
 430   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 431     my $pdf;
 432     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 433                                                     format     => $::form->{print_options}->{format},
 434                                                     formname   => $::form->{print_options}->{formname},
 435                                                     language   => $self->order->language,
 436                                                     groupitems => $::form->{print_options}->{groupitems}});
 437     if (scalar @errors) {
 438       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 439     }
 440
 441     my $sfile = SL::SessionFile::Random->new(mode => "w");
 442     $sfile->fh->print($pdf);
 443     $sfile->fh->close;
 444
 445     $::form->{tmpfile} = $sfile->file_name;
 446     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 447   }
 448
 449   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 450   $::form->send_email(\%::myconfig, 'pdf');
 451
 452   # internal notes
 453   my $intnotes = $self->order->intnotes;
 454   $intnotes   .= "\n\n" if $self->order->intnotes;
 455   $intnotes   .= t8('[email]')                                                                                        . "\n";
 456   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 457   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 458   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 459   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 460   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 461   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 462
 463   $self->order->update_attributes(intnotes => $intnotes);
 464
 465   flash_later('info', t8('The email has been sent.'));
 466
 467   my @redirect_params = (
 468     action => 'edit',
 469     type   => $self->type,
 470     id     => $self->order->id,
 471   );
 472
 473   $self->redirect_to(@redirect_params);
 474 }
 475
 476 # open the periodic invoices config dialog
 477 #
 478 # If there are values in the form (i.e. dialog was opened before),
 479 # then use this values. Create new ones, else.
 480 sub action_show_periodic_invoices_config_dialog {
 481   my ($self) = @_;
 482
 483   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 484   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 485   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 486                                                    order_value_periodicity => 'p', # = same as periodicity
 487                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 488                                                    extend_automatically_by => 12,
 489                                                    active                  => 1,
 490                                                    email_subject           => GenericTranslations->get(
 491                                                                                 language_id      => $::form->{language_id},
 492                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 493                                                    email_body              => GenericTranslations->get(
 494                                                                                 language_id      => $::form->{language_id},
 495                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 496   );
 497   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 498   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 499
 500   $::form->get_lists(printers => "ALL_PRINTERS",
 501                      charts   => { key       => 'ALL_CHARTS',
 502                                    transdate => 'current_date' });
 503
 504   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 505
 506   if ($::form->{customer_id}) {
 507     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 508     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 509   }
 510
 511   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 512                 popup_dialog             => 1,
 513                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 514                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 515                 config                   => $config,
 516                 %$::form);
 517 }
 518
 519 # assign the values of the periodic invoices config dialog
 520 # as yaml in the hidden tag and set the status.
 521 sub action_assign_periodic_invoices_config {
 522   my ($self) = @_;
 523
 524   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 525
 526   my $config = { active                     => $::form->{active}       ? 1 : 0,
 527                  terminated                 => $::form->{terminated}   ? 1 : 0,
 528                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 529                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 530                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 531                  start_date_as_date         => $::form->{start_date_as_date},
 532                  end_date_as_date           => $::form->{end_date_as_date},
 533                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 534                  print                      => $::form->{print}      ? 1                         : 0,
 535                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 536                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 537                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 538                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 539                  send_email                 => $::form->{send_email} ? 1 : 0,
 540                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 541                  email_recipient_address    => $::form->{email_recipient_address},
 542                  email_sender               => $::form->{email_sender},
 543                  email_subject              => $::form->{email_subject},
 544                  email_body                 => $::form->{email_body},
 545                };
 546
 547   my $periodic_invoices_config = SL::YAML::Dump($config);
 548
 549   my $status = $self->get_periodic_invoices_status($config);
 550
 551   $self->js
 552     ->remove('#order_periodic_invoices_config')
 553     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 554     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 555     ->html('#periodic_invoices_status', $status)
 556     ->flash('info', t8('The periodic invoices config has been assigned.'))
 557     ->render($self);
 558 }
 559
 560 sub action_get_has_active_periodic_invoices {
 561   my ($self) = @_;
 562
 563   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 564   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 565
 566   my $has_active_periodic_invoices =
 567        $self->type eq sales_order_type()
 568     && $config
 569     && $config->active
 570     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 571     && $config->get_previous_billed_period_start_date;
 572
 573   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 574 }
 575
 576 # save the order and redirect to the frontend subroutine for a new
 577 # delivery order
 578 sub action_save_and_delivery_order {
 579   my ($self) = @_;
 580
 581   my $errors = $self->save();
 582
 583   if (scalar @{ $errors }) {
 584     $self->js->flash('error', $_) foreach @{ $errors };
 585     return $self->js->render();
 586   }
 587
 588   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 589            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 590            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 591            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 592            : '';
 593   flash_later('info', $text);
 594
 595   my @redirect_params = (
 596     controller => 'oe.pl',
 597     action     => 'oe_delivery_order_from_order',
 598     id         => $self->order->id,
 599   );
 600
 601   $self->redirect_to(@redirect_params);
 602 }
 603
 604 # save the order and redirect to the frontend subroutine for a new
 605 # invoice
 606 sub action_save_and_invoice {
 607   my ($self) = @_;
 608
 609   my $errors = $self->save();
 610
 611   if (scalar @{ $errors }) {
 612     $self->js->flash('error', $_) foreach @{ $errors };
 613     return $self->js->render();
 614   }
 615
 616   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 617            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 618            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 619            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 620            : '';
 621   flash_later('info', $text);
 622
 623   my @redirect_params = (
 624     controller => 'oe.pl',
 625     action     => 'oe_invoice_from_order',
 626     id         => $self->order->id,
 627   );
 628
 629   $self->redirect_to(@redirect_params);
 630 }
 631
 632 # workflow from sales quotation to sales order
 633 sub action_sales_order {
 634   $_[0]->workflow_sales_or_purchase_order();
 635 }
 636
 637 # workflow from rfq to purchase order
 638 sub action_purchase_order {
 639   $_[0]->workflow_sales_or_purchase_order();
 640 }
 641
 642 # workflow from purchase order to ap transaction
 643 sub action_save_and_ap_transaction {
 644   my ($self) = @_;
 645
 646   my $errors = $self->save();
 647
 648   if (scalar @{ $errors }) {
 649     $self->js->flash('error', $_) foreach @{ $errors };
 650     return $self->js->render();
 651   }
 652
 653   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 654            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 655            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 656            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 657            : '';
 658   flash_later('info', $text);
 659
 660   my @redirect_params = (
 661     controller => 'ap.pl',
 662     action     => 'add_from_purchase_order',
 663     id         => $self->order->id,
 664   );
 665
 666   $self->redirect_to(@redirect_params);
 667 }
 668
 669 # set form elements in respect to a changed customer or vendor
 670 #
 671 # This action is called on an change of the customer/vendor picker.
 672 sub action_customer_vendor_changed {
 673   my ($self) = @_;
 674
 675   setup_order_from_cv($self->order);
 676   $self->recalc();
 677
 678   my $cv_method = $self->cv;
 679
 680   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 681     $self->js->show('#cp_row');
 682   } else {
 683     $self->js->hide('#cp_row');
 684   }
 685
 686   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 687     $self->js->show('#shipto_selection');
 688   } else {
 689     $self->js->hide('#shipto_selection');
 690   }
 691
 692   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 693
 694   $self->js
 695     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 696     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 697     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 698     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 699     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 700     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 701     ->val(        '#order_currency_id',      $self->order->currency_id)
 702     ->val(        '#order_payment_id',       $self->order->payment_id)
 703     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 704     ->val(        '#order_intnotes',         $self->order->intnotes)
 705     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 706     ->focus(      '#order_' . $self->cv . '_id')
 707     ->run('kivi.Order.update_exchangerate');
 708
 709   $self->js_redisplay_amounts_and_taxes;
 710   $self->js_redisplay_cvpartnumbers;
 711   $self->js->render();
 712 }
 713
 714 # open the dialog for customer/vendor details
 715 sub action_show_customer_vendor_details_dialog {
 716   my ($self) = @_;
 717
 718   my $is_customer = 'customer' eq $::form->{vc};
 719   my $cv;
 720   if ($is_customer) {
 721     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 722   } else {
 723     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 724   }
 725
 726   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 727   $details{discount_as_percent} = $cv->discount_as_percent;
 728   $details{creditlimt}          = $cv->creditlimit_as_number;
 729   $details{business}            = $cv->business->description      if $cv->business;
 730   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 731   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 732   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 733   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 734
 735   foreach my $entry (@{ $cv->shipto }) {
 736     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 737   }
 738   foreach my $entry (@{ $cv->contacts }) {
 739     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 740   }
 741
 742   $_[0]->render('common/show_vc_details', { layout => 0 },
 743                 is_customer => $is_customer,
 744                 %details);
 745
 746 }
 747
 748 # called if a unit in an existing item row is changed
 749 sub action_unit_changed {
 750   my ($self) = @_;
 751
 752   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 753   my $item = $self->order->items_sorted->[$idx];
 754
 755   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 756   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 757
 758   $self->recalc();
 759
 760   $self->js
 761     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 762   $self->js_redisplay_line_values;
 763   $self->js_redisplay_amounts_and_taxes;
 764   $self->js->render();
 765 }
 766
 767 # add an item row for a new item entered in the input row
 768 sub action_add_item {
 769   my ($self) = @_;
 770
 771   my $form_attr = $::form->{add_item};
 772
 773   return unless $form_attr->{parts_id};
 774
 775   my $item = new_item($self->order, $form_attr);
 776
 777   $self->order->add_items($item);
 778
 779   $self->recalc();
 780
 781   $self->get_item_cvpartnumber($item);
 782
 783   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 784   my $row_as_html = $self->p->render('order/tabs/_row',
 785                                      ITEM => $item,
 786                                      ID   => $item_id,
 787                                      SELF => $self,
 788   );
 789
 790   if ($::form->{insert_before_item_id}) {
 791     $self->js
 792       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 793   } else {
 794     $self->js
 795       ->append('#row_table_id', $row_as_html);
 796   }
 797
 798   if ( $item->part->is_assortment ) {
 799     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 800     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 801       my $attr = { parts_id => $assortment_item->parts_id,
 802                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 803                    unit     => $assortment_item->unit,
 804                    description => $assortment_item->part->description,
 805                  };
 806       my $item = new_item($self->order, $attr);
 807
 808       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 809       $item->discount(1) unless $assortment_item->charge;
 810
 811       $self->order->add_items( $item );
 812       $self->recalc();
 813       $self->get_item_cvpartnumber($item);
 814       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 815       my $row_as_html = $self->p->render('order/tabs/_row',
 816                                          ITEM => $item,
 817                                          ID   => $item_id,
 818                                          SELF => $self,
 819       );
 820       if ($::form->{insert_before_item_id}) {
 821         $self->js
 822           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 823       } else {
 824         $self->js
 825           ->append('#row_table_id', $row_as_html);
 826       }
 827     };
 828   };
 829
 830   $self->js
 831     ->val('.add_item_input', '')
 832     ->run('kivi.Order.init_row_handlers')
 833     ->run('kivi.Order.renumber_positions')
 834     ->focus('#add_item_parts_id_name');
 835
 836   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 837
 838   $self->js_redisplay_amounts_and_taxes;
 839   $self->js->render();
 840 }
 841
 842 # open the dialog for entering multiple items at once
 843 sub action_show_multi_items_dialog {
 844   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 845                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 846 }
 847
 848 # update the filter results in the multi item dialog
 849 sub action_multi_items_update_result {
 850   my $max_count = 100;
 851
 852   $::form->{multi_items}->{filter}->{obsolete} = 0;
 853
 854   my $count = $_[0]->multi_items_models->count;
 855
 856   if ($count == 0) {
 857     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 858     $_[0]->render($text, { layout => 0 });
 859   } elsif ($count > $max_count) {
 860     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 861     $_[0]->render($text, { layout => 0 });
 862   } else {
 863     my $multi_items = $_[0]->multi_items_models->get;
 864     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 865                   multi_items => $multi_items);
 866   }
 867 }
 868
 869 # add item rows for multiple items at once
 870 sub action_add_multi_items {
 871   my ($self) = @_;
 872
 873   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 874   return $self->js->render() unless scalar @form_attr;
 875
 876   my @items;
 877   foreach my $attr (@form_attr) {
 878     my $item = new_item($self->order, $attr);
 879     push @items, $item;
 880     if ( $item->part->is_assortment ) {
 881       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 882         my $attr = { parts_id => $assortment_item->parts_id,
 883                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 884                      unit     => $assortment_item->unit,
 885                      description => $assortment_item->part->description,
 886                    };
 887         my $item = new_item($self->order, $attr);
 888
 889         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 890         $item->discount(1) unless $assortment_item->charge;
 891         push @items, $item;
 892       }
 893     }
 894   }
 895   $self->order->add_items(@items);
 896
 897   $self->recalc();
 898
 899   foreach my $item (@items) {
 900     $self->get_item_cvpartnumber($item);
 901     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 902     my $row_as_html = $self->p->render('order/tabs/_row',
 903                                        ITEM => $item,
 904                                        ID   => $item_id,
 905                                        SELF => $self,
 906     );
 907
 908     if ($::form->{insert_before_item_id}) {
 909       $self->js
 910         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 911     } else {
 912       $self->js
 913         ->append('#row_table_id', $row_as_html);
 914     }
 915   }
 916
 917   $self->js
 918     ->run('kivi.Order.close_multi_items_dialog')
 919     ->run('kivi.Order.init_row_handlers')
 920     ->run('kivi.Order.renumber_positions')
 921     ->focus('#add_item_parts_id_name');
 922
 923   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 924
 925   $self->js_redisplay_amounts_and_taxes;
 926   $self->js->render();
 927 }
 928
 929 # recalculate all linetotals, amounts and taxes and redisplay them
 930 sub action_recalc_amounts_and_taxes {
 931   my ($self) = @_;
 932
 933   $self->recalc();
 934
 935   $self->js_redisplay_line_values;
 936   $self->js_redisplay_amounts_and_taxes;
 937   $self->js->render();
 938 }
 939
 940 sub action_update_exchangerate {
 941   my ($self) = @_;
 942
 943   my $data = {
 944     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 945     currency_name => $self->order->currency->name,
 946     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 947   };
 948
 949   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 950 }
 951
 952 # redisplay item rows if they are sorted by an attribute
 953 sub action_reorder_items {
 954   my ($self) = @_;
 955
 956   my %sort_keys = (
 957     partnumber   => sub { $_[0]->part->partnumber },
 958     description  => sub { $_[0]->description },
 959     qty          => sub { $_[0]->qty },
 960     sellprice    => sub { $_[0]->sellprice },
 961     discount     => sub { $_[0]->discount },
 962     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 963   );
 964
 965   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 966
 967   my $method = $sort_keys{$::form->{order_by}};
 968   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 969   if ($::form->{sort_dir}) {
 970     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 971       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 972     } else {
 973       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 974     }
 975   } else {
 976     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 977       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 978     } else {
 979       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 980     }
 981   }
 982   $self->js
 983     ->run('kivi.Order.redisplay_items', \@to_sort)
 984     ->render;
 985 }
 986
 987 # show the popup to choose a price/discount source
 988 sub action_price_popup {
 989   my ($self) = @_;
 990
 991   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 992   my $item = $self->order->items_sorted->[$idx];
 993
 994   $self->render_price_dialog($item);
 995 }
 996
 997 # load the second row for one or more items
 998 #
 999 # This action gets the html code for all items second rows by rendering a template for
1000 # the second row and sets the html code via client js.
1001 sub action_load_second_rows {
1002   my ($self) = @_;
1003
1004   $self->recalc() if $self->order->is_sales; # for margin calculation
1005
1006   foreach my $item_id (@{ $::form->{item_ids} }) {
1007     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1008     my $item = $self->order->items_sorted->[$idx];
1009
1010     $self->js_load_second_row($item, $item_id, 0);
1011   }
1012
1013   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1014
1015   $self->js->render();
1016 }
1017
1018 # update description, notes and sellprice from master data
1019 sub action_update_row_from_master_data {
1020   my ($self) = @_;
1021
1022   foreach my $item_id (@{ $::form->{item_ids} }) {
1023     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1024     my $item  = $self->order->items_sorted->[$idx];
1025     my $texts = get_part_texts($item->part, $self->order->language_id);
1026
1027     $item->description($texts->{description});
1028     $item->longdescription($texts->{longdescription});
1029
1030     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1031
1032     my $price_src;
1033     if ($item->part->is_assortment) {
1034     # add assortment items with price 0, as the components carry the price
1035       $price_src = $price_source->price_from_source("");
1036       $price_src->price(0);
1037     } else {
1038       $price_src = $price_source->best_price
1039                  ? $price_source->best_price
1040                  : $price_source->price_from_source("");
1041       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1042       $price_src->price(0) if !$price_source->best_price;
1043     }
1044
1045
1046     $item->sellprice($price_src->price);
1047     $item->active_price_source($price_src);
1048
1049     $self->js
1050       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1051       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1052       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1053       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1054
1055     if ($self->search_cvpartnumber) {
1056       $self->get_item_cvpartnumber($item);
1057       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1058     }
1059   }
1060
1061   $self->recalc();
1062   $self->js_redisplay_line_values;
1063   $self->js_redisplay_amounts_and_taxes;
1064
1065   $self->js->render();
1066 }
1067
1068 sub js_load_second_row {
1069   my ($self, $item, $item_id, $do_parse) = @_;
1070
1071   if ($do_parse) {
1072     # Parse values from form (they are formated while rendering (template)).
1073     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1074     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1075     foreach my $var (@{ $item->cvars_by_config }) {
1076       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1077     }
1078     $item->parse_custom_variable_values;
1079   }
1080
1081   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1082
1083   $self->js
1084     ->html('#second_row_' . $item_id, $row_as_html)
1085     ->data('#second_row_' . $item_id, 'loaded', 1);
1086 }
1087
1088 sub js_redisplay_line_values {
1089   my ($self) = @_;
1090
1091   my $is_sales = $self->order->is_sales;
1092
1093   # sales orders with margins
1094   my @data;
1095   if ($is_sales) {
1096     @data = map {
1097       [
1098        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1099        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1100        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1101       ]} @{ $self->order->items_sorted };
1102   } else {
1103     @data = map {
1104       [
1105        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1106       ]} @{ $self->order->items_sorted };
1107   }
1108
1109   $self->js
1110     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1111 }
1112
1113 sub js_redisplay_amounts_and_taxes {
1114   my ($self) = @_;
1115
1116   if (scalar @{ $self->{taxes} }) {
1117     $self->js->show('#taxincluded_row_id');
1118   } else {
1119     $self->js->hide('#taxincluded_row_id');
1120   }
1121
1122   if ($self->order->taxincluded) {
1123     $self->js->hide('#subtotal_row_id');
1124   } else {
1125     $self->js->show('#subtotal_row_id');
1126   }
1127
1128   if ($self->order->is_sales) {
1129     my $is_neg = $self->order->marge_total < 0;
1130     $self->js
1131       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1132       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1133       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1134       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1135       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1136       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1137       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1138       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1139   }
1140
1141   $self->js
1142     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1143     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1144     ->remove('.tax_row')
1145     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1146 }
1147
1148 sub js_redisplay_cvpartnumbers {
1149   my ($self) = @_;
1150
1151   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1152
1153   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1154
1155   $self->js
1156     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1157 }
1158
1159 sub js_reset_order_and_item_ids_after_save {
1160   my ($self) = @_;
1161
1162   $self->js
1163     ->val('#id', $self->order->id)
1164     ->val('#converted_from_oe_id', '')
1165     ->val('#order_' . $self->nr_key(), $self->order->number);
1166
1167   my $idx = 0;
1168   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1169     next if !$self->order->items_sorted->[$idx]->id;
1170     next if $form_item_id !~ m{^new};
1171     $self->js
1172       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1173       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1174       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1175   } continue {
1176     $idx++;
1177   }
1178   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1179 }
1180
1181 #
1182 # helpers
1183 #
1184
1185 sub init_valid_types {
1186   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1187 }
1188
1189 sub init_type {
1190   my ($self) = @_;
1191
1192   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1193     die "Not a valid type for order";
1194   }
1195
1196   $self->type($::form->{type});
1197 }
1198
1199 sub init_cv {
1200   my ($self) = @_;
1201
1202   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1203          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1204          : die "Not a valid type for order";
1205
1206   return $cv;
1207 }
1208
1209 sub init_search_cvpartnumber {
1210   my ($self) = @_;
1211
1212   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1213   my $search_cvpartnumber;
1214   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1215   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1216
1217   return $search_cvpartnumber;
1218 }
1219
1220 sub init_show_update_button {
1221   my ($self) = @_;
1222
1223   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1224 }
1225
1226 sub init_p {
1227   SL::Presenter->get;
1228 }
1229
1230 sub init_order {
1231   $_[0]->make_order;
1232 }
1233
1234 # model used to filter/display the parts in the multi-items dialog
1235 sub init_multi_items_models {
1236   SL::Controller::Helper::GetModels->new(
1237     controller     => $_[0],
1238     model          => 'Part',
1239     with_objects   => [ qw(unit_obj) ],
1240     disable_plugin => 'paginated',
1241     source         => $::form->{multi_items},
1242     sorted         => {
1243       _default    => {
1244         by  => 'partnumber',
1245         dir => 1,
1246       },
1247       partnumber  => t8('Partnumber'),
1248       description => t8('Description')}
1249   );
1250 }
1251
1252 sub init_all_price_factors {
1253   SL::DB::Manager::PriceFactor->get_all;
1254 }
1255
1256 sub check_auth {
1257   my ($self) = @_;
1258
1259   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1260
1261   my $right   = $right_for->{ $self->type };
1262   $right    ||= 'DOES_NOT_EXIST';
1263
1264   $::auth->assert($right);
1265 }
1266
1267 # build the selection box for contacts
1268 #
1269 # Needed, if customer/vendor changed.
1270 sub build_contact_select {
1271   my ($self) = @_;
1272
1273   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1274     value_key  => 'cp_id',
1275     title_key  => 'full_name_dep',
1276     default    => $self->order->cp_id,
1277     with_empty => 1,
1278     style      => 'width: 300px',
1279   );
1280 }
1281
1282 # build the selection box for shiptos
1283 #
1284 # Needed, if customer/vendor changed.
1285 sub build_shipto_select {
1286   my ($self) = @_;
1287
1288   select_tag('order.shipto_id',
1289              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1290              value_key  => 'shipto_id',
1291              title_key  => 'displayable_id',
1292              default    => $self->order->shipto_id,
1293              with_empty => 0,
1294              style      => 'width: 300px',
1295   );
1296 }
1297
1298 # build the inputs for the cusom shipto dialog
1299 #
1300 # Needed, if customer/vendor changed.
1301 sub build_shipto_inputs {
1302   my ($self) = @_;
1303
1304   my $content = $self->p->render('common/_ship_to_dialog',
1305                                  vc_obj      => $self->order->customervendor,
1306                                  cs_obj      => $self->order->custom_shipto,
1307                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1308                                  id_selector => '#order_shipto_id');
1309
1310   div_tag($content, id => 'shipto_inputs');
1311 }
1312
1313 # render the info line for business
1314 #
1315 # Needed, if customer/vendor changed.
1316 sub build_business_info_row
1317 {
1318   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1319 }
1320
1321 # build the rows for displaying taxes
1322 #
1323 # Called if amounts where recalculated and redisplayed.
1324 sub build_tax_rows {
1325   my ($self) = @_;
1326
1327   my $rows_as_html;
1328   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1329     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1330   }
1331   return $rows_as_html;
1332 }
1333
1334
1335 sub render_price_dialog {
1336   my ($self, $record_item) = @_;
1337
1338   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1339
1340   $self->js
1341     ->run(
1342       'kivi.io.price_chooser_dialog',
1343       t8('Available Prices'),
1344       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1345     )
1346     ->reinit_widgets;
1347
1348 #   if (@errors) {
1349 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1350 #     $self->js->show('#dialog_flash_error');
1351 #   }
1352
1353   $self->js->render;
1354 }
1355
1356 sub load_order {
1357   my ($self) = @_;
1358
1359   return if !$::form->{id};
1360
1361   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1362
1363   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1364   # You need a custom shipto object to call cvars_by_config to get the cvars.
1365   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1366
1367   return $self->order;
1368 }
1369
1370 # load or create a new order object
1371 #
1372 # And assign changes from the form to this object.
1373 # If the order is loaded from db, check if items are deleted in the form,
1374 # remove them form the object and collect them for removing from db on saving.
1375 # Then create/update items from form (via make_item) and add them.
1376 sub make_order {
1377   my ($self) = @_;
1378
1379   # add_items adds items to an order with no items for saving, but they cannot
1380   # be retrieved via items until the order is saved. Adding empty items to new
1381   # order here solves this problem.
1382   my $order;
1383   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1384   $order ||= SL::DB::Order->new(orderitems  => [],
1385                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1386                                 currency_id => $::instance_conf->get_currency_id(),);
1387
1388   my $cv_id_method = $self->cv . '_id';
1389   if (!$::form->{id} && $::form->{$cv_id_method}) {
1390     $order->$cv_id_method($::form->{$cv_id_method});
1391     setup_order_from_cv($order);
1392   }
1393
1394   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1395   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1396
1397   $order->assign_attributes(%{$::form->{order}});
1398
1399   $self->setup_custom_shipto_from_form($order, $::form);
1400
1401   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1402     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1403     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1404   }
1405
1406   # remove deleted items
1407   $self->item_ids_to_delete([]);
1408   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1409     my $item = $order->orderitems->[$idx];
1410     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1411       splice @{$order->orderitems}, $idx, 1;
1412       push @{$self->item_ids_to_delete}, $item->id;
1413     }
1414   }
1415
1416   my @items;
1417   my $pos = 1;
1418   foreach my $form_attr (@{$form_orderitems}) {
1419     my $item = make_item($order, $form_attr);
1420     $item->position($pos);
1421     push @items, $item;
1422     $pos++;
1423   }
1424   $order->add_items(grep {!$_->id} @items);
1425
1426   return $order;
1427 }
1428
1429 # create or update items from form
1430 #
1431 # Make item objects from form values. For items already existing read from db.
1432 # Create a new item else. And assign attributes.
1433 sub make_item {
1434   my ($record, $attr) = @_;
1435
1436   my $item;
1437   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1438
1439   my $is_new = !$item;
1440
1441   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1442   # they cannot be retrieved via custom_variables until the order/orderitem is
1443   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1444   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1445
1446   $item->assign_attributes(%$attr);
1447
1448   if ($is_new) {
1449     my $texts = get_part_texts($item->part, $record->language_id);
1450     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1451     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1452     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1453   }
1454
1455   return $item;
1456 }
1457
1458 # create a new item
1459 #
1460 # This is used to add one item
1461 sub new_item {
1462   my ($record, $attr) = @_;
1463
1464   my $item = SL::DB::OrderItem->new;
1465
1466   # Remove attributes where the user left or set the inputs empty.
1467   # So these attributes will be undefined and we can distinguish them
1468   # from zero later on.
1469   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1470     delete $attr->{$_} if $attr->{$_} eq '';
1471   }
1472
1473   $item->assign_attributes(%$attr);
1474
1475   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1476   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1477
1478   $item->unit($part->unit) if !$item->unit;
1479
1480   my $price_src;
1481   if ( $part->is_assortment ) {
1482     # add assortment items with price 0, as the components carry the price
1483     $price_src = $price_source->price_from_source("");
1484     $price_src->price(0);
1485   } elsif (defined $item->sellprice) {
1486     $price_src = $price_source->price_from_source("");
1487     $price_src->price($item->sellprice);
1488   } else {
1489     $price_src = $price_source->best_price
1490                ? $price_source->best_price
1491                : $price_source->price_from_source("");
1492     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1493     $price_src->price(0) if !$price_source->best_price;
1494   }
1495
1496   my $discount_src;
1497   if (defined $item->discount) {
1498     $discount_src = $price_source->discount_from_source("");
1499     $discount_src->discount($item->discount);
1500   } else {
1501     $discount_src = $price_source->best_discount
1502                   ? $price_source->best_discount
1503                   : $price_source->discount_from_source("");
1504     $discount_src->discount(0) if !$price_source->best_discount;
1505   }
1506
1507   my %new_attr;
1508   $new_attr{part}                   = $part;
1509   $new_attr{description}            = $part->description     if ! $item->description;
1510   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1511   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1512   $new_attr{sellprice}              = $price_src->price;
1513   $new_attr{discount}               = $discount_src->discount;
1514   $new_attr{active_price_source}    = $price_src;
1515   $new_attr{active_discount_source} = $discount_src;
1516   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1517   $new_attr{project_id}             = $record->globalproject_id;
1518   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1519
1520   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1521   # they cannot be retrieved via custom_variables until the order/orderitem is
1522   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1523   $new_attr{custom_variables} = [];
1524
1525   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1526
1527   $item->assign_attributes(%new_attr, %{ $texts });
1528
1529   return $item;
1530 }
1531
1532 sub setup_order_from_cv {
1533   my ($order) = @_;
1534
1535   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1536
1537   $order->intnotes($order->customervendor->notes);
1538
1539   if ($order->is_sales) {
1540     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1541     $order->taxincluded(defined($order->customer->taxincluded_checked)
1542                         ? $order->customer->taxincluded_checked
1543                         : $::myconfig{taxincluded_checked});
1544   }
1545
1546 }
1547
1548 # setup custom shipto from form
1549 #
1550 # The dialog returns form variables starting with 'shipto' and cvars starting
1551 # with 'shiptocvar_'.
1552 # Mark it to be deleted if a shipto from master data is selected
1553 # (i.e. order has a shipto).
1554 # Else, update or create a new custom shipto. If the fields are empty, it
1555 # will not be saved on save.
1556 sub setup_custom_shipto_from_form {
1557   my ($self, $order, $form) = @_;
1558
1559   if ($order->shipto) {
1560     $self->is_custom_shipto_to_delete(1);
1561   } else {
1562     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1563
1564     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1565     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1566
1567     $custom_shipto->assign_attributes(%$shipto_attrs);
1568     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1569   }
1570 }
1571
1572 # recalculate prices and taxes
1573 #
1574 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1575 sub recalc {
1576   my ($self) = @_;
1577
1578   my %pat = $self->order->calculate_prices_and_taxes();
1579
1580   $self->{taxes} = [];
1581   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1582     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1583
1584     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1585                                 netamount => $netamount,
1586                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1587   }
1588   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1589 }
1590
1591 # get data for saving, printing, ..., that is not changed in the form
1592 #
1593 # Only cvars for now.
1594 sub get_unalterable_data {
1595   my ($self) = @_;
1596
1597   foreach my $item (@{ $self->order->items }) {
1598     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1599     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1600     foreach my $var (@{ $item->cvars_by_config }) {
1601       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1602     }
1603     $item->parse_custom_variable_values;
1604   }
1605 }
1606
1607 # delete the order
1608 #
1609 # And remove related files in the spool directory
1610 sub delete {
1611   my ($self) = @_;
1612
1613   my $errors = [];
1614   my $db     = $self->order->db;
1615
1616   $db->with_transaction(
1617     sub {
1618       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1619       $self->order->delete;
1620       my $spool = $::lx_office_conf{paths}->{spool};
1621       unlink map { "$spool/$_" } @spoolfiles if $spool;
1622
1623       1;
1624   }) || push(@{$errors}, $db->error);
1625
1626   return $errors;
1627 }
1628
1629 # save the order
1630 #
1631 # And delete items that are deleted in the form.
1632 sub save {
1633   my ($self) = @_;
1634
1635   my $errors = [];
1636   my $db     = $self->order->db;
1637
1638   $db->with_transaction(sub {
1639     # delete custom shipto if it is to be deleted or if it is empty
1640     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1641       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1642       $self->order->custom_shipto(undef);
1643     }
1644
1645     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1646     $self->order->save(cascade => 1);
1647
1648     # link records
1649     if ($::form->{converted_from_oe_id}) {
1650       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1651       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1652         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1653         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1654         $src->link_to_record($self->order);
1655       }
1656       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1657         my $idx = 0;
1658         foreach (@{ $self->order->items_sorted }) {
1659           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1660           next if !$from_id;
1661           SL::DB::RecordLink->new(from_table => 'orderitems',
1662                                   from_id    => $from_id,
1663                                   to_table   => 'orderitems',
1664                                   to_id      => $_->id
1665           )->save;
1666           $idx++;
1667         }
1668       }
1669     }
1670     1;
1671   }) || push(@{$errors}, $db->error);
1672
1673   return $errors;
1674 }
1675
1676 sub workflow_sales_or_purchase_order {
1677   my ($self) = @_;
1678
1679   # always save
1680   my $errors = $self->save();
1681
1682   if (scalar @{ $errors }) {
1683     $self->js->flash('error', $_) foreach @{ $errors };
1684     return $self->js->render();
1685   }
1686
1687   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1688                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1689                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1690                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1691                        : '';
1692
1693   # check for direct delivery
1694   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1695   my $custom_shipto;
1696   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1697       && $::form->{use_shipto} && $self->order->shipto) {
1698     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1699   }
1700
1701   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1702   $self->{converted_from_oe_id} = delete $::form->{id};
1703
1704   # set item ids to new fake id, to identify them as new items
1705   foreach my $item (@{$self->order->items_sorted}) {
1706     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1707   }
1708
1709   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1710     if ($::form->{use_shipto}) {
1711       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1712     } else {
1713       # remove any custom shipto if not wanted
1714       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1715     }
1716   }
1717
1718   # change form type
1719   $::form->{type} = $destination_type;
1720   $self->type($self->init_type);
1721   $self->cv  ($self->init_cv);
1722   $self->check_auth;
1723
1724   $self->recalc();
1725   $self->get_unalterable_data();
1726   $self->pre_render();
1727
1728   # trigger rendering values for second row as hidden, because they
1729   # are loaded only on demand. So we need to keep the values from the
1730   # source.
1731   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1732
1733   $self->render(
1734     'order/form',
1735     title => $self->get_title_for('edit'),
1736     %{$self->{template_args}}
1737   );
1738 }
1739
1740
1741 sub pre_render {
1742   my ($self) = @_;
1743
1744   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1745   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1746   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1747   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1748   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1749                                                                                               deleted => 0 ] ],
1750                                                                            sort_by => 'name');
1751   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1752                                                                                               deleted => 0 ] ],
1753                                                                            sort_by => 'name');
1754   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1755                                                                                                         obsolete => 0 ] ]);
1756   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1757   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1758   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1759   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1760   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1761
1762   my $print_form = Form->new('');
1763   $print_form->{type}        = $self->type;
1764   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1765   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1766     form => $print_form,
1767     options => {dialog_name_prefix => 'print_options.',
1768                 show_headers       => 1,
1769                 no_queue           => 1,
1770                 no_postscript      => 1,
1771                 no_opendocument    => 0,
1772                 no_html            => 1},
1773   );
1774
1775   foreach my $item (@{$self->order->orderitems}) {
1776     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1777     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1778     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1779   }
1780
1781   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1782     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1783     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1784   }
1785
1786   if ($self->order->number && $::instance_conf->get_webdav) {
1787     my $webdav = SL::Webdav->new(
1788       type     => $self->type,
1789       number   => $self->order->number,
1790     );
1791     my @all_objects = $webdav->get_all_objects;
1792     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1793                                                     type => t8('File'),
1794                                                     link => File::Spec->catfile($_->full_filedescriptor),
1795                                                 } } @all_objects;
1796   }
1797
1798   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1799
1800   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1801                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up);
1802   $self->setup_edit_action_bar;
1803 }
1804
1805 sub setup_edit_action_bar {
1806   my ($self, %params) = @_;
1807
1808   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1809                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1810                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1811
1812   for my $bar ($::request->layout->get('actionbar')) {
1813     $bar->add(
1814       combobox => [
1815         action => [
1816           t8('Save'),
1817           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1818                                                     $::instance_conf->get_order_warn_no_deliverydate,
1819                                                                                                       ],
1820           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1821         ],
1822         action => [
1823           t8('Save as new'),
1824           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1825           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1826           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1827         ],
1828       ], # end of combobox "Save"
1829
1830       combobox => [
1831         action => [
1832           t8('Workflow'),
1833         ],
1834         action => [
1835           t8('Save and Sales Order'),
1836           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1837           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1838         ],
1839         action => [
1840           t8('Save and Purchase Order'),
1841           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1842           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1843         ],
1844         action => [
1845           t8('Save and Delivery Order'),
1846           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1847                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1848                                                                                                                         ],
1849           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1850           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1851         ],
1852         action => [
1853           t8('Save and Invoice'),
1854           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1855           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1856         ],
1857         action => [
1858           t8('Save and AP Transaction'),
1859           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1860           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1861         ],
1862
1863       ], # end of combobox "Workflow"
1864
1865       combobox => [
1866         action => [
1867           t8('Export'),
1868         ],
1869         action => [
1870           t8('Save and print'),
1871           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1872         ],
1873         action => [
1874           t8('Save and E-mail'),
1875           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts ],
1876           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1877         ],
1878         action => [
1879           t8('Download attachments of all parts'),
1880           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1881           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1882           only_if  => $::instance_conf->get_doc_storage,
1883         ],
1884       ], # end of combobox "Export"
1885
1886       action => [
1887         t8('Delete'),
1888         call     => [ 'kivi.Order.delete_order' ],
1889         confirm  => $::locale->text('Do you really want to delete this object?'),
1890         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1891         only_if  => $deletion_allowed,
1892       ],
1893
1894       combobox => [
1895         action => [
1896           t8('more')
1897         ],
1898         action => [
1899           t8('Follow-Up'),
1900           call     => [ 'kivi.Order.follow_up_window' ],
1901           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1902           only_if  => $::auth->assert('productivity', 1),
1903         ],
1904       ], # end of combobox "more"
1905     );
1906   }
1907 }
1908
1909 sub generate_pdf {
1910   my ($order, $pdf_ref, $params) = @_;
1911
1912   my @errors = ();
1913
1914   my $print_form = Form->new('');
1915   $print_form->{type}        = $order->type;
1916   $print_form->{formname}    = $params->{formname} || $order->type;
1917   $print_form->{format}      = $params->{format}   || 'pdf';
1918   $print_form->{media}       = $params->{media}    || 'file';
1919   $print_form->{groupitems}  = $params->{groupitems};
1920   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1921
1922   $order->language($params->{language});
1923   $order->flatten_to_form($print_form, format_amounts => 1);
1924
1925   my $template_ext;
1926   my $template_type;
1927   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1928     $template_ext  = 'odt';
1929     $template_type = 'OpenDocument';
1930   }
1931
1932   # search for the template
1933   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1934     name        => $print_form->{formname},
1935     extension   => $template_ext,
1936     email       => $print_form->{media} eq 'email',
1937     language    => $params->{language},
1938     printer_id  => $print_form->{printer_id},  # todo
1939   );
1940
1941   if (!defined $template_file) {
1942     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1943   }
1944
1945   return @errors if scalar @errors;
1946
1947   $print_form->throw_on_error(sub {
1948     eval {
1949       $print_form->prepare_for_printing;
1950
1951       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1952         format        => $print_form->{format},
1953         template_type => $template_type,
1954         template      => $template_file,
1955         variables     => $print_form,
1956         variable_content_types => {
1957           longdescription => 'html',
1958           partnotes       => 'html',
1959           notes           => 'html',
1960         },
1961       );
1962       1;
1963     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1964   });
1965
1966   return @errors;
1967 }
1968
1969 sub get_files_for_email_dialog {
1970   my ($self) = @_;
1971
1972   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1973
1974   return %files if !$::instance_conf->get_doc_storage;
1975
1976   if ($self->order->id) {
1977     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1978     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1979     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1980   }
1981
1982   my @parts =
1983     uniq_by { $_->{id} }
1984     map {
1985       +{ id         => $_->part->id,
1986          partnumber => $_->part->partnumber }
1987     } @{$self->order->items_sorted};
1988
1989   foreach my $part (@parts) {
1990     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1991     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1992   }
1993
1994   foreach my $key (keys %files) {
1995     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1996   }
1997
1998   return %files;
1999 }
2000
2001 sub make_periodic_invoices_config_from_yaml {
2002   my ($yaml_config) = @_;
2003
2004   return if !$yaml_config;
2005   my $attr = SL::YAML::Load($yaml_config);
2006   return if 'HASH' ne ref $attr;
2007   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2008 }
2009
2010
2011 sub get_periodic_invoices_status {
2012   my ($self, $config) = @_;
2013
2014   return                      if $self->type ne sales_order_type();
2015   return t8('not configured') if !$config;
2016
2017   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2018              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2019              :                                                     die "Cannot get status of periodic invoices config";
2020
2021   return $active ? t8('active') : t8('inactive');
2022 }
2023
2024 sub get_title_for {
2025   my ($self, $action) = @_;
2026
2027   return '' if none { lc($action)} qw(add edit);
2028
2029   # for locales:
2030   # $::locale->text("Add Sales Order");
2031   # $::locale->text("Add Purchase Order");
2032   # $::locale->text("Add Quotation");
2033   # $::locale->text("Add Request for Quotation");
2034   # $::locale->text("Edit Sales Order");
2035   # $::locale->text("Edit Purchase Order");
2036   # $::locale->text("Edit Quotation");
2037   # $::locale->text("Edit Request for Quotation");
2038
2039   $action = ucfirst(lc($action));
2040   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2041        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2042        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2043        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2044        : '';
2045 }
2046
2047 sub get_item_cvpartnumber {
2048   my ($self, $item) = @_;
2049
2050   return if !$self->search_cvpartnumber;
2051   return if !$self->order->customervendor;
2052
2053   if ($self->cv eq 'vendor') {
2054     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2055     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2056   } elsif ($self->cv eq 'customer') {
2057     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2058     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2059   }
2060 }
2061
2062 sub get_part_texts {
2063   my ($part_or_id, $language_or_id, %defaults) = @_;
2064
2065   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2066   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2067   my $texts       = {
2068     description     => $defaults{description}     // $part->description,
2069     longdescription => $defaults{longdescription} // $part->notes,
2070   };
2071
2072   return $texts unless $language_id;
2073
2074   my $translation = SL::DB::Manager::Translation->get_first(
2075     where => [
2076       parts_id    => $part->id,
2077       language_id => $language_id,
2078     ]);
2079
2080   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2081   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2082
2083   return $texts;
2084 }
2085
2086 sub sales_order_type {
2087   'sales_order';
2088 }
2089
2090 sub purchase_order_type {
2091   'purchase_order';
2092 }
2093
2094 sub sales_quotation_type {
2095   'sales_quotation';
2096 }
2097
2098 sub request_quotation_type {
2099   'request_quotation';
2100 }
2101
2102 sub nr_key {
2103   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2104        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2105        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2106        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2107        : '';
2108 }
2109
2110 1;
2111
2112 __END__
2113
2114 =encoding utf-8
2115
2116 =head1 NAME
2117
2118 SL::Controller::Order - controller for orders
2119
2120 =head1 SYNOPSIS
2121
2122 This is a new form to enter orders, completely rewritten with the use
2123 of controller and java script techniques.
2124
2125 The aim is to provide the user a better experience and a faster workflow. Also
2126 the code should be more readable, more reliable and better to maintain.
2127
2128 =head2 Key Features
2129
2130 =over 4
2131
2132 =item *
2133
2134 One input row, so that input happens every time at the same place.
2135
2136 =item *
2137
2138 Use of pickers where possible.
2139
2140 =item *
2141
2142 Possibility to enter more than one item at once.
2143
2144 =item *
2145
2146 Item list in a scrollable area, so that the workflow buttons stay at
2147 the bottom.
2148
2149 =item *
2150
2151 Reordering item rows with drag and drop is possible. Sorting item rows is
2152 possible (by partnumber, description, qty, sellprice and discount for now).
2153
2154 =item *
2155
2156 No C<update> is necessary. All entries and calculations are managed
2157 with ajax-calls and the page only reloads on C<save>.
2158
2159 =item *
2160
2161 User can see changes immediately, because of the use of java script
2162 and ajax.
2163
2164 =back
2165
2166 =head1 CODE
2167
2168 =head2 Layout
2169
2170 =over 4
2171
2172 =item * C<SL/Controller/Order.pm>
2173
2174 the controller
2175
2176 =item * C<template/webpages/order/form.html>
2177
2178 main form
2179
2180 =item * C<template/webpages/order/tabs/basic_data.html>
2181
2182 Main tab for basic_data.
2183
2184 This is the only tab here for now. "linked records" and "webdav" tabs are
2185 reused from generic code.
2186
2187 =over 4
2188
2189 =item * C<template/webpages/order/tabs/_business_info_row.html>
2190
2191 For displaying information on business type
2192
2193 =item * C<template/webpages/order/tabs/_item_input.html>
2194
2195 The input line for items
2196
2197 =item * C<template/webpages/order/tabs/_row.html>
2198
2199 One row for already entered items
2200
2201 =item * C<template/webpages/order/tabs/_tax_row.html>
2202
2203 Displaying tax information
2204
2205 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
2206
2207 Dialog for entering more than one item at once
2208
2209 =item * C<template/webpages/order/tabs/_multi_items_result.html>
2210
2211 Results for the filter in the multi items dialog
2212
2213 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2214
2215 Dialog for selecting price and discount sources
2216
2217 =back
2218
2219 =item * C<js/kivi.Order.js>
2220
2221 java script functions
2222
2223 =back
2224
2225 =head1 TODO
2226
2227 =over 4
2228
2229 =item * testing
2230
2231 =item * credit limit
2232
2233 =item * more workflows (quotation, rfq)
2234
2235 =item * price sources: little symbols showing better price / better discount
2236
2237 =item * select units in input row?
2238
2239 =item * check for direct delivery (workflow sales order -> purchase order)
2240
2241 =item * language / part translations
2242
2243 =item * access rights
2244
2245 =item * display weights
2246
2247 =item * history
2248
2249 =item * mtime check
2250
2251 =item * optional client/user behaviour
2252
2253 (transactions has to be set - department has to be set -
2254  force project if enabled in client config - transport cost reminder)
2255
2256 =back
2257
2258 =head1 KNOWN BUGS AND CAVEATS
2259
2260 =over 4
2261
2262 =item *
2263
2264 Customer discount is not displayed as a valid discount in price source popup
2265 (this might be a bug in price sources)
2266
2267 (I cannot reproduce this (Bernd))
2268
2269 =item *
2270
2271 No indication that <shift>-up/down expands/collapses second row.
2272
2273 =item *
2274
2275 Inline creation of parts is not currently supported
2276
2277 =item *
2278
2279 Table header is not sticky in the scrolling area.
2280
2281 =item *
2282
2283 Sorting does not include C<position>, neither does reordering.
2284
2285 This behavior was implemented intentionally. But we can discuss, which behavior
2286 should be implemented.
2287
2288 =item *
2289
2290 C<show_multi_items_dialog> does not use the currently inserted string for
2291 filtering.
2292
2293 =back
2294
2295 =head1 To discuss / Nice to have
2296
2297 =over 4
2298
2299 =item *
2300
2301 How to expand/collapse second row. Now it can be done clicking the icon or
2302 <shift>-up/down.
2303
2304 =item *
2305
2306 Possibility to select PriceSources in input row?
2307
2308 =item *
2309
2310 This controller uses a (changed) copy of the template for the PriceSource
2311 dialog. Maybe there could be used one code source.
2312
2313 =item *
2314
2315 Rounding-differences between this controller (PriceTaxCalculator) and the old
2316 form. This is not only a problem here, but also in all parts using the PTC.
2317 There exists a ticket and a patch. This patch should be testet.
2318
2319 =item *
2320
2321 An indicator, if the actual inputs are saved (like in an
2322 editor or on text processing application).
2323
2324 =item *
2325
2326 A warning when leaving the page without saveing unchanged inputs.
2327
2328
2329 =back
2330
2331 =head1 AUTHOR
2332
2333 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2334
2335 =cut