SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 # Force scripts/locales.pl to parse these templates:
   6 #   parse_html_template('login_screen/auth_db_unreachable')
   7 #   parse_html_template('login_screen/user_login')
   8 #   parse_html_template('generic/error')
   9
  10 BEGIN {
  11   use SL::System::Process;
  12   my $exe_dir = SL::System::Process::exe_dir;
  13
  14   unshift @INC, "${exe_dir}/modules/override"; # Use our own versions of various modules (e.g. YAML).
  15   push    @INC, "${exe_dir}/modules/fallback"; # Only use our own versions of modules if there's no system version.
  16   unshift @INC, $exe_dir;
  17 }
  18
  19 use Carp;
  20 use CGI qw( -no_xhtml);
  21 use Config::Std;
  22 use DateTime;
  23 use Encode;
  24 use English qw(-no_match_vars);
  25 use File::Basename;
  26 use List::MoreUtils qw(all);
  27 use List::Util qw(first);
  28 use POSIX;
  29 use SL::ArchiveZipFixes;
  30 use SL::Auth;
  31 use SL::Dispatcher::AuthHandler;
  32 use SL::LXDebug;
  33 use SL::LxOfficeConf;
  34 use SL::Locale;
  35 use SL::ClientJS;
  36 use SL::Common;
  37 use SL::Form;
  38 use SL::Helper::DateTime;
  39 use SL::InstanceConfiguration;
  40 use SL::Template::Plugin::HTMLFixes;
  41
  42 # Trailing new line is added so that Perl will not add the line
  43 # number 'die' was called in.
  44 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  45
  46 my %fcgi_file_cache;
  47
  48 sub new {
  49   my ($class, $interface) = @_;
  50
  51   my $self           = bless {}, $class;
  52   $self->{interface} = lc($interface || 'cgi');
  53   $self->{auth_handler} = SL::Dispatcher::AuthHandler->new;
  54
  55   SL::ArchiveZipFixes->apply_fixes;
  56
  57   return $self;
  58 }
  59
  60 sub interface_type {
  61   my ($self) = @_;
  62   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  63 }
  64
  65 sub is_admin_request {
  66   my %params = @_;
  67   return ($params{script} eq 'admin.pl') || (($params{routing_type} eq 'controller') && ($params{script_name} eq 'Admin'));
  68 }
  69
  70 sub pre_request_checks {
  71   my (%params) = @_;
  72
  73   _check_for_old_config_files();
  74
  75   if (!$::auth->session_tables_present && !is_admin_request(%params)) {
  76     show_error('login_screen/auth_db_unreachable');
  77   }
  78
  79   if ($::request->type !~ m/^ (?: html | js | json ) $/x) {
  80     die $::locale->text("Invalid request type '#1'", $::request->type);
  81   }
  82 }
  83
  84 sub pre_request_initialization {
  85   my ($self, %params) = @_;
  86
  87   $self->unrequire_bin_mozilla;
  88
  89   $::locale        = Locale->new($::lx_office_conf{system}->{language});
  90   $::form          = Form->new;
  91   $::instance_conf = SL::InstanceConfiguration->new;
  92   $::request       = SL::Request->new(
  93     cgi            => CGI->new({}),
  94     layout         => SL::Layout::None->new,
  95   );
  96
  97   my $session_result = $::auth->restore_session;
  98   $::auth->create_or_refresh_session;
  99
 100   if ($params{client}) {
 101     $::auth->set_client($params{client}) || die("cannot find client " . $params{client});
 102
 103     if ($params{login}) {
 104       die "cannot find user " . $params{login}            unless %::myconfig = $::auth->read_user(login => $params{login});
 105       die "cannot find locale for user " . $params{login} unless $::locale   = Locale->new($::myconfig{countrycode});
 106
 107       $::form->{login} = $params{login}; # normaly implicit at login
 108
 109       $::instance_conf->init;
 110     }
 111   }
 112
 113   return $session_result;
 114 }
 115
 116 sub render_error_ajax {
 117   my ($error) = @_;
 118
 119   SL::ClientJS->new
 120     ->error($error)
 121     ->render(SL::Controller::Base->new);
 122 }
 123
 124 sub show_error {
 125   $::lxdebug->enter_sub;
 126   my $template             = shift;
 127   my $error_type           = shift || '';
 128   my %params               = @_;
 129
 130   $::myconfig{countrycode} = delete($params{countrycode}) || $::lx_office_conf{system}->{language};
 131   $::locale                = Locale->new($::myconfig{countrycode});
 132   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
 133   $::form->{error}         = $::locale->text('Incorrect password!')                    if ($error_type eq 'password');
 134   $::form->{error}         = $::locale->text('The action is missing or invalid.')      if ($error_type eq 'action');
 135
 136   return render_error_ajax($::form->{error}) if $::request->is_ajax;
 137
 138   $::form->header;
 139   print $::form->parse_html_template($template, \%params);
 140   $::lxdebug->leave_sub;
 141
 142   ::end_of_request();
 143 }
 144
 145 sub pre_startup_setup {
 146   my ($self) = @_;
 147
 148   SL::LxOfficeConf->read;
 149
 150   eval {
 151     package main;
 152     require "bin/mozilla/common.pl";
 153     require "bin/mozilla/installationcheck.pl";
 154   } or die $EVAL_ERROR;
 155
 156   # canonial globals. if it's not here, chances are it will get refactored someday.
 157   {
 158     no warnings 'once';
 159     $::lxdebug     = LXDebug->new;
 160     $::auth        = SL::Auth->new;
 161     $::form        = undef;
 162     %::myconfig    = ();
 163     $::request     = undef;
 164   }
 165
 166   $SIG{__WARN__} = sub {
 167     $::lxdebug->warn(@_);
 168   };
 169
 170   $SIG{__DIE__} = sub { Carp::confess( @_ ) } if $::lx_office_conf{debug}->{backtrace_on_die};
 171
 172   $self->_cache_file_modification_times;
 173 }
 174
 175 sub pre_startup_checks {
 176   ::verify_installation();
 177 }
 178
 179 sub pre_startup {
 180   my ($self) = @_;
 181   $self->pre_startup_setup;
 182   $self->pre_startup_checks;
 183 }
 184
 185 sub require_main_code {
 186   $::lxdebug->enter_sub;
 187   my ($script, $suffix) = @_;
 188
 189   eval {
 190     package main;
 191     require "bin/mozilla/$script$suffix";
 192   } or die $EVAL_ERROR;
 193
 194   if (-f "bin/mozilla/custom_$script$suffix") {
 195     eval {
 196       package main;
 197       require "bin/mozilla/custom_$script$suffix";
 198     };
 199     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 200   }
 201   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 202     eval {
 203       package main;
 204       require "bin/mozilla/$::form->{login}_$script";
 205     };
 206     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 207   }
 208   $::lxdebug->leave_sub;
 209 }
 210
 211 sub _require_controller {
 212   my $controller =  shift;
 213   $controller    =~ s|[^A-Za-z0-9_]||g;
 214   $controller    =  "SL/Controller/${controller}";
 215
 216   eval {
 217     package main;
 218     require "${controller}.pm";
 219   } or die $EVAL_ERROR;
 220 }
 221
 222 sub _run_controller {
 223   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 224 }
 225
 226 sub handle_request {
 227   my $self         = shift;
 228   $self->{request} = shift;
 229
 230   $::lxdebug->enter_sub;
 231   $::lxdebug->begin_request;
 232
 233   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 234
 235   my $session_result = $self->pre_request_initialization;
 236
 237   $::form->read_cgi_input;
 238
 239   my %routing;
 240   eval { %routing = $self->_route_request($ENV{SCRIPT_NAME}); 1; } or return;
 241   ($routing_type, $script_name, $action) = @routing{qw(type controller action)};
 242   $::lxdebug->log_request($routing_type, $script_name, $action);
 243
 244   $::request->type(lc($routing{request_type} || 'html'));
 245
 246   if ($routing_type eq 'old') {
 247     $::form->{action}  =  lc $::form->{action};
 248     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 249
 250    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 251     require_main_code($script, $suffix) unless $script eq 'admin';
 252
 253     $::form->{script} = $script . $suffix;
 254
 255   } else {
 256     _require_controller($script_name);
 257     $::form->{script} = "controller.pl";
 258   }
 259
 260   eval {
 261     pre_request_checks(script => $script, action => $action, routing_type => $routing_type, script_name => $script_name);
 262
 263     if (   SL::System::InstallationLock->is_locked
 264         && !is_admin_request(script => $script, script_name => $script_name, routing_type => $routing_type)) {
 265       $::form->error($::locale->text('System currently down for maintenance!'));
 266     }
 267
 268     # For compatibility with a lot of database upgrade scripts etc:
 269     # Re-write request to old 'login.pl?action=login' to new
 270     # 'LoginScreen' controller. Make sure to load its code!
 271     if (($script eq 'login') && ($action eq 'login')) {
 272       ($routing_type, $script, $script_name, $action) = qw(controller controller LoginScreen login);
 273       _require_controller('LoginScreen');
 274     }
 275
 276     if (   (($script eq 'login') && !$action)
 277         || ($script eq 'admin')
 278         || (SL::Auth::SESSION_EXPIRED() == $session_result)) {
 279       $self->redirect_to_login(script => $script, error => 'session');
 280
 281     }
 282
 283     my %auth_result = $self->{auth_handler}->handle(
 284       routing_type => $routing_type,
 285       script       => $script,
 286       controller   => $script_name,
 287       action       => $action,
 288     );
 289
 290     ::end_of_request() unless $auth_result{auth_ok};
 291
 292     delete @{ $::form }{ grep { m/^\{AUTH\}/ } keys %{ $::form } } unless $auth_result{keep_auth_vars};
 293
 294     if ($action) {
 295       $::form->set_standard_title;
 296       if ($routing_type eq 'old') {
 297         ::call_sub('::' . $::locale->findsub($action));
 298       } else {
 299         _run_controller($script_name, $action);
 300       }
 301     } else {
 302       $::form->error($::locale->text('action= not defined!'));
 303     }
 304
 305     1;
 306   } or do {
 307     if (substr($EVAL_ERROR, 0, length(END_OF_REQUEST())) ne END_OF_REQUEST()) {
 308       my $error = $EVAL_ERROR;
 309       print STDERR $error;
 310
 311       if ($::request->is_ajax) {
 312         eval { render_error_ajax($error) };
 313       } else {
 314         $::form->{label_error} = $::request->{cgi}->pre($error);
 315         chdir SL::System::Process::exe_dir;
 316         eval { show_error('generic/error') };
 317       }
 318     }
 319   };
 320
 321   $::form->footer;
 322
 323   # cleanup
 324   $::auth->save_session;
 325   $::auth->expire_sessions;
 326   $::auth->reset;
 327
 328   $::locale   = undef;
 329   $::form     = undef;
 330   $::myconfig = ();
 331   $::request  = undef;
 332   Form::disconnect_standard_dbh;
 333
 334   $::lxdebug->end_request;
 335
 336   $self->_watch_for_changed_files;
 337
 338   $::lxdebug->leave_sub;
 339 }
 340
 341 sub redirect_to_login {
 342   my ($self, %params) = @_;
 343   my $action          = ($params{script} // '') =~ m/^admin/i ? 'Admin/login' : 'LoginScreen/user_login';
 344   $action            .= '&error=' . $params{error} if $params{error};
 345
 346   print $::request->cgi->redirect("controller.pl?action=${action}");
 347   ::end_of_request();
 348 }
 349
 350 sub unrequire_bin_mozilla {
 351   my $self = shift;
 352   return unless $self->_interface_is_fcgi;
 353
 354   for (keys %INC) {
 355     next unless m#^bin/mozilla/#;
 356     next if /\bcommon.pl$/;
 357     next if /\binstallationcheck.pl$/;
 358     delete $INC{$_};
 359   }
 360 }
 361
 362 sub _interface_is_fcgi {
 363   my $self = shift;
 364   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 365 }
 366
 367 sub _route_request {
 368   my ($self, $script_name) = @_;
 369
 370   return $script_name =~ m/dispatcher\.pl$/ ? (type => 'old',        $self->_route_dispatcher_request)
 371        : $script_name =~ m/controller\.pl/  ? (type => 'controller', $self->_route_controller_request)
 372        :                                      (type => 'old',        controller => $script_name, action => $::form->{action});
 373 }
 374
 375 sub _route_dispatcher_request {
 376   my ($self)  = @_;
 377   my $name_re = qr{[a-z]\w*};
 378   my ($script_name, $action);
 379
 380   eval {
 381     die "Unroutable request -- invalid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 382     $script_name = $::form->{M} . '.pl';
 383
 384     if ($::form->{A}) {
 385       $action = $::form->{A};
 386
 387     } else {
 388       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 389       die "Unroutable request -- invalid action name.\n" if !$action;
 390
 391       delete $::form->{$action};
 392       $action = substr $action, 2;
 393     }
 394
 395     delete @{$::form}{qw(M A)};
 396
 397     1;
 398   } or do {
 399     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 400     show_error('generic/error');
 401   };
 402
 403   return (controller => $script_name, action => $action);
 404 }
 405
 406 sub _route_controller_request {
 407   my ($self) = @_;
 408   my ($controller, $action, $request_type);
 409
 410   eval {
 411     # Redirect simple requests to controller.pl without any GET/POST
 412     # param to the login page.
 413     $self->redirect_to_login(error => 'action') if !$::form->{action};
 414
 415     # Show an error if the »action« parameter doesn't match the
 416     # pattern »Controller/action«.
 417     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) ( \. [a-zA-Z]+ )? $|x || die "Unroutable request -- invalid controller/action.\n";
 418     ($controller, $action) =  ($1, $2);
 419     delete $::form->{action};
 420
 421     $request_type = $3 ? lc(substr($3, 1)) : 'html';
 422
 423     1;
 424   } or do {
 425     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 426     show_error('generic/error');
 427   };
 428
 429   return (controller => $controller, action => $action, request_type => $request_type);
 430 }
 431
 432 sub _cache_file_modification_times {
 433   my ($self) = @_;
 434
 435   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 436
 437   require File::Find;
 438   require POSIX;
 439
 440   my $wanted = sub {
 441     return unless $File::Find::name =~ m/\.(?:pm|f?pl|html|conf|conf\.default)$/;
 442     $fcgi_file_cache{ $File::Find::name } = (stat $File::Find::name)[9];
 443   };
 444
 445   my $cwd = POSIX::getcwd();
 446   File::Find::find($wanted, map { "${cwd}/${_}" } qw(config bin SL templates/webpages));
 447   map { my $name = "${cwd}/${_}"; $fcgi_file_cache{$name} = (stat $name)[9] } qw(admin.pl dispatcher.fpl);
 448 }
 449
 450 sub _watch_for_changed_files {
 451   my ($self) = @_;
 452
 453   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 454
 455   my $ok = all { (stat($_))[9] == $fcgi_file_cache{$_} } keys %fcgi_file_cache;
 456   return if $ok;
 457   $::lxdebug->message(LXDebug::DEBUG1(), "Program modifications detected. Restarting.");
 458   exit;
 459 }
 460
 461 sub get_standard_filehandles {
 462   my $self = shift;
 463
 464   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 465 }
 466
 467 sub _check_for_old_config_files {
 468   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 469   return unless @old_files;
 470
 471   $::form->{title} = $::locale->text('Old configuration files');
 472   $::form->header;
 473   print $::form->parse_html_template('login_screen/old_configuration_files', { FILES => \@old_files });
 474
 475   ::end_of_request();
 476 }
 477
 478 package main;
 479
 480 use strict;
 481
 482 sub end_of_request {
 483   die SL::Dispatcher->END_OF_REQUEST;
 484 }
 485
 486 1;