SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::AdditionalBillingAddress;
  17 use SL::DB::AuthUser;
  18 use SL::DB::History;
  19 use SL::DB::Order;
  20 use SL::DB::Default;
  21 use SL::DB::Unit;
  22 use SL::DB::Part;
  23 use SL::DB::PartClassification;
  24 use SL::DB::PartsGroup;
  25 use SL::DB::Printer;
  26 use SL::DB::Language;
  27 use SL::DB::RecordLink;
  28 use SL::DB::RequirementSpec;
  29 use SL::DB::Shipto;
  30 use SL::DB::Translation;
  31
  32 use SL::Helper::CreatePDF qw(:all);
  33 use SL::Helper::PrintOptions;
  34 use SL::Helper::ShippedQty;
  35 use SL::Helper::UserPreferences::PositionsScrollbar;
  36 use SL::Helper::UserPreferences::UpdatePositions;
  37
  38 use SL::Controller::Helper::GetModels;
  39
  40 use List::Util qw(first sum0);
  41 use List::UtilsBy qw(sort_by uniq_by);
  42 use List::MoreUtils qw(any none pairwise first_index);
  43 use English qw(-no_match_vars);
  44 use File::Spec;
  45 use Cwd;
  46 use Sort::Naturally;
  47
  48 use Rose::Object::MakeMethods::Generic
  49 (
  50  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  51  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  52 );
  53
  54
  55 # safety
  56 __PACKAGE__->run_before('check_auth');
  57
  58 __PACKAGE__->run_before('recalc',
  59                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  60                                      print send_email) ]);
  61
  62 __PACKAGE__->run_before('get_unalterable_data',
  63                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  64                                      print send_email) ]);
  65
  66 #
  67 # actions
  68 #
  69
  70 # add a new order
  71 sub action_add {
  72   my ($self) = @_;
  73
  74   $self->order->transdate(DateTime->now_local());
  75   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  76                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  77
  78   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  79       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  80       && (!$self->order->reqdate)) {
  81     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  82   }
  83
  84
  85   $self->pre_render();
  86   $self->render(
  87     'order/form',
  88     title => $self->get_title_for('add'),
  89     %{$self->{template_args}}
  90   );
  91 }
  92
  93 # edit an existing order
  94 sub action_edit {
  95   my ($self) = @_;
  96
  97   if ($::form->{id}) {
  98     $self->load_order;
  99
 100   } else {
 101     # this is to edit an order from an unsaved order object
 102
 103     # set item ids to new fake id, to identify them as new items
 104     foreach my $item (@{$self->order->items_sorted}) {
 105       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 106     }
 107     # trigger rendering values for second row as hidden, because they
 108     # are loaded only on demand. So we need to keep the values from
 109     # the source.
 110     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 111   }
 112
 113   $self->recalc();
 114   $self->pre_render();
 115   $self->render(
 116     'order/form',
 117     title => $self->get_title_for('edit'),
 118     %{$self->{template_args}}
 119   );
 120 }
 121
 122 # edit a collective order (consisting of one or more existing orders)
 123 sub action_edit_collective {
 124   my ($self) = @_;
 125
 126   # collect order ids
 127   my @multi_ids = map {
 128     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 129   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 130
 131   # fall back to add if no ids are given
 132   if (scalar @multi_ids == 0) {
 133     $self->action_add();
 134     return;
 135   }
 136
 137   # fall back to save as new if only one id is given
 138   if (scalar @multi_ids == 1) {
 139     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 140     $self->action_save_as_new();
 141     return;
 142   }
 143
 144   # make new order from given orders
 145   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 146   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 147   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 148
 149   $self->action_edit();
 150 }
 151
 152 # delete the order
 153 sub action_delete {
 154   my ($self) = @_;
 155
 156   my $errors = $self->delete();
 157
 158   if (scalar @{ $errors }) {
 159     $self->js->flash('error', $_) foreach @{ $errors };
 160     return $self->js->render();
 161   }
 162
 163   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 164            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 165            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 166            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 167            : '';
 168   flash_later('info', $text);
 169
 170   my @redirect_params = (
 171     action => 'add',
 172     type   => $self->type,
 173   );
 174
 175   $self->redirect_to(@redirect_params);
 176 }
 177
 178 # save the order
 179 sub action_save {
 180   my ($self) = @_;
 181
 182   my $errors = $self->save();
 183
 184   if (scalar @{ $errors }) {
 185     $self->js->flash('error', $_) foreach @{ $errors };
 186     return $self->js->render();
 187   }
 188
 189   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 190            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 191            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 192            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 193            : '';
 194   flash_later('info', $text);
 195
 196   my @redirect_params = (
 197     action => 'edit',
 198     type   => $self->type,
 199     id     => $self->order->id,
 200   );
 201
 202   $self->redirect_to(@redirect_params);
 203 }
 204
 205 # save the order as new document an open it for edit
 206 sub action_save_as_new {
 207   my ($self) = @_;
 208
 209   my $order = $self->order;
 210
 211   if (!$order->id) {
 212     $self->js->flash('error', t8('This object has not been saved yet.'));
 213     return $self->js->render();
 214   }
 215
 216   # load order from db to check if values changed
 217   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 218
 219   my %new_attrs;
 220   # Lets assign a new number if the user hasn't changed the previous one.
 221   # If it has been changed manually then use it as-is.
 222   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 223                         ? ''
 224                         : trim($order->number);
 225
 226   # Clear transdate unless changed
 227   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 228                         ? DateTime->today_local
 229                         : $order->transdate;
 230
 231   # Set new reqdate unless changed if it is enabled in client config
 232   if ($order->reqdate == $saved_order->reqdate) {
 233     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 234                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 235
 236     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 237         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 238       $new_attrs{reqdate} = '';
 239     } else {
 240       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 241     }
 242   } else {
 243     $new_attrs{reqdate} = $order->reqdate;
 244   }
 245
 246   # Update employee
 247   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 248
 249   # Create new record from current one
 250   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 251
 252   # no linked records on save as new
 253   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 254
 255   # save
 256   $self->action_save();
 257 }
 258
 259 # print the order
 260 #
 261 # This is called if "print" is pressed in the print dialog.
 262 # If PDF creation was requested and succeeded, the pdf is offered for download
 263 # via send_file (which uses ajax in this case).
 264 sub action_print {
 265   my ($self) = @_;
 266
 267   my $errors = $self->save();
 268
 269   if (scalar @{ $errors }) {
 270     $self->js->flash('error', $_) foreach @{ $errors };
 271     return $self->js->render();
 272   }
 273
 274   $self->js_reset_order_and_item_ids_after_save;
 275
 276   my $format      = $::form->{print_options}->{format};
 277   my $media       = $::form->{print_options}->{media};
 278   my $formname    = $::form->{print_options}->{formname};
 279   my $copies      = $::form->{print_options}->{copies};
 280   my $groupitems  = $::form->{print_options}->{groupitems};
 281   my $printer_id  = $::form->{print_options}->{printer_id};
 282
 283   # only pdf and opendocument by now
 284   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 285     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 286   }
 287
 288   # only screen or printer by now
 289   if (none { $media eq $_ } qw(screen printer)) {
 290     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 291   }
 292
 293   # create a form for generate_attachment_filename
 294   my $form   = Form->new;
 295   $form->{$self->nr_key()}  = $self->order->number;
 296   $form->{type}             = $self->type;
 297   $form->{format}           = $format;
 298   $form->{formname}         = $formname;
 299   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 300   my $pdf_filename          = $form->generate_attachment_filename();
 301
 302   my $pdf;
 303   my @errors = $self->generate_pdf(\$pdf, { format     => $format,
 304                                             formname   => $formname,
 305                                             language   => $self->order->language,
 306                                             printer_id => $printer_id,
 307                                             groupitems => $groupitems });
 308   if (scalar @errors) {
 309     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 310   }
 311
 312   if ($media eq 'screen') {
 313     # screen/download
 314     $self->js->flash('info', t8('The PDF has been created'));
 315     $self->send_file(
 316       \$pdf,
 317       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 318       name         => $pdf_filename,
 319       js_no_render => 1,
 320     );
 321
 322   } elsif ($media eq 'printer') {
 323     # printer
 324     my $printer_id = $::form->{print_options}->{printer_id};
 325     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 326       copies  => $copies,
 327       content => $pdf,
 328     );
 329
 330     $self->js->flash('info', t8('The PDF has been printed'));
 331   }
 332
 333   my @warnings = $self->store_pdf_to_webdav_and_filemanagement($pdf, $pdf_filename);
 334   if (scalar @warnings) {
 335     $self->js->flash('warning', $_) for @warnings;
 336   }
 337
 338   $self->save_history('PRINTED');
 339
 340   $self->js
 341     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 342     ->render;
 343 }
 344 sub action_preview_pdf {
 345   my ($self) = @_;
 346
 347   my $errors = $self->save();
 348   if (scalar @{ $errors }) {
 349     $self->js->flash('error', $_) foreach @{ $errors };
 350     return $self->js->render();
 351   }
 352
 353   $self->js_reset_order_and_item_ids_after_save;
 354
 355   my $format      = 'pdf';
 356   my $media       = 'screen';
 357   my $formname    = $self->type;
 358
 359   # only pdf
 360   # create a form for generate_attachment_filename
 361   my $form   = Form->new;
 362   $form->{$self->nr_key()}  = $self->order->number;
 363   $form->{type}             = $self->type;
 364   $form->{format}           = $format;
 365   $form->{formname}         = $formname;
 366   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 367   my $pdf_filename          = $form->generate_attachment_filename();
 368
 369   my $pdf;
 370   my @errors = $self->generate_pdf(\$pdf, { format     => $format,
 371                                             formname   => $formname,
 372                                             language   => $self->order->language,
 373                                           });
 374   if (scalar @errors) {
 375     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 376   }
 377   $self->save_history('PREVIEWED');
 378   $self->js->flash('info', t8('The PDF has been previewed'));
 379   # screen/download
 380   $self->send_file(
 381     \$pdf,
 382     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 383     name         => $pdf_filename,
 384     js_no_render => 0,
 385   );
 386 }
 387
 388 # open the email dialog
 389 sub action_save_and_show_email_dialog {
 390   my ($self) = @_;
 391
 392   my $errors = $self->save();
 393
 394   if (scalar @{ $errors }) {
 395     $self->js->flash('error', $_) foreach @{ $errors };
 396     return $self->js->render();
 397   }
 398
 399   my $cv_method = $self->cv;
 400
 401   if (!$self->order->$cv_method) {
 402     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 403                     ->render($self);
 404   }
 405
 406   my $email_form;
 407   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 408   $email_form->{to} ||= $self->order->$cv_method->email;
 409   $email_form->{cc}   = $self->order->$cv_method->cc;
 410   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 411   # Todo: get addresses from shipto, if any
 412
 413   my $form = Form->new;
 414   $form->{$self->nr_key()}  = $self->order->number;
 415   $form->{cusordnumber}     = $self->order->cusordnumber;
 416   $form->{formname}         = $self->type;
 417   $form->{type}             = $self->type;
 418   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 419   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 420   $form->{format}           = 'pdf';
 421   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 422
 423   $email_form->{subject}             = $form->generate_email_subject();
 424   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 425   $email_form->{message}             = $form->generate_email_body();
 426   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 427
 428   my %files = $self->get_files_for_email_dialog();
 429
 430   my @employees_with_email = grep {
 431     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 432     $user && !!trim($user->get_config_value('email'));
 433   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 434
 435   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 436                                   email_form    => $email_form,
 437                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 438                                   FILES         => \%files,
 439                                   is_customer   => $self->cv eq 'customer',
 440                                   ALL_EMPLOYEES => \@employees_with_email,
 441   );
 442
 443   $self->js
 444       ->run('kivi.Order.show_email_dialog', $dialog_html)
 445       ->reinit_widgets
 446       ->render($self);
 447 }
 448
 449 # send email
 450 #
 451 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 452 sub action_send_email {
 453   my ($self) = @_;
 454
 455   my $errors = $self->save();
 456
 457   if (scalar @{ $errors }) {
 458     $self->js->run('kivi.Order.close_email_dialog');
 459     $self->js->flash('error', $_) foreach @{ $errors };
 460     return $self->js->render();
 461   }
 462
 463   $self->js_reset_order_and_item_ids_after_save;
 464
 465   my $email_form  = delete $::form->{email_form};
 466   my %field_names = (to => 'email');
 467
 468   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 469
 470   # for Form::cleanup which may be called in Form::send_email
 471   $::form->{cwd}    = getcwd();
 472   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 473
 474   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 475   $::form->{media}  = 'email';
 476
 477   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 478     my $pdf;
 479     my @errors = $self->generate_pdf(\$pdf, {media      => $::form->{media},
 480                                             format     => $::form->{print_options}->{format},
 481                                             formname   => $::form->{print_options}->{formname},
 482                                             language   => $self->order->language,
 483                                             printer_id => $::form->{print_options}->{printer_id},
 484                                             groupitems => $::form->{print_options}->{groupitems}});
 485     if (scalar @errors) {
 486       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 487     }
 488
 489     my @warnings = $self->store_pdf_to_webdav_and_filemanagement($pdf, $::form->{attachment_filename});
 490     if (scalar @warnings) {
 491       flash_later('warning', $_) for @warnings;
 492     }
 493
 494     my $sfile = SL::SessionFile::Random->new(mode => "w");
 495     $sfile->fh->print($pdf);
 496     $sfile->fh->close;
 497
 498     $::form->{tmpfile} = $sfile->file_name;
 499     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 500   }
 501
 502   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 503   $::form->send_email(\%::myconfig, 'pdf');
 504
 505   # internal notes
 506   my $intnotes = $self->order->intnotes;
 507   $intnotes   .= "\n\n" if $self->order->intnotes;
 508   $intnotes   .= t8('[email]')                                                                                        . "\n";
 509   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 510   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 511   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 512   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 513   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 514   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 515
 516   $self->order->update_attributes(intnotes => $intnotes);
 517
 518   $self->save_history('MAILED');
 519
 520   flash_later('info', t8('The email has been sent.'));
 521
 522   my @redirect_params = (
 523     action => 'edit',
 524     type   => $self->type,
 525     id     => $self->order->id,
 526   );
 527
 528   $self->redirect_to(@redirect_params);
 529 }
 530
 531 # open the periodic invoices config dialog
 532 #
 533 # If there are values in the form (i.e. dialog was opened before),
 534 # then use this values. Create new ones, else.
 535 sub action_show_periodic_invoices_config_dialog {
 536   my ($self) = @_;
 537
 538   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 539   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 540   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 541                                                    order_value_periodicity => 'p', # = same as periodicity
 542                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 543                                                    extend_automatically_by => 12,
 544                                                    active                  => 1,
 545                                                    email_subject           => GenericTranslations->get(
 546                                                                                 language_id      => $::form->{language_id},
 547                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 548                                                    email_body              => GenericTranslations->get(
 549                                                                                 language_id      => $::form->{language_id},
 550                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 551   );
 552   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 553   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 554
 555   $::form->get_lists(printers => "ALL_PRINTERS",
 556                      charts   => { key       => 'ALL_CHARTS',
 557                                    transdate => 'current_date' });
 558
 559   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 560
 561   if ($::form->{customer_id}) {
 562     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 563     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 564     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 565     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 566     $config->send_email(0) if $::form->{postal_invoice};
 567   }
 568
 569   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 570                 popup_dialog             => 1,
 571                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 572                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 573                 config                   => $config,
 574                 %$::form);
 575 }
 576
 577 # assign the values of the periodic invoices config dialog
 578 # as yaml in the hidden tag and set the status.
 579 sub action_assign_periodic_invoices_config {
 580   my ($self) = @_;
 581
 582   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 583
 584   my $config = { active                     => $::form->{active}       ? 1 : 0,
 585                  terminated                 => $::form->{terminated}   ? 1 : 0,
 586                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 587                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 588                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 589                  start_date_as_date         => $::form->{start_date_as_date},
 590                  end_date_as_date           => $::form->{end_date_as_date},
 591                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 592                  print                      => $::form->{print}      ? 1                         : 0,
 593                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 594                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 595                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 596                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 597                  send_email                 => $::form->{send_email} ? 1 : 0,
 598                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 599                  email_recipient_address    => $::form->{email_recipient_address},
 600                  email_sender               => $::form->{email_sender},
 601                  email_subject              => $::form->{email_subject},
 602                  email_body                 => $::form->{email_body},
 603                };
 604
 605   my $periodic_invoices_config = SL::YAML::Dump($config);
 606
 607   my $status = $self->get_periodic_invoices_status($config);
 608
 609   $self->js
 610     ->remove('#order_periodic_invoices_config')
 611     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 612     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 613     ->html('#periodic_invoices_status', $status)
 614     ->flash('info', t8('The periodic invoices config has been assigned.'))
 615     ->render($self);
 616 }
 617
 618 sub action_get_has_active_periodic_invoices {
 619   my ($self) = @_;
 620
 621   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 622   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 623
 624   my $has_active_periodic_invoices =
 625        $self->type eq sales_order_type()
 626     && $config
 627     && $config->active
 628     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 629     && $config->get_previous_billed_period_start_date;
 630
 631   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 632 }
 633
 634 # save the order and redirect to the frontend subroutine for a new
 635 # delivery order
 636 sub action_save_and_delivery_order {
 637   my ($self) = @_;
 638
 639   $self->save_and_redirect_to(
 640     controller => 'oe.pl',
 641     action     => 'oe_delivery_order_from_order',
 642   );
 643 }
 644
 645 # save the order and redirect to the frontend subroutine for a new
 646 # invoice
 647 sub action_save_and_invoice {
 648   my ($self) = @_;
 649
 650   $self->save_and_redirect_to(
 651     controller => 'oe.pl',
 652     action     => 'oe_invoice_from_order',
 653   );
 654 }
 655
 656 # workflow from sales order to sales quotation
 657 sub action_sales_quotation {
 658   $_[0]->workflow_sales_or_request_for_quotation();
 659 }
 660
 661 # workflow from sales order to sales quotation
 662 sub action_request_for_quotation {
 663   $_[0]->workflow_sales_or_request_for_quotation();
 664 }
 665
 666 # workflow from sales quotation to sales order
 667 sub action_sales_order {
 668   $_[0]->workflow_sales_or_purchase_order();
 669 }
 670
 671 # workflow from rfq to purchase order
 672 sub action_purchase_order {
 673   $_[0]->workflow_sales_or_purchase_order();
 674 }
 675
 676 # workflow from purchase order to ap transaction
 677 sub action_save_and_ap_transaction {
 678   my ($self) = @_;
 679
 680   $self->save_and_redirect_to(
 681     controller => 'ap.pl',
 682     action     => 'add_from_purchase_order',
 683   );
 684 }
 685
 686 # set form elements in respect to a changed customer or vendor
 687 #
 688 # This action is called on an change of the customer/vendor picker.
 689 sub action_customer_vendor_changed {
 690   my ($self) = @_;
 691
 692   setup_order_from_cv($self->order);
 693   $self->recalc();
 694
 695   my $cv_method = $self->cv;
 696
 697   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 698     $self->js->show('#cp_row');
 699   } else {
 700     $self->js->hide('#cp_row');
 701   }
 702
 703   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 704     $self->js->show('#shipto_selection');
 705   } else {
 706     $self->js->hide('#shipto_selection');
 707   }
 708
 709   if ($cv_method eq 'customer') {
 710     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 711     $self->js->$show_hide('#billing_address_row');
 712   }
 713
 714   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 715
 716   $self->js
 717     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 718     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 719     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 720     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 721     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 722     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 723     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 724     ->val(        '#order_currency_id',        $self->order->currency_id)
 725     ->val(        '#order_payment_id',         $self->order->payment_id)
 726     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 727     ->val(        '#order_intnotes',           $self->order->intnotes)
 728     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 729     ->focus(      '#order_' . $self->cv . '_id')
 730     ->run('kivi.Order.update_exchangerate');
 731
 732   $self->js_redisplay_amounts_and_taxes;
 733   $self->js_redisplay_cvpartnumbers;
 734   $self->js->render();
 735 }
 736
 737 # open the dialog for customer/vendor details
 738 sub action_show_customer_vendor_details_dialog {
 739   my ($self) = @_;
 740
 741   my $is_customer = 'customer' eq $::form->{vc};
 742   my $cv;
 743   if ($is_customer) {
 744     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 745   } else {
 746     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 747   }
 748
 749   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 750   $details{discount_as_percent} = $cv->discount_as_percent;
 751   $details{creditlimt}          = $cv->creditlimit_as_number;
 752   $details{business}            = $cv->business->description      if $cv->business;
 753   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 754   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 755   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 756   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 757
 758   foreach my $entry (@{ $cv->additional_billing_addresses }) {
 759     push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 760   }
 761   foreach my $entry (@{ $cv->shipto }) {
 762     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 763   }
 764   foreach my $entry (@{ $cv->contacts }) {
 765     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 766   }
 767
 768   $_[0]->render('common/show_vc_details', { layout => 0 },
 769                 is_customer => $is_customer,
 770                 %details);
 771
 772 }
 773
 774 # called if a unit in an existing item row is changed
 775 sub action_unit_changed {
 776   my ($self) = @_;
 777
 778   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 779   my $item = $self->order->items_sorted->[$idx];
 780
 781   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 782   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 783
 784   $self->recalc();
 785
 786   $self->js
 787     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 788   $self->js_redisplay_line_values;
 789   $self->js_redisplay_amounts_and_taxes;
 790   $self->js->render();
 791 }
 792
 793 # add an item row for a new item entered in the input row
 794 sub action_add_item {
 795   my ($self) = @_;
 796
 797   delete $::form->{add_item}->{create_part_type};
 798
 799   my $form_attr = $::form->{add_item};
 800
 801   return unless $form_attr->{parts_id};
 802
 803   my $item = new_item($self->order, $form_attr);
 804
 805   $self->order->add_items($item);
 806
 807   $self->recalc();
 808
 809   $self->get_item_cvpartnumber($item);
 810
 811   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 812   my $row_as_html = $self->p->render('order/tabs/_row',
 813                                      ITEM => $item,
 814                                      ID   => $item_id,
 815                                      SELF => $self,
 816   );
 817
 818   if ($::form->{insert_before_item_id}) {
 819     $self->js
 820       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 821   } else {
 822     $self->js
 823       ->append('#row_table_id', $row_as_html);
 824   }
 825
 826   if ( $item->part->is_assortment ) {
 827     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 828     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 829       my $attr = { parts_id => $assortment_item->parts_id,
 830                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 831                    unit     => $assortment_item->unit,
 832                    description => $assortment_item->part->description,
 833                  };
 834       my $item = new_item($self->order, $attr);
 835
 836       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 837       $item->discount(1) unless $assortment_item->charge;
 838
 839       $self->order->add_items( $item );
 840       $self->recalc();
 841       $self->get_item_cvpartnumber($item);
 842       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 843       my $row_as_html = $self->p->render('order/tabs/_row',
 844                                          ITEM => $item,
 845                                          ID   => $item_id,
 846                                          SELF => $self,
 847       );
 848       if ($::form->{insert_before_item_id}) {
 849         $self->js
 850           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 851       } else {
 852         $self->js
 853           ->append('#row_table_id', $row_as_html);
 854       }
 855     };
 856   };
 857
 858   $self->js
 859     ->val('.add_item_input', '')
 860     ->run('kivi.Order.init_row_handlers')
 861     ->run('kivi.Order.renumber_positions')
 862     ->focus('#add_item_parts_id_name');
 863
 864   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 865
 866   $self->js_redisplay_amounts_and_taxes;
 867   $self->js->render();
 868 }
 869
 870 # add item rows for multiple items at once
 871 sub action_add_multi_items {
 872   my ($self) = @_;
 873
 874   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 875   return $self->js->render() unless scalar @form_attr;
 876
 877   my @items;
 878   foreach my $attr (@form_attr) {
 879     my $item = new_item($self->order, $attr);
 880     push @items, $item;
 881     if ( $item->part->is_assortment ) {
 882       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 883         my $attr = { parts_id => $assortment_item->parts_id,
 884                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 885                      unit     => $assortment_item->unit,
 886                      description => $assortment_item->part->description,
 887                    };
 888         my $item = new_item($self->order, $attr);
 889
 890         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 891         $item->discount(1) unless $assortment_item->charge;
 892         push @items, $item;
 893       }
 894     }
 895   }
 896   $self->order->add_items(@items);
 897
 898   $self->recalc();
 899
 900   foreach my $item (@items) {
 901     $self->get_item_cvpartnumber($item);
 902     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 903     my $row_as_html = $self->p->render('order/tabs/_row',
 904                                        ITEM => $item,
 905                                        ID   => $item_id,
 906                                        SELF => $self,
 907     );
 908
 909     if ($::form->{insert_before_item_id}) {
 910       $self->js
 911         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 912     } else {
 913       $self->js
 914         ->append('#row_table_id', $row_as_html);
 915     }
 916   }
 917
 918   $self->js
 919     ->run('kivi.Part.close_picker_dialogs')
 920     ->run('kivi.Order.init_row_handlers')
 921     ->run('kivi.Order.renumber_positions')
 922     ->focus('#add_item_parts_id_name');
 923
 924   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 925
 926   $self->js_redisplay_amounts_and_taxes;
 927   $self->js->render();
 928 }
 929
 930 # recalculate all linetotals, amounts and taxes and redisplay them
 931 sub action_recalc_amounts_and_taxes {
 932   my ($self) = @_;
 933
 934   $self->recalc();
 935
 936   $self->js_redisplay_line_values;
 937   $self->js_redisplay_amounts_and_taxes;
 938   $self->js->render();
 939 }
 940
 941 sub action_update_exchangerate {
 942   my ($self) = @_;
 943
 944   my $data = {
 945     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 946     currency_name => $self->order->currency->name,
 947     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 948   };
 949
 950   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 951 }
 952
 953 # redisplay item rows if they are sorted by an attribute
 954 sub action_reorder_items {
 955   my ($self) = @_;
 956
 957   my %sort_keys = (
 958     partnumber   => sub { $_[0]->part->partnumber },
 959     description  => sub { $_[0]->description },
 960     qty          => sub { $_[0]->qty },
 961     sellprice    => sub { $_[0]->sellprice },
 962     discount     => sub { $_[0]->discount },
 963     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 964   );
 965
 966   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 967
 968   my $method = $sort_keys{$::form->{order_by}};
 969   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 970   if ($::form->{sort_dir}) {
 971     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 972       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 973     } else {
 974       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 975     }
 976   } else {
 977     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 978       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 979     } else {
 980       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 981     }
 982   }
 983   $self->js
 984     ->run('kivi.Order.redisplay_items', \@to_sort)
 985     ->render;
 986 }
 987
 988 # show the popup to choose a price/discount source
 989 sub action_price_popup {
 990   my ($self) = @_;
 991
 992   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 993   my $item = $self->order->items_sorted->[$idx];
 994
 995   $self->render_price_dialog($item);
 996 }
 997
 998 # save the order in a session variable and redirect to the part controller
 999 sub action_create_part {
1000   my ($self) = @_;
1001
1002   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1003
1004   my $callback     = $self->url_for(
1005     action       => 'return_from_create_part',
1006     type         => $self->type, # type is needed for check_auth on return
1007     previousform => $previousform,
1008   );
1009
1010   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1011
1012   my @redirect_params = (
1013     controller => 'Part',
1014     action     => 'add',
1015     part_type  => $::form->{add_item}->{create_part_type},
1016     callback   => $callback,
1017     show_abort => 1,
1018   );
1019
1020   $self->redirect_to(@redirect_params);
1021 }
1022
1023 sub action_return_from_create_part {
1024   my ($self) = @_;
1025
1026   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1027
1028   $::auth->restore_form_from_session(delete $::form->{previousform});
1029
1030   # set item ids to new fake id, to identify them as new items
1031   foreach my $item (@{$self->order->items_sorted}) {
1032     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1033   }
1034
1035   $self->recalc();
1036   $self->get_unalterable_data();
1037   $self->pre_render();
1038
1039   # trigger rendering values for second row/longdescription as hidden,
1040   # because they are loaded only on demand. So we need to keep the values
1041   # from the source.
1042   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1043   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1044
1045   $self->render(
1046     'order/form',
1047     title => $self->get_title_for('edit'),
1048     %{$self->{template_args}}
1049   );
1050
1051 }
1052
1053 # load the second row for one or more items
1054 #
1055 # This action gets the html code for all items second rows by rendering a template for
1056 # the second row and sets the html code via client js.
1057 sub action_load_second_rows {
1058   my ($self) = @_;
1059
1060   $self->recalc() if $self->order->is_sales; # for margin calculation
1061
1062   foreach my $item_id (@{ $::form->{item_ids} }) {
1063     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1064     my $item = $self->order->items_sorted->[$idx];
1065
1066     $self->js_load_second_row($item, $item_id, 0);
1067   }
1068
1069   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1070
1071   $self->js->render();
1072 }
1073
1074 # update description, notes and sellprice from master data
1075 sub action_update_row_from_master_data {
1076   my ($self) = @_;
1077
1078   foreach my $item_id (@{ $::form->{item_ids} }) {
1079     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1080     my $item  = $self->order->items_sorted->[$idx];
1081     my $texts = get_part_texts($item->part, $self->order->language_id);
1082
1083     $item->description($texts->{description});
1084     $item->longdescription($texts->{longdescription});
1085
1086     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1087
1088     my $price_src;
1089     if ($item->part->is_assortment) {
1090     # add assortment items with price 0, as the components carry the price
1091       $price_src = $price_source->price_from_source("");
1092       $price_src->price(0);
1093     } else {
1094       $price_src = $price_source->best_price
1095                  ? $price_source->best_price
1096                  : $price_source->price_from_source("");
1097       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1098       $price_src->price(0) if !$price_source->best_price;
1099     }
1100
1101
1102     $item->sellprice($price_src->price);
1103     $item->active_price_source($price_src);
1104
1105     $self->js
1106       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1107       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1108       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1109       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1110
1111     if ($self->search_cvpartnumber) {
1112       $self->get_item_cvpartnumber($item);
1113       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1114     }
1115   }
1116
1117   $self->recalc();
1118   $self->js_redisplay_line_values;
1119   $self->js_redisplay_amounts_and_taxes;
1120
1121   $self->js->render();
1122 }
1123
1124 sub js_load_second_row {
1125   my ($self, $item, $item_id, $do_parse) = @_;
1126
1127   if ($do_parse) {
1128     # Parse values from form (they are formated while rendering (template)).
1129     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1130     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1131     foreach my $var (@{ $item->cvars_by_config }) {
1132       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1133     }
1134     $item->parse_custom_variable_values;
1135   }
1136
1137   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1138
1139   $self->js
1140     ->html('#second_row_' . $item_id, $row_as_html)
1141     ->data('#second_row_' . $item_id, 'loaded', 1);
1142 }
1143
1144 sub js_redisplay_line_values {
1145   my ($self) = @_;
1146
1147   my $is_sales = $self->order->is_sales;
1148
1149   # sales orders with margins
1150   my @data;
1151   if ($is_sales) {
1152     @data = map {
1153       [
1154        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1155        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1156        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1157       ]} @{ $self->order->items_sorted };
1158   } else {
1159     @data = map {
1160       [
1161        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1162       ]} @{ $self->order->items_sorted };
1163   }
1164
1165   $self->js
1166     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1167 }
1168
1169 sub js_redisplay_amounts_and_taxes {
1170   my ($self) = @_;
1171
1172   if (scalar @{ $self->{taxes} }) {
1173     $self->js->show('#taxincluded_row_id');
1174   } else {
1175     $self->js->hide('#taxincluded_row_id');
1176   }
1177
1178   if ($self->order->taxincluded) {
1179     $self->js->hide('#subtotal_row_id');
1180   } else {
1181     $self->js->show('#subtotal_row_id');
1182   }
1183
1184   if ($self->order->is_sales) {
1185     my $is_neg = $self->order->marge_total < 0;
1186     $self->js
1187       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1188       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1189       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1190       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1191       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1192       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1193       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1194       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1195   }
1196
1197   $self->js
1198     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1199     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1200     ->remove('.tax_row')
1201     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1202 }
1203
1204 sub js_redisplay_cvpartnumbers {
1205   my ($self) = @_;
1206
1207   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1208
1209   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1210
1211   $self->js
1212     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1213 }
1214
1215 sub js_reset_order_and_item_ids_after_save {
1216   my ($self) = @_;
1217
1218   $self->js
1219     ->val('#id', $self->order->id)
1220     ->val('#converted_from_oe_id', '')
1221     ->val('#order_' . $self->nr_key(), $self->order->number);
1222
1223   my $idx = 0;
1224   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1225     next if !$self->order->items_sorted->[$idx]->id;
1226     next if $form_item_id !~ m{^new};
1227     $self->js
1228       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1229       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1230       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1231   } continue {
1232     $idx++;
1233   }
1234   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1235 }
1236
1237 #
1238 # helpers
1239 #
1240
1241 sub init_valid_types {
1242   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1243 }
1244
1245 sub init_type {
1246   my ($self) = @_;
1247
1248   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1249     die "Not a valid type for order";
1250   }
1251
1252   $self->type($::form->{type});
1253 }
1254
1255 sub init_cv {
1256   my ($self) = @_;
1257
1258   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1259          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1260          : die "Not a valid type for order";
1261
1262   return $cv;
1263 }
1264
1265 sub init_search_cvpartnumber {
1266   my ($self) = @_;
1267
1268   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1269   my $search_cvpartnumber;
1270   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1271   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1272
1273   return $search_cvpartnumber;
1274 }
1275
1276 sub init_show_update_button {
1277   my ($self) = @_;
1278
1279   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1280 }
1281
1282 sub init_p {
1283   SL::Presenter->get;
1284 }
1285
1286 sub init_order {
1287   $_[0]->make_order;
1288 }
1289
1290 sub init_all_price_factors {
1291   SL::DB::Manager::PriceFactor->get_all;
1292 }
1293
1294 sub init_part_picker_classification_ids {
1295   my ($self)    = @_;
1296   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1297
1298   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1299 }
1300
1301 sub check_auth {
1302   my ($self) = @_;
1303
1304   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1305
1306   my $right   = $right_for->{ $self->type };
1307   $right    ||= 'DOES_NOT_EXIST';
1308
1309   $::auth->assert($right);
1310 }
1311
1312 # build the selection box for contacts
1313 #
1314 # Needed, if customer/vendor changed.
1315 sub build_contact_select {
1316   my ($self) = @_;
1317
1318   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1319     value_key  => 'cp_id',
1320     title_key  => 'full_name_dep',
1321     default    => $self->order->cp_id,
1322     with_empty => 1,
1323     style      => 'width: 300px',
1324   );
1325 }
1326
1327 # build the selection box for the additional billing address
1328 #
1329 # Needed, if customer/vendor changed.
1330 sub build_billing_address_select {
1331   my ($self) = @_;
1332
1333   select_tag('order.billing_address_id',
1334              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1335              value_key  => 'id',
1336              title_key  => 'displayable_id',
1337              default    => $self->order->billing_address_id,
1338              with_empty => 0,
1339              style      => 'width: 300px',
1340   );
1341 }
1342
1343 # build the selection box for shiptos
1344 #
1345 # Needed, if customer/vendor changed.
1346 sub build_shipto_select {
1347   my ($self) = @_;
1348
1349   select_tag('order.shipto_id',
1350              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1351              value_key  => 'shipto_id',
1352              title_key  => 'displayable_id',
1353              default    => $self->order->shipto_id,
1354              with_empty => 0,
1355              style      => 'width: 300px',
1356   );
1357 }
1358
1359 # build the inputs for the cusom shipto dialog
1360 #
1361 # Needed, if customer/vendor changed.
1362 sub build_shipto_inputs {
1363   my ($self) = @_;
1364
1365   my $content = $self->p->render('common/_ship_to_dialog',
1366                                  vc_obj      => $self->order->customervendor,
1367                                  cs_obj      => $self->order->custom_shipto,
1368                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1369                                  id_selector => '#order_shipto_id');
1370
1371   div_tag($content, id => 'shipto_inputs');
1372 }
1373
1374 # render the info line for business
1375 #
1376 # Needed, if customer/vendor changed.
1377 sub build_business_info_row
1378 {
1379   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1380 }
1381
1382 # build the rows for displaying taxes
1383 #
1384 # Called if amounts where recalculated and redisplayed.
1385 sub build_tax_rows {
1386   my ($self) = @_;
1387
1388   my $rows_as_html;
1389   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1390     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1391   }
1392   return $rows_as_html;
1393 }
1394
1395
1396 sub render_price_dialog {
1397   my ($self, $record_item) = @_;
1398
1399   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1400
1401   $self->js
1402     ->run(
1403       'kivi.io.price_chooser_dialog',
1404       t8('Available Prices'),
1405       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1406     )
1407     ->reinit_widgets;
1408
1409 #   if (@errors) {
1410 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1411 #     $self->js->show('#dialog_flash_error');
1412 #   }
1413
1414   $self->js->render;
1415 }
1416
1417 sub load_order {
1418   my ($self) = @_;
1419
1420   return if !$::form->{id};
1421
1422   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1423
1424   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1425   # You need a custom shipto object to call cvars_by_config to get the cvars.
1426   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1427
1428   return $self->order;
1429 }
1430
1431 # load or create a new order object
1432 #
1433 # And assign changes from the form to this object.
1434 # If the order is loaded from db, check if items are deleted in the form,
1435 # remove them form the object and collect them for removing from db on saving.
1436 # Then create/update items from form (via make_item) and add them.
1437 sub make_order {
1438   my ($self) = @_;
1439
1440   # add_items adds items to an order with no items for saving, but they cannot
1441   # be retrieved via items until the order is saved. Adding empty items to new
1442   # order here solves this problem.
1443   my $order;
1444   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1445   $order ||= SL::DB::Order->new(orderitems  => [],
1446                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1447                                 currency_id => $::instance_conf->get_currency_id(),);
1448
1449   my $cv_id_method = $self->cv . '_id';
1450   if (!$::form->{id} && $::form->{$cv_id_method}) {
1451     $order->$cv_id_method($::form->{$cv_id_method});
1452     setup_order_from_cv($order);
1453   }
1454
1455   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1456   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1457
1458   $order->assign_attributes(%{$::form->{order}});
1459
1460   $self->setup_custom_shipto_from_form($order, $::form);
1461
1462   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1463     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1464     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1465   }
1466
1467   # remove deleted items
1468   $self->item_ids_to_delete([]);
1469   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1470     my $item = $order->orderitems->[$idx];
1471     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1472       splice @{$order->orderitems}, $idx, 1;
1473       push @{$self->item_ids_to_delete}, $item->id;
1474     }
1475   }
1476
1477   my @items;
1478   my $pos = 1;
1479   foreach my $form_attr (@{$form_orderitems}) {
1480     my $item = make_item($order, $form_attr);
1481     $item->position($pos);
1482     push @items, $item;
1483     $pos++;
1484   }
1485   $order->add_items(grep {!$_->id} @items);
1486
1487   return $order;
1488 }
1489
1490 # create or update items from form
1491 #
1492 # Make item objects from form values. For items already existing read from db.
1493 # Create a new item else. And assign attributes.
1494 sub make_item {
1495   my ($record, $attr) = @_;
1496
1497   my $item;
1498   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1499
1500   my $is_new = !$item;
1501
1502   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1503   # they cannot be retrieved via custom_variables until the order/orderitem is
1504   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1505   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1506
1507   $item->assign_attributes(%$attr);
1508
1509   if ($is_new) {
1510     my $texts = get_part_texts($item->part, $record->language_id);
1511     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1512     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1513     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1514   }
1515
1516   return $item;
1517 }
1518
1519 # create a new item
1520 #
1521 # This is used to add one item
1522 sub new_item {
1523   my ($record, $attr) = @_;
1524
1525   my $item = SL::DB::OrderItem->new;
1526
1527   # Remove attributes where the user left or set the inputs empty.
1528   # So these attributes will be undefined and we can distinguish them
1529   # from zero later on.
1530   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1531     delete $attr->{$_} if $attr->{$_} eq '';
1532   }
1533
1534   $item->assign_attributes(%$attr);
1535
1536   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1537   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1538
1539   $item->unit($part->unit) if !$item->unit;
1540
1541   my $price_src;
1542   if ( $part->is_assortment ) {
1543     # add assortment items with price 0, as the components carry the price
1544     $price_src = $price_source->price_from_source("");
1545     $price_src->price(0);
1546   } elsif (defined $item->sellprice) {
1547     $price_src = $price_source->price_from_source("");
1548     $price_src->price($item->sellprice);
1549   } else {
1550     $price_src = $price_source->best_price
1551                ? $price_source->best_price
1552                : $price_source->price_from_source("");
1553     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1554     $price_src->price(0) if !$price_source->best_price;
1555   }
1556
1557   my $discount_src;
1558   if (defined $item->discount) {
1559     $discount_src = $price_source->discount_from_source("");
1560     $discount_src->discount($item->discount);
1561   } else {
1562     $discount_src = $price_source->best_discount
1563                   ? $price_source->best_discount
1564                   : $price_source->discount_from_source("");
1565     $discount_src->discount(0) if !$price_source->best_discount;
1566   }
1567
1568   my %new_attr;
1569   $new_attr{part}                   = $part;
1570   $new_attr{description}            = $part->description     if ! $item->description;
1571   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1572   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1573   $new_attr{sellprice}              = $price_src->price;
1574   $new_attr{discount}               = $discount_src->discount;
1575   $new_attr{active_price_source}    = $price_src;
1576   $new_attr{active_discount_source} = $discount_src;
1577   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1578   $new_attr{project_id}             = $record->globalproject_id;
1579   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1580
1581   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1582   # they cannot be retrieved via custom_variables until the order/orderitem is
1583   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1584   $new_attr{custom_variables} = [];
1585
1586   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1587
1588   $item->assign_attributes(%new_attr, %{ $texts });
1589
1590   return $item;
1591 }
1592
1593 sub setup_order_from_cv {
1594   my ($order) = @_;
1595
1596   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1597
1598   $order->intnotes($order->customervendor->notes);
1599
1600   return if !$order->is_sales;
1601
1602   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1603   $order->taxincluded(defined($order->customer->taxincluded_checked)
1604                       ? $order->customer->taxincluded_checked
1605                       : $::myconfig{taxincluded_checked});
1606
1607   my $address = $order->customer->default_billing_address;;
1608   $order->billing_address_id($address ? $address->id : undef);
1609 }
1610
1611 # setup custom shipto from form
1612 #
1613 # The dialog returns form variables starting with 'shipto' and cvars starting
1614 # with 'shiptocvar_'.
1615 # Mark it to be deleted if a shipto from master data is selected
1616 # (i.e. order has a shipto).
1617 # Else, update or create a new custom shipto. If the fields are empty, it
1618 # will not be saved on save.
1619 sub setup_custom_shipto_from_form {
1620   my ($self, $order, $form) = @_;
1621
1622   if ($order->shipto) {
1623     $self->is_custom_shipto_to_delete(1);
1624   } else {
1625     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1626
1627     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1628     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1629
1630     $custom_shipto->assign_attributes(%$shipto_attrs);
1631     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1632   }
1633 }
1634
1635 # recalculate prices and taxes
1636 #
1637 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1638 sub recalc {
1639   my ($self) = @_;
1640
1641   my %pat = $self->order->calculate_prices_and_taxes();
1642
1643   $self->{taxes} = [];
1644   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1645     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1646
1647     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1648                                 netamount => $netamount,
1649                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1650   }
1651   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1652 }
1653
1654 # get data for saving, printing, ..., that is not changed in the form
1655 #
1656 # Only cvars for now.
1657 sub get_unalterable_data {
1658   my ($self) = @_;
1659
1660   foreach my $item (@{ $self->order->items }) {
1661     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1662     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1663     foreach my $var (@{ $item->cvars_by_config }) {
1664       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1665     }
1666     $item->parse_custom_variable_values;
1667   }
1668 }
1669
1670 # delete the order
1671 #
1672 # And remove related files in the spool directory
1673 sub delete {
1674   my ($self) = @_;
1675
1676   my $errors = [];
1677   my $db     = $self->order->db;
1678
1679   $db->with_transaction(
1680     sub {
1681       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1682       $self->order->delete;
1683       my $spool = $::lx_office_conf{paths}->{spool};
1684       unlink map { "$spool/$_" } @spoolfiles if $spool;
1685
1686       $self->save_history('DELETED');
1687
1688       1;
1689   }) || push(@{$errors}, $db->error);
1690
1691   return $errors;
1692 }
1693
1694 # save the order
1695 #
1696 # And delete items that are deleted in the form.
1697 sub save {
1698   my ($self) = @_;
1699
1700   my $errors = [];
1701   my $db     = $self->order->db;
1702
1703   $db->with_transaction(sub {
1704     # delete custom shipto if it is to be deleted or if it is empty
1705     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1706       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1707       $self->order->custom_shipto(undef);
1708     }
1709
1710     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1711     $self->order->save(cascade => 1);
1712
1713     # link records
1714     if ($::form->{converted_from_oe_id}) {
1715       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1716
1717       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1718         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1719         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1720         $src->link_to_record($self->order);
1721       }
1722       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1723         my $idx = 0;
1724         foreach (@{ $self->order->items_sorted }) {
1725           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1726           next if !$from_id;
1727           SL::DB::RecordLink->new(from_table => 'orderitems',
1728                                   from_id    => $from_id,
1729                                   to_table   => 'orderitems',
1730                                   to_id      => $_->id
1731           )->save;
1732           $idx++;
1733         }
1734       }
1735
1736       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1737     }
1738
1739     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1740
1741     $self->save_history('SAVED');
1742
1743     1;
1744   }) || push(@{$errors}, $db->error);
1745
1746   return $errors;
1747 }
1748
1749 sub workflow_sales_or_request_for_quotation {
1750   my ($self) = @_;
1751
1752   # always save
1753   my $errors = $self->save();
1754
1755   if (scalar @{ $errors }) {
1756     $self->js->flash('error', $_) for @{ $errors };
1757     return $self->js->render();
1758   }
1759
1760   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1761
1762   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1763   $self->{converted_from_oe_id} = delete $::form->{id};
1764
1765   # set item ids to new fake id, to identify them as new items
1766   foreach my $item (@{$self->order->items_sorted}) {
1767     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1768   }
1769
1770   # change form type
1771   $::form->{type} = $destination_type;
1772   $self->type($self->init_type);
1773   $self->cv  ($self->init_cv);
1774   $self->check_auth;
1775
1776   $self->recalc();
1777   $self->get_unalterable_data();
1778   $self->pre_render();
1779
1780   # trigger rendering values for second row as hidden, because they
1781   # are loaded only on demand. So we need to keep the values from the
1782   # source.
1783   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1784
1785   $self->render(
1786     'order/form',
1787     title => $self->get_title_for('edit'),
1788     %{$self->{template_args}}
1789   );
1790 }
1791
1792 sub workflow_sales_or_purchase_order {
1793   my ($self) = @_;
1794
1795   # always save
1796   my $errors = $self->save();
1797
1798   if (scalar @{ $errors }) {
1799     $self->js->flash('error', $_) foreach @{ $errors };
1800     return $self->js->render();
1801   }
1802
1803   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1804                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1805                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1806                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1807                        : '';
1808
1809   # check for direct delivery
1810   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1811   my $custom_shipto;
1812   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1813       && $::form->{use_shipto} && $self->order->shipto) {
1814     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1815   }
1816
1817   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1818   $self->{converted_from_oe_id} = delete $::form->{id};
1819
1820   # set item ids to new fake id, to identify them as new items
1821   foreach my $item (@{$self->order->items_sorted}) {
1822     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1823   }
1824
1825   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1826     if ($::form->{use_shipto}) {
1827       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1828     } else {
1829       # remove any custom shipto if not wanted
1830       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1831     }
1832   }
1833
1834   # change form type
1835   $::form->{type} = $destination_type;
1836   $self->type($self->init_type);
1837   $self->cv  ($self->init_cv);
1838   $self->check_auth;
1839
1840   $self->recalc();
1841   $self->get_unalterable_data();
1842   $self->pre_render();
1843
1844   # trigger rendering values for second row as hidden, because they
1845   # are loaded only on demand. So we need to keep the values from the
1846   # source.
1847   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1848
1849   $self->render(
1850     'order/form',
1851     title => $self->get_title_for('edit'),
1852     %{$self->{template_args}}
1853   );
1854 }
1855
1856
1857 sub pre_render {
1858   my ($self) = @_;
1859
1860   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1861   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1862   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1863   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1864   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1865                                                                                               deleted => 0 ] ],
1866                                                                            sort_by => 'name');
1867   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1868                                                                                               deleted => 0 ] ],
1869                                                                            sort_by => 'name');
1870   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1871                                                                                                         obsolete => 0 ] ]);
1872   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1873   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1874   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1875   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1876   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1877
1878   my $print_form = Form->new('');
1879   $print_form->{type}        = $self->type;
1880   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1881   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1882     form => $print_form,
1883     options => {dialog_name_prefix => 'print_options.',
1884                 show_headers       => 1,
1885                 no_queue           => 1,
1886                 no_postscript      => 1,
1887                 no_opendocument    => 0,
1888                 no_html            => 1},
1889   );
1890
1891   foreach my $item (@{$self->order->orderitems}) {
1892     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1893     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1894     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1895   }
1896
1897   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1898     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1899     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1900     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1901     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1902   }
1903
1904   if ($self->order->number && $::instance_conf->get_webdav) {
1905     my $webdav = SL::Webdav->new(
1906       type     => $self->type,
1907       number   => $self->order->number,
1908     );
1909     my @all_objects = $webdav->get_all_objects;
1910     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1911                                                     type => t8('File'),
1912                                                     link => File::Spec->catfile($_->full_filedescriptor),
1913                                                 } } @all_objects;
1914   }
1915
1916   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1917       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1918     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1919   }
1920
1921   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1922
1923   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1924                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
1925   $self->setup_edit_action_bar;
1926 }
1927
1928 sub setup_edit_action_bar {
1929   my ($self, %params) = @_;
1930
1931   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1932                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1933                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1934
1935   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
1936   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
1937
1938   for my $bar ($::request->layout->get('actionbar')) {
1939     $bar->add(
1940       combobox => [
1941         action => [
1942           t8('Save'),
1943           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1944                                                     $::instance_conf->get_order_warn_no_deliverydate,
1945           ],
1946           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
1947                          @req_trans_cost_art, @req_cusordnumber,
1948           ],
1949         ],
1950         action => [
1951           t8('Save as new'),
1952           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1953           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1954                          @req_trans_cost_art, @req_cusordnumber,
1955           ],
1956           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1957         ],
1958       ], # end of combobox "Save"
1959
1960       combobox => [
1961         action => [
1962           t8('Workflow'),
1963         ],
1964         action => [
1965           t8('Save and Quotation'),
1966           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1967           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
1968           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1969         ],
1970         action => [
1971           t8('Save and RFQ'),
1972           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1973           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1974         ],
1975         action => [
1976           t8('Save and Sales Order'),
1977           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1978           checks   => [ @req_trans_cost_art ],
1979           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1980         ],
1981         action => [
1982           t8('Save and Purchase Order'),
1983           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1984           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
1985           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1986         ],
1987         action => [
1988           t8('Save and Delivery Order'),
1989           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1990                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1991                                                                                                                         ],
1992           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
1993                          @req_trans_cost_art, @req_cusordnumber,
1994           ],
1995           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1996         ],
1997         action => [
1998           t8('Save and Invoice'),
1999           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2000           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2001                          @req_trans_cost_art, @req_cusordnumber,
2002           ],
2003         ],
2004         action => [
2005           t8('Save and AP Transaction'),
2006           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2007           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
2008         ],
2009
2010       ], # end of combobox "Workflow"
2011
2012       combobox => [
2013         action => [
2014           t8('Export'),
2015         ],
2016         action => [
2017           t8('Save and preview PDF'),
2018           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2019                                                         $::instance_conf->get_order_warn_no_deliverydate,
2020                     ],
2021           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2022         ],
2023         action => [
2024           t8('Save and print'),
2025           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2026                                                        $::instance_conf->get_order_warn_no_deliverydate,
2027                     ],
2028           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2029         ],
2030         action => [
2031           t8('Save and E-mail'),
2032           id   => 'save_and_email_action',
2033           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2034                                                                      $::instance_conf->get_order_warn_no_deliverydate,
2035                   ],
2036           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2037         ],
2038         action => [
2039           t8('Download attachments of all parts'),
2040           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2041           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2042           only_if  => $::instance_conf->get_doc_storage,
2043         ],
2044       ], # end of combobox "Export"
2045
2046       action => [
2047         t8('Delete'),
2048         call     => [ 'kivi.Order.delete_order' ],
2049         confirm  => $::locale->text('Do you really want to delete this object?'),
2050         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2051         only_if  => $deletion_allowed,
2052       ],
2053
2054       combobox => [
2055         action => [
2056           t8('more')
2057         ],
2058         action => [
2059           t8('History'),
2060           call     => [ 'set_history_window', $self->order->id, 'id' ],
2061           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2062         ],
2063         action => [
2064           t8('Follow-Up'),
2065           call     => [ 'kivi.Order.follow_up_window' ],
2066           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2067           only_if  => $::auth->assert('productivity', 1),
2068         ],
2069       ], # end of combobox "more"
2070     );
2071   }
2072 }
2073
2074 sub generate_pdf {
2075   my ($self, $pdf_ref, $params) = @_;
2076
2077   my $order  = $self->order;
2078   my @errors = ();
2079
2080   my $print_form = Form->new('');
2081   $print_form->{type}        = $order->type;
2082   $print_form->{formname}    = $params->{formname} || $order->type;
2083   $print_form->{format}      = $params->{format}   || 'pdf';
2084   $print_form->{media}       = $params->{media}    || 'file';
2085   $print_form->{groupitems}  = $params->{groupitems};
2086   $print_form->{printer_id}  = $params->{printer_id};
2087   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2088
2089   $order->language($params->{language});
2090   $order->flatten_to_form($print_form, format_amounts => 1);
2091
2092   my $template_ext;
2093   my $template_type;
2094   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2095     $template_ext  = 'odt';
2096     $template_type = 'OpenDocument';
2097   }
2098
2099   # search for the template
2100   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2101     name        => $print_form->{formname},
2102     extension   => $template_ext,
2103     email       => $print_form->{media} eq 'email',
2104     language    => $params->{language},
2105     printer_id  => $print_form->{printer_id},
2106   );
2107
2108   if (!defined $template_file) {
2109     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2110   }
2111
2112   return @errors if scalar @errors;
2113
2114   $print_form->throw_on_error(sub {
2115     eval {
2116       $print_form->prepare_for_printing;
2117
2118       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
2119         format        => $print_form->{format},
2120         template_type => $template_type,
2121         template      => $template_file,
2122         variables     => $print_form,
2123         variable_content_types => {
2124           longdescription => 'html',
2125           partnotes       => 'html',
2126           notes           => 'html',
2127         },
2128       );
2129       1;
2130     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2131   });
2132
2133   return @errors;
2134 }
2135
2136 sub get_files_for_email_dialog {
2137   my ($self) = @_;
2138
2139   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2140
2141   return %files if !$::instance_conf->get_doc_storage;
2142
2143   if ($self->order->id) {
2144     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2145     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2146     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2147     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2148   }
2149
2150   my @parts =
2151     uniq_by { $_->{id} }
2152     map {
2153       +{ id         => $_->part->id,
2154          partnumber => $_->part->partnumber }
2155     } @{$self->order->items_sorted};
2156
2157   foreach my $part (@parts) {
2158     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2159     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2160   }
2161
2162   foreach my $key (keys %files) {
2163     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2164   }
2165
2166   return %files;
2167 }
2168
2169 sub make_periodic_invoices_config_from_yaml {
2170   my ($yaml_config) = @_;
2171
2172   return if !$yaml_config;
2173   my $attr = SL::YAML::Load($yaml_config);
2174   return if 'HASH' ne ref $attr;
2175   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2176 }
2177
2178
2179 sub get_periodic_invoices_status {
2180   my ($self, $config) = @_;
2181
2182   return                      if $self->type ne sales_order_type();
2183   return t8('not configured') if !$config;
2184
2185   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2186              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2187              :                                                     die "Cannot get status of periodic invoices config";
2188
2189   return $active ? t8('active') : t8('inactive');
2190 }
2191
2192 sub get_title_for {
2193   my ($self, $action) = @_;
2194
2195   return '' if none { lc($action)} qw(add edit);
2196
2197   # for locales:
2198   # $::locale->text("Add Sales Order");
2199   # $::locale->text("Add Purchase Order");
2200   # $::locale->text("Add Quotation");
2201   # $::locale->text("Add Request for Quotation");
2202   # $::locale->text("Edit Sales Order");
2203   # $::locale->text("Edit Purchase Order");
2204   # $::locale->text("Edit Quotation");
2205   # $::locale->text("Edit Request for Quotation");
2206
2207   $action = ucfirst(lc($action));
2208   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2209        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2210        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2211        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2212        : '';
2213 }
2214
2215 sub get_item_cvpartnumber {
2216   my ($self, $item) = @_;
2217
2218   return if !$self->search_cvpartnumber;
2219   return if !$self->order->customervendor;
2220
2221   if ($self->cv eq 'vendor') {
2222     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2223     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2224   } elsif ($self->cv eq 'customer') {
2225     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2226     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2227   }
2228 }
2229
2230 sub get_part_texts {
2231   my ($part_or_id, $language_or_id, %defaults) = @_;
2232
2233   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2234   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2235   my $texts       = {
2236     description     => $defaults{description}     // $part->description,
2237     longdescription => $defaults{longdescription} // $part->notes,
2238   };
2239
2240   return $texts unless $language_id;
2241
2242   my $translation = SL::DB::Manager::Translation->get_first(
2243     where => [
2244       parts_id    => $part->id,
2245       language_id => $language_id,
2246     ]);
2247
2248   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2249   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2250
2251   return $texts;
2252 }
2253
2254 sub sales_order_type {
2255   'sales_order';
2256 }
2257
2258 sub purchase_order_type {
2259   'purchase_order';
2260 }
2261
2262 sub sales_quotation_type {
2263   'sales_quotation';
2264 }
2265
2266 sub request_quotation_type {
2267   'request_quotation';
2268 }
2269
2270 sub nr_key {
2271   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2272        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2273        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2274        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2275        : '';
2276 }
2277
2278 sub save_and_redirect_to {
2279   my ($self, %params) = @_;
2280
2281   my $errors = $self->save();
2282
2283   if (scalar @{ $errors }) {
2284     $self->js->flash('error', $_) foreach @{ $errors };
2285     return $self->js->render();
2286   }
2287
2288   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2289            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2290            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2291            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2292            : '';
2293   flash_later('info', $text);
2294
2295   $self->redirect_to(%params, id => $self->order->id);
2296 }
2297
2298 sub save_history {
2299   my ($self, $addition) = @_;
2300
2301   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2302   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2303
2304   SL::DB::History->new(
2305     trans_id    => $self->order->id,
2306     employee_id => SL::DB::Manager::Employee->current->id,
2307     what_done   => $self->order->type,
2308     snumbers    => $snumbers,
2309     addition    => $addition,
2310   )->save;
2311 }
2312
2313 sub store_pdf_to_webdav_and_filemanagement {
2314   my ($self, $content, $filename) = @_;
2315
2316   my $order = $self->order;
2317   my @errors;
2318
2319   # copy file to webdav folder
2320   if ($order->number && $::instance_conf->get_webdav_documents) {
2321     my $webdav = SL::Webdav->new(
2322       type     => $order->type,
2323       number   => $order->number,
2324     );
2325     my $webdav_file = SL::Webdav::File->new(
2326       webdav   => $webdav,
2327       filename => $filename,
2328     );
2329     eval {
2330       $webdav_file->store(data => \$content);
2331       1;
2332     } or do {
2333       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2334     };
2335   }
2336   if ($order->id && $::instance_conf->get_doc_storage) {
2337     eval {
2338       SL::File->save(object_id     => $order->id,
2339                      object_type   => $order->type,
2340                      mime_type     => 'application/pdf',
2341                      source        => 'created',
2342                      file_type     => 'document',
2343                      file_name     => $filename,
2344                      file_contents => $content);
2345       1;
2346     } or do {
2347       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2348     };
2349   }
2350
2351   return @errors;
2352 }
2353
2354 sub link_requirement_specs_linking_to_created_from_objects {
2355   my ($self, @converted_from_oe_ids) = @_;
2356
2357   return unless @converted_from_oe_ids;
2358
2359   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2360   foreach my $rs_order (@{ $rs_orders }) {
2361     SL::DB::RequirementSpecOrder->new(
2362       order_id            => $self->order->id,
2363       requirement_spec_id => $rs_order->requirement_spec_id,
2364       version_id          => $rs_order->version_id,
2365     )->save;
2366   }
2367 }
2368
2369 sub set_project_in_linked_requirement_specs {
2370   my ($self) = @_;
2371
2372   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2373   foreach my $rs_order (@{ $rs_orders }) {
2374     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2375
2376     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2377   }
2378 }
2379
2380 1;
2381
2382 __END__
2383
2384 =encoding utf-8
2385
2386 =head1 NAME
2387
2388 SL::Controller::Order - controller for orders
2389
2390 =head1 SYNOPSIS
2391
2392 This is a new form to enter orders, completely rewritten with the use
2393 of controller and java script techniques.
2394
2395 The aim is to provide the user a better experience and a faster workflow. Also
2396 the code should be more readable, more reliable and better to maintain.
2397
2398 =head2 Key Features
2399
2400 =over 4
2401
2402 =item *
2403
2404 One input row, so that input happens every time at the same place.
2405
2406 =item *
2407
2408 Use of pickers where possible.
2409
2410 =item *
2411
2412 Possibility to enter more than one item at once.
2413
2414 =item *
2415
2416 Item list in a scrollable area, so that the workflow buttons stay at
2417 the bottom.
2418
2419 =item *
2420
2421 Reordering item rows with drag and drop is possible. Sorting item rows is
2422 possible (by partnumber, description, qty, sellprice and discount for now).
2423
2424 =item *
2425
2426 No C<update> is necessary. All entries and calculations are managed
2427 with ajax-calls and the page only reloads on C<save>.
2428
2429 =item *
2430
2431 User can see changes immediately, because of the use of java script
2432 and ajax.
2433
2434 =back
2435
2436 =head1 CODE
2437
2438 =head2 Layout
2439
2440 =over 4
2441
2442 =item * C<SL/Controller/Order.pm>
2443
2444 the controller
2445
2446 =item * C<template/webpages/order/form.html>
2447
2448 main form
2449
2450 =item * C<template/webpages/order/tabs/basic_data.html>
2451
2452 Main tab for basic_data.
2453
2454 This is the only tab here for now. "linked records" and "webdav" tabs are
2455 reused from generic code.
2456
2457 =over 4
2458
2459 =item * C<template/webpages/order/tabs/_business_info_row.html>
2460
2461 For displaying information on business type
2462
2463 =item * C<template/webpages/order/tabs/_item_input.html>
2464
2465 The input line for items
2466
2467 =item * C<template/webpages/order/tabs/_row.html>
2468
2469 One row for already entered items
2470
2471 =item * C<template/webpages/order/tabs/_tax_row.html>
2472
2473 Displaying tax information
2474
2475 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2476
2477 Dialog for selecting price and discount sources
2478
2479 =back
2480
2481 =item * C<js/kivi.Order.js>
2482
2483 java script functions
2484
2485 =back
2486
2487 =head1 TODO
2488
2489 =over 4
2490
2491 =item * testing
2492
2493 =item * price sources: little symbols showing better price / better discount
2494
2495 =item * select units in input row?
2496
2497 =item * check for direct delivery (workflow sales order -> purchase order)
2498
2499 =item * access rights
2500
2501 =item * display weights
2502
2503 =item * mtime check
2504
2505 =item * optional client/user behaviour
2506
2507 (transactions has to be set - department has to be set -
2508  force project if enabled in client config)
2509
2510 =back
2511
2512 =head1 KNOWN BUGS AND CAVEATS
2513
2514 =over 4
2515
2516 =item *
2517
2518 Customer discount is not displayed as a valid discount in price source popup
2519 (this might be a bug in price sources)
2520
2521 (I cannot reproduce this (Bernd))
2522
2523 =item *
2524
2525 No indication that <shift>-up/down expands/collapses second row.
2526
2527 =item *
2528
2529 Inline creation of parts is not currently supported
2530
2531 =item *
2532
2533 Table header is not sticky in the scrolling area.
2534
2535 =item *
2536
2537 Sorting does not include C<position>, neither does reordering.
2538
2539 This behavior was implemented intentionally. But we can discuss, which behavior
2540 should be implemented.
2541
2542 =back
2543
2544 =head1 To discuss / Nice to have
2545
2546 =over 4
2547
2548 =item *
2549
2550 How to expand/collapse second row. Now it can be done clicking the icon or
2551 <shift>-up/down.
2552
2553 =item *
2554
2555 Possibility to select PriceSources in input row?
2556
2557 =item *
2558
2559 This controller uses a (changed) copy of the template for the PriceSource
2560 dialog. Maybe there could be used one code source.
2561
2562 =item *
2563
2564 Rounding-differences between this controller (PriceTaxCalculator) and the old
2565 form. This is not only a problem here, but also in all parts using the PTC.
2566 There exists a ticket and a patch. This patch should be testet.
2567
2568 =item *
2569
2570 An indicator, if the actual inputs are saved (like in an
2571 editor or on text processing application).
2572
2573 =item *
2574
2575 A warning when leaving the page without saveing unchanged inputs.
2576
2577
2578 =back
2579
2580 =head1 AUTHOR
2581
2582 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2583
2584 =cut