SL/DATEV.pm

   1 #=====================================================================
   2 # kivitendo ERP
   3 # Copyright (c) 2004
   4 #
   5 #  Author: Philip Reetz
   6 #   Email: p.reetz@linet-services.de
   7 #     Web: http://www.lx-office.org
   8 #
   9 #
  10 # This program is free software; you can redistribute it and/or modify
  11 # it under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 2 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # This program is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 # GNU General Public License for more details.
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  22 #======================================================================
  23 #
  24 # Datev export module
  25 #======================================================================
  26
  27 package SL::DATEV;
  28
  29 use utf8;
  30 use strict;
  31
  32 use SL::DBUtils;
  33 use SL::DATEV::KNEFile;
  34 use SL::Taxkeys;
  35
  36 use Data::Dumper;
  37 use DateTime;
  38 use Exporter qw(import);
  39 use File::Path;
  40 use List::Util qw(max sum);
  41 use Time::HiRes qw(gettimeofday);
  42
  43 {
  44   my $i = 0;
  45   use constant {
  46     DATEV_ET_BUCHUNGEN => $i++,
  47     DATEV_ET_STAMM     => $i++,
  48
  49     DATEV_FORMAT_KNE   => $i++,
  50     DATEV_FORMAT_OBE   => $i++,
  51   };
  52 }
  53
  54 my @export_constants = qw(DATEV_ET_BUCHUNGEN DATEV_ET_STAMM DATEV_FORMAT_KNE DATEV_FORMAT_OBE);
  55 our @EXPORT_OK = (@export_constants);
  56 our %EXPORT_TAGS = (CONSTANTS => [ @export_constants ]);
  57
  58
  59 sub new {
  60   my $class = shift;
  61   my %data  = @_;
  62
  63   my $obj = bless {}, $class;
  64
  65   $obj->$_($data{$_}) for keys %data;
  66
  67   $obj;
  68 }
  69
  70 sub exporttype {
  71   my $self = shift;
  72   $self->{exporttype} = $_[0] if @_;
  73   return $self->{exporttype};
  74 }
  75
  76 sub has_exporttype {
  77   defined $_[0]->{exporttype};
  78 }
  79
  80 sub format {
  81   my $self = shift;
  82   $self->{format} = $_[0] if @_;
  83   return $self->{format};
  84 }
  85
  86 sub has_format {
  87   defined $_[0]->{format};
  88 }
  89
  90 sub _get_export_path {
  91   $main::lxdebug->enter_sub();
  92
  93   my ($a, $b) = gettimeofday();
  94   my $path    = _get_path_for_download_token("${a}-${b}-${$}");
  95
  96   mkpath($path) unless (-d $path);
  97
  98   $main::lxdebug->leave_sub();
  99
 100   return $path;
 101 }
 102
 103 sub _get_path_for_download_token {
 104   $main::lxdebug->enter_sub();
 105
 106   my $token = shift || '';
 107   my $path;
 108
 109   if ($token =~ m|^(\d+)-(\d+)-(\d+)$|) {
 110     $path = $::lx_office_conf{paths}->{userspath} . "/datev-export-${1}-${2}-${3}/";
 111   }
 112
 113   $main::lxdebug->leave_sub();
 114
 115   return $path;
 116 }
 117
 118 sub _get_download_token_for_path {
 119   $main::lxdebug->enter_sub();
 120
 121   my $path = shift;
 122   my $token;
 123
 124   if ($path =~ m|.*datev-export-(\d+)-(\d+)-(\d+)/?$|) {
 125     $token = "${1}-${2}-${3}";
 126   }
 127
 128   $main::lxdebug->leave_sub();
 129
 130   return $token;
 131 }
 132
 133 sub download_token {
 134   my $self = shift;
 135   $self->{download_token} = $_[0] if @_;
 136   return $self->{download_token} ||= _get_download_token_for_path($self->export_path);
 137 }
 138
 139 sub export_path {
 140   my ($self) = @_;
 141
 142   return  $self->{export_path} ||= _get_path_for_download_token($self->{download_token}) || _get_export_path();
 143 }
 144
 145 sub add_filenames {
 146   my $self = shift;
 147   push @{ $self->{filenames} ||= [] }, @_;
 148 }
 149
 150 sub filenames {
 151   return @{ $_[0]{filenames} || [] };
 152 }
 153
 154 sub add_error {
 155   my $self = shift;
 156   push @{ $self->{errors} ||= [] }, @_;
 157 }
 158
 159 sub errors {
 160   return @{ $_[0]{errors} || [] };
 161 }
 162
 163 sub add_net_gross_differences {
 164   my $self = shift;
 165   push @{ $self->{net_gross_differences} ||= [] }, @_;
 166 }
 167
 168 sub net_gross_differences {
 169   return @{ $_[0]{net_gross_differences} || [] };
 170 }
 171
 172 sub sum_net_gross_differences {
 173   return sum $_[0]->net_gross_differences;
 174 }
 175
 176 sub from {
 177  my $self = shift;
 178
 179  if (@_) {
 180    $self->{from} = $_[0];
 181  }
 182
 183  return $self->{from};
 184 }
 185
 186 sub to {
 187  my $self = shift;
 188
 189  if (@_) {
 190    $self->{to} = $_[0];
 191  }
 192
 193  return $self->{to};
 194 }
 195
 196 sub accnofrom {
 197  my $self = shift;
 198
 199  if (@_) {
 200    $self->{accnofrom} = $_[0];
 201  }
 202
 203  return $self->{accnofrom};
 204 }
 205
 206 sub accnoto {
 207  my $self = shift;
 208
 209  if (@_) {
 210    $self->{accnoto} = $_[0];
 211  }
 212
 213  return $self->{accnoto};
 214 }
 215
 216
 217 sub dbh {
 218   my $self = shift;
 219
 220   if (@_) {
 221     $self->{dbh} = $_[0];
 222     $self->{provided_dbh} = 1;
 223   }
 224
 225   $self->{dbh} ||= $::form->get_standard_dbh;
 226 }
 227
 228 sub provided_dbh {
 229   $_[0]{provided_dbh};
 230 }
 231
 232 sub clean_temporary_directories {
 233   $::lxdebug->enter_sub;
 234
 235   foreach my $path (glob($::lx_office_conf{paths}->{userspath} . "/datev-export-*")) {
 236     next unless -d $path;
 237
 238     my $mtime = (stat($path))[9];
 239     next if ((time() - $mtime) < 8 * 60 * 60);
 240
 241     rmtree $path;
 242   }
 243
 244   $::lxdebug->leave_sub;
 245 }
 246
 247 sub _fill {
 248   $main::lxdebug->enter_sub();
 249
 250   my $text      = shift;
 251   my $field_len = shift;
 252   my $fill_char = shift;
 253   my $alignment = shift || 'right';
 254
 255   my $text_len  = length $text;
 256
 257   if ($field_len < $text_len) {
 258     $text = substr $text, 0, $field_len;
 259
 260   } elsif ($field_len > $text_len) {
 261     my $filler = ($fill_char) x ($field_len - $text_len);
 262     $text      = $alignment eq 'right' ? $filler . $text : $text . $filler;
 263   }
 264
 265   $main::lxdebug->leave_sub();
 266
 267   return $text;
 268 }
 269
 270 sub get_datev_stamm {
 271   return $_[0]{stamm} ||= selectfirst_hashref_query($::form, $_[0]->dbh, 'SELECT * FROM datev');
 272 }
 273
 274 sub save_datev_stamm {
 275   my ($self, $data) = @_;
 276
 277   do_query($::form, $self->dbh, 'DELETE FROM datev');
 278
 279   my @columns = qw(beraternr beratername dfvkz mandantennr datentraegernr abrechnungsnr);
 280
 281   my $query = "INSERT INTO datev (" . join(', ', @columns) . ") VALUES (" . join(', ', ('?') x @columns) . ")";
 282   do_query($::form, $self->dbh, $query, map { $data->{$_} } @columns);
 283
 284   $self->dbh->commit unless $self->provided_dbh;
 285 }
 286
 287 sub export {
 288   my ($self) = @_;
 289   my $result;
 290
 291   die 'no format set!' unless $self->has_format;
 292
 293   if ($self->format == DATEV_FORMAT_KNE) {
 294     $result = $self->kne_export;
 295   } elsif ($self->format == DATEV_FORMAT_OBE) {
 296     $result = $self->obe_export;
 297   } else {
 298     die 'unrecognized export format';
 299   }
 300
 301   return $result;
 302 }
 303
 304 sub kne_export {
 305   my ($self) = @_;
 306   my $result;
 307
 308   die 'no exporttype set!' unless $self->has_exporttype;
 309
 310   if ($self->exporttype == DATEV_ET_BUCHUNGEN) {
 311     $result = $self->kne_buchungsexport;
 312   } elsif ($self->exporttype == DATEV_ET_STAMM) {
 313     $result = $self->kne_stammdatenexport;
 314   } else {
 315     die 'unrecognized exporttype';
 316   }
 317
 318   return $result;
 319 }
 320
 321 sub obe_export {
 322   die 'not yet implemented';
 323 }
 324
 325 sub fromto {
 326   my ($self) = @_;
 327
 328   return unless $self->from && $self->to;
 329
 330   return "transdate >= '" . $self->from->to_lxoffice . "' and transdate <= '" . $self->to->to_lxoffice . "'";
 331 }
 332
 333 sub _sign {
 334   $_[0] <=> 0;
 335 }
 336
 337 sub _get_transactions {
 338   $main::lxdebug->enter_sub();
 339   my $self     = shift;
 340   my $fromto   =  shift;
 341   my $progress_callback = shift || sub {};
 342
 343   my $form     =  $main::form;
 344
 345   my ($notsplitindex);
 346
 347   $fromto      =~ s/transdate/ac\.transdate/g;
 348
 349   my $taxkeys  = Taxkeys->new();
 350   my $filter   = '';            # Useful for debugging purposes
 351
 352   my %all_taxchart_ids = selectall_as_map($form, $self->dbh, qq|SELECT DISTINCT chart_id, TRUE AS is_set FROM tax|, 'chart_id', 'is_set');
 353
 354   my $query    =
 355     qq|SELECT ac.acc_trans_id, ac.transdate, ac.trans_id,ar.id, ac.amount, ac.taxkey,
 356          ar.invnumber, ar.duedate, ar.amount as umsatz,
 357          ct.name,
 358          c.accno, c.taxkey_id as charttax, c.datevautomatik, c.id, c.link,
 359          ar.invoice
 360        FROM acc_trans ac
 361        LEFT JOIN ar          ON (ac.trans_id    = ar.id)
 362        LEFT JOIN customer ct ON (ar.customer_id = ct.id)
 363        LEFT JOIN chart c     ON (ac.chart_id    = c.id)
 364        WHERE (ar.id IS NOT NULL)
 365          AND $fromto
 366          $filter
 367
 368        UNION ALL
 369
 370        SELECT ac.acc_trans_id, ac.transdate, ac.trans_id,ap.id, ac.amount, ac.taxkey,
 371          ap.invnumber, ap.duedate, ap.amount as umsatz,
 372          ct.name,
 373          c.accno, c.taxkey_id as charttax, c.datevautomatik, c.id, c.link,
 374          ap.invoice
 375        FROM acc_trans ac
 376        LEFT JOIN ap        ON (ac.trans_id  = ap.id)
 377        LEFT JOIN vendor ct ON (ap.vendor_id = ct.id)
 378        LEFT JOIN chart c   ON (ac.chart_id  = c.id)
 379        WHERE (ap.id IS NOT NULL)
 380          AND $fromto
 381          $filter
 382
 383        UNION ALL
 384
 385        SELECT ac.acc_trans_id, ac.transdate, ac.trans_id,gl.id, ac.amount, ac.taxkey,
 386          gl.reference AS invnumber, gl.transdate AS duedate, ac.amount as umsatz,
 387          gl.description AS name,
 388          c.accno, c.taxkey_id as charttax, c.datevautomatik, c.id, c.link,
 389          FALSE AS invoice
 390        FROM acc_trans ac
 391        LEFT JOIN gl      ON (ac.trans_id  = gl.id)
 392        LEFT JOIN chart c ON (ac.chart_id  = c.id)
 393        WHERE (gl.id IS NOT NULL)
 394          AND $fromto
 395          $filter
 396
 397        ORDER BY trans_id, acc_trans_id|;
 398
 399   my $sth = prepare_execute_query($form, $self->dbh, $query);
 400   $self->{DATEV} = [];
 401
 402   my $counter = 0;
 403   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 404     $counter++;
 405     if (($counter % 500) == 0) {
 406       $progress_callback->($counter);
 407     }
 408
 409     my $trans    = [ $ref ];
 410
 411     my $count    = $ref->{amount};
 412     my $firstrun = 1;
 413
 414     # if the amount of a booking in a group is smaller than 0.02, any tax
 415     # amounts will likely be smaller than 1 cent, so go into subcent mode
 416     my $subcent  = abs($count) < 0.02;
 417
 418     # records from acc_trans are ordered by trans_id and acc_trans_id
 419     # first check for unbalanced ledger inside one trans_id
 420     # there may be several groups inside a trans_id, e.g. the original booking and the payment
 421     # each group individually should be exactly balanced and each group
 422     # individually needs its own datev lines
 423
 424     # keep fetching new acc_trans lines until the end of a balanced group is reached
 425     while (abs($count) > 0.01 || $firstrun || ($subcent && abs($count) > 0.005)) {
 426       my $ref2 = $sth->fetchrow_hashref("NAME_lc");
 427       last unless ($ref2);
 428
 429       # check if trans_id of current acc_trans line is still the same as the
 430       # trans_id of the first line in group
 431
 432       if ($ref2->{trans_id} != $trans->[0]->{trans_id}) {
 433         $self->add_error("Unbalanced ledger! old trans_id " . $trans->[0]->{trans_id} . " new trans_id " . $ref2->{trans_id} . " count $count");
 434         return;
 435       }
 436
 437       push @{ $trans }, $ref2;
 438
 439       $count    += $ref2->{amount};
 440       $firstrun  = 0;
 441     }
 442
 443     foreach my $i (0 .. scalar(@{ $trans }) - 1) {
 444       my $ref        = $trans->[$i];
 445       my $prev_ref   = 0 < $i ? $trans->[$i - 1] : undef;
 446       if (   $all_taxchart_ids{$ref->{id}}
 447           && ($ref->{link} =~ m/(?:AP_tax|AR_tax)/)
 448           && (   ($prev_ref && $prev_ref->{taxkey} && (_sign($ref->{amount}) == _sign($prev_ref->{amount})))
 449               || $ref->{invoice})) {
 450         $ref->{is_tax} = 1;
 451       }
 452
 453       if (   !$ref->{invoice}   # we have a non-invoice booking (=gl)
 454           &&  $ref->{is_tax}    # that has "is_tax" set
 455           && !($prev_ref->{is_tax})  # previous line wasn't is_tax
 456           &&  (_sign($ref->{amount}) == _sign($prev_ref->{amount}))) {  # and sign same as previous sign
 457         $trans->[$i - 1]->{tax_amount} = $ref->{amount};
 458       }
 459     }
 460
 461     my %taxid_taxkeys = ();
 462     my $absumsatz     = 0;
 463     if (scalar(@{$trans}) <= 2) {
 464       push @{ $self->{DATEV} }, $trans;
 465       next;
 466     }
 467
 468     # determine at which array position the reference value (called absumsatz) is
 469     # and which amount it has
 470
 471     for my $j (0 .. (scalar(@{$trans}) - 1)) {
 472
 473       # Three cases:
 474       # 1: gl transaction (Dialogbuchung), invoice is false, no double split booking allowed
 475
 476       # 2: sales or vendor invoice (Verkaufs- und Einkaufsrechnung): invoice is
 477       # true, instead of absumsatz use link AR/AP (there should only be one
 478       # entry)
 479
 480       # 3. AR/AP transaction (Kreditoren- und Debitorenbuchung): invoice is false,
 481       # instead of absumsatz use link AR/AP (there should only be one, so jump
 482       # out of search as soon as you find it )
 483
 484       # case 1 and 2
 485       # for gl-bookings no split is allowed and there is no AR/AP account, so we always use the maximum value as a reference
 486       # for ap/ar bookings we can always search for AR/AP in link and use that
 487       if ( ( not $trans->[$j]->{'invoice'} and abs($trans->[$j]->{'amount'}) > abs($absumsatz) )
 488          or ($trans->[$j]->{'invoice'} and ($trans->[$j]->{'link'} eq 'AR' or $trans->[$j]->{'link'} eq 'AP'))) {
 489         $absumsatz     = $trans->[$j]->{'amount'};
 490         $notsplitindex = $j;
 491       }
 492
 493       # case 3
 494       # Problem: we can't distinguish between AR and AP and normal invoices via boolean "invoice"
 495       # for AR and AP transaction exit the loop as soon as an AR or AP account is found
 496       # there must be only one AR or AP chart in the booking
 497       if ( $trans->[$j]->{'link'} eq 'AR' or $trans->[$j]->{'link'} eq 'AP') {
 498         $notsplitindex = $j;   # position in booking with highest amount
 499         $absumsatz     = $trans->[$j]->{'amount'};
 500         last;
 501       };
 502     }
 503
 504     my $ml             = ($trans->[0]->{'umsatz'} > 0) ? 1 : -1;
 505     my $rounding_error = 0;
 506     my @taxed;
 507
 508     # go through each line and determine if it is a tax booking or not
 509     # skip all tax lines and notsplitindex line
 510     # push all other accounts (e.g. income or expense) with corresponding taxkey
 511
 512     for my $j (0 .. (scalar(@{$trans}) - 1)) {
 513       if (   ($j != $notsplitindex)
 514           && !$trans->[$j]->{is_tax}
 515           && (   $trans->[$j]->{'taxkey'} eq ""
 516               || $trans->[$j]->{'taxkey'} eq "0"
 517               || $trans->[$j]->{'taxkey'} eq "1"
 518               || $trans->[$j]->{'taxkey'} eq "10"
 519               || $trans->[$j]->{'taxkey'} eq "11")) {
 520         my %new_trans = ();
 521         map { $new_trans{$_} = $trans->[$notsplitindex]->{$_}; } keys %{ $trans->[$notsplitindex] };
 522
 523         $absumsatz               += $trans->[$j]->{'amount'};
 524         $new_trans{'amount'}      = $trans->[$j]->{'amount'} * (-1);
 525         $new_trans{'umsatz'}      = abs($trans->[$j]->{'amount'}) * $ml;
 526         $trans->[$j]->{'umsatz'}  = abs($trans->[$j]->{'amount'}) * $ml;
 527
 528         push @{ $self->{DATEV} }, [ \%new_trans, $trans->[$j] ];
 529
 530       } elsif (($j != $notsplitindex) && !$trans->[$j]->{is_tax}) {
 531         my %tax_info = $taxkeys->get_full_tax_info('transdate' => $trans->[$j]->{transdate});
 532
 533         my %new_trans = ();
 534         map { $new_trans{$_} = $trans->[$notsplitindex]->{$_}; } keys %{ $trans->[$notsplitindex] };
 535
 536         my $tax_rate              = $tax_info{taxkeys}->{ $trans->[$j]->{'taxkey'} }->{taxrate};
 537         $new_trans{'net_amount'}  = $trans->[$j]->{'amount'} * -1;
 538         $new_trans{'tax_rate'}    = 1 + $tax_rate;
 539
 540         if (!$trans->[$j]->{'invoice'}) {
 541           $new_trans{'amount'}      = $form->round_amount(-1 * ($trans->[$j]->{amount} + $trans->[$j]->{tax_amount}), 2);
 542           $new_trans{'umsatz'}      = abs($new_trans{'amount'}) * $ml;
 543           $trans->[$j]->{'umsatz'}  = $new_trans{'umsatz'};
 544           $absumsatz               += -1 * $new_trans{'amount'};
 545
 546         } else {
 547           my $unrounded             = $trans->[$j]->{'amount'} * (1 + $tax_rate) * -1 + $rounding_error;
 548           my $rounded               = $form->round_amount($unrounded, 2);
 549
 550           $rounding_error           = $unrounded - $rounded;
 551           $new_trans{'amount'}      = $rounded;
 552           $new_trans{'umsatz'}      = abs($rounded) * $ml;
 553           $trans->[$j]->{'umsatz'}  = $new_trans{umsatz};
 554           $absumsatz               -= $rounded;
 555         }
 556
 557         push @{ $self->{DATEV} }, [ \%new_trans, $trans->[$j] ];
 558         push @taxed, $self->{DATEV}->[-1];
 559       }
 560     }
 561
 562     my $idx        = 0;
 563     my $correction = 0;
 564     while ((abs($absumsatz) >= 0.01) && (abs($absumsatz) < 1.00)) {
 565       if ($idx >= scalar @taxed) {
 566         last if (!$correction);
 567
 568         $correction = 0;
 569         $idx        = 0;
 570       }
 571
 572       my $transaction = $taxed[$idx]->[0];
 573
 574       my $old_amount     = $transaction->{amount};
 575       my $old_correction = $correction;
 576       my @possible_diffs;
 577
 578       if (!$transaction->{diff}) {
 579         @possible_diffs = (0.01, -0.01);
 580       } else {
 581         @possible_diffs = ($transaction->{diff});
 582       }
 583
 584       foreach my $diff (@possible_diffs) {
 585         my $net_amount = $form->round_amount(($transaction->{amount} + $diff) / $transaction->{tax_rate}, 2);
 586         next if ($net_amount != $transaction->{net_amount});
 587
 588         $transaction->{diff}    = $diff;
 589         $transaction->{amount} += $diff;
 590         $transaction->{umsatz} += $diff;
 591         $absumsatz             -= $diff;
 592         $correction             = 1;
 593
 594         last;
 595       }
 596
 597       $idx++;
 598     }
 599
 600     $absumsatz = $form->round_amount($absumsatz, 2);
 601     if (abs($absumsatz) >= (0.01 * (1 + scalar @taxed))) {
 602       $self->add_error("Datev-Export fehlgeschlagen! Bei Transaktion $trans->[0]->{trans_id} ($absumsatz)");
 603
 604     } elsif (abs($absumsatz) >= 0.01) {
 605       $self->add_net_gross_differences($absumsatz);
 606     }
 607   }
 608
 609   $sth->finish();
 610
 611   $::lxdebug->leave_sub;
 612 }
 613
 614 sub make_kne_data_header {
 615   $main::lxdebug->enter_sub();
 616
 617   my ($self, $form) = @_;
 618   my ($primanota);
 619
 620   my $stamm = $self->get_datev_stamm;
 621
 622   my $jahr = $self->from ? $self->from->year : DateTime->today->year;
 623
 624   #Header
 625   my $header  = "\x1D\x181";
 626   $header    .= _fill($stamm->{datentraegernr}, 3, ' ', 'left');
 627   $header    .= ($self->fromto) ? "11" : "13"; # Anwendungsnummer
 628   $header    .= _fill($stamm->{dfvkz}, 2, '0');
 629   $header    .= _fill($stamm->{beraternr}, 7, '0');
 630   $header    .= _fill($stamm->{mandantennr}, 5, '0');
 631   $header    .= _fill($stamm->{abrechnungsnr} . $jahr, 6, '0');
 632
 633   $header .= $self->from ? $self->from->strftime('%d%m%y') : '';
 634   $header .= $self->to   ? $self->to->strftime('%d%m%y')   : '';
 635
 636   if ($self->fromto) {
 637     $primanota = "001";
 638     $header .= $primanota;
 639   }
 640
 641   $header .= _fill($stamm->{passwort}, 4, '0');
 642   $header .= " " x 16;       # Anwendungsinfo
 643   $header .= " " x 16;       # Inputinfo
 644   $header .= "\x79";
 645
 646   #Versionssatz
 647   my $versionssatz  = $self->exporttype == DATEV_ET_BUCHUNGEN ? "\xB5" . "1," : "\xB6" . "1,";
 648
 649   my $query         = qq|SELECT accno FROM chart LIMIT 1|;
 650   my $ref           = selectfirst_hashref_query($form, $self->dbh, $query);
 651
 652   $versionssatz    .= length $ref->{accno};
 653   $versionssatz    .= ",";
 654   $versionssatz    .= length $ref->{accno};
 655   $versionssatz    .= ",SELF" . "\x1C\x79";
 656
 657   $header          .= $versionssatz;
 658
 659   $main::lxdebug->leave_sub();
 660
 661   return $header;
 662 }
 663
 664 sub datetofour {
 665   $main::lxdebug->enter_sub();
 666
 667   my ($date, $six) = @_;
 668
 669   my ($day, $month, $year) = split(/\./, $date);
 670
 671   if ($day =~ /^0/) {
 672     $day = substr($day, 1, 1);
 673   }
 674   if (length($month) < 2) {
 675     $month = "0" . $month;
 676   }
 677   if (length($year) > 2) {
 678     $year = substr($year, -2, 2);
 679   }
 680
 681   if ($six) {
 682     $date = $day . $month . $year;
 683   } else {
 684     $date = $day . $month;
 685   }
 686
 687   $main::lxdebug->leave_sub();
 688
 689   return $date;
 690 }
 691
 692 sub trim_leading_zeroes {
 693   my $str = shift;
 694
 695   $str =~ s/^0+//g;
 696
 697   return $str;
 698 }
 699
 700 sub make_ed_versionset {
 701   $main::lxdebug->enter_sub();
 702
 703   my ($self, $header, $filename, $blockcount) = @_;
 704
 705   my $versionset  = "V" . substr($filename, 2, 5);
 706   $versionset    .= substr($header, 6, 22);
 707
 708   if ($self->fromto) {
 709     $versionset .= "0000" . substr($header, 28, 19);
 710   } else {
 711     my $datum = " " x 16;
 712     $versionset .= $datum . "001" . substr($header, 28, 4);
 713   }
 714
 715   $versionset .= _fill($blockcount, 5, '0');
 716   $versionset .= "001";
 717   $versionset .= " 1";
 718   $versionset .= substr($header, -12, 10) . "    ";
 719   $versionset .= " " x 53;
 720
 721   $main::lxdebug->leave_sub();
 722
 723   return $versionset;
 724 }
 725
 726 sub make_ev_header {
 727   $main::lxdebug->enter_sub();
 728
 729   my ($self, $form, $fileno) = @_;
 730
 731   my $stamm = $self->get_datev_stamm;
 732
 733   my $ev_header  = _fill($stamm->{datentraegernr}, 3, ' ', 'left');
 734   $ev_header    .= "   ";
 735   $ev_header    .= _fill($stamm->{beraternr}, 7, ' ', 'left');
 736   $ev_header    .= _fill($stamm->{beratername}, 9, ' ', 'left');
 737   $ev_header    .= " ";
 738   $ev_header    .= (_fill($fileno, 5, '0')) x 2;
 739   $ev_header    .= " " x 95;
 740
 741   $main::lxdebug->leave_sub();
 742
 743   return $ev_header;
 744 }
 745
 746 sub kne_buchungsexport {
 747   $main::lxdebug->enter_sub();
 748
 749   my ($self) = @_;
 750
 751   my $form = $::form;
 752
 753   my @filenames;
 754
 755   my $filename    = "ED00000";
 756   my $evfile      = "EV01";
 757   my @ed_versionset;
 758   my $fileno = 0;
 759
 760   my $fromto = $self->fromto;
 761
 762   $self->_get_transactions($fromto);
 763
 764   return if $self->errors;
 765
 766   my $counter = 0;
 767
 768   while (scalar(@{ $self->{DATEV} || [] })) {
 769     my $umsatzsumme = 0;
 770     $filename++;
 771     my $ed_filename = $self->export_path . $filename;
 772     push(@filenames, $filename);
 773     my $header = $self->make_kne_data_header($form);
 774
 775     my $kne_file = SL::DATEV::KNEFile->new();
 776     $kne_file->add_block($header);
 777
 778     while (scalar(@{ $self->{DATEV} }) > 0) {
 779       my $transaction = shift @{ $self->{DATEV} };
 780       my $trans_lines = scalar(@{$transaction});
 781       $counter++;
 782
 783       my $umsatz         = 0;
 784       my $gegenkonto     = "";
 785       my $konto          = "";
 786       my $belegfeld1     = "";
 787       my $datum          = "";
 788       my $waehrung       = "";
 789       my $buchungstext   = "";
 790       my $belegfeld2     = "";
 791       my $datevautomatik = 0;
 792       my $taxkey         = 0;
 793       my $charttax       = 0;
 794       my ($haben, $soll);
 795       my $iconv          = $::locale->{iconv_utf8};
 796       my %umlaute = ($iconv->convert('ä') => 'ae',
 797                      $iconv->convert('ö') => 'oe',
 798                      $iconv->convert('ü') => 'ue',
 799                      $iconv->convert('Ä') => 'Ae',
 800                      $iconv->convert('Ö') => 'Oe',
 801                      $iconv->convert('Ü') => 'Ue',
 802                      $iconv->convert('ß') => 'sz');
 803       for (my $i = 0; $i < $trans_lines; $i++) {
 804         if ($trans_lines == 2) {
 805           if (abs($transaction->[$i]->{'amount'}) > abs($umsatz)) {
 806             $umsatz = $transaction->[$i]->{'amount'};
 807           }
 808         } else {
 809           if (abs($transaction->[$i]->{'umsatz'}) > abs($umsatz)) {
 810             $umsatz = $transaction->[$i]->{'umsatz'};
 811           }
 812         }
 813         if ($transaction->[$i]->{'datevautomatik'}) {
 814           $datevautomatik = 1;
 815         }
 816         if ($transaction->[$i]->{'taxkey'}) {
 817           $taxkey = $transaction->[$i]->{'taxkey'};
 818         }
 819         if ($transaction->[$i]->{'charttax'}) {
 820           $charttax = $transaction->[$i]->{'charttax'};
 821         }
 822         if ($transaction->[$i]->{'amount'} > 0) {
 823           $haben = $i;
 824         } else {
 825           $soll = $i;
 826         }
 827       }
 828
 829       # Umwandlung von Umlauten und Sonderzeichen in erlaubte Zeichen bei Textfeldern
 830       foreach my $umlaut (keys(%umlaute)) {
 831         $transaction->[$haben]->{'invnumber'} =~ s/${umlaut}/${umlaute{$umlaut}}/g;
 832         $transaction->[$haben]->{'name'}      =~ s/${umlaut}/${umlaute{$umlaut}}/g;
 833       }
 834
 835       $transaction->[$haben]->{'invnumber'} =~ s/[^0-9A-Za-z\$\%\&\*\+\-\/]//g;
 836       $transaction->[$haben]->{'name'}      =~ s/[^0-9A-Za-z\$\%\&\*\+\-\ \/]//g;
 837
 838       $transaction->[$haben]->{'invnumber'} =  substr($transaction->[$haben]->{'invnumber'}, 0, 12);
 839       $transaction->[$haben]->{'name'}      =  substr($transaction->[$haben]->{'name'}, 0, 30);
 840       $transaction->[$haben]->{'invnumber'} =~ s/\ *$//;
 841       $transaction->[$haben]->{'name'}      =~ s/\ *$//;
 842
 843       if ($trans_lines >= 2) {
 844
 845         $gegenkonto = "a" . trim_leading_zeroes($transaction->[$haben]->{'accno'});
 846         $konto      = "e" . trim_leading_zeroes($transaction->[$soll]->{'accno'});
 847         if ($transaction->[$haben]->{'invnumber'} ne "") {
 848           $belegfeld1 = "\xBD" . $transaction->[$haben]->{'invnumber'} . "\x1C";
 849         }
 850         $datum = "d";
 851         $datum .= &datetofour($transaction->[$haben]->{'transdate'}, 0);
 852         $waehrung = "\xB3" . "EUR" . "\x1C";
 853         if ($transaction->[$haben]->{'name'} ne "") {
 854           $buchungstext = "\x1E" . $transaction->[$haben]->{'name'} . "\x1C";
 855         }
 856         if ($transaction->[$haben]->{'duedate'} ne "") {
 857           $belegfeld2 = "\xBE" . &datetofour($transaction->[$haben]->{'duedate'}, 1) . "\x1C";
 858         }
 859       }
 860
 861       $umsatz       = $kne_file->format_amount(abs($umsatz), 0);
 862       $umsatzsumme += $umsatz;
 863       $kne_file->add_block("+" . $umsatz);
 864
 865       # Dies ist die einzige Stelle die datevautomatik auswertet. Was soll gesagt werden?
 866       # Im Prinzip hat jeder acc_trans Eintrag einen Steuerschlüssel, außer, bei gewissen Fällen
 867       # wie: Kreditorenbuchung mit negativen Vorzeichen, SEPA-Export oder Rechnungen die per
 868       # Skript angelegt werden.
 869       # Also falls ein Steuerschlüssel da ist und NICHT datevautomatik diesen Block hinzufügen.
 870       # Oder aber datevautomatik ist WAHR, aber der Steuerschlüssel in der acc_trans weicht
 871       # von dem in der Chart ab: Also wahrscheinlich Programmfehler (NULL übergeben, statt
 872       # DATEV-Steuerschlüssel) oder der Steuerschlüssel des Kontos weicht WIRKLICH von dem Eintrag in der
 873       # acc_trans ab. Gibt es für diesen Fall eine plausiblen Grund?
 874       #
 875       if (   ( $datevautomatik || $taxkey)
 876           && (!$datevautomatik || ($datevautomatik && ($charttax ne $taxkey)))) {
 877 #         $kne_file->add_block("\x6C" . (!$datevautomatik ? $taxkey : "4"));
 878         $kne_file->add_block("\x6C${taxkey}");
 879       }
 880
 881       $kne_file->add_block($gegenkonto);
 882       $kne_file->add_block($belegfeld1);
 883       $kne_file->add_block($belegfeld2);
 884       $kne_file->add_block($datum);
 885       $kne_file->add_block($konto);
 886       $kne_file->add_block($buchungstext);
 887       $kne_file->add_block($waehrung . "\x79");
 888     }
 889
 890     my $mandantenendsumme = "x" . $kne_file->format_amount($umsatzsumme / 100.0, 14) . "\x79\x7a";
 891
 892     $kne_file->add_block($mandantenendsumme);
 893     $kne_file->flush();
 894
 895     open(ED, ">", $ed_filename) or die "can't open outputfile: $!\n";
 896     print(ED $kne_file->get_data());
 897     close(ED);
 898
 899     $ed_versionset[$fileno] = $self->make_ed_versionset($header, $filename, $kne_file->get_block_count());
 900     $fileno++;
 901   }
 902
 903   #Make EV Verwaltungsdatei
 904   my $ev_header = $self->make_ev_header($form, $fileno);
 905   my $ev_filename = $self->export_path . $evfile;
 906   push(@filenames, $evfile);
 907   open(EV, ">", $ev_filename) or die "can't open outputfile: EV01\n";
 908   print(EV $ev_header);
 909
 910   foreach my $file (@ed_versionset) {
 911     print(EV $ed_versionset[$file]);
 912   }
 913   close(EV);
 914   ###
 915
 916   $self->add_filenames(@filenames);
 917
 918   $main::lxdebug->leave_sub();
 919
 920   return { 'download_token' => $self->download_token, 'filenames' => \@filenames };
 921 }
 922
 923 sub kne_stammdatenexport {
 924   $main::lxdebug->enter_sub();
 925
 926   my ($self) = @_;
 927   my $form = $::form;
 928
 929   $self->get_datev_stamm->{abrechnungsnr} = "99";
 930
 931   my @filenames;
 932
 933   my $filename    = "ED00000";
 934   my $evfile      = "EV01";
 935   my @ed_versionset;
 936   my $fileno          = 1;
 937   my $i               = 0;
 938   my $blockcount      = 1;
 939   my $remaining_bytes = 256;
 940   my $total_bytes     = 256;
 941   my $buchungssatz    = "";
 942   $filename++;
 943   my $ed_filename = $self->export_path . $filename;
 944   push(@filenames, $filename);
 945   open(ED, ">", $ed_filename) or die "can't open outputfile: $!\n";
 946   my $header = $self->make_kne_data_header($form);
 947   $remaining_bytes -= length($header);
 948
 949   my $fuellzeichen;
 950
 951   my (@where, @values) = ((), ());
 952   if ($self->accnofrom) {
 953     push @where, 'c.accno >= ?';
 954     push @values, $self->accnofrom;
 955   }
 956   if ($self->accnoto) {
 957     push @where, 'c.accno <= ?';
 958     push @values, $self->accnoto;
 959   }
 960
 961   my $where_str = @where ? ' WHERE ' . join(' AND ', map { "($_)" } @where) : '';
 962
 963   my $query     = qq|SELECT c.accno, c.description
 964                      FROM chart c
 965                      $where_str
 966                      ORDER BY c.accno|;
 967
 968   my $sth = $self->dbh->prepare($query);
 969   $sth->execute(@values) || $form->dberror($query);
 970
 971   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 972     if (($remaining_bytes - length("t" . $ref->{'accno'})) <= 6) {
 973       $fuellzeichen = ($blockcount * 256 - length($buchungssatz . $header));
 974       $buchungssatz .= "\x00" x $fuellzeichen;
 975       $blockcount++;
 976       $total_bytes = ($blockcount) * 256;
 977     }
 978     $buchungssatz .= "t" . $ref->{'accno'};
 979     $remaining_bytes = $total_bytes - length($buchungssatz . $header);
 980     $ref->{'description'} =~ s/[^0-9A-Za-z\$\%\&\*\+\-\/]//g;
 981     $ref->{'description'} = substr($ref->{'description'}, 0, 40);
 982     $ref->{'description'} =~ s/\ *$//;
 983
 984     if (
 985         ($remaining_bytes - length("\x1E" . $ref->{'description'} . "\x1C\x79")
 986         ) <= 6
 987       ) {
 988       $fuellzeichen = ($blockcount * 256 - length($buchungssatz . $header));
 989       $buchungssatz .= "\x00" x $fuellzeichen;
 990       $blockcount++;
 991       $total_bytes = ($blockcount) * 256;
 992     }
 993     $buchungssatz .= "\x1E" . $ref->{'description'} . "\x1C\x79";
 994     $remaining_bytes = $total_bytes - length($buchungssatz . $header);
 995   }
 996
 997   $sth->finish;
 998   print(ED $header);
 999   print(ED $buchungssatz);
