SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::History;
  17 use SL::DB::Order;
  18 use SL::DB::Default;
  19 use SL::DB::Unit;
  20 use SL::DB::Part;
  21 use SL::DB::PartClassification;
  22 use SL::DB::PartsGroup;
  23 use SL::DB::Printer;
  24 use SL::DB::Language;
  25 use SL::DB::RecordLink;
  26 use SL::DB::Shipto;
  27 use SL::DB::Translation;
  28
  29 use SL::Helper::CreatePDF qw(:all);
  30 use SL::Helper::PrintOptions;
  31 use SL::Helper::ShippedQty;
  32 use SL::Helper::UserPreferences::PositionsScrollbar;
  33 use SL::Helper::UserPreferences::UpdatePositions;
  34
  35 use SL::Controller::Helper::GetModels;
  36
  37 use List::Util qw(first sum0);
  38 use List::UtilsBy qw(sort_by uniq_by);
  39 use List::MoreUtils qw(any none pairwise first_index);
  40 use English qw(-no_match_vars);
  41 use File::Spec;
  42 use Cwd;
  43 use Sort::Naturally;
  44
  45 use Rose::Object::MakeMethods::Generic
  46 (
  47  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  48  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  49 );
  50
  51
  52 # safety
  53 __PACKAGE__->run_before('check_auth');
  54
  55 __PACKAGE__->run_before('recalc',
  56                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  57                                      print send_email) ]);
  58
  59 __PACKAGE__->run_before('get_unalterable_data',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 #
  64 # actions
  65 #
  66
  67 # add a new order
  68 sub action_add {
  69   my ($self) = @_;
  70
  71   $self->order->transdate(DateTime->now_local());
  72   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  73                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  74
  75   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  76       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  77       && (!$self->order->reqdate)) {
  78     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  79   }
  80
  81
  82   $self->pre_render();
  83   $self->render(
  84     'order/form',
  85     title => $self->get_title_for('add'),
  86     %{$self->{template_args}}
  87   );
  88 }
  89
  90 # edit an existing order
  91 sub action_edit {
  92   my ($self) = @_;
  93
  94   if ($::form->{id}) {
  95     $self->load_order;
  96
  97   } else {
  98     # this is to edit an order from an unsaved order object
  99
 100     # set item ids to new fake id, to identify them as new items
 101     foreach my $item (@{$self->order->items_sorted}) {
 102       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 103     }
 104     # trigger rendering values for second row as hidden, because they
 105     # are loaded only on demand. So we need to keep the values from
 106     # the source.
 107     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 108   }
 109
 110   $self->recalc();
 111   $self->pre_render();
 112   $self->render(
 113     'order/form',
 114     title => $self->get_title_for('edit'),
 115     %{$self->{template_args}}
 116   );
 117 }
 118
 119 # edit a collective order (consisting of one or more existing orders)
 120 sub action_edit_collective {
 121   my ($self) = @_;
 122
 123   # collect order ids
 124   my @multi_ids = map {
 125     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 126   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 127
 128   # fall back to add if no ids are given
 129   if (scalar @multi_ids == 0) {
 130     $self->action_add();
 131     return;
 132   }
 133
 134   # fall back to save as new if only one id is given
 135   if (scalar @multi_ids == 1) {
 136     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 137     $self->action_save_as_new();
 138     return;
 139   }
 140
 141   # make new order from given orders
 142   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 143   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 144   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 145
 146   $self->action_edit();
 147 }
 148
 149 # delete the order
 150 sub action_delete {
 151   my ($self) = @_;
 152
 153   my $errors = $self->delete();
 154
 155   if (scalar @{ $errors }) {
 156     $self->js->flash('error', $_) foreach @{ $errors };
 157     return $self->js->render();
 158   }
 159
 160   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 161            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 162            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 163            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 164            : '';
 165   flash_later('info', $text);
 166
 167   my @redirect_params = (
 168     action => 'add',
 169     type   => $self->type,
 170   );
 171
 172   $self->redirect_to(@redirect_params);
 173 }
 174
 175 # save the order
 176 sub action_save {
 177   my ($self) = @_;
 178
 179   my $errors = $self->save();
 180
 181   if (scalar @{ $errors }) {
 182     $self->js->flash('error', $_) foreach @{ $errors };
 183     return $self->js->render();
 184   }
 185
 186   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 187            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 188            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 189            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 190            : '';
 191   flash_later('info', $text);
 192
 193   my @redirect_params = (
 194     action => 'edit',
 195     type   => $self->type,
 196     id     => $self->order->id,
 197   );
 198
 199   $self->redirect_to(@redirect_params);
 200 }
 201
 202 # save the order as new document an open it for edit
 203 sub action_save_as_new {
 204   my ($self) = @_;
 205
 206   my $order = $self->order;
 207
 208   if (!$order->id) {
 209     $self->js->flash('error', t8('This object has not been saved yet.'));
 210     return $self->js->render();
 211   }
 212
 213   # load order from db to check if values changed
 214   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 215
 216   my %new_attrs;
 217   # Lets assign a new number if the user hasn't changed the previous one.
 218   # If it has been changed manually then use it as-is.
 219   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 220                         ? ''
 221                         : trim($order->number);
 222
 223   # Clear transdate unless changed
 224   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 225                         ? DateTime->today_local
 226                         : $order->transdate;
 227
 228   # Set new reqdate unless changed if it is enabled in client config
 229   if ($order->reqdate == $saved_order->reqdate) {
 230     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 231                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 232
 233     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 234         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 235       $new_attrs{reqdate} = '';
 236     } else {
 237       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 238     }
 239   } else {
 240     $new_attrs{reqdate} = $order->reqdate;
 241   }
 242
 243   # Update employee
 244   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 245
 246   # Create new record from current one
 247   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 248
 249   # no linked records on save as new
 250   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 251
 252   # save
 253   $self->action_save();
 254 }
 255
 256 # print the order
 257 #
 258 # This is called if "print" is pressed in the print dialog.
 259 # If PDF creation was requested and succeeded, the pdf is offered for download
 260 # via send_file (which uses ajax in this case).
 261 sub action_print {
 262   my ($self) = @_;
 263
 264   my $errors = $self->save();
 265
 266   if (scalar @{ $errors }) {
 267     $self->js->flash('error', $_) foreach @{ $errors };
 268     return $self->js->render();
 269   }
 270
 271   $self->js_reset_order_and_item_ids_after_save;
 272
 273   my $format      = $::form->{print_options}->{format};
 274   my $media       = $::form->{print_options}->{media};
 275   my $formname    = $::form->{print_options}->{formname};
 276   my $copies      = $::form->{print_options}->{copies};
 277   my $groupitems  = $::form->{print_options}->{groupitems};
 278   my $printer_id  = $::form->{print_options}->{printer_id};
 279
 280   # only pdf and opendocument by now
 281   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 282     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 283   }
 284
 285   # only screen or printer by now
 286   if (none { $media eq $_ } qw(screen printer)) {
 287     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 288   }
 289
 290   # create a form for generate_attachment_filename
 291   my $form   = Form->new;
 292   $form->{$self->nr_key()}  = $self->order->number;
 293   $form->{type}             = $self->type;
 294   $form->{format}           = $format;
 295   $form->{formname}         = $formname;
 296   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 297   my $pdf_filename          = $form->generate_attachment_filename();
 298
 299   my $pdf;
 300   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 301                                                    formname   => $formname,
 302                                                    language   => $self->order->language,
 303                                                    printer_id => $printer_id,
 304                                                    groupitems => $groupitems });
 305   if (scalar @errors) {
 306     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 307   }
 308
 309   if ($media eq 'screen') {
 310     # screen/download
 311     $self->js->flash('info', t8('The PDF has been created'));
 312     $self->send_file(
 313       \$pdf,
 314       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 315       name         => $pdf_filename,
 316       js_no_render => 1,
 317     );
 318
 319   } elsif ($media eq 'printer') {
 320     # printer
 321     my $printer_id = $::form->{print_options}->{printer_id};
 322     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 323       copies  => $copies,
 324       content => $pdf,
 325     );
 326
 327     $self->js->flash('info', t8('The PDF has been printed'));
 328   }
 329
 330   my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $pdf_filename);
 331   if (scalar @warnings) {
 332     $self->js->flash('warning', $_) for @warnings;
 333   }
 334
 335   $self->save_history('PRINTED');
 336
 337   $self->js
 338     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 339     ->render;
 340 }
 341
 342 # open the email dialog
 343 sub action_save_and_show_email_dialog {
 344   my ($self) = @_;
 345
 346   my $errors = $self->save();
 347
 348   if (scalar @{ $errors }) {
 349     $self->js->flash('error', $_) foreach @{ $errors };
 350     return $self->js->render();
 351   }
 352
 353   my $cv_method = $self->cv;
 354
 355   if (!$self->order->$cv_method) {
 356     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 357                     ->render($self);
 358   }
 359
 360   my $email_form;
 361   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 362   $email_form->{to} ||= $self->order->$cv_method->email;
 363   $email_form->{cc}   = $self->order->$cv_method->cc;
 364   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 365   # Todo: get addresses from shipto, if any
 366
 367   my $form = Form->new;
 368   $form->{$self->nr_key()}  = $self->order->number;
 369   $form->{cusordnumber}     = $self->order->cusordnumber;
 370   $form->{formname}         = $self->type;
 371   $form->{type}             = $self->type;
 372   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 373   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 374   $form->{format}           = 'pdf';
 375   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 376
 377   $email_form->{subject}             = $form->generate_email_subject();
 378   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 379   $email_form->{message}             = $form->generate_email_body();
 380   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 381
 382   my %files = $self->get_files_for_email_dialog();
 383   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 384                                   email_form  => $email_form,
 385                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 386                                   FILES       => \%files,
 387                                   is_customer => $self->cv eq 'customer',
 388   );
 389
 390   $self->js
 391       ->run('kivi.Order.show_email_dialog', $dialog_html)
 392       ->reinit_widgets
 393       ->render($self);
 394 }
 395
 396 # send email
 397 #
 398 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 399 sub action_send_email {
 400   my ($self) = @_;
 401
 402   my $errors = $self->save();
 403
 404   if (scalar @{ $errors }) {
 405     $self->js->run('kivi.Order.close_email_dialog');
 406     $self->js->flash('error', $_) foreach @{ $errors };
 407     return $self->js->render();
 408   }
 409
 410   $self->js_reset_order_and_item_ids_after_save;
 411
 412   my $email_form  = delete $::form->{email_form};
 413   my %field_names = (to => 'email');
 414
 415   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 416
 417   # for Form::cleanup which may be called in Form::send_email
 418   $::form->{cwd}    = getcwd();
 419   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 420
 421   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 422   $::form->{media}  = 'email';
 423
 424   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 425     my $pdf;
 426     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 427                                                     format     => $::form->{print_options}->{format},
 428                                                     formname   => $::form->{print_options}->{formname},
 429                                                     language   => $self->order->language,
 430                                                     printer_id => $::form->{print_options}->{printer_id},
 431                                                     groupitems => $::form->{print_options}->{groupitems}});
 432     if (scalar @errors) {
 433       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 434     }
 435
 436     my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $::form->{attachment_filename});
 437     if (scalar @warnings) {
 438       flash_later('warning', $_) for @warnings;
 439     }
 440
 441     my $sfile = SL::SessionFile::Random->new(mode => "w");
 442     $sfile->fh->print($pdf);
 443     $sfile->fh->close;
 444
 445     $::form->{tmpfile} = $sfile->file_name;
 446     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 447   }
 448
 449   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 450   $::form->send_email(\%::myconfig, 'pdf');
 451
 452   # internal notes
 453   my $intnotes = $self->order->intnotes;
 454   $intnotes   .= "\n\n" if $self->order->intnotes;
 455   $intnotes   .= t8('[email]')                                                                                        . "\n";
 456   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 457   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 458   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 459   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 460   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 461   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 462
 463   $self->order->update_attributes(intnotes => $intnotes);
 464
 465   $self->save_history('MAILED');
 466
 467   flash_later('info', t8('The email has been sent.'));
 468
 469   my @redirect_params = (
 470     action => 'edit',
 471     type   => $self->type,
 472     id     => $self->order->id,
 473   );
 474
 475   $self->redirect_to(@redirect_params);
 476 }
 477
 478 # open the periodic invoices config dialog
 479 #
 480 # If there are values in the form (i.e. dialog was opened before),
 481 # then use this values. Create new ones, else.
 482 sub action_show_periodic_invoices_config_dialog {
 483   my ($self) = @_;
 484
 485   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 486   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 487   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 488                                                    order_value_periodicity => 'p', # = same as periodicity
 489                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 490                                                    extend_automatically_by => 12,
 491                                                    active                  => 1,
 492                                                    email_subject           => GenericTranslations->get(
 493                                                                                 language_id      => $::form->{language_id},
 494                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 495                                                    email_body              => GenericTranslations->get(
 496                                                                                 language_id      => $::form->{language_id},
 497                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 498   );
 499   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 500   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 501
 502   $::form->get_lists(printers => "ALL_PRINTERS",
 503                      charts   => { key       => 'ALL_CHARTS',
 504                                    transdate => 'current_date' });
 505
 506   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 507
 508   if ($::form->{customer_id}) {
 509     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 510     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 511   }
 512
 513   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 514                 popup_dialog             => 1,
 515                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 516                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 517                 config                   => $config,
 518                 %$::form);
 519 }
 520
 521 # assign the values of the periodic invoices config dialog
 522 # as yaml in the hidden tag and set the status.
 523 sub action_assign_periodic_invoices_config {
 524   my ($self) = @_;
 525
 526   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 527
 528   my $config = { active                     => $::form->{active}       ? 1 : 0,
 529                  terminated                 => $::form->{terminated}   ? 1 : 0,
 530                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 531                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 532                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 533                  start_date_as_date         => $::form->{start_date_as_date},
 534                  end_date_as_date           => $::form->{end_date_as_date},
 535                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 536                  print                      => $::form->{print}      ? 1                         : 0,
 537                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 538                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 539                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 540                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 541                  send_email                 => $::form->{send_email} ? 1 : 0,
 542                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 543                  email_recipient_address    => $::form->{email_recipient_address},
 544                  email_sender               => $::form->{email_sender},
 545                  email_subject              => $::form->{email_subject},
 546                  email_body                 => $::form->{email_body},
 547                };
 548
 549   my $periodic_invoices_config = SL::YAML::Dump($config);
 550
 551   my $status = $self->get_periodic_invoices_status($config);
 552
 553   $self->js
 554     ->remove('#order_periodic_invoices_config')
 555     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 556     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 557     ->html('#periodic_invoices_status', $status)
 558     ->flash('info', t8('The periodic invoices config has been assigned.'))
 559     ->render($self);
 560 }
 561
 562 sub action_get_has_active_periodic_invoices {
 563   my ($self) = @_;
 564
 565   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 566   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 567
 568   my $has_active_periodic_invoices =
 569        $self->type eq sales_order_type()
 570     && $config
 571     && $config->active
 572     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 573     && $config->get_previous_billed_period_start_date;
 574
 575   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 576 }
 577
 578 # save the order and redirect to the frontend subroutine for a new
 579 # delivery order
 580 sub action_save_and_delivery_order {
 581   my ($self) = @_;
 582
 583   $self->save_and_redirect_to(
 584     controller => 'oe.pl',
 585     action     => 'oe_delivery_order_from_order',
 586   );
 587 }
 588
 589 # save the order and redirect to the frontend subroutine for a new
 590 # invoice
 591 sub action_save_and_invoice {
 592   my ($self) = @_;
 593
 594   $self->save_and_redirect_to(
 595     controller => 'oe.pl',
 596     action     => 'oe_invoice_from_order',
 597   );
 598 }
 599
 600 # workflow from sales order to sales quotation
 601 sub action_sales_quotation {
 602   $_[0]->workflow_sales_or_request_for_quotation();
 603 }
 604
 605 # workflow from sales order to sales quotation
 606 sub action_request_for_quotation {
 607   $_[0]->workflow_sales_or_request_for_quotation();
 608 }
 609
 610 # workflow from sales quotation to sales order
 611 sub action_sales_order {
 612   $_[0]->workflow_sales_or_purchase_order();
 613 }
 614
 615 # workflow from rfq to purchase order
 616 sub action_purchase_order {
 617   $_[0]->workflow_sales_or_purchase_order();
 618 }
 619
 620 # workflow from purchase order to ap transaction
 621 sub action_save_and_ap_transaction {
 622   my ($self) = @_;
 623
 624   $self->save_and_redirect_to(
 625     controller => 'ap.pl',
 626     action     => 'add_from_purchase_order',
 627   );
 628 }
 629
 630 # set form elements in respect to a changed customer or vendor
 631 #
 632 # This action is called on an change of the customer/vendor picker.
 633 sub action_customer_vendor_changed {
 634   my ($self) = @_;
 635
 636   setup_order_from_cv($self->order);
 637   $self->recalc();
 638
 639   my $cv_method = $self->cv;
 640
 641   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 642     $self->js->show('#cp_row');
 643   } else {
 644     $self->js->hide('#cp_row');
 645   }
 646
 647   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 648     $self->js->show('#shipto_selection');
 649   } else {
 650     $self->js->hide('#shipto_selection');
 651   }
 652
 653   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 654
 655   $self->js
 656     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 657     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 658     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 659     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 660     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 661     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 662     ->val(        '#order_currency_id',      $self->order->currency_id)
 663     ->val(        '#order_payment_id',       $self->order->payment_id)
 664     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 665     ->val(        '#order_intnotes',         $self->order->intnotes)
 666     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 667     ->focus(      '#order_' . $self->cv . '_id')
 668     ->run('kivi.Order.update_exchangerate');
 669
 670   $self->js_redisplay_amounts_and_taxes;
 671   $self->js_redisplay_cvpartnumbers;
 672   $self->js->render();
 673 }
 674
 675 # open the dialog for customer/vendor details
 676 sub action_show_customer_vendor_details_dialog {
 677   my ($self) = @_;
 678
 679   my $is_customer = 'customer' eq $::form->{vc};
 680   my $cv;
 681   if ($is_customer) {
 682     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 683   } else {
 684     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 685   }
 686
 687   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 688   $details{discount_as_percent} = $cv->discount_as_percent;
 689   $details{creditlimt}          = $cv->creditlimit_as_number;
 690   $details{business}            = $cv->business->description      if $cv->business;
 691   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 692   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 693   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 694   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 695
 696   foreach my $entry (@{ $cv->shipto }) {
 697     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 698   }
 699   foreach my $entry (@{ $cv->contacts }) {
 700     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 701   }
 702
 703   $_[0]->render('common/show_vc_details', { layout => 0 },
 704                 is_customer => $is_customer,
 705                 %details);
 706
 707 }
 708
 709 # called if a unit in an existing item row is changed
 710 sub action_unit_changed {
 711   my ($self) = @_;
 712
 713   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 714   my $item = $self->order->items_sorted->[$idx];
 715
 716   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 717   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 718
 719   $self->recalc();
 720
 721   $self->js
 722     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 723   $self->js_redisplay_line_values;
 724   $self->js_redisplay_amounts_and_taxes;
 725   $self->js->render();
 726 }
 727
 728 # add an item row for a new item entered in the input row
 729 sub action_add_item {
 730   my ($self) = @_;
 731
 732   my $form_attr = $::form->{add_item};
 733
 734   return unless $form_attr->{parts_id};
 735
 736   my $item = new_item($self->order, $form_attr);
 737
 738   $self->order->add_items($item);
 739
 740   $self->recalc();
 741
 742   $self->get_item_cvpartnumber($item);
 743
 744   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 745   my $row_as_html = $self->p->render('order/tabs/_row',
 746                                      ITEM => $item,
 747                                      ID   => $item_id,
 748                                      SELF => $self,
 749   );
 750
 751   if ($::form->{insert_before_item_id}) {
 752     $self->js
 753       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 754   } else {
 755     $self->js
 756       ->append('#row_table_id', $row_as_html);
 757   }
 758
 759   if ( $item->part->is_assortment ) {
 760     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 761     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 762       my $attr = { parts_id => $assortment_item->parts_id,
 763                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 764                    unit     => $assortment_item->unit,
 765                    description => $assortment_item->part->description,
 766                  };
 767       my $item = new_item($self->order, $attr);
 768
 769       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 770       $item->discount(1) unless $assortment_item->charge;
 771
 772       $self->order->add_items( $item );
 773       $self->recalc();
 774       $self->get_item_cvpartnumber($item);
 775       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 776       my $row_as_html = $self->p->render('order/tabs/_row',
 777                                          ITEM => $item,
 778                                          ID   => $item_id,
 779                                          SELF => $self,
 780       );
 781       if ($::form->{insert_before_item_id}) {
 782         $self->js
 783           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 784       } else {
 785         $self->js
 786           ->append('#row_table_id', $row_as_html);
 787       }
 788     };
 789   };
 790
 791   $self->js
 792     ->val('.add_item_input', '')
 793     ->run('kivi.Order.init_row_handlers')
 794     ->run('kivi.Order.renumber_positions')
 795     ->focus('#add_item_parts_id_name');
 796
 797   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 798
 799   $self->js_redisplay_amounts_and_taxes;
 800   $self->js->render();
 801 }
 802
 803 # add item rows for multiple items at once
 804 sub action_add_multi_items {
 805   my ($self) = @_;
 806
 807   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 808   return $self->js->render() unless scalar @form_attr;
 809
 810   my @items;
 811   foreach my $attr (@form_attr) {
 812     my $item = new_item($self->order, $attr);
 813     push @items, $item;
 814     if ( $item->part->is_assortment ) {
 815       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 816         my $attr = { parts_id => $assortment_item->parts_id,
 817                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 818                      unit     => $assortment_item->unit,
 819                      description => $assortment_item->part->description,
 820                    };
 821         my $item = new_item($self->order, $attr);
 822
 823         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 824         $item->discount(1) unless $assortment_item->charge;
 825         push @items, $item;
 826       }
 827     }
 828   }
 829   $self->order->add_items(@items);
 830
 831   $self->recalc();
 832
 833   foreach my $item (@items) {
 834     $self->get_item_cvpartnumber($item);
 835     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 836     my $row_as_html = $self->p->render('order/tabs/_row',
 837                                        ITEM => $item,
 838                                        ID   => $item_id,
 839                                        SELF => $self,
 840     );
 841
 842     if ($::form->{insert_before_item_id}) {
 843       $self->js
 844         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 845     } else {
 846       $self->js
 847         ->append('#row_table_id', $row_as_html);
 848     }
 849   }
 850
 851   $self->js
 852     ->run('kivi.Part.close_picker_dialogs')
 853     ->run('kivi.Order.init_row_handlers')
 854     ->run('kivi.Order.renumber_positions')
 855     ->focus('#add_item_parts_id_name');
 856
 857   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 858
 859   $self->js_redisplay_amounts_and_taxes;
 860   $self->js->render();
 861 }
 862
 863 # recalculate all linetotals, amounts and taxes and redisplay them
 864 sub action_recalc_amounts_and_taxes {
 865   my ($self) = @_;
 866
 867   $self->recalc();
 868
 869   $self->js_redisplay_line_values;
 870   $self->js_redisplay_amounts_and_taxes;
 871   $self->js->render();
 872 }
 873
 874 sub action_update_exchangerate {
 875   my ($self) = @_;
 876
 877   my $data = {
 878     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 879     currency_name => $self->order->currency->name,
 880     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 881   };
 882
 883   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 884 }
 885
 886 # redisplay item rows if they are sorted by an attribute
 887 sub action_reorder_items {
 888   my ($self) = @_;
 889
 890   my %sort_keys = (
 891     partnumber   => sub { $_[0]->part->partnumber },
 892     description  => sub { $_[0]->description },
 893     qty          => sub { $_[0]->qty },
 894     sellprice    => sub { $_[0]->sellprice },
 895     discount     => sub { $_[0]->discount },
 896     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 897   );
 898
 899   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 900
 901   my $method = $sort_keys{$::form->{order_by}};
 902   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 903   if ($::form->{sort_dir}) {
 904     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 905       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 906     } else {
 907       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 908     }
 909   } else {
 910     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 911       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 912     } else {
 913       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 914     }
 915   }
 916   $self->js
 917     ->run('kivi.Order.redisplay_items', \@to_sort)
 918     ->render;
 919 }
 920
 921 # show the popup to choose a price/discount source
 922 sub action_price_popup {
 923   my ($self) = @_;
 924
 925   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 926   my $item = $self->order->items_sorted->[$idx];
 927
 928   $self->render_price_dialog($item);
 929 }
 930
 931 # load the second row for one or more items
 932 #
 933 # This action gets the html code for all items second rows by rendering a template for
 934 # the second row and sets the html code via client js.
 935 sub action_load_second_rows {
 936   my ($self) = @_;
 937
 938   $self->recalc() if $self->order->is_sales; # for margin calculation
 939
 940   foreach my $item_id (@{ $::form->{item_ids} }) {
 941     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 942     my $item = $self->order->items_sorted->[$idx];
 943
 944     $self->js_load_second_row($item, $item_id, 0);
 945   }
 946
 947   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 948
 949   $self->js->render();
 950 }
 951
 952 # update description, notes and sellprice from master data
 953 sub action_update_row_from_master_data {
 954   my ($self) = @_;
 955
 956   foreach my $item_id (@{ $::form->{item_ids} }) {
 957     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 958     my $item  = $self->order->items_sorted->[$idx];
 959     my $texts = get_part_texts($item->part, $self->order->language_id);
 960
 961     $item->description($texts->{description});
 962     $item->longdescription($texts->{longdescription});
 963
 964     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 965
 966     my $price_src;
 967     if ($item->part->is_assortment) {
 968     # add assortment items with price 0, as the components carry the price
 969       $price_src = $price_source->price_from_source("");
 970       $price_src->price(0);
 971     } else {
 972       $price_src = $price_source->best_price
 973                  ? $price_source->best_price
 974                  : $price_source->price_from_source("");
 975       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
 976       $price_src->price(0) if !$price_source->best_price;
 977     }
 978
 979
 980     $item->sellprice($price_src->price);
 981     $item->active_price_source($price_src);
 982
 983     $self->js
 984       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
 985       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
 986       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
 987       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
 988
 989     if ($self->search_cvpartnumber) {
 990       $self->get_item_cvpartnumber($item);
 991       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
 992     }
 993   }
 994
 995   $self->recalc();
 996   $self->js_redisplay_line_values;
 997   $self->js_redisplay_amounts_and_taxes;
 998
 999   $self->js->render();
1000 }
1001
1002 sub js_load_second_row {
1003   my ($self, $item, $item_id, $do_parse) = @_;
1004
1005   if ($do_parse) {
1006     # Parse values from form (they are formated while rendering (template)).
1007     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1008     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1009     foreach my $var (@{ $item->cvars_by_config }) {
1010       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1011     }
1012     $item->parse_custom_variable_values;
1013   }
1014
1015   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1016
1017   $self->js
1018     ->html('#second_row_' . $item_id, $row_as_html)
1019     ->data('#second_row_' . $item_id, 'loaded', 1);
1020 }
1021
1022 sub js_redisplay_line_values {
1023   my ($self) = @_;
1024
1025   my $is_sales = $self->order->is_sales;
1026
1027   # sales orders with margins
1028   my @data;
1029   if ($is_sales) {
1030     @data = map {
1031       [
1032        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1033        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1034        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1035       ]} @{ $self->order->items_sorted };
1036   } else {
1037     @data = map {
1038       [
1039        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1040       ]} @{ $self->order->items_sorted };
1041   }
1042
1043   $self->js
1044     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1045 }
1046
1047 sub js_redisplay_amounts_and_taxes {
1048   my ($self) = @_;
1049
1050   if (scalar @{ $self->{taxes} }) {
1051     $self->js->show('#taxincluded_row_id');
1052   } else {
1053     $self->js->hide('#taxincluded_row_id');
1054   }
1055
1056   if ($self->order->taxincluded) {
1057     $self->js->hide('#subtotal_row_id');
1058   } else {
1059     $self->js->show('#subtotal_row_id');
1060   }
1061
1062   if ($self->order->is_sales) {
1063     my $is_neg = $self->order->marge_total < 0;
1064     $self->js
1065       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1066       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1067       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1068       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1069       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1070       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1071       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1072       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1073   }
1074
1075   $self->js
1076     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1077     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1078     ->remove('.tax_row')
1079     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1080 }
1081
1082 sub js_redisplay_cvpartnumbers {
1083   my ($self) = @_;
1084
1085   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1086
1087   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1088
1089   $self->js
1090     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1091 }
1092
1093 sub js_reset_order_and_item_ids_after_save {
1094   my ($self) = @_;
1095
1096   $self->js
1097     ->val('#id', $self->order->id)
1098     ->val('#converted_from_oe_id', '')
1099     ->val('#order_' . $self->nr_key(), $self->order->number);
1100
1101   my $idx = 0;
1102   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1103     next if !$self->order->items_sorted->[$idx]->id;
1104     next if $form_item_id !~ m{^new};
1105     $self->js
1106       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1107       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1108       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1109   } continue {
1110     $idx++;
1111   }
1112   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1113 }
1114
1115 #
1116 # helpers
1117 #
1118
1119 sub init_valid_types {
1120   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1121 }
1122
1123 sub init_type {
1124   my ($self) = @_;
1125
1126   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1127     die "Not a valid type for order";
1128   }
1129
1130   $self->type($::form->{type});
1131 }
1132
1133 sub init_cv {
1134   my ($self) = @_;
1135
1136   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1137          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1138          : die "Not a valid type for order";
1139
1140   return $cv;
1141 }
1142
1143 sub init_search_cvpartnumber {
1144   my ($self) = @_;
1145
1146   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1147   my $search_cvpartnumber;
1148   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1149   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1150
1151   return $search_cvpartnumber;
1152 }
1153
1154 sub init_show_update_button {
1155   my ($self) = @_;
1156
1157   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1158 }
1159
1160 sub init_p {
1161   SL::Presenter->get;
1162 }
1163
1164 sub init_order {
1165   $_[0]->make_order;
1166 }
1167
1168 sub init_all_price_factors {
1169   SL::DB::Manager::PriceFactor->get_all;
1170 }
1171
1172 sub init_part_picker_classification_ids {
1173   my ($self)    = @_;
1174   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1175
1176   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1177 }
1178
1179 sub check_auth {
1180   my ($self) = @_;
1181
1182   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1183
1184   my $right   = $right_for->{ $self->type };
1185   $right    ||= 'DOES_NOT_EXIST';
1186
1187   $::auth->assert($right);
1188 }
1189
1190 # build the selection box for contacts
1191 #
1192 # Needed, if customer/vendor changed.
1193 sub build_contact_select {
1194   my ($self) = @_;
1195
1196   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1197     value_key  => 'cp_id',
1198     title_key  => 'full_name_dep',
1199     default    => $self->order->cp_id,
1200     with_empty => 1,
1201     style      => 'width: 300px',
1202   );
1203 }
1204
1205 # build the selection box for shiptos
1206 #
1207 # Needed, if customer/vendor changed.
1208 sub build_shipto_select {
1209   my ($self) = @_;
1210
1211   select_tag('order.shipto_id',
1212              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1213              value_key  => 'shipto_id',
1214              title_key  => 'displayable_id',
1215              default    => $self->order->shipto_id,
1216              with_empty => 0,
1217              style      => 'width: 300px',
1218   );
1219 }
1220
1221 # build the inputs for the cusom shipto dialog
1222 #
1223 # Needed, if customer/vendor changed.
1224 sub build_shipto_inputs {
1225   my ($self) = @_;
1226
1227   my $content = $self->p->render('common/_ship_to_dialog',
1228                                  vc_obj      => $self->order->customervendor,
1229                                  cs_obj      => $self->order->custom_shipto,
1230                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1231                                  id_selector => '#order_shipto_id');
1232
1233   div_tag($content, id => 'shipto_inputs');
1234 }
1235
1236 # render the info line for business
1237 #
1238 # Needed, if customer/vendor changed.
1239 sub build_business_info_row
1240 {
1241   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1242 }
1243
1244 # build the rows for displaying taxes
1245 #
1246 # Called if amounts where recalculated and redisplayed.
1247 sub build_tax_rows {
1248   my ($self) = @_;
1249
1250   my $rows_as_html;
1251   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1252     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1253   }
1254   return $rows_as_html;
1255 }
1256
1257
1258 sub render_price_dialog {
1259   my ($self, $record_item) = @_;
1260
1261   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1262
1263   $self->js
1264     ->run(
1265       'kivi.io.price_chooser_dialog',
1266       t8('Available Prices'),
1267       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1268     )
1269     ->reinit_widgets;
1270
1271 #   if (@errors) {
1272 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1273 #     $self->js->show('#dialog_flash_error');
1274 #   }
1275
1276   $self->js->render;
1277 }
1278
1279 sub load_order {
1280   my ($self) = @_;
1281
1282   return if !$::form->{id};
1283
1284   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1285
1286   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1287   # You need a custom shipto object to call cvars_by_config to get the cvars.
1288   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1289
1290   return $self->order;
1291 }
1292
1293 # load or create a new order object
1294 #
1295 # And assign changes from the form to this object.
1296 # If the order is loaded from db, check if items are deleted in the form,
1297 # remove them form the object and collect them for removing from db on saving.
1298 # Then create/update items from form (via make_item) and add them.
1299 sub make_order {
1300   my ($self) = @_;
1301
1302   # add_items adds items to an order with no items for saving, but they cannot
1303   # be retrieved via items until the order is saved. Adding empty items to new
1304   # order here solves this problem.
1305   my $order;
1306   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1307   $order ||= SL::DB::Order->new(orderitems  => [],
1308                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1309                                 currency_id => $::instance_conf->get_currency_id(),);
1310
1311   my $cv_id_method = $self->cv . '_id';
1312   if (!$::form->{id} && $::form->{$cv_id_method}) {
1313     $order->$cv_id_method($::form->{$cv_id_method});
1314     setup_order_from_cv($order);
1315   }
1316
1317   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1318   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1319
1320   $order->assign_attributes(%{$::form->{order}});
1321
1322   $self->setup_custom_shipto_from_form($order, $::form);
1323
1324   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1325     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1326     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1327   }
1328
1329   # remove deleted items
1330   $self->item_ids_to_delete([]);
1331   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1332     my $item = $order->orderitems->[$idx];
1333     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1334       splice @{$order->orderitems}, $idx, 1;
1335       push @{$self->item_ids_to_delete}, $item->id;
1336     }
1337   }
1338
1339   my @items;
1340   my $pos = 1;
1341   foreach my $form_attr (@{$form_orderitems}) {
1342     my $item = make_item($order, $form_attr);
1343     $item->position($pos);
1344     push @items, $item;
1345     $pos++;
1346   }
1347   $order->add_items(grep {!$_->id} @items);
1348
1349   return $order;
1350 }
1351
1352 # create or update items from form
1353 #
1354 # Make item objects from form values. For items already existing read from db.
1355 # Create a new item else. And assign attributes.
1356 sub make_item {
1357   my ($record, $attr) = @_;
1358
1359   my $item;
1360   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1361
1362   my $is_new = !$item;
1363
1364   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1365   # they cannot be retrieved via custom_variables until the order/orderitem is
1366   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1367   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1368
1369   $item->assign_attributes(%$attr);
1370
1371   if ($is_new) {
1372     my $texts = get_part_texts($item->part, $record->language_id);
1373     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1374     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1375     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1376   }
1377
1378   return $item;
1379 }
1380
1381 # create a new item
1382 #
1383 # This is used to add one item
1384 sub new_item {
1385   my ($record, $attr) = @_;
1386
1387   my $item = SL::DB::OrderItem->new;
1388
1389   # Remove attributes where the user left or set the inputs empty.
1390   # So these attributes will be undefined and we can distinguish them
1391   # from zero later on.
1392   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1393     delete $attr->{$_} if $attr->{$_} eq '';
1394   }
1395
1396   $item->assign_attributes(%$attr);
1397
1398   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1399   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1400
1401   $item->unit($part->unit) if !$item->unit;
1402
1403   my $price_src;
1404   if ( $part->is_assortment ) {
1405     # add assortment items with price 0, as the components carry the price
1406     $price_src = $price_source->price_from_source("");
1407     $price_src->price(0);
1408   } elsif (defined $item->sellprice) {
1409     $price_src = $price_source->price_from_source("");
1410     $price_src->price($item->sellprice);
1411   } else {
1412     $price_src = $price_source->best_price
1413                ? $price_source->best_price
1414                : $price_source->price_from_source("");
1415     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1416     $price_src->price(0) if !$price_source->best_price;
1417   }
1418
1419   my $discount_src;
1420   if (defined $item->discount) {
1421     $discount_src = $price_source->discount_from_source("");
1422     $discount_src->discount($item->discount);
1423   } else {
1424     $discount_src = $price_source->best_discount
1425                   ? $price_source->best_discount
1426                   : $price_source->discount_from_source("");
1427     $discount_src->discount(0) if !$price_source->best_discount;
1428   }
1429
1430   my %new_attr;
1431   $new_attr{part}                   = $part;
1432   $new_attr{description}            = $part->description     if ! $item->description;
1433   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1434   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1435   $new_attr{sellprice}              = $price_src->price;
1436   $new_attr{discount}               = $discount_src->discount;
1437   $new_attr{active_price_source}    = $price_src;
1438   $new_attr{active_discount_source} = $discount_src;
1439   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1440   $new_attr{project_id}             = $record->globalproject_id;
1441   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1442
1443   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1444   # they cannot be retrieved via custom_variables until the order/orderitem is
1445   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1446   $new_attr{custom_variables} = [];
1447
1448   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1449
1450   $item->assign_attributes(%new_attr, %{ $texts });
1451
1452   return $item;
1453 }
1454
1455 sub setup_order_from_cv {
1456   my ($order) = @_;
1457
1458   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1459
1460   $order->intnotes($order->customervendor->notes);
1461
1462   if ($order->is_sales) {
1463     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1464     $order->taxincluded(defined($order->customer->taxincluded_checked)
1465                         ? $order->customer->taxincluded_checked
1466                         : $::myconfig{taxincluded_checked});
1467   }
1468
1469 }
1470
1471 # setup custom shipto from form
1472 #
1473 # The dialog returns form variables starting with 'shipto' and cvars starting
1474 # with 'shiptocvar_'.
1475 # Mark it to be deleted if a shipto from master data is selected
1476 # (i.e. order has a shipto).
1477 # Else, update or create a new custom shipto. If the fields are empty, it
1478 # will not be saved on save.
1479 sub setup_custom_shipto_from_form {
1480   my ($self, $order, $form) = @_;
1481
1482   if ($order->shipto) {
1483     $self->is_custom_shipto_to_delete(1);
1484   } else {
1485     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1486
1487     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1488     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1489
1490     $custom_shipto->assign_attributes(%$shipto_attrs);
1491     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1492   }
1493 }
1494
1495 # recalculate prices and taxes
1496 #
1497 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1498 sub recalc {
1499   my ($self) = @_;
1500
1501   my %pat = $self->order->calculate_prices_and_taxes();
1502
1503   $self->{taxes} = [];
1504   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1505     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1506
1507     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1508                                 netamount => $netamount,
1509                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1510   }
1511   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1512 }
1513
1514 # get data for saving, printing, ..., that is not changed in the form
1515 #
1516 # Only cvars for now.
1517 sub get_unalterable_data {
1518   my ($self) = @_;
1519
1520   foreach my $item (@{ $self->order->items }) {
1521     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1522     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1523     foreach my $var (@{ $item->cvars_by_config }) {
1524       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1525     }
1526     $item->parse_custom_variable_values;
1527   }
1528 }
1529
1530 # delete the order
1531 #
1532 # And remove related files in the spool directory
1533 sub delete {
1534   my ($self) = @_;
1535
1536   my $errors = [];
1537   my $db     = $self->order->db;
1538
1539   $db->with_transaction(
1540     sub {
1541       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1542       $self->order->delete;
1543       my $spool = $::lx_office_conf{paths}->{spool};
1544       unlink map { "$spool/$_" } @spoolfiles if $spool;
1545
1546       $self->save_history('DELETED');
1547
1548       1;
1549   }) || push(@{$errors}, $db->error);
1550
1551   return $errors;
1552 }
1553
1554 # save the order
1555 #
1556 # And delete items that are deleted in the form.
1557 sub save {
1558   my ($self) = @_;
1559
1560   my $errors = [];
1561   my $db     = $self->order->db;
1562
1563   $db->with_transaction(sub {
1564     # delete custom shipto if it is to be deleted or if it is empty
1565     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1566       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1567       $self->order->custom_shipto(undef);
1568     }
1569
1570     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1571     $self->order->save(cascade => 1);
1572
1573     # link records
1574     if ($::form->{converted_from_oe_id}) {
1575       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1576       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1577         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1578         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1579         $src->link_to_record($self->order);
1580       }
1581       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1582         my $idx = 0;
1583         foreach (@{ $self->order->items_sorted }) {
1584           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1585           next if !$from_id;
1586           SL::DB::RecordLink->new(from_table => 'orderitems',
1587                                   from_id    => $from_id,
1588                                   to_table   => 'orderitems',
1589                                   to_id      => $_->id
1590           )->save;
1591           $idx++;
1592         }
1593       }
1594     }
1595
1596     $self->save_history('SAVED');
1597
1598     1;
1599   }) || push(@{$errors}, $db->error);
1600
1601   return $errors;
1602 }
1603
1604 sub workflow_sales_or_request_for_quotation {
1605   my ($self) = @_;
1606
1607   # always save
1608   my $errors = $self->save();
1609
1610   if (scalar @{ $errors }) {
1611     $self->js->flash('error', $_) for @{ $errors };
1612     return $self->js->render();
1613   }
1614
1615   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1616
1617   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1618   $self->{converted_from_oe_id} = delete $::form->{id};
1619
1620   # set item ids to new fake id, to identify them as new items
1621   foreach my $item (@{$self->order->items_sorted}) {
1622     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1623   }
1624
1625   # change form type
1626   $::form->{type} = $destination_type;
1627   $self->type($self->init_type);
1628   $self->cv  ($self->init_cv);
1629   $self->check_auth;
1630
1631   $self->recalc();
1632   $self->get_unalterable_data();
1633   $self->pre_render();
1634
1635   # trigger rendering values for second row as hidden, because they
1636   # are loaded only on demand. So we need to keep the values from the
1637   # source.
1638   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1639
1640   $self->render(
1641     'order/form',
1642     title => $self->get_title_for('edit'),
1643     %{$self->{template_args}}
1644   );
1645 }
1646
1647 sub workflow_sales_or_purchase_order {
1648   my ($self) = @_;
1649
1650   # always save
1651   my $errors = $self->save();
1652
1653   if (scalar @{ $errors }) {
1654     $self->js->flash('error', $_) foreach @{ $errors };
1655     return $self->js->render();
1656   }
1657
1658   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1659                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1660                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1661                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1662                        : '';
1663
1664   # check for direct delivery
1665   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1666   my $custom_shipto;
1667   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1668       && $::form->{use_shipto} && $self->order->shipto) {
1669     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1670   }
1671
1672   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1673   $self->{converted_from_oe_id} = delete $::form->{id};
1674
1675   # set item ids to new fake id, to identify them as new items
1676   foreach my $item (@{$self->order->items_sorted}) {
1677     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1678   }
1679
1680   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1681     if ($::form->{use_shipto}) {
1682       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1683     } else {
1684       # remove any custom shipto if not wanted
1685       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1686     }
1687   }
1688
1689   # change form type
1690   $::form->{type} = $destination_type;
1691   $self->type($self->init_type);
1692   $self->cv  ($self->init_cv);
1693   $self->check_auth;
1694
1695   $self->recalc();
1696   $self->get_unalterable_data();
1697   $self->pre_render();
1698
1699   # trigger rendering values for second row as hidden, because they
1700   # are loaded only on demand. So we need to keep the values from the
1701   # source.
1702   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1703
1704   $self->render(
1705     'order/form',
1706     title => $self->get_title_for('edit'),
1707     %{$self->{template_args}}
1708   );
1709 }
1710
1711
1712 sub pre_render {
1713   my ($self) = @_;
1714
1715   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1716   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1717   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1718   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1719   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1720                                                                                               deleted => 0 ] ],
1721                                                                            sort_by => 'name');
1722   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1723                                                                                               deleted => 0 ] ],
1724                                                                            sort_by => 'name');
1725   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1726                                                                                                         obsolete => 0 ] ]);
1727   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1728   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1729   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1730   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1731   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1732
1733   my $print_form = Form->new('');
1734   $print_form->{type}        = $self->type;
1735   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1736   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1737     form => $print_form,
1738     options => {dialog_name_prefix => 'print_options.',
1739                 show_headers       => 1,
1740                 no_queue           => 1,
1741                 no_postscript      => 1,
1742                 no_opendocument    => 0,
1743                 no_html            => 1},
1744   );
1745
1746   foreach my $item (@{$self->order->orderitems}) {
1747     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1748     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1749     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1750   }
1751
1752   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1753     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1754     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1755   }
1756
1757   if ($self->order->number && $::instance_conf->get_webdav) {
1758     my $webdav = SL::Webdav->new(
1759       type     => $self->type,
1760       number   => $self->order->number,
1761     );
1762     my @all_objects = $webdav->get_all_objects;
1763     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1764                                                     type => t8('File'),
1765                                                     link => File::Spec->catfile($_->full_filedescriptor),
1766                                                 } } @all_objects;
1767   }
1768
1769   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1770
1771   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1772                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up show_history);
1773   $self->setup_edit_action_bar;
1774 }
1775
1776 sub setup_edit_action_bar {
1777   my ($self, %params) = @_;
1778
1779   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1780                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1781                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1782
1783   for my $bar ($::request->layout->get('actionbar')) {
1784     $bar->add(
1785       combobox => [
1786         action => [
1787           t8('Save'),
1788           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1789                                                     $::instance_conf->get_order_warn_no_deliverydate,
1790                                                                                                       ],
1791           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1792         ],
1793         action => [
1794           t8('Save as new'),
1795           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1796           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1797           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1798         ],
1799       ], # end of combobox "Save"
1800
1801       combobox => [
1802         action => [
1803           t8('Workflow'),
1804         ],
1805         action => [
1806           t8('Save and Quotation'),
1807           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1808           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1809         ],
1810         action => [
1811           t8('Save and RFQ'),
1812           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1813           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1814         ],
1815         action => [
1816           t8('Save and Sales Order'),
1817           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1818           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1819         ],
1820         action => [
1821           t8('Save and Purchase Order'),
1822           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1823           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1824         ],
1825         action => [
1826           t8('Save and Delivery Order'),
1827           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1828                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1829                                                                                                                         ],
1830           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1831           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1832         ],
1833         action => [
1834           t8('Save and Invoice'),
1835           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1836           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1837         ],
1838         action => [
1839           t8('Save and AP Transaction'),
1840           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1841           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1842         ],
1843
1844       ], # end of combobox "Workflow"
1845
1846       combobox => [
1847         action => [
1848           t8('Export'),
1849         ],
1850         action => [
1851           t8('Save and print'),
1852           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1853         ],
1854         action => [
1855           t8('Save and E-mail'),
1856           id   => 'save_and_email_action',
1857           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts ],
1858           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1859         ],
1860         action => [
1861           t8('Download attachments of all parts'),
1862           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1863           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1864           only_if  => $::instance_conf->get_doc_storage,
1865         ],
1866       ], # end of combobox "Export"
1867
1868       action => [
1869         t8('Delete'),
1870         call     => [ 'kivi.Order.delete_order' ],
1871         confirm  => $::locale->text('Do you really want to delete this object?'),
1872         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1873         only_if  => $deletion_allowed,
1874       ],
1875
1876       combobox => [
1877         action => [
1878           t8('more')
1879         ],
1880         action => [
1881           t8('Follow-Up'),
1882           call     => [ 'kivi.Order.follow_up_window' ],
1883           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1884           only_if  => $::auth->assert('productivity', 1),
1885         ],
1886         action => [
1887           t8('History'),
1888           call     => [ 'set_history_window', $self->order->id, 'id' ],
1889           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
1890         ],
1891       ], # end of combobox "more"
1892     );
1893   }
1894 }
1895
1896 sub generate_pdf {
1897   my ($order, $pdf_ref, $params) = @_;
1898
1899   my @errors = ();
1900
1901   my $print_form = Form->new('');
1902   $print_form->{type}        = $order->type;
1903   $print_form->{formname}    = $params->{formname} || $order->type;
1904   $print_form->{format}      = $params->{format}   || 'pdf';
1905   $print_form->{media}       = $params->{media}    || 'file';
1906   $print_form->{groupitems}  = $params->{groupitems};
1907   $print_form->{printer_id}  = $params->{printer_id};
1908   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1909
1910   $order->language($params->{language});
1911   $order->flatten_to_form($print_form, format_amounts => 1);
1912
1913   my $template_ext;
1914   my $template_type;
1915   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1916     $template_ext  = 'odt';
1917     $template_type = 'OpenDocument';
1918   }
1919
1920   # search for the template
1921   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1922     name        => $print_form->{formname},
1923     extension   => $template_ext,
1924     email       => $print_form->{media} eq 'email',
1925     language    => $params->{language},
1926     printer_id  => $print_form->{printer_id},
1927   );
1928
1929   if (!defined $template_file) {
1930     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1931   }
1932
1933   return @errors if scalar @errors;
1934
1935   $print_form->throw_on_error(sub {
1936     eval {
1937       $print_form->prepare_for_printing;
1938
1939       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1940         format        => $print_form->{format},
1941         template_type => $template_type,
1942         template      => $template_file,
1943         variables     => $print_form,
1944         variable_content_types => {
1945           longdescription => 'html',
1946           partnotes       => 'html',
1947           notes           => 'html',
1948         },
1949       );
1950       1;
1951     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1952   });
1953
1954   return @errors;
1955 }
1956
1957 sub get_files_for_email_dialog {
1958   my ($self) = @_;
1959
1960   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1961
1962   return %files if !$::instance_conf->get_doc_storage;
1963
1964   if ($self->order->id) {
1965     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1966     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1967     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1968     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
1969   }
1970
1971   my @parts =
1972     uniq_by { $_->{id} }
1973     map {
1974       +{ id         => $_->part->id,
1975          partnumber => $_->part->partnumber }
1976     } @{$self->order->items_sorted};
1977
1978   foreach my $part (@parts) {
1979     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1980     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1981   }
1982
1983   foreach my $key (keys %files) {
1984     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1985   }
1986
1987   return %files;
1988 }
1989
1990 sub make_periodic_invoices_config_from_yaml {
1991   my ($yaml_config) = @_;
1992
1993   return if !$yaml_config;
1994   my $attr = SL::YAML::Load($yaml_config);
1995   return if 'HASH' ne ref $attr;
1996   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1997 }
1998
1999
2000 sub get_periodic_invoices_status {
2001   my ($self, $config) = @_;
2002
2003   return                      if $self->type ne sales_order_type();
2004   return t8('not configured') if !$config;
2005
2006   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2007              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2008              :                                                     die "Cannot get status of periodic invoices config";
2009
2010   return $active ? t8('active') : t8('inactive');
2011 }
2012
2013 sub get_title_for {
2014   my ($self, $action) = @_;
2015
2016   return '' if none { lc($action)} qw(add edit);
2017
2018   # for locales:
2019   # $::locale->text("Add Sales Order");
2020   # $::locale->text("Add Purchase Order");
2021   # $::locale->text("Add Quotation");
2022   # $::locale->text("Add Request for Quotation");
2023   # $::locale->text("Edit Sales Order");
2024   # $::locale->text("Edit Purchase Order");
2025   # $::locale->text("Edit Quotation");
2026   # $::locale->text("Edit Request for Quotation");
2027
2028   $action = ucfirst(lc($action));
2029   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2030        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2031        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2032        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2033        : '';
2034 }
2035
2036 sub get_item_cvpartnumber {
2037   my ($self, $item) = @_;
2038
2039   return if !$self->search_cvpartnumber;
2040   return if !$self->order->customervendor;
2041
2042   if ($self->cv eq 'vendor') {
2043     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2044     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2045   } elsif ($self->cv eq 'customer') {
2046     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2047     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2048   }
2049 }
2050
2051 sub get_part_texts {
2052   my ($part_or_id, $language_or_id, %defaults) = @_;
2053
2054   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2055   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2056   my $texts       = {
2057     description     => $defaults{description}     // $part->description,
2058     longdescription => $defaults{longdescription} // $part->notes,
2059   };
2060
2061   return $texts unless $language_id;
2062
2063   my $translation = SL::DB::Manager::Translation->get_first(
2064     where => [
2065       parts_id    => $part->id,
2066       language_id => $language_id,
2067     ]);
2068
2069   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2070   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2071
2072   return $texts;
2073 }
2074
2075 sub sales_order_type {
2076   'sales_order';
2077 }
2078
2079 sub purchase_order_type {
2080   'purchase_order';
2081 }
2082
2083 sub sales_quotation_type {
2084   'sales_quotation';
2085 }
2086
2087 sub request_quotation_type {
2088   'request_quotation';
2089 }
2090
2091 sub nr_key {
2092   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2093        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2094        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2095        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2096        : '';
2097 }
2098
2099 sub save_and_redirect_to {
2100   my ($self, %params) = @_;
2101
2102   my $errors = $self->save();
2103
2104   if (scalar @{ $errors }) {
2105     $self->js->flash('error', $_) foreach @{ $errors };
2106     return $self->js->render();
2107   }
2108
2109   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2110            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2111            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2112            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2113            : '';
2114   flash_later('info', $text);
2115
2116   $self->redirect_to(%params, id => $self->order->id);
2117 }
2118
2119 sub save_history {
2120   my ($self, $addition) = @_;
2121
2122   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2123   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2124
2125   SL::DB::History->new(
2126     trans_id    => $self->order->id,
2127     employee_id => SL::DB::Manager::Employee->current->id,
2128     what_done   => $self->order->type,
2129     snumbers    => $snumbers,
2130     addition    => $addition,
2131   )->save;
2132 }
2133
2134 sub store_pdf_to_webdav_and_filemanagement {
2135   my($order, $content, $filename) = @_;
2136
2137   my @errors;
2138
2139   # copy file to webdav folder
2140   if ($order->number && $::instance_conf->get_webdav_documents) {
2141     my $webdav = SL::Webdav->new(
2142       type     => $order->type,
2143       number   => $order->number,
2144     );
2145     my $webdav_file = SL::Webdav::File->new(
2146       webdav   => $webdav,
2147       filename => $filename,
2148     );
2149     eval {
2150       $webdav_file->store(data => \$content);
2151       1;
2152     } or do {
2153       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2154     };
2155   }
2156   if ($order->id && $::instance_conf->get_doc_storage) {
2157     eval {
2158       SL::File->save(object_id     => $order->id,
2159                      object_type   => $order->type,
2160                      mime_type     => 'application/pdf',
2161                      source        => 'created',
2162                      file_type     => 'document',
2163                      file_name     => $filename,
2164                      file_contents => $content);
2165       1;
2166     } or do {
2167       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2168     };
2169   }
2170
2171   return @errors;
2172 }
2173
2174 1;
2175
2176 __END__
2177
2178 =encoding utf-8
2179
2180 =head1 NAME
2181
2182 SL::Controller::Order - controller for orders
2183
2184 =head1 SYNOPSIS
2185
2186 This is a new form to enter orders, completely rewritten with the use
2187 of controller and java script techniques.
2188
2189 The aim is to provide the user a better experience and a faster workflow. Also
2190 the code should be more readable, more reliable and better to maintain.
2191
2192 =head2 Key Features
2193
2194 =over 4
2195
2196 =item *
2197
2198 One input row, so that input happens every time at the same place.
2199
2200 =item *
2201
2202 Use of pickers where possible.
2203
2204 =item *
2205
2206 Possibility to enter more than one item at once.
2207
2208 =item *
2209
2210 Item list in a scrollable area, so that the workflow buttons stay at
2211 the bottom.
2212
2213 =item *
2214
2215 Reordering item rows with drag and drop is possible. Sorting item rows is
2216 possible (by partnumber, description, qty, sellprice and discount for now).
2217
2218 =item *
2219
2220 No C<update> is necessary. All entries and calculations are managed
2221 with ajax-calls and the page only reloads on C<save>.
2222
2223 =item *
2224
2225 User can see changes immediately, because of the use of java script
2226 and ajax.
2227
2228 =back
2229
2230 =head1 CODE
2231
2232 =head2 Layout
2233
2234 =over 4
2235
2236 =item * C<SL/Controller/Order.pm>
2237
2238 the controller
2239
2240 =item * C<template/webpages/order/form.html>
2241
2242 main form
2243
2244 =item * C<template/webpages/order/tabs/basic_data.html>
2245
2246 Main tab for basic_data.
2247
2248 This is the only tab here for now. "linked records" and "webdav" tabs are
2249 reused from generic code.
2250
2251 =over 4
2252
2253 =item * C<template/webpages/order/tabs/_business_info_row.html>
2254
2255 For displaying information on business type
2256
2257 =item * C<template/webpages/order/tabs/_item_input.html>
2258
2259 The input line for items
2260
2261 =item * C<template/webpages/order/tabs/_row.html>
2262
2263 One row for already entered items
2264
2265 =item * C<template/webpages/order/tabs/_tax_row.html>
2266
2267 Displaying tax information
2268
2269 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2270
2271 Dialog for selecting price and discount sources
2272
2273 =back
2274
2275 =item * C<js/kivi.Order.js>
2276
2277 java script functions
2278
2279 =back
2280
2281 =head1 TODO
2282
2283 =over 4
2284
2285 =item * testing
2286
2287 =item * price sources: little symbols showing better price / better discount
2288
2289 =item * select units in input row?
2290
2291 =item * check for direct delivery (workflow sales order -> purchase order)
2292
2293 =item * access rights
2294
2295 =item * display weights
2296
2297 =item * mtime check
2298
2299 =item * optional client/user behaviour
2300
2301 (transactions has to be set - department has to be set -
2302  force project if enabled in client config - transport cost reminder)
2303
2304 =back
2305
2306 =head1 KNOWN BUGS AND CAVEATS
2307
2308 =over 4
2309
2310 =item *
2311
2312 Customer discount is not displayed as a valid discount in price source popup
2313 (this might be a bug in price sources)
2314
2315 (I cannot reproduce this (Bernd))
2316
2317 =item *
2318
2319 No indication that <shift>-up/down expands/collapses second row.
2320
2321 =item *
2322
2323 Inline creation of parts is not currently supported
2324
2325 =item *
2326
2327 Table header is not sticky in the scrolling area.
2328
2329 =item *
2330
2331 Sorting does not include C<position>, neither does reordering.
2332
2333 This behavior was implemented intentionally. But we can discuss, which behavior
2334 should be implemented.
2335
2336 =back
2337
2338 =head1 To discuss / Nice to have
2339
2340 =over 4
2341
2342 =item *
2343
2344 How to expand/collapse second row. Now it can be done clicking the icon or
2345 <shift>-up/down.
2346
2347 =item *
2348
2349 Possibility to select PriceSources in input row?
2350
2351 =item *
2352
2353 This controller uses a (changed) copy of the template for the PriceSource
2354 dialog. Maybe there could be used one code source.
2355
2356 =item *
2357
2358 Rounding-differences between this controller (PriceTaxCalculator) and the old
2359 form. This is not only a problem here, but also in all parts using the PTC.
2360 There exists a ticket and a patch. This patch should be testet.
2361
2362 =item *
2363
2364 An indicator, if the actual inputs are saved (like in an
2365 editor or on text processing application).
2366
2367 =item *
2368
2369 A warning when leaving the page without saveing unchanged inputs.
2370
2371
2372 =back
2373
2374 =head1 AUTHOR
2375
2376 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2377
2378 =cut