SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::ReportGenerator;
  10 use SL::Locale::String;
  11 use Carp;
  12
  13 use Rose::Object::MakeMethods::Generic (
  14   scalar => [ qw(db_args flat_filter) ],
  15   'scalar --get_set_init' => [ qw(models all_edit_right mode vc) ],
  16 );
  17
  18 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  19
  20 my %sort_columns = (
  21   reqdate           => t8('Reqdate'),
  22   description       => t8('Description'),
  23   partnumber        => t8('Part Number'),
  24   qty               => t8('Qty'),
  25   unit              => t8('Unit'),
  26   shipped_qty       => t8('shipped'),
  27   delivered_qty     => t8('transferred in / out'),
  28   not_shipped_qty   => t8('not shipped'),
  29   ordnumber         => t8('Order'),
  30   customer          => t8('Customer'),
  31   vendor            => t8('Vendor'),
  32   value_of_goods    => t8('Value of transferred goods'),
  33 );
  34
  35
  36 sub action_list {
  37   my ($self) = @_;
  38   $self->make_filter_summary;
  39   $self->prepare_report;
  40
  41   my $orderitems = $self->models->get;
  42
  43   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  44 }
  45
  46 # private functions
  47 #
  48 sub prepare_report {
  49   my ($self)      = @_;
  50
  51   my $vc          = $self->vc;
  52   my $mode        = $self->mode;
  53   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  54   my $csv_option  = $::form->{report_generator_output_format};
  55   $self->{report} = $report;
  56
  57   my @columns     = qw(reqdate customer vendor ordnumber partnumber description qty shipped_qty not_shipped_qty delivered_qty value_of_goods);
  58
  59   my @sortable    = qw(reqdate customer vendor ordnumber partnumber description);
  60   my $rp_csv_mod  = ($csv_option eq 'CSV' && $mode eq 'delivery_value_report') ? 1 : '';
  61
  62   my %column_defs = (
  63     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  64     description       => {      sub => sub { $_[0]->description                                                              },
  65                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  66     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  67                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  68     qty               => {      sub => sub { $_[0]->qty_as_number .
  69                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  70     unit              => {      sub => sub {  $_[0]->unit                                                                    },
  71                             visible => $rp_csv_mod                                                                           },
  72     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) .
  73                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  74     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]->shipped_qty, 2) .
  75                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  76     delivered_qty     => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->delivered_qty, 2) .
  77                                              ($rp_csv_mod ? '' : ' ' .  $_[0]->unit)                                         } },
  78     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  79                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  80     vendor            => {      sub => sub { $_[0]->order->vendor->name                                                      },
  81                             visible => $vc eq 'vendor',
  82                            obj_link => sub { $self->link_to($_[0]->order->vendor)                                            } },
  83     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  84                             visible => $vc eq 'customer',
  85                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  86     value_of_goods    => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->value_of_goods, 2) . ' ' . $_[0]->taxincluded },
  87                             visible => $::auth->assert('sales_order_edit', 1) && $mode eq 'delivery_value_report' &&   $::instance_conf->get_delivery_plan_show_value_of_goods, },
  88   );
  89
  90   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  91
  92   $report->set_options(
  93     std_column_visibility => 1,
  94     controller_class      => 'DeliveryPlan',
  95     output_format         => 'HTML',
  96     top_info_text         => ($vc eq 'customer') ?  (($mode eq 'delivery_plan') ? $::locale->text('Delivery Plan for currently outstanding sales orders') :
  97                                                    $::locale->text('Delivery Value Report for currently open sales orders')) :
  98                                                    ($mode eq 'delivery_value_report') ? $::locale->text('Delivery Value Report for currently outstanding purchase orders') :
  99                                                    $::locale->text('Delivery Plan for currently outstanding purchase orders'),
 100     title                 => ($mode eq 'delivery_plan') ? $::locale->text('Delivery Plan') : $::locale->text('Delivery Value Report'),
 101     allow_pdf_export      => 1,
 102     allow_csv_export      => 1,
 103   );
 104   $report->set_columns(%column_defs);
 105   $report->set_column_order(@columns);
 106   $report->set_export_options(qw(list filter vc mode));
 107   $report->set_options_from_form;
 108   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 109   $self->models->finalize; # for filter laundering
 110   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 111   $report->set_options(
 112     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
 113     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
 114   );
 115 }
 116
 117 sub make_filter_summary {
 118   my ($self) = @_;
 119   my $vc     = $self->vc;
 120   my $mode   = $self->mode;
 121
 122   my $filter = $::form->{filter} || {};
 123   my @filter_strings;
 124
 125   my @filters = (
 126     [ $filter->{order}{"ordnumber:substr::ilike"},                $::locale->text('Number')                                             ],
 127     [ $filter->{part}{"partnumber:substr::ilike"},                $::locale->text('Part Number')                                        ],
 128     [ $filter->{"description:substr::ilike"},                     $::locale->text('Part Description')                                   ],
 129     [ $filter->{"reqdate:date::ge"},                              $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 130     [ $filter->{"reqdate:date::le"},                              $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 131     [ $filter->{"qty:number"},                                    $::locale->text('Quantity')                                           ],
 132     [ $filter->{order}{vendor}{"name:substr::ilike"},             $::locale->text('Vendor')                                             ],
 133     [ $filter->{order}{vendor}{"vendornumber:substr::ilike"},     $::locale->text('Vendor Number')                                      ],
 134     [ $filter->{order}{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                           ],
 135     [ $filter->{order}{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                    ],
 136   );
 137
 138   my %flags = (
 139     part     => $::locale->text('Parts'),
 140     service  => $::locale->text('Services'),
 141     assembly => $::locale->text('Assemblies'),
 142   );
 143   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 144
 145   for (@flags) {
 146     push @filter_strings, $_ if $_;
 147   }
 148   for (@filters) {
 149     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 150   }
 151
 152   $self->{filter_summary} = join ', ', @filter_strings;
 153 }
 154
 155 sub delivery_plan_query {
 156   my ($self) = @_;
 157   my $vc     = $self->vc;
 158   my $mode   = $self->mode;
 159   my $employee_id = SL::DB::Manager::Employee->current->id;
 160   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 161   # check delivered state for delivery_orders (transferred out) if enabled
 162   # OR if we are delivery_value_report mode
 163   my $filter_delivered = ($::instance_conf->get_delivery_plan_calculate_transferred_do ||
 164                           $mode eq 'delivery_value_report' ) ?
 165                           "AND (SELECT delivered from delivery_orders where id = doi.delivery_order_id)" : '';
 166   # Show ALL open orders in delivery_value_report mode
 167   my $comment_show_all_open_orders = ($mode eq 'delivery_value_report' ) ? "-- " : "";
 168   [
 169   "order.${vc}_id" => { gt => 0 },
 170   'order.closed' => 0,
 171   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 172
 173   # filter by shipped_qty < qty, read from innermost to outermost
 174   'id' => [ \"
 175     -- 3. resolve the desired information about those
 176     SELECT oi.id FROM (
 177       -- 2. slice only part, orderitem and both quantities from it
 178       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
 179         -- 1. join orderitems and deliverorder items via record_links.
 180         --    also add customer data to filter for sales_orders
 181         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
 182         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 183         WHERE
 184           oe.id = oi.trans_id AND
 185           oe.${vc}_id IS NOT NULL AND
 186           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 187           NOT oe.closed AND
 188           $oe_owner
 189           rl.from_id = oe.id AND
 190           rl.from_id = oi.trans_id AND
 191           oe.id = oi.trans_id AND
 192           rl.from_table = 'oe' AND
 193           rl.to_table = 'delivery_orders' AND
 194           rl.to_id = doi.delivery_order_id AND
 195           oi.parts_id = doi.parts_id
 196           $filter_delivered
 197       ) tuples GROUP BY parts_id, trans_id, qty
 198     ) partials
 199     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 200     WHERE oi.qty > doi_qty
 201
 202     UNION ALL
 203
 204     -- 4. since the join over record_links fails for sales_orders without any delivery order
 205     --    retrieve those without record_links at all
 206     SELECT oi.id FROM orderitems oi, oe
 207     WHERE
 208       oe.id = oi.trans_id AND
 209       oe.${vc}_id IS NOT NULL AND
 210       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 211       NOT oe.closed AND
 212       $oe_owner
 213       oi.trans_id NOT IN (
 214         SELECT from_id
 215         FROM record_links rl
 216         WHERE
 217           rl.from_table ='oe' AND
 218           rl.to_table = 'delivery_orders'
 219       )
 220
 221     UNION ALL
 222
 223     -- 5. now for the really nasty cases.
 224     --    If someone partially delivered an order in several delivery orders,
 225     --    there will be lots of record_links (4 doesn't catch those) but those
 226     --    won't have matching part_ids in delivery_order_items, so 1-3 can't
 227     --    find anything
 228     --    In this case aggreg record_links - delivery_order - delivery_order_items
 229     --    slice only oe.id, parts_id and sum of of qty
 230     --    left join that onto orderitems to get matching qtys in doi while retaining
 231     --    entrys without matches and then throw out those without record_links
 232     --    TODO: join this and 1-3 into a general case
 233                   -- need debug info? uncomment these:
 234     SELECT oi.id  -- ,oi.trans_id, oi.parts_id, coalesce(sum, 0), agg.parts_id
 235     FROM orderitems oi LEFT JOIN (
 236       SELECT rl.from_id as oid, doi.parts_id, sum(doi.qty) FROM (
 237         SELECT from_id, to_id
 238         FROM record_links rl
 239         LEFT JOIN oe ON oe.id = from_id
 240         WHERE
 241           rl.from_table = 'oe' AND
 242           rl.to_table = 'delivery_orders' AND
 243
 244           oe.${vc}_id IS NOT NULL AND
 245           $oe_owner
 246           (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 247       ) rl
 248       LEFT JOIN delivery_order_items doi ON (rl.to_id = doi.delivery_order_id)
 249       WHERE 1 = 1
 250       $filter_delivered
 251       GROUP BY rl.from_id, doi.parts_id
 252     ) agg ON (agg.oid = oi.trans_id AND agg.parts_id = oi.parts_id)
 253     LEFT JOIN oe ON oe.id = oi.trans_id
 254     WHERE
 255       EXISTS (
 256         SELECT to_id
 257         FROM record_links rl
 258         WHERE oi.trans_id = rl.from_id AND rl.from_table = 'oe' AND rl.to_table = 'delivery_orders'
 259       ) AND
 260       $comment_show_all_open_orders coalesce(sum, 0) < oi.qty AND
 261       oe.${vc}_id IS NOT NULL AND
 262       $oe_owner
 263       (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 264   " ],
 265   ]
 266 }
 267
 268 sub init_models {
 269   my ($self) = @_;
 270   my $vc     = $self->vc;
 271   my $mode   = $self->mode;
 272   SL::Controller::Helper::GetModels->new(
 273     controller            => $self,
 274     model                 => 'OrderItem',
 275     sorted                => {
 276       _default              => {
 277         by                    => 'reqdate',
 278         dir                   => 1,
 279       },
 280       %sort_columns,
 281     },
 282     query                 => $self->delivery_plan_query,
 283     with_objects          => [ 'order', "order.$vc", 'part' ],
 284     additional_url_params => { vc => $vc, mode => $mode},
 285   );
 286 }
 287
 288 sub init_all_edit_right {
 289   $::auth->assert('sales_all_edit', 1)
 290 }
 291 sub init_vc {
 292   return $::form->{vc} if ($::form->{vc} eq 'customer' || $::form->{vc} eq 'vendor') || croak "self (DeliveryPlan) has no vc defined";
 293 }
 294 sub init_mode {
 295   return $::form->{mode} if ($::form->{mode} eq 'delivery_value_report' || $::form->{mode} eq 'delivery_plan') || croak "self (DeliveryPlan) has no mode defined";
 296 }
 297
 298 sub link_to {
 299   my ($self, $object, %params) = @_;
 300
 301   return unless $object;
 302   my $action = $params{action} || 'edit';
 303
 304   if ($object->isa('SL::DB::Order')) {
 305     my $type   = $object->type;
 306     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 307     my $id     = $object->id;
 308
 309     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 310   }
 311   if ($object->isa('SL::DB::Part')) {
 312     my $id     = $object->id;
 313     return "ic.pl?action=$action&id=$id";
 314   }
 315   if ($object->isa('SL::DB::Customer')) {
 316     my $id     = $object->id;
 317     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 318   }
 319 }
 320
 321 1;