SL/Presenter/CustomerVendor.pm

   1 package SL::Presenter::CustomerVendor;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6
   7 use Exporter qw(import);
   8 our @EXPORT = qw(customer vendor customer_vendor_picker);
   9
  10 use Carp;
  11
  12 sub customer {
  13   my ($self, $customer, %params) = @_;
  14   return _customer_vendor($self, $customer, 'customer', %params);
  15 }
  16
  17 sub vendor {
  18   my ($self, $vendor, %params) = @_;
  19   return _customer_vendor($self, $vendor, 'vendor', %params);
  20 }
  21
  22 sub _customer_vendor {
  23   my ($self, $cv, $type, %params) = @_;
  24
  25   $params{display} ||= 'inline';
  26
  27   croak "Unknown display type '$params{display}'" unless $params{display} =~ m/^(?:inline|table-cell)$/;
  28
  29   my $callback = $params{callback} ? '&callback=' . $::form->escape($params{callback}) : '';
  30
  31   my $text = join '', (
  32     $params{no_link} ? '' : '<a href="controller.pl?action=CustomerVendor/edit&amp;db=' . $type . '&amp;id=' . $self->escape($cv->id) . '">',
  33     $self->escape($cv->name),
  34     $params{no_link} ? '' : '</a>',
  35   );
  36   return $self->escaped_text($text);
  37 }
  38
  39 sub customer_vendor_picker {
  40   my ($self, $name, $value, %params) = @_;
  41
  42   croak 'Unknown "type" parameter' unless $params{type} =~ m{^(?:customer|vendor)$};
  43   croak 'Unknown value class'      if     $value && ref($value) && (ref($value) !~ m{^SL::DB::(?:Customer|Vendor)$});
  44
  45   if ($value && !ref $value) {
  46     my $class = $params{type} eq 'customer' ? 'SL::DB::Manager::Customer' : 'SL::DB::Manager::Vendor';
  47     $value    = $class->find_by(id => $value);
  48   }
  49
  50   my $id = delete($params{id}) || $self->name_to_id($name);
  51   my $fat_set_item = delete $params{fat_set_item};
  52
  53   my @classes = $params{class} ? ($params{class}) : ();
  54   push @classes, 'customer_vendor_autocomplete';
  55   push @classes, 'customer-vendor-picker-fat-set-item' if $fat_set_item;
  56
  57   my $ret =
  58     $self->input_tag($name, (ref $value && $value->can('id') ? $value->id : ''), class => "@classes", type => 'hidden', id => $id) .
  59     join('', map { $params{$_} ? $self->input_tag("", delete $params{$_}, id => "${id}_${_}", type => 'hidden') : '' } qw(type)) .
  60     $self->input_tag("", (ref $value && $value->can('name')) ? $value->name : '', id => "${id}_name", %params);
  61
  62   $::request->presenter->need_reinit_widgets($id);
  63
  64   $self->html_tag('span', $ret, class => 'customer_vendor_picker');
  65 }
  66
  67 1;
  68
  69 __END__
  70
  71 =pod
  72
  73 =encoding utf8
  74
  75 =head1 NAME
  76
  77 SL::Presenter::CustomerVendor - Presenter module for customer and
  78 vendor Rose::DB objects
  79
  80 =head1 SYNOPSIS
  81
  82   # Customers:
  83   my $customer = SL::DB::Manager::Customer->get_first;
  84   my $html     = SL::Presenter->get->customer($customer, display => 'inline');
  85
  86   # Vendors:
  87   my $vendor = SL::DB::Manager::Vendor->get_first;
  88   my $html   = SL::Presenter->get->vendor($customer, display => 'inline');
  89
  90 =head1 FUNCTIONS
  91
  92 =over 4
  93
  94 =item C<customer $object, %params>
  95
  96 Returns a rendered version (actually an instance of
  97 L<SL::Presenter::EscapedText>) of the customer object C<$object>.
  98
  99 C<%params> can include:
 100
 101 =over 2
 102
 103 =item * display
 104
 105 Either C<inline> (the default) or C<table-cell>. At the moment both
 106 representations are identical and produce the customer's name linked
 107 to the corresponding 'edit' action.
 108
 109 =item * no_link
 110
 111 If falsish (the default) then the customer's name will be linked to
 112 the "edit customer" dialog from the master data menu.
 113
 114 =back
 115
 116 =item C<vendor $object, %params>
 117
 118 Returns a rendered version (actually an instance of
 119 L<SL::Presenter::EscapedText>) of the vendor object C<$object>.
 120
 121 C<%params> can include:
 122
 123 =over 2
 124
 125 =item * display
 126
 127 Either C<inline> (the default) or C<table-cell>. At the moment both
 128 representations are identical and produce the vendor's name linked
 129 to the corresponding 'edit' action.
 130
 131 =item * no_link
 132
 133 If falsish (the default) then the vendor's name will be linked to
 134 the "edit vendor" dialog from the master data menu.
 135
 136 =back
 137
 138 =back
 139
 140 =head1 BUGS
 141
 142 Nothing here yet.
 143
 144 =head1 AUTHOR
 145
 146 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 147
 148 =cut