SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24 use SL::DB::Shipto;
  25
  26 use SL::Helper::CreatePDF qw(:all);
  27 use SL::Helper::PrintOptions;
  28 use SL::Helper::ShippedQty;
  29 use SL::Helper::UserPreferences::PositionsScrollbar;
  30 use SL::Helper::UserPreferences::UpdatePositions;
  31
  32 use SL::Controller::Helper::GetModels;
  33
  34 use List::Util qw(first sum0);
  35 use List::UtilsBy qw(sort_by uniq_by);
  36 use List::MoreUtils qw(any none pairwise first_index);
  37 use English qw(-no_match_vars);
  38 use File::Spec;
  39 use Cwd;
  40 use Sort::Naturally;
  41
  42 use Rose::Object::MakeMethods::Generic
  43 (
  44  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  45  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors search_cvpartnumber show_update_button) ],
  46 );
  47
  48
  49 # safety
  50 __PACKAGE__->run_before('check_auth');
  51
  52 __PACKAGE__->run_before('recalc',
  53                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  54                                      print send_email) ]);
  55
  56 __PACKAGE__->run_before('get_unalterable_data',
  57                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  58                                      print send_email) ]);
  59
  60 #
  61 # actions
  62 #
  63
  64 # add a new order
  65 sub action_add {
  66   my ($self) = @_;
  67
  68   $self->order->transdate(DateTime->now_local());
  69   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  70                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  71   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  72
  73
  74   $self->pre_render();
  75   $self->render(
  76     'order/form',
  77     title => $self->get_title_for('add'),
  78     %{$self->{template_args}}
  79   );
  80 }
  81
  82 # edit an existing order
  83 sub action_edit {
  84   my ($self) = @_;
  85
  86   if ($::form->{id}) {
  87     $self->load_order;
  88
  89   } else {
  90     # this is to edit an order from an unsaved order object
  91
  92     # set item ids to new fake id, to identify them as new items
  93     foreach my $item (@{$self->order->items_sorted}) {
  94       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  95     }
  96     # trigger rendering values for second row/longdescription as hidden,
  97     # because they are loaded only on demand. So we need to keep the values
  98     # from the source.
  99     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
 100     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 101   }
 102
 103   $self->recalc();
 104   $self->pre_render();
 105   $self->render(
 106     'order/form',
 107     title => $self->get_title_for('edit'),
 108     %{$self->{template_args}}
 109   );
 110 }
 111
 112 # edit a collective order (consisting of one or more existing orders)
 113 sub action_edit_collective {
 114   my ($self) = @_;
 115
 116   # collect order ids
 117   my @multi_ids = map {
 118     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 119   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 120
 121   # fall back to add if no ids are given
 122   if (scalar @multi_ids == 0) {
 123     $self->action_add();
 124     return;
 125   }
 126
 127   # fall back to save as new if only one id is given
 128   if (scalar @multi_ids == 1) {
 129     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 130     $self->action_save_as_new();
 131     return;
 132   }
 133
 134   # make new order from given orders
 135   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 136   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 137   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 138
 139   $self->action_edit();
 140 }
 141
 142 # delete the order
 143 sub action_delete {
 144   my ($self) = @_;
 145
 146   my $errors = $self->delete();
 147
 148   if (scalar @{ $errors }) {
 149     $self->js->flash('error', $_) foreach @{ $errors };
 150     return $self->js->render();
 151   }
 152
 153   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 154            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 155            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 156            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 157            : '';
 158   flash_later('info', $text);
 159
 160   my @redirect_params = (
 161     action => 'add',
 162     type   => $self->type,
 163   );
 164
 165   $self->redirect_to(@redirect_params);
 166 }
 167
 168 # save the order
 169 sub action_save {
 170   my ($self) = @_;
 171
 172   my $errors = $self->save();
 173
 174   if (scalar @{ $errors }) {
 175     $self->js->flash('error', $_) foreach @{ $errors };
 176     return $self->js->render();
 177   }
 178
 179   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 180            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 181            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 182            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 183            : '';
 184   flash_later('info', $text);
 185
 186   my @redirect_params = (
 187     action => 'edit',
 188     type   => $self->type,
 189     id     => $self->order->id,
 190   );
 191
 192   $self->redirect_to(@redirect_params);
 193 }
 194
 195 # save the order as new document an open it for edit
 196 sub action_save_as_new {
 197   my ($self) = @_;
 198
 199   my $order = $self->order;
 200
 201   if (!$order->id) {
 202     $self->js->flash('error', t8('This object has not been saved yet.'));
 203     return $self->js->render();
 204   }
 205
 206   # load order from db to check if values changed
 207   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 208
 209   my %new_attrs;
 210   # Lets assign a new number if the user hasn't changed the previous one.
 211   # If it has been changed manually then use it as-is.
 212   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 213                         ? ''
 214                         : trim($order->number);
 215
 216   # Clear transdate unless changed
 217   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 218                         ? DateTime->today_local
 219                         : $order->transdate;
 220
 221   # Set new reqdate unless changed
 222   if ($order->reqdate == $saved_order->reqdate) {
 223     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 224                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 225     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 226   } else {
 227     $new_attrs{reqdate} = $order->reqdate;
 228   }
 229
 230   # Update employee
 231   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 232
 233   # Create new record from current one
 234   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 235
 236   # no linked records on save as new
 237   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 238
 239   # save
 240   $self->action_save();
 241 }
 242
 243 # print the order
 244 #
 245 # This is called if "print" is pressed in the print dialog.
 246 # If PDF creation was requested and succeeded, the pdf is offered for download
 247 # via send_file (which uses ajax in this case).
 248 sub action_print {
 249   my ($self) = @_;
 250
 251   my $errors = $self->save();
 252
 253   if (scalar @{ $errors }) {
 254     $self->js->flash('error', $_) foreach @{ $errors };
 255     return $self->js->render();
 256   }
 257
 258   $self->js_reset_order_and_item_ids_after_save;
 259
 260   my $format      = $::form->{print_options}->{format};
 261   my $media       = $::form->{print_options}->{media};
 262   my $formname    = $::form->{print_options}->{formname};
 263   my $copies      = $::form->{print_options}->{copies};
 264   my $groupitems  = $::form->{print_options}->{groupitems};
 265
 266   # only pdf and opendocument by now
 267   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 268     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 269   }
 270
 271   # only screen or printer by now
 272   if (none { $media eq $_ } qw(screen printer)) {
 273     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 274   }
 275
 276   my $language;
 277   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 278
 279   # create a form for generate_attachment_filename
 280   my $form   = Form->new;
 281   $form->{$self->nr_key()}  = $self->order->number;
 282   $form->{type}             = $self->type;
 283   $form->{format}           = $format;
 284   $form->{formname}         = $formname;
 285   $form->{language}         = '_' . $language->template_code if $language;
 286   my $pdf_filename          = $form->generate_attachment_filename();
 287
 288   my $pdf;
 289   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 290                                                    formname   => $formname,
 291                                                    language   => $language,
 292                                                    groupitems => $groupitems });
 293   if (scalar @errors) {
 294     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 295   }
 296
 297   if ($media eq 'screen') {
 298     # screen/download
 299     $self->js->flash('info', t8('The PDF has been created'));
 300     $self->send_file(
 301       \$pdf,
 302       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 303       name         => $pdf_filename,
 304       js_no_render => 1,
 305     );
 306
 307   } elsif ($media eq 'printer') {
 308     # printer
 309     my $printer_id = $::form->{print_options}->{printer_id};
 310     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 311       copies  => $copies,
 312       content => $pdf,
 313     );
 314
 315     $self->js->flash('info', t8('The PDF has been printed'));
 316   }
 317
 318   # copy file to webdav folder
 319   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 320     my $webdav = SL::Webdav->new(
 321       type     => $self->type,
 322       number   => $self->order->number,
 323     );
 324     my $webdav_file = SL::Webdav::File->new(
 325       webdav   => $webdav,
 326       filename => $pdf_filename,
 327     );
 328     eval {
 329       $webdav_file->store(data => \$pdf);
 330       1;
 331     } or do {
 332       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 333     }
 334   }
 335   if ($self->order->number && $::instance_conf->get_doc_storage) {
 336     eval {
 337       SL::File->save(object_id     => $self->order->id,
 338                      object_type   => $self->type,
 339                      mime_type     => 'application/pdf',
 340                      source        => 'created',
 341                      file_type     => 'document',
 342                      file_name     => $pdf_filename,
 343                      file_contents => $pdf);
 344       1;
 345     } or do {
 346       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 347     }
 348   }
 349   $self->js->render;
 350 }
 351
 352 # open the email dialog
 353 sub action_save_and_show_email_dialog {
 354   my ($self) = @_;
 355
 356   my $errors = $self->save();
 357
 358   if (scalar @{ $errors }) {
 359     $self->js->flash('error', $_) foreach @{ $errors };
 360     return $self->js->render();
 361   }
 362
 363   my $cv_method = $self->cv;
 364
 365   if (!$self->order->$cv_method) {
 366     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 367                     ->render($self);
 368   }
 369
 370   my $email_form;
 371   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 372   $email_form->{to} ||= $self->order->$cv_method->email;
 373   $email_form->{cc}   = $self->order->$cv_method->cc;
 374   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 375   # Todo: get addresses from shipto, if any
 376
 377   my $form = Form->new;
 378   $form->{$self->nr_key()}  = $self->order->number;
 379   $form->{formname}         = $self->type;
 380   $form->{type}             = $self->type;
 381   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 382   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 383   $form->{cusordnumber}     = $self->order->cusordnumber;
 384   $form->{format}           = 'pdf';
 385
 386   $email_form->{subject}             = $form->generate_email_subject();
 387   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 388   $email_form->{message}             = $form->generate_email_body();
 389   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 390
 391   my %files = $self->get_files_for_email_dialog();
 392   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 393                                   email_form  => $email_form,
 394                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 395                                   FILES       => \%files,
 396                                   is_customer => $self->cv eq 'customer',
 397   );
 398
 399   $self->js
 400       ->run('kivi.Order.show_email_dialog', $dialog_html)
 401       ->reinit_widgets
 402       ->render($self);
 403 }
 404
 405 # send email
 406 #
 407 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 408 sub action_send_email {
 409   my ($self) = @_;
 410
 411   my $errors = $self->save();
 412
 413   if (scalar @{ $errors }) {
 414     $self->js->run('kivi.Order.close_email_dialog');
 415     $self->js->flash('error', $_) foreach @{ $errors };
 416     return $self->js->render();
 417   }
 418
 419   $self->js_reset_order_and_item_ids_after_save;
 420
 421   my $email_form  = delete $::form->{email_form};
 422   my %field_names = (to => 'email');
 423
 424   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 425
 426   # for Form::cleanup which may be called in Form::send_email
 427   $::form->{cwd}    = getcwd();
 428   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 429
 430   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 431   $::form->{media}  = 'email';
 432
 433   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 434     my $language;
 435     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 436
 437     my $pdf;
 438     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 439                                                     format     => $::form->{print_options}->{format},
 440                                                     formname   => $::form->{print_options}->{formname},
 441                                                     language   => $language,
 442                                                     groupitems => $::form->{print_options}->{groupitems}});
 443     if (scalar @errors) {
 444       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 445     }
 446
 447     my $sfile = SL::SessionFile::Random->new(mode => "w");
 448     $sfile->fh->print($pdf);
 449     $sfile->fh->close;
 450
 451     $::form->{tmpfile} = $sfile->file_name;
 452     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 453   }
 454
 455   $::form->send_email(\%::myconfig, 'pdf');
 456
 457   # internal notes
 458   my $intnotes = $self->order->intnotes;
 459   $intnotes   .= "\n\n" if $self->order->intnotes;
 460   $intnotes   .= t8('[email]')                                                                                        . "\n";
 461   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 462   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 463   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 464   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 465   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 466   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 467
 468   $self->order->update_attributes(intnotes => $intnotes);
 469
 470   $self->js
 471       ->val('#order_intnotes', $intnotes)
 472       ->run('kivi.Order.close_email_dialog')
 473       ->flash('info', t8('The email has been sent.'))
 474       ->render($self);
 475 }
 476
 477 # open the periodic invoices config dialog
 478 #
 479 # If there are values in the form (i.e. dialog was opened before),
 480 # then use this values. Create new ones, else.
 481 sub action_show_periodic_invoices_config_dialog {
 482   my ($self) = @_;
 483
 484   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 485   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 486   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 487                                                    order_value_periodicity => 'p', # = same as periodicity
 488                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 489                                                    extend_automatically_by => 12,
 490                                                    active                  => 1,
 491                                                    email_subject           => GenericTranslations->get(
 492                                                                                 language_id      => $::form->{language_id},
 493                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 494                                                    email_body              => GenericTranslations->get(
 495                                                                                 language_id      => $::form->{language_id},
 496                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 497   );
 498   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 499   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 500
 501   $::form->get_lists(printers => "ALL_PRINTERS",
 502                      charts   => { key       => 'ALL_CHARTS',
 503                                    transdate => 'current_date' });
 504
 505   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 506
 507   if ($::form->{customer_id}) {
 508     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 509     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 510   }
 511
 512   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 513                 popup_dialog             => 1,
 514                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 515                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 516                 config                   => $config,
 517                 %$::form);
 518 }
 519
 520 # assign the values of the periodic invoices config dialog
 521 # as yaml in the hidden tag and set the status.
 522 sub action_assign_periodic_invoices_config {
 523   my ($self) = @_;
 524
 525   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 526
 527   my $config = { active                     => $::form->{active}       ? 1 : 0,
 528                  terminated                 => $::form->{terminated}   ? 1 : 0,
 529                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 530                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 531                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 532                  start_date_as_date         => $::form->{start_date_as_date},
 533                  end_date_as_date           => $::form->{end_date_as_date},
 534                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 535                  print                      => $::form->{print}      ? 1                         : 0,
 536                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 537                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 538                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 539                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 540                  send_email                 => $::form->{send_email} ? 1 : 0,
 541                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 542                  email_recipient_address    => $::form->{email_recipient_address},
 543                  email_sender               => $::form->{email_sender},
 544                  email_subject              => $::form->{email_subject},
 545                  email_body                 => $::form->{email_body},
 546                };
 547
 548   my $periodic_invoices_config = SL::YAML::Dump($config);
 549
 550   my $status = $self->get_periodic_invoices_status($config);
 551
 552   $self->js
 553     ->remove('#order_periodic_invoices_config')
 554     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 555     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 556     ->html('#periodic_invoices_status', $status)
 557     ->flash('info', t8('The periodic invoices config has been assigned.'))
 558     ->render($self);
 559 }
 560
 561 sub action_get_has_active_periodic_invoices {
 562   my ($self) = @_;
 563
 564   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 565   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 566
 567   my $has_active_periodic_invoices =
 568        $self->type eq sales_order_type()
 569     && $config
 570     && $config->active
 571     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 572     && $config->get_previous_billed_period_start_date;
 573
 574   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 575 }
 576
 577 # save the order and redirect to the frontend subroutine for a new
 578 # delivery order
 579 sub action_save_and_delivery_order {
 580   my ($self) = @_;
 581
 582   my $errors = $self->save();
 583
 584   if (scalar @{ $errors }) {
 585     $self->js->flash('error', $_) foreach @{ $errors };
 586     return $self->js->render();
 587   }
 588
 589   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 590            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 591            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 592            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 593            : '';
 594   flash_later('info', $text);
 595
 596   my @redirect_params = (
 597     controller => 'oe.pl',
 598     action     => 'oe_delivery_order_from_order',
 599     id         => $self->order->id,
 600   );
 601
 602   $self->redirect_to(@redirect_params);
 603 }
 604
 605 # save the order and redirect to the frontend subroutine for a new
 606 # invoice
 607 sub action_save_and_invoice {
 608   my ($self) = @_;
 609
 610   my $errors = $self->save();
 611
 612   if (scalar @{ $errors }) {
 613     $self->js->flash('error', $_) foreach @{ $errors };
 614     return $self->js->render();
 615   }
 616
 617   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 618            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 619            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 620            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 621            : '';
 622   flash_later('info', $text);
 623
 624   my @redirect_params = (
 625     controller => 'oe.pl',
 626     action     => 'oe_invoice_from_order',
 627     id         => $self->order->id,
 628   );
 629
 630   $self->redirect_to(@redirect_params);
 631 }
 632
 633 # workflow from sales quotation to sales order
 634 sub action_sales_order {
 635   $_[0]->workflow_sales_or_purchase_order();
 636 }
 637
 638 # workflow from rfq to purchase order
 639 sub action_purchase_order {
 640   $_[0]->workflow_sales_or_purchase_order();
 641 }
 642
 643 # workflow from purchase order to ap transaction
 644 sub action_save_and_ap_transaction {
 645   my ($self) = @_;
 646
 647   my $errors = $self->save();
 648
 649   if (scalar @{ $errors }) {
 650     $self->js->flash('error', $_) foreach @{ $errors };
 651     return $self->js->render();
 652   }
 653
 654   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 655            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 656            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 657            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 658            : '';
 659   flash_later('info', $text);
 660
 661   my @redirect_params = (
 662     controller => 'ap.pl',
 663     action     => 'add_from_purchase_order',
 664     id         => $self->order->id,
 665   );
 666
 667   $self->redirect_to(@redirect_params);
 668 }
 669
 670 # set form elements in respect to a changed customer or vendor
 671 #
 672 # This action is called on an change of the customer/vendor picker.
 673 sub action_customer_vendor_changed {
 674   my ($self) = @_;
 675
 676   setup_order_from_cv($self->order);
 677   $self->recalc();
 678
 679   my $cv_method = $self->cv;
 680
 681   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 682     $self->js->show('#cp_row');
 683   } else {
 684     $self->js->hide('#cp_row');
 685   }
 686
 687   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 688     $self->js->show('#shipto_selection');
 689   } else {
 690     $self->js->hide('#shipto_selection');
 691   }
 692
 693   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 694
 695   $self->js
 696     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 697     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 698     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 699     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 700     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 701     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 702     ->val(        '#order_currency_id',      $self->order->currency_id)
 703     ->val(        '#order_payment_id',       $self->order->payment_id)
 704     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 705     ->val(        '#order_intnotes',         $self->order->intnotes)
 706     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 707     ->focus(      '#order_' . $self->cv . '_id')
 708     ->run('kivi.Order.update_exchangerate');
 709
 710   $self->js_redisplay_amounts_and_taxes;
 711   $self->js_redisplay_cvpartnumbers;
 712   $self->js->render();
 713 }
 714
 715 # open the dialog for customer/vendor details
 716 sub action_show_customer_vendor_details_dialog {
 717   my ($self) = @_;
 718
 719   my $is_customer = 'customer' eq $::form->{vc};
 720   my $cv;
 721   if ($is_customer) {
 722     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 723   } else {
 724     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 725   }
 726
 727   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 728   $details{discount_as_percent} = $cv->discount_as_percent;
 729   $details{creditlimt}          = $cv->creditlimit_as_number;
 730   $details{business}            = $cv->business->description      if $cv->business;
 731   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 732   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 733   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 734   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 735
 736   foreach my $entry (@{ $cv->shipto }) {
 737     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 738   }
 739   foreach my $entry (@{ $cv->contacts }) {
 740     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 741   }
 742
 743   $_[0]->render('common/show_vc_details', { layout => 0 },
 744                 is_customer => $is_customer,
 745                 %details);
 746
 747 }
 748
 749 # called if a unit in an existing item row is changed
 750 sub action_unit_changed {
 751   my ($self) = @_;
 752
 753   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 754   my $item = $self->order->items_sorted->[$idx];
 755
 756   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 757   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 758
 759   $self->recalc();
 760
 761   $self->js
 762     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 763   $self->js_redisplay_line_values;
 764   $self->js_redisplay_amounts_and_taxes;
 765   $self->js->render();
 766 }
 767
 768 # add an item row for a new item entered in the input row
 769 sub action_add_item {
 770   my ($self) = @_;
 771
 772   my $form_attr = $::form->{add_item};
 773
 774   return unless $form_attr->{parts_id};
 775
 776   my $item = new_item($self->order, $form_attr);
 777
 778   $self->order->add_items($item);
 779
 780   $self->recalc();
 781
 782   $self->get_item_cvpartnumber($item);
 783
 784   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 785   my $row_as_html = $self->p->render('order/tabs/_row',
 786                                      ITEM => $item,
 787                                      ID   => $item_id,
 788                                      SELF => $self,
 789   );
 790
 791   if ($::form->{insert_before_item_id}) {
 792     $self->js
 793       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 794   } else {
 795     $self->js
 796       ->append('#row_table_id', $row_as_html);
 797   }
 798
 799   if ( $item->part->is_assortment ) {
 800     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 801     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 802       my $attr = { parts_id => $assortment_item->parts_id,
 803                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 804                    unit     => $assortment_item->unit,
 805                    description => $assortment_item->part->description,
 806                  };
 807       my $item = new_item($self->order, $attr);
 808
 809       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 810       $item->discount(1) unless $assortment_item->charge;
 811
 812       $self->order->add_items( $item );
 813       $self->recalc();
 814       $self->get_item_cvpartnumber($item);
 815       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 816       my $row_as_html = $self->p->render('order/tabs/_row',
 817                                          ITEM => $item,
 818                                          ID   => $item_id,
 819                                          SELF => $self,
 820       );
 821       if ($::form->{insert_before_item_id}) {
 822         $self->js
 823           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 824       } else {
 825         $self->js
 826           ->append('#row_table_id', $row_as_html);
 827       }
 828     };
 829   };
 830
 831   $self->js
 832     ->val('.add_item_input', '')
 833     ->run('kivi.Order.init_row_handlers')
 834     ->run('kivi.Order.renumber_positions')
 835     ->focus('#add_item_parts_id_name');
 836
 837   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 838
 839   $self->js_redisplay_amounts_and_taxes;
 840   $self->js->render();
 841 }
 842
 843 # open the dialog for entering multiple items at once
 844 sub action_show_multi_items_dialog {
 845   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 846                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 847 }
 848
 849 # update the filter results in the multi item dialog
 850 sub action_multi_items_update_result {
 851   my $max_count = 100;
 852
 853   $::form->{multi_items}->{filter}->{obsolete} = 0;
 854
 855   my $count = $_[0]->multi_items_models->count;
 856
 857   if ($count == 0) {
 858     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 859     $_[0]->render($text, { layout => 0 });
 860   } elsif ($count > $max_count) {
 861     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 862     $_[0]->render($text, { layout => 0 });
 863   } else {
 864     my $multi_items = $_[0]->multi_items_models->get;
 865     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 866                   multi_items => $multi_items);
 867   }
 868 }
 869
 870 # add item rows for multiple items at once
 871 sub action_add_multi_items {
 872   my ($self) = @_;
 873
 874   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 875   return $self->js->render() unless scalar @form_attr;
 876
 877   my @items;
 878   foreach my $attr (@form_attr) {
 879     my $item = new_item($self->order, $attr);
 880     push @items, $item;
 881     if ( $item->part->is_assortment ) {
 882       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 883         my $attr = { parts_id => $assortment_item->parts_id,
 884                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 885                      unit     => $assortment_item->unit,
 886                      description => $assortment_item->part->description,
 887                    };
 888         my $item = new_item($self->order, $attr);
 889
 890         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 891         $item->discount(1) unless $assortment_item->charge;
 892         push @items, $item;
 893       }
 894     }
 895   }
 896   $self->order->add_items(@items);
 897
 898   $self->recalc();
 899
 900   foreach my $item (@items) {
 901     $self->get_item_cvpartnumber($item);
 902     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 903     my $row_as_html = $self->p->render('order/tabs/_row',
 904                                        ITEM => $item,
 905                                        ID   => $item_id,
 906                                        SELF => $self,
 907     );
 908
 909     if ($::form->{insert_before_item_id}) {
 910       $self->js
 911         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 912     } else {
 913       $self->js
 914         ->append('#row_table_id', $row_as_html);
 915     }
 916   }
 917
 918   $self->js
 919     ->run('kivi.Order.close_multi_items_dialog')
 920     ->run('kivi.Order.init_row_handlers')
 921     ->run('kivi.Order.renumber_positions')
 922     ->focus('#add_item_parts_id_name');
 923
 924   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 925
 926   $self->js_redisplay_amounts_and_taxes;
 927   $self->js->render();
 928 }
 929
 930 # recalculate all linetotals, amounts and taxes and redisplay them
 931 sub action_recalc_amounts_and_taxes {
 932   my ($self) = @_;
 933
 934   $self->recalc();
 935
 936   $self->js_redisplay_line_values;
 937   $self->js_redisplay_amounts_and_taxes;
 938   $self->js->render();
 939 }
 940
 941 sub action_update_exchangerate {
 942   my ($self) = @_;
 943
 944   my $data = {
 945     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 946     currency_name => $self->order->currency->name,
 947     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 948   };
 949
 950   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 951 }
 952
 953 # redisplay item rows if they are sorted by an attribute
 954 sub action_reorder_items {
 955   my ($self) = @_;
 956
 957   my %sort_keys = (
 958     partnumber   => sub { $_[0]->part->partnumber },
 959     description  => sub { $_[0]->description },
 960     qty          => sub { $_[0]->qty },
 961     sellprice    => sub { $_[0]->sellprice },
 962     discount     => sub { $_[0]->discount },
 963     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 964   );
 965
 966   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 967
 968   my $method = $sort_keys{$::form->{order_by}};
 969   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 970   if ($::form->{sort_dir}) {
 971     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 972       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 973     } else {
 974       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 975     }
 976   } else {
 977     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 978       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 979     } else {
 980       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 981     }
 982   }
 983   $self->js
 984     ->run('kivi.Order.redisplay_items', \@to_sort)
 985     ->render;
 986 }
 987
 988 # show the popup to choose a price/discount source
 989 sub action_price_popup {
 990   my ($self) = @_;
 991
 992   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 993   my $item = $self->order->items_sorted->[$idx];
 994
 995   $self->render_price_dialog($item);
 996 }
 997
 998 # get the longdescription for an item if the dialog to enter/change the
 999 # longdescription was opened and the longdescription is empty
