SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise any);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::DeliveryTerm;
  12 use SL::DB::Vendor;
  13 use SL::DB::Contact;
  14 use SL::DB::History;
  15
  16 use parent qw(Rose::Object);
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  21  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by delivery_terms_by all_vc vc_by) ],
  22 );
  23
  24 sub run {
  25   my ($self, %params) = @_;
  26
  27   $self->test_run($params{test_run});
  28
  29   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  30
  31   my $profile = $self->profile;
  32   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  33                                   encoding               => $self->controller->profile->get('charset'),
  34                                   profile                => [{ profile => $profile, class => $self->class }],
  35                                   ignore_unknown_columns => 1,
  36                                   strict_profile         => 1,
  37                                   case_insensitive_header => 1,
  38                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  39                                  ));
  40
  41   $self->controller->track_progress(progress => 10);
  42
  43   my $old_numberformat      = $::myconfig{numberformat};
  44   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  45
  46   $self->csv->parse;
  47
  48   $self->controller->track_progress(progress => 50);
  49
  50   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  51
  52   return if ( !$self->csv->header || $self->csv->errors );
  53
  54   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  55   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  56   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  57   $self->controller->headers($headers);
  58   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  59   $self->controller->info_headers({ used => { }, headers => [ ] });
  60
  61   my @objects  = $self->csv->get_objects;
  62
  63   $self->controller->track_progress(progress => 70);
  64
  65   my @raw_data = @{ $self->csv->get_data };
  66
  67   $self->controller->track_progress(progress => 80);
  68
  69   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  70
  71   $self->controller->track_progress(progress => 90);
  72
  73   $self->check_objects;
  74   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  75     $self->check_std_duplicates();
  76     $self->check_duplicates();
  77   }
  78   $self->fix_field_lengths;
  79
  80   $self->controller->track_progress(progress => 100);
  81
  82   $::myconfig{numberformat} = $old_numberformat;
  83 }
  84
  85 sub add_columns {
  86   my ($self, @columns) = @_;
  87
  88   my $h = $self->controller->headers;
  89
  90   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  91     $h->{used}->{$column} = 1;
  92     push @{ $h->{methods} }, $column;
  93     push @{ $h->{headers} }, $column;
  94   }
  95 }
  96
  97 sub add_info_columns {
  98   my ($self, @columns) = @_;
  99
 100   my $h = $self->controller->info_headers;
 101
 102   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 103     $h->{used}->{ $column->{method} } = 1;
 104     push @{ $h->{methods} }, $column->{method};
 105     push @{ $h->{headers} }, $column->{header};
 106   }
 107 }
 108
 109 sub add_raw_data_columns {
 110   my ($self, @columns) = @_;
 111
 112   my $h = $self->controller->raw_data_headers;
 113
 114   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 115     $h->{used}->{$column} = 1;
 116     push @{ $h->{headers} }, $column;
 117   }
 118 }
 119
 120 sub add_cvar_raw_data_columns {
 121   my ($self) = @_;
 122
 123   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 124 }
 125
 126 sub init_all_cvar_configs {
 127   # Must be overridden by derived specialized importer classes.
 128   return [];
 129 }
 130
 131 sub init_cvar_columns {
 132   my ($self) = @_;
 133
 134   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 135 }
 136
 137 sub init_all_languages {
 138   my ($self) = @_;
 139
 140   return SL::DB::Manager::Language->get_all;
 141 }
 142
 143 sub init_payment_terms_by {
 144   my ($self) = @_;
 145
 146   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 147   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 148 }
 149
 150 sub init_delivery_terms_by {
 151   my ($self) = @_;
 152
 153   my $all_delivery_terms = SL::DB::Manager::DeliveryTerm->get_all;
 154   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_delivery_terms } } ) } qw(id description) };
 155 }
 156
 157 sub init_all_vc {
 158   my ($self) = @_;
 159
 160   return { customers => SL::DB::Manager::Customer->get_all,
 161            vendors   => SL::DB::Manager::Vendor->get_all };
 162 }
 163
 164 sub force_allow_columns {
 165   return ();
 166 }
 167
 168 sub init_vc_by {
 169   my ($self)    = @_;
 170
 171   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 172   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 173                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 174   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 175                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 176
 177   return { id     => \%by_id,
 178            number => \%by_number,
 179            name   => \%by_name,   };
 180 }
 181
 182 sub check_vc {
 183   my ($self, $entry, $id_column) = @_;
 184
 185   if ($entry->{object}->$id_column) {
 186     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 187   }
 188
 189   if (!$entry->{object}->$id_column) {
 190     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 191           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 192     $entry->{object}->$id_column($vc->id) if $vc;
 193   }
 194
 195   if (!$entry->{object}->$id_column) {
 196     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 197           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 198     $entry->{object}->$id_column($vc->id) if $vc;
 199   }
 200
 201   if ($entry->{object}->$id_column) {
 202     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 203   } else {
 204     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 205   }
 206 }
 207
 208 sub handle_cvars {
 209   my ($self, $entry) = @_;
 210
 211   my %type_to_column = ( text      => 'text_value',
 212                          textfield => 'text_value',
 213                          select    => 'text_value',
 214                          date      => 'timestamp_value_as_date',
 215                          timestamp => 'timestamp_value_as_date',
 216                          number    => 'number_value_as_number',
 217                          bool      => 'bool_value' );
 218
 219   my @cvars;
 220   foreach my $config (@{ $self->all_cvar_configs }) {
 221     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 222     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 223     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 224
 225     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 226   }
 227
 228   $entry->{object}->custom_variables(\@cvars);
 229 }
 230
 231 sub init_profile {
 232   my ($self) = @_;
 233
 234   eval "require " . $self->class;
 235
 236   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 237   delete $unwanted{$_} for ($self->force_allow_columns);
 238
 239   my %profile;
 240   for my $col ($self->class->meta->columns) {
 241     next if $unwanted{$col};
 242
 243     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 244       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 245       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 246       :                                                                     $col->name;
 247
 248     $profile{$col} = $name;
 249   }
 250
 251   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 252
 253   \%profile;
 254 }
 255
 256 sub add_displayable_columns {
 257   my ($self, @columns) = @_;
 258
 259   my @cols       = @{ $self->controller->displayable_columns || [] };
 260   my %ex_col_map = map { $_->{name} => $_ } @cols;
 261
 262   foreach my $column (@columns) {
 263     if ($ex_col_map{ $column->{name} }) {
 264       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 265     } else {
 266       push @cols, $column;
 267     }
 268   }
 269
 270   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 271 }
 272
 273 sub setup_displayable_columns {
 274   my ($self) = @_;
 275
 276   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 277 }
 278
 279 sub add_cvar_columns_to_displayable_columns {
 280   my ($self) = @_;
 281
 282   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 283                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 284                                      @{ $self->all_cvar_configs });
 285 }
 286
 287 sub init_existing_objects {
 288   my ($self) = @_;
 289
 290   eval "require " . $self->class;
 291   $self->existing_objects($self->manager_class->get_all);
 292 }
 293
 294 sub init_class {
 295   die "class not set";
 296 }
 297
 298 sub init_manager_class {
 299   my ($self) = @_;
 300
 301   $self->class =~ m/^SL::DB::(.+)/;
 302   $self->manager_class("SL::DB::Manager::" . $1);
 303 }
 304
 305 sub is_multiplexed { 0 }
 306
 307 sub check_objects {
 308 }
 309
 310 sub check_duplicates {
 311 }
 312
 313 sub check_std_duplicates {
 314   my $self = shift;
 315
 316   my $duplicates = {};
 317
 318   my $all_fields = $self->get_duplicate_check_fields();
 319
 320   foreach my $key (keys(%{ $all_fields })) {
 321     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 322       $duplicates->{$key} = {};
 323     }
 324   }
 325
 326   my @duplicates_keys = keys(%{ $duplicates });
 327
 328   if ( !scalar(@duplicates_keys) ) {
 329     return;
 330   }
 331
 332   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 333     foreach my $object (@{ $self->existing_objects }) {
 334       foreach my $key (@duplicates_keys) {
 335         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 336         $duplicates->{$key}->{$value} = 'db';
 337       }
 338     }
 339   }
 340
 341   foreach my $entry (@{ $self->controller->data }) {
 342     if ( @{ $entry->{errors} } ) {
 343       next;
 344     }
 345
 346     my $object = $entry->{object};
 347
 348     foreach my $key (@duplicates_keys) {
 349       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 350
 351       if ( exists($duplicates->{$key}->{$value}) ) {
 352         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 353         last;
 354       } else {
 355         $duplicates->{$key}->{$value} = 'csv';
 356       }
 357
 358     }
 359   }
 360
 361 }
 362
 363 sub get_duplicate_check_fields {
 364   return {};
 365 }
 366
 367 sub check_payment {
 368   my ($self, $entry) = @_;
 369
 370   my $object = $entry->{object};
 371
 372   # Check whether or not payment ID is valid.
 373   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 374     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 375     return 0;
 376   }
 377
 378   # Map name to ID if given.
 379   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 380     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 381
 382     if (!$terms) {
 383       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 384       return 0;
 385     }
 386
 387     $object->payment_id($terms->id);
 388   }
 389
 390   return 1;
 391 }
 392
 393 sub check_delivery_term {
 394   my ($self, $entry) = @_;
 395
 396   my $object = $entry->{object};
 397
 398   # Check whether or not delivery term ID is valid.
 399   if ($object->delivery_term_id && !$self->delivery_terms_by->{id}->{ $object->delivery_term_id }) {
 400     push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 401     return 0;
 402   }
 403
 404   # Map name to ID if given.
 405   if (!$object->delivery_term_id && $entry->{raw_data}->{delivery_term}) {
 406     my $terms = $self->delivery_terms_by->{description}->{ $entry->{raw_data}->{delivery_term} };
 407
 408     if (!$terms) {
 409       push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 410       return 0;
 411     }
 412
 413     $object->delivery_term_id($terms->id);
 414   }
 415
 416   return 1;
 417 }
 418
 419 sub save_objects {
 420   my ($self, %params) = @_;
 421
 422   my $data = $params{data} || $self->controller->data;
 423
 424   return unless $data->[0];
 425   return unless $data->[0]{object};
 426
 427   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 428
 429   my $dbh = $data->[0]{object}->db;
 430
 431   $dbh->begin_work;
 432   foreach my $entry_index (0 .. $#$data) {
 433     my $entry = $data->[$entry_index];
 434     next if @{ $entry->{errors} };
 435
 436     my $object = $entry->{object_to_save} || $entry->{object};
 437
 438     my $ret;
 439     if (!eval { $ret = $object->save(cascade => !!$self->save_with_cascade()); 1 }) {
 440       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $@);
 441     } elsif ( !$ret ) {
 442       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 443     } else {
 444       $self->_save_history($object);
 445       $self->controller->num_imported($self->controller->num_imported + 1);
 446     }
 447   } continue {
 448     if ($entry_index % 100 == 0) {
 449       $dbh->commit;
 450       $self->controller->track_progress(progress => $entry_index/scalar(@$data) * 100); # scale from 45..95%;
 451       $dbh->begin_work;
 452     }
 453   }
 454   $dbh->commit;
 455 }
 456
 457 sub field_lengths {
 458   return ();
 459 }
 460
 461 sub fix_field_lengths {
 462   my ($self) = @_;
 463
 464   my %field_lengths = $self->field_lengths;
 465   foreach my $entry (@{ $self->controller->data }) {
 466     next unless @{ $entry->{errors} };
 467     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 468   }
 469 }
 470
 471 sub clean_fields {
 472   my ($self, $illegal_chars, $object, @fields) = @_;
 473
 474   my @cleaned_fields;
 475   foreach my $field (grep { $object->can($_) } @fields) {
 476     my $value = $object->$field;
 477
 478     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 479
 480     $object->$field($value);
 481     push @cleaned_fields, $field;
 482   }
 483
 484   return @cleaned_fields;
 485 }
 486
 487 sub _save_history {
 488   my ($self, $object) = @_;
 489
 490   if (any { $_ eq $self->controller->{type} } qw(parts customers_vendors orders)) {
 491     my $snumbers = $self->controller->{type} eq 'parts'             ? 'partnumber_' . $object->partnumber
 492                  : $self->controller->{type} eq 'customers_vendors' ?
 493                      ($self->table eq 'customer' ? 'customernumber_' . $object->customernumber : 'vendornumber_' . $object->vendornumber)
 494                  : $self->controller->{type} eq 'orders'            ? 'ordnumber_' . $object->ordnumber
 495                  : '';
 496
 497     my $what_done = $self->controller->{type} eq 'orders' ? 'sales_order'
 498                   : '';
 499
 500     SL::DB::History->new(
 501       trans_id    => $object->id,
 502       snumbers    => $snumbers,
 503       employee_id => $self->controller->{employee_id},
 504       addition    => 'SAVED',
 505       what_done   => $what_done,
 506     )->save();
 507   }
 508 }
 509
 510 1;