SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::Util qw(trim);
  14 use SL::YAML;
  15 use SL::DB::Order;
  16 use SL::DB::Default;
  17 use SL::DB::Unit;
  18 use SL::DB::Part;
  19 use SL::DB::PartsGroup;
  20 use SL::DB::Printer;
  21 use SL::DB::Language;
  22 use SL::DB::RecordLink;
  23
  24 use SL::Helper::CreatePDF qw(:all);
  25 use SL::Helper::PrintOptions;
  26 use SL::Helper::ShippedQty;
  27 use SL::Helper::UserPreferences::PositionsScrollbar;
  28
  29 use SL::Controller::Helper::GetModels;
  30
  31 use List::Util qw(first);
  32 use List::UtilsBy qw(sort_by uniq_by);
  33 use List::MoreUtils qw(any none pairwise first_index);
  34 use English qw(-no_match_vars);
  35 use File::Spec;
  36 use Cwd;
  37 use Sort::Naturally;
  38
  39 use Rose::Object::MakeMethods::Generic
  40 (
  41  scalar => [ qw(item_ids_to_delete) ],
  42  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors) ],
  43 );
  44
  45
  46 # safety
  47 __PACKAGE__->run_before('check_auth');
  48
  49 __PACKAGE__->run_before('recalc',
  50                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice print send_email) ]);
  51
  52 __PACKAGE__->run_before('get_unalterable_data',
  53                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice print send_email) ]);
  54
  55 #
  56 # actions
  57 #
  58
  59 # add a new order
  60 sub action_add {
  61   my ($self) = @_;
  62
  63   $self->order->transdate(DateTime->now_local());
  64   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  65                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  66   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  67
  68
  69   $self->pre_render();
  70   $self->render(
  71     'order/form',
  72     title => $self->get_title_for('add'),
  73     %{$self->{template_args}}
  74   );
  75 }
  76
  77 # edit an existing order
  78 sub action_edit {
  79   my ($self) = @_;
  80
  81   if ($::form->{id}) {
  82     $self->load_order;
  83
  84   } else {
  85     # this is to edit an order from an unsaved order object
  86
  87     # set item ids to new fake id, to identify them as new items
  88     foreach my $item (@{$self->order->items_sorted}) {
  89       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  90     }
  91     # trigger rendering values for second row/longdescription as hidden,
  92     # because they are loaded only on demand. So we need to keep the values
  93     # from the source.
  94     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
  95     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
  96   }
  97
  98   $self->recalc();
  99   $self->pre_render();
 100   $self->render(
 101     'order/form',
 102     title => $self->get_title_for('edit'),
 103     %{$self->{template_args}}
 104   );
 105 }
 106
 107 # edit a collective order (consisting of one or more existing orders)
 108 sub action_edit_collective {
 109   my ($self) = @_;
 110
 111   # collect order ids
 112   my @multi_ids = map {
 113     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 114   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 115
 116   # fall back to add if no ids are given
 117   if (scalar @multi_ids == 0) {
 118     $self->action_add();
 119     return;
 120   }
 121
 122   # fall back to save as new if only one id is given
 123   if (scalar @multi_ids == 1) {
 124     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 125     $self->action_save_as_new();
 126     return;
 127   }
 128
 129   # make new order from given orders
 130   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 131   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 132   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 133
 134   $self->action_edit();
 135 }
 136
 137 # delete the order
 138 sub action_delete {
 139   my ($self) = @_;
 140
 141   my $errors = $self->delete();
 142
 143   if (scalar @{ $errors }) {
 144     $self->js->flash('error', $_) foreach @{ $errors };
 145     return $self->js->render();
 146   }
 147
 148   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 149            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 150            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 151            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 152            : '';
 153   flash_later('info', $text);
 154
 155   my @redirect_params = (
 156     action => 'add',
 157     type   => $self->type,
 158   );
 159
 160   $self->redirect_to(@redirect_params);
 161 }
 162
 163 # save the order
 164 sub action_save {
 165   my ($self) = @_;
 166
 167   my $errors = $self->save();
 168
 169   if (scalar @{ $errors }) {
 170     $self->js->flash('error', $_) foreach @{ $errors };
 171     return $self->js->render();
 172   }
 173
 174   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 175            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 176            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 177            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 178            : '';
 179   flash_later('info', $text);
 180
 181   my @redirect_params = (
 182     action => 'edit',
 183     type   => $self->type,
 184     id     => $self->order->id,
 185   );
 186
 187   $self->redirect_to(@redirect_params);
 188 }
 189
 190 # save the order as new document an open it for edit
 191 sub action_save_as_new {
 192   my ($self) = @_;
 193
 194   my $order = $self->order;
 195
 196   if (!$order->id) {
 197     $self->js->flash('error', t8('This object has not been saved yet.'));
 198     return $self->js->render();
 199   }
 200
 201   # load order from db to check if values changed
 202   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 203
 204   my %new_attrs;
 205   # Lets assign a new number if the user hasn't changed the previous one.
 206   # If it has been changed manually then use it as-is.
 207   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 208                         ? ''
 209                         : trim($order->number);
 210
 211   # Clear transdate unless changed
 212   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 213                         ? DateTime->today_local
 214                         : $order->transdate;
 215
 216   # Set new reqdate unless changed
 217   if ($order->reqdate == $saved_order->reqdate) {
 218     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 219                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 220     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 221   } else {
 222     $new_attrs{reqdate} = $order->reqdate;
 223   }
 224
 225   # Update employee
 226   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 227
 228   # Create new record from current one
 229   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 230
 231   # no linked records on save as new
 232   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 233
 234   # save
 235   $self->action_save();
 236 }
 237
 238 # print the order
 239 #
 240 # This is called if "print" is pressed in the print dialog.
 241 # If PDF creation was requested and succeeded, the pdf is stored in a session
 242 # file and the filename is stored as session value with an unique key. A
 243 # javascript function with this key is then called. This function calls the
 244 # download action below (action_download_pdf), which offers the file for
 245 # download.
 246 sub action_print {
 247   my ($self) = @_;
 248
 249   my $errors = $self->save();
 250
 251   if (scalar @{ $errors }) {
 252     $self->js->flash('error', $_) foreach @{ $errors };
 253     return $self->js->render();
 254   }
 255
 256   $self->js_reset_order_and_item_ids_after_save;
 257
 258   my $format      = $::form->{print_options}->{format};
 259   my $media       = $::form->{print_options}->{media};
 260   my $formname    = $::form->{print_options}->{formname};
 261   my $copies      = $::form->{print_options}->{copies};
 262   my $groupitems  = $::form->{print_options}->{groupitems};
 263
 264   # only pdf and opendocument by now
 265   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 266     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 267   }
 268
 269   # only screen or printer by now
 270   if (none { $media eq $_ } qw(screen printer)) {
 271     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 272   }
 273
 274   my $language;
 275   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 276
 277   # create a form for generate_attachment_filename
 278   my $form   = Form->new;
 279   $form->{$self->nr_key()}  = $self->order->number;
 280   $form->{type}             = $self->type;
 281   $form->{format}           = $format;
 282   $form->{formname}         = $formname;
 283   $form->{language}         = '_' . $language->template_code if $language;
 284   my $pdf_filename          = $form->generate_attachment_filename();
 285
 286   my $pdf;
 287   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 288                                                    formname   => $formname,
 289                                                    language   => $language,
 290                                                    groupitems => $groupitems });
 291   if (scalar @errors) {
 292     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 293   }
 294
 295   if ($media eq 'screen') {
 296     # screen/download
 297     my $sfile = SL::SessionFile::Random->new(mode => "w");
 298     $sfile->fh->print($pdf);
 299     $sfile->fh->close;
 300
 301     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 302     $::auth->set_session_value("Order::print-${key}" => $sfile->file_name);
 303
 304     $self->js
 305     ->run('kivi.Order.download_pdf', $pdf_filename, $key)
 306     ->flash('info', t8('The PDF has been created'));
 307
 308   } elsif ($media eq 'printer') {
 309     # printer
 310     my $printer_id = $::form->{print_options}->{printer_id};
 311     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 312       copies  => $copies,
 313       content => $pdf,
 314     );
 315
 316     $self->js->flash('info', t8('The PDF has been printed'));
 317   }
 318
 319   # copy file to webdav folder
 320   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 321     my $webdav = SL::Webdav->new(
 322       type     => $self->type,
 323       number   => $self->order->number,
 324     );
 325     my $webdav_file = SL::Webdav::File->new(
 326       webdav   => $webdav,
 327       filename => $pdf_filename,
 328     );
 329     eval {
 330       $webdav_file->store(data => \$pdf);
 331       1;
 332     } or do {
 333       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 334     }
 335   }
 336   if ($self->order->number && $::instance_conf->get_doc_storage) {
 337     eval {
 338       SL::File->save(object_id     => $self->order->id,
 339                      object_type   => $self->type,
 340                      mime_type     => 'application/pdf',
 341                      source        => 'created',
 342                      file_type     => 'document',
 343                      file_name     => $pdf_filename,
 344                      file_contents => $pdf);
 345       1;
 346     } or do {
 347       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 348     }
 349   }
 350   $self->js->render;
 351 }
 352
 353 # offer pdf for download
 354 #
 355 # It needs to get the key for the session value to get the pdf file.
 356 sub action_download_pdf {
 357   my ($self) = @_;
 358
 359   my $key = $::form->{key};
 360   my $tmp_filename = $::auth->get_session_value("Order::print-${key}");
 361   return $self->send_file(
 362     $tmp_filename,
 363     type => 'application/pdf',
 364     name => $::form->{pdf_filename},
 365   );
 366 }
 367
 368 # open the email dialog
 369 sub action_show_email_dialog {
 370   my ($self) = @_;
 371
 372   my $cv_method = $self->cv;
 373
 374   if (!$self->order->$cv_method) {
 375     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 376                     ->render($self);
 377   }
 378
 379   my $email_form;
 380   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 381   $email_form->{to} ||= $self->order->$cv_method->email;
 382   $email_form->{cc}   = $self->order->$cv_method->cc;
 383   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 384   # Todo: get addresses from shipto, if any
 385
 386   my $form = Form->new;
 387   $form->{$self->nr_key()}  = $self->order->number;
 388   $form->{formname}         = $self->type;
 389   $form->{type}             = $self->type;
 390   $form->{language}         = 'de';
 391   $form->{format}           = 'pdf';
 392
 393   $email_form->{subject}             = $form->generate_email_subject();
 394   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 395   $email_form->{message}             = $form->generate_email_body();
 396   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 397
 398   my %files = $self->get_files_for_email_dialog();
 399   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 400                                   email_form  => $email_form,
 401                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 402                                   FILES       => \%files,
 403                                   is_customer => $self->cv eq 'customer',
 404   );
 405
 406   $self->js
 407       ->run('kivi.Order.show_email_dialog', $dialog_html)
 408       ->reinit_widgets
 409       ->render($self);
 410 }
 411
 412 # send email
 413 #
 414 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 415 sub action_send_email {
 416   my ($self) = @_;
 417
 418   my $errors = $self->save();
 419
 420   if (scalar @{ $errors }) {
 421     $self->js->run('kivi.Order.close_email_dialog');
 422     $self->js->flash('error', $_) foreach @{ $errors };
 423     return $self->js->render();
 424   }
 425
 426   $self->js_reset_order_and_item_ids_after_save;
 427
 428   my $email_form  = delete $::form->{email_form};
 429   my %field_names = (to => 'email');
 430
 431   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 432
 433   # for Form::cleanup which may be called in Form::send_email
 434   $::form->{cwd}    = getcwd();
 435   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 436
 437   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 438   $::form->{media}  = 'email';
 439
 440   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 441     my $language;
 442     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 443
 444     my $pdf;
 445     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 446                                                     format     => $::form->{print_options}->{format},
 447                                                     formname   => $::form->{print_options}->{formname},
 448                                                     language   => $language,
 449                                                     groupitems => $::form->{print_options}->{groupitems}});
 450     if (scalar @errors) {
 451       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 452     }
 453
 454     my $sfile = SL::SessionFile::Random->new(mode => "w");
 455     $sfile->fh->print($pdf);
 456     $sfile->fh->close;
 457
 458     $::form->{tmpfile} = $sfile->file_name;
 459     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 460   }
 461
 462   $::form->send_email(\%::myconfig, 'pdf');
 463
 464   # internal notes
 465   my $intnotes = $self->order->intnotes;
 466   $intnotes   .= "\n\n" if $self->order->intnotes;
 467   $intnotes   .= t8('[email]')                                                                                        . "\n";
 468   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 469   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 470   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 471   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 472   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 473   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 474
 475   $self->order->update_attributes(intnotes => $intnotes);
 476
 477   $self->js
 478       ->val('#order_intnotes', $intnotes)
 479       ->run('kivi.Order.close_email_dialog')
 480       ->flash('info', t8('The email has been sent.'))
 481       ->render($self);
 482 }
 483
 484 # open the periodic invoices config dialog
 485 #
 486 # If there are values in the form (i.e. dialog was opened before),
 487 # then use this values. Create new ones, else.
 488 sub action_show_periodic_invoices_config_dialog {
 489   my ($self) = @_;
 490
 491   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 492   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 493   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 494                                                    order_value_periodicity => 'p', # = same as periodicity
 495                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 496                                                    extend_automatically_by => 12,
 497                                                    active                  => 1,
 498                                                    email_subject           => GenericTranslations->get(
 499                                                                                 language_id      => $::form->{language_id},
 500                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 501                                                    email_body              => GenericTranslations->get(
 502                                                                                 language_id      => $::form->{language_id},
 503                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 504   );
 505   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 506   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 507
 508   $::form->get_lists(printers => "ALL_PRINTERS",
 509                      charts   => { key       => 'ALL_CHARTS',
 510                                    transdate => 'current_date' });
 511
 512   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 513
 514   if ($::form->{customer_id}) {
 515     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 516     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 517   }
 518
 519   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 520                 popup_dialog             => 1,
 521                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 522                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 523                 config                   => $config,
 524                 %$::form);
 525 }
 526
 527 # assign the values of the periodic invoices config dialog
 528 # as yaml in the hidden tag and set the status.
 529 sub action_assign_periodic_invoices_config {
 530   my ($self) = @_;
 531
 532   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 533
 534   my $config = { active                     => $::form->{active}       ? 1 : 0,
 535                  terminated                 => $::form->{terminated}   ? 1 : 0,
 536                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 537                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 538                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 539                  start_date_as_date         => $::form->{start_date_as_date},
 540                  end_date_as_date           => $::form->{end_date_as_date},
 541                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 542                  print                      => $::form->{print}      ? 1                         : 0,
 543                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 544                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 545                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 546                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 547                  send_email                 => $::form->{send_email} ? 1 : 0,
 548                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 549                  email_recipient_address    => $::form->{email_recipient_address},
 550                  email_sender               => $::form->{email_sender},
 551                  email_subject              => $::form->{email_subject},
 552                  email_body                 => $::form->{email_body},
 553                };
 554
 555   my $periodic_invoices_config = SL::YAML::Dump($config);
 556
 557   my $status = $self->get_periodic_invoices_status($config);
 558
 559   $self->js
 560     ->remove('#order_periodic_invoices_config')
 561     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 562     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 563     ->html('#periodic_invoices_status', $status)
 564     ->flash('info', t8('The periodic invoices config has been assigned.'))
 565     ->render($self);
 566 }
 567
 568 sub action_get_has_active_periodic_invoices {
 569   my ($self) = @_;
 570
 571   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 572   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 573
 574   my $has_active_periodic_invoices =
 575        $self->type eq sales_order_type()
 576     && $config
 577     && $config->active
 578     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 579     && $config->get_previous_billed_period_start_date;
 580
 581   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 582 }
 583
 584 # save the order and redirect to the frontend subroutine for a new
 585 # delivery order
 586 sub action_save_and_delivery_order {
 587   my ($self) = @_;
 588
 589   my $errors = $self->save();
 590
 591   if (scalar @{ $errors }) {
 592     $self->js->flash('error', $_) foreach @{ $errors };
 593     return $self->js->render();
 594   }
 595
 596   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 597            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 598            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 599            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 600            : '';
 601   flash_later('info', $text);
 602
 603   my @redirect_params = (
 604     controller => 'oe.pl',
 605     action     => 'oe_delivery_order_from_order',
 606     id         => $self->order->id,
 607   );
 608
 609   $self->redirect_to(@redirect_params);
 610 }
 611
 612 # save the order and redirect to the frontend subroutine for a new
 613 # invoice
 614 sub action_save_and_invoice {
 615   my ($self) = @_;
 616
 617   my $errors = $self->save();
 618
 619   if (scalar @{ $errors }) {
 620     $self->js->flash('error', $_) foreach @{ $errors };
 621     return $self->js->render();
 622   }
 623
 624   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 625            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 626            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 627            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 628            : '';
 629   flash_later('info', $text);
 630
 631   my @redirect_params = (
 632     controller => 'oe.pl',
 633     action     => 'oe_invoice_from_order',
 634     id         => $self->order->id,
 635   );
 636
 637   $self->redirect_to(@redirect_params);
 638 }
 639
 640 # workflow from sales quotation to sales order
 641 sub action_sales_order {
 642   $_[0]->workflow_sales_or_purchase_order();
 643 }
 644
 645 # workflow from rfq to purchase order
 646 sub action_purchase_order {
 647   $_[0]->workflow_sales_or_purchase_order();
 648 }
 649
 650 # set form elements in respect to a changed customer or vendor
 651 #
 652 # This action is called on an change of the customer/vendor picker.
 653 sub action_customer_vendor_changed {
 654   my ($self) = @_;
 655
 656   setup_order_from_cv($self->order);
 657   $self->recalc();
 658
 659   my $cv_method = $self->cv;
 660
 661   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 662     $self->js->show('#cp_row');
 663   } else {
 664     $self->js->hide('#cp_row');
 665   }
 666
 667   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 668     $self->js->show('#shipto_row');
 669   } else {
 670     $self->js->hide('#shipto_row');
 671   }
 672
 673   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 674
 675   $self->js
 676     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 677     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 678     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 679     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 680     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 681     ->val(        '#order_payment_id',       $self->order->payment_id)
 682     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 683     ->val(        '#order_intnotes',         $self->order->intnotes)
 684     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 685     ->focus(      '#order_' . $self->cv . '_id');
 686
 687   $self->js_redisplay_amounts_and_taxes;
 688   $self->js->render();
 689 }
 690
 691 # open the dialog for customer/vendor details
 692 sub action_show_customer_vendor_details_dialog {
 693   my ($self) = @_;
 694
 695   my $is_customer = 'customer' eq $::form->{vc};
 696   my $cv;
 697   if ($is_customer) {
 698     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 699   } else {
 700     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 701   }
 702
 703   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 704   $details{discount_as_percent} = $cv->discount_as_percent;
 705   $details{creditlimt}          = $cv->creditlimit_as_number;
 706   $details{business}            = $cv->business->description      if $cv->business;
 707   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 708   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 709   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 710   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 711
 712   foreach my $entry (@{ $cv->shipto }) {
 713     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 714   }
 715   foreach my $entry (@{ $cv->contacts }) {
 716     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 717   }
 718
 719   $_[0]->render('common/show_vc_details', { layout => 0 },
 720                 is_customer => $is_customer,
 721                 %details);
 722
 723 }
 724
 725 # called if a unit in an existing item row is changed
 726 sub action_unit_changed {
 727   my ($self) = @_;
 728
 729   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 730   my $item = $self->order->items_sorted->[$idx];
 731
 732   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 733   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 734
 735   $self->recalc();
 736
 737   $self->js
 738     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 739   $self->js_redisplay_line_values;
 740   $self->js_redisplay_amounts_and_taxes;
 741   $self->js->render();
 742 }
 743
 744 # add an item row for a new item entered in the input row
 745 sub action_add_item {
 746   my ($self) = @_;
 747
 748   my $form_attr = $::form->{add_item};
 749
 750   return unless $form_attr->{parts_id};
 751
 752   my $item = new_item($self->order, $form_attr);
 753
 754   $self->order->add_items($item);
 755
 756   $self->recalc();
 757
 758   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 759   my $row_as_html = $self->p->render('order/tabs/_row',
 760                                      ITEM              => $item,
 761                                      ID                => $item_id,
 762                                      TYPE              => $self->type,
 763                                      ALL_PRICE_FACTORS => $self->all_price_factors
 764   );
 765
 766   $self->js
 767     ->append('#row_table_id', $row_as_html);
 768
 769   if ( $item->part->is_assortment ) {
 770     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 771     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 772       my $attr = { parts_id => $assortment_item->parts_id,
 773                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 774                    unit     => $assortment_item->unit,
 775                    description => $assortment_item->part->description,
 776                  };
 777       my $item = new_item($self->order, $attr);
 778
 779       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 780       $item->discount(1) unless $assortment_item->charge;
 781
 782       $self->order->add_items( $item );
 783       $self->recalc();
 784       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 785       my $row_as_html = $self->p->render('order/tabs/_row',
 786                                          ITEM              => $item,
 787                                          ID                => $item_id,
 788                                          TYPE              => $self->type,
 789                                          ALL_PRICE_FACTORS => $self->all_price_factors
 790       );
 791       $self->js
 792         ->append('#row_table_id', $row_as_html);
 793     };
 794   };
 795
 796   $self->js
 797     ->val('.add_item_input', '')
 798     ->run('kivi.Order.init_row_handlers')
 799     ->run('kivi.Order.row_table_scroll_down')
 800     ->run('kivi.Order.renumber_positions')
 801     ->focus('#add_item_parts_id_name');
 802
 803   $self->js_redisplay_amounts_and_taxes;
 804   $self->js->render();
 805 }
 806
 807 # open the dialog for entering multiple items at once
 808 sub action_show_multi_items_dialog {
 809   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 810                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 811 }
 812
 813 # update the filter results in the multi item dialog
 814 sub action_multi_items_update_result {
 815   my $max_count = 100;
 816
 817   $::form->{multi_items}->{filter}->{obsolete} = 0;
 818
 819   my $count = $_[0]->multi_items_models->count;
 820
 821   if ($count == 0) {
 822     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 823     $_[0]->render($text, { layout => 0 });
 824   } elsif ($count > $max_count) {
 825     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 826     $_[0]->render($text, { layout => 0 });
 827   } else {
 828     my $multi_items = $_[0]->multi_items_models->get;
 829     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 830                   multi_items => $multi_items);
 831   }
 832 }
 833
 834 # add item rows for multiple items at once
 835 sub action_add_multi_items {
 836   my ($self) = @_;
 837
 838   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 839   return $self->js->render() unless scalar @form_attr;
 840
 841   my @items;
 842   foreach my $attr (@form_attr) {
 843     my $item = new_item($self->order, $attr);
 844     push @items, $item;
 845     if ( $item->part->is_assortment ) {
 846       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 847         my $attr = { parts_id => $assortment_item->parts_id,
 848                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 849                      unit     => $assortment_item->unit,
 850                      description => $assortment_item->part->description,
 851                    };
 852         my $item = new_item($self->order, $attr);
 853
 854         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 855         $item->discount(1) unless $assortment_item->charge;
 856         push @items, $item;
 857       }
 858     }
 859   }
 860   $self->order->add_items(@items);
 861
 862   $self->recalc();
 863
 864   foreach my $item (@items) {
 865     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 866     my $row_as_html = $self->p->render('order/tabs/_row',
 867                                        ITEM              => $item,
 868                                        ID                => $item_id,
 869                                        TYPE              => $self->type,
 870                                        ALL_PRICE_FACTORS => $self->all_price_factors
 871     );
 872
 873     $self->js->append('#row_table_id', $row_as_html);
 874   }
 875
 876   $self->js
 877     ->run('kivi.Order.close_multi_items_dialog')
 878     ->run('kivi.Order.init_row_handlers')
 879     ->run('kivi.Order.row_table_scroll_down')
 880     ->run('kivi.Order.renumber_positions')
 881     ->focus('#add_item_parts_id_name');
 882
 883   $self->js_redisplay_amounts_and_taxes;
 884   $self->js->render();
 885 }
 886
 887 # recalculate all linetotals, amounts and taxes and redisplay them
 888 sub action_recalc_amounts_and_taxes {
 889   my ($self) = @_;
 890
 891   $self->recalc();
 892
 893   $self->js_redisplay_line_values;
 894   $self->js_redisplay_amounts_and_taxes;
 895   $self->js->render();
 896 }
 897
 898 # redisplay item rows if they are sorted by an attribute
 899 sub action_reorder_items {
 900   my ($self) = @_;
 901
 902   my %sort_keys = (
 903     partnumber  => sub { $_[0]->part->partnumber },
 904     description => sub { $_[0]->description },
 905     qty         => sub { $_[0]->qty },
 906     sellprice   => sub { $_[0]->sellprice },
 907     discount    => sub { $_[0]->discount },
 908   );
 909
 910   my $method = $sort_keys{$::form->{order_by}};
 911   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 912   if ($::form->{sort_dir}) {
 913     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 914       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 915     } else {
 916       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 917     }
 918   } else {
 919     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 920       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 921     } else {
 922       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 923     }
 924   }
 925   $self->js
 926     ->run('kivi.Order.redisplay_items', \@to_sort)
 927     ->render;
 928 }
 929
 930 # show the popup to choose a price/discount source
 931 sub action_price_popup {
 932   my ($self) = @_;
 933
 934   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 935   my $item = $self->order->items_sorted->[$idx];
 936
 937   $self->render_price_dialog($item);
 938 }
 939
 940 # get the longdescription for an item if the dialog to enter/change the
 941 # longdescription was opened and the longdescription is empty
 942 #
 943 # If this item is new, get the longdescription from Part.
 944 # Otherwise get it from OrderItem.
 945 sub action_get_item_longdescription {
 946   my $longdescription;
 947
 948   if ($::form->{item_id}) {
 949     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 950   } elsif ($::form->{parts_id}) {
 951     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 952   }
 953   $_[0]->render(\ $longdescription, { type => 'text' });
 954 }
 955
 956 # load the second row for one or more items
 957 #
 958 # This action gets the html code for all items second rows by rendering a template for
 959 # the second row and sets the html code via client js.
 960 sub action_load_second_rows {
 961   my ($self) = @_;
 962
 963   $self->recalc() if $self->order->is_sales; # for margin calculation
 964
 965   foreach my $item_id (@{ $::form->{item_ids} }) {
 966     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 967     my $item = $self->order->items_sorted->[$idx];
 968
 969     $self->js_load_second_row($item, $item_id, 0);
 970   }
 971
 972   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 973
 974   $self->js->render();
 975 }
 976
 977 sub js_load_second_row {
 978   my ($self, $item, $item_id, $do_parse) = @_;
 979
 980   if ($do_parse) {
 981     # Parse values from form (they are formated while rendering (template)).
 982     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 983     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
 984     foreach my $var (@{ $item->cvars_by_config }) {
 985       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 986     }
 987     $item->parse_custom_variable_values;
 988   }
 989
 990   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
 991
 992   $self->js
 993     ->html('#second_row_' . $item_id, $row_as_html)
 994     ->data('#second_row_' . $item_id, 'loaded', 1);
 995 }
 996
 997 sub js_redisplay_line_values {
 998   my ($self) = @_;
 999
1000   my $is_sales = $self->order->is_sales;
1001
1002   # sales orders with margins
1003   my @data;
1004   if ($is_sales) {
1005     @data = map {
1006       [
1007        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1008        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1009        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1010       ]} @{ $self->order->items_sorted };
1011   } else {
1012     @data = map {
1013       [
1014        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1015       ]} @{ $self->order->items_sorted };
1016   }
1017
1018   $self->js
1019     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1020 }
1021
1022 sub js_redisplay_amounts_and_taxes {
1023   my ($self) = @_;
1024
1025   if (scalar @{ $self->{taxes} }) {
1026     $self->js->show('#taxincluded_row_id');
1027   } else {
1028     $self->js->hide('#taxincluded_row_id');
1029   }
1030
1031   if ($self->order->taxincluded) {
1032     $self->js->hide('#subtotal_row_id');
1033   } else {
1034     $self->js->show('#subtotal_row_id');
1035   }
1036
1037   if ($self->order->is_sales) {
1038     my $is_neg = $self->order->marge_total < 0;
1039     $self->js
1040       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1041       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1042       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1043       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1044       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1045       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1046       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1047       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1048   }
1049
1050   $self->js
1051     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1052     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1053     ->remove('.tax_row')
1054     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1055 }
1056
1057 sub js_reset_order_and_item_ids_after_save {
1058   my ($self) = @_;
1059
1060   $self->js
1061     ->val('#id', $self->order->id)
1062     ->val('#converted_from_oe_id', '')
1063     ->val('#order_' . $self->nr_key(), $self->order->number);
1064
1065   my $idx = 0;
1066   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1067     next if !$self->order->items_sorted->[$idx]->id;
1068     next if $form_item_id !~ m{^new};
1069     $self->js
1070       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1071       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1072       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1073   } continue {
1074     $idx++;
1075   }
1076   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1077 }
1078
1079 #
1080 # helpers
1081 #
1082
1083 sub init_valid_types {
1084   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1085 }
1086
1087 sub init_type {
1088   my ($self) = @_;
1089
1090   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1091     die "Not a valid type for order";
1092   }
1093
1094   $self->type($::form->{type});
1095 }
1096
1097 sub init_cv {
1098   my ($self) = @_;
1099
1100   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1101          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1102          : die "Not a valid type for order";
1103
1104   return $cv;
1105 }
1106
1107 sub init_p {
1108   SL::Presenter->get;
1109 }
1110
1111 sub init_order {
1112   $_[0]->make_order;
1113 }
1114
1115 # model used to filter/display the parts in the multi-items dialog
1116 sub init_multi_items_models {
1117   SL::Controller::Helper::GetModels->new(
1118     controller     => $_[0],
1119     model          => 'Part',
1120     with_objects   => [ qw(unit_obj) ],
1121     disable_plugin => 'paginated',
1122     source         => $::form->{multi_items},
1123     sorted         => {
1124       _default    => {
1125         by  => 'partnumber',
1126         dir => 1,
1127       },
1128       partnumber  => t8('Partnumber'),
1129       description => t8('Description')}
1130   );
1131 }
1132
1133 sub init_all_price_factors {
1134   SL::DB::Manager::PriceFactor->get_all;
1135 }
1136
1137 sub check_auth {
1138   my ($self) = @_;
1139
1140   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1141
1142   my $right   = $right_for->{ $self->type };
1143   $right    ||= 'DOES_NOT_EXIST';
1144
1145   $::auth->assert($right);
1146 }
1147
1148 # build the selection box for contacts
1149 #
1150 # Needed, if customer/vendor changed.
1151 sub build_contact_select {
1152   my ($self) = @_;
1153
1154   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1155     value_key  => 'cp_id',
1156     title_key  => 'full_name_dep',
1157     default    => $self->order->cp_id,
1158     with_empty => 1,
1159     style      => 'width: 300px',
1160   );
1161 }
1162
1163 # build the selection box for shiptos
1164 #
1165 # Needed, if customer/vendor changed.
1166 sub build_shipto_select {
1167   my ($self) = @_;
1168
1169   select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
1170     value_key  => 'shipto_id',
1171     title_key  => 'displayable_id',
1172     default    => $self->order->shipto_id,
1173     with_empty => 1,
1174     style      => 'width: 300px',
1175   );
1176 }
1177
1178 # render the info line for business
1179 #
1180 # Needed, if customer/vendor changed.
1181 sub build_business_info_row
1182 {
1183   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1184 }
1185
1186 # build the rows for displaying taxes
1187 #
1188 # Called if amounts where recalculated and redisplayed.
1189 sub build_tax_rows {
1190   my ($self) = @_;
1191
1192   my $rows_as_html;
1193   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1194     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1195   }
1196   return $rows_as_html;
1197 }
1198
1199
1200 sub render_price_dialog {
1201   my ($self, $record_item) = @_;
1202
1203   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1204
1205   $self->js
1206     ->run(
1207       'kivi.io.price_chooser_dialog',
1208       t8('Available Prices'),
1209       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1210     )
1211     ->reinit_widgets;
1212
1213 #   if (@errors) {
1214 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1215 #     $self->js->show('#dialog_flash_error');
1216 #   }
1217
1218   $self->js->render;
1219 }
1220
1221 sub load_order {
1222   my ($self) = @_;
1223
1224   return if !$::form->{id};
1225
1226   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1227 }
1228
1229 # load or create a new order object
1230 #
1231 # And assign changes from the form to this object.
1232 # If the order is loaded from db, check if items are deleted in the form,
1233 # remove them form the object and collect them for removing from db on saving.
1234 # Then create/update items from form (via make_item) and add them.
1235 sub make_order {
1236   my ($self) = @_;
1237
1238   # add_items adds items to an order with no items for saving, but they cannot
1239   # be retrieved via items until the order is saved. Adding empty items to new
1240   # order here solves this problem.
1241   my $order;
1242   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1243   $order ||= SL::DB::Order->new(orderitems => [],
1244                                 quotation  => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())));
1245
1246   my $cv_id_method = $self->cv . '_id';
1247   if (!$::form->{id} && $::form->{$cv_id_method}) {
1248     $order->$cv_id_method($::form->{$cv_id_method});
1249     setup_order_from_cv($order);
1250   }
1251
1252   my $form_orderitems               = delete $::form->{order}->{orderitems};
1253   my $form_periodic_invoices_config = delete $::form->{order}->{periodic_invoices_config};
1254
1255   $order->assign_attributes(%{$::form->{order}});
1256
1257   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1258     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1259     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1260   }
1261
1262   # remove deleted items
1263   $self->item_ids_to_delete([]);
1264   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1265     my $item = $order->orderitems->[$idx];
1266     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1267       splice @{$order->orderitems}, $idx, 1;
1268       push @{$self->item_ids_to_delete}, $item->id;
1269     }
1270   }
1271
1272   my @items;
1273   my $pos = 1;
1274   foreach my $form_attr (@{$form_orderitems}) {
1275     my $item = make_item($order, $form_attr);
1276     $item->position($pos);
1277     push @items, $item;
1278     $pos++;
1279   }
1280   $order->add_items(grep {!$_->id} @items);
1281
1282   return $order;
1283 }
1284
1285 # create or update items from form
1286 #
1287 # Make item objects from form values. For items already existing read from db.
1288 # Create a new item else. And assign attributes.
1289 sub make_item {
1290   my ($record, $attr) = @_;
1291
1292   my $item;
1293   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1294
1295   my $is_new = !$item;
1296
1297   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1298   # they cannot be retrieved via custom_variables until the order/orderitem is
1299   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1300   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1301
1302   $item->assign_attributes(%$attr);
1303   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1304   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1305   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1306
1307   return $item;
1308 }
1309
1310 # create a new item
1311 #
1312 # This is used to add one item
1313 sub new_item {
1314   my ($record, $attr) = @_;
1315
1316   my $item = SL::DB::OrderItem->new;
1317
1318   # Remove attributes where the user left or set the inputs empty.
1319   # So these attributes will be undefined and we can distinguish them
1320   # from zero later on.
1321   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1322     delete $attr->{$_} if $attr->{$_} eq '';
1323   }
1324
1325   $item->assign_attributes(%$attr);
1326
1327   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1328   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1329
1330   $item->unit($part->unit) if !$item->unit;
1331
1332   my $price_src;
1333   if ( $part->is_assortment ) {
1334     # add assortment items with price 0, as the components carry the price
1335     $price_src = $price_source->price_from_source("");
1336     $price_src->price(0);
1337   } elsif (defined $item->sellprice) {
1338     $price_src = $price_source->price_from_source("");
1339     $price_src->price($item->sellprice);
1340   } else {
1341     $price_src = $price_source->best_price
1342            ? $price_source->best_price
1343            : $price_source->price_from_source("");
1344     $price_src->price(0) if !$price_source->best_price;
1345   }
1346
1347   my $discount_src;
1348   if (defined $item->discount) {
1349     $discount_src = $price_source->discount_from_source("");
1350     $discount_src->discount($item->discount);
1351   } else {
1352     $discount_src = $price_source->best_discount
1353                   ? $price_source->best_discount
1354                   : $price_source->discount_from_source("");
1355     $discount_src->discount(0) if !$price_source->best_discount;
1356   }
1357
1358   my %new_attr;
1359   $new_attr{part}                   = $part;
1360   $new_attr{description}            = $part->description     if ! $item->description;
1361   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1362   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1363   $new_attr{sellprice}              = $price_src->price;
1364   $new_attr{discount}               = $discount_src->discount;
1365   $new_attr{active_price_source}    = $price_src;
1366   $new_attr{active_discount_source} = $discount_src;
1367   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1368   $new_attr{project_id}             = $record->globalproject_id;
1369   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1370
1371   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1372   # they cannot be retrieved via custom_variables until the order/orderitem is
1373   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1374   $new_attr{custom_variables} = [];
1375
1376   $item->assign_attributes(%new_attr);
1377
1378   return $item;
1379 }
1380
1381 sub setup_order_from_cv {
1382   my ($order) = @_;
1383
1384   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id));
1385
1386   $order->intnotes($order->customervendor->notes);
1387
1388   if ($order->is_sales) {
1389     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1390     $order->taxincluded(defined($order->customer->taxincluded_checked)
1391                         ? $order->customer->taxincluded_checked
1392                         : $::myconfig{taxincluded_checked});
1393   }
1394
1395 }
1396
1397 # recalculate prices and taxes
1398 #
1399 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1400 sub recalc {
1401   my ($self) = @_;
1402
1403   # bb: todo: currency later
1404   $self->order->currency_id($::instance_conf->get_currency_id());
1405
1406   my %pat = $self->order->calculate_prices_and_taxes();
1407   $self->{taxes} = [];
1408   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
1409     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
1410
1411     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
1412     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
1413                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
1414                                 tax       => $tax });
1415   }
1416
1417   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1418 }
1419
1420 # get data for saving, printing, ..., that is not changed in the form
1421 #
1422 # Only cvars for now.
1423 sub get_unalterable_data {
1424   my ($self) = @_;
1425
1426   foreach my $item (@{ $self->order->items }) {
1427     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1428     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1429     foreach my $var (@{ $item->cvars_by_config }) {
1430       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1431     }
1432     $item->parse_custom_variable_values;
1433   }
1434 }
1435
1436 # delete the order
1437 #
1438 # And remove related files in the spool directory
1439 sub delete {
1440   my ($self) = @_;
1441
1442   my $errors = [];
1443   my $db     = $self->order->db;
1444
1445   $db->with_transaction(
1446     sub {
1447       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1448       $self->order->delete;
1449       my $spool = $::lx_office_conf{paths}->{spool};
1450       unlink map { "$spool/$_" } @spoolfiles if $spool;
1451
1452       1;
1453   }) || push(@{$errors}, $db->error);
1454
1455   return $errors;
1456 }
1457
1458 # save the order
1459 #
1460 # And delete items that are deleted in the form.
1461 sub save {
1462   my ($self) = @_;
1463
1464   my $errors = [];
1465   my $db     = $self->order->db;
1466
1467   $db->with_transaction(sub {
1468     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1469     $self->order->save(cascade => 1);
1470
1471     # link records
1472     if ($::form->{converted_from_oe_id}) {
1473       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1474       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1475         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1476         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1477         $src->link_to_record($self->order);
1478       }
1479       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1480         my $idx = 0;
1481         foreach (@{ $self->order->items_sorted }) {
1482           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1483           next if !$from_id;
1484           SL::DB::RecordLink->new(from_table => 'orderitems',
1485                                   from_id    => $from_id,
1486                                   to_table   => 'orderitems',
1487                                   to_id      => $_->id
1488           )->save;
1489           $idx++;
1490         }
1491       }
1492     }
1493     1;
1494   }) || push(@{$errors}, $db->error);
1495
1496   return $errors;
1497 }
1498
1499 sub workflow_sales_or_purchase_order {
1500   my ($self) = @_;
1501
1502   # always save
1503   my $errors = $self->save();
1504
1505   if (scalar @{ $errors }) {
1506     $self->js->flash('error', $_) foreach @{ $errors };
1507     return $self->js->render();
1508   }
1509
1510   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1511                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1512                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1513                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1514                        : '';
1515
1516   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1517   $self->{converted_from_oe_id} = delete $::form->{id};
1518
1519   # set item ids to new fake id, to identify them as new items
1520   foreach my $item (@{$self->order->items_sorted}) {
1521     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1522   }
1523
1524   # change form type
1525   $::form->{type} = $destination_type;
1526   $self->type($self->init_type);
1527   $self->cv  ($self->init_cv);
1528   $self->check_auth;
1529
1530   $self->recalc();
1531   $self->get_unalterable_data();
1532   $self->pre_render();
1533
1534   # trigger rendering values for second row/longdescription as hidden,
1535   # because they are loaded only on demand. So we need to keep the values
1536   # from the source.
1537   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1538   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1539
1540   $self->render(
1541     'order/form',
1542     title => $self->get_title_for('edit'),
1543     %{$self->{template_args}}
1544   );
1545 }
1546
1547
1548 sub pre_render {
1549   my ($self) = @_;
1550
1551   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1552   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1553   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1554                                                                                               deleted => 0 ] ],
1555                                                                            sort_by => 'name');
1556   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1557                                                                                               deleted => 0 ] ],
1558                                                                            sort_by => 'name');
1559   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1560                                                                                                         obsolete => 0 ] ]);
1561   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1562   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1563   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1564   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1565   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1566
1567   my $print_form = Form->new('');
1568   $print_form->{type}      = $self->type;
1569   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
1570   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
1571   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
1572     form => $print_form,
1573     options => {dialog_name_prefix => 'print_options.',
1574                 show_headers       => 1,
1575                 no_queue           => 1,
1576                 no_postscript      => 1,
1577                 no_opendocument    => 0,
1578                 no_html            => 1},
1579   );
1580
1581   foreach my $item (@{$self->order->orderitems}) {
1582     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1583     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1584     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1585   }
1586
1587   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1588     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1589     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1590   }
1591
1592   if ($self->order->number && $::instance_conf->get_webdav) {
1593     my $webdav = SL::Webdav->new(
1594       type     => $self->type,
1595       number   => $self->order->number,
1596     );
1597     my @all_objects = $webdav->get_all_objects;
1598     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1599                                                     type => t8('File'),
1600                                                     link => File::Spec->catfile($_->full_filedescriptor),
1601                                                 } } @all_objects;
1602   }
1603
1604   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery edit_periodic_invoices_config calculate_qty);
1605   $self->setup_edit_action_bar;
1606 }
1607
1608 sub setup_edit_action_bar {
1609   my ($self, %params) = @_;
1610
1611   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1612                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1613                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1614
1615   for my $bar ($::request->layout->get('actionbar')) {
1616     $bar->add(
1617       combobox => [
1618         action => [
1619           t8('Save'),
1620           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1621                                                     $::instance_conf->get_order_warn_no_deliverydate,
1622                                                                                                       ],
1623           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1624         ],
1625         action => [
1626           t8('Save as new'),
1627           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1628           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1629           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1630         ],
1631       ], # end of combobox "Save"
1632
1633       combobox => [
1634         action => [
1635           t8('Workflow'),
1636         ],
1637         action => [
1638           t8('Save and Sales Order'),
1639           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1640           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1641           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1642         ],
1643         action => [
1644           t8('Save and Purchase Order'),
1645           submit   => [ '#order_form', { action => "Order/purchase_order" } ],
1646           only_if  => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1647           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1648         ],
1649         action => [
1650           t8('Save and Delivery Order'),
1651           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1652                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1653                                                                                                                         ],
1654           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1655           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1656         ],
1657         action => [
1658           t8('Save and Invoice'),
1659           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1660           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1661         ],
1662       ], # end of combobox "Workflow"
1663
1664       combobox => [
1665         action => [
1666           t8('Export'),
1667         ],
1668         action => [
1669           t8('Save and print'),
1670           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1671         ],
1672         action => [
1673           t8('Save and E-mail'),
1674           call => [ 'kivi.Order.email', $::instance_conf->get_order_warn_duplicate_parts ],
1675         ],
1676         action => [
1677           t8('Download attachments of all parts'),
1678           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1679           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1680           only_if  => $::instance_conf->get_doc_storage,
1681         ],
1682       ], # end of combobox "Export"
1683
1684       action => [
1685         t8('Delete'),
1686         call     => [ 'kivi.Order.delete_order' ],
1687         confirm  => $::locale->text('Do you really want to delete this object?'),
1688         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1689         only_if  => $deletion_allowed,
1690       ],
1691     );
1692   }
1693 }
1694
1695 sub generate_pdf {
1696   my ($order, $pdf_ref, $params) = @_;
1697
1698   my @errors = ();
1699
1700   my $print_form = Form->new('');
1701   $print_form->{type}        = $order->type;
1702   $print_form->{formname}    = $params->{formname} || $order->type;
1703   $print_form->{format}      = $params->{format}   || 'pdf';
1704   $print_form->{media}       = $params->{media}    || 'file';
1705   $print_form->{groupitems}  = $params->{groupitems};
1706   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1707
1708   $order->language($params->{language});
1709   $order->flatten_to_form($print_form, format_amounts => 1);
1710
1711   my $template_ext;
1712   my $template_type;
1713   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1714     $template_ext  = 'odt';
1715     $template_type = 'OpenDocument';
1716   }
1717
1718   # search for the template
1719   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1720     name        => $print_form->{formname},
1721     extension   => $template_ext,
1722     email       => $print_form->{media} eq 'email',
1723     language    => $params->{language},
1724     printer_id  => $print_form->{printer_id},  # todo
1725   );
1726
1727   if (!defined $template_file) {
1728     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1729   }
1730
1731   return @errors if scalar @errors;
1732
1733   $print_form->throw_on_error(sub {
1734     eval {
1735       $print_form->prepare_for_printing;
1736
1737       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1738         format        => $print_form->{format},
1739         template_type => $template_type,
1740         template      => $template_file,
1741         variables     => $print_form,
1742         variable_content_types => {
1743           longdescription => 'html',
1744           partnotes       => 'html',
1745           notes           => 'html',
1746         },
1747       );
1748       1;
1749     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1750   });
1751
1752   return @errors;
1753 }
1754
1755 sub get_files_for_email_dialog {
1756   my ($self) = @_;
1757
1758   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1759
1760   return %files if !$::instance_conf->get_doc_storage;
1761
1762   if ($self->order->id) {
1763     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1764     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1765     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1766   }
1767
1768   my @parts =
1769     uniq_by { $_->{id} }
1770     map {
1771       +{ id         => $_->part->id,
1772          partnumber => $_->part->partnumber }
1773     } @{$self->order->items_sorted};
1774
1775   foreach my $part (@parts) {
1776     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1777     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1778   }
1779
1780   foreach my $key (keys %files) {
1781     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1782   }
1783
1784   return %files;
1785 }
1786
1787 sub make_periodic_invoices_config_from_yaml {
1788   my ($yaml_config) = @_;
1789
1790   return if !$yaml_config;
1791   my $attr = SL::YAML::Load($yaml_config);
1792   return if 'HASH' ne ref $attr;
1793   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1794 }
1795
1796
1797 sub get_periodic_invoices_status {
1798   my ($self, $config) = @_;
1799
1800   return                      if $self->type ne sales_order_type();
1801   return t8('not configured') if !$config;
1802
1803   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1804              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1805              :                                                     die "Cannot get status of periodic invoices config";
1806
1807   return $active ? t8('active') : t8('inactive');
1808 }
1809
1810 sub get_title_for {
1811   my ($self, $action) = @_;
1812
1813   return '' if none { lc($action)} qw(add edit);
1814
1815   # for locales:
1816   # $::locale->text("Add Sales Order");
1817   # $::locale->text("Add Purchase Order");
1818   # $::locale->text("Add Quotation");
1819   # $::locale->text("Add Request for Quotation");
1820   # $::locale->text("Edit Sales Order");
1821   # $::locale->text("Edit Purchase Order");
1822   # $::locale->text("Edit Quotation");
1823   # $::locale->text("Edit Request for Quotation");
1824
1825   $action = ucfirst(lc($action));
1826   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
1827        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
1828        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
1829        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
1830        : '';
1831 }
1832
1833 sub sales_order_type {
1834   'sales_order';
1835 }
1836
1837 sub purchase_order_type {
1838   'purchase_order';
1839 }
1840
1841 sub sales_quotation_type {
1842   'sales_quotation';
1843 }
1844
1845 sub request_quotation_type {
1846   'request_quotation';
1847 }
1848
1849 sub nr_key {
1850   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
1851        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
1852        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
1853        : $_[0]->type eq request_quotation_type() ? 'quonumber'
1854        : '';
1855 }
1856
1857 1;
1858
1859 __END__
1860
1861 =encoding utf-8
1862
1863 =head1 NAME
1864
1865 SL::Controller::Order - controller for orders
1866
1867 =head1 SYNOPSIS
1868
1869 This is a new form to enter orders, completely rewritten with the use
1870 of controller and java script techniques.
1871
1872 The aim is to provide the user a better expirience and a faster flow
1873 of work. Also the code should be more readable, more reliable and
1874 better to maintain.
1875
1876 =head2 Key Features
1877
1878 =over 4
1879
1880 =item *
1881
1882 One input row, so that input happens every time at the same place.
1883
1884 =item *
1885
1886 Use of pickers where possible.
1887
1888 =item *
1889
1890 Possibility to enter more than one item at once.
1891
1892 =item *
1893
1894 Item list in a scrollable area, so that the workflow buttons stay at
1895 the bottom.
1896
1897 =item *
1898
1899 Reordering item rows with drag and drop is possible. Sorting item rows is
1900 possible (by partnumber, description, qty, sellprice and discount for now).
1901
1902 =item *
1903
1904 No C<update> is necessary. All entries and calculations are managed
1905 with ajax-calls and the page does only reload on C<save>.
1906
1907 =item *
1908
1909 User can see changes immediately, because of the use of java script
1910 and ajax.
1911
1912 =back
1913
1914 =head1 CODE
1915
1916 =head2 Layout
1917
1918 =over 4
1919
1920 =item * C<SL/Controller/Order.pm>
1921
1922 the controller
1923
1924 =item * C<template/webpages/order/form.html>
1925
1926 main form
1927
1928 =item * C<template/webpages/order/tabs/basic_data.html>
1929
1930 Main tab for basic_data.
1931
1932 This is the only tab here for now. "linked records" and "webdav" tabs are
1933 reused from generic code.
1934
1935 =over 4
1936
1937 =item * C<template/webpages/order/tabs/_business_info_row.html>
1938
1939 For displaying information on business type
1940
1941 =item * C<template/webpages/order/tabs/_item_input.html>
1942
1943 The input line for items
1944
1945 =item * C<template/webpages/order/tabs/_row.html>
1946
1947 One row for already entered items
1948
1949 =item * C<template/webpages/order/tabs/_tax_row.html>
1950
1951 Displaying tax information
1952
1953 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
1954
1955 Dialog for entering more than one item at once
1956
1957 =item * C<template/webpages/order/tabs/_multi_items_result.html>
1958
1959 Results for the filter in the multi items dialog
1960
1961 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
1962
1963 Dialog for selecting price and discount sources
1964
1965 =back
1966
1967 =item * C<js/kivi.Order.js>
1968
1969 java script functions
1970
1971 =back
1972
1973 =head1 TODO
1974
1975 =over 4
1976
1977 =item * testing
1978
1979 =item * currency
1980
1981 =item * credit limit
1982
1983 =item * more workflows (quotation, rfq)
1984
1985 =item * price sources: little symbols showing better price / better discount
1986
1987 =item * select units in input row?
1988
1989 =item * custom shipto address
1990
1991 =item * check for direct delivery (workflow sales order -> purchase order)
1992
1993 =item * language / part translations
1994
1995 =item * access rights
1996
1997 =item * display weights
1998
1999 =item * history
2000
2001 =item * mtime check
2002
2003 =item * optional client/user behaviour
2004
2005 (transactions has to be set - department has to be set -
2006  force project if enabled in client config - transport cost reminder)
2007
2008 =back
2009
2010 =head1 KNOWN BUGS AND CAVEATS
2011
2012 =over 4
2013
2014 =item *
2015
2016 Customer discount is not displayed as a valid discount in price source popup
2017 (this might be a bug in price sources)
2018
2019 (I cannot reproduce this (Bernd))
2020
2021 =item *
2022
2023 No indication that <shift>-up/down expands/collapses second row.
2024
2025 =item *
2026
2027 Inline creation of parts is not currently supported
2028
2029 =item *
2030
2031 Table header is not sticky in the scrolling area.
2032
2033 =item *
2034
2035 Sorting does not include C<position>, neither does reordering.
2036
2037 This behavior was implemented intentionally. But we can discuss, which behavior
2038 should be implemented.
2039
2040 =item *
2041
2042 C<show_multi_items_dialog> does not use the currently inserted string for
2043 filtering.
2044
2045 =item *
2046
2047 The language selected in print or email dialog is not saved when the order is saved.
2048
2049 =back
2050
2051 =head1 To discuss / Nice to have
2052
2053 =over 4
2054
2055 =item *
2056
2057 How to expand/collapse second row. Now it can be done clicking the icon or
2058 <shift>-up/down.
2059
2060 =item *
2061
2062 Possibility to change longdescription in input row?
2063
2064 =item *
2065
2066 Possibility to select PriceSources in input row?
2067
2068 =item *
2069
2070 This controller uses a (changed) copy of the template for the PriceSource
2071 dialog. Maybe there could be used one code source.
2072
2073 =item *
2074
2075 Rounding-differences between this controller (PriceTaxCalculator) and the old
2076 form. This is not only a problem here, but also in all parts using the PTC.
2077 There exists a ticket and a patch. This patch should be testet.
2078
2079 =item *
2080
2081 An indicator, if the actual inputs are saved (like in an
2082 editor or on text processing application).
2083
2084 =item *
2085
2086 A warning when leaving the page without saveing unchanged inputs.
2087
2088
2089 =back
2090
2091 =head1 AUTHOR
2092
2093 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2094
2095 =cut