1000   $fuellzeichen = 256 - (length($header . $buchungssatz . "z") % 256);
1001   my $dateiende = "\x00" x $fuellzeichen;
1002   print(ED "z");
1003   print(ED $dateiende);
1004   close(ED);
1005
1006   #Make EV Verwaltungsdatei
1007   $ed_versionset[0] =
1008     $self->make_ed_versionset($header, $filename, $blockcount);
1009
1010   my $ev_header = $self->make_ev_header($form, $fileno);
1011   my $ev_filename = $self->export_path . $evfile;
1012   push(@filenames, $evfile);
1013   open(EV, ">", $ev_filename) or die "can't open outputfile: EV01\n";
1014   print(EV $ev_header);
1015
1016   foreach my $file (@ed_versionset) {
1017     print(EV $ed_versionset[$file]);
1018   }
1019   close(EV);
1020
1021   $self->add_filenames(@filenames);
1022
1023   $main::lxdebug->leave_sub();
1024
1025   return { 'download_token' => $self->download_token, 'filenames' => \@filenames };
1026 }
1027
1028 sub DESTROY {
1029   clean_temporary_directories();
1030 }
1031
1032 1;
1033
1034 __END__
1035
1036 =encoding utf-8
1037
1038 =head1 NAME
1039
1040 SL::DATEV - kivitendo DATEV Export module
1041
1042 =head1 SYNOPSIS
1043
1044   use SL::DATEV qw(:CONSTANTS);
1045
1046   my $datev = SL::DATEV->new(
1047     exporttype => DATEV_ET_BUCHUNGEN,
1048     format     => DATEV_FORMAT_KNE,
1049     from       => $startdate,
1050     to         => $enddate,
1051   );
1052
1053   my $datev = SL::DATEV->new(
1054     exporttype => DATEV_ET_STAMM,
1055     format     => DATEV_FORMAT_KNE,
1056     accnofrom  => $start_account_number,
1057     accnoto    => $end_account_number,
1058   );
1059
1060   # get or set datev stamm
1061   my $hashref = $datev->get_datev_stamm;
1062   $datev->save_datev_stamm($hashref);
1063
1064   # manually clean up temporary directories
1065   $datev->clean_temporary_directories;
1066
1067   # export
1068   $datev->export;
1069
1070   if ($datev->errors) {
1071     die join "\n", $datev->error;
1072   }
1073
1074   # get relevant data for saving the export:
1075   my $dl_token = $datev->download_token;
1076   my $path     = $datev->export_path;
1077   my @files    = $datev->filenames;
1078
1079   # retrieving an export at a later time
1080   my $datev = SL::DATEV->new(
1081     download_token => $dl_token_from_user,
1082   );
1083
1084   my $path     = $datev->export_path;
1085   my @files    = glob("$path/*");
1086
1087 =head1 DESCRIPTION
1088
1089 This module implements the DATEV export standard. For usage see above.
1090
1091 =head1 FUNCTIONS
1092
1093 =over 4
1094
1095 =item new PARAMS
1096
1097 Generic constructor. See section attributes for information about hat to pass.
1098
1099 =item get_datev_stamm
1100
1101 Loads DATEV Stammdaten and returns as hashref.
1102
1103 =item save_datev_stamm HASHREF
1104
1105 Saves DATEV Stammdaten from provided hashref.
1106
1107 =item exporttype
1108
1109 See L<CONSTANTS> for possible values
1110
1111 =item has_exporttype
1112
1113 Returns true if an exporttype has been set. Without exporttype most report functions won't work.
1114
1115 =item format
1116
1117 Specifies the designated format of the export. Currently only KNE export is implemented.
1118
1119 See L<CONSTANTS> for possible values
1120
1121 =item has_format
1122
1123 Returns true if a format has been set. Without format most report functions won't work.
1124
1125 =item download_token
1126
1127 Returns a download token for this DATEV object.
1128
1129 Note: If either a download_token or export_path were set at the creation these are infered, otherwise randomly generated.
1130
1131 =item export_path
1132
1133 Returns an export_path for this DATEV object.
1134
1135 Note: If either a download_token or export_path were set at the creation these are infered, otherwise randomly generated.
1136
1137 =item filenames
1138
1139 Returns a list of filenames generated by this DATEV object. This only works if th files were generated during it's lifetime, not if the object was created from a download_token.
1140
1141 =item net_gross_differences
1142
1143 If there were any net gross differences during calculation they will be collected here.
1144
1145 =item sum_net_gross_differences
1146
1147 Sum of all differences.
1148
1149 =item clean_temporary_directories
1150
1151 Forces a garbage collection on previous exports which will delete all exports that are older than 8 hours. It will be automatically called on destruction of the object, but is advised to be called manually before delivering results of an export to the user.
1152
1153 =item errors
1154
1155 Returns a list of errors that occured. If no errors occured, the export was a success.
1156
1157 =item export
1158
1159 Exports data. You have to have set L<exporttype> and L<format> or an error will
1160 occur. OBE exports are currently not implemented.
1161
1162 =back
1163
1164 =head1 ATTRIBUTES
1165
1166 This is a list of attributes set in either the C<new> or a method of the same name.
1167
1168 =over 4
1169
1170 =item dbh
1171
1172 Set a database handle to use in the process. This allows for an export to be
1173 done on a transaction in progress without committing first.
1174
1175 =item exporttype
1176
1177 See L<CONSTANTS> for possible values. This MUST be set before export is called.
1178
1179 =item format
1180
1181 See L<CONSTANTS> for possible values. This MUST be set before export is called.
1182
1183 =item download_token
1184
1185 Can be set on creation to retrieve a prior export for download.
1186
1187 =item from
1188
1189 =item to
1190
1191 Set boundary dates for the export. Currently thse MUST be set for the export to work.
1192
1193 =item accnofrom
1194
1195 =item accnoto
1196
1197 Set boundary account numbers for the export. Only useful for a stammdaten export.
1198
1199 =back
1200
1201 =head1 CONSTANTS
1202
1203 =head2 Supplied to L<exporttype>
1204
1205 =over 4
1206
1207 =item DATEV_ET_BUCHUNGEN
1208
1209 =item DATEV_ET_STAMM
1210
1211 =back
1212
1213 =head2 Supplied to L<format>.
1214
1215 =over 4
1216
1217 =item DATEV_FORMAT_KNE
1218
1219 =item DATEV_FORMAT_OBE
1220
1221 =back
1222
1223 =head1 ERROR HANDLING
1224
1225 This module will die in the following cases:
1226
1227 =over 4
1228
1229 =item *
1230
1231 No or unrecognized exporttype or format was provided for an export
1232
1233 =item *
1234
1235 OBE rxport was called, which is not yet implemented.
1236
1237 =item *
1238
1239 general I/O errors
1240
1241 =back
1242
1243 Errors that occur during th actual export will be collected in L<errors>. The following types can occur at the moment:
1244
1245 =over 4
1246
1247 =item *
1248
1249 C<Unbalanced Ledger!>. Exactly that, your ledger is unbalanced. Should never occur.
1250
1251 =item *
1252
1253 C<Datev-Export fehlgeschlagen! Bei Transaktion %d (%f).>  This error occurs if a
1254 transaction could not be reliably sorted out, or had rounding errors over the acceptable threshold.
1255
1256 =back
1257
1258 =head1 BUGS AND CAVEATS
1259
1260 =over 4
1261
1262 =item *
1263
1264 Handling of Vollvorlauf is currently not fully implemented. You must provide both from and to to get a working export.
1265
1266 =item *
1267
1268 OBE export is currently not implemented.
1269
1270 =back
1271
1272 =head1 TODO
1273
1274 - handling of export_path and download token is a bit dodgy, clean that up.
1275
1276 =head1 SEE ALSO
1277
1278 L<SL::DATEV::KNEFile>
1279
1280 =head1 AUTHORS
1281
1282 Philip Reetz E<lt>p.reetz@linet-services.deE<gt>,
1283
1284 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>,
1285
1286 Jan Büren E<lt>jan@lx-office-hosting.deE<gt>,
1287
1288 Geoffrey Richardson E<lt>information@lx-office-hosting.deE<gt>,
1289
1290 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>,
1291
1292 Stephan Köhler
1293
1294 =cut