SL/Dev/Record.pm

   1 package SL::Dev::Record;
   2
   3 use strict;
   4 use base qw(Exporter);
   5 our @EXPORT = qw(create_invoice_item create_sales_invoice create_order_item  create_sales_order create_purchase_order create_delivery_order_item create_sales_delivery_order);
   6
   7 use SL::DB::Invoice;
   8 use SL::DB::InvoiceItem;
   9 use SL::DB::Employee;
  10 use SL::Dev::Part;
  11 use SL::Dev::CustomerVendor;
  12 use DateTime;
  13
  14 my %record_type_to_item_type = ( sales_invoice        => 'SL::DB::InvoiceItem',
  15                                  sales_order          => 'SL::DB::OrderItem',
  16                                  purchase_order       => 'SL::DB::OrderItem',
  17                                  sales_delivery_order => 'SL::DB::DeliveryOrderItem',
  18                                );
  19
  20 sub create_sales_invoice {
  21   my (%params) = @_;
  22
  23   my $record_type = 'sales_invoice';
  24   my $invoiceitems = delete $params{invoiceitems} // _create_two_items($record_type);
  25   _check_items($invoiceitems, $record_type);
  26
  27   my $customer = delete $params{customer} // SL::Dev::CustomerVendor::create_customer(name => 'Testcustomer')->save;
  28   die "illegal customer" unless defined $customer && ref($customer) eq 'SL::DB::Customer';
  29
  30   my $invoice = SL::DB::Invoice->new(
  31     invoice      => 1,
  32     type         => 'sales_invoice',
  33     customer_id  => $customer->id,
  34     taxzone_id   => $customer->taxzone->id,
  35     invnumber    => delete $params{invnumber}   // undef,
  36     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
  37     taxincluded  => $params{taxincluded} // 0,
  38     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  39     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  40     transdate    => $params{transdate}   // DateTime->today_local->to_kivitendo,
  41     payment_id   => $params{payment_id}  // undef,
  42     gldate       => DateTime->today_local->to_kivitendo,
  43     invoiceitems => $invoiceitems,
  44     %params,
  45   );
  46
  47   $invoice->post;
  48   return $invoice;
  49 }
  50
  51 sub create_sales_delivery_order {
  52   my (%params) = @_;
  53
  54   my $record_type = 'sales_delivery_order';
  55   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
  56   _check_items($orderitems, $record_type);
  57
  58   my $customer = $params{customer} // SL::Dev::CustomerVendor::create_customer(name => 'Testcustomer')->save;
  59   die "illegal customer" unless ref($customer) eq 'SL::DB::Customer';
  60
  61   my $delivery_order = SL::DB::DeliveryOrder->new(
  62     'is_sales'   => 'true',
  63     'closed'     => undef,
  64     customer_id  => $customer->id,
  65     taxzone_id   => $customer->taxzone_id,
  66     donumber     => $params{donumber}    // undef,
  67     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
  68     taxincluded  => $params{taxincluded} // 0,
  69     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  70     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  71     transdate    => $params{transdate}   // DateTime->today_local->to_kivitendo,
  72     orderitems   => $orderitems,
  73     %params
  74   );
  75   $delivery_order->save;
  76   return $delivery_order;
  77 }
  78
  79 sub create_sales_order {
  80   my (%params) = @_;
  81
  82   my $record_type = 'sales_order';
  83   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
  84   _check_items($orderitems, $record_type);
  85
  86   my $save = delete $params{save} // 0;
  87
  88   my $customer = $params{customer} // SL::Dev::CustomerVendor::create_customer(name => 'Testcustomer')->save;
  89   die "illegal customer" unless ref($customer) eq 'SL::DB::Customer';
  90
  91   my $order = SL::DB::Order->new(
  92     customer_id  => delete $params{customer_id} // $customer->id,
  93     taxzone_id   => delete $params{taxzone_id}  // $customer->taxzone->id,
  94     currency_id  => delete $params{currency_id} // $::instance_conf->get_currency_id,
  95     taxincluded  => delete $params{taxincluded} // 0,
  96     # employee_id  => delete $params{employee_id} // SL::DB::Manager::Employee->current->id,
  97     # salesman_id  => delete $params{employee_id} // SL::DB::Manager::Employee->current->id,
  98     transdate    => delete $params{transdate}   // DateTime->today_local->to_kivitendo,
  99     orderitems   => $orderitems,
 100     %params
 101   );
 102
 103   if ( $save ) {
 104     $order->calculate_prices_and_taxes;
 105     $order->save;
 106   }
 107   return $order;
 108 }
 109
 110 sub create_purchase_order {
 111   my (%params) = @_;
 112
 113   my $record_type = 'purchase_order';
 114   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
 115   _check_items($orderitems, $record_type);
 116
 117   my $save = delete $params{save} // 0;
 118
 119   my $vendor = $params{vendor} // SL::Dev::CustomerVendor::create_vendor(name => 'Testvendor')->save;
 120   die "illegal vendor" unless ref($vendor) eq 'SL::DB::Vendor';
 121
 122   my $order = SL::DB::Order->new(
 123     vendor_id    => delete $params{vendor_id}   // $vendor->id,
 124     taxzone_id   => delete $params{taxzone_id}  // $vendor->taxzone->id,
 125     currency_id  => delete $params{currency_id} // $::instance_conf->get_currency_id,
 126     taxincluded  => delete $params{taxincluded} // 0,
 127     transdate    => delete $params{transdate}   // DateTime->today_local->to_kivitendo,
 128     'closed'     => undef,
 129     orderitems   => $orderitems,
 130     %params
 131   );
 132
 133   if ( $save ) {
 134     $order->calculate_prices_and_taxes; # not tested for purchase orders
 135     $order->save;
 136   }
 137   return $order;
 138 };
 139
 140 sub _check_items {
 141   my ($items, $record_type) = @_;
 142
 143   if  ( scalar @{$items} == 0 or grep { ref($_) ne $record_type_to_item_type{"$record_type"} } @{$items} ) {
 144     die "Error: items must be an arrayref of " . $record_type_to_item_type{"$record_type"} . "objects.";
 145   }
 146 }
 147
 148 sub create_invoice_item {
 149   my (%params) = @_;
 150
 151   return _create_item(record_type => 'sales_invoice', %params);
 152 }
 153
 154 sub create_order_item {
 155   my (%params) = @_;
 156
 157   return _create_item(record_type => 'sales_order', %params);
 158 }
 159
 160 sub create_delivery_order_item {
 161   my (%params) = @_;
 162
 163   return _create_item(record_type => 'sales_delivery_order', %params);
 164 }
 165
 166 sub _create_item {
 167   my (%params) = @_;
 168
 169   my $record_type = delete($params{record_type});
 170   my $part        = delete($params{part});
 171
 172   die "illegal record type: $record_type, must be one of: " . join(' ', keys %record_type_to_item_type) unless $record_type_to_item_type{ $record_type };
 173   die "part missing as param" unless $part && ref($part) eq 'SL::DB::Part';
 174
 175   my ($sellprice, $lastcost);
 176
 177   if ( $record_type =~ /^sales/ ) {
 178     $sellprice = delete $params{sellprice} // $part->sellprice;
 179     $lastcost  = delete $params{lastcost}  // $part->lastcost;
 180   } else {
 181     $sellprice = delete $params{sellprice} // $part->lastcost;
 182     $lastcost  = delete $params{lastcost}  // 0; # $part->lastcost;
 183   }
 184
 185   my $item = "$record_type_to_item_type{$record_type}"->new(
 186     parts_id    => $part->id,
 187     sellprice   => $sellprice,
 188     lastcost    => $lastcost,
 189     description => $part->description,
 190     unit        => $part->unit,
 191     qty         => $params{qty} || 5,
 192     %params,
 193   );
 194   return $item;
 195 }
 196
 197 sub _create_two_items {
 198   my ($record_type) = @_;
 199
 200   my $part1 = SL::Dev::Part::create_part(description => 'Testpart 1',
 201                                          sellprice   => 12,
 202                                         )->save;
 203   my $part2 = SL::Dev::Part::create_part(description => 'Testpart 2',
 204                                          sellprice   => 10,
 205                                         )->save;
 206   my $item1 = _create_item(record_type => $record_type, part => $part1, qty => 5);
 207   my $item2 = _create_item(record_type => $record_type, part => $part2, qty => 8);
 208   return [ $item1, $item2 ];
 209 }
 210
 211 1;
 212
 213 __END__
 214
 215 =head1 NAME
 216
 217 SL::Dev::Record - create record objects for testing, with minimal defaults
 218
 219 =head1 FUNCTIONS
 220
 221 =head2 C<create_sales_invoice %PARAMS>
 222
 223 Creates a new sales invoice (table ar, invoice = 1).
 224
 225 If neither customer nor invoiceitems are passed as params a customer and two
 226 parts are created and used for building the invoice.
 227
 228 Minimal usage example:
 229
 230   my $invoice = SL::Dev::Record::create_sales_invoice();
 231
 232 Example with params:
 233
 234   my $invoice2 = SL::Dev::Record::create_sales_invoice(
 235     invnumber   => 777,
 236     transdate   => DateTime->today_local->subtract(days => 7),
 237     taxincluded => 1,
 238   );
 239
 240 =head2 C<create_sales_order %PARAMS>
 241
 242 Examples:
 243
 244 Create a sales order and save it directly via rose, without running
 245 calculate_prices_and_taxes:
 246
 247  my $order = SL::Dev::Record::create_sales_order()->save;
 248
 249 Let create_sales_order run calculate_prices_and_taxes and save:
 250
 251  my $order = SL::Dev::Record::create_sales_order(save => 1);
 252
 253
 254 Example including creation of part and of sales order.
 255   my $part1 = SL::Dev::Part::create_part(   partnumber => 'T4254')->save;
 256   my $part2 = SL::Dev::Part::create_service(partnumber => 'Serv1')->save;
 257   my $order = SL::Dev::Record::create_sales_order(
 258     save         => 1,
 259     taxincluded  => 0,
 260     orderitems => [ SL::Dev::Record::create_order_item(part => $part1, qty =>  3, sellprice => 70),
 261                     SL::Dev::Record::create_order_item(part => $part2, qty => 10, sellprice => 50),
 262                   ]
 263   );
 264
 265 =head2 C<create_purchase_order %PARAMS>
 266
 267 See comments for C<create_sales_order>.
 268
 269 Example:
 270  my $purchase_order = SL::Dev::Record::create_purchase_order(save => 1);
 271
 272
 273 =head2 C<create_item %PARAMS>
 274
 275 Creates an item from a part object that can be added to a record.
 276
 277 Required params: record_type (sales_invoice, sales_order, sales_delivery_order)
 278                  part        (an SL::DB::Part object)
 279
 280 Example including creation of part and of invoice:
 281   my $part    = SL::Dev::Part::create_part(  partnumber  => 'T4254')->save;
 282   my $item    = SL::Dev::Record::create_item(record_type => 'sales_invoice', part => $part, qty => 2.5);
 283   my $invoice = SL::Dev::Record::create_sales_invoice(
 284     taxincluded  => 0,
 285     invoiceitems => [ $item ],
 286   );
 287
 288 =head1 TODO
 289
 290 =head1 BUGS
 291
 292 Nothing here yet.
 293
 294 =head1 AUTHOR
 295
 296 G. Richardson E<lt>grichardson@kivitendo-premium.deE<gt>
 297
 298 =cut