SL/Controller/ClientConfig.pm

   1 package SL::Controller::ClientConfig;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use File::Copy::Recursive ();
   7 use List::Util qw(first);
   8
   9 use SL::DB::Chart;
  10 use SL::DB::Currency;
  11 use SL::DB::Default;
  12 use SL::DB::Language;
  13 use SL::DB::Part;
  14 use SL::DB::Unit;
  15 use SL::Helper::Flash;
  16 use SL::Locale::String qw(t8);
  17 use SL::PriceSource::ALL;
  18 use SL::Template;
  19
  20 __PACKAGE__->run_before('check_auth');
  21
  22 use Rose::Object::MakeMethods::Generic (
  23   'scalar --get_set_init' => [ qw(defaults all_warehouses all_weightunits all_languages all_currencies all_templates all_price_sources h_unit_name
  24                                   all_project_statuses all_project_types
  25                                   posting_options payment_options accounting_options inventory_options profit_options balance_startdate_method_options) ],
  26 );
  27
  28 sub action_edit {
  29   my ($self, %params) = @_;
  30
  31   $::form->{use_templates} = $self->defaults->templates ? 'existing' : 'new';
  32   $self->edit_form;
  33 }
  34
  35 sub action_save {
  36   my ($self, %params)      = @_;
  37
  38   my $defaults             = delete($::form->{defaults}) || {};
  39   my $entered_currencies   = delete($::form->{currencies}) || [];
  40   my $original_currency_id = $self->defaults->currency_id;
  41   $defaults->{disabled_price_sources} ||= [];
  42
  43   # undef several fields if an empty value has been selected.
  44   foreach (qw(warehouse_id bin_id warehouse_id_ignore_onhand bin_id_ignore_onhand)) {
  45     undef $defaults->{$_} if !$defaults->{$_};
  46   }
  47
  48   $defaults->{$_} = $::form->parse_amount(\%::myconfig, $defaults->{$_}) for qw(customer_hourly_rate);
  49
  50   $self->defaults->assign_attributes(%{ $defaults });
  51
  52   my %errors_idx;
  53
  54   # Handle currencies
  55   my (%new_currency_names);
  56   foreach my $existing_currency (@{ $self->all_currencies }) {
  57     my $new_name     = $existing_currency->name;
  58     my $new_currency = first { $_->{id} == $existing_currency->id } @{ $entered_currencies };
  59     $new_name        = $new_currency->{name} if $new_currency;
  60
  61     if (!$new_name) {
  62       $errors_idx{0} = t8('Currency names must not be empty.');
  63     } elsif ($new_currency_names{$new_name}) {
  64       $errors_idx{1} = t8('Currency names must be unique.');
  65     }
  66
  67     if ($new_name) {
  68       $new_currency_names{$new_name} = 1;
  69       $existing_currency->name($new_name);
  70     }
  71   }
  72
  73   if ($::form->{new_currency} && $new_currency_names{ $::form->{new_currency} }) {
  74     $errors_idx{1} = t8('Currency names must be unique.');
  75   }
  76
  77   my @errors = map { $errors_idx{$_} } sort keys %errors_idx;
  78
  79   # Check templates
  80   $::form->{new_templates}        =~ s:/::g;
  81   $::form->{new_master_templates} =~ s:/::g;
  82
  83   if (($::form->{use_templates} eq 'existing') && ($self->defaults->templates !~ m:^templates/[^/]+$:)) {
  84     push @errors, t8('You must select existing print templates or create a new set.');
  85
  86   } elsif ($::form->{use_templates} eq 'new') {
  87     if (!$::form->{new_templates}) {
  88       push @errors, t8('You must enter a name for your new print templates.');
  89     } elsif (-d "templates/" . $::form->{new_templates}) {
  90       push @errors, t8('A directory with the name for the new print templates exists already.');
  91     } elsif (! -d "templates/print/" . $::form->{new_master_templates}) {
  92       push @errors, t8('The master templates where not found.');
  93     }
  94   }
  95
  96   # Show form again if there were any errors. Nothing's been changed
  97   # yet in the database.
  98   if (@errors) {
  99     flash('error', @errors);
 100     return $self->edit_form;
 101   }
 102
 103   # Save currencies. As the names must be unique we cannot simply save
 104   # them as they are -- the user might want to swap to names. So make
 105   # them unique first and assign the actual names in a second step.
 106   my %currency_names_by_id = map { ($_->id => $_->name) } @{ $self->all_currencies };
 107   $_->update_attributes(name => '__039519735__' . $_->{id})        for @{ $self->all_currencies };
 108   $_->update_attributes(name => $currency_names_by_id{ $_->{id} }) for @{ $self->all_currencies };
 109
 110   # Create new currency if required
 111   my $new_currency;
 112   if ($::form->{new_currency}) {
 113     $new_currency = SL::DB::Currency->new(name => $::form->{new_currency});
 114     $new_currency->save;
 115   }
 116
 117   # If the user wants the new currency to be the default then replace
 118   # the ID placeholder with the proper value. However, if no new
 119   # currency has been created then don't change the value at all.
 120   if (-1 == $self->defaults->currency_id) {
 121     $self->defaults->currency_id($new_currency ? $new_currency->id : $original_currency_id);
 122   }
 123
 124   # Create new templates if requested.
 125   if ($::form->{use_templates} eq 'new') {
 126     local $File::Copy::Recursive::SkipFlop = 1;
 127     File::Copy::Recursive::dircopy('templates/print/' . $::form->{new_master_templates}, 'templates/' . $::form->{new_templates});
 128     $self->defaults->templates('templates/' . $::form->{new_templates});
 129   }
 130
 131   # Finally save defaults.
 132   $self->defaults->save;
 133
 134   flash_later('info', t8('Client Configuration saved!'));
 135
 136   $self->redirect_to(action => 'edit');
 137 }
 138
 139 #
 140 # initializers
 141 #
 142
 143 sub init_defaults        { SL::DB::Default->get                                                                          }
 144 sub init_all_warehouses  { SL::DB::Manager::Warehouse->get_all_sorted                                                    }
 145 sub init_all_languages   { SL::DB::Manager::Language->get_all_sorted                                                     }
 146 sub init_all_currencies  { SL::DB::Manager::Currency->get_all_sorted                                                     }
 147 sub init_all_weightunits { my $unit = SL::DB::Manager::Unit->find_by(name => 'kg'); $unit ? $unit->convertible_units : [] }
 148 sub init_all_templates   { +{ SL::Template->available_templates }                                                        }
 149 sub init_h_unit_name     { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde)                         };
 150 sub init_all_project_types    { SL::DB::Manager::ProjectType->get_all_sorted                                             }
 151 sub init_all_project_statuses { SL::DB::Manager::ProjectStatus->get_all_sorted                                           }
 152
 153 sub init_posting_options {
 154   [ { title => t8("never"),           value => 0           },
 155     { title => t8("every time"),      value => 1           },
 156     { title => t8("on the same day"), value => 2           }, ]
 157 }
 158
 159 sub init_payment_options {
 160   [ { title => t8("never"),           value => 0           },
 161     { title => t8("every time"),      value => 1           },
 162     { title => t8("on the same day"), value => 2           }, ]
 163 }
 164
 165 sub init_accounting_options {
 166   [ { title => t8("Accrual"),         value => "accrual"   },
 167     { title => t8("cash"),            value => "cash"      }, ]
 168 }
 169
 170 sub init_inventory_options {
 171   [ { title => t8("perpetual"),       value => "perpetual" },
 172     { title => t8("periodic"),        value => "periodic"  }, ]
 173 }
 174
 175 sub init_profit_options {
 176   [ { title => t8("balance"),         value => "balance"   },
 177     { title => t8("income"),          value => "income"    }, ]
 178 }
 179
 180 sub init_balance_startdate_method_options {
 181   [ { title => t8("After closed period"),                       value => "closed_to"                   },
 182     { title => t8("Start of year"),                             value => "start_of_year"               },
 183     { title => t8("All transactions"),                          value => "all_transactions"            },
 184     { title => t8("Last opening balance or all transactions"),  value => "last_ob_or_all_transactions" },
 185     { title => t8("Last opening balance or start of year"),     value => "last_ob_or_start_of_year"    }, ]
 186 }
 187
 188 sub init_all_price_sources {
 189   my @classes = SL::PriceSource::ALL->all_price_sources;
 190
 191   [ map { [ $_->name, $_->description ] } @classes ];
 192 }
 193
 194 #
 195 # filters
 196 #
 197
 198 sub check_auth {
 199   $::auth->assert('admin');
 200 }
 201
 202 #
 203 # helpers
 204 #
 205
 206 sub edit_form {
 207   my ($self) = @_;
 208
 209   $::request->layout->use_javascript("${_}.js") for qw(jquery.selectboxes jquery.multiselect2side);
 210
 211   $self->render('client_config/form', title => t8('Client Configuration'),
 212                 make_chart_title     => sub { $_[0]->accno . '--' . $_[0]->description },
 213                 make_templates_value => sub { 'templates/' . $_[0] },
 214               );
 215 }
 216
 217 1;