SL/Dev/Record.pm

   1 package SL::Dev::Record;
   2
   3 use strict;
   4 use base qw(Exporter);
   5 our @EXPORT = qw(create_invoice_item create_sales_invoice create_order_item  create_sales_order create_purchase_order create_delivery_order_item create_sales_delivery_order create_project);
   6
   7 use SL::DB::Invoice;
   8 use SL::DB::InvoiceItem;
   9 use SL::DB::Employee;
  10 use SL::Dev::Part;
  11 use SL::Dev::CustomerVendor;
  12 use SL::DB::Project;
  13 use SL::DB::ProjectStatus;
  14 use SL::DB::ProjectType;
  15 use DateTime;
  16
  17 my %record_type_to_item_type = ( sales_invoice        => 'SL::DB::InvoiceItem',
  18                                  sales_order          => 'SL::DB::OrderItem',
  19                                  purchase_order       => 'SL::DB::OrderItem',
  20                                  sales_delivery_order => 'SL::DB::DeliveryOrderItem',
  21                                );
  22
  23 sub create_sales_invoice {
  24   my (%params) = @_;
  25
  26   my $record_type = 'sales_invoice';
  27   my $invoiceitems = delete $params{invoiceitems} // _create_two_items($record_type);
  28   _check_items($invoiceitems, $record_type);
  29
  30   my $customer = delete $params{customer} // SL::Dev::CustomerVendor::create_customer(name => 'Testcustomer')->save;
  31   die "illegal customer" unless defined $customer && ref($customer) eq 'SL::DB::Customer';
  32
  33   my $invoice = SL::DB::Invoice->new(
  34     invoice      => 1,
  35     type         => 'sales_invoice',
  36     customer_id  => $customer->id,
  37     taxzone_id   => $customer->taxzone->id,
  38     invnumber    => delete $params{invnumber}   // undef,
  39     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
  40     taxincluded  => $params{taxincluded} // 0,
  41     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  42     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  43     transdate    => $params{transdate}   // DateTime->today_local->to_kivitendo,
  44     payment_id   => $params{payment_id}  // undef,
  45     gldate       => DateTime->today_local->to_kivitendo,
  46     invoiceitems => $invoiceitems,
  47   );
  48   $invoice->assign_attributes(%params) if %params;
  49
  50   $invoice->post;
  51   return $invoice;
  52 }
  53
  54 sub create_sales_delivery_order {
  55   my (%params) = @_;
  56
  57   my $record_type = 'sales_delivery_order';
  58   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
  59   _check_items($orderitems, $record_type);
  60
  61   my $customer = $params{customer} // SL::Dev::CustomerVendor::create_customer(name => 'Testcustomer')->save;
  62   die "illegal customer" unless ref($customer) eq 'SL::DB::Customer';
  63
  64   my $delivery_order = SL::DB::DeliveryOrder->new(
  65     'is_sales'   => 'true',
  66     'closed'     => undef,
  67     customer_id  => $customer->id,
  68     taxzone_id   => $customer->taxzone_id,
  69     donumber     => $params{donumber}    // undef,
  70     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
  71     taxincluded  => $params{taxincluded} // 0,
  72     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  73     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  74     transdate    => $params{transdate}   // DateTime->today_local->to_kivitendo,
  75     orderitems   => $orderitems,
  76   );
  77   $delivery_order->assign_attributes(%params) if %params;
  78   $delivery_order->save;
  79   return $delivery_order;
  80 }
  81
  82 sub create_sales_order {
  83   my (%params) = @_;
  84
  85   my $record_type = 'sales_order';
  86   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
  87   _check_items($orderitems, $record_type);
  88
  89   my $save = delete $params{save} // 0;
  90
  91   my $customer = $params{customer} // SL::Dev::CustomerVendor::create_customer(name => 'Testcustomer')->save;
  92   die "illegal customer" unless ref($customer) eq 'SL::DB::Customer';
  93
  94   my $order = SL::DB::Order->new(
  95     customer_id  => delete $params{customer_id} // $customer->id,
  96     taxzone_id   => delete $params{taxzone_id}  // $customer->taxzone->id,
  97     currency_id  => delete $params{currency_id} // $::instance_conf->get_currency_id,
  98     taxincluded  => delete $params{taxincluded} // 0,
  99     # employee_id  => delete $params{employee_id} // SL::DB::Manager::Employee->current->id,
 100     # salesman_id  => delete $params{employee_id} // SL::DB::Manager::Employee->current->id,
 101     transdate    => delete $params{transdate}   // DateTime->today_local->to_kivitendo,
 102     orderitems   => $orderitems,
 103   );
 104   $order->assign_attributes(%params) if %params;
 105
 106   if ( $save ) {
 107     $order->calculate_prices_and_taxes;
 108     $order->save;
 109   }
 110   return $order;
 111 }
 112
 113 sub create_purchase_order {
 114   my (%params) = @_;
 115
 116   my $record_type = 'purchase_order';
 117   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
 118   _check_items($orderitems, $record_type);
 119
 120   my $save = delete $params{save} // 0;
 121
 122   my $vendor = $params{vendor} // SL::Dev::CustomerVendor::create_vendor(name => 'Testvendor')->save;
 123   die "illegal vendor" unless ref($vendor) eq 'SL::DB::Vendor';
 124
 125   my $order = SL::DB::Order->new(
 126     vendor_id    => delete $params{vendor_id}   // $vendor->id,
 127     taxzone_id   => delete $params{taxzone_id}  // $vendor->taxzone->id,
 128     currency_id  => delete $params{currency_id} // $::instance_conf->get_currency_id,
 129     taxincluded  => delete $params{taxincluded} // 0,
 130     transdate    => delete $params{transdate}   // DateTime->today_local->to_kivitendo,
 131     'closed'     => undef,
 132     orderitems   => $orderitems,
 133   );
 134   $order->assign_attributes(%params) if %params;
 135
 136   if ( $save ) {
 137     $order->calculate_prices_and_taxes; # not tested for purchase orders
 138     $order->save;
 139   }
 140   return $order;
 141 };
 142
 143 sub _check_items {
 144   my ($items, $record_type) = @_;
 145
 146   if  ( scalar @{$items} == 0 or grep { ref($_) ne $record_type_to_item_type{"$record_type"} } @{$items} ) {
 147     die "Error: items must be an arrayref of " . $record_type_to_item_type{"$record_type"} . "objects.";
 148   }
 149 }
 150
 151 sub create_invoice_item {
 152   my (%params) = @_;
 153
 154   return _create_item(record_type => 'sales_invoice', %params);
 155 }
 156
 157 sub create_order_item {
 158   my (%params) = @_;
 159
 160   return _create_item(record_type => 'sales_order', %params);
 161 }
 162
 163 sub create_delivery_order_item {
 164   my (%params) = @_;
 165
 166   return _create_item(record_type => 'sales_delivery_order', %params);
 167 }
 168
 169 sub _create_item {
 170   my (%params) = @_;
 171
 172   my $record_type = delete($params{record_type});
 173   my $part        = delete($params{part});
 174
 175   die "illegal record type: $record_type, must be one of: " . join(' ', keys %record_type_to_item_type) unless $record_type_to_item_type{ $record_type };
 176   die "part missing as param" unless $part && ref($part) eq 'SL::DB::Part';
 177
 178   my ($sellprice, $lastcost);
 179
 180   if ( $record_type =~ /^sales/ ) {
 181     $sellprice = delete $params{sellprice} // $part->sellprice;
 182     $lastcost  = delete $params{lastcost}  // $part->lastcost;
 183   } else {
 184     $sellprice = delete $params{sellprice} // $part->lastcost;
 185     $lastcost  = delete $params{lastcost}  // 0; # $part->lastcost;
 186   }
 187
 188   my $item = "$record_type_to_item_type{$record_type}"->new(
 189     parts_id    => $part->id,
 190     sellprice   => $sellprice,
 191     lastcost    => $lastcost,
 192     description => $part->description,
 193     unit        => $part->unit,
 194     qty         => $params{qty} || 5,
 195   );
 196   $item->assign_attributes(%params) if %params;
 197   return $item;
 198 }
 199
 200 sub _create_two_items {
 201   my ($record_type) = @_;
 202
 203   my $part1 = SL::Dev::Part::create_part(description => 'Testpart 1',
 204                                          sellprice   => 12,
 205                                         )->save;
 206   my $part2 = SL::Dev::Part::create_part(description => 'Testpart 2',
 207                                          sellprice   => 10,
 208                                         )->save;
 209   my $item1 = _create_item(record_type => $record_type, part => $part1, qty => 5);
 210   my $item2 = _create_item(record_type => $record_type, part => $part2, qty => 8);
 211   return [ $item1, $item2 ];
 212 }
 213
 214 sub create_project {
 215   my (%params) = @_;
 216   my $project = SL::DB::Project->new(
 217     projectnumber     => 1,
 218     description       => "Test project",
 219     active            => 1,
 220     valid             => 1,
 221     project_status_id => SL::DB::Manager::ProjectStatus->find_by(name => "running")->id,
 222     project_type_id   => SL::DB::Manager::ProjectType->find_by(description => "Standard")->id,
 223   )->save;
 224   $project->assign_attributes(%params) if %params;
 225   return $project;
 226 }
 227
 228 1;
 229
 230 __END__
 231
 232 =head1 NAME
 233
 234 SL::Dev::Record - create record objects for testing, with minimal defaults
 235
 236 =head1 FUNCTIONS
 237
 238 =head2 C<create_sales_invoice %PARAMS>
 239
 240 Creates a new sales invoice (table ar, invoice = 1).
 241
 242 If neither customer nor invoiceitems are passed as params a customer and two
 243 parts are created and used for building the invoice.
 244
 245 Minimal usage example:
 246
 247   my $invoice = SL::Dev::Record::create_sales_invoice();
 248
 249 Example with params:
 250
 251   my $invoice2 = SL::Dev::Record::create_sales_invoice(
 252     invnumber   => 777,
 253     transdate   => DateTime->today_local->subtract(days => 7),
 254     taxincluded => 1,
 255   );
 256
 257 =head2 C<create_sales_order %PARAMS>
 258
 259 Examples:
 260
 261 Create a sales order and save it directly via rose, without running
 262 calculate_prices_and_taxes:
 263
 264  my $order = SL::Dev::Record::create_sales_order()->save;
 265
 266 Let create_sales_order run calculate_prices_and_taxes and save:
 267
 268  my $order = SL::Dev::Record::create_sales_order(save => 1);
 269
 270
 271 Example including creation of part and of sales order.
 272   my $part1 = SL::Dev::Part::create_part(   partnumber => 'T4254')->save;
 273   my $part2 = SL::Dev::Part::create_service(partnumber => 'Serv1')->save;
 274   my $order = SL::Dev::Record::create_sales_order(
 275     save         => 1,
 276     taxincluded  => 0,
 277     orderitems => [ SL::Dev::Record::create_order_item(part => $part1, qty =>  3, sellprice => 70),
 278                     SL::Dev::Record::create_order_item(part => $part2, qty => 10, sellprice => 50),
 279                   ]
 280   );
 281
 282 =head2 C<create_purchase_order %PARAMS>
 283
 284 See comments for C<create_sales_order>.
 285
 286 Example:
 287  my $purchase_order = SL::Dev::Record::create_purchase_order(save => 1);
 288
 289
 290 =head2 C<create_item %PARAMS>
 291
 292 Creates an item from a part object that can be added to a record.
 293
 294 Required params: record_type (sales_invoice, sales_order, sales_delivery_order)
 295                  part        (an SL::DB::Part object)
 296
 297 Example including creation of part and of invoice:
 298   my $part    = SL::Dev::Part::create_part(  partnumber  => 'T4254')->save;
 299   my $item    = SL::Dev::Record::create_item(record_type => 'sales_invoice', part => $part, qty => 2.5);
 300   my $invoice = SL::Dev::Record::create_sales_invoice(
 301     taxincluded  => 0,
 302     invoiceitems => [ $item ],
 303   );
 304
 305 =head2 C<create_project %PARAMS>
 306
 307 Creates a default project.
 308
 309 Minimal example, creating a project with status "running" and type "Standard":
 310   my $project = SL::Dev::Record::create_project();
 311
 312   $project = SL::Dev::Record::create_project(
 313     projectnumber => 'p1',
 314     description   => 'Test project',
 315   )
 316
 317 =head1 TODO
 318
 319 =head1 BUGS
 320
 321 Nothing here yet.
 322
 323 =head1 AUTHOR
 324
 325 G. Richardson E<lt>grichardson@kivitendo-premium.deE<gt>
 326
 327 =cut