SL/DB/Order.pm

   1 package SL::DB::Order;
   2
   3 use utf8;
   4 use strict;
   5
   6 use Carp;
   7 use DateTime;
   8 use List::Util qw(max);
   9
  10 use SL::DB::MetaSetup::Order;
  11 use SL::DB::Manager::Order;
  12 use SL::DB::Helper::AttrHTML;
  13 use SL::DB::Helper::AttrSorted;
  14 use SL::DB::Helper::FlattenToForm;
  15 use SL::DB::Helper::LinkedRecords;
  16 use SL::DB::Helper::PriceTaxCalculator;
  17 use SL::DB::Helper::PriceUpdater;
  18 use SL::DB::Helper::TransNumberGenerator;
  19 use SL::RecordLinks;
  20 use Rose::DB::Object::Helpers qw(as_tree);
  21
  22 __PACKAGE__->meta->add_relationship(
  23   orderitems => {
  24     type         => 'one to many',
  25     class        => 'SL::DB::OrderItem',
  26     column_map   => { id => 'trans_id' },
  27     manager_args => {
  28       with_objects => [ 'part' ]
  29     }
  30   },
  31   periodic_invoices_config => {
  32     type                   => 'one to one',
  33     class                  => 'SL::DB::PeriodicInvoicesConfig',
  34     column_map             => { id => 'oe_id' },
  35   },
  36   custom_shipto            => {
  37     type                   => 'one to one',
  38     class                  => 'SL::DB::Shipto',
  39     column_map             => { id => 'trans_id' },
  40     query_args             => [ module => 'OE' ],
  41   },
  42 );
  43
  44 __PACKAGE__->meta->initialize;
  45
  46 __PACKAGE__->attr_html('notes');
  47 __PACKAGE__->attr_sorted('items');
  48
  49 __PACKAGE__->before_save('_before_save_set_ord_quo_number');
  50
  51 # hooks
  52
  53 sub _before_save_set_ord_quo_number {
  54   my ($self) = @_;
  55
  56   # ordnumber is 'NOT NULL'. Therefore make sure it's always set to at
  57   # least an empty string, even if we're saving a quotation.
  58   $self->ordnumber('') if !$self->ordnumber;
  59
  60   my $field = $self->quotation ? 'quonumber' : 'ordnumber';
  61   $self->create_trans_number if !$self->$field;
  62
  63   return 1;
  64 }
  65
  66 # methods
  67
  68 sub items { goto &orderitems; }
  69 sub add_items { goto &add_orderitems; }
  70 sub record_number { goto &number; }
  71
  72 sub type {
  73   my $self = shift;
  74
  75   return 'sales_order'       if $self->customer_id && ! $self->quotation;
  76   return 'purchase_order'    if $self->vendor_id   && ! $self->quotation;
  77   return 'sales_quotation'   if $self->customer_id &&   $self->quotation;
  78   return 'request_quotation' if $self->vendor_id   &&   $self->quotation;
  79
  80   return;
  81 }
  82
  83 sub is_type {
  84   return shift->type eq shift;
  85 }
  86
  87 sub displayable_type {
  88   my $type = shift->type;
  89
  90   return $::locale->text('Sales quotation')   if $type eq 'sales_quotation';
  91   return $::locale->text('Request quotation') if $type eq 'request_quotation';
  92   return $::locale->text('Sales Order')       if $type eq 'sales_order';
  93   return $::locale->text('Purchase Order')    if $type eq 'purchase_order';
  94
  95   die 'invalid type';
  96 }
  97
  98 sub displayable_name {
  99   join ' ', grep $_, map $_[0]->$_, qw(displayable_type record_number);
 100 };
 101
 102 sub is_sales {
 103   croak 'not an accessor' if @_ > 1;
 104   return !!shift->customer_id;
 105 }
 106
 107 sub invoices {
 108   my $self   = shift;
 109   my %params = @_;
 110
 111   if ($self->quotation) {
 112     return [];
 113   } else {
 114     require SL::DB::Invoice;
 115     return SL::DB::Manager::Invoice->get_all(
 116       query => [
 117         ordnumber => $self->ordnumber,
 118         @{ $params{query} || [] },
 119       ]
 120     );
 121   }
 122 }
 123
 124 sub displayable_state {
 125   my ($self) = @_;
 126
 127   return $self->closed ? $::locale->text('closed') : $::locale->text('open');
 128 }
 129
 130 sub abschlag_invoices {
 131   return shift()->invoices(query => [ abschlag => 1 ]);
 132 }
 133
 134 sub end_invoice {
 135   return shift()->invoices(query => [ abschlag => 0 ]);
 136 }
 137
 138 sub convert_to_invoice {
 139   my ($self, %params) = @_;
 140
 141   croak("Conversion to invoices is only supported for sales records") unless $self->customer_id;
 142
 143   my $invoice;
 144   if (!$self->db->with_transaction(sub {
 145     require SL::DB::Invoice;
 146     $invoice = SL::DB::Invoice->new_from($self)->post(%params) || die;
 147     $self->link_to_record($invoice);
 148     $self->update_attributes(closed => 1);
 149     1;
 150   })) {
 151     return undef;
 152   }
 153
 154   return $invoice;
 155 }
 156
 157 sub convert_to_delivery_order {
 158   my ($self, @args) = @_;
 159
 160   my $delivery_order;
 161   if (!$self->db->with_transaction(sub {
 162     require SL::DB::DeliveryOrder;
 163     $delivery_order = SL::DB::DeliveryOrder->new_from($self, @args);
 164     $delivery_order->save;
 165     $self->link_to_record($delivery_order);
 166     # TODO extend link_to_record for items, otherwise long-term no d.r.y.
 167     foreach my $item (@{ $delivery_order->items }) {
 168       foreach (qw(orderitems)) {    # expand if needed (delivery_order_items)
 169         if ($item->{"converted_from_${_}_id"}) {
 170           die unless $item->{id};
 171           RecordLinks->create_links('dbh'        => $self->db->dbh,
 172                                     'mode'       => 'ids',
 173                                     'from_table' => $_,
 174                                     'from_ids'   => $item->{"converted_from_${_}_id"},
 175                                     'to_table'   => 'delivery_order_items',
 176                                     'to_id'      => $item->{id},
 177           ) || die;
 178           delete $item->{"converted_from_${_}_id"};
 179         }
 180       }
 181     }
 182
 183     $self->update_attributes(delivered => 1);
 184     1;
 185   })) {
 186     return undef;
 187   }
 188
 189   return $delivery_order;
 190 }
 191
 192 sub number {
 193   my $self = shift;
 194
 195   my %number_method = (
 196     sales_order       => 'ordnumber',
 197     sales_quotation   => 'quonumber',
 198     purchase_order    => 'ordnumber',
 199     request_quotation => 'quonumber',
 200   );
 201
 202   return $self->${ \ $number_method{$self->type} }(@_);
 203 }
 204
 205 sub customervendor {
 206   $_[0]->is_sales ? $_[0]->customer : $_[0]->vendor;
 207 }
 208
 209 sub date {
 210   goto &transdate;
 211 }
 212
 213 sub digest {
 214   my ($self) = @_;
 215
 216   sprintf "%s %s %s (%s)",
 217     $self->number,
 218     $self->customervendor->name,
 219     $self->amount_as_number,
 220     $self->date->to_kivitendo;
 221 }
 222
 223 1;
 224
 225 __END__
 226
 227 =pod
 228
 229 =encoding utf8
 230
 231 =head1 NAME
 232
 233 SL::DB::Order - Order Datenbank Objekt.
 234
 235 =head1 FUNCTIONS
 236
 237 =head2 C<type>
 238
 239 Returns one of the following string types:
 240
 241 =over 4
 242
 243 =item sales_order
 244
 245 =item purchase_order
 246
 247 =item sales_quotation
 248
 249 =item request_quotation
 250
 251 =back
 252
 253 =head2 C<is_type TYPE>
 254
 255 Returns true if the order is of the given type.
 256
 257 =head2 C<convert_to_delivery_order %params>
 258
 259 Creates a new delivery order with C<$self> as the basis by calling
 260 L<SL::DB::DeliveryOrder::new_from>. That delivery order is saved, and
 261 C<$self> is linked to the new invoice via
 262 L<SL::DB::RecordLink>. C<$self>'s C<delivered> attribute is set to
 263 C<true>, and C<$self> is saved.
 264
 265 The arguments in C<%params> are passed to
 266 L<SL::DB::DeliveryOrder::new_from>.
 267
 268 Returns C<undef> on failure. Otherwise the new delivery order will be
 269 returned.
 270
 271 =head2 C<convert_to_invoice %params>
 272
 273 Creates a new invoice with C<$self> as the basis by calling
 274 L<SL::DB::Invoice::new_from>. That invoice is posted, and C<$self> is
 275 linked to the new invoice via L<SL::DB::RecordLink>. C<$self>'s
 276 C<closed> attribute is set to C<true>, and C<$self> is saved.
 277
 278 The arguments in C<%params> are passed to L<SL::DB::Invoice::post>.
 279
 280 Returns the new invoice instance on success and C<undef> on
 281 failure. The whole process is run inside a transaction. On failure
 282 nothing is created or changed in the database.
 283
 284 At the moment only sales quotations and sales orders can be converted.
 285
 286 =head2 C<create_sales_process>
 287
 288 Creates and saves a new sales process. Can only be called for sales
 289 orders.
 290
 291 The newly created process will be linked bidirectionally to both
 292 C<$self> and to all sales quotations that are linked to C<$self>.
 293
 294 Returns the newly created process instance.
 295
 296 =head1 BUGS
 297
 298 Nothing here yet.
 299
 300 =head1 AUTHOR
 301
 302 Sven Schöling <s.schoeling@linet-services.de>
 303
 304 =cut