SL/Controller/Project.pm

   1 package SL::Controller::Project;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Clone qw(clone);
   8
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ParseFilter;
  11 use SL::Controller::Helper::ReportGenerator;
  12 use SL::CVar;
  13 use SL::DB::Customer;
  14 use SL::DB::DeliveryOrder;
  15 use SL::DB::Employee;
  16 use SL::DB::Invoice;
  17 use SL::DB::Order;
  18 use SL::DB::Project;
  19 use SL::DB::ProjectType;
  20 use SL::DB::ProjectStatus;
  21 use SL::DB::PurchaseInvoice;
  22 use SL::DB::ProjectType;
  23 use SL::Helper::Flash;
  24 use SL::Locale::String;
  25
  26 use Data::Dumper;
  27 use JSON;
  28 use Rose::DB::Object::Helpers qw(as_tree);
  29
  30 use Rose::Object::MakeMethods::Generic
  31 (
  32  scalar => [ qw(project) ],
  33  'scalar --get_set_init' => [ qw(models customers project_types project_statuses projects linked_records employees may_edit_invoice_permissions
  34                                  cvar_configs includeable_cvar_configs include_cvars) ],
  35 );
  36
  37 __PACKAGE__->run_before('check_auth',   except => [ qw(ajax_autocomplete) ]);
  38 __PACKAGE__->run_before('load_project', only   => [ qw(edit update destroy) ]);
  39 __PACKAGE__->run_before('use_multiselect_js', only => [ qw(new create edit update) ]);
  40
  41 #
  42 # actions
  43 #
  44
  45 sub action_list {
  46   my ($self) = @_;
  47
  48   $self->setup_list_action_bar;
  49
  50   $self->make_filter_summary;
  51
  52   $self->prepare_report;
  53
  54   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  55 }
  56
  57 sub action_new {
  58   my ($self) = @_;
  59
  60   $self->project(SL::DB::Project->new);
  61   $self->display_form(title    => $::locale->text('Create a new project'),
  62                       callback => $::form->{callback} || $self->url_for(action => 'list'));
  63 }
  64
  65 sub action_edit {
  66   my ($self) = @_;
  67
  68   $self->display_form(title    => $::locale->text('Edit project #1', $self->project->projectnumber),
  69                       callback => $::form->{callback} || $self->url_for(action => 'list'));
  70 }
  71
  72 sub action_create {
  73   my ($self) = @_;
  74
  75   $self->project(SL::DB::Project->new);
  76   $self->create_or_update;
  77 }
  78
  79 sub action_update {
  80   my ($self) = @_;
  81   $self->create_or_update;
  82 }
  83
  84 sub action_destroy {
  85   my ($self) = @_;
  86
  87   if (eval { $self->project->delete; 1; }) {
  88     flash_later('info',  $::locale->text('The project has been deleted.'));
  89   } else {
  90     flash_later('error', $::locale->text('The project is in use and cannot be deleted.'));
  91   }
  92
  93   $self->redirect_to(action => 'list');
  94 }
  95
  96 sub action_ajax_autocomplete {
  97   my ($self, %params) = @_;
  98
  99   $::form->{filter}{'all:substr:multi::ilike'} =~ s{[\(\)]+}{}g;
 100
 101   # if someone types something, and hits enter, assume he entered the full name.
 102   # if something matches, treat that as the sole match
 103   # since we need a second get models instance with different filters for that,
 104   # we only modify the original filter temporarily in place
 105   if ($::form->{prefer_exact}) {
 106     local $::form->{filter}{'all::ilike'} = delete local $::form->{filter}{'all:substr:multi::ilike'};
 107     # active and valid filters are use as they are
 108
 109     my $exact_models = SL::Controller::Helper::GetModels->new(
 110       controller   => $self,
 111       sorted       => 0,
 112       paginated    => { per_page => 2 },
 113       with_objects => [ 'customer', 'project_status', 'project_type' ],
 114     );
 115     my $exact_matches;
 116     if (1 == scalar @{ $exact_matches = $exact_models->get }) {
 117       $self->project($exact_matches);
 118     }
 119   }
 120
 121   $::form->{sort_by} = 'customer_and_description';
 122
 123   my $description_style = ($::form->{description_style} =~ m{both|number|description|full})
 124                         ? $::form->{description_style}
 125                         : 'full';
 126
 127   my @hashes = map {
 128    +{
 129      value         => $_->full_description(style => $description_style),
 130      label         => $_->full_description(style => $description_style),
 131      id            => $_->id,
 132      projectnumber => $_->projectnumber,
 133      description   => $_->description,
 134      cvars         => { map { ($_->config->name => { value => $_->value_as_text, is_valid => $_->is_valid }) } @{ $_->cvars_by_config } },
 135     }
 136   } @{ $self->projects }; # neato: if exact match triggers we don't even need the init_projects
 137
 138   $self->render(\ SL::JSON::to_json(\@hashes), { layout => 0, type => 'json', process => 0 });
 139 }
 140
 141 sub action_test_page {
 142   $_[0]->render('project/test_page');
 143 }
 144
 145 sub action_project_picker_search {
 146   $_[0]->render('project/project_picker_search', { layout => 0 });
 147 }
 148
 149 sub action_project_picker_result {
 150   $_[0]->render('project/_project_picker_result', { layout => 0 });
 151 }
 152
 153 #
 154 # filters
 155 #
 156
 157 sub check_auth {
 158   $::auth->assert('project_edit');
 159 }
 160
 161 #
 162 # helpers
 163 #
 164
 165 sub init_project_statuses { SL::DB::Manager::ProjectStatus->get_all_sorted }
 166 sub init_project_types    { SL::DB::Manager::ProjectType->get_all_sorted   }
 167 sub init_employees        { SL::DB::Manager::Employee->get_all_sorted   }
 168 sub init_may_edit_invoice_permissions { $::auth->assert('project_edit_view_invoices_permission', 1) }
 169 sub init_cvar_configs                 { SL::DB::Manager::CustomVariableConfig->get_all_sorted(where => [ module => 'Projects' ]) }
 170 sub init_includeable_cvar_configs     { [ grep { $_->includeable } @{ $_[0]->cvar_configs } ] };
 171
 172 sub init_include_cvars {
 173   my ($self) = @_;
 174   return { map { ($_->name => $::form->{"include_cvars_" . $_->name}) }       @{ $self->cvar_configs } } if $::form->{_include_cvars_from_form};
 175   return { map { ($_->name => ($_->includeable && $_->included_by_default)) } @{ $self->cvar_configs } };
 176 }
 177
 178 sub init_linked_records {
 179   my ($self) = @_;
 180   return [
 181     map  { @{ $_ } }
 182     grep { $_      } (
 183       SL::DB::Manager::Invoice->        get_all(where        => [ invoice => 1, or => [ globalproject_id => $self->project->id, 'invoiceitems.project_id' => $self->project->id ] ],
 184                                                 with_objects => [ 'invoiceitems', 'customer' ],
 185                                                 distinct     => [ 'customer' ],
 186                                                 sort_by       => 'transdate ASC'),
 187       SL::DB::Manager::Invoice->        get_all(where        => [ invoice => 0, or => [ globalproject_id => $self->project->id, 'transactions.project_id' => $self->project->id ] ],
 188                                                 with_objects => [ 'transactions', 'customer' ],
 189                                                 distinct     => [ 'customer' ],
 190                                                 sort_by       => 'transdate ASC'),
 191       SL::DB::Manager::PurchaseInvoice->get_all(where => [ invoice => 1,
 192                                                            or => [ globalproject_id => $self->project->id, 'invoiceitems.project_id' => $self->project->id ]
 193                                                          ],
 194                                                 with_objects => [ 'invoiceitems', 'vendor' ],
 195                                                 distinct     => [ 'customer' ],
 196                                                 sort_by => 'transdate ASC'),
 197       SL::DB::Manager::PurchaseInvoice->get_all(where => [ invoice => 0,
 198                                                            or => [ globalproject_id => $self->project->id, 'transactions.project_id' => $self->project->id ]
 199                                                          ],
 200                                                 with_objects => [ 'transactions', 'vendor' ],
 201                                                 distinct     => [ 'customer' ],
 202                                                 sort_by => 'transdate ASC'),
 203       SL::DB::Manager::GLTransaction->  get_all(where => [ 'transactions.project_id' => $self->project->id ],
 204                                                 with_objects => [ 'transactions' ],
 205                                                 distinct     => 1,
 206                                                 sort_by => 'transdate ASC'),
 207       SL::DB::Manager::Order->          get_all(where => [ or => [ globalproject_id => $self->project->id, 'orderitems.project_id' => $self->project->id ] ],
 208                                                 with_objects => [ 'orderitems', 'customer', 'vendor' ],
 209                                                 distinct => [ 'customer', 'vendor' ],
 210                                                 sort_by => 'transdate ASC' ),
 211       SL::DB::Manager::DeliveryOrder->  get_all(where => [ or => [ globalproject_id => $self->project->id, 'orderitems.project_id' => $self->project->id ] ],
 212                                                 with_objects => [ 'orderitems', 'customer', 'vendor' ],
 213                                                 distinct => [ 'customer', 'vendor' ],
 214                                                 sort_by => 'transdate ASC'),
 215     )];
 216 }
 217
 218
 219 sub init_projects {
 220   if ($::form->{no_paginate}) {
 221     $_[0]->models->disable_plugin('paginated');
 222   }
 223
 224   $_[0]->models->get;
 225 }
 226
 227 sub init_customers {
 228   my ($self)      = @_;
 229   my @customer_id = $self->project && $self->project->customer_id ? (id => $self->project->customer_id) : ();
 230
 231   return SL::DB::Manager::Customer->get_all_sorted(where => [ or => [ obsolete => 0, obsolete => undef, @customer_id ]]);
 232 }
 233
 234 sub use_multiselect_js {
 235   $::request->layout->use_javascript("${_}.js") for qw(jquery.selectboxes jquery.multiselect2side);
 236 }
 237
 238 sub display_form {
 239   my ($self, %params) = @_;
 240
 241   $params{CUSTOM_VARIABLES}  = CVar->get_custom_variables(module => 'Projects', trans_id => $self->project->id);
 242
 243   if ($params{keep_cvars}) {
 244     for my $cvar (@{ $params{CUSTOM_VARIABLES} }) {
 245       $cvar->{value} = $::form->{"cvar_$cvar->{name}"} if $::form->{"cvar_$cvar->{name}"};
 246     }
 247   }
 248
 249   CVar->render_inputs(variables => $params{CUSTOM_VARIABLES}) if @{ $params{CUSTOM_VARIABLES} };
 250
 251   $::request->layout->use_javascript("$_.js") for qw(kivi.File ckeditor/ckeditor ckeditor/adapters/jquery);
 252   $self->setup_edit_action_bar(callback => $params{callback});
 253
 254   $self->render('project/form', %params);
 255 }
 256
 257 sub create_or_update {
 258   my $self   = shift;
 259   my $is_new = !$self->project->id;
 260   my $params = delete($::form->{project}) || { };
 261
 262   if (!$self->may_edit_invoice_permissions) {
 263     delete $params->{employee_invoice_permissions};
 264   } elsif (!$params->{employee_invoice_permissions}) {
 265     $params->{employee_invoice_permissions} = [];
 266   }
 267
 268   delete $params->{id};
 269   $self->project->assign_attributes(%{ $params });
 270
 271   my @errors = $self->project->validate;
 272
 273   if (@errors) {
 274     flash('error', @errors);
 275     $self->display_form(title    => $is_new ? $::locale->text('Create a new project') : $::locale->text('Edit project'),
 276                         callback => $::form->{callback},
 277                         keep_cvars => 1);
 278     return;
 279   }
 280
 281   $self->project->save;
 282
 283   CVar->save_custom_variables(
 284     dbh          => $self->project->db->dbh,
 285     module       => 'Projects',
 286     trans_id     => $self->project->id,
 287     variables    => $::form,
 288     always_valid => 1,
 289   );
 290
 291   flash_later('info', $is_new ? $::locale->text('The project has been created.') : $::locale->text('The project has been saved.'));
 292
 293   $self->redirect_to($::form->{callback} || (action => 'search'));
 294 }
 295
 296 sub load_project {
 297   my ($self) = @_;
 298   $self->project(SL::DB::Project->new(id => $::form->{id})->load);
 299 }
 300
 301
 302 sub prepare_report {
 303   my ($self)      = @_;
 304
 305   my $callback    = $self->models->get_callback;
 306
 307   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 308   $self->{report} = $report;
 309
 310   my @columns     = qw(project_status customer projectnumber description active valid project_type);
 311   my @sortable    = qw(projectnumber description customer              project_type project_status);
 312
 313   my %column_defs = (
 314     projectnumber => { obj_link => sub { $self->url_for(action => 'edit', id => $_[0]->id, callback => $callback) } },
 315     description   => { obj_link => sub { $self->url_for(action => 'edit', id => $_[0]->id, callback => $callback) } },
 316     project_type  => { sub  => sub { $_[0]->project_type->description } },
 317     project_status => { sub  => sub { $_[0]->project_status->description }, text => t8('Status') },
 318     customer      => { sub       => sub { !$_[0]->customer_id ? '' : $_[0]->customer->name },
 319                        raw_data  => sub { !$_[0]->customer_id ? '' : $_[0]->customer->presenter->customer(display => 'table-cell', callback => $callback) } },
 320     active        => { sub  => sub { $_[0]->active   ? $::locale->text('Active') : $::locale->text('Inactive') },
 321                        text => $::locale->text('Active') },
 322     valid         => { sub  => sub { $_[0]->valid    ? $::locale->text('Valid')  : $::locale->text('Invalid')  },
 323                        text => $::locale->text('Valid')  },
 324   );
 325
 326   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 327
 328   # Custom variables
 329   my %cvar_column_defs = map {
 330     my $cfg = $_;
 331     (('cvar_' . $cfg->name) => {
 332       sub     => sub { my $var = $_[0]->cvar_by_name($cfg->name); $var ? $var->value_as_text : '' },
 333       text    => $cfg->description,
 334       visible => $self->include_cvars->{ $cfg->name } ? 1 : 0,
 335     })
 336   } @{ $self->includeable_cvar_configs };
 337
 338   push @columns, map { 'cvar_' . $_->name } @{ $self->includeable_cvar_configs };
 339   %column_defs = (%column_defs, %cvar_column_defs);
 340
 341   my @cvar_column_form_names = ('_include_cvars_from_form', map { "include_cvars_" . $_->name } @{ $self->includeable_cvar_configs });
 342
 343   $report->set_options(
 344     std_column_visibility => 1,
 345     controller_class      => 'Project',
 346     output_format         => 'HTML',
 347     title                 => $::locale->text('Projects'),
 348     allow_pdf_export      => 1,
 349     allow_csv_export      => 1,
 350   );
 351   $report->set_columns(%column_defs);
 352   $report->set_column_order(@columns);
 353   $report->set_export_options(qw(list filter), @cvar_column_form_names);
 354   $report->set_options_from_form;
 355   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 356   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 357   $report->set_options(
 358     raw_top_info_text     => $self->render('project/report_top',    { output => 0 }),
 359     raw_bottom_info_text  => $self->render('project/report_bottom', { output => 0 }),
 360   );
 361 }
 362
 363 sub init_models {
 364   my ($self) = @_;
 365
 366   SL::Controller::Helper::GetModels->new(
 367     controller => $self,
 368     sorted => {
 369       _default => {
 370         by    => 'projectnumber',
 371         dir   => 1,
 372       },
 373       customer       => t8('Customer'),
 374       description    => t8('Description'),
 375       projectnumber  => t8('Project Number'),
 376       project_type   => t8('Project Type'),
 377       project_status => t8('Project Status'),
 378       customer_and_description => 1,
 379     },
 380     with_objects => [ 'customer', 'project_status', 'project_type' ],
 381   );
 382 }
 383
 384 sub make_filter_summary {
 385   my ($self) = @_;
 386
 387   my $filter = $::form->{filter} || {};
 388   my @filter_strings;
 389
 390   my @filters = (
 391     [ $filter->{"projectnumber:substr::ilike"},  t8('Project Number') ],
 392     [ $filter->{"description:substr::ilike"},    t8('Description')    ],
 393     [ $filter->{customer}{"name:substr::ilike"}, t8('Customer')       ],
 394     [ $filter->{"project_type_id"},              t8('Project Type'),    sub { SL::DB::Manager::ProjectType->find_by(id => $filter->{"project_type_id"})->description }   ],
 395     [ $filter->{"project_status_id"},            t8('Project Status'),  sub { SL::DB::Manager::ProjectStatus->find_by(id => $filter->{"project_status_id"})->description } ],
 396   );
 397
 398   my @flags = (
 399     [ $filter->{active} eq 'active',    $::locale->text('Active')      ],
 400     [ $filter->{active} eq 'inactive',  $::locale->text('Inactive')    ],
 401     [ $filter->{valid}  eq 'valid',     $::locale->text('Valid')       ],
 402     [ $filter->{valid}  eq 'invalid',   $::locale->text('Invalid')     ],
 403     [ $filter->{orphaned},              $::locale->text('Orphaned')    ],
 404   );
 405
 406   for (@flags) {
 407     push @filter_strings, "$_->[1]" if $_->[0];
 408   }
 409   for (@filters) {
 410     push @filter_strings, "$_->[1]: " . ($_->[2] ? $_->[2]->() : $_->[0]) if $_->[0];
 411   }
 412
 413   $self->{filter_summary} = join ', ', @filter_strings;
 414 }
 415
 416 sub setup_edit_action_bar {
 417   my ($self, %params) = @_;
 418
 419   my $is_new = !$self->project->id;
 420
 421   for my $bar ($::request->layout->get('actionbar')) {
 422     $bar->add(
 423       combobox => [
 424         action => [
 425           t8('Save'),
 426           submit    => [ '#form', { action => 'Project/' . ($is_new ? 'create' : 'update') } ],
 427           accesskey => 'enter',
 428         ],
 429         action => [
 430           t8('Save as new'),
 431           submit   => [ '#form', { action => 'Project/create' }],
 432           disabled => $is_new ? t8('The object has not been saved yet.') : undef,
 433         ],
 434       ], # end of combobox "Save"
 435
 436       action => [
 437         t8('Delete'),
 438         submit   => [ '#form', { action => 'Project/destroy' } ],
 439         confirm  => $::locale->text('Do you really want to delete this object?'),
 440         disabled => $is_new                 ? t8('This object has not been saved yet.')
 441                   : $self->project->is_used ? t8('This object has already been used.')
 442                   :                           undef,
 443       ],
 444
 445       link => [
 446         t8('Abort'),
 447         link => $params{callback} || $self->url_for(action => 'list'),
 448       ],
 449     );
 450   }
 451 }
 452
 453 sub setup_list_action_bar {
 454   my ($self, %params) = @_;
 455
 456   for my $bar ($::request->layout->get('actionbar')) {
 457     $bar->add(
 458       action => [
 459         t8('Update'),
 460         submit    => [ '#search_form', { action => 'Project/list' } ],
 461         accesskey => 'enter',
 462       ],
 463       link => [
 464         t8('Add'),
 465         link => $self->url_for(action => 'new'),
 466       ],
 467     );
 468   }
 469 }
 470
 471 1;