scripts/task_server.pl

   1 #!/usr/bin/perl
   2
   3
   4 use List::MoreUtils qw(any);
   5
   6 use strict;
   7
   8 my $exe_dir;
   9
  10 BEGIN {
  11   use FindBin;
  12   use lib "$FindBin::Bin/..";
  13
  14   use SL::System::Process;
  15   $exe_dir = SL::System::Process::exe_dir;
  16
  17   unshift @INC, "${exe_dir}/modules/override"; # Use our own versions of various modules (e.g. YAML).
  18   push    @INC, "${exe_dir}/modules/fallback"; # Only use our own versions of modules if there's no system version.
  19   unshift @INC, $exe_dir;
  20
  21   chdir($exe_dir) || die "Cannot change directory to ${exe_dir}\n";
  22 }
  23
  24 use CGI qw( -no_xhtml);
  25 use Cwd;
  26 use Daemon::Generic;
  27 use Data::Dumper;
  28 use DateTime;
  29 use Encode qw();
  30 use English qw(-no_match_vars);
  31 use File::Spec;
  32 use List::Util qw(first);
  33 use POSIX qw(setuid setgid);
  34 use SL::Auth;
  35 use SL::DB::BackgroundJob;
  36 use SL::BackgroundJob::ALL;
  37 use SL::Form;
  38 use SL::Helper::DateTime;
  39 use SL::InstanceConfiguration;
  40 use SL::LXDebug;
  41 use SL::LxOfficeConf;
  42 use SL::Locale;
  43 use SL::Mailer;
  44 use SL::System::TaskServer;
  45 use Template;
  46
  47 our %lx_office_conf;
  48
  49 sub debug {
  50   return if !$lx_office_conf{task_server}->{debug};
  51   $::lxdebug->message(0, @_);
  52 }
  53
  54 sub lxinit {
  55   my $login  = $lx_office_conf{task_server}->{login};
  56   my $client = $lx_office_conf{task_server}->{client};
  57
  58   package main;
  59
  60   $::lxdebug       = LXDebug->new;
  61   $::locale        = Locale->new($::lx_office_conf{system}->{language});
  62   $::form          = Form->new;
  63   $::auth          = SL::Auth->new;
  64   die "No client configured or no client found with the name/ID '$client'" unless $::auth->set_client($client);
  65   $::instance_conf = SL::InstanceConfiguration->new;
  66   $::request       = { cgi => CGI->new({}) };
  67
  68   die 'cannot reach auth db'               unless $::auth->session_tables_present;
  69
  70   $::auth->restore_session;
  71
  72   require "bin/mozilla/common.pl";
  73
  74   die "cannot find user $login"            unless %::myconfig = $::auth->read_user(login => $login);
  75   die "cannot find locale for user $login" unless $::locale   = Locale->new('de');
  76 }
  77
  78 sub drop_privileges {
  79   my $user = $lx_office_conf{task_server}->{run_as};
  80   return unless $user;
  81
  82   my ($uid, $gid);
  83   while (my @details = getpwent()) {
  84     next unless $details[0] eq $user;
  85     ($uid, $gid) = @details[2, 3];
  86     last;
  87   }
  88   endpwent();
  89
  90   if (!$uid) {
  91     print "Error: Cannot drop privileges to ${user}: user does not exist\n";
  92     exit 1;
  93   }
  94
  95   if (!setgid($gid)) {
  96     print "Error: Cannot drop group privileges to ${user} (group ID $gid): $!\n";
  97     exit 1;
  98   }
  99
 100   if (!setuid($uid)) {
 101     print "Error: Cannot drop user privileges to ${user} (user ID $uid): $!\n";
 102     exit 1;
 103   }
 104 }
 105
 106 sub notify_on_failure {
 107   my (%params) = @_;
 108
 109   my $cfg = $lx_office_conf{'task_server/notify_on_failure'} || {};
 110
 111   return if any { !$cfg->{$_} } qw(send_email_to email_from email_subject email_template);
 112
 113   chdir $exe_dir;
 114
 115   return debug("Template " . $cfg->{email_template} . " missing!") unless -f $cfg->{email_template};
 116
 117   my $email_to = $cfg->{send_email_to};
 118   if ($email_to !~ m{\@}) {
 119     my %user = $::auth->read_user(login => $email_to);
 120     return debug("cannot find user for notification $email_to") unless %user;
 121
 122     $email_to = $user{email};
 123     return debug("user for notification " . $user{login} . " doesn't have a valid email address") unless $email_to =~ m{\@};
 124   }
 125
 126   my $template  = Template->new({
 127     INTERPOLATE => 0,
 128     EVAL_PERL   => 0,
 129     ABSOLUTE    => 1,
 130     CACHE_SIZE  => 0,
 131   });
 132
 133   return debug("Could not create Template instance") unless $template;
 134
 135   $params{client} = $::auth->client;
 136
 137   my $body;
 138   $template->process($cfg->{email_template}, \%params, \$body);
 139
 140   Mailer->new(
 141     from         => $cfg->{email_from},
 142     to           => $email_to,
 143     subject      => $cfg->{email_subject},
 144     content_type => 'text/plain',
 145     charset      => 'utf-8',
 146     message      => Encode::decode('utf-8', $body),
 147   )->send;
 148 }
 149
 150 sub gd_preconfig {
 151   my $self = shift;
 152
 153   SL::LxOfficeConf->read($self->{configfile});
 154
 155   die "Missing section [task_server] in config file"                 unless $lx_office_conf{task_server};
 156   die "Missing key 'login' in section [task_server] in config file"  unless $lx_office_conf{task_server}->{login};
 157   die "Missing key 'client' in section [task_server] in config file" unless $lx_office_conf{task_server}->{client};
 158
 159   drop_privileges();
 160   lxinit();
 161
 162   return ();
 163 }
 164
 165 sub gd_run {
 166   while (1) {
 167     my $ok = eval {
 168       debug("Retrieving jobs");
 169
 170       my $jobs = SL::DB::Manager::BackgroundJob->get_all_need_to_run;
 171
 172       debug("  Found: " . join(' ', map { $_->package_name } @{ $jobs })) if @{ $jobs };
 173
 174       foreach my $job (@{ $jobs }) {
 175         # Provide fresh global variables in case legacy code modifies
 176         # them somehow.
 177         $::locale = Locale->new($::lx_office_conf{system}->{language});
 178         $::form   = Form->new;
 179
 180         chdir $exe_dir;
 181
 182         my $history = $job->run;
 183
 184         notify_on_failure(history => $history) if $history && $history->has_failed;
 185       }
 186
 187       1;
 188     };
 189
 190     if (!$ok) {
 191       my $error = $EVAL_ERROR;
 192       debug("Exception during execution: ${error}");
 193       notify_on_failure(exception => $error);
 194     }
 195
 196     debug("Sleeping");
 197
 198     my $seconds = 60 - (localtime)[0];
 199     if (!eval {
 200       local $SIG{'ALRM'} = sub {
 201         debug("Got woken up by SIGALRM");
 202         die "Alarm!\n"
 203       };
 204       sleep($seconds < 30 ? $seconds + 60 : $seconds);
 205       1;
 206     }) {
 207       die $@ unless $@ eq "Alarm!\n";
 208     }
 209   }
 210 }
 211
 212 chdir $exe_dir;
 213
 214 mkdir SL::System::TaskServer::PID_BASE() if !-d SL::System::TaskServer::PID_BASE();
 215
 216 my $file = first { -f } ("${exe_dir}/config/kivitendo.conf", "${exe_dir}/config/lx_office.conf", "${exe_dir}/config/kivitendo.conf.default");
 217
 218 die "No configuration file found." unless $file;
 219
 220 $file = File::Spec->abs2rel(Cwd::abs_path($file), Cwd::abs_path($exe_dir));
 221
 222 newdaemon(configfile => $file,
 223           progname   => 'kivitendo-background-jobs',
 224           pidbase    => SL::System::TaskServer::PID_BASE() . '/',
 225           );
 226
 227 1;