SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24 use SL::DB::Shipto;
  25 use SL::DB::Translation;
  26
  27 use SL::Helper::CreatePDF qw(:all);
  28 use SL::Helper::PrintOptions;
  29 use SL::Helper::ShippedQty;
  30 use SL::Helper::UserPreferences::PositionsScrollbar;
  31 use SL::Helper::UserPreferences::UpdatePositions;
  32
  33 use SL::Controller::Helper::GetModels;
  34
  35 use List::Util qw(first sum0);
  36 use List::UtilsBy qw(sort_by uniq_by);
  37 use List::MoreUtils qw(any none pairwise first_index);
  38 use English qw(-no_match_vars);
  39 use File::Spec;
  40 use Cwd;
  41 use Sort::Naturally;
  42
  43 use Rose::Object::MakeMethods::Generic
  44 (
  45  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  46  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button) ],
  47 );
  48
  49
  50 # safety
  51 __PACKAGE__->run_before('check_auth');
  52
  53 __PACKAGE__->run_before('recalc',
  54                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  55                                      print send_email) ]);
  56
  57 __PACKAGE__->run_before('get_unalterable_data',
  58                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  59                                      print send_email) ]);
  60
  61 #
  62 # actions
  63 #
  64
  65 # add a new order
  66 sub action_add {
  67   my ($self) = @_;
  68
  69   $self->order->transdate(DateTime->now_local());
  70   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  71                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  72   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  73
  74
  75   $self->pre_render();
  76   $self->render(
  77     'order/form',
  78     title => $self->get_title_for('add'),
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 # edit an existing order
  84 sub action_edit {
  85   my ($self) = @_;
  86
  87   if ($::form->{id}) {
  88     $self->load_order;
  89
  90   } else {
  91     # this is to edit an order from an unsaved order object
  92
  93     # set item ids to new fake id, to identify them as new items
  94     foreach my $item (@{$self->order->items_sorted}) {
  95       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  96     }
  97     # trigger rendering values for second row as hidden, because they
  98     # are loaded only on demand. So we need to keep the values from
  99     # the source.
 100     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 101   }
 102
 103   $self->recalc();
 104   $self->pre_render();
 105   $self->render(
 106     'order/form',
 107     title => $self->get_title_for('edit'),
 108     %{$self->{template_args}}
 109   );
 110 }
 111
 112 # edit a collective order (consisting of one or more existing orders)
 113 sub action_edit_collective {
 114   my ($self) = @_;
 115
 116   # collect order ids
 117   my @multi_ids = map {
 118     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 119   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 120
 121   # fall back to add if no ids are given
 122   if (scalar @multi_ids == 0) {
 123     $self->action_add();
 124     return;
 125   }
 126
 127   # fall back to save as new if only one id is given
 128   if (scalar @multi_ids == 1) {
 129     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 130     $self->action_save_as_new();
 131     return;
 132   }
 133
 134   # make new order from given orders
 135   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 136   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 137   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 138
 139   $self->action_edit();
 140 }
 141
 142 # delete the order
 143 sub action_delete {
 144   my ($self) = @_;
 145
 146   my $errors = $self->delete();
 147
 148   if (scalar @{ $errors }) {
 149     $self->js->flash('error', $_) foreach @{ $errors };
 150     return $self->js->render();
 151   }
 152
 153   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 154            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 155            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 156            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 157            : '';
 158   flash_later('info', $text);
 159
 160   my @redirect_params = (
 161     action => 'add',
 162     type   => $self->type,
 163   );
 164
 165   $self->redirect_to(@redirect_params);
 166 }
 167
 168 # save the order
 169 sub action_save {
 170   my ($self) = @_;
 171
 172   my $errors = $self->save();
 173
 174   if (scalar @{ $errors }) {
 175     $self->js->flash('error', $_) foreach @{ $errors };
 176     return $self->js->render();
 177   }
 178
 179   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 180            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 181            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 182            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 183            : '';
 184   flash_later('info', $text);
 185
 186   my @redirect_params = (
 187     action => 'edit',
 188     type   => $self->type,
 189     id     => $self->order->id,
 190   );
 191
 192   $self->redirect_to(@redirect_params);
 193 }
 194
 195 # save the order as new document an open it for edit
 196 sub action_save_as_new {
 197   my ($self) = @_;
 198
 199   my $order = $self->order;
 200
 201   if (!$order->id) {
 202     $self->js->flash('error', t8('This object has not been saved yet.'));
 203     return $self->js->render();
 204   }
 205
 206   # load order from db to check if values changed
 207   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 208
 209   my %new_attrs;
 210   # Lets assign a new number if the user hasn't changed the previous one.
 211   # If it has been changed manually then use it as-is.
 212   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 213                         ? ''
 214                         : trim($order->number);
 215
 216   # Clear transdate unless changed
 217   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 218                         ? DateTime->today_local
 219                         : $order->transdate;
 220
 221   # Set new reqdate unless changed
 222   if ($order->reqdate == $saved_order->reqdate) {
 223     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 224                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 225     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 226   } else {
 227     $new_attrs{reqdate} = $order->reqdate;
 228   }
 229
 230   # Update employee
 231   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 232
 233   # Create new record from current one
 234   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 235
 236   # no linked records on save as new
 237   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 238
 239   # save
 240   $self->action_save();
 241 }
 242
 243 # print the order
 244 #
 245 # This is called if "print" is pressed in the print dialog.
 246 # If PDF creation was requested and succeeded, the pdf is offered for download
 247 # via send_file (which uses ajax in this case).
 248 sub action_print {
 249   my ($self) = @_;
 250
 251   my $errors = $self->save();
 252
 253   if (scalar @{ $errors }) {
 254     $self->js->flash('error', $_) foreach @{ $errors };
 255     return $self->js->render();
 256   }
 257
 258   $self->js_reset_order_and_item_ids_after_save;
 259
 260   my $format      = $::form->{print_options}->{format};
 261   my $media       = $::form->{print_options}->{media};
 262   my $formname    = $::form->{print_options}->{formname};
 263   my $copies      = $::form->{print_options}->{copies};
 264   my $groupitems  = $::form->{print_options}->{groupitems};
 265   my $printer_id  = $::form->{print_options}->{printer_id};
 266
 267   # only pdf and opendocument by now
 268   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 269     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 270   }
 271
 272   # only screen or printer by now
 273   if (none { $media eq $_ } qw(screen printer)) {
 274     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 275   }
 276
 277   # create a form for generate_attachment_filename
 278   my $form   = Form->new;
 279   $form->{$self->nr_key()}  = $self->order->number;
 280   $form->{type}             = $self->type;
 281   $form->{format}           = $format;
 282   $form->{formname}         = $formname;
 283   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 284   my $pdf_filename          = $form->generate_attachment_filename();
 285
 286   my $pdf;
 287   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 288                                                    formname   => $formname,
 289                                                    language   => $self->order->language,
 290                                                    printer_id => $printer_id,
 291                                                    groupitems => $groupitems });
 292   if (scalar @errors) {
 293     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 294   }
 295
 296   if ($media eq 'screen') {
 297     # screen/download
 298     $self->js->flash('info', t8('The PDF has been created'));
 299     $self->send_file(
 300       \$pdf,
 301       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 302       name         => $pdf_filename,
 303       js_no_render => 1,
 304     );
 305
 306   } elsif ($media eq 'printer') {
 307     # printer
 308     my $printer_id = $::form->{print_options}->{printer_id};
 309     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 310       copies  => $copies,
 311       content => $pdf,
 312     );
 313
 314     $self->js->flash('info', t8('The PDF has been printed'));
 315   }
 316
 317   # copy file to webdav folder
 318   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 319     my $webdav = SL::Webdav->new(
 320       type     => $self->type,
 321       number   => $self->order->number,
 322     );
 323     my $webdav_file = SL::Webdav::File->new(
 324       webdav   => $webdav,
 325       filename => $pdf_filename,
 326     );
 327     eval {
 328       $webdav_file->store(data => \$pdf);
 329       1;
 330     } or do {
 331       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 332     }
 333   }
 334   if ($self->order->number && $::instance_conf->get_doc_storage) {
 335     eval {
 336       SL::File->save(object_id     => $self->order->id,
 337                      object_type   => $self->type,
 338                      mime_type     => 'application/pdf',
 339                      source        => 'created',
 340                      file_type     => 'document',
 341                      file_name     => $pdf_filename,
 342                      file_contents => $pdf);
 343       1;
 344     } or do {
 345       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 346     }
 347   }
 348   $self->js->render;
 349 }
 350
 351 # open the email dialog
 352 sub action_save_and_show_email_dialog {
 353   my ($self) = @_;
 354
 355   my $errors = $self->save();
 356
 357   if (scalar @{ $errors }) {
 358     $self->js->flash('error', $_) foreach @{ $errors };
 359     return $self->js->render();
 360   }
 361
 362   my $cv_method = $self->cv;
 363
 364   if (!$self->order->$cv_method) {
 365     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 366                     ->render($self);
 367   }
 368
 369   my $email_form;
 370   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 371   $email_form->{to} ||= $self->order->$cv_method->email;
 372   $email_form->{cc}   = $self->order->$cv_method->cc;
 373   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 374   # Todo: get addresses from shipto, if any
 375
 376   my $form = Form->new;
 377   $form->{$self->nr_key()}  = $self->order->number;
 378   $form->{cusordnumber}     = $self->order->cusordnumber;
 379   $form->{formname}         = $self->type;
 380   $form->{type}             = $self->type;
 381   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 382   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 383   $form->{format}           = 'pdf';
 384
 385   $email_form->{subject}             = $form->generate_email_subject();
 386   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 387   $email_form->{message}             = $form->generate_email_body();
 388   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 389
 390   my %files = $self->get_files_for_email_dialog();
 391   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 392                                   email_form  => $email_form,
 393                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 394                                   FILES       => \%files,
 395                                   is_customer => $self->cv eq 'customer',
 396   );
 397
 398   $self->js
 399       ->run('kivi.Order.show_email_dialog', $dialog_html)
 400       ->reinit_widgets
 401       ->render($self);
 402 }
 403
 404 # send email
 405 #
 406 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 407 sub action_send_email {
 408   my ($self) = @_;
 409
 410   my $errors = $self->save();
 411
 412   if (scalar @{ $errors }) {
 413     $self->js->run('kivi.Order.close_email_dialog');
 414     $self->js->flash('error', $_) foreach @{ $errors };
 415     return $self->js->render();
 416   }
 417
 418   $self->js_reset_order_and_item_ids_after_save;
 419
 420   my $email_form  = delete $::form->{email_form};
 421   my %field_names = (to => 'email');
 422
 423   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 424
 425   # for Form::cleanup which may be called in Form::send_email
 426   $::form->{cwd}    = getcwd();
 427   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 428
 429   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 430   $::form->{media}  = 'email';
 431
 432   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 433     my $pdf;
 434     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 435                                                     format     => $::form->{print_options}->{format},
 436                                                     formname   => $::form->{print_options}->{formname},
 437                                                     language   => $self->order->language,
 438                                                     printer_id => $::form->{print_options}->{printer_id},
 439                                                     groupitems => $::form->{print_options}->{groupitems}});
 440     if (scalar @errors) {
 441       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 442     }
 443
 444     my $sfile = SL::SessionFile::Random->new(mode => "w");
 445     $sfile->fh->print($pdf);
 446     $sfile->fh->close;
 447
 448     $::form->{tmpfile} = $sfile->file_name;
 449     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 450   }
 451
 452   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 453   $::form->send_email(\%::myconfig, 'pdf');
 454
 455   # internal notes
 456   my $intnotes = $self->order->intnotes;
 457   $intnotes   .= "\n\n" if $self->order->intnotes;
 458   $intnotes   .= t8('[email]')                                                                                        . "\n";
 459   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 460   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 461   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 462   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 463   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 464   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 465
 466   $self->order->update_attributes(intnotes => $intnotes);
 467
 468   flash_later('info', t8('The email has been sent.'));
 469
 470   my @redirect_params = (
 471     action => 'edit',
 472     type   => $self->type,
 473     id     => $self->order->id,
 474   );
 475
 476   $self->redirect_to(@redirect_params);
 477 }
 478
 479 # open the periodic invoices config dialog
 480 #
 481 # If there are values in the form (i.e. dialog was opened before),
 482 # then use this values. Create new ones, else.
 483 sub action_show_periodic_invoices_config_dialog {
 484   my ($self) = @_;
 485
 486   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 487   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 488   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 489                                                    order_value_periodicity => 'p', # = same as periodicity
 490                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 491                                                    extend_automatically_by => 12,
 492                                                    active                  => 1,
 493                                                    email_subject           => GenericTranslations->get(
 494                                                                                 language_id      => $::form->{language_id},
 495                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 496                                                    email_body              => GenericTranslations->get(
 497                                                                                 language_id      => $::form->{language_id},
 498                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 499   );
 500   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 501   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 502
 503   $::form->get_lists(printers => "ALL_PRINTERS",
 504                      charts   => { key       => 'ALL_CHARTS',
 505                                    transdate => 'current_date' });
 506
 507   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 508
 509   if ($::form->{customer_id}) {
 510     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 511     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 512   }
 513
 514   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 515                 popup_dialog             => 1,
 516                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 517                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 518                 config                   => $config,
 519                 %$::form);
 520 }
 521
 522 # assign the values of the periodic invoices config dialog
 523 # as yaml in the hidden tag and set the status.
 524 sub action_assign_periodic_invoices_config {
 525   my ($self) = @_;
 526
 527   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 528
 529   my $config = { active                     => $::form->{active}       ? 1 : 0,
 530                  terminated                 => $::form->{terminated}   ? 1 : 0,
 531                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 532                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 533                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 534                  start_date_as_date         => $::form->{start_date_as_date},
 535                  end_date_as_date           => $::form->{end_date_as_date},
 536                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 537                  print                      => $::form->{print}      ? 1                         : 0,
 538                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 539                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 540                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 541                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 542                  send_email                 => $::form->{send_email} ? 1 : 0,
 543                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 544                  email_recipient_address    => $::form->{email_recipient_address},
 545                  email_sender               => $::form->{email_sender},
 546                  email_subject              => $::form->{email_subject},
 547                  email_body                 => $::form->{email_body},
 548                };
 549
 550   my $periodic_invoices_config = SL::YAML::Dump($config);
 551
 552   my $status = $self->get_periodic_invoices_status($config);
 553
 554   $self->js
 555     ->remove('#order_periodic_invoices_config')
 556     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 557     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 558     ->html('#periodic_invoices_status', $status)
 559     ->flash('info', t8('The periodic invoices config has been assigned.'))
 560     ->render($self);
 561 }
 562
 563 sub action_get_has_active_periodic_invoices {
 564   my ($self) = @_;
 565
 566   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 567   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 568
 569   my $has_active_periodic_invoices =
 570        $self->type eq sales_order_type()
 571     && $config
 572     && $config->active
 573     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 574     && $config->get_previous_billed_period_start_date;
 575
 576   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 577 }
 578
 579 # save the order and redirect to the frontend subroutine for a new
 580 # delivery order
 581 sub action_save_and_delivery_order {
 582   my ($self) = @_;
 583
 584   $self->save_and_redirect_to(
 585     controller => 'oe.pl',
 586     action     => 'oe_delivery_order_from_order',
 587   );
 588 }
 589
 590 # save the order and redirect to the frontend subroutine for a new
 591 # invoice
 592 sub action_save_and_invoice {
 593   my ($self) = @_;
 594
 595   $self->save_and_redirect_to(
 596     controller => 'oe.pl',
 597     action     => 'oe_invoice_from_order',
 598   );
 599 }
 600
 601 # workflow from sales order to sales quotation
 602 sub action_sales_quotation {
 603   $_[0]->workflow_sales_quotation();
 604 }
 605
 606 # workflow from sales quotation to sales order
 607 sub action_sales_order {
 608   $_[0]->workflow_sales_or_purchase_order();
 609 }
 610
 611 # workflow from rfq to purchase order
 612 sub action_purchase_order {
 613   $_[0]->workflow_sales_or_purchase_order();
 614 }
 615
 616 # workflow from purchase order to ap transaction
 617 sub action_save_and_ap_transaction {
 618   my ($self) = @_;
 619
 620   $self->save_and_redirect_to(
 621     controller => 'ap.pl',
 622     action     => 'add_from_purchase_order',
 623   );
 624 }
 625
 626 # set form elements in respect to a changed customer or vendor
 627 #
 628 # This action is called on an change of the customer/vendor picker.
 629 sub action_customer_vendor_changed {
 630   my ($self) = @_;
 631
 632   setup_order_from_cv($self->order);
 633   $self->recalc();
 634
 635   my $cv_method = $self->cv;
 636
 637   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 638     $self->js->show('#cp_row');
 639   } else {
 640     $self->js->hide('#cp_row');
 641   }
 642
 643   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 644     $self->js->show('#shipto_selection');
 645   } else {
 646     $self->js->hide('#shipto_selection');
 647   }
 648
 649   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 650
 651   $self->js
 652     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 653     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 654     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 655     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 656     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 657     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 658     ->val(        '#order_currency_id',      $self->order->currency_id)
 659     ->val(        '#order_payment_id',       $self->order->payment_id)
 660     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 661     ->val(        '#order_intnotes',         $self->order->intnotes)
 662     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 663     ->focus(      '#order_' . $self->cv . '_id')
 664     ->run('kivi.Order.update_exchangerate');
 665
 666   $self->js_redisplay_amounts_and_taxes;
 667   $self->js_redisplay_cvpartnumbers;
 668   $self->js->render();
 669 }
 670
 671 # open the dialog for customer/vendor details
 672 sub action_show_customer_vendor_details_dialog {
 673   my ($self) = @_;
 674
 675   my $is_customer = 'customer' eq $::form->{vc};
 676   my $cv;
 677   if ($is_customer) {
 678     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 679   } else {
 680     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 681   }
 682
 683   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 684   $details{discount_as_percent} = $cv->discount_as_percent;
 685   $details{creditlimt}          = $cv->creditlimit_as_number;
 686   $details{business}            = $cv->business->description      if $cv->business;
 687   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 688   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 689   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 690   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 691
 692   foreach my $entry (@{ $cv->shipto }) {
 693     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 694   }
 695   foreach my $entry (@{ $cv->contacts }) {
 696     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 697   }
 698
 699   $_[0]->render('common/show_vc_details', { layout => 0 },
 700                 is_customer => $is_customer,
 701                 %details);
 702
 703 }
 704
 705 # called if a unit in an existing item row is changed
 706 sub action_unit_changed {
 707   my ($self) = @_;
 708
 709   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 710   my $item = $self->order->items_sorted->[$idx];
 711
 712   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 713   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 714
 715   $self->recalc();
 716
 717   $self->js
 718     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 719   $self->js_redisplay_line_values;
 720   $self->js_redisplay_amounts_and_taxes;
 721   $self->js->render();
 722 }
 723
 724 # add an item row for a new item entered in the input row
 725 sub action_add_item {
 726   my ($self) = @_;
 727
 728   my $form_attr = $::form->{add_item};
 729
 730   return unless $form_attr->{parts_id};
 731
 732   my $item = new_item($self->order, $form_attr);
 733
 734   $self->order->add_items($item);
 735
 736   $self->recalc();
 737
 738   $self->get_item_cvpartnumber($item);
 739
 740   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 741   my $row_as_html = $self->p->render('order/tabs/_row',
 742                                      ITEM => $item,
 743                                      ID   => $item_id,
 744                                      SELF => $self,
 745   );
 746
 747   if ($::form->{insert_before_item_id}) {
 748     $self->js
 749       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 750   } else {
 751     $self->js
 752       ->append('#row_table_id', $row_as_html);
 753   }
 754
 755   if ( $item->part->is_assortment ) {
 756     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 757     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 758       my $attr = { parts_id => $assortment_item->parts_id,
 759                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 760                    unit     => $assortment_item->unit,
 761                    description => $assortment_item->part->description,
 762                  };
 763       my $item = new_item($self->order, $attr);
 764
 765       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 766       $item->discount(1) unless $assortment_item->charge;
 767
 768       $self->order->add_items( $item );
 769       $self->recalc();
 770       $self->get_item_cvpartnumber($item);
 771       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 772       my $row_as_html = $self->p->render('order/tabs/_row',
 773                                          ITEM => $item,
 774                                          ID   => $item_id,
 775                                          SELF => $self,
 776       );
 777       if ($::form->{insert_before_item_id}) {
 778         $self->js
 779           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 780       } else {
 781         $self->js
 782           ->append('#row_table_id', $row_as_html);
 783       }
 784     };
 785   };
 786
 787   $self->js
 788     ->val('.add_item_input', '')
 789     ->run('kivi.Order.init_row_handlers')
 790     ->run('kivi.Order.renumber_positions')
 791     ->focus('#add_item_parts_id_name');
 792
 793   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 794
 795   $self->js_redisplay_amounts_and_taxes;
 796   $self->js->render();
 797 }
 798
 799 # add item rows for multiple items at once
 800 sub action_add_multi_items {
 801   my ($self) = @_;
 802
 803   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 804   return $self->js->render() unless scalar @form_attr;
 805
 806   my @items;
 807   foreach my $attr (@form_attr) {
 808     my $item = new_item($self->order, $attr);
 809     push @items, $item;
 810     if ( $item->part->is_assortment ) {
 811       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 812         my $attr = { parts_id => $assortment_item->parts_id,
 813                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 814                      unit     => $assortment_item->unit,
 815                      description => $assortment_item->part->description,
 816                    };
 817         my $item = new_item($self->order, $attr);
 818
 819         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 820         $item->discount(1) unless $assortment_item->charge;
 821         push @items, $item;
 822       }
 823     }
 824   }
 825   $self->order->add_items(@items);
 826
 827   $self->recalc();
 828
 829   foreach my $item (@items) {
 830     $self->get_item_cvpartnumber($item);
 831     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 832     my $row_as_html = $self->p->render('order/tabs/_row',
 833                                        ITEM => $item,
 834                                        ID   => $item_id,
 835                                        SELF => $self,
 836     );
 837
 838     if ($::form->{insert_before_item_id}) {
 839       $self->js
 840         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 841     } else {
 842       $self->js
 843         ->append('#row_table_id', $row_as_html);
 844     }
 845   }
 846
 847   $self->js
 848     ->run('kivi.Part.close_picker_dialogs')
 849     ->run('kivi.Order.init_row_handlers')
 850     ->run('kivi.Order.renumber_positions')
 851     ->focus('#add_item_parts_id_name');
 852
 853   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 854
 855   $self->js_redisplay_amounts_and_taxes;
 856   $self->js->render();
 857 }
 858
 859 # recalculate all linetotals, amounts and taxes and redisplay them
 860 sub action_recalc_amounts_and_taxes {
 861   my ($self) = @_;
 862
 863   $self->recalc();
 864
 865   $self->js_redisplay_line_values;
 866   $self->js_redisplay_amounts_and_taxes;
 867   $self->js->render();
 868 }
 869
 870 sub action_update_exchangerate {
 871   my ($self) = @_;
 872
 873   my $data = {
 874     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 875     currency_name => $self->order->currency->name,
 876     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 877   };
 878
 879   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 880 }
 881
 882 # redisplay item rows if they are sorted by an attribute
 883 sub action_reorder_items {
 884   my ($self) = @_;
 885
 886   my %sort_keys = (
 887     partnumber   => sub { $_[0]->part->partnumber },
 888     description  => sub { $_[0]->description },
 889     qty          => sub { $_[0]->qty },
 890     sellprice    => sub { $_[0]->sellprice },
 891     discount     => sub { $_[0]->discount },
 892     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 893   );
 894
 895   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 896
 897   my $method = $sort_keys{$::form->{order_by}};
 898   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 899   if ($::form->{sort_dir}) {
 900     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 901       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 902     } else {
 903       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 904     }
 905   } else {
 906     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 907       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 908     } else {
 909       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 910     }
 911   }
 912   $self->js
 913     ->run('kivi.Order.redisplay_items', \@to_sort)
 914     ->render;
 915 }
 916
 917 # show the popup to choose a price/discount source
 918 sub action_price_popup {
 919   my ($self) = @_;
 920
 921   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 922   my $item = $self->order->items_sorted->[$idx];
 923
 924   $self->render_price_dialog($item);
 925 }
 926
 927 # load the second row for one or more items
 928 #
 929 # This action gets the html code for all items second rows by rendering a template for
 930 # the second row and sets the html code via client js.
 931 sub action_load_second_rows {
 932   my ($self) = @_;
 933
 934   $self->recalc() if $self->order->is_sales; # for margin calculation
 935
 936   foreach my $item_id (@{ $::form->{item_ids} }) {
 937     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 938     my $item = $self->order->items_sorted->[$idx];
 939
 940     $self->js_load_second_row($item, $item_id, 0);
 941   }
 942
 943   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 944
 945   $self->js->render();
 946 }
 947
 948 # update description, notes and sellprice from master data
 949 sub action_update_row_from_master_data {
 950   my ($self) = @_;
 951
 952   foreach my $item_id (@{ $::form->{item_ids} }) {
 953     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 954     my $item  = $self->order->items_sorted->[$idx];
 955     my $texts = get_part_texts($item->part, $self->order->language_id);
 956
 957     $item->description($texts->{description});
 958     $item->longdescription($texts->{longdescription});
 959
 960     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 961
 962     my $price_src;
 963     if ($item->part->is_assortment) {
 964     # add assortment items with price 0, as the components carry the price
 965       $price_src = $price_source->price_from_source("");
 966       $price_src->price(0);
 967     } else {
 968       $price_src = $price_source->best_price
 969                  ? $price_source->best_price
 970                  : $price_source->price_from_source("");
 971       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
 972       $price_src->price(0) if !$price_source->best_price;
 973     }
 974
 975
 976     $item->sellprice($price_src->price);
 977     $item->active_price_source($price_src);
 978
 979     $self->js
 980       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
 981       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
 982       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
 983       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
 984
 985     if ($self->search_cvpartnumber) {
 986       $self->get_item_cvpartnumber($item);
 987       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
 988     }
 989   }
 990
 991   $self->recalc();
 992   $self->js_redisplay_line_values;
 993   $self->js_redisplay_amounts_and_taxes;
 994
 995   $self->js->render();
 996 }
 997
 998 sub js_load_second_row {
 999   my ($self, $item, $item_id, $do_parse) = @_;
1000
1001   if ($do_parse) {
1002     # Parse values from form (they are formated while rendering (template)).
1003     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1004     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1005     foreach my $var (@{ $item->cvars_by_config }) {
1006       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1007     }
1008     $item->parse_custom_variable_values;
1009   }
1010
1011   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1012
1013   $self->js
1014     ->html('#second_row_' . $item_id, $row_as_html)
1015     ->data('#second_row_' . $item_id, 'loaded', 1);
1016 }
1017
1018 sub js_redisplay_line_values {
1019   my ($self) = @_;
1020
1021   my $is_sales = $self->order->is_sales;
1022
1023   # sales orders with margins
1024   my @data;
1025   if ($is_sales) {
1026     @data = map {
1027       [
1028        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1029        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1030        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1031       ]} @{ $self->order->items_sorted };
1032   } else {
1033     @data = map {
1034       [
1035        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1036       ]} @{ $self->order->items_sorted };
1037   }
1038
1039   $self->js
1040     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1041 }
1042
1043 sub js_redisplay_amounts_and_taxes {
1044   my ($self) = @_;
1045
1046   if (scalar @{ $self->{taxes} }) {
1047     $self->js->show('#taxincluded_row_id');
1048   } else {
1049     $self->js->hide('#taxincluded_row_id');
1050   }
1051
1052   if ($self->order->taxincluded) {
1053     $self->js->hide('#subtotal_row_id');
1054   } else {
1055     $self->js->show('#subtotal_row_id');
1056   }
1057
1058   if ($self->order->is_sales) {
1059     my $is_neg = $self->order->marge_total < 0;
1060     $self->js
1061       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1062       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1063       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1064       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1065       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1066       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1067       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1068       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1069   }
1070
1071   $self->js
1072     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1073     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1074     ->remove('.tax_row')
1075     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1076 }
1077
1078 sub js_redisplay_cvpartnumbers {
1079   my ($self) = @_;
1080
1081   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1082
1083   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1084
1085   $self->js
1086     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1087 }
1088
1089 sub js_reset_order_and_item_ids_after_save {
1090   my ($self) = @_;
1091
1092   $self->js
1093     ->val('#id', $self->order->id)
1094     ->val('#converted_from_oe_id', '')
1095     ->val('#order_' . $self->nr_key(), $self->order->number);
1096
1097   my $idx = 0;
1098   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1099     next if !$self->order->items_sorted->[$idx]->id;
1100     next if $form_item_id !~ m{^new};
1101     $self->js
1102       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1103       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1104       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1105   } continue {
1106     $idx++;
1107   }
1108   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1109 }
1110
1111 #
1112 # helpers
1113 #
1114
1115 sub init_valid_types {
1116   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1117 }
1118
1119 sub init_type {
1120   my ($self) = @_;
1121
1122   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1123     die "Not a valid type for order";
1124   }
1125
1126   $self->type($::form->{type});
1127 }
1128
1129 sub init_cv {
1130   my ($self) = @_;
1131
1132   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1133          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1134          : die "Not a valid type for order";
1135
1136   return $cv;
1137 }
1138
1139 sub init_search_cvpartnumber {
1140   my ($self) = @_;
1141
1142   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1143   my $search_cvpartnumber;
1144   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1145   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1146
1147   return $search_cvpartnumber;
1148 }
1149
1150 sub init_show_update_button {
1151   my ($self) = @_;
1152
1153   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1154 }
1155
1156 sub init_p {
1157   SL::Presenter->get;
1158 }
1159
1160 sub init_order {
1161   $_[0]->make_order;
1162 }
1163
1164 sub init_all_price_factors {
1165   SL::DB::Manager::PriceFactor->get_all;
1166 }
1167
1168 sub check_auth {
1169   my ($self) = @_;
1170
1171   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1172
1173   my $right   = $right_for->{ $self->type };
1174   $right    ||= 'DOES_NOT_EXIST';
1175
1176   $::auth->assert($right);
1177 }
1178
1179 # build the selection box for contacts
1180 #
1181 # Needed, if customer/vendor changed.
1182 sub build_contact_select {
1183   my ($self) = @_;
1184
1185   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1186     value_key  => 'cp_id',
1187     title_key  => 'full_name_dep',
1188     default    => $self->order->cp_id,
1189     with_empty => 1,
1190     style      => 'width: 300px',
1191   );
1192 }
1193
1194 # build the selection box for shiptos
1195 #
1196 # Needed, if customer/vendor changed.
1197 sub build_shipto_select {
1198   my ($self) = @_;
1199
1200   select_tag('order.shipto_id',
1201              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1202              value_key  => 'shipto_id',
1203              title_key  => 'displayable_id',
1204              default    => $self->order->shipto_id,
1205              with_empty => 0,
1206              style      => 'width: 300px',
1207   );
1208 }
1209
1210 # build the inputs for the cusom shipto dialog
1211 #
1212 # Needed, if customer/vendor changed.
1213 sub build_shipto_inputs {
1214   my ($self) = @_;
1215
1216   my $content = $self->p->render('common/_ship_to_dialog',
1217                                  vc_obj      => $self->order->customervendor,
1218                                  cs_obj      => $self->order->custom_shipto,
1219                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1220                                  id_selector => '#order_shipto_id');
1221
1222   div_tag($content, id => 'shipto_inputs');
1223 }
1224
1225 # render the info line for business
1226 #
1227 # Needed, if customer/vendor changed.
1228 sub build_business_info_row
1229 {
1230   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1231 }
1232
1233 # build the rows for displaying taxes
1234 #
1235 # Called if amounts where recalculated and redisplayed.
1236 sub build_tax_rows {
1237   my ($self) = @_;
1238
1239   my $rows_as_html;
1240   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1241     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1242   }
1243   return $rows_as_html;
1244 }
1245
1246
1247 sub render_price_dialog {
1248   my ($self, $record_item) = @_;
1249
1250   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1251
1252   $self->js
1253     ->run(
1254       'kivi.io.price_chooser_dialog',
1255       t8('Available Prices'),
1256       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1257     )
1258     ->reinit_widgets;
1259
1260 #   if (@errors) {
1261 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1262 #     $self->js->show('#dialog_flash_error');
1263 #   }
1264
1265   $self->js->render;
1266 }
1267
1268 sub load_order {
1269   my ($self) = @_;
1270
1271   return if !$::form->{id};
1272
1273   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1274
1275   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1276   # You need a custom shipto object to call cvars_by_config to get the cvars.
1277   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1278
1279   return $self->order;
1280 }
1281
1282 # load or create a new order object
1283 #
1284 # And assign changes from the form to this object.
1285 # If the order is loaded from db, check if items are deleted in the form,
1286 # remove them form the object and collect them for removing from db on saving.
1287 # Then create/update items from form (via make_item) and add them.
1288 sub make_order {
1289   my ($self) = @_;
1290
1291   # add_items adds items to an order with no items for saving, but they cannot
1292   # be retrieved via items until the order is saved. Adding empty items to new
1293   # order here solves this problem.
1294   my $order;
1295   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1296   $order ||= SL::DB::Order->new(orderitems  => [],
1297                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1298                                 currency_id => $::instance_conf->get_currency_id(),);
1299
1300   my $cv_id_method = $self->cv . '_id';
1301   if (!$::form->{id} && $::form->{$cv_id_method}) {
1302     $order->$cv_id_method($::form->{$cv_id_method});
1303     setup_order_from_cv($order);
1304   }
1305
1306   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1307   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1308
1309   $order->assign_attributes(%{$::form->{order}});
1310
1311   $self->setup_custom_shipto_from_form($order, $::form);
1312
1313   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1314     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1315     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1316   }
1317
1318   # remove deleted items
1319   $self->item_ids_to_delete([]);
1320   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1321     my $item = $order->orderitems->[$idx];
1322     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1323       splice @{$order->orderitems}, $idx, 1;
1324       push @{$self->item_ids_to_delete}, $item->id;
1325     }
1326   }
1327
1328   my @items;
1329   my $pos = 1;
1330   foreach my $form_attr (@{$form_orderitems}) {
1331     my $item = make_item($order, $form_attr);
1332     $item->position($pos);
1333     push @items, $item;
1334     $pos++;
1335   }
1336   $order->add_items(grep {!$_->id} @items);
1337
1338   return $order;
1339 }
1340
1341 # create or update items from form
1342 #
1343 # Make item objects from form values. For items already existing read from db.
1344 # Create a new item else. And assign attributes.
1345 sub make_item {
1346   my ($record, $attr) = @_;
1347
1348   my $item;
1349   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1350
1351   my $is_new = !$item;
1352
1353   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1354   # they cannot be retrieved via custom_variables until the order/orderitem is
1355   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1356   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1357
1358   $item->assign_attributes(%$attr);
1359
1360   if ($is_new) {
1361     my $texts = get_part_texts($item->part, $record->language_id);
1362     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1363     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1364     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1365   }
1366
1367   return $item;
1368 }
1369
1370 # create a new item
1371 #
1372 # This is used to add one item
1373 sub new_item {
1374   my ($record, $attr) = @_;
1375
1376   my $item = SL::DB::OrderItem->new;
1377
1378   # Remove attributes where the user left or set the inputs empty.
1379   # So these attributes will be undefined and we can distinguish them
1380   # from zero later on.
1381   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1382     delete $attr->{$_} if $attr->{$_} eq '';
1383   }
1384
1385   $item->assign_attributes(%$attr);
1386
1387   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1388   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1389
1390   $item->unit($part->unit) if !$item->unit;
1391
1392   my $price_src;
1393   if ( $part->is_assortment ) {
1394     # add assortment items with price 0, as the components carry the price
1395     $price_src = $price_source->price_from_source("");
1396     $price_src->price(0);
1397   } elsif (defined $item->sellprice) {
1398     $price_src = $price_source->price_from_source("");
1399     $price_src->price($item->sellprice);
1400   } else {
1401     $price_src = $price_source->best_price
1402                ? $price_source->best_price
1403                : $price_source->price_from_source("");
1404     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1405     $price_src->price(0) if !$price_source->best_price;
1406   }
1407
1408   my $discount_src;
1409   if (defined $item->discount) {
1410     $discount_src = $price_source->discount_from_source("");
1411     $discount_src->discount($item->discount);
1412   } else {
1413     $discount_src = $price_source->best_discount
1414                   ? $price_source->best_discount
1415                   : $price_source->discount_from_source("");
1416     $discount_src->discount(0) if !$price_source->best_discount;
1417   }
1418
1419   my %new_attr;
1420   $new_attr{part}                   = $part;
1421   $new_attr{description}            = $part->description     if ! $item->description;
1422   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1423   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1424   $new_attr{sellprice}              = $price_src->price;
1425   $new_attr{discount}               = $discount_src->discount;
1426   $new_attr{active_price_source}    = $price_src;
1427   $new_attr{active_discount_source} = $discount_src;
1428   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1429   $new_attr{project_id}             = $record->globalproject_id;
1430   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1431
1432   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1433   # they cannot be retrieved via custom_variables until the order/orderitem is
1434   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1435   $new_attr{custom_variables} = [];
1436
1437   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1438
1439   $item->assign_attributes(%new_attr, %{ $texts });
1440
1441   return $item;
1442 }
1443
1444 sub setup_order_from_cv {
1445   my ($order) = @_;
1446
1447   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1448
1449   $order->intnotes($order->customervendor->notes);
1450
1451   if ($order->is_sales) {
1452     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1453     $order->taxincluded(defined($order->customer->taxincluded_checked)
1454                         ? $order->customer->taxincluded_checked
1455                         : $::myconfig{taxincluded_checked});
1456   }
1457
1458 }
1459
1460 # setup custom shipto from form
1461 #
1462 # The dialog returns form variables starting with 'shipto' and cvars starting
1463 # with 'shiptocvar_'.
1464 # Mark it to be deleted if a shipto from master data is selected
1465 # (i.e. order has a shipto).
1466 # Else, update or create a new custom shipto. If the fields are empty, it
1467 # will not be saved on save.
1468 sub setup_custom_shipto_from_form {
1469   my ($self, $order, $form) = @_;
1470
1471   if ($order->shipto) {
1472     $self->is_custom_shipto_to_delete(1);
1473   } else {
1474     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1475
1476     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1477     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1478
1479     $custom_shipto->assign_attributes(%$shipto_attrs);
1480     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1481   }
1482 }
1483
1484 # recalculate prices and taxes
1485 #
1486 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1487 sub recalc {
1488   my ($self) = @_;
1489
1490   my %pat = $self->order->calculate_prices_and_taxes();
1491
1492   $self->{taxes} = [];
1493   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1494     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1495
1496     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1497                                 netamount => $netamount,
1498                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1499   }
1500   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1501 }
1502
1503 # get data for saving, printing, ..., that is not changed in the form
1504 #
1505 # Only cvars for now.
1506 sub get_unalterable_data {
1507   my ($self) = @_;
1508
1509   foreach my $item (@{ $self->order->items }) {
1510     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1511     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1512     foreach my $var (@{ $item->cvars_by_config }) {
1513       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1514     }
1515     $item->parse_custom_variable_values;
1516   }
1517 }
1518
1519 # delete the order
1520 #
1521 # And remove related files in the spool directory
1522 sub delete {
1523   my ($self) = @_;
1524
1525   my $errors = [];
1526   my $db     = $self->order->db;
1527
1528   $db->with_transaction(
1529     sub {
1530       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1531       $self->order->delete;
1532       my $spool = $::lx_office_conf{paths}->{spool};
1533       unlink map { "$spool/$_" } @spoolfiles if $spool;
1534
1535       1;
1536   }) || push(@{$errors}, $db->error);
1537
1538   return $errors;
1539 }
1540
1541 # save the order
1542 #
1543 # And delete items that are deleted in the form.
1544 sub save {
1545   my ($self) = @_;
1546
1547   my $errors = [];
1548   my $db     = $self->order->db;
1549
1550   $db->with_transaction(sub {
1551     # delete custom shipto if it is to be deleted or if it is empty
1552     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1553       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1554       $self->order->custom_shipto(undef);
1555     }
1556
1557     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1558     $self->order->save(cascade => 1);
1559
1560     # link records
1561     if ($::form->{converted_from_oe_id}) {
1562       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1563       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1564         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1565         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1566         $src->link_to_record($self->order);
1567       }
1568       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1569         my $idx = 0;
1570         foreach (@{ $self->order->items_sorted }) {
1571           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1572           next if !$from_id;
1573           SL::DB::RecordLink->new(from_table => 'orderitems',
1574                                   from_id    => $from_id,
1575                                   to_table   => 'orderitems',
1576                                   to_id      => $_->id
1577           )->save;
1578           $idx++;
1579         }
1580       }
1581     }
1582     1;
1583   }) || push(@{$errors}, $db->error);
1584
1585   return $errors;
1586 }
1587
1588 sub workflow_sales_quotation {
1589   my ($self) = @_;
1590
1591   # always save
1592   my $errors = $self->save();
1593
1594   if (scalar @{ $errors }) {
1595     $self->js->flash('error', $_) for @{ $errors };
1596     return $self->js->render();
1597   }
1598
1599   my $destination_type = sales_quotation_type();
1600
1601   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1602   $self->{converted_from_oe_id} = delete $::form->{id};
1603
1604   # set item ids to new fake id, to identify them as new items
1605   foreach my $item (@{$self->order->items_sorted}) {
1606     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1607   }
1608
1609   # change form type
1610   $::form->{type} = $destination_type;
1611   $self->type($self->init_type);
1612   $self->cv  ($self->init_cv);
1613   $self->check_auth;
1614
1615   $self->recalc();
1616   $self->get_unalterable_data();
1617   $self->pre_render();
1618
1619   # trigger rendering values for second row as hidden, because they
1620   # are loaded only on demand. So we need to keep the values from the
1621   # source.
1622   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1623
1624   $self->render(
1625     'order/form',
1626     title => $self->get_title_for('edit'),
1627     %{$self->{template_args}}
1628   );
1629 }
1630
1631 sub workflow_sales_or_purchase_order {
1632   my ($self) = @_;
1633
1634   # always save
1635   my $errors = $self->save();
1636
1637   if (scalar @{ $errors }) {
1638     $self->js->flash('error', $_) foreach @{ $errors };
1639     return $self->js->render();
1640   }
1641
1642   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1643                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1644                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1645                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1646                        : '';
1647
1648   # check for direct delivery
1649   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1650   my $custom_shipto;
1651   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1652       && $::form->{use_shipto} && $self->order->shipto) {
1653     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1654   }
1655
1656   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1657   $self->{converted_from_oe_id} = delete $::form->{id};
1658
1659   # set item ids to new fake id, to identify them as new items
1660   foreach my $item (@{$self->order->items_sorted}) {
1661     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1662   }
1663
1664   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1665     if ($::form->{use_shipto}) {
1666       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1667     } else {
1668       # remove any custom shipto if not wanted
1669       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1670     }
1671   }
1672
1673   # change form type
1674   $::form->{type} = $destination_type;
1675   $self->type($self->init_type);
1676   $self->cv  ($self->init_cv);
1677   $self->check_auth;
1678
1679   $self->recalc();
1680   $self->get_unalterable_data();
1681   $self->pre_render();
1682
1683   # trigger rendering values for second row as hidden, because they
1684   # are loaded only on demand. So we need to keep the values from the
1685   # source.
1686   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1687
1688   $self->render(
1689     'order/form',
1690     title => $self->get_title_for('edit'),
1691     %{$self->{template_args}}
1692   );
1693 }
1694
1695
1696 sub pre_render {
1697   my ($self) = @_;
1698
1699   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1700   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1701   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1702   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1703   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1704                                                                                               deleted => 0 ] ],
1705                                                                            sort_by => 'name');
1706   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1707                                                                                               deleted => 0 ] ],
1708                                                                            sort_by => 'name');
1709   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1710                                                                                                         obsolete => 0 ] ]);
1711   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1712   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1713   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1714   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1715   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1716
1717   my $print_form = Form->new('');
1718   $print_form->{type}        = $self->type;
1719   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1720   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1721     form => $print_form,
1722     options => {dialog_name_prefix => 'print_options.',
1723                 show_headers       => 1,
1724                 no_queue           => 1,
1725                 no_postscript      => 1,
1726                 no_opendocument    => 0,
1727                 no_html            => 1},
1728   );
1729
1730   foreach my $item (@{$self->order->orderitems}) {
1731     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1732     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1733     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1734   }
1735
1736   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1737     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1738     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1739   }
1740
1741   if ($self->order->number && $::instance_conf->get_webdav) {
1742     my $webdav = SL::Webdav->new(
1743       type     => $self->type,
1744       number   => $self->order->number,
1745     );
1746     my @all_objects = $webdav->get_all_objects;
1747     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1748                                                     type => t8('File'),
1749                                                     link => File::Spec->catfile($_->full_filedescriptor),
1750                                                 } } @all_objects;
1751   }
1752
1753   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1754
1755   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1756                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up);
1757   $self->setup_edit_action_bar;
1758 }
1759
1760 sub setup_edit_action_bar {
1761   my ($self, %params) = @_;
1762
1763   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1764                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1765                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1766
1767   for my $bar ($::request->layout->get('actionbar')) {
1768     $bar->add(
1769       combobox => [
1770         action => [
1771           t8('Save'),
1772           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1773                                                     $::instance_conf->get_order_warn_no_deliverydate,
1774                                                                                                       ],
1775           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1776         ],
1777         action => [
1778           t8('Save as new'),
1779           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1780           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1781           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1782         ],
1783       ], # end of combobox "Save"
1784
1785       combobox => [
1786         action => [
1787           t8('Workflow'),
1788         ],
1789         action => [
1790           t8('Save and Quotation'),
1791           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1792           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1793         ],
1794         action => [
1795           t8('Save and Sales Order'),
1796           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1797           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1798         ],
1799         action => [
1800           t8('Save and Purchase Order'),
1801           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1802           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1803         ],
1804         action => [
1805           t8('Save and Delivery Order'),
1806           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1807                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1808                                                                                                                         ],
1809           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1810           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1811         ],
1812         action => [
1813           t8('Save and Invoice'),
1814           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1815           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1816         ],
1817         action => [
1818           t8('Save and AP Transaction'),
1819           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1820           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1821         ],
1822
1823       ], # end of combobox "Workflow"
1824
1825       combobox => [
1826         action => [
1827           t8('Export'),
1828         ],
1829         action => [
1830           t8('Save and print'),
1831           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1832         ],
1833         action => [
1834           t8('Save and E-mail'),
1835           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts ],
1836           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1837         ],
1838         action => [
1839           t8('Download attachments of all parts'),
1840           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1841           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1842           only_if  => $::instance_conf->get_doc_storage,
1843         ],
1844       ], # end of combobox "Export"
1845
1846       action => [
1847         t8('Delete'),
1848         call     => [ 'kivi.Order.delete_order' ],
1849         confirm  => $::locale->text('Do you really want to delete this object?'),
1850         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1851         only_if  => $deletion_allowed,
1852       ],
1853
1854       combobox => [
1855         action => [
1856           t8('more')
1857         ],
1858         action => [
1859           t8('Follow-Up'),
1860           call     => [ 'kivi.Order.follow_up_window' ],
1861           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1862           only_if  => $::auth->assert('productivity', 1),
1863         ],
1864       ], # end of combobox "more"
1865     );
1866   }
1867 }
1868
1869 sub generate_pdf {
1870   my ($order, $pdf_ref, $params) = @_;
1871
1872   my @errors = ();
1873
1874   my $print_form = Form->new('');
1875   $print_form->{type}        = $order->type;
1876   $print_form->{formname}    = $params->{formname} || $order->type;
1877   $print_form->{format}      = $params->{format}   || 'pdf';
1878   $print_form->{media}       = $params->{media}    || 'file';
1879   $print_form->{groupitems}  = $params->{groupitems};
1880   $print_form->{printer_id}  = $params->{printer_id};
1881   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1882
1883   $order->language($params->{language});
1884   $order->flatten_to_form($print_form, format_amounts => 1);
1885
1886   my $template_ext;
1887   my $template_type;
1888   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1889     $template_ext  = 'odt';
1890     $template_type = 'OpenDocument';
1891   }
1892
1893   # search for the template
1894   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1895     name        => $print_form->{formname},
1896     extension   => $template_ext,
1897     email       => $print_form->{media} eq 'email',
1898     language    => $params->{language},
1899     printer_id  => $print_form->{printer_id},
1900   );
1901
1902   if (!defined $template_file) {
1903     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1904   }
1905
1906   return @errors if scalar @errors;
1907
1908   $print_form->throw_on_error(sub {
1909     eval {
1910       $print_form->prepare_for_printing;
1911
1912       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1913         format        => $print_form->{format},
1914         template_type => $template_type,
1915         template      => $template_file,
1916         variables     => $print_form,
1917         variable_content_types => {
1918           longdescription => 'html',
1919           partnotes       => 'html',
1920           notes           => 'html',
1921         },
1922       );
1923       1;
1924     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1925   });
1926
1927   return @errors;
1928 }
1929
1930 sub get_files_for_email_dialog {
1931   my ($self) = @_;
1932
1933   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1934
1935   return %files if !$::instance_conf->get_doc_storage;
1936
1937   if ($self->order->id) {
1938     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1939     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1940     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1941   }
1942
1943   my @parts =
1944     uniq_by { $_->{id} }
1945     map {
1946       +{ id         => $_->part->id,
1947          partnumber => $_->part->partnumber }
1948     } @{$self->order->items_sorted};
1949
1950   foreach my $part (@parts) {
1951     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1952     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1953   }
1954
1955   foreach my $key (keys %files) {
1956     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1957   }
1958
1959   return %files;
1960 }
1961
1962 sub make_periodic_invoices_config_from_yaml {
1963   my ($yaml_config) = @_;
1964
1965   return if !$yaml_config;
1966   my $attr = SL::YAML::Load($yaml_config);
1967   return if 'HASH' ne ref $attr;
1968   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1969 }
1970
1971
1972 sub get_periodic_invoices_status {
1973   my ($self, $config) = @_;
1974
1975   return                      if $self->type ne sales_order_type();
1976   return t8('not configured') if !$config;
1977
1978   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1979              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1980              :                                                     die "Cannot get status of periodic invoices config";
1981
1982   return $active ? t8('active') : t8('inactive');
1983 }
1984
1985 sub get_title_for {
1986   my ($self, $action) = @_;
1987
1988   return '' if none { lc($action)} qw(add edit);
1989
1990   # for locales:
1991   # $::locale->text("Add Sales Order");
1992   # $::locale->text("Add Purchase Order");
1993   # $::locale->text("Add Quotation");
1994   # $::locale->text("Add Request for Quotation");
1995   # $::locale->text("Edit Sales Order");
1996   # $::locale->text("Edit Purchase Order");
1997   # $::locale->text("Edit Quotation");
1998   # $::locale->text("Edit Request for Quotation");
1999
2000   $action = ucfirst(lc($action));
2001   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2002        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2003        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2004        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2005        : '';
2006 }
2007
2008 sub get_item_cvpartnumber {
2009   my ($self, $item) = @_;
2010
2011   return if !$self->search_cvpartnumber;
2012   return if !$self->order->customervendor;
2013
2014   if ($self->cv eq 'vendor') {
2015     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2016     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2017   } elsif ($self->cv eq 'customer') {
2018     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2019     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2020   }
2021 }
2022
2023 sub get_part_texts {
2024   my ($part_or_id, $language_or_id, %defaults) = @_;
2025
2026   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2027   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2028   my $texts       = {
2029     description     => $defaults{description}     // $part->description,
2030     longdescription => $defaults{longdescription} // $part->notes,
2031   };
2032
2033   return $texts unless $language_id;
2034
2035   my $translation = SL::DB::Manager::Translation->get_first(
2036     where => [
2037       parts_id    => $part->id,
2038       language_id => $language_id,
2039     ]);
2040
2041   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2042   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2043
2044   return $texts;
2045 }
2046
2047 sub sales_order_type {
2048   'sales_order';
2049 }
2050
2051 sub purchase_order_type {
2052   'purchase_order';
2053 }
2054
2055 sub sales_quotation_type {
2056   'sales_quotation';
2057 }
2058
2059 sub request_quotation_type {
2060   'request_quotation';
2061 }
2062
2063 sub nr_key {
2064   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2065        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2066        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2067        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2068        : '';
2069 }
2070
2071 sub save_and_redirect_to {
2072   my ($self, %params) = @_;
2073
2074   my $errors = $self->save();
2075
2076   if (scalar @{ $errors }) {
2077     $self->js->flash('error', $_) foreach @{ $errors };
2078     return $self->js->render();
2079   }
2080
2081   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2082            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2083            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2084            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2085            : '';
2086   flash_later('info', $text);
2087
2088   $self->redirect_to(%params, id => $self->order->id);
2089 }
2090
2091 1;
2092
2093 __END__
2094
2095 =encoding utf-8
2096
2097 =head1 NAME
2098
2099 SL::Controller::Order - controller for orders
2100
2101 =head1 SYNOPSIS
2102
2103 This is a new form to enter orders, completely rewritten with the use
2104 of controller and java script techniques.
2105
2106 The aim is to provide the user a better experience and a faster workflow. Also
2107 the code should be more readable, more reliable and better to maintain.
2108
2109 =head2 Key Features
2110
2111 =over 4
2112
2113 =item *
2114
2115 One input row, so that input happens every time at the same place.
2116
2117 =item *
2118
2119 Use of pickers where possible.
2120
2121 =item *
2122
2123 Possibility to enter more than one item at once.
2124
2125 =item *
2126
2127 Item list in a scrollable area, so that the workflow buttons stay at
2128 the bottom.
2129
2130 =item *
2131
2132 Reordering item rows with drag and drop is possible. Sorting item rows is
2133 possible (by partnumber, description, qty, sellprice and discount for now).
2134
2135 =item *
2136
2137 No C<update> is necessary. All entries and calculations are managed
2138 with ajax-calls and the page only reloads on C<save>.
2139
2140 =item *
2141
2142 User can see changes immediately, because of the use of java script
2143 and ajax.
2144
2145 =back
2146
2147 =head1 CODE
2148
2149 =head2 Layout
2150
2151 =over 4
2152
2153 =item * C<SL/Controller/Order.pm>
2154
2155 the controller
2156
2157 =item * C<template/webpages/order/form.html>
2158
2159 main form
2160
2161 =item * C<template/webpages/order/tabs/basic_data.html>
2162
2163 Main tab for basic_data.
2164
2165 This is the only tab here for now. "linked records" and "webdav" tabs are
2166 reused from generic code.
2167
2168 =over 4
2169
2170 =item * C<template/webpages/order/tabs/_business_info_row.html>
2171
2172 For displaying information on business type
2173
2174 =item * C<template/webpages/order/tabs/_item_input.html>
2175
2176 The input line for items
2177
2178 =item * C<template/webpages/order/tabs/_row.html>
2179
2180 One row for already entered items
2181
2182 =item * C<template/webpages/order/tabs/_tax_row.html>
2183
2184 Displaying tax information
2185
2186 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2187
2188 Dialog for selecting price and discount sources
2189
2190 =back
2191
2192 =item * C<js/kivi.Order.js>
2193
2194 java script functions
2195
2196 =back
2197
2198 =head1 TODO
2199
2200 =over 4
2201
2202 =item * testing
2203
2204 =item * credit limit
2205
2206 =item * more workflows (rfq)
2207
2208 =item * price sources: little symbols showing better price / better discount
2209
2210 =item * select units in input row?
2211
2212 =item * check for direct delivery (workflow sales order -> purchase order)
2213
2214 =item * access rights
2215
2216 =item * display weights
2217
2218 =item * history
2219
2220 =item * mtime check
2221
2222 =item * optional client/user behaviour
2223
2224 (transactions has to be set - department has to be set -
2225  force project if enabled in client config - transport cost reminder)
2226
2227 =back
2228
2229 =head1 KNOWN BUGS AND CAVEATS
2230
2231 =over 4
2232
2233 =item *
2234
2235 Customer discount is not displayed as a valid discount in price source popup
2236 (this might be a bug in price sources)
2237
2238 (I cannot reproduce this (Bernd))
2239
2240 =item *
2241
2242 No indication that <shift>-up/down expands/collapses second row.
2243
2244 =item *
2245
2246 Inline creation of parts is not currently supported
2247
2248 =item *
2249
2250 Table header is not sticky in the scrolling area.
2251
2252 =item *
2253
2254 Sorting does not include C<position>, neither does reordering.
2255
2256 This behavior was implemented intentionally. But we can discuss, which behavior
2257 should be implemented.
2258
2259 =back
2260
2261 =head1 To discuss / Nice to have
2262
2263 =over 4
2264
2265 =item *
2266
2267 How to expand/collapse second row. Now it can be done clicking the icon or
2268 <shift>-up/down.
2269
2270 =item *
2271
2272 Possibility to select PriceSources in input row?
2273
2274 =item *
2275
2276 This controller uses a (changed) copy of the template for the PriceSource
2277 dialog. Maybe there could be used one code source.
2278
2279 =item *
2280
2281 Rounding-differences between this controller (PriceTaxCalculator) and the old
2282 form. This is not only a problem here, but also in all parts using the PTC.
2283 There exists a ticket and a patch. This patch should be testet.
2284
2285 =item *
2286
2287 An indicator, if the actual inputs are saved (like in an
2288 editor or on text processing application).
2289
2290 =item *
2291
2292 A warning when leaving the page without saveing unchanged inputs.
2293
2294
2295 =back
2296
2297 =head1 AUTHOR
2298
2299 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2300
2301 =cut