SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13 use SL::Template;
  14
  15 use SL::DB::Order;
  16 use SL::DB::Customer;
  17 use SL::DB::Vendor;
  18 use SL::DB::TaxZone;
  19 use SL::DB::Employee;
  20 use SL::DB::Project;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Price;
  24 use SL::DB::PriceFactor;
  25 use SL::DB::Part;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28
  29 use SL::Helper::DateTime;
  30 use SL::Helper::CreatePDF qw(:all);
  31 use SL::Helper::PrintOptions;
  32
  33 use SL::Controller::Helper::GetModels;
  34
  35 use List::Util qw(max first);
  36 use List::MoreUtils qw(none pairwise first_index);
  37 use English qw(-no_match_vars);
  38 use File::Spec;
  39
  40 use Rose::Object::MakeMethods::Generic
  41 (
  42  scalar => [ qw(item_ids_to_delete) ],
  43  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors) ],
  44 );
  45
  46
  47 # safety
  48 __PACKAGE__->run_before('_check_auth');
  49
  50 __PACKAGE__->run_before('_recalc',
  51                         only => [ qw(update save save_and_delivery_order print create_pdf send_email) ]);
  52
  53 __PACKAGE__->run_before('_get_unalterable_data',
  54                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  55
  56 #
  57 # actions
  58 #
  59
  60 sub action_add {
  61   my ($self) = @_;
  62
  63   $self->order->transdate(DateTime->now_local());
  64   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  65
  66   $self->_pre_render();
  67   $self->render(
  68     'order/form',
  69     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  70            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  71            : '',
  72     %{$self->{template_args}}
  73   );
  74 }
  75
  76 sub action_edit {
  77   my ($self) = @_;
  78
  79   $self->_load_order;
  80   $self->_recalc();
  81   $self->_pre_render();
  82   $self->render(
  83     'order/form',
  84     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  85            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  86            : '',
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 sub action_update {
  92   my ($self) = @_;
  93
  94   $self->_pre_render();
  95   $self->render(
  96     'order/form',
  97     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  98            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  99            : '',
 100     %{$self->{template_args}}
 101   );
 102 }
 103
 104 sub action_delete {
 105   my ($self) = @_;
 106
 107   my $errors = $self->_delete();
 108
 109   if (scalar @{ $errors }) {
 110     $self->js->flash('error', $_) foreach @{ $errors };
 111     return $self->js->render();
 112   }
 113
 114   flash_later('info', $::locale->text('The order has been deleted'));
 115   my @redirect_params = (
 116     action => 'edit',
 117     type   => $self->type,
 118   );
 119
 120   $self->redirect_to(@redirect_params);
 121 }
 122
 123 sub action_save {
 124   my ($self) = @_;
 125
 126   my $errors = $self->_save();
 127
 128   if (scalar @{ $errors }) {
 129     $self->js->flash('error', $_) foreach @{ $errors };
 130     return $self->js->render();
 131   }
 132
 133   flash_later('info', $::locale->text('The order has been saved'));
 134   my @redirect_params = (
 135     action => 'edit',
 136     type   => $self->type,
 137     id     => $self->order->id,
 138   );
 139
 140   $self->redirect_to(@redirect_params);
 141 }
 142
 143 sub action_print {
 144   my ($self) = @_;
 145
 146   my $format      = $::form->{print_options}->{format};
 147   my $media       = $::form->{print_options}->{media};
 148   my $formname    = $::form->{print_options}->{formname};
 149   my $copies      = $::form->{print_options}->{copies};
 150   my $groupitems  = $::form->{print_options}->{groupitems};
 151
 152   # only pdf by now
 153   if (none { $format eq $_ } qw(pdf)) {
 154     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 155   }
 156
 157   # only screen or printer by now
 158   if (none { $media eq $_ } qw(screen printer)) {
 159     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 160   }
 161
 162   my $language;
 163   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 164
 165   my $form = Form->new;
 166   $form->{ordnumber} = $self->order->ordnumber;
 167   $form->{type}      = $self->type;
 168   $form->{format}    = $format;
 169   $form->{formname}  = $formname;
 170   $form->{language}  = '_' . $language->template_code if $language;
 171   my $pdf_filename   = $form->generate_attachment_filename();
 172
 173   my $pdf;
 174   my @errors = _create_pdf($self->order, \$pdf, { format     => $format,
 175                                                   formname   => $formname,
 176                                                   language   => $language,
 177                                                   groupitems => $groupitems });
 178   if (scalar @errors) {
 179     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 180   }
 181
 182   if ($media eq 'screen') {
 183     # screen/download
 184     my $sfile = SL::SessionFile::Random->new(mode => "w");
 185     $sfile->fh->print($pdf);
 186     $sfile->fh->close;
 187
 188     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 189     $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 190
 191     $self->js
 192     ->run('kivi.Order.download_pdf', $pdf_filename, $key)
 193     ->flash('info', t8('The PDF has been created'));
 194
 195   } elsif ($media eq 'printer') {
 196     # printer
 197     my $printer_id = $::form->{print_options}->{printer_id};
 198     my $printer;
 199     $printer = SL::DB::Printer->new(id => $printer_id)->load if $printer_id;
 200     if (!$printer) {
 201       return $self->js->flash('error', t8('Printer not found.'))->render;
 202     }
 203
 204     my $command = SL::Template::create(type => 'ShellCommand', form => Form->new(''))->parse($printer->printer_command);
 205
 206     for my $i (1 .. $copies) {
 207       open my $out, '|-', $command or die $!;
 208       binmode $out;
 209       print $out $pdf;
 210       close $out;
 211     }
 212
 213     $self->js->flash('info', t8('The PDF has been printed'));
 214   }
 215
 216   # copy file to webdav folder
 217   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 218     my $webdav = SL::Webdav->new(
 219       type     => $self->type,
 220       number   => $self->order->ordnumber,
 221     );
 222     my $webdav_file = SL::Webdav::File->new(
 223       webdav   => $webdav,
 224       filename => $pdf_filename,
 225     );
 226     eval {
 227       $webdav_file->store(data => \$pdf);
 228       1;
 229     } or do {
 230       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 231     }
 232   }
 233
 234   $self->js->render;
 235 }
 236
 237 sub action_download_pdf {
 238   my ($self) = @_;
 239
 240   my $key = $::form->{key};
 241   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 242   return $self->send_file(
 243     $tmp_filename,
 244     type => 'application/pdf',
 245     name => $::form->{pdf_filename},
 246   );
 247 }
 248
 249 sub action_show_email_dialog {
 250   my ($self) = @_;
 251
 252   my $cv_method = $self->cv;
 253
 254   if (!$self->order->$cv_method) {
 255     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 256                     ->render($self);
 257   }
 258
 259   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 260   $self->{email}->{to} ||= $self->order->$cv_method->email;
 261   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 262   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 263   # Todo: get addresses from shipto, if any
 264
 265   my $form = Form->new;
 266   $form->{ordnumber} = $self->order->ordnumber;
 267   $form->{formname}  = $self->type;
 268   $form->{type}      = $self->type;
 269   $form->{language} = 'de';
 270   $form->{format}   = 'pdf';
 271
 272   $self->{email}->{subject}             = $form->generate_email_subject();
 273   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 274   $self->{email}->{message}             = $form->create_email_signature();
 275
 276   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 277   $self->js
 278       ->run('kivi.Order.show_email_dialog', $dialog_html)
 279       ->reinit_widgets
 280       ->render($self);
 281 }
 282
 283 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 284 sub action_send_email {
 285   my ($self) = @_;
 286
 287   my $mail      = Mailer->new;
 288   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 289   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 290
 291   my $pdf;
 292   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 293   if (scalar @errors) {
 294     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 295   }
 296
 297   $mail->{attachments} = [{ "content" => $pdf,
 298                             "name"    => $::form->{email}->{attachment_filename} }];
 299
 300   if (my $err = $mail->send) {
 301     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 302                     ->render($self);
 303   }
 304
 305   # internal notes
 306   my $intnotes = $self->order->intnotes;
 307   $intnotes   .= "\n\n" if $self->order->intnotes;
 308   $intnotes   .= t8('[email]')                                                                                        . "\n";
 309   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 310   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 311   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 312   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 313   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 314   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 315
 316   $self->js
 317       ->val('#order_intnotes', $intnotes)
 318       ->run('kivi.Order.close_email_dialog')
 319       ->render($self);
 320 }
 321
 322 sub action_save_and_delivery_order {
 323   my ($self) = @_;
 324
 325   my $errors = $self->_save();
 326
 327   if (scalar @{ $errors }) {
 328     $self->js->flash('error', $_) foreach @{ $errors };
 329     return $self->js->render();
 330   }
 331   flash_later('info', $::locale->text('The order has been saved'));
 332
 333   my @redirect_params = (
 334     controller => 'oe.pl',
 335     action     => 'oe_delivery_order_from_order',
 336     id         => $self->order->id,
 337   );
 338
 339   $self->redirect_to(@redirect_params);
 340 }
 341
 342 sub action_customer_vendor_changed {
 343   my ($self) = @_;
 344
 345   my $cv_method = $self->cv;
 346
 347   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 348     $self->js->show('#cp_row');
 349   } else {
 350     $self->js->hide('#cp_row');
 351   }
 352
 353   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 354     $self->js->show('#shipto_row');
 355   } else {
 356     $self->js->hide('#shipto_row');
 357   }
 358
 359   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 360
 361   if ($self->order->is_sales) {
 362     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 363                               ? $self->order->$cv_method->taxincluded_checked
 364                               : $::myconfig{taxincluded_checked});
 365   }
 366
 367   $self->order->payment_id($self->order->$cv_method->payment_id);
 368   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 369
 370   $self->_recalc();
 371
 372   $self->js
 373     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 374     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 375     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 376     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 377     ->val(        '#order_payment_id',       $self->order->payment_id)
 378     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 379     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 380     ->focus(      '#order_' . $self->cv . '_id');
 381
 382   $self->_js_redisplay_amounts_and_taxes;
 383   $self->js->render();
 384 }
 385
 386 sub action_unit_changed {
 387   my ($self) = @_;
 388
 389   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 390   my $item = $self->order->items_sorted->[$idx];
 391
 392   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 393   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 394
 395   $self->_recalc();
 396
 397   $self->js
 398     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 399   $self->_js_redisplay_linetotals;
 400   $self->_js_redisplay_amounts_and_taxes;
 401   $self->js->render();
 402 }
 403
 404 sub action_add_item {
 405   my ($self) = @_;
 406
 407   my $form_attr = $::form->{add_item};
 408
 409   return unless $form_attr->{parts_id};
 410
 411   my $item = _new_item($self->order, $form_attr);
 412   $self->order->add_items($item);
 413
 414   $self->_recalc();
 415
 416   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 417   my $row_as_html = $self->p->render('order/tabs/_row',
 418                                      ITEM              => $item,
 419                                      ID                => $item_id,
 420                                      ALL_PRICE_FACTORS => $self->all_price_factors
 421   );
 422
 423   $self->js
 424     ->append('#row_table_id', $row_as_html)
 425     ->val('.add_item_input', '')
 426     ->run('kivi.Order.init_row_handlers')
 427     ->run('kivi.Order.row_table_scroll_down')
 428     ->run('kivi.Order.renumber_positions')
 429     ->focus('#add_item_parts_id_name');
 430
 431   $self->_js_redisplay_amounts_and_taxes;
 432   $self->js->render();
 433 }
 434
 435 sub action_show_multi_items_dialog {
 436   require SL::DB::PartsGroup;
 437   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 438                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 439 }
 440
 441 sub action_multi_items_update_result {
 442   my $max_count = 100;
 443
 444   $::form->{multi_items}->{filter}->{obsolete} = 0;
 445
 446   my $count = $_[0]->multi_items_models->count;
 447
 448   if ($count == 0) {
 449     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 450     $_[0]->render($text, { layout => 0 });
 451   } elsif ($count > $max_count) {
 452     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 453     $_[0]->render($text, { layout => 0 });
 454   } else {
 455     my $multi_items = $_[0]->multi_items_models->get;
 456     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 457                   multi_items => $multi_items);
 458   }
 459 }
 460
 461 sub action_add_multi_items {
 462   my ($self) = @_;
 463
 464   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 465   return $self->js->render() unless scalar @form_attr;
 466
 467   my @items;
 468   foreach my $attr (@form_attr) {
 469     push @items, _new_item($self->order, $attr);
 470   }
 471   $self->order->add_items(@items);
 472
 473   $self->_recalc();
 474
 475   foreach my $item (@items) {
 476     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 477     my $row_as_html = $self->p->render('order/tabs/_row',
 478                                        ITEM              => $item,
 479                                        ID                => $item_id,
 480                                        ALL_PRICE_FACTORS => $self->all_price_factors
 481     );
 482
 483     $self->js->append('#row_table_id', $row_as_html);
 484   }
 485
 486   $self->js
 487     ->run('kivi.Order.close_multi_items_dialog')
 488     ->run('kivi.Order.init_row_handlers')
 489     ->run('kivi.Order.row_table_scroll_down')
 490     ->run('kivi.Order.renumber_positions')
 491     ->focus('#add_item_parts_id_name');
 492
 493   $self->_js_redisplay_amounts_and_taxes;
 494   $self->js->render();
 495 }
 496
 497 sub action_recalc_amounts_and_taxes {
 498   my ($self) = @_;
 499
 500   $self->_recalc();
 501
 502   $self->_js_redisplay_linetotals;
 503   $self->_js_redisplay_amounts_and_taxes;
 504   $self->js->render();
 505 }
 506
 507 sub action_reorder_items {
 508   my ($self) = @_;
 509
 510   my %sort_keys = (
 511     partnumber  => sub { $_[0]->part->partnumber },
 512     description => sub { $_[0]->description },
 513     qty         => sub { $_[0]->qty },
 514     sellprice   => sub { $_[0]->sellprice },
 515     discount    => sub { $_[0]->discount },
 516   );
 517
 518   my $method = $sort_keys{$::form->{order_by}};
 519   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 520   if ($::form->{sort_dir}) {
 521     @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 522   } else {
 523     @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 524   }
 525   $self->js
 526     ->run('kivi.Order.redisplay_items', \@to_sort)
 527     ->render;
 528 }
 529
 530 sub action_price_popup {
 531   my ($self) = @_;
 532
 533   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 534   my $item = $self->order->items_sorted->[$idx];
 535
 536   $self->render_price_dialog($item);
 537 }
 538
 539 sub action_get_item_longdescription {
 540   my $longdescription;
 541
 542   if ($::form->{item_id}) {
 543     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 544   } elsif ($::form->{parts_id}) {
 545     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 546   }
 547   $_[0]->render(\ $longdescription, { type => 'text' });
 548 }
 549
 550
 551 sub _js_redisplay_linetotals {
 552   my ($self) = @_;
 553
 554   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items_sorted };
 555   $self->js
 556     ->run('kivi.Order.redisplay_linetotals', \@data);
 557 }
 558
 559 sub _js_redisplay_amounts_and_taxes {
 560   my ($self) = @_;
 561
 562   if (scalar @{ $self->{taxes} }) {
 563     $self->js->show('#taxincluded_row_id');
 564   } else {
 565     $self->js->hide('#taxincluded_row_id');
 566   }
 567
 568   if ($self->order->taxincluded) {
 569     $self->js->hide('#subtotal_row_id');
 570   } else {
 571     $self->js->show('#subtotal_row_id');
 572   }
 573
 574   $self->js
 575     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 576     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 577     ->remove('.tax_row')
 578     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 579 }
 580
 581 #
 582 # helpers
 583 #
 584
 585 sub init_valid_types {
 586   [ _sales_order_type(), _purchase_order_type() ];
 587 }
 588
 589 sub init_type {
 590   my ($self) = @_;
 591
 592   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 593     die "Not a valid type for order";
 594   }
 595
 596   $self->type($::form->{type});
 597 }
 598
 599 sub init_cv {
 600   my ($self) = @_;
 601
 602   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 603          : $self->type eq _purchase_order_type() ? 'vendor'
 604          : die "Not a valid type for order";
 605
 606   return $cv;
 607 }
 608
 609 sub init_p {
 610   SL::Presenter->get;
 611 }
 612
 613 sub init_order {
 614   $_[0]->_make_order;
 615 }
 616
 617 sub init_multi_items_models {
 618   SL::Controller::Helper::GetModels->new(
 619     controller     => $_[0],
 620     model          => 'Part',
 621     with_objects   => [ qw(unit_obj) ],
 622     disable_plugin => 'paginated',
 623     source         => $::form->{multi_items},
 624     sorted         => {
 625       _default    => {
 626         by  => 'partnumber',
 627         dir => 1,
 628       },
 629       partnumber  => t8('Partnumber'),
 630       description => t8('Description')}
 631   );
 632 }
 633
 634 sub init_all_price_factors {
 635   SL::DB::Manager::PriceFactor->get_all;
 636 }
 637
 638 sub _check_auth {
 639   my ($self) = @_;
 640
 641   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 642
 643   my $right   = $right_for->{ $self->type };
 644   $right    ||= 'DOES_NOT_EXIST';
 645
 646   $::auth->assert($right);
 647 }
 648
 649 sub build_contact_select {
 650   my ($self) = @_;
 651
 652   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 653                        value_key  => 'cp_id',
 654                        title_key  => 'full_name_dep',
 655                        default    => $self->order->cp_id,
 656                        with_empty => 1,
 657                        style      => 'width: 300px',
 658   );
 659 }
 660
 661 sub build_shipto_select {
 662   my ($self) = @_;
 663
 664   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 665                        value_key  => 'shipto_id',
 666                        title_key  => 'displayable_id',
 667                        default    => $self->order->shipto_id,
 668                        with_empty => 1,
 669                        style      => 'width: 300px',
 670   );
 671 }
 672
 673 sub build_tax_rows {
 674   my ($self) = @_;
 675
 676   my $rows_as_html;
 677   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 678     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 679   }
 680   return $rows_as_html;
 681 }
 682
 683
 684 sub render_price_dialog {
 685   my ($self, $record_item) = @_;
 686
 687   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 688
 689   $self->js
 690     ->run(
 691       'kivi.io.price_chooser_dialog',
 692       t8('Available Prices'),
 693       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 694     )
 695     ->reinit_widgets;
 696
 697 #   if (@errors) {
 698 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 699 #     $self->js->show('#dialog_flash_error');
 700 #   }
 701
 702   $self->js->render;
 703 }
 704
 705 sub _load_order {
 706   my ($self) = @_;
 707
 708   return if !$::form->{id};
 709
 710   $self->order(SL::DB::Manager::Order->find_by(id => $::form->{id}));
 711 }
 712
 713 sub _make_order {
 714   my ($self) = @_;
 715
 716   # add_items adds items to an order with no items for saving, but they cannot
 717   # be retrieved via items until the order is saved. Adding empty items to new
 718   # order here solves this problem.
 719   my $order;
 720   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 721   $order ||= SL::DB::Order->new(orderitems => []);
 722
 723   my $form_orderitems = delete $::form->{order}->{orderitems};
 724   $order->assign_attributes(%{$::form->{order}});
 725
 726   # remove deleted items
 727   $self->item_ids_to_delete([]);
 728   foreach my $idx (reverse 0..$#{$order->orderitems}) {
 729     my $item = $order->orderitems->[$idx];
 730     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
 731       splice @{$order->orderitems}, $idx, 1;
 732       push @{$self->item_ids_to_delete}, $item->id;
 733     }
 734   }
 735
 736   my @items;
 737   my $pos = 1;
 738   foreach my $form_attr (@{$form_orderitems}) {
 739     my $item = _make_item($order, $form_attr);
 740     $item->position($pos);
 741     push @items, $item;
 742     $pos++;
 743   }
 744   $order->add_items(grep {!$_->id} @items);
 745
 746   return $order;
 747 }
 748
 749
 750 # Make item objects from form values. For items already existing read from db.
 751 # Create a new item else. And assign attributes.
 752 sub _make_item {
 753   my ($record, $attr) = @_;
 754
 755   my $item;
 756   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
 757
 758   my $is_new = !$item;
 759
 760   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 761   # they cannot be retrieved via custom_variables until the order/orderitem is
 762   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 763   $item ||= SL::DB::OrderItem->new(custom_variables => []);
 764
 765   $item->assign_attributes(%$attr);
 766   $item->longdescription($item->part->notes) if $is_new && !defined $attr->{longdescription};
 767
 768   return $item;
 769 }
 770
 771 sub _new_item {
 772   my ($record, $attr) = @_;
 773
 774   my $item = SL::DB::OrderItem->new;
 775   $item->assign_attributes(%$attr);
 776
 777   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 778   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 779
 780   $item->unit($part->unit) if !$item->unit;
 781
 782   my $price_src;
 783   if ($item->sellprice) {
 784     $price_src = $price_source->price_from_source("");
 785     $price_src->price($item->sellprice);
 786   } else {
 787     $price_src = $price_source->best_price
 788            ? $price_source->best_price
 789            : $price_source->price_from_source("");
 790     $price_src->price(0) if !$price_source->best_price;
 791   }
 792
 793   my $discount_src;
 794   if ($item->discount) {
 795     $discount_src = $price_source->discount_from_source("");
 796     $discount_src->discount($item->discount);
 797   } else {
 798     $discount_src = $price_source->best_discount
 799                   ? $price_source->best_discount
 800                   : $price_source->discount_from_source("");
 801     $discount_src->discount(0) if !$price_source->best_discount;
 802   }
 803
 804   my %new_attr;
 805   $new_attr{part}                   = $part;
 806   $new_attr{description}            = $part->description     if ! $item->description;
 807   $new_attr{qty}                    = 1.0                    if ! $item->qty;
 808   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
 809   $new_attr{sellprice}              = $price_src->price;
 810   $new_attr{discount}               = $discount_src->discount;
 811   $new_attr{active_price_source}    = $price_src;
 812   $new_attr{active_discount_source} = $discount_src;
 813
 814   $new_attr{longdescription}        = $part->notes if ! defined $attr->{longdescription};
 815
 816   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 817   # they cannot be retrieved via custom_variables until the order/orderitem is
 818   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 819   $new_attr{custom_variables} = [];
 820
 821   $item->assign_attributes(%new_attr);
 822
 823   return $item;
 824 }
 825
 826 sub _recalc {
 827   my ($self) = @_;
 828
 829   # bb: todo: currency later
 830   $self->order->currency_id($::instance_conf->get_currency_id());
 831
 832   my %pat = $self->order->calculate_prices_and_taxes();
 833   $self->{taxes} = [];
 834   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 835     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 836
 837     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 838     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 839                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 840                                 tax       => $tax });
 841   }
 842
 843   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 844 }
 845
 846
 847 sub _get_unalterable_data {
 848   my ($self) = @_;
 849
 850   foreach my $item (@{ $self->order->items }) {
 851     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 852     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 853     foreach my $var (@{ $item->cvars_by_config }) {
 854       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 855     }
 856     $item->parse_custom_variable_values;
 857   }
 858 }
 859
 860
 861 sub _delete {
 862   my ($self) = @_;
 863
 864   my $errors = [];
 865   my $db = $self->order->db;
 866
 867   $db->do_transaction(
 868     sub {
 869       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 870       $self->order->delete;
 871       my $spool = $::lx_office_conf{paths}->{spool};
 872       unlink map { "$spool/$_" } @spoolfiles if $spool;
 873
 874       1;
 875   }) || push(@{$errors}, $db->error);
 876
 877   return $errors;
 878 }
 879
 880
 881 sub _save {
 882   my ($self) = @_;
 883
 884   my $errors = [];
 885   my $db = $self->order->db;
 886
 887   $db->do_transaction(
 888     sub {
 889       SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete};
 890       $self->order->save(cascade => 1);
 891   }) || push(@{$errors}, $db->error);
 892
 893   return $errors;
 894 }
 895
 896
 897 sub _pre_render {
 898   my ($self) = @_;
 899
 900   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 901   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 902   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 903                                                                                        deleted => 0 ] ],
 904                                                                     sort_by => 'name');
 905   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 906                                                                                        deleted => 0 ] ],
 907                                                                     sort_by => 'name');
 908   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 909                                                                                       active => 1 ] ],
 910                                                                    sort_by => 'projectnumber');
 911   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 912   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 913
 914   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 915
 916   my $print_form = Form->new('');
 917   $print_form->{type}      = $self->type;
 918   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
 919   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
 920   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
 921     form => $print_form,
 922     options => {dialog_name_prefix => 'print_options.',
 923                 show_headers       => 1,
 924                 no_queue           => 1,
 925                 no_postscript      => 1,
 926                 no_opendocument    => 1,
 927                 no_html            => 1},
 928   );
 929
 930   foreach my $item (@{$self->order->orderitems}) {
 931     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 932     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 933     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 934   }
 935
 936   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 937     my $webdav = SL::Webdav->new(
 938       type     => $self->type,
 939       number   => $self->order->ordnumber,
 940     );
 941     my $webdav_path = $webdav->webdav_path;
 942     my @all_objects = $webdav->get_all_objects;
 943     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 944                                                     type => t8('File'),
 945                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 946                                                 } } @all_objects;
 947   }
 948
 949   $::request->{layout}->use_javascript("${_}.js")  for qw(kivi.SalesPurchase kivi.Order ckeditor/ckeditor ckeditor/adapters/jquery);
 950 }
 951
 952 sub _create_pdf {
 953   my ($order, $pdf_ref, $params) = @_;
 954
 955   my @errors = ();
 956
 957   my $print_form = Form->new('');
 958   $print_form->{type}        = $order->type;
 959   $print_form->{formname}    = $params->{formname} || $order->type;
 960   $print_form->{format}      = $params->{format}   || 'pdf';
 961   $print_form->{media}       = $params->{media}    || 'file';
 962   $print_form->{groupitems}  = $params->{groupitems};
 963   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
 964   $print_form->{language}    = $params->{language}->template_code if $print_form->{language};
 965   $print_form->{language_id} = $params->{language}->id            if $print_form->{language};
 966
 967   $order->flatten_to_form($print_form, format_amounts => 1);
 968   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 969   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 970
 971   # search for the template
 972   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 973     name        => $print_form->{formname},
 974     email       => $print_form->{media} eq 'email',
 975     language    => $params->{language},
 976     printer_id  => $print_form->{printer_id},  # todo
 977   );
 978
 979   if (!defined $template_file) {
 980     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
 981   }
 982
 983   return @errors if scalar @errors;
 984
 985   $print_form->throw_on_error(sub {
 986     eval {
 987       $print_form->prepare_for_printing;
 988
 989       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 990         template  => $template_file,
 991         variables => $print_form,
 992         variable_content_types => {
 993           longdescription => 'html',
 994           partnotes       => 'html',
 995           notes           => 'html',
 996         },
 997       );
 998       1;
 999     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
1000   });
1001
1002   return @errors;
1003 }
1004
1005 sub _sales_order_type {
1006   'sales_order';
1007 }
1008
1009 sub _purchase_order_type {
1010   'purchase_order';
1011 }
1012
1013 1;