bin/mozilla/ap.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  28 # MA 02110-1335, USA.
  29 #======================================================================
  30 #
  31 # Accounts Payables
  32 #
  33 #======================================================================
  34
  35 use POSIX qw(strftime);
  36 use List::Util qw(max sum);
  37 use List::UtilsBy qw(sort_by);
  38
  39 use SL::AP;
  40 use SL::FU;
  41 use SL::GL;
  42 use SL::IR;
  43 use SL::IS;
  44 use SL::ReportGenerator;
  45 use SL::DB::Default;
  46 use SL::DB::PurchaseInvoice;
  47 use SL::Webdav;
  48 use SL::Locale::String qw(t8);
  49
  50 require "bin/mozilla/arap.pl";
  51 require "bin/mozilla/common.pl";
  52 require "bin/mozilla/reportgenerator.pl";
  53
  54 use strict;
  55
  56 1;
  57
  58 # end of main
  59
  60 # this is for our long dates
  61 # $locale->text('January')
  62 # $locale->text('February')
  63 # $locale->text('March')
  64 # $locale->text('April')
  65 # $locale->text('May ')
  66 # $locale->text('June')
  67 # $locale->text('July')
  68 # $locale->text('August')
  69 # $locale->text('September')
  70 # $locale->text('October')
  71 # $locale->text('November')
  72 # $locale->text('December')
  73
  74 # this is for our short month
  75 # $locale->text('Jan')
  76 # $locale->text('Feb')
  77 # $locale->text('Mar')
  78 # $locale->text('Apr')
  79 # $locale->text('May')
  80 # $locale->text('Jun')
  81 # $locale->text('Jul')
  82 # $locale->text('Aug')
  83 # $locale->text('Sep')
  84 # $locale->text('Oct')
  85 # $locale->text('Nov')
  86 # $locale->text('Dec')
  87
  88 sub add {
  89   $main::lxdebug->enter_sub();
  90
  91   my $form     = $main::form;
  92   my %myconfig = %main::myconfig;
  93
  94   $main::auth->assert('ap_transactions');
  95
  96   $form->{title} = "Add";
  97
  98   $form->{callback} = "ap.pl?action=add" unless $form->{callback};
  99
 100   AP->get_transdate(\%myconfig, $form);
 101   $form->{initial_transdate} = $form->{transdate};
 102   create_links(dont_save => 1);
 103   $form->{transdate} = $form->{initial_transdate};
 104
 105   if ($form->{vendor_id}) {
 106     my $last_used_ap_chart = SL::DB::Vendor->load_cached($form->{vendor_id})->last_used_ap_chart;
 107     $form->{"AP_amount_chart_id_1"} = $last_used_ap_chart->id if $last_used_ap_chart;
 108   }
 109
 110   &display_form;
 111
 112   $main::lxdebug->leave_sub();
 113 }
 114
 115 sub edit {
 116   $main::lxdebug->enter_sub();
 117
 118   my $form     = $main::form;
 119
 120   $main::auth->assert('ap_transactions');
 121
 122   $form->{title} = "Edit";
 123
 124   create_links();
 125   &display_form;
 126
 127   $main::lxdebug->leave_sub();
 128 }
 129
 130 sub display_form {
 131   $main::lxdebug->enter_sub();
 132
 133   my $form     = $main::form;
 134
 135   $main::auth->assert('ap_transactions');
 136
 137   # get all files stored in the webdav folder
 138   if ($form->{invnumber} && $::instance_conf->get_webdav) {
 139     my $webdav = SL::Webdav->new(
 140       type     => 'accounts_payable',
 141       number   => $form->{invnumber},
 142     );
 143     my $webdav_path = $webdav->webdav_path;
 144     my @all_objects = $webdav->get_all_objects;
 145     @{ $form->{WEBDAV} } = map { { name => $_->filename,
 146                                    type => t8('File'),
 147                                    link => File::Spec->catfile($_->full_filedescriptor),
 148                                } } @all_objects;
 149   }
 150   &form_header;
 151   &form_footer;
 152
 153   $main::lxdebug->leave_sub();
 154 }
 155
 156 sub create_links {
 157   $main::lxdebug->enter_sub();
 158
 159   my %params   = @_;
 160
 161   my $form     = $main::form;
 162   my %myconfig = %main::myconfig;
 163
 164   $main::auth->assert('ap_transactions');
 165
 166   $form->create_links("AP", \%myconfig, "vendor");
 167   my %saved;
 168   if (!$params{dont_save}) {
 169     %saved = map { ($_ => $form->{$_}) } qw(direct_debit taxincluded);
 170     $saved{duedate} = $form->{duedate} if $form->{duedate};
 171     $saved{currency} = $form->{currency} if $form->{currency};
 172     $saved{taxincluded} = $form->{taxincluded} if $form->{taxincluded};
 173   }
 174
 175   IR->get_vendor(\%myconfig, \%$form);
 176
 177   $form->{$_}        = $saved{$_} for keys %saved;
 178   $form->{oldvendor} = "$form->{vendor}--$form->{vendor_id}";
 179   $form->{rowcount}  = 1;
 180   $form->{AP_chart_id} = $form->{acc_trans} && $form->{acc_trans}->{AP} ? $form->{acc_trans}->{AP}->[0]->{chart_id} : $form->{AP_links}->{AP}->[0]->{chart_id};
 181
 182   # build the popup menus
 183   $form->{taxincluded} = ($form->{id}) ? $form->{taxincluded} : "checked";
 184
 185   # currencies
 186   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 187
 188   $form->{selectcurrency} = "";
 189   map { my $quoted = H($_); $form->{selectcurrency} .= "<option value=\"${quoted}\">${quoted}\n" } $form->get_all_currencies(\%myconfig);
 190
 191   # vendors
 192   if (@{ $form->{all_vendor} || [] }) {
 193     $form->{vendor} = qq|$form->{vendor}--$form->{vendor_id}|;
 194     map { my $quoted = H($_->{name} . "--" . $_->{id}); $form->{selectvendor} .= "<option value=\"${quoted}\">${quoted}\n" }
 195       (@{ $form->{all_vendor} });
 196   }
 197
 198   $::form->{ALL_DEPARTMENTS} = SL::DB::Manager::Department->get_all;
 199
 200   $form->{employee} = "$form->{employee}--$form->{employee_id}";
 201
 202   AP->setup_form($form);
 203
 204   $form->{locked} =
 205     ($form->datetonum($form->{transdate}, \%myconfig) <=
 206      $form->datetonum($form->{closedto}, \%myconfig));
 207
 208   $main::lxdebug->leave_sub();
 209 }
 210
 211 sub _sort_payments {
 212   my @fields   = qw(acc_trans_id gldate datepaid source memo paid AP_paid paid_project_id);
 213   my @payments =
 214     grep { $_->{paid} != 0 }
 215     map  {
 216       my $idx = $_;
 217       +{ map { ($_ => delete($::form->{"${_}_${idx}"})) } @fields }
 218     } (1..$::form->{paidaccounts});
 219
 220   @payments = sort_by { DateTime->from_kivitendo($_->{datepaid}) } @payments;
 221
 222   $::form->{paidaccounts} = max scalar(@payments), 1;
 223
 224   foreach my $idx (1 .. scalar(@payments)) {
 225     my $payment = $payments[$idx - 1];
 226     $::form->{"${_}_${idx}"} = $payment->{$_} for @fields;
 227   }
 228 }
 229
 230 sub form_header {
 231   $main::lxdebug->enter_sub();
 232
 233   my $form     = $main::form;
 234   my %myconfig = %main::myconfig;
 235   my $locale   = $main::locale;
 236   my $cgi      = $::request->{cgi};
 237
 238   $main::auth->assert('ap_transactions');
 239
 240   $::form->{invoice_obj} = SL::DB::PurchaseInvoice->new(id => $::form->{id})->load if $::form->{id};
 241
 242   $form->{initial_focus} = !($form->{amount_1} * 1) ? 'vendor' : 'row_' . $form->{rowcount};
 243
 244   $form->{title_} = $form->{title};
 245   $form->{title} = $form->{title} eq 'Add' ? $locale->text('Add Accounts Payables Transaction') : $locale->text('Edit Accounts Payables Transaction');
 246
 247   # type=submit $locale->text('Add Accounts Payables Transaction')
 248   # type=submit $locale->text('Edit Accounts Payables Transaction')
 249
 250   # set option selected
 251   foreach my $item (qw(vendor currency)) {
 252     my $to_replace         =  H($form->{$item});
 253     $form->{"select$item"} =~ s/ selected//;
 254     $form->{"select$item"} =~ s/>\Q${to_replace}\E/ selected>${to_replace}/;
 255   }
 256   my $readonly = $form->{id} ? "readonly" : "";
 257
 258   $form->{radier} = ($::instance_conf->get_ap_changeable == 2)
 259                       ? ($form->current_date(\%myconfig) eq $form->{gldate})
 260                       : ($::instance_conf->get_ap_changeable == 1);
 261   $readonly       = $form->{radier} ? "" : $readonly;
 262
 263   $form->{readonly} = $readonly;
 264
 265   $form->{forex} = $form->check_exchangerate( \%myconfig, $form->{currency}, $form->{transdate}, 'sell');
 266   if ( $form->{forex} ) {
 267     $form->{exchangerate} = $form->{forex};
 268   }
 269
 270   # format amounts
 271   $form->{exchangerate}    = $form->{exchangerate} ? $form->format_amount(\%myconfig, $form->{exchangerate}) : '';
 272   $form->{creditlimit}     = $form->format_amount(\%myconfig, $form->{creditlimit}, 0, "0");
 273   $form->{creditremaining} = $form->format_amount(\%myconfig, $form->{creditremaining}, 0, "0");
 274
 275   my $rows;
 276   if (($rows = $form->numtextrows($form->{notes}, 50)) < 2) {
 277     $rows = 2;
 278   }
 279   $form->{textarea_rows} = $rows;
 280
 281   $form->{creditremaining_plus} = ($form->{creditremaining} =~ /-/) ? "0" : "1";
 282
 283   my @old_project_ids = ();
 284   map(
 285     {
 286       if ($form->{"project_id_$_"}) {
 287         push(@old_project_ids, $form->{"project_id_$_"});
 288       }
 289     }
 290     (1..$form->{"rowcount"})
 291   );
 292
 293   $form->get_lists("projects"  => { "key"       => "ALL_PROJECTS",
 294                                     "all"       => 0,
 295                                     "old_id"    => \@old_project_ids },
 296                    "charts"    => { "key"       => "ALL_CHARTS",
 297                                     "transdate" => $form->{transdate} },
 298                    "taxcharts" => { "key"       => "ALL_TAXCHARTS",
 299                                     "module"    => "AP" },);
 300
 301   map(
 302     { $_->{link_split} = [ split(/:/, $_->{link}) ]; }
 303     @{ $form->{ALL_CHARTS} }
 304   );
 305
 306   $form->{ALL_DEPARTMENTS} = SL::DB::Manager::Department->get_all;
 307
 308   my %project_labels = ();
 309   foreach my $item (@{ $form->{"ALL_PROJECTS"} }) {
 310     $project_labels{$item->{id}} = $item->{projectnumber};
 311   }
 312
 313   my %charts;
 314   my $default_ap_amount_chart_id;
 315
 316   foreach my $item (@{ $form->{ALL_CHARTS} }) {
 317     if ( grep({ $_ eq 'AP_amount' } @{ $item->{link_split} }) ) {
 318       $default_ap_amount_chart_id //= $item->{id};
 319
 320     } elsif ( grep({ $_ eq 'AP_paid' } @{ $item->{link_split} }) ) {
 321       push(@{ $form->{ALL_CHARTS_AP_paid} }, $item);
 322     }
 323
 324     $charts{$item->{accno}} = $item;
 325   }
 326
 327   my $follow_up_vc         =  $form->{vendor};
 328   $follow_up_vc            =~ s/--.*?//;
 329   my $follow_up_trans_info =  "$form->{invnumber} ($follow_up_vc)";
 330
 331   $::request->layout->add_javascripts("autocomplete_chart.js", "show_vc_details.js", "show_history.js", "follow_up.js", "kivi.Draft.js", "kivi.GL.js");
 332   my $transdate = $::form->{transdate} ? DateTime->from_kivitendo($::form->{transdate}) : DateTime->today_local;
 333   my $first_taxchart;
 334
 335   $form->header();
 336
 337   for my $i (1 .. $form->{rowcount}) {
 338
 339     # format amounts
 340     $form->{"amount_$i"} = $form->format_amount(\%myconfig, $form->{"amount_$i"}, 2);
 341     $form->{"tax_$i"} = $form->format_amount(\%myconfig, $form->{"tax_$i"}, 2);
 342
 343     my ($default_taxchart, $taxchart_to_use);
 344     my $amount_chart_id   = $form->{"AP_amount_chart_id_$i"} || $default_ap_amount_chart_id;
 345     my $chart_has_changed = $::form->{"previous_AP_amount_chart_id_$i"} && ($amount_chart_id != $::form->{"previous_AP_amount_chart_id_$i"});
 346     my @taxcharts         = GL->get_active_taxes_for_chart($amount_chart_id, $transdate);
 347
 348     foreach my $item (@taxcharts) {
 349       my $key             = $item->id . "--" . $item->rate;
 350       $first_taxchart   //= $item;
 351       $default_taxchart   = $item if $item->{is_default};
 352       $taxchart_to_use    = $item if $key eq $form->{"taxchart_$i"};
 353     }
 354
 355     $taxchart_to_use                 = $default_taxchart // $first_taxchart if $chart_has_changed || !$taxchart_to_use;
 356     my $selected_taxchart            = $taxchart_to_use->id . '--' . $taxchart_to_use->rate;
 357     $form->{"selected_taxchart_$i"}  = $selected_taxchart;
 358     $form->{"AP_amount_chart_id_$i"} = $amount_chart_id;
 359     $form->{"taxcharts_$i"}          = \@taxcharts;
 360   }
 361
 362   $form->{taxchart_value_title_sub} = sub {
 363     my $item = shift;
 364     return [
 365       $item->{id} .'--'. $item->{rate},
 366       $item->{taxdescription} .' '. ($item->{rate} * 100) .' %',
 367     ];
 368   };
 369
 370   $form->{AP_paid_value_title_sub} = sub {
 371     my $item = shift;
 372     return [
 373       $item->{accno},
 374       $item->{accno} .'--'. $item->{description}
 375     ];
 376   };
 377
 378   $form->{invtotal_unformatted} = $form->{invtotal};
 379   $form->{invtotal} = $form->format_amount(\%myconfig, $form->{invtotal}, 2);
 380
 381   $form->{totalpaid} = 0;
 382
 383   _sort_payments();
 384
 385   if ( $form->{'paid_'. $form->{paidaccounts}} ) {
 386     $form->{paidaccounts}++;
 387   }
 388
 389   # default account for current assets (i.e. 1801 - SKR04)
 390   $form->{accno_arap} = IS->get_standard_accno_current_assets(\%myconfig, \%$form);
 391
 392   for my $i (1 .. $form->{paidaccounts}) {
 393     $form->{totalpaid} += $form->{"paid_$i"};
 394
 395     # format amounts
 396     if ($form->{"paid_$i"}) {
 397       $form->{"paid_$i"} = $form->format_amount(\%myconfig, $form->{"paid_$i"}, 2);
 398     }
 399     if ($form->{"exchangerate_$i"} == 0) {
 400       $form->{"exchangerate_$i"} = "";
 401     } else {
 402       $form->{"exchangerate_$i"} =
 403         $form->format_amount(\%myconfig, $form->{"exchangerate_$i"});
 404     }
 405
 406     my $changeable = 1;
 407     if (SL::DB::Default->get->payments_changeable == 0) {
 408       # never
 409       $changeable = ($form->{"acc_trans_id_$i"})? 0 : 1;
 410     }
 411     if (SL::DB::Default->get->payments_changeable == 2) {
 412       # on the same day
 413       $changeable = (($form->{"gldate_$i"} eq '') || $form->current_date(\%myconfig) eq $form->{"gldate_$i"});
 414     }
 415
 416     #deaktivieren von gebuchten Zahlungen ausserhalb der Bücherkontrolle, vorher prüfen ob heute eingegeben
 417     if ($form->date_closed($form->{"gldate_$i"})) {
 418        $changeable = 0;
 419     }
 420
 421     $form->{'paidaccount_changeable_'. $i} = $changeable;
 422
 423     $form->{'labelpaid_project_id_'. $i} = $project_labels{$form->{'paid_project_id_'. $i}};
 424   }
 425
 426   $form->{paid_missing} = $form->{invtotal_unformatted} - $form->{totalpaid};
 427
 428   print $form->parse_html_template('ap/form_header', {
 429     today => DateTime->today,
 430   });
 431
 432   $main::lxdebug->leave_sub();
 433 }
 434
 435 sub form_footer {
 436   $::lxdebug->enter_sub;
 437   $::auth->assert('ap_transactions');
 438
 439   my $num_due;
 440   my $num_follow_ups;
 441   if ($::form->{id}) {
 442     my $follow_ups = FU->follow_ups('trans_id' => $::form->{id}, 'not_done' => 1);
 443
 444     if (@{ $follow_ups }) {
 445       $num_due        = sum map { $_->{due} * 1 } @{ $follow_ups };
 446       $num_follow_ups = scalar @{ $follow_ups }
 447     }
 448   }
 449
 450   my $transdate = $::form->datetonum($::form->{transdate}, \%::myconfig);
 451   my $closedto  = $::form->datetonum($::form->{closedto},  \%::myconfig);
 452
 453   my $storno = $::form->{id}
 454             && !IS->has_storno(\%::myconfig, $::form, 'ap')
 455             && !IS->is_storno( \%::myconfig, $::form, 'ap', $::form->{id})
 456             && ($::form->{totalpaid} == 0 || $::form->{totalpaid} eq '');
 457
 458   $::form->header;
 459   print $::form->parse_html_template('ap/form_footer', {
 460     num_due           => $num_due,
 461     num_follow_ups    => $num_follow_ups,
 462     show_post_draft   => ($transdate > $closedto) && !$::form->{id},
 463     show_storno       => $storno,
 464   });
 465
 466   $::lxdebug->leave_sub;
 467 }
 468
 469 sub mark_as_paid {
 470   $::auth->assert('ap_transactions');
 471
 472   SL::DB::PurchaseInvoice->new(id => $::form->{id})->load->mark_as_paid;
 473
 474   $::form->redirect($::locale->text("Marked as paid"));
 475 }
 476
 477 sub show_draft {
 478   $::form->{transdate} = DateTime->today_local->to_kivitendo if !$::form->{transdate};
 479   $::form->{gldate}    = $::form->{transdate} if !$::form->{gldate};
 480   update();
 481 }
 482
 483 sub update {
 484   $main::lxdebug->enter_sub();
 485
 486   my $form     = $main::form;
 487   my %myconfig = %main::myconfig;
 488
 489   $main::auth->assert('ap_transactions');
 490
 491   my $display = shift;
 492
 493   $form->{invtotal} = 0;
 494
 495   delete @{ $form }{ grep { m/^tax_\d+$/ } keys %{ $form } };
 496
 497   map { $form->{$_} = $form->parse_amount(\%myconfig, $form->{$_}) }
 498     qw(exchangerate creditlimit creditremaining);
 499
 500   my @flds  = qw(amount AP_amount projectnumber oldprojectnumber project_id taxchart);
 501   my $count = 0;
 502   my (@a, $j, $totaltax);
 503   for my $i (1 .. $form->{rowcount}) {
 504     $form->{"amount_$i"} = $form->parse_amount(\%myconfig, $form->{"amount_$i"});
 505     if ($form->{"amount_$i"}) {
 506       push @a, {};
 507       $j = $#a;
 508       my ($taxkey, $rate) = split(/--/, $form->{"taxchart_$i"});
 509
 510       # calculate tax exactly the same way as AP in post_transaction via form->calculate_tax
 511       my $tmpnetamount;
 512       ($tmpnetamount,$form->{"tax_$i"}) = $form->calculate_tax($form->{"amount_$i"},$rate,$form->{taxincluded},2);
 513
 514       $totaltax += $form->{"tax_$i"};
 515       map { $a[$j]->{$_} = $form->{"${_}_$i"} } @flds;
 516       $count++;
 517     }
 518   }
 519   $form->redo_rows(\@flds, \@a, $count, $form->{rowcount});
 520
 521   map { $form->{invtotal} += $form->{"amount_$_"} } (1 .. $form->{rowcount});
 522
 523   $form->{forex}        = $form->check_exchangerate( \%myconfig, $form->{currency}, $form->{transdate}, 'sell');
 524   $form->{exchangerate} = $form->{forex} if $form->{forex};
 525
 526   $form->{invdate} = $form->{transdate};
 527
 528   my $vendor_changed = &check_name("vendor");
 529
 530   $form->{rowcount} = $count + 1;
 531
 532   $form->{invtotal} =
 533     ($form->{taxincluded}) ? $form->{invtotal} : $form->{invtotal} + $totaltax;
 534
 535   my $totalpaid;
 536   for my $i (1 .. $form->{paidaccounts}) {
 537     if ($form->parse_amount(\%myconfig, $form->{"paid_$i"})) {
 538       map {
 539         $form->{"${_}_$i"} =
 540           $form->parse_amount(\%myconfig, $form->{"${_}_$i"})
 541       } qw(paid exchangerate);
 542
 543       $totalpaid += $form->{"paid_$i"};
 544
 545       $form->{"forex_$i"}        = $form->check_exchangerate( \%myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'sell');
 546       $form->{"exchangerate_$i"} = $form->{"forex_$i"} if $form->{"forex_$i"};
 547     }
 548   }
 549
 550   $form->{creditremaining} -=
 551     ($form->{invtotal} - $totalpaid + $form->{oldtotalpaid} -
 552      $form->{oldinvtotal});
 553   $form->{oldinvtotal}  = $form->{invtotal};
 554   $form->{oldtotalpaid} = $totalpaid;
 555
 556   &display_form;
 557
 558   $main::lxdebug->leave_sub();
 559 }
 560
 561
 562 sub post_payment {
 563   $main::lxdebug->enter_sub();
 564
 565   my $form     = $main::form;
 566   my %myconfig = %main::myconfig;
 567   my $locale   = $main::locale;
 568
 569   $main::auth->assert('ap_transactions');
 570   $form->mtime_ischanged('ap');
 571
 572   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 573
 574   my $invdate = $form->datetonum($form->{transdate}, \%myconfig);
 575
 576   for my $i (1 .. $form->{paidaccounts}) {
 577     if ($form->parse_amount(\%myconfig, $form->{"paid_$i"})) {
 578       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 579
 580       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 581
 582       $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 583         if ($form->date_max_future($form->{"datepaid_$i"}, \%myconfig));
 584
 585       #Zusätzlich noch das Buchungsdatum in die Bücherkontrolle einbeziehen
 586       # (Dient zur Prüfung ob ZE oder ZA geprüft werden soll)
 587       $form->error($locale->text('Cannot post payment for a closed period!'))
 588         if ($form->date_closed($form->{"datepaid_$i"})  && !$form->date_closed($form->{"gldate_$i"}, \%myconfig));
 589
 590       if ($form->{defaultcurrency} && ($form->{currency} ne $form->{defaultcurrency})) {
 591         $form->{"exchangerate_$i"} = $form->{exchangerate}
 592           if ($invdate == $datepaid);
 593         $form->isblank("exchangerate_$i",
 594                        $locale->text('Exchangerate for payment missing!'));
 595       }
 596     }
 597   }
 598
 599   ($form->{AP})      = split /--/, $form->{AP};
 600   ($form->{AP_paid}) = split /--/, $form->{AP_paid};
 601   if (AP->post_payment(\%myconfig, \%$form)) {
 602     $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 603     $form->{what_done} = 'invoice';
 604     $form->{addition}  = "PAYMENT POSTED";
 605     $form->save_history;
 606     $form->redirect($locale->text('Payment posted!'))
 607   } else {
 608     $form->error($locale->text('Cannot post payment!'));
 609   };
 610
 611
 612   $main::lxdebug->leave_sub();
 613 }
 614
 615
 616 sub post {
 617   $main::lxdebug->enter_sub();
 618
 619   my $form     = $main::form;
 620   my %myconfig = %main::myconfig;
 621   my $locale   = $main::locale;
 622
 623   $main::auth->assert('ap_transactions');
 624   $form->mtime_ischanged('ap');
 625
 626   my ($inline) = @_;
 627
 628   # check if there is a vendor, invoice, due date and invnumber
 629   $form->isblank("transdate", $locale->text("Invoice Date missing!"));
 630   $form->isblank("duedate",   $locale->text("Due Date missing!"));
 631   $form->isblank("vendor",    $locale->text('Vendor missing!'));
 632   $form->isblank("invnumber", $locale->text('Invoice Number missing!'));
 633
 634   if ($myconfig{mandatory_departments} && !$form->{department_id}) {
 635     $form->{saved_message} = $::locale->text('You have to specify a department.');
 636     update();
 637     exit;
 638   }
 639
 640   my $closedto  = $form->datetonum($form->{closedto},  \%myconfig);
 641   my $transdate = $form->datetonum($form->{transdate}, \%myconfig);
 642
 643   $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 644     if ($form->date_max_future($form->{"transdate"}, \%myconfig));
 645   $form->error($locale->text('Cannot post transaction for a closed period!')) if ($form->date_closed($form->{"transdate"}, \%myconfig));
 646
 647   my $zero_amount_posting = 1;
 648   for my $i (1 .. $form->{rowcount}) {
 649     if ($form->parse_amount(\%myconfig, $form->{"amount_$i"})) {
 650       $zero_amount_posting = 0;
 651       last;
 652     }
 653   }
 654
 655   $form->error($locale->text('Zero amount posting!')) if $zero_amount_posting;
 656
 657   $form->isblank("exchangerate", $locale->text('Exchangerate missing!'))
 658     if ($form->{defaultcurrency} && ($form->{currency} ne $form->{defaultcurrency}));
 659   delete($form->{AP});
 660
 661   for my $i (1 .. $form->{paidaccounts}) {
 662     if ($form->parse_amount(\%myconfig, $form->{"paid_$i"})) {
 663       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 664
 665       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 666
 667       $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 668       if ($form->date_max_future($form->{"datepaid_$i"}, \%myconfig));
 669
 670       #Zusätzlich noch das Buchungsdatum in die Bücherkontrolle einbeziehen
 671       # (Dient zur Prüfung ob ZE oder ZA geprüft werden soll)
 672       $form->error($locale->text('Cannot post payment for a closed period!'))
 673         if ($form->date_closed($form->{"datepaid_$i"})  && !$form->date_closed($form->{"gldate_$i"}, \%myconfig));
 674
 675       if ($form->{defaultcurrency} && ($form->{currency} ne $form->{defaultcurrency})) {
 676         $form->{"exchangerate_$i"} = $form->{exchangerate}
 677           if ($transdate == $datepaid);
 678         $form->isblank("exchangerate_$i",
 679                        $locale->text('Exchangerate for payment missing!'));
 680       }
 681
 682     }
 683   }
 684
 685   # if old vendor ne vendor redo form
 686   my ($vendor) = split /--/, $form->{vendor};
 687   if ($form->{oldvendor} ne "$vendor--$form->{vendor_id}") {
 688     &update;
 689     $::dispatcher->end_request;
 690   }
 691   $form->{storno}       = 0;
 692
 693   $form->{id} = 0 if $form->{postasnew};
 694
 695   if (AP->post_transaction(\%myconfig, \%$form)) {
 696     # create webdav folder
 697     if ($::instance_conf->get_webdav) {
 698       SL::Webdav->new(type     => 'accounts_payable',
 699                       number   => $form->{invnumber},
 700                      )->webdav_path;
 701     }
 702     # saving the history
 703     if(!exists $form->{addition} && $form->{id} ne "") {
 704       $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 705       $form->{addition}  = "POSTED";
 706       $form->{what_done} = "invoice";
 707       $form->save_history;
 708     }
 709     # /saving the history
 710     # Dieser Text wird niemals ausgegeben: Probleme beim redirect?
 711     $form->redirect($locale->text('Transaction posted!')) unless $inline;
 712   } else {
 713     $form->error($locale->text('Cannot post transaction!'));
 714   }
 715
 716   $main::lxdebug->leave_sub();
 717 }
 718
 719 sub post_as_new {
 720   $main::lxdebug->enter_sub();
 721
 722   my $form     = $main::form;
 723   my %myconfig = %main::myconfig;
 724
 725   $main::auth->assert('ap_transactions');
 726
 727   $form->{postasnew} = 1;
 728   # saving the history
 729   if(!exists $form->{addition} && $form->{id} ne "") {
 730     # does this work? post_as_new for ap doesn't immediately save the
 731     # invoice, because the invnumber has to be entered by hand.
 732     # And the value of $form->{postasnew} isn't checked when calling post
 733     $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 734     $form->{addition}  = "POSTED AS NEW";
 735     $form->{what_done} = "invoice";
 736     $form->save_history;
 737   }
 738   # /saving the history
 739   &post;
 740
 741   $main::lxdebug->leave_sub();
 742 }
 743
 744 sub use_as_new {
 745   $main::lxdebug->enter_sub();
 746
 747   my $form     = $main::form;
 748   my %myconfig = %main::myconfig;
 749
 750   $main::auth->assert('ap_transactions');
 751
 752   map { delete $form->{$_} } qw(printed emailed queued invnumber invdate deliverydate id datepaid_1 gldate_1 acc_trans_id_1 source_1 memo_1 paid_1 exchangerate_1 AP_paid_1 storno);
 753   $form->{paidaccounts} = 1;
 754   $form->{rowcount}--;
 755   $form->{invdate} = $form->current_date(\%myconfig);
 756   &update;
 757
 758   $main::lxdebug->leave_sub();
 759 }
 760
 761 sub delete {
 762   $main::lxdebug->enter_sub();
 763
 764   my $form     = $main::form;
 765   my $locale   = $main::locale;
 766
 767   $main::auth->assert('ap_transactions');
 768
 769   $form->{title} = $locale->text('Confirm!');
 770
 771   $form->header;
 772
 773   delete $form->{header};
 774
 775   print qq|
 776 <form method=post action=$form->{script}>
 777 |;
 778
 779   foreach my $key (keys %$form) {
 780     next if (($key eq 'login') || ($key eq 'password') || ('' ne ref $form->{$key}));
 781     $form->{$key} =~ s/\"/&quot;/g;
 782     print qq|<input type=hidden name=$key value="$form->{$key}">\n|;
 783   }
 784
 785   print qq|
 786 <h2 class=confirm>$form->{title}</h2>
 787
 788 <h4>|
 789     . $locale->text('Are you sure you want to delete Transaction')
 790     . qq| $form->{invnumber}</h4>
 791
 792 <input name=action class=submit type=submit value="|
 793     . $locale->text('Yes') . qq|">
 794 </form>
 795 |;
 796
 797   $main::lxdebug->leave_sub();
 798 }
 799
 800 sub yes {
 801   $main::lxdebug->enter_sub();
 802
 803   my $form     = $main::form;
 804   my %myconfig = %main::myconfig;
 805   my $locale   = $main::locale;
 806
 807   $main::auth->assert('ap_transactions');
 808
 809   if (AP->delete_transaction(\%myconfig, \%$form)) {
 810     # saving the history
 811     if(!exists $form->{addition}) {
 812       $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 813       $form->{addition}  = "DELETED";
 814       $form->{what_done} = "invoice";
 815       $form->save_history;
 816     }
 817     # /saving the history
 818     $form->redirect($locale->text('Transaction deleted!'));
 819   }
 820   $form->error($locale->text('Cannot delete transaction!'));
 821
 822   $main::lxdebug->leave_sub();
 823 }
 824
 825 sub search {
 826   $main::lxdebug->enter_sub();
 827
 828   $main::auth->assert('vendor_invoice_edit');
 829
 830   my $form     = $main::form;
 831   my %myconfig = %main::myconfig;
 832   my $locale   = $main::locale;
 833
 834   # setup customer selection
 835   $form->all_vc(\%myconfig, "vendor", "AP");
 836
 837   $form->{title}    = $locale->text('AP Transactions');
 838
 839   $form->get_lists("projects"     => { "key" => "ALL_PROJECTS", "all" => 1 },
 840                    "vendors"      => "ALL_VC");
 841
 842   $::form->{ALL_DEPARTMENTS} = SL::DB::Manager::Department->get_all;
 843   # constants and subs for template
 844   $form->{vc_keys}   = sub { "$_[0]->{name}--$_[0]->{id}" };
 845
 846   $form->header;
 847   print $form->parse_html_template('ap/search', { %myconfig });
 848
 849   $main::lxdebug->leave_sub();
 850 }
 851
 852 sub create_subtotal_row {
 853   $main::lxdebug->enter_sub();
 854
 855   my ($totals, $columns, $column_alignment, $subtotal_columns, $class) = @_;
 856
 857   my $form     = $main::form;
 858   my %myconfig = %main::myconfig;
 859
 860   my $row = { map { $_ => { 'data' => '', 'class' => $class, 'align' => $column_alignment->{$_}, } } @{ $columns } };
 861
 862   map { $row->{$_}->{data} = $form->format_amount(\%myconfig, $totals->{$_}, 2) } @{ $subtotal_columns };
 863
 864   $row->{tax}->{data} = $form->format_amount(\%myconfig, $totals->{amount} - $totals->{netamount}, 2);
 865
 866   map { $totals->{$_} = 0 } @{ $subtotal_columns };
 867
 868   $main::lxdebug->leave_sub();
 869
 870   return $row;
 871 }
 872
 873 sub ap_transactions {
 874   $main::lxdebug->enter_sub();
 875
 876   my $form     = $main::form;
 877   my %myconfig = %main::myconfig;
 878   my $locale   = $main::locale;
 879
 880   $main::auth->assert('vendor_invoice_edit');
 881
 882   ($form->{vendor}, $form->{vendor_id}) = split(/--/, $form->{vendor});
 883
 884   report_generator_set_default_sort('transdate', 1);
 885
 886   AP->ap_transactions(\%myconfig, \%$form);
 887
 888   $form->{title} = $locale->text('AP Transactions');
 889
 890   my $report = SL::ReportGenerator->new(\%myconfig, $form);
 891
 892   my @columns =
 893     qw(transdate id type invnumber ordnumber name netamount tax amount paid datepaid
 894        due duedate transaction_description notes employee globalprojectnumber
 895        vendornumber country ustid taxzone payment_terms charts direct_debit);
 896
 897   my @hidden_variables = map { "l_${_}" } @columns;
 898   push @hidden_variables, "l_subtotal", qw(open closed vendor invnumber ordnumber transaction_description notes project_id transdatefrom transdateto
 899                                            parts_partnumber parts_description);
 900
 901   my $href = build_std_url('action=ap_transactions', grep { $form->{$_} } @hidden_variables);
 902
 903   my %column_defs = (
 904     'transdate'               => { 'text' => $locale->text('Date'), },
 905     'id'                      => { 'text' => $locale->text('ID'), },
 906     'type'                    => { 'text' => $locale->text('Type'), },
 907     'invnumber'               => { 'text' => $locale->text('Invoice'), },
 908     'ordnumber'               => { 'text' => $locale->text('Order'), },
 909     'name'                    => { 'text' => $locale->text('Vendor'), },
 910     'netamount'               => { 'text' => $locale->text('Amount'), },
 911     'tax'                     => { 'text' => $locale->text('Tax'), },
 912     'amount'                  => { 'text' => $locale->text('Total'), },
 913     'paid'                    => { 'text' => $locale->text('Paid'), },
 914     'datepaid'                => { 'text' => $locale->text('Date Paid'), },
 915     'due'                     => { 'text' => $locale->text('Amount Due'), },
 916     'duedate'                 => { 'text' => $locale->text('Due Date'), },
 917     'transaction_description' => { 'text' => $locale->text('Transaction description'), },
 918     'notes'                   => { 'text' => $locale->text('Notes'), },
 919     'employee'                => { 'text' => $locale->text('Employee'), },
 920     'globalprojectnumber'     => { 'text' => $locale->text('Document Project Number'), },
 921     'vendornumber'            => { 'text' => $locale->text('Vendor Number'), },
 922     'country'                 => { 'text' => $locale->text('Country'), },
 923     'ustid'                   => { 'text' => $locale->text('USt-IdNr.'), },
 924     'taxzone'                 => { 'text' => $locale->text('Tax rate'), },
 925     'payment_terms'           => { 'text' => $locale->text('Payment Terms'), },
 926     'charts'                  => { 'text' => $locale->text('Buchungskonto'), },
 927     'direct_debit'            => { 'text' => $locale->text('direct debit'), },
 928   );
 929
 930   foreach my $name (qw(id transdate duedate invnumber ordnumber name datepaid employee shippingpoint shipvia transaction_description direct_debit)) {
 931     my $sortdir                 = $form->{sort} eq $name ? 1 - $form->{sortdir} : $form->{sortdir};
 932     $column_defs{$name}->{link} = $href . "&sort=$name&sortdir=$sortdir";
 933   }
 934
 935   my %column_alignment = map { $_ => 'right' } qw(netamount tax amount paid due);
 936
 937   $form->{"l_type"} = "Y";
 938   map { $column_defs{$_}->{visible} = $form->{"l_${_}"} ? 1 : 0 } @columns;
 939
 940   $report->set_columns(%column_defs);
 941   $report->set_column_order(@columns);
 942
 943   $report->set_export_options('ap_transactions', @hidden_variables, qw(sort sortdir));
 944
 945   $report->set_sort_indicator($form->{sort}, $form->{sortdir});
 946
 947   my @options;
 948   push @options, $locale->text('Vendor')                  . " : $form->{vendor}"                         if ($form->{vendor});
 949   push @options, $locale->text('Contact Person')          . " : $form->{cp_name}"                        if ($form->{cp_name});
 950   push @options, $locale->text('Department')              . " : $form->{department}"                     if ($form->{department});
 951   push @options, $locale->text('Invoice Number')          . " : $form->{invnumber}"                      if ($form->{invnumber});
 952   push @options, $locale->text('Order Number')            . " : $form->{ordnumber}"                      if ($form->{ordnumber});
 953   push @options, $locale->text('Notes')                   . " : $form->{notes}"                          if ($form->{notes});
 954   push @options, $locale->text('Transaction description') . " : $form->{transaction_description}"        if ($form->{transaction_description});
 955   push @options, $locale->text('Part Description')        . " : $form->{parts_description}"              if $form->{parts_description};
 956   push @options, $locale->text('Part Number')             . " : $form->{parts_partnumber}"               if $form->{parts_partnumber};
 957   push @options, $locale->text('From') . " " . $locale->date(\%myconfig, $form->{transdatefrom}, 1)      if ($form->{transdatefrom});
 958   push @options, $locale->text('Bis')  . " " . $locale->date(\%myconfig, $form->{transdateto},   1)      if ($form->{transdateto});
 959   push @options, $locale->text('Open')                                                                   if ($form->{open});
 960   push @options, $locale->text('Closed')                                                                 if ($form->{closed});
 961
 962   $report->set_options('top_info_text'        => join("\n", @options),
 963                        'raw_bottom_info_text' => $form->parse_html_template('ap/ap_transactions_bottom'),
 964                        'output_format'        => 'HTML',
 965                        'title'                => $form->{title},
 966                        'attachment_basename'  => $locale->text('vendor_invoice_list') . strftime('_%Y%m%d', localtime time),
 967     );
 968   $report->set_options_from_form();
 969   $locale->set_numberformat_wo_thousands_separator(\%myconfig) if lc($report->{options}->{output_format}) eq 'csv';
 970
 971   # add sort and escape callback, this one we use for the add sub
 972   $form->{callback} = $href .= "&sort=$form->{sort}";
 973
 974   # escape callback for href
 975   my $callback = $form->escape($href);
 976
 977   my @subtotal_columns = qw(netamount amount paid due);
 978
 979   my %totals    = map { $_ => 0 } @subtotal_columns;
 980   my %subtotals = map { $_ => 0 } @subtotal_columns;
 981
 982   my $idx = 0;
 983
 984   foreach my $ap (@{ $form->{AP} }) {
 985     $ap->{tax} = $ap->{amount} - $ap->{netamount};
 986     $ap->{due} = $ap->{amount} - $ap->{paid};
 987
 988     map { $subtotals{$_} += $ap->{$_};
 989           $totals{$_}    += $ap->{$_} } @subtotal_columns;
 990
 991     map { $ap->{$_} = $form->format_amount(\%myconfig, $ap->{$_}, 2) } qw(netamount tax amount paid due);
 992
 993     my $is_storno  = $ap->{storno} &&  $ap->{storno_id};
 994     my $has_storno = $ap->{storno} && !$ap->{storno_id};
 995
 996     if ($ap->{invoice}) {
 997       $ap->{type} =
 998           $has_storno       ? $locale->text("Invoice with Storno (abbreviation)")
 999         : $is_storno        ? $locale->text("Storno (one letter abbreviation)")
1000         :                     $locale->text("Invoice (one letter abbreviation)");
1001     } else {
1002       $ap->{type} =
1003           $has_storno       ? $locale->text("AP Transaction with Storno (abbreviation)")
1004         : $is_storno        ? $locale->text("AP Transaction Storno (one letter abbreviation)")
1005         :                     $locale->text("AP Transaction (abbreviation)");
1006     }
1007
1008     $ap->{direct_debit} = $ap->{direct_debit} ? $::locale->text('yes') : $::locale->text('no');
1009
1010     my $row = { };
1011
1012     foreach my $column (@columns) {
1013       $row->{$column} = {
1014         'data'  => $ap->{$column},
1015         'align' => $column_alignment{$column},
1016       };
1017     }
1018
1019     $row->{invnumber}->{link} = build_std_url("script=" . ($ap->{invoice} ? 'ir.pl' : 'ap.pl'), 'action=edit')
1020       . "&id=" . E($ap->{id}) . "&callback=${callback}";
1021
1022     my $row_set = [ $row ];
1023
1024     if (($form->{l_subtotal} eq 'Y')
1025         && (($idx == (scalar @{ $form->{AP} } - 1))
1026             || ($ap->{ $form->{sort} } ne $form->{AP}->[$idx + 1]->{ $form->{sort} }))) {
1027       push @{ $row_set }, create_subtotal_row(\%subtotals, \@columns, \%column_alignment, \@subtotal_columns, 'listsubtotal');
1028     }
1029
1030     $report->add_data($row_set);
1031
1032     $idx++;
1033   }
1034
1035   $report->add_separator();
1036   $report->add_data(create_subtotal_row(\%totals, \@columns, \%column_alignment, \@subtotal_columns, 'listtotal'));
1037
1038   $report->generate_with_headers();
1039
1040   $main::lxdebug->leave_sub();
1041 }
1042
1043 sub storno {
1044   $main::lxdebug->enter_sub();
1045
1046   my $form     = $main::form;
1047   my %myconfig = %main::myconfig;
1048   my $locale   = $main::locale;
1049
1050   $main::auth->assert('ap_transactions');
1051
1052   if (IS->has_storno(\%myconfig, $form, 'ap')) {
1053     $form->{title} = $locale->text("Cancel Accounts Payables Transaction");
1054     $form->error($locale->text("Transaction has already been cancelled!"));
1055   }
1056
1057   $form->error($locale->text('Cannot post storno for a closed period!'))
1058     if ( $form->date_closed($form->{transdate}, \%myconfig));
1059
1060   AP->storno($form, \%myconfig, $form->{id});
1061
1062   # saving the history
1063   if(!exists $form->{addition} && $form->{id} ne "") {
1064     $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
1065     $form->{addition}  = "STORNO";
1066     $form->{what_done} = "invoice";
1067     $form->save_history;
1068   }
1069   # /saving the history
1070
1071   $form->redirect(sprintf $locale->text("Transaction %d cancelled."), $form->{storno_id});
1072
1073   $main::lxdebug->leave_sub();
1074 }