SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any none);
   7
   8 use SL::Helper::Csv;
   9 use SL::Controller::CsvImport::Helper::Consistency;
  10 use SL::DB::Order;
  11 use SL::DB::OrderItem;
  12 use SL::DB::Part;
  13 use SL::DB::PaymentTerm;
  14 use SL::DB::Contact;
  15 use SL::DB::Department;
  16 use SL::DB::PriceFactor;
  17 use SL::DB::Pricegroup;
  18 use SL::DB::Project;
  19 use SL::DB::Shipto;
  20 use SL::DB::TaxZone;
  21 use SL::DB::Unit;
  22 use SL::TransNumber;
  23
  24 use parent qw(SL::Controller::CsvImport::BaseMulti);
  25
  26
  27 use Rose::Object::MakeMethods::Generic
  28 (
  29  'scalar --get_set_init' => [ qw(settings languages_by parts_by contacts_by ct_shiptos_by price_factors_by pricegroups_by units_by) ],
  30 );
  31
  32
  33 sub init_class {
  34   my ($self) = @_;
  35   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  36 }
  37
  38 sub set_profile_defaults {
  39   my ($self) = @_;
  40
  41   $self->controller->profile->_set_defaults(
  42                        order_column    => $::locale->text('Order'),
  43                        item_column     => $::locale->text('OrderItem'),
  44                        max_amount_diff => 0.02,
  45                       );
  46 };
  47
  48
  49 sub init_settings {
  50   my ($self) = @_;
  51
  52   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  53 }
  54
  55
  56 sub init_cvar_configs_by {
  57   my ($self) = @_;
  58
  59   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  60   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  61
  62   my $ccb;
  63   $ccb->{class}->{'SL::DB::Order'}          = [];
  64   $ccb->{class}->{'SL::DB::OrderItem'}      = $item_cvar_configs;
  65   $ccb->{row_ident}->{$self->_order_column} = [];
  66   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  67
  68   return $ccb;
  69 }
  70
  71
  72 sub init_profile {
  73   my ($self) = @_;
  74
  75   my $profile = $self->SUPER::init_profile;
  76
  77   # SUPER::init_profile sets row_ident to the translated class name
  78   # overwrite it with the user specified settings
  79   foreach my $p (@{ $profile }) {
  80     if ($p->{class} eq 'SL::DB::Order') {
  81       $p->{row_ident} = $self->_order_column;
  82     }
  83     if ($p->{class} eq 'SL::DB::OrderItem') {
  84       $p->{row_ident} = $self->_item_column;
  85     }
  86   }
  87
  88   foreach my $p (@{ $profile }) {
  89     my $prof = $p->{profile};
  90     if ($p->{row_ident} eq $self->_order_column) {
  91       # no need to handle
  92       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  93     }
  94     if ($p->{row_ident} eq $self->_item_column) {
  95       # no need to handle
  96       delete @{$prof}{qw(trans_id)};
  97     }
  98   }
  99
 100   return $profile;
 101 }
 102
 103
 104 sub setup_displayable_columns {
 105   my ($self) = @_;
 106
 107   $self->SUPER::setup_displayable_columns;
 108
 109   $self->add_displayable_columns($self->_order_column,
 110                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 111                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 112                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 113                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 114                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 115                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 116                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 117                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 118                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 119                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 120                                  { name => 'marge_percent',           description => $::locale->text('Margepercent')                          },
 121                                  { name => 'marge_total',             description => $::locale->text('Margetotal')                            },
 122                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 123                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 124                                  { name => 'quonumber',               description => $::locale->text('Quotation Number')                      },
 125                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 126                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 127                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 128                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 129                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 130                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 131                                  { name => 'verify_amount',           description => $::locale->text('Amount (for verification)') . ' [2]'    },
 132                                  { name => 'verify_netamount',        description => $::locale->text('Net amount (for verification)') . ' [2]'},
 133                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 134                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 135                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 136                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 137                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 138                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 139                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 140                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 141                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 142                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 143                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 144                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 145                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 146                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 147                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 148                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 149                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 150                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 151                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 152                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 153                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 154                                 );
 155
 156   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 157
 158   $self->add_displayable_columns($self->_item_column,
 159                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 160                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 161                                  { name => 'description',     description => $::locale->text('Description')                },
 162                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 163                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 164                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 165                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 166                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 167                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 168                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 169                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 170                                  { name => 'position',        description => $::locale->text('position')                   },
 171                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 172                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 173                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 174                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 175                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 176                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 177                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 178                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 179                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 180                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 181                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 182                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 183                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 184                                 );
 185 }
 186
 187
 188 sub init_languages_by {
 189   my ($self) = @_;
 190
 191   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 192 }
 193
 194 sub init_parts_by {
 195   my ($self) = @_;
 196
 197   my $all_parts = SL::DB::Manager::Part->get_all;
 198   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_parts } } ) } qw(id partnumber ean description) };
 199 }
 200
 201 sub init_contacts_by {
 202   my ($self) = @_;
 203
 204   my $all_contacts = SL::DB::Manager::Contact->get_all;
 205
 206   my $cby;
 207   # by customer/vendor id  _and_  contact person id
 208   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 209   # by customer/vendor id  _and_  contact person name
 210   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 211
 212   return $cby;
 213 }
 214
 215 sub init_ct_shiptos_by {
 216   my ($self) = @_;
 217
 218   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 219
 220   my $sby;
 221   # by trans_id  _and_  shipto_id
 222   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 223
 224   return $sby;
 225 }
 226
 227 sub init_price_factors_by {
 228   my ($self) = @_;
 229
 230   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 231   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 232 }
 233
 234 sub init_pricegroups_by {
 235   my ($self) = @_;
 236
 237   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 238   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 239 }
 240
 241 sub init_units_by {
 242   my ($self) = @_;
 243
 244   my $all_units = SL::DB::Manager::Unit->get_all;
 245   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
 246 }
 247
 248 sub check_objects {
 249   my ($self) = @_;
 250
 251   $self->controller->track_progress(phase => 'building data', progress => 0);
 252
 253   my $i = 0;
 254   my $num_data = scalar @{ $self->controller->data };
 255   foreach my $entry (@{ $self->controller->data }) {
 256     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 257
 258     $entry->{info_data}->{datatype} = $entry->{raw_data}->{datatype};
 259
 260     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 261       $self->handle_order($entry);
 262     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 263       $self->handle_item($entry);
 264     }
 265     $self->handle_cvars($entry, sub_module => 'orderitems');
 266
 267   } continue {
 268     $i++;
 269   }
 270
 271   $self->add_info_columns($self->_order_column,
 272                           { header => $::locale->text('Data type'), method => 'datatype' });
 273   $self->add_info_columns($self->_item_column,
 274                           { header => $::locale->text('Data type'), method => 'datatype' });
 275
 276   $self->add_info_columns($self->_order_column,
 277                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 278   # Todo: access via ->[0] ok? Better: search first order column and use this
 279   $self->add_columns($self->_order_column,
 280                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 281   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 282   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 283
 284   $self->add_info_columns($self->_item_column,
 285                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 286   # Todo: access via ->[1] ok? Better: search first item column and use this
 287   $self->add_columns($self->_item_column,
 288                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 289   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 290
 291   $self->add_cvar_raw_data_columns();
 292
 293   $self->add_items_to_order();
 294   $self->handle_prices_and_taxes();
 295 }
 296
 297 sub handle_order {
 298   my ($self, $entry) = @_;
 299
 300   my $object = $entry->{object};
 301
 302   my $vc_obj;
 303   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_id)) {
 304     $self->check_vc($entry, 'customer_id');
 305     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 306   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_id)) {
 307     $self->check_vc($entry, 'vendor_id');
 308     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 309   } else {
 310     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 311   }
 312
 313   $self->check_contact($entry);
 314   $self->check_language($entry);
 315   $self->check_payment($entry);
 316   $self->check_delivery_term($entry);
 317   $self->check_department($entry);
 318   $self->check_project($entry, global => 1);
 319   $self->check_ct_shipto($entry);
 320   $self->check_taxzone($entry);
 321   $self->check_currency($entry, take_default => 0);
 322
 323   if ($vc_obj) {
 324     # copy from customer if not given
 325     foreach (qw(payment_id delivery_term_id language_id taxzone_id currency_id)) {
 326       $object->$_($vc_obj->$_) unless $object->$_;
 327     }
 328   }
 329
 330   $self->handle_salesman($entry);
 331   $self->handle_employee($entry);
 332 }
 333
 334 sub check_language {
 335   my ($self, $entry) = @_;
 336
 337   my $object = $entry->{object};
 338
 339   # Check whether or not language ID is valid.
 340   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 341     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 342     return 0;
 343   }
 344
 345   # Map name to ID if given.
 346   if (!$object->language_id && $entry->{raw_data}->{language}) {
 347     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 348                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 349
 350     if (!$language) {
 351       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 352       return 0;
 353     }
 354
 355     $object->language_id($language->id);
 356   }
 357
 358   if ($object->language_id) {
 359     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 360   }
 361
 362   return 1;
 363 }
 364
 365 sub handle_item {
 366   my ($self, $entry) = @_;
 367
 368   my $object = $entry->{object};
 369   return unless $self->check_part($entry);
 370
 371   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 372
 373   $self->handle_unit($entry);
 374   $self->handle_sellprice($entry);
 375
 376   # copy from part if not given
 377   $object->description($part_obj->description) unless $object->description;
 378   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 379   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 380
 381   # set to 0 if not given
 382   $object->discount(0) unless $object->discount;
 383   $object->ship(0)     unless $object->ship;
 384
 385   $self->check_project($entry, global => 0);
 386   $self->check_price_factor($entry);
 387   $self->check_pricegroup($entry);
 388 }
 389
 390 sub handle_unit {
 391   my ($self, $entry) = @_;
 392
 393   my $object = $entry->{object};
 394
 395   # Set unit from part if not given.
 396   if (!$object->unit) {
 397     $object->unit($object->part->unit);
 398     return 1;
 399   }
 400
 401   # Check whether or not unit is valid.
 402   if ($object->unit && !$self->units_by->{name}->{ $object->unit }) {
 403     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 404     return 0;
 405   }
 406
 407   # Check whether unit is convertible to parts unit
 408   if (none { $object->unit eq $_ } map { $_->name } @{ $object->part->unit_obj->convertible_units }) {
 409     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 410     return 0;
 411   }
 412
 413   return 1;
 414 }
 415
 416 sub handle_sellprice {
 417   my ($self, $entry) = @_;
 418
 419   my $object = $entry->{object};
 420
 421   # Set sellprice from part if not given. Convert with respect to unit.
 422   if (!defined $object->sellprice) {
 423     my $sellprice = $object->part->sellprice;
 424
 425     if ($object->unit ne $object->part->unit) {
 426       $sellprice = $object->unit_obj->convert_to($sellprice, $object->part->unit_obj);
 427     }
 428     $object->sellprice($sellprice);
 429   }
 430 }
 431
 432 sub check_part {
 433   my ($self, $entry) = @_;
 434
 435   my $object = $entry->{object};
 436
 437   # Check whether or not part ID is valid.
 438   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 439     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 440     return 0;
 441   }
 442
 443   # Map number to ID if given.
 444   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 445     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 446     if (!$part) {
 447       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 448       return 0;
 449     }
 450
 451     $object->parts_id($part->id);
 452   }
 453
 454   # Map description to ID if given.
 455   if (!$object->parts_id && $entry->{raw_data}->{description}) {
 456     my $part = $self->parts_by->{description}->{ $entry->{raw_data}->{description} };
 457     if (!$part) {
 458       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 459       return 0;
 460     }
 461
 462     $object->parts_id($part->id);
 463   }
 464
 465   if ($object->parts_id) {
 466     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 467   } else {
 468     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 469     return 0;
 470   }
 471
 472   if ($self->parts_by->{id}->{ $object->parts_id }->obsolete) {
 473     push @{ $entry->{errors} }, $::locale->text('Error: Part is obsolete');
 474     return 0;
 475   }
 476
 477   return 1;
 478 }
 479
 480 sub check_contact {
 481   my ($self, $entry) = @_;
 482
 483   my $object = $entry->{object};
 484
 485   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 486   return 0 unless $cp_cv_id;
 487
 488   # Check whether or not contact ID is valid.
 489   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 490     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 491     return 0;
 492   }
 493
 494   # Map name to ID if given.
 495   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 496     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 497     if (!$cp) {
 498       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 499       return 0;
 500     }
 501
 502     $object->cp_id($cp->cp_id);
 503   }
 504
 505   if ($object->cp_id) {
 506     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 507   }
 508
 509   return 1;
 510 }
 511
 512 sub check_ct_shipto {
 513   my ($self, $entry) = @_;
 514
 515   my $object = $entry->{object};
 516
 517   my $trans_id = $object->customer_id || $object->vendor_id;
 518   return 0 unless $trans_id;
 519
 520   # Check whether or not shipto ID is valid.
 521   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 522     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 523     return 0;
 524   }
 525
 526   return 1;
 527 }
 528
 529 sub check_price_factor {
 530   my ($self, $entry) = @_;
 531
 532   my $object = $entry->{object};
 533
 534   # Check whether or not price_factor ID is valid.
 535   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 536     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 537     return 0;
 538   }
 539
 540   # Map description to ID if given.
 541   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 542     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 543     if (!$price_factor) {
 544       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 545       return 0;
 546     }
 547
 548     $object->price_factor_id($price_factor->id);
 549   }
 550
 551   return 1;
 552 }
 553
 554 sub check_pricegroup {
 555   my ($self, $entry) = @_;
 556
 557   my $object = $entry->{object};
 558
 559   # Check whether or not pricegroup ID is valid.
 560   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 561     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 562     return 0;
 563   }
 564
 565   # Map pricegroup to ID if given.
 566   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 567     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 568     if (!$pricegroup) {
 569       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 570       return 0;
 571     }
 572
 573     $object->pricegroup_id($pricegroup->id);
 574   }
 575
 576   return 1;
 577 }
 578
 579 sub add_items_to_order {
 580   my ($self) = @_;
 581
 582   # add orderitems to order
 583   my $order_entry;
 584   my @orderitems;
 585   foreach my $entry (@{ $self->controller->data }) {
 586     # search first/next order
 587     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 588
 589       # next order entry: add collected orderitems to the previous one
 590       if (defined $order_entry) {
 591         $order_entry->{object}->orderitems(@orderitems);
 592         @orderitems = ();
 593       }
 594
 595       $order_entry = $entry;
 596
 597     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 598       # collect orderitems to add to order (if they have no errors)
 599       # ( add_orderitems does not work here if we want to call
 600       #   calculate_prices_and_taxes afterwards ...
 601       #   so collect orderitems and add them at once )
 602       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 603     }
 604   }
 605   # add last collected orderitems to last order
 606   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 607 }
 608
 609 sub handle_prices_and_taxes() {
 610   my ($self) = @_;
 611
 612   # calculate prices and taxes
 613   foreach my $entry (@{ $self->controller->data }) {
 614     next if @{ $entry->{errors} };
 615
 616     if ($entry->{raw_data}->{datatype} eq $self->_order_column && $entry->{object}->orderitems) {
 617
 618       $entry->{object}->calculate_prices_and_taxes;
 619
 620       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 621       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 622     }
 623   }
 624
 625   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 626   # And throw an error if the differences are too big.
 627   my @to_verify = ( { column      => 'amount',
 628                       raw_column  => 'verify_amount',
 629                       info_header => 'Calc. Amount',
 630                       info_method => 'calc_amount',
 631                       err_msg     => 'Amounts differ too much',
 632                     },
 633                     { column      => 'netamount',
 634                       raw_column  => 'verify_netamount',
 635                       info_header => 'Calc. Net amount',
 636                       info_method => 'calc_netamount',
 637                       err_msg     => 'Net amounts differ too much',
 638                     } );
 639
 640   foreach my $tv (@to_verify) {
 641     # Todo: access via ->[0] ok? Better: search first order column and use this
 642     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 643       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 644       $self->add_info_columns($self->_order_column,
 645                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 646     }
 647
 648     # check differences
 649     foreach my $entry (@{ $self->controller->data }) {
 650       next if @{ $entry->{errors} };
 651       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 652         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 653         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 654         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 655           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 656         }
 657       }
 658     }
 659   }
 660
 661 }
 662
 663 sub save_objects {
 664   my ($self, %params) = @_;
 665
 666   # Collect orders without errors to save.
 667   my $entries_to_save = [];
 668   foreach my $entry (@{ $self->controller->data }) {
 669     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
 670     next if @{ $entry->{errors} };
 671
 672     push @{ $entries_to_save }, $entry;
 673   }
 674
 675   $self->SUPER::save_objects(data => $entries_to_save);
 676 }
 677
 678 sub _order_column {
 679   $_[0]->settings->{'order_column'}
 680 }
 681
 682 sub _item_column {
 683   $_[0]->settings->{'item_column'}
 684 }
 685
 686 1;