SL/Controller/FinancialControllingReport.pm

   1 package SL::Controller::FinancialControllingReport;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use List::Util qw(sum);
   7
   8 use SL::DB::Order;
   9 use SL::DB::ProjectType;
  10 use SL::Controller::Helper::GetModels;
  11 use SL::Controller::Helper::ReportGenerator;
  12 use SL::Locale::String;
  13
  14 use Rose::Object::MakeMethods::Generic (
  15   scalar => [ qw(project_types) ],
  16   'scalar --get_set_init' => [ qw(models) ],
  17 );
  18
  19 __PACKAGE__->run_before(sub { $::auth->assert('sales_order_edit'); });
  20
  21 my %sort_columns = (
  22   ordnumber               => t8('Order'),
  23   customer                => t8('Customer'),
  24   transaction_description => t8('Transaction description'),
  25   globalprojectnumber     => t8('Project'),
  26   globalproject_type      => t8('Project Type'),
  27 );
  28
  29 sub action_list {
  30   my ($self) = @_;
  31
  32   $self->project_types(SL::DB::Manager::ProjectType->get_all_sorted);
  33
  34   $self->make_filter_summary;
  35
  36   $self->prepare_report;
  37
  38   $self->{orders} = $self->models->get;
  39
  40   $self->calculate_data;
  41
  42   $self->list_objects;
  43 }
  44
  45 # private functions
  46
  47 sub prepare_report {
  48   my ($self)      = @_;
  49
  50   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  51   $self->{report} = $report;
  52
  53   my @columns     = qw(customer globalprojectnumber globalproject_type ordnumber net_amount delivered_amount delivered_amount_p billed_amount billed_amount_p paid_amount paid_amount_p
  54                        billable_amount billable_amount_p other_amount);
  55   my @sortable    = qw(ordnumber transdate customer globalprojectnumber globalproject_type);
  56   $self->{number_columns} = [ qw(net_amount billed_amount billed_amount_p delivered_amount delivered_amount_p paid_amount paid_amount_p other_amount billable_amount billable_amount_p) ];
  57
  58   my %column_defs           = (
  59     net_amount              => { text     => $::locale->text('Order amount')                                             },
  60     billed_amount           => { text     => $::locale->text('Billed amount')                                            },
  61     billed_amount_p         => { text     => $::locale->text('%')                                                        },
  62     delivered_amount        => { text     => $::locale->text('Delivered amount')                                         },
  63     delivered_amount_p      => { text     => $::locale->text('%')                                                        },
  64     paid_amount             => { text     => $::locale->text('Paid amount')                                              },
  65     paid_amount_p           => { text     => $::locale->text('%')                                                        },
  66     billable_amount         => { text     => $::locale->text('Billable amount')                                          },
  67     billable_amount_p       => { text     => $::locale->text('%')                                                        },
  68     other_amount            => { text     => $::locale->text('Billed extra expenses')                                    },
  69     ordnumber               => { obj_link => sub { $self->link_to($_[0])                                              }  },
  70     customer                => {      sub => sub { $_[0]->customer->name                                              },
  71                                  obj_link => sub { $self->link_to($_[0]->customer)                                    }  },
  72     globalprojectnumber     => {      sub => sub { $_[0]->globalproject_id ? $_[0]->globalproject->projectnumber : '' },
  73                                  obj_link => sub { $self->link_to($_[0]->globalproject)                               }  },
  74     globalproject_type      => { text     => $::locale->text('Project type'),
  75                                  sub      => sub { $_[0]->globalproject_id ? $_[0]->globalproject->project_type->description : '' }  },
  76   );
  77
  78   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
  79   map { $column_defs{$_}->{align} = 'right' } @{ $self->{number_columns} };
  80
  81   $report->set_options(
  82     std_column_visibility => 1,
  83     controller_class      => 'FinancialControllingReport',
  84     output_format         => 'HTML',
  85     top_info_text         => $::locale->text('Financial controlling report for open sales orders'),
  86     title                 => $::locale->text('Financial Controlling Report'),
  87     allow_pdf_export      => 1,
  88     allow_csv_export      => 1,
  89   );
  90   $report->set_columns(%column_defs);
  91   $report->set_column_order(@columns);
  92   $report->set_export_options(qw(list filter));
  93   $report->set_options_from_form;
  94   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
  95   $self->models->finalize;
  96   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
  97   $report->set_options(
  98     raw_top_info_text     => $self->render('financial_controlling_report/report_top',    { output => 0 }),
  99     raw_bottom_info_text  => $self->render('financial_controlling_report/report_bottom', { output => 0 }, models => $self->models),
 100   );
 101 }
 102
 103 sub calculate_data {
 104   my ($self) = @_;
 105
 106   foreach my $order (@{ $self->{orders} }) {
 107     my @delivery_orders = @{ $order->linked_records(direction => 'to', to => 'DeliveryOrder', via => 'Order', query => [ '!customer_id' => undef ]) };
 108     my @invoices        = @{ $order->linked_records(direction => 'to', to => 'Invoice',       via => [ 'Order', 'DeliveryOrder' ])                  };
 109
 110     @invoices = (
 111       grep({ !$_->storno_id } @invoices),
 112       map({ @{ $_->storno_invoices } } grep { $_->storno && !$_->storno_id } @invoices),
 113     );
 114
 115     $order->{delivered_amount}  = sum map { $self->sum_relevant_items(order => $order, other => $_, by_order => 1)    } @delivery_orders;
 116     $order->{billed_amount}     = sum map { $self->sum_relevant_items(order => $order, other => $_)                   } @invoices;
 117     $order->{paid_amount}       = sum map { $_->paid * $_->netamount / (($_->amount * 1) || ($_->netamount * 1) || 1) } @invoices;
 118     my $billed_amount           = sum map { $_->netamount                                                             } @invoices;
 119     $order->{other_amount}      = $billed_amount             - $order->{billed_amount};
 120     $order->{billable_amount}   = $order->{delivered_amount} - $order->{billed_amount};
 121
 122     if ($order->periodic_invoices_config) {
 123       my @dates = $order->periodic_invoices_config->calculate_invoice_dates(past_dates => 1, end_date => $order->periodic_invoices_config->end_date || DateTime->today_local);
 124       $order->{net_amount} = $order->netamount * scalar(@dates);
 125
 126     } else {
 127       $order->{net_amount} = $order->netamount;
 128     }
 129
 130     foreach (qw(delivered billed paid billable)) {
 131       $order->{"${_}_amount_p"} = $order->{net_amount} * 1 ? $order->{"${_}_amount"} * 100 / $order->{net_amount} : undef;
 132     }
 133   }
 134 }
 135
 136 sub sum_items {
 137   my ($self, %params) = @_;
 138
 139   my %vals;
 140
 141   foreach my $item (@{ $params{obj}->items }) {
 142     my $key  = $item->parts_id;
 143     $key    .= ':' . $item->serialnumber if $item->serialnumber;
 144
 145     $vals{$key}            ||= { parts_id => $item->parts_id, serialnumber => $item->serialnumber, amount => 0, base_qty => 0 };
 146     $vals{$key}->{amount}   += $item->qty * $item->sellprice * (1 - $item->discount) / (($item->price_factor * 1) || 1);
 147     $vals{$key}->{base_qty} += $item->qty * $item->unit_obj->base_factor;
 148   }
 149
 150   return \%vals;
 151 }
 152
 153 sub sum_relevant_items {
 154   my ($self, %params) = @_;
 155
 156   $params{order}->{amounts_by_parts_id} ||= $self->sum_items(obj => $params{order});
 157   my $sums                                = $self->sum_items(obj => $params{other});
 158   my $total                               = 0;
 159
 160   foreach my $item (grep { $params{order}->{amounts_by_parts_id}->{ $_->{parts_id} } } values %{ $sums }) {
 161     my $key = $item->{parts_id};
 162
 163     if ($params{by_order}) {
 164       $key           .= ':' . $item->{serialnumber};
 165       my $order_item  = $params{order}->{amounts_by_parts_id}->{ $key } || $params{order}->{amounts_by_parts_id}->{ $item->{parts_id} };
 166
 167       if ($order_item && $order_item->{base_qty}) {
 168         $total += $order_item->{amount} * $item->{base_qty} / $order_item->{base_qty};
 169         next;
 170       }
 171     }
 172
 173     $total += $item->{amount};
 174   }
 175
 176   return $total;
 177 }
 178
 179 sub list_objects {
 180   my ($self)      = @_;
 181   my $modify_data = sub {
 182     my ($data) = @_;
 183     map { $data->{$_}->{data} = defined $data->{$_}->{data} ? int($data->{$_}->{data}) : ''  } grep {  m/_p$/ } @{ $self->{number_columns} };
 184     map { $data->{$_}->{data} = $::form->format_amount(\%::myconfig, $data->{$_}->{data}, 2) } grep { !m/_p$/ } @{ $self->{number_columns} };
 185   };
 186
 187   return $self->report_generator_list_objects(report => $self->{report}, objects => $self->{orders}, data_callback => $modify_data);
 188 }
 189
 190 sub make_filter_summary {
 191   my ($self) = @_;
 192
 193   my $filter = $::form->{filter} || {};
 194   my @filter_strings;
 195
 196   my @filters = (
 197     [ $filter->{"ordnumber:substr::ilike"},                $::locale->text('Number')                                          ],
 198     [ $filter->{"transdate:date::ge"},                     $::locale->text('Order Date') . " " . $::locale->text('From Date') ],
 199     [ $filter->{"transdate:date::le"},                     $::locale->text('Order Date') . " " . $::locale->text('To Date')   ],
 200     [ $filter->{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                        ],
 201     [ $filter->{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                 ],
 202   );
 203
 204   $self->{filter_summary} = join ', ', @filter_strings;
 205 }
 206
 207 sub init_models {
 208   my ($self) = @_;
 209
 210   SL::Controller::Helper::GetModels->new(
 211     controller   => $self,
 212     model        => 'Order',
 213     sorted       => {
 214       _default     => {
 215         by           => 'globalprojectnumber',
 216         dir          => 1,
 217       },
 218       %sort_columns,
 219     },
 220     query => [
 221       SL::DB::Manager::Order->type_filter('sales_order'),
 222       '!closed' => 1,
 223       or        => [
 224         globalproject_id => undef,
 225         and              => [
 226           'globalproject.active' => 1,
 227           'globalproject.valid'  => 1,
 228         ]],
 229       # keine WR
 230       # oder aber (WR aktiv und (kein enddatum oder enddatum noch nicht überschritten))
 231       or => [
 232         'periodic_invoices_config.id' => undef,
 233         # and => [
 234           'periodic_invoices_config.active' => 1,
 235         #   or => [
 236         #     'periodic_invoices_config.end_date' => undef,
 237         #     'periodic_invoices_config.end_date' => { le => DateTime->today_local },
 238         # ]
 239         # ]
 240       ],
 241     ],
 242     with_objects => [ 'customer', 'globalproject', 'globalproject.project_type', 'periodic_invoices_config' ],
 243   );
 244 }
 245
 246 sub link_to {
 247   my ($self, $object, %params) = @_;
 248
 249   return unless $object;
 250   my $action = $params{action} || 'edit';
 251
 252   if ($object->isa('SL::DB::Order')) {
 253     my $type = $object->type;
 254     my $id   = $object->id;
 255
 256     return "oe.pl?action=$action&type=$type&vc=customer&id=$id";
 257   }
 258   if ($object->isa('SL::DB::Customer')) {
 259     my $id     = $object->id;
 260     return "controller.pl?action=CustomerVendor/$action&id=$id";
 261   }
 262   if ($object->isa('SL::DB::Project')) {
 263     my $id     = $object->id;
 264     return "controller.pl?action=Project/$action&id=$id";
 265   }
 266 }
 267
 268 1;