SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::DB::Business;
   7 use SL::DB::CustomVariable;
   8 use SL::DB::CustomVariableConfig;
   9 use SL::DB::PaymentTerm;
  10 use SL::TransNumber;
  11
  12 use parent qw(SL::Controller::CsvImport::Base);
  13
  14 use Rose::Object::MakeMethods::Generic
  15 (
  16  'scalar --get_set_init' => [ qw(table languages_by businesses_by currencies_by) ],
  17 );
  18
  19 sub init_table {
  20   my ($self) = @_;
  21   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  22 }
  23
  24 sub init_class {
  25   my ($self) = @_;
  26   $self->class('SL::DB::' . ucfirst($self->table));
  27 }
  28
  29 sub init_all_cvar_configs {
  30   my ($self) = @_;
  31
  32   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  33 }
  34
  35 sub init_businesses_by {
  36   my ($self) = @_;
  37
  38   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  39 }
  40
  41 sub init_languages_by {
  42   my ($self) = @_;
  43
  44   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  45 }
  46
  47 sub init_currencies_by {
  48   my ($self) = @_;
  49
  50   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_currencies } } ) } qw(id name) };
  51 }
  52
  53 sub check_objects {
  54   my ($self) = @_;
  55
  56   $self->controller->track_progress(phase => 'building data', progress => 0);
  57
  58   my $vc            = $self->controller->profile->get('table');
  59   my $update_policy = $self->controller->profile->get('update_policy') || 'update_existing';
  60   my $numbercolumn  = "${vc}number";
  61   my %vcs_by_number = map { ( $_->$numbercolumn => $_ ) } @{ $self->existing_objects };
  62   my $methods       = $self->controller->headers->{methods};
  63
  64   my $i;
  65   my $num_data = scalar @{ $self->controller->data };
  66   foreach my $entry (@{ $self->controller->data }) {
  67     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
  68     my $object = $entry->{object};
  69
  70     $self->check_name($entry);
  71     $self->check_language($entry);
  72     $self->check_business($entry);
  73     $self->check_payment($entry);
  74     $self->check_currency($entry);
  75     $self->handle_cvars($entry);
  76
  77     next if @{ $entry->{errors} };
  78
  79     my @cleaned_fields = $self->clean_fields(qr{[\r\n]}, $object, qw(name department_1 department_2 street zipcode city country contact phone fax homepage email cc bcc
  80                                                                      taxnumber account_number bank_code bank username greeting));
  81
  82     push @{ $entry->{information} }, $::locale->text('Illegal characters have been removed from the following fields: #1', join(', ', @cleaned_fields))
  83       if @cleaned_fields;
  84
  85     my $existing_vc = $vcs_by_number{ $object->$numbercolumn };
  86     if (!$existing_vc) {
  87       $vcs_by_number{ $object->$numbercolumn } = $object if $object->$numbercolumn;
  88
  89     } elsif ($update_policy eq 'skip') {
  90       push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry in database'));
  91
  92     } elsif ($update_policy eq 'update_existing') {
  93       # Update existing customer/vendor records.
  94       $entry->{object_to_save} = $existing_vc;
  95
  96       $existing_vc->$_( $entry->{object}->$_ ) for @{ $methods };
  97
  98       push @{ $entry->{information} }, $::locale->text('Updating existing entry in database');
  99
 100     } else {
 101       $object->$numbercolumn('####');
 102     }
 103   } continue {
 104     $i++;
 105   }
 106
 107   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment));
 108   $self->add_cvar_raw_data_columns;
 109 }
 110
 111 sub get_duplicate_check_fields {
 112   return {
 113     name => {
 114       label     => $::locale->text('Customer Name'),
 115       default   => 1,
 116       maker     => sub {
 117         my $name = shift->name;
 118         $name =~ s/[\s,\.\-]//g;
 119         return $name;
 120       }
 121     },
 122   };
 123 }
 124
 125 sub check_name {
 126   my ($self, $entry) = @_;
 127
 128   my $name =  $entry->{object}->name;
 129   $name    =~ s/^\s+//;
 130   $name    =~ s/\s+$//;
 131
 132   return 1 if $name;
 133
 134   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 135   return 0;
 136 }
 137
 138 sub check_language {
 139   my ($self, $entry) = @_;
 140
 141   my $object = $entry->{object};
 142
 143   # Check whether or not language ID is valid.
 144   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 145     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 146     return 0;
 147   }
 148
 149   # Map name to ID if given.
 150   if (!$object->language_id && $entry->{raw_data}->{language}) {
 151     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 152                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 153
 154     if (!$language) {
 155       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 156       return 0;
 157     }
 158
 159     $object->language_id($language->id);
 160   }
 161
 162   return 1;
 163 }
 164
 165 sub check_currency {
 166   my ($self, $entry) = @_;
 167
 168   my $object = $entry->{object};
 169
 170   # Check whether or not currency ID is valid.
 171   if ($object->currency_id && !$self->currencies_by->{id}->{ $object->currency_id }) {
 172     push @{ $entry->{errors} }, $::locale->text('Error: Invalid currency');
 173     return 0;
 174   }
 175
 176   # Map name to ID if given.
 177   if (!$object->currency_id && $entry->{raw_data}->{currency}) {
 178     my $currency = $self->currencies_by->{name}->{  $entry->{raw_data}->{currency} };
 179     if (!$currency) {
 180       push @{ $entry->{errors} }, $::locale->text('Error: Invalid currency');
 181       return 0;
 182     }
 183
 184     $object->currency_id($currency->id);
 185   }
 186
 187   # Set default currency if none was given.
 188   $object->currency_id($self->default_currency_id) if !$object->currency_id;
 189
 190   $entry->{raw_data}->{currency_id} = $object->currency_id;
 191
 192   return 1;
 193 }
 194
 195 sub check_business {
 196   my ($self, $entry) = @_;
 197
 198   my $object = $entry->{object};
 199
 200   # Check whether or not business ID is valid.
 201   if ($object->business_id && !$self->businesses_by->{id}->{ $object->business_id }) {
 202     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 203     return 0;
 204   }
 205
 206   # Map name to ID if given.
 207   if (!$object->business_id && $entry->{raw_data}->{business}) {
 208     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 209
 210     if (!$business) {
 211       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 212       return 0;
 213     }
 214
 215     $object->business_id($business->id);
 216   }
 217
 218   return 1;
 219 }
 220
 221 sub save_objects {
 222   my ($self, %params) = @_;
 223
 224   my $numbercolumn   = $self->table . 'number';
 225   my $with_number    = [ grep { $_->{object}->$numbercolumn ne '####' } @{ $self->controller->data } ];
 226   my $without_number = [ grep { $_->{object}->$numbercolumn eq '####' } @{ $self->controller->data } ];
 227
 228   foreach my $entry (@{$with_number}, @{$without_number}) {
 229     my $object = $entry->{object};
 230
 231     my $number = SL::TransNumber->new(type        => $self->table(),
 232                                       number      => $object->$numbercolumn(),
 233                                       business_id => $object->business_id(),
 234                                       save        => 1);
 235
 236     if ( $object->$numbercolumn eq '####' || !$number->is_unique() ) {
 237       $object->$numbercolumn($number->create_unique());
 238     }
 239   }
 240
 241   $self->SUPER::save_objects(data => $with_number);
 242   $self->SUPER::save_objects(data => $without_number);
 243 }
 244
 245 sub field_lengths {
 246   return ( name           => 75,
 247            department_1   => 75,
 248            department_2   => 75,
 249            street         => 75,
 250            zipcode        => 10,
 251            city           => 75,
 252            country        => 75,
 253            contact        => 75,
 254            fax            => 30,
 255            account_number => 15,
 256            bank_code      => 10,
 257            language       => 5,
 258            username       => 50,
 259            ustid          => 14,
 260            iban           => 100,
 261            bic            => 100,
 262          );
 263 }
 264
 265 sub init_profile {
 266   my ($self) = @_;
 267
 268   my $profile = $self->SUPER::init_profile;
 269   delete @{$profile}{qw(business datevexport language payment salesman salesman_id taxincluded terms)};
 270
 271   return $profile;
 272 }
 273
 274 sub setup_displayable_columns {
 275   my ($self) = @_;
 276
 277   $self->SUPER::setup_displayable_columns;
 278   $self->add_cvar_columns_to_displayable_columns;
 279
 280   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 281                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 282                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 283                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 284                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 285                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 286                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 287                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 288                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 289                                  { name => 'city',              description => $::locale->text('City')                            },
 290                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 291                                  { name => 'country',           description => $::locale->text('Country')                         },
 292                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 293                                  { name => 'currency',          description => $::locale->text('Currency')                        },
 294                                  { name => 'currency_id',       description => $::locale->text('Currency (database ID)')          },
 295                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 296                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 297                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 298                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 299                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 300                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 301                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 302                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 303                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 304                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 305                                  { name => 'klass',             description => $::locale->text('Preisklasse')                     },
 306                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 307                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 308                                  { name => 'name',              description => $::locale->text('Name')                            },
 309                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 310                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 311                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 312                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 313                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 314                                  { name => 'street',            description => $::locale->text('Street')                          },
 315                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 316                                  { name => 'taxzone_id',        description => $::locale->text('Steuersatz')                      },
 317                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 318                                  { name => 'username',          description => $::locale->text('Username')                        },
 319                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 320                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 321                                 );
 322 }
 323
 324 # TODO:
 325 # salesman_id -- Kunden mit Typ 'Verkäufer', falls Vertreter-Modus an ist, ansonsten Employees
 326
 327 1;