1000 #
1001 # If this item is new, get the longdescription from Part.
1002 # Otherwise get it from OrderItem.
1003 sub action_get_item_longdescription {
1004   my $longdescription;
1005
1006   if ($::form->{item_id}) {
1007     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
1008   } elsif ($::form->{parts_id}) {
1009     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
1010   }
1011   $_[0]->render(\ $longdescription, { type => 'text' });
1012 }
1013
1014 # load the second row for one or more items
1015 #
1016 # This action gets the html code for all items second rows by rendering a template for
1017 # the second row and sets the html code via client js.
1018 sub action_load_second_rows {
1019   my ($self) = @_;
1020
1021   $self->recalc() if $self->order->is_sales; # for margin calculation
1022
1023   foreach my $item_id (@{ $::form->{item_ids} }) {
1024     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1025     my $item = $self->order->items_sorted->[$idx];
1026
1027     $self->js_load_second_row($item, $item_id, 0);
1028   }
1029
1030   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1031
1032   $self->js->render();
1033 }
1034
1035 # update description, notes and sellprice from master data
1036 sub action_update_row_from_master_data {
1037   my ($self) = @_;
1038
1039   foreach my $item_id (@{ $::form->{item_ids} }) {
1040     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1041     my $item = $self->order->items_sorted->[$idx];
1042
1043     $item->description($item->part->description);
1044     $item->longdescription($item->part->notes);
1045
1046     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1047
1048     my $price_src;
1049     if ($item->part->is_assortment) {
1050     # add assortment items with price 0, as the components carry the price
1051       $price_src = $price_source->price_from_source("");
1052       $price_src->price(0);
1053     } else {
1054       $price_src = $price_source->best_price
1055                  ? $price_source->best_price
1056                  : $price_source->price_from_source("");
1057       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1058       $price_src->price(0) if !$price_source->best_price;
1059     }
1060
1061
1062     $item->sellprice($price_src->price);
1063     $item->active_price_source($price_src);
1064
1065     $self->js
1066       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1067       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1068       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1069       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1070
1071     if ($self->search_cvpartnumber) {
1072       $self->get_item_cvpartnumber($item);
1073       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1074     }
1075   }
1076
1077   $self->recalc();
1078   $self->js_redisplay_line_values;
1079   $self->js_redisplay_amounts_and_taxes;
1080
1081   $self->js->render();
1082 }
1083
1084 sub js_load_second_row {
1085   my ($self, $item, $item_id, $do_parse) = @_;
1086
1087   if ($do_parse) {
1088     # Parse values from form (they are formated while rendering (template)).
1089     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1090     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1091     foreach my $var (@{ $item->cvars_by_config }) {
1092       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1093     }
1094     $item->parse_custom_variable_values;
1095   }
1096
1097   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1098
1099   $self->js
1100     ->html('#second_row_' . $item_id, $row_as_html)
1101     ->data('#second_row_' . $item_id, 'loaded', 1);
1102 }
1103
1104 sub js_redisplay_line_values {
1105   my ($self) = @_;
1106
1107   my $is_sales = $self->order->is_sales;
1108
1109   # sales orders with margins
1110   my @data;
1111   if ($is_sales) {
1112     @data = map {
1113       [
1114        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1115        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1116        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1117       ]} @{ $self->order->items_sorted };
1118   } else {
1119     @data = map {
1120       [
1121        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1122       ]} @{ $self->order->items_sorted };
1123   }
1124
1125   $self->js
1126     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1127 }
1128
1129 sub js_redisplay_amounts_and_taxes {
1130   my ($self) = @_;
1131
1132   if (scalar @{ $self->{taxes} }) {
1133     $self->js->show('#taxincluded_row_id');
1134   } else {
1135     $self->js->hide('#taxincluded_row_id');
1136   }
1137
1138   if ($self->order->taxincluded) {
1139     $self->js->hide('#subtotal_row_id');
1140   } else {
1141     $self->js->show('#subtotal_row_id');
1142   }
1143
1144   if ($self->order->is_sales) {
1145     my $is_neg = $self->order->marge_total < 0;
1146     $self->js
1147       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1148       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1149       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1150       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1151       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1152       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1153       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1154       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1155   }
1156
1157   $self->js
1158     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1159     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1160     ->remove('.tax_row')
1161     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1162 }
1163
1164 sub js_redisplay_cvpartnumbers {
1165   my ($self) = @_;
1166
1167   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1168
1169   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1170
1171   $self->js
1172     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1173 }
1174
1175 sub js_reset_order_and_item_ids_after_save {
1176   my ($self) = @_;
1177
1178   $self->js
1179     ->val('#id', $self->order->id)
1180     ->val('#converted_from_oe_id', '')
1181     ->val('#order_' . $self->nr_key(), $self->order->number);
1182
1183   my $idx = 0;
1184   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1185     next if !$self->order->items_sorted->[$idx]->id;
1186     next if $form_item_id !~ m{^new};
1187     $self->js
1188       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1189       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1190       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1191   } continue {
1192     $idx++;
1193   }
1194   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1195 }
1196
1197 #
1198 # helpers
1199 #
1200
1201 sub init_valid_types {
1202   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1203 }
1204
1205 sub init_type {
1206   my ($self) = @_;
1207
1208   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1209     die "Not a valid type for order";
1210   }
1211
1212   $self->type($::form->{type});
1213 }
1214
1215 sub init_cv {
1216   my ($self) = @_;
1217
1218   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1219          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1220          : die "Not a valid type for order";
1221
1222   return $cv;
1223 }
1224
1225 sub init_search_cvpartnumber {
1226   my ($self) = @_;
1227
1228   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1229   my $search_cvpartnumber;
1230   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1231   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1232
1233   return $search_cvpartnumber;
1234 }
1235
1236 sub init_show_update_button {
1237   my ($self) = @_;
1238
1239   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1240 }
1241
1242 sub init_p {
1243   SL::Presenter->get;
1244 }
1245
1246 sub init_order {
1247   $_[0]->make_order;
1248 }
1249
1250 # model used to filter/display the parts in the multi-items dialog
1251 sub init_multi_items_models {
1252   SL::Controller::Helper::GetModels->new(
1253     controller     => $_[0],
1254     model          => 'Part',
1255     with_objects   => [ qw(unit_obj) ],
1256     disable_plugin => 'paginated',
1257     source         => $::form->{multi_items},
1258     sorted         => {
1259       _default    => {
1260         by  => 'partnumber',
1261         dir => 1,
1262       },
1263       partnumber  => t8('Partnumber'),
1264       description => t8('Description')}
1265   );
1266 }
1267
1268 sub init_all_price_factors {
1269   SL::DB::Manager::PriceFactor->get_all;
1270 }
1271
1272 sub check_auth {
1273   my ($self) = @_;
1274
1275   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1276
1277   my $right   = $right_for->{ $self->type };
1278   $right    ||= 'DOES_NOT_EXIST';
1279
1280   $::auth->assert($right);
1281 }
1282
1283 # build the selection box for contacts
1284 #
1285 # Needed, if customer/vendor changed.
1286 sub build_contact_select {
1287   my ($self) = @_;
1288
1289   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1290     value_key  => 'cp_id',
1291     title_key  => 'full_name_dep',
1292     default    => $self->order->cp_id,
1293     with_empty => 1,
1294     style      => 'width: 300px',
1295   );
1296 }
1297
1298 # build the selection box for shiptos
1299 #
1300 # Needed, if customer/vendor changed.
1301 sub build_shipto_select {
1302   my ($self) = @_;
1303
1304   select_tag('order.shipto_id',
1305              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1306              value_key  => 'shipto_id',
1307              title_key  => 'displayable_id',
1308              default    => $self->order->shipto_id,
1309              with_empty => 0,
1310              style      => 'width: 300px',
1311   );
1312 }
1313
1314 # build the inputs for the cusom shipto dialog
1315 #
1316 # Needed, if customer/vendor changed.
1317 sub build_shipto_inputs {
1318   my ($self) = @_;
1319
1320   my $content = $self->p->render('common/_ship_to_dialog',
1321                                  vc_obj      => $self->order->customervendor,
1322                                  cs_obj      => $self->order->custom_shipto,
1323                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1324                                  id_selector => '#order_shipto_id');
1325
1326   div_tag($content, id => 'shipto_inputs');
1327 }
1328
1329 # render the info line for business
1330 #
1331 # Needed, if customer/vendor changed.
1332 sub build_business_info_row
1333 {
1334   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1335 }
1336
1337 # build the rows for displaying taxes
1338 #
1339 # Called if amounts where recalculated and redisplayed.
1340 sub build_tax_rows {
1341   my ($self) = @_;
1342
1343   my $rows_as_html;
1344   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1345     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1346   }
1347   return $rows_as_html;
1348 }
1349
1350
1351 sub render_price_dialog {
1352   my ($self, $record_item) = @_;
1353
1354   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1355
1356   $self->js
1357     ->run(
1358       'kivi.io.price_chooser_dialog',
1359       t8('Available Prices'),
1360       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1361     )
1362     ->reinit_widgets;
1363
1364 #   if (@errors) {
1365 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1366 #     $self->js->show('#dialog_flash_error');
1367 #   }
1368
1369   $self->js->render;
1370 }
1371
1372 sub load_order {
1373   my ($self) = @_;
1374
1375   return if !$::form->{id};
1376
1377   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1378
1379   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1380   # You need a custom shipto object to call cvars_by_config to get the cvars.
1381   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1382
1383   return $self->order;
1384 }
1385
1386 # load or create a new order object
1387 #
1388 # And assign changes from the form to this object.
1389 # If the order is loaded from db, check if items are deleted in the form,
1390 # remove them form the object and collect them for removing from db on saving.
1391 # Then create/update items from form (via make_item) and add them.
1392 sub make_order {
1393   my ($self) = @_;
1394
1395   # add_items adds items to an order with no items for saving, but they cannot
1396   # be retrieved via items until the order is saved. Adding empty items to new
1397   # order here solves this problem.
1398   my $order;
1399   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1400   $order ||= SL::DB::Order->new(orderitems  => [],
1401                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1402                                 currency_id => $::instance_conf->get_currency_id(),);
1403
1404   my $cv_id_method = $self->cv . '_id';
1405   if (!$::form->{id} && $::form->{$cv_id_method}) {
1406     $order->$cv_id_method($::form->{$cv_id_method});
1407     setup_order_from_cv($order);
1408   }
1409
1410   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1411   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1412
1413   $order->assign_attributes(%{$::form->{order}});
1414
1415   $self->setup_custom_shipto_from_form($order, $::form);
1416
1417   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1418     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1419     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1420   }
1421
1422   # remove deleted items
1423   $self->item_ids_to_delete([]);
1424   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1425     my $item = $order->orderitems->[$idx];
1426     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1427       splice @{$order->orderitems}, $idx, 1;
1428       push @{$self->item_ids_to_delete}, $item->id;
1429     }
1430   }
1431
1432   my @items;
1433   my $pos = 1;
1434   foreach my $form_attr (@{$form_orderitems}) {
1435     my $item = make_item($order, $form_attr);
1436     $item->position($pos);
1437     push @items, $item;
1438     $pos++;
1439   }
1440   $order->add_items(grep {!$_->id} @items);
1441
1442   return $order;
1443 }
1444
1445 # create or update items from form
1446 #
1447 # Make item objects from form values. For items already existing read from db.
1448 # Create a new item else. And assign attributes.
1449 sub make_item {
1450   my ($record, $attr) = @_;
1451
1452   my $item;
1453   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1454
1455   my $is_new = !$item;
1456
1457   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1458   # they cannot be retrieved via custom_variables until the order/orderitem is
1459   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1460   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1461
1462   $item->assign_attributes(%$attr);
1463   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1464   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1465   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1466
1467   return $item;
1468 }
1469
1470 # create a new item
1471 #
1472 # This is used to add one item
1473 sub new_item {
1474   my ($record, $attr) = @_;
1475
1476   my $item = SL::DB::OrderItem->new;
1477
1478   # Remove attributes where the user left or set the inputs empty.
1479   # So these attributes will be undefined and we can distinguish them
1480   # from zero later on.
1481   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1482     delete $attr->{$_} if $attr->{$_} eq '';
1483   }
1484
1485   $item->assign_attributes(%$attr);
1486
1487   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1488   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1489
1490   $item->unit($part->unit) if !$item->unit;
1491
1492   my $price_src;
1493   if ( $part->is_assortment ) {
1494     # add assortment items with price 0, as the components carry the price
1495     $price_src = $price_source->price_from_source("");
1496     $price_src->price(0);
1497   } elsif (defined $item->sellprice) {
1498     $price_src = $price_source->price_from_source("");
1499     $price_src->price($item->sellprice);
1500   } else {
1501     $price_src = $price_source->best_price
1502                ? $price_source->best_price
1503                : $price_source->price_from_source("");
1504     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1505     $price_src->price(0) if !$price_source->best_price;
1506   }
1507
1508   my $discount_src;
1509   if (defined $item->discount) {
1510     $discount_src = $price_source->discount_from_source("");
1511     $discount_src->discount($item->discount);
1512   } else {
1513     $discount_src = $price_source->best_discount
1514                   ? $price_source->best_discount
1515                   : $price_source->discount_from_source("");
1516     $discount_src->discount(0) if !$price_source->best_discount;
1517   }
1518
1519   my %new_attr;
1520   $new_attr{part}                   = $part;
1521   $new_attr{description}            = $part->description     if ! $item->description;
1522   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1523   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1524   $new_attr{sellprice}              = $price_src->price;
1525   $new_attr{discount}               = $discount_src->discount;
1526   $new_attr{active_price_source}    = $price_src;
1527   $new_attr{active_discount_source} = $discount_src;
1528   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1529   $new_attr{project_id}             = $record->globalproject_id;
1530   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1531
1532   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1533   # they cannot be retrieved via custom_variables until the order/orderitem is
1534   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1535   $new_attr{custom_variables} = [];
1536
1537   $item->assign_attributes(%new_attr);
1538
1539   return $item;
1540 }
1541
1542 sub setup_order_from_cv {
1543   my ($order) = @_;
1544
1545   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1546
1547   $order->intnotes($order->customervendor->notes);
1548
1549   if ($order->is_sales) {
1550     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1551     $order->taxincluded(defined($order->customer->taxincluded_checked)
1552                         ? $order->customer->taxincluded_checked
1553                         : $::myconfig{taxincluded_checked});
1554   }
1555
1556 }
1557
1558 # setup custom shipto from form
1559 #
1560 # The dialog returns form variables starting with 'shipto' and cvars starting
1561 # with 'shiptocvar_'.
1562 # Mark it to be deleted if a shipto from master data is selected
1563 # (i.e. order has a shipto).
1564 # Else, update or create a new custom shipto. If the fields are empty, it
1565 # will not be saved on save.
1566 sub setup_custom_shipto_from_form {
1567   my ($self, $order, $form) = @_;
1568
1569   if ($order->shipto) {
1570     $self->is_custom_shipto_to_delete(1);
1571   } else {
1572     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1573
1574     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1575     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1576
1577     $custom_shipto->assign_attributes(%$shipto_attrs);
1578     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1579   }
1580 }
1581
1582 # recalculate prices and taxes
1583 #
1584 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1585 sub recalc {
1586   my ($self) = @_;
1587
1588   my %pat = $self->order->calculate_prices_and_taxes();
1589
1590   $self->{taxes} = [];
1591   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1592     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1593
1594     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1595                                 netamount => $netamount,
1596                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1597   }
1598   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1599 }
1600
1601 # get data for saving, printing, ..., that is not changed in the form
1602 #
1603 # Only cvars for now.
1604 sub get_unalterable_data {
1605   my ($self) = @_;
1606
1607   foreach my $item (@{ $self->order->items }) {
1608     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1609     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1610     foreach my $var (@{ $item->cvars_by_config }) {
1611       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1612     }
1613     $item->parse_custom_variable_values;
1614   }
1615 }
1616
1617 # delete the order
1618 #
1619 # And remove related files in the spool directory
1620 sub delete {
1621   my ($self) = @_;
1622
1623   my $errors = [];
1624   my $db     = $self->order->db;
1625
1626   $db->with_transaction(
1627     sub {
1628       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1629       $self->order->delete;
1630       my $spool = $::lx_office_conf{paths}->{spool};
1631       unlink map { "$spool/$_" } @spoolfiles if $spool;
1632
1633       1;
1634   }) || push(@{$errors}, $db->error);
1635
1636   return $errors;
1637 }
1638
1639 # save the order
1640 #
1641 # And delete items that are deleted in the form.
1642 sub save {
1643   my ($self) = @_;
1644
1645   my $errors = [];
1646   my $db     = $self->order->db;
1647
1648   $db->with_transaction(sub {
1649     # delete custom shipto if it is to be deleted or if it is empty
1650     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1651       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1652       $self->order->custom_shipto(undef);
1653     }
1654
1655     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1656     $self->order->save(cascade => 1);
1657
1658     # link records
1659     if ($::form->{converted_from_oe_id}) {
1660       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1661       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1662         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1663         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1664         $src->link_to_record($self->order);
1665       }
1666       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1667         my $idx = 0;
1668         foreach (@{ $self->order->items_sorted }) {
1669           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1670           next if !$from_id;
1671           SL::DB::RecordLink->new(from_table => 'orderitems',
1672                                   from_id    => $from_id,
1673                                   to_table   => 'orderitems',
1674                                   to_id      => $_->id
1675           )->save;
1676           $idx++;
1677         }
1678       }
1679     }
1680     1;
1681   }) || push(@{$errors}, $db->error);
1682
1683   return $errors;
1684 }
1685
1686 sub workflow_sales_or_purchase_order {
1687   my ($self) = @_;
1688
1689   # always save
1690   my $errors = $self->save();
1691
1692   if (scalar @{ $errors }) {
1693     $self->js->flash('error', $_) foreach @{ $errors };
1694     return $self->js->render();
1695   }
1696
1697   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1698                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1699                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1700                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1701                        : '';
1702
1703   # check for direct delivery
1704   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1705   my $custom_shipto;
1706   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1707       && $::form->{use_shipto} && $self->order->shipto) {
1708     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1709   }
1710
1711   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1712   $self->{converted_from_oe_id} = delete $::form->{id};
1713
1714   # set item ids to new fake id, to identify them as new items
1715   foreach my $item (@{$self->order->items_sorted}) {
1716     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1717   }
1718
1719   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1720     if ($::form->{use_shipto}) {
1721       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1722     } else {
1723       # remove any custom shipto if not wanted
1724       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1725     }
1726   }
1727
1728   # change form type
1729   $::form->{type} = $destination_type;
1730   $self->type($self->init_type);
1731   $self->cv  ($self->init_cv);
1732   $self->check_auth;
1733
1734   $self->recalc();
1735   $self->get_unalterable_data();
1736   $self->pre_render();
1737
1738   # trigger rendering values for second row/longdescription as hidden,
1739   # because they are loaded only on demand. So we need to keep the values
1740   # from the source.
1741   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1742   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1743
1744   $self->render(
1745     'order/form',
1746     title => $self->get_title_for('edit'),
1747     %{$self->{template_args}}
1748   );
1749 }
1750
1751
1752 sub pre_render {
1753   my ($self) = @_;
1754
1755   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1756   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1757   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1758   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1759                                                                                               deleted => 0 ] ],
1760                                                                            sort_by => 'name');
1761   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1762                                                                                               deleted => 0 ] ],
1763                                                                            sort_by => 'name');
1764   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1765                                                                                                         obsolete => 0 ] ]);
1766   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1767   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1768   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1769   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1770   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1771
1772   my $print_form = Form->new('');
1773   $print_form->{type}        = $self->type;
1774   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1775   $print_form->{languages}   = SL::DB::Manager::Language->get_all_sorted;
1776   $print_form->{language_id} = $self->order->language_id;
1777   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1778     form => $print_form,
1779     options => {dialog_name_prefix => 'print_options.',
1780                 show_headers       => 1,
1781                 no_queue           => 1,
1782                 no_postscript      => 1,
1783                 no_opendocument    => 0,
1784                 no_html            => 1},
1785   );
1786
1787   foreach my $item (@{$self->order->orderitems}) {
1788     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1789     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1790     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1791   }
1792
1793   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1794     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1795     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1796   }
1797
1798   if ($self->order->number && $::instance_conf->get_webdav) {
1799     my $webdav = SL::Webdav->new(
1800       type     => $self->type,
1801       number   => $self->order->number,
1802     );
1803     my @all_objects = $webdav->get_all_objects;
1804     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1805                                                     type => t8('File'),
1806                                                     link => File::Spec->catfile($_->full_filedescriptor),
1807                                                 } } @all_objects;
1808   }
1809
1810   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1811
1812   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1813                                                          edit_periodic_invoices_config calculate_qty kivi.Validator);
1814   $self->setup_edit_action_bar;
1815 }
1816
1817 sub setup_edit_action_bar {
1818   my ($self, %params) = @_;
1819
1820   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1821                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1822                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1823
1824   for my $bar ($::request->layout->get('actionbar')) {
1825     $bar->add(
1826       combobox => [
1827         action => [
1828           t8('Save'),
1829           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1830                                                     $::instance_conf->get_order_warn_no_deliverydate,
1831                                                                                                       ],
1832           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1833         ],
1834         action => [
1835           t8('Save as new'),
1836           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1837           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1838           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1839         ],
1840       ], # end of combobox "Save"
1841
1842       combobox => [
1843         action => [
1844           t8('Workflow'),
1845         ],
1846         action => [
1847           t8('Save and Sales Order'),
1848           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1849           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1850         ],
1851         action => [
1852           t8('Save and Purchase Order'),
1853           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1854           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1855         ],
1856         action => [
1857           t8('Save and Delivery Order'),
1858           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1859                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1860                                                                                                                         ],
1861           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1862           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1863         ],
1864         action => [
1865           t8('Save and Invoice'),
1866           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1867           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1868         ],
1869         action => [
1870           t8('Save and AP Transaction'),
1871           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1872           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1873         ],
1874
1875       ], # end of combobox "Workflow"
1876
1877       combobox => [
1878         action => [
1879           t8('Export'),
1880         ],
1881         action => [
1882           t8('Save and print'),
1883           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1884         ],
1885         action => [
1886           t8('Save and E-mail'),
1887           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts ],
1888         ],
1889         action => [
1890           t8('Download attachments of all parts'),
1891           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1892           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1893           only_if  => $::instance_conf->get_doc_storage,
1894         ],
1895       ], # end of combobox "Export"
1896
1897       action => [
1898         t8('Delete'),
1899         call     => [ 'kivi.Order.delete_order' ],
1900         confirm  => $::locale->text('Do you really want to delete this object?'),
1901         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1902         only_if  => $deletion_allowed,
1903       ],
1904     );
1905   }
1906 }
1907
1908 sub generate_pdf {
1909   my ($order, $pdf_ref, $params) = @_;
1910
1911   my @errors = ();
1912
1913   my $print_form = Form->new('');
1914   $print_form->{type}        = $order->type;
1915   $print_form->{formname}    = $params->{formname} || $order->type;
1916   $print_form->{format}      = $params->{format}   || 'pdf';
1917   $print_form->{media}       = $params->{media}    || 'file';
1918   $print_form->{groupitems}  = $params->{groupitems};
1919   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1920
1921   $order->language($params->{language});
1922   $order->flatten_to_form($print_form, format_amounts => 1);
1923
1924   my $template_ext;
1925   my $template_type;
1926   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1927     $template_ext  = 'odt';
1928     $template_type = 'OpenDocument';
1929   }
1930
1931   # search for the template
1932   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1933     name        => $print_form->{formname},
1934     extension   => $template_ext,
1935     email       => $print_form->{media} eq 'email',
1936     language    => $params->{language},
1937     printer_id  => $print_form->{printer_id},  # todo
1938   );
1939
1940   if (!defined $template_file) {
1941     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1942   }
1943
1944   return @errors if scalar @errors;
1945
1946   $print_form->throw_on_error(sub {
1947     eval {
1948       $print_form->prepare_for_printing;
1949
1950       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1951         format        => $print_form->{format},
1952         template_type => $template_type,
1953         template      => $template_file,
1954         variables     => $print_form,
1955         variable_content_types => {
1956           longdescription => 'html',
1957           partnotes       => 'html',
1958           notes           => 'html',
1959         },
1960       );
1961       1;
1962     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1963   });
1964
1965   return @errors;
1966 }
1967
1968 sub get_files_for_email_dialog {
1969   my ($self) = @_;
1970
1971   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1972
1973   return %files if !$::instance_conf->get_doc_storage;
1974
1975   if ($self->order->id) {
1976     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1977     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1978     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1979   }
1980
1981   my @parts =
1982     uniq_by { $_->{id} }
1983     map {
1984       +{ id         => $_->part->id,
1985          partnumber => $_->part->partnumber }
1986     } @{$self->order->items_sorted};
1987
1988   foreach my $part (@parts) {
1989     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1990     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1991   }
1992
1993   foreach my $key (keys %files) {
1994     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1995   }
1996
1997   return %files;
1998 }
1999
2000 sub make_periodic_invoices_config_from_yaml {
2001   my ($yaml_config) = @_;
2002
2003   return if !$yaml_config;
2004   my $attr = SL::YAML::Load($yaml_config);
2005   return if 'HASH' ne ref $attr;
2006   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2007 }
2008
2009
2010 sub get_periodic_invoices_status {
2011   my ($self, $config) = @_;
2012
2013   return                      if $self->type ne sales_order_type();
2014   return t8('not configured') if !$config;
2015
2016   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2017              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2018              :                                                     die "Cannot get status of periodic invoices config";
2019
2020   return $active ? t8('active') : t8('inactive');
2021 }
2022
2023 sub get_title_for {
2024   my ($self, $action) = @_;
2025
2026   return '' if none { lc($action)} qw(add edit);
2027
2028   # for locales:
2029   # $::locale->text("Add Sales Order");
2030   # $::locale->text("Add Purchase Order");
2031   # $::locale->text("Add Quotation");
2032   # $::locale->text("Add Request for Quotation");
2033   # $::locale->text("Edit Sales Order");
2034   # $::locale->text("Edit Purchase Order");
2035   # $::locale->text("Edit Quotation");
2036   # $::locale->text("Edit Request for Quotation");
2037
2038   $action = ucfirst(lc($action));
2039   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2040        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2041        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2042        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2043        : '';
2044 }
2045
2046 sub get_item_cvpartnumber {
2047   my ($self, $item) = @_;
2048
2049   return if !$self->search_cvpartnumber;
2050   return if !$self->order->customervendor;
2051
2052   if ($self->cv eq 'vendor') {
2053     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2054     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2055   } elsif ($self->cv eq 'customer') {
2056     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2057     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2058   }
2059 }
2060
2061 sub sales_order_type {
2062   'sales_order';
2063 }
2064
2065 sub purchase_order_type {
2066   'purchase_order';
2067 }
2068
2069 sub sales_quotation_type {
2070   'sales_quotation';
2071 }
2072
2073 sub request_quotation_type {
2074   'request_quotation';
2075 }
2076
2077 sub nr_key {
2078   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2079        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2080        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2081        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2082        : '';
2083 }
2084
2085 1;
2086
2087 __END__
2088
2089 =encoding utf-8
2090
2091 =head1 NAME
2092
2093 SL::Controller::Order - controller for orders
2094
2095 =head1 SYNOPSIS
2096
2097 This is a new form to enter orders, completely rewritten with the use
2098 of controller and java script techniques.
2099
2100 The aim is to provide the user a better experience and a faster workflow. Also
2101 the code should be more readable, more reliable and better to maintain.
2102
2103 =head2 Key Features
2104
2105 =over 4
2106
2107 =item *
2108
2109 One input row, so that input happens every time at the same place.
2110
2111 =item *
2112
2113 Use of pickers where possible.
2114
2115 =item *
2116
2117 Possibility to enter more than one item at once.
2118
2119 =item *
2120
2121 Item list in a scrollable area, so that the workflow buttons stay at
2122 the bottom.
2123
2124 =item *
2125
2126 Reordering item rows with drag and drop is possible. Sorting item rows is
2127 possible (by partnumber, description, qty, sellprice and discount for now).
2128
2129 =item *
2130
2131 No C<update> is necessary. All entries and calculations are managed
2132 with ajax-calls and the page only reloads on C<save>.
2133
2134 =item *
2135
2136 User can see changes immediately, because of the use of java script
2137 and ajax.
2138
2139 =back
2140
2141 =head1 CODE
2142
2143 =head2 Layout
2144
2145 =over 4
2146
2147 =item * C<SL/Controller/Order.pm>
2148
2149 the controller
2150
2151 =item * C<template/webpages/order/form.html>
2152
2153 main form
2154
2155 =item * C<template/webpages/order/tabs/basic_data.html>
2156
2157 Main tab for basic_data.
2158
2159 This is the only tab here for now. "linked records" and "webdav" tabs are
2160 reused from generic code.
2161
2162 =over 4
2163
2164 =item * C<template/webpages/order/tabs/_business_info_row.html>
2165
2166 For displaying information on business type
2167
2168 =item * C<template/webpages/order/tabs/_item_input.html>
2169
2170 The input line for items
2171
2172 =item * C<template/webpages/order/tabs/_row.html>
2173
2174 One row for already entered items
2175
2176 =item * C<template/webpages/order/tabs/_tax_row.html>
2177
2178 Displaying tax information
2179
2180 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
2181
2182 Dialog for entering more than one item at once
2183
2184 =item * C<template/webpages/order/tabs/_multi_items_result.html>
2185
2186 Results for the filter in the multi items dialog
2187
2188 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2189
2190 Dialog for selecting price and discount sources
2191
2192 =back
2193
2194 =item * C<js/kivi.Order.js>
2195
2196 java script functions
2197
2198 =back
2199
2200 =head1 TODO
2201
2202 =over 4
2203
2204 =item * testing
2205
2206 =item * credit limit
2207
2208 =item * more workflows (quotation, rfq)
2209
2210 =item * price sources: little symbols showing better price / better discount
2211
2212 =item * select units in input row?
2213
2214 =item * check for direct delivery (workflow sales order -> purchase order)
2215
2216 =item * language / part translations
2217
2218 =item * access rights
2219
2220 =item * display weights
2221
2222 =item * history
2223
2224 =item * mtime check
2225
2226 =item * optional client/user behaviour
2227
2228 (transactions has to be set - department has to be set -
2229  force project if enabled in client config - transport cost reminder)
2230
2231 =back
2232
2233 =head1 KNOWN BUGS AND CAVEATS
2234
2235 =over 4
2236
2237 =item *
2238
2239 Customer discount is not displayed as a valid discount in price source popup
2240 (this might be a bug in price sources)
2241
2242 (I cannot reproduce this (Bernd))
2243
2244 =item *
2245
2246 No indication that <shift>-up/down expands/collapses second row.
2247
2248 =item *
2249
2250 Inline creation of parts is not currently supported
2251
2252 =item *
2253
2254 Table header is not sticky in the scrolling area.
2255
2256 =item *
2257
2258 Sorting does not include C<position>, neither does reordering.
2259
2260 This behavior was implemented intentionally. But we can discuss, which behavior
2261 should be implemented.
2262
2263 =item *
2264
2265 C<show_multi_items_dialog> does not use the currently inserted string for
2266 filtering.
2267
2268 =back
2269
2270 =head1 To discuss / Nice to have
2271
2272 =over 4
2273
2274 =item *
2275
2276 How to expand/collapse second row. Now it can be done clicking the icon or
2277 <shift>-up/down.
2278
2279 =item *
2280
2281 Possibility to change longdescription in input row?
2282
2283 =item *
2284
2285 Possibility to select PriceSources in input row?
2286
2287 =item *
2288
2289 This controller uses a (changed) copy of the template for the PriceSource
2290 dialog. Maybe there could be used one code source.
2291
2292 =item *
2293
2294 Rounding-differences between this controller (PriceTaxCalculator) and the old
2295 form. This is not only a problem here, but also in all parts using the PTC.
2296 There exists a ticket and a patch. This patch should be testet.
2297
2298 =item *
2299
2300 An indicator, if the actual inputs are saved (like in an
2301 editor or on text processing application).
2302
2303 =item *
2304
2305 A warning when leaving the page without saveing unchanged inputs.
2306
2307
2308 =back
2309
2310 =head1 AUTHOR
2311
2312 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2313
2314 =cut