SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::Helper::Flash;
   8 use SL::SessionFile;
   9 use SL::Controller::CsvImport::Contact;
  10 use SL::Controller::CsvImport::CustomerVendor;
  11 use SL::Controller::CsvImport::Part;
  12 use SL::Controller::CsvImport::Shipto;
  13
  14 use List::MoreUtils qw(none);
  15
  16 use parent qw(SL::Controller::Base);
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20  scalar => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen
  21                 import_status errors headers raw_data_headers info_headers data num_imported num_importable displayable_columns) ],
  22 );
  23
  24 __PACKAGE__->run_before('check_auth');
  25 __PACKAGE__->run_before('ensure_form_structure');
  26 __PACKAGE__->run_before('check_type');
  27 __PACKAGE__->run_before('load_all_profiles');
  28
  29 #
  30 # actions
  31 #
  32
  33 sub action_new {
  34   my ($self) = @_;
  35
  36   $self->load_default_profile unless $self->profile;
  37   $self->render_inputs;
  38 }
  39
  40 sub action_test {
  41   my ($self) = @_;
  42   $self->test_and_import(test => 1);
  43 }
  44
  45 sub action_import {
  46   my $self = shift;
  47   $self->test_and_import(test => 0);
  48 }
  49
  50 sub action_save {
  51   my ($self) = @_;
  52
  53   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}));
  54   $self->profile->save;
  55
  56   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  57   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  58 }
  59
  60 sub action_destroy {
  61   my $self = shift;
  62
  63   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id});
  64   $profile->delete(cascade => 1);
  65
  66   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  67   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  68 }
  69
  70 #
  71 # filters
  72 #
  73
  74 sub check_auth {
  75   $::auth->assert('config');
  76 }
  77
  78 sub check_type {
  79   my ($self) = @_;
  80
  81   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts);
  82   $self->type($::form->{profile}->{type});
  83 }
  84
  85 sub ensure_form_structure {
  86   my ($self, %params) = @_;
  87
  88   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
  89   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
  90 }
  91
  92 #
  93 # helpers
  94 #
  95
  96 sub render_inputs {
  97   my ($self, %params) = @_;
  98
  99   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 100                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 101                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 102                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 103                         [ 'CP1252',      'CP1252 (Windows)'      ],
 104                       ]);
 105
 106   my %char_map = $self->char_map;
 107
 108   foreach my $type (qw(sep quote escape)) {
 109     my $sub = "all_${type}_chars";
 110     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 111
 112     my $char = $self->profile->get($type . '_char');
 113     $sub     = "${type}_char";
 114     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 115   }
 116
 117   $self->file(SL::SessionFile->new($self->csv_file_name));
 118
 119   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 120             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 121             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 122             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 123             : die;
 124
 125   $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 126
 127   $self->setup_help;
 128
 129   $self->render('csv_import/form', title => $title);
 130 }
 131
 132 sub test_and_import {
 133   my ($self, %params) = @_;
 134
 135   $self->profile_from_form;
 136
 137   if ($::form->{file}) {
 138     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 139     $file->fh->print($::form->{file});
 140     $file->fh->close;
 141   }
 142
 143   my $file = SL::SessionFile->new($self->csv_file_name, mode => '<', encoding => $self->profile->get('charset'));
 144   if (!$file->fh) {
 145     flash('error', $::locale->text('No file has been uploaded yet.'));
 146     return $self->action_new;
 147   }
 148
 149   my $worker = $self->create_worker($file);
 150   $worker->run;
 151   $worker->save_objects if !$params{test};
 152
 153   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 154   $self->import_status($params{test} ? 'tested' : 'imported');
 155
 156   flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 157
 158   $self->action_new;
 159 }
 160
 161 sub load_default_profile {
 162   my ($self) = @_;
 163
 164   if ($::form->{profile}->{id}) {
 165     $self->profile(SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id})->load);
 166
 167   } else {
 168     $self->profile(SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1));
 169     $self->profile(SL::DB::CsvImportProfile->new(type => $self->{type})) unless $self->profile;
 170   }
 171
 172   $self->profile->set_defaults;
 173 }
 174
 175 sub load_all_profiles {
 176   my ($self, %params) = @_;
 177
 178   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(where => [ type => $self->type ], sort_by => 'name'));
 179 }
 180
 181 sub profile_from_form {
 182   my ($self, $existing_profile) = @_;
 183
 184   delete $::form->{profile}->{id};
 185
 186   my %char_map = $self->char_map;
 187   my @settings;
 188
 189   foreach my $type (qw(sep quote escape)) {
 190     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 191     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 192
 193     push @settings, { key => "${type}_char", value => $char };
 194   }
 195
 196   if ($self->type eq 'parts') {
 197     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 198   }
 199
 200   delete $::form->{profile}->{id};
 201   $self->profile($existing_profile || SL::DB::CsvImportProfile->new);
 202   $self->profile->assign_attributes(%{ $::form->{profile} });
 203   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 204                            @settings);
 205   $self->profile->set_defaults;
 206 }
 207
 208 sub char_map {
 209   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 210                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 211                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 212                        ' '  => [ 'space',     $::locale->text('Space')     ],
 213                      },
 214            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 215                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 216                      },
 217            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 218                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 219                      },
 220          );
 221 }
 222
 223 sub csv_file_name {
 224   my ($self) = @_;
 225   return "csv-import-" . $self->type . ".csv";
 226 }
 227
 228 sub create_worker {
 229   my ($self, $file) = @_;
 230
 231   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(controller => $self, file => $file)
 232        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(       controller => $self, file => $file)
 233        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(        controller => $self, file => $file)
 234        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(          controller => $self, file => $file)
 235        :                                        die "Program logic error";
 236 }
 237
 238 sub setup_help {
 239   my ($self) = @_;
 240
 241   $self->create_worker->setup_displayable_columns;
 242 }
 243
 244
 245 1;