SL/Controller/RequirementSpecItem.pm

   1 package SL::Controller::RequirementSpecItem;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Carp;
   8 use List::MoreUtils qw(apply);
   9 use List::Util qw(first);
  10 use Time::HiRes ();
  11
  12 use SL::Clipboard;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::RequirementSpec;
  15 use SL::DB::RequirementSpecComplexity;
  16 use SL::DB::RequirementSpecItem;
  17 use SL::DB::RequirementSpecRisk;
  18 use SL::Helper::Flash;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar                  => [ qw(item visible_item visible_section clicked_item sections) ],
  25   'scalar --get_set_init' => [ qw(complexities risks js) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('load_requirement_spec_item', only => [ qw(dragged_and_dropped ajax_update ajax_edit ajax_delete ajax_flag ajax_copy) ]);
  30 __PACKAGE__->run_before('init_visible_section');
  31
  32 #
  33 # actions
  34 #
  35
  36 sub action_ajax_list {
  37   my ($self) = @_;
  38
  39   if (!$::form->{clicked_id}) {
  40     # Clicked on "sections" in the tree. Do nothing.
  41     return $self->render($self->js);
  42   }
  43
  44   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $::form->{clicked_id})->load;
  45   $self->item($clicked_item->section);
  46
  47   if (!$self->visible_section || ($self->visible_section->id != $self->item->id)) {
  48     $self->render_list($self->item, $clicked_item);
  49   } else {
  50     $self->select_node($clicked_item);
  51   }
  52
  53   $self->render($self->js);
  54 }
  55
  56 sub insert_new_item_in_section_view {
  57   my ($self) = @_;
  58
  59   $self->js->hide('#section-list-empty');
  60
  61   my $new_type  = $self->item->item_type;
  62   my $id_prefix = $new_type eq 'sub-function-block' ? 'sub-' : '';
  63   my $template  = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $new_type);
  64   my $html      = "" . $self->render($template, { output => 0 }, requirement_spec_item => $self->item);
  65   my $next_item = $self->item->get_next_in_list;
  66
  67   if ($next_item) {
  68     $self->js->insertBefore($html, '#' . $id_prefix . 'function-block-' . $next_item->id);
  69   } else {
  70     my $parent_is_section = $self->item->parent->item_type eq 'section';
  71     $self->js->appendTo($html, $parent_is_section ? '#section-list' : '#sub-function-block-container-' . $self->item->parent_id);
  72     $self->js->show('#sub-function-block-container-' . $self->item->parent_id) if !$parent_is_section;
  73   }
  74
  75   $self->replace_bottom($self->item->parent) if $new_type eq 'sub-function-block';
  76 }
  77
  78 sub action_dragged_and_dropped {
  79   my ($self)              = @_;
  80
  81   my $position            = $::form->{position} =~ m/^ (?: before | after | last ) $/x ? $::form->{position}                                             : die "Unknown 'position' parameter";
  82   my $dropped_item        = $::form->{dropped_id}                                  ? SL::DB::RequirementSpecItem->new(id => $::form->{dropped_id})->load : undef;
  83
  84   my $old_visible_section = $self->visible_section ? $self->visible_section : undef;
  85   my $old_parent_id       = $self->item->parent_id;
  86   my $old_type            = $self->item->item_type;
  87   my $new_type            = !$dropped_item ? 'section' : $position =~ m/before|after/ ? $dropped_item->item_type : $dropped_item->child_type;
  88
  89   $self->item->db->do_transaction(sub {
  90     $self->item->remove_from_list;
  91     $self->item->parent_id($position =~ m/before|after/ ? $dropped_item->parent_id : $dropped_item->id) if $dropped_item;
  92     $self->item->item_type($new_type);
  93     $self->item->add_to_list(position => $position, reference => $::form->{dropped_id} || undef);
  94   });
  95
  96   $self->item(SL::DB::RequirementSpecItem->new(id => $self->item->id)->load);
  97   my $new_section         = $self->item->section;
  98   my $new_visible_section = SL::DB::RequirementSpecItem->new(id => $self->visible_item->id)->load->section;
  99
 100   return $self->invalidate_version->render($self) if !$old_visible_section || ($new_type eq 'section');
 101
 102   # From here on $old_visible_section is definitely set.
 103
 104   my $old_parent  = SL::DB::RequirementSpecItem->new(id => $old_parent_id)->load;
 105   my $old_section = $old_parent->section;
 106
 107   # Section debug info:
 108   # $::lxdebug->message(0, "old sec ID " . $old_section->id . " new " . $new_section->id . " old visible " . $old_visible_section->id . " new visible " . $new_visible_section->id
 109   #                       . " PARENT: old " . $old_parent->id . " new " . $self->item->parent_id . '/' . $self->item->parent->id);
 110
 111   # Item debug info:
 112   # $::lxdebug->message(0, 'item id: ' . $self->item->id . " new type: $new_type old type: $old_type #old children: " . scalar(@{ $old_parent->children }));
 113
 114   if ($old_visible_section->id != $new_visible_section->id) {
 115     # The currently visible item has been dragged to a different section.
 116     $self->invalidate_version;
 117     return $self->render_list($new_section, $self->item)
 118       ->render($self);
 119   }
 120
 121   if ($old_visible_section->id == $old_section->id) {
 122     my $id_prefix = $old_type eq 'sub-function-block' ? 'sub-' : '';
 123     $self->js->remove('#' . $id_prefix . 'function-block-' . $self->item->id);
 124
 125     if ($old_type eq 'sub-function-block') {
 126       $self->replace_bottom($old_parent) ;
 127       $self->js->hide('#sub-function-block-container-' . $old_parent->id) if 0 == scalar(@{ $old_parent->children });
 128
 129     } elsif (0 == scalar(@{ $old_section->children })) {
 130       $self->js->show('#section-list-empty');
 131     }
 132   }
 133
 134   if ($old_visible_section->id == $new_section->id) {
 135     $self->insert_new_item_in_section_view($self->js);
 136   }
 137
 138   # $::lxdebug->dump(0, "js", $self->js->to_array);
 139
 140   $self->invalidate_version->render($self);
 141 }
 142
 143 sub action_ajax_add_section {
 144   my ($self, %params) = @_;
 145
 146   die "Missing parameter 'requirement_spec_id'" if !$::form->{requirement_spec_id};
 147
 148   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, item_type => 'section'));
 149
 150   my $insert_after = $::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load->section->id : undef;
 151   my $html         = $self->render('requirement_spec_item/_section_form', { output => 0 }, id_base => 'new_section', insert_after => $insert_after);
 152
 153   $self->js
 154     ->remove('#new_section_form')
 155     ->hide('#column-content > *')
 156     ->appendTo($html, '#column-content')
 157     ->focus('#new_section_title')
 158     ->render($self);
 159 }
 160
 161 sub action_ajax_add_function_block {
 162   my ($self, %params) = @_;
 163
 164   return $self->add_function_block('function-block');
 165 }
 166
 167 sub action_ajax_add_sub_function_block {
 168   my ($self, %params) = @_;
 169
 170   return $self->add_function_block('sub-function-block');
 171 }
 172
 173 sub action_ajax_create {
 174   my ($self, %params) = @_;
 175
 176   my $prefix          = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 177   my $attributes      = $::form->{$prefix}     || die "Missing parameter group '${prefix}'";
 178   my $insert_after    = delete $attributes->{insert_after};
 179
 180   if (!$attributes->{parent_id}) {
 181     $attributes->{order_part_id} ||= $::instance_conf->get_requirement_spec_section_order_part_id;
 182   }
 183
 184   my @errors = $self->item(SL::DB::RequirementSpecItem->new(%{ $attributes }))->validate;
 185   return $self->js->error(@errors)->render($self) if @errors;
 186
 187   $self->item->save;
 188   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 189
 190   my $type = $self->item->item_type;
 191
 192   if ($type eq 'section') {
 193     my $node = $self->presenter->requirement_spec_item_jstree_data($self->item);
 194     $self->invalidate_version;
 195     $self->render_list($self->item)
 196       ->hide('#section-list-empty')
 197       ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#sections', 'last'), $node)
 198       ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 199     return $self->add_new_item_form_after_create
 200       ->render($self);
 201   }
 202
 203   my $template = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $type);
 204   my $html     = $self->render($template, { output => 0 }, requirement_spec_item => $self->item, id_prefix => $type eq 'function-block' ? '' : 'sub-');
 205   my $node     = $self->presenter->requirement_spec_item_jstree_data($self->item);
 206
 207   $self->js
 208     ->replaceWith('#' . $prefix . '_form', $html)
 209     ->hide('#section-list-empty')
 210     ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#fb-' . $self->item->parent_id, 'last'), $node)
 211     ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 212
 213   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 214
 215   $self->add_new_item_form_after_create;
 216
 217   $self->invalidate_version->render($self);
 218 }
 219
 220 sub action_ajax_edit {
 221   my ($self, %params) = @_;
 222
 223   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 224
 225   if (!$self->is_item_visible) {
 226     # Show section/item to edit if it is not visible.
 227
 228     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item->section);
 229     $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 230       ->html('#column-content', $html);
 231   }
 232
 233   if ($self->item->item_type =~ m/section/) {
 234     # Edit the section header, not an item.
 235     my $html = $self->render('requirement_spec_item/_section_form', { output => 0 });
 236
 237     $self->js
 238       ->hide('#section-header-' . $self->item->id)
 239       ->remove("#edit_section_form")
 240       ->insertAfter($html, '#section-header-' . $self->item->id)
 241       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 242       ->focus("#edit_section_title")
 243       ->val('#current_content_type', 'section')
 244       ->val('#current_content_id',   $self->item->id)
 245       ->render($self);
 246     return;
 247   }
 248
 249   # Edit a function block or a sub function block
 250   my @dependencies          = $self->create_dependencies;
 251   my @selected_dependencies = map { $_->id } @{ $self->item->dependencies };
 252
 253   my $html                  = $self->render('requirement_spec_item/_function_block_form', { output => 0 }, DEPENDENCIES => \@dependencies, SELECTED_DEPENDENCIES => \@selected_dependencies);
 254   my $id_base               = 'edit_function_block_' . $self->item->id;
 255   my $content_top_id        = '#' . $self->item->item_type . '-content-top-' . $self->item->id;
 256
 257   $self->js
 258     ->hide($content_top_id)
 259     ->remove("#${id_base}_form")
 260     ->insertAfter($html, $content_top_id)
 261     ->on("#${id_base}_form INPUT[type=text]", "keydown", "kivi.requirement_spec.text_block_input_key_down")
 262     ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 263     ->focus("#${id_base}_description")
 264     ->val('#current_content_type', $self->item->item_type)
 265     ->val('#current_content_id', $self->item->id)
 266     ->render($self);
 267 }
 268
 269 sub action_ajax_update {
 270   my ($self, %params) = @_;
 271
 272   my $prefix     = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 273   my $attributes = $::form->{$prefix}     || {};
 274
 275   foreach (qw(requirement_spec_id parent_id position)) {
 276     delete $attributes->{$_} if !defined $attributes->{$_};
 277   }
 278
 279   my @errors = $self->item->assign_attributes(%{ $attributes })->validate;
 280   return $self->js->error(@errors)->render($self) if @errors;
 281
 282   $self->item->save;
 283
 284   my $type = $self->item->item_type;
 285
 286   if ($type eq 'section') {
 287     # Updated section, now update section header.
 288
 289     my $html = $self->render('requirement_spec_item/_section_header', { output => 0 }, requirement_spec_item => $self->item);
 290
 291     return $self->invalidate_version
 292       ->remove('#edit_section_form')
 293       ->html('#section-header-' . $self->item->id, $html)
 294       ->show('#section-header-' . $self->item->id)
 295       ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item))
 296       ->render($self);
 297   }
 298
 299   # Updated function block or sub function block. Update (sub)
 300   # function block and potentially the bottom of the parent function
 301   # block.
 302
 303   my $id_prefix    = $type eq 'function-block' ? '' : 'sub-';
 304   my $html_top     = $self->render('requirement_spec_item/_function_block_content_top',    { output => 0 }, requirement_spec_item => $self->item, id_prefix => $id_prefix);
 305   $id_prefix      .= 'function-block-content-';
 306
 307   $self->js
 308     ->remove('#' . $prefix . '_form')
 309     ->replaceWith('#' . $id_prefix . 'top-' . $self->item->id, $html_top)
 310     ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item));
 311
 312   $self->replace_bottom($self->item, id_prefix => $id_prefix);
 313   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 314
 315   $self->invalidate_version->render($self);
 316 }
 317
 318 sub action_ajax_delete {
 319   my ($self) = @_;
 320
 321   my $full_list = $self->item->get_full_list;
 322
 323   $self->item->delete;
 324
 325   if ($self->visible_section && ($self->visible_section->id == $self->item->id)) {
 326     # Currently visible section is deleted.
 327
 328     my $new_section = first { $_->id != $self->item->id } @{ $self->item->requirement_spec->sections };
 329     if ($new_section) {
 330       $self->render_list($new_section);
 331
 332     } else {
 333       my $html = $self->render('requirement_spec_item/_no_section', { output => 0 });
 334       $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 335         ->html('#column-content',      $html)
 336         ->val('#current_content_type', '')
 337         ->val('#current_content_id',   '')
 338     }
 339
 340   } elsif ($self->is_item_visible) {
 341     # Item in currently visible section is deleted.
 342
 343     my $type = $self->item->item_type;
 344     $self->js->remove('#edit_function_block_' . $self->item->id . '_form')
 345              ->remove('#' . $type . '-' . $self->item->id);
 346
 347     $self->replace_bottom($self->item->parent_id) if $type eq 'sub-function-block';
 348
 349     if (1 == scalar @{ $full_list }) {
 350       if ($type eq 'function-block') {
 351         $self->js->show('#section-list-empty');
 352       } elsif ($type eq 'sub-function-block') {
 353         $self->js->hide('#sub-function-block-container-' . $self->item->parent_id);
 354       }
 355     }
 356   }
 357
 358   $self->invalidate_version
 359     ->jstree->delete_node('#tree', '#fb-' . $self->item->id)
 360     ->render($self);
 361 }
 362
 363 sub action_ajax_flag {
 364   my ($self) = @_;
 365
 366   $self->item->update_attributes(is_flagged => !$self->item->is_flagged);
 367
 368   $self->js
 369    ->action_if($self->is_item_visible, 'toggleClass', '#' . $self->item->item_type . '-' . $self->item->id, 'flagged')
 370    ->toggleClass('#fb-' . $self->item->id, 'flagged')
 371    ->render($self);
 372 }
 373
 374 sub action_ajax_copy {
 375   my ($self, %params) = @_;
 376
 377   SL::Clipboard->new->copy($self->item);
 378   $self->render($self->js);
 379 }
 380
 381 sub determine_paste_position {
 382   my ($self) = @_;
 383
 384   if ($self->item->item_type eq 'section') {
 385     # Sections are always pasted either directly after the
 386     # clicked-upon section or at the very end.
 387     return $self->clicked_item ? (undef, $self->clicked_item->section->id) : ();
 388
 389   } elsif ($self->item->item_type eq 'function-block') {
 390     # A function block:
 391     # - paste on section list: insert into last section as last element
 392     # - paste on section: insert into that section as last element
 393     # - paste on function block: insert after clicked-upon element
 394     # - paste on sub function block: insert after parent function block of clicked-upon element
 395     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,              undef                          )
 396          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,                undef                          )
 397          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->parent_id,         $self->clicked_item->id        )
 398          :                                                       ( $self->clicked_item->parent->parent_id, $self->clicked_item->parent_id );
 399
 400   } else {                      # sub-function-block
 401     # A sub function block:
 402     # - paste on section list: promote to function block and insert into last section as last element
 403     # - paste on section: promote to function block and insert into that section as last element
 404     # - paste on function block: insert as last element in clicked-upon element
 405     # - paste on sub function block: insert after clicked-upon element
 406
 407     # Promote sub function blocks to function blocks when pasting on a
 408     # section or the section list.
 409     $self->item->item_type('function-block') if !$self->clicked_item || ($self->clicked_item->item_type eq 'section');
 410
 411     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,      undef                   )
 412          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,        undef                   )
 413          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->id,        undef                   )
 414          :                                                       ( $self->clicked_item->parent_id, $self->clicked_item->id );
 415   }
 416 }
 417
 418 sub assign_requirement_spec_id_rec {
 419   my ($self, $item) = @_;
 420
 421   $item->assign_attributes(requirement_spec_id => $::form->{requirement_spec_id}, fb_number => undef);
 422   $self->assign_requirement_spec_id_rec($_) for @{ $item->children || [] };
 423
 424   return $item;
 425 }
 426
 427 sub create_and_insert_node_rec {
 428   my ($self, $item, $new_parent_id, $insert_after) = @_;
 429
 430   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 431   $self->js->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : $new_parent_id ? ('#fb-' . $new_parent_id, 'last') : ('#sections', 'last'), $node);
 432
 433   $self->create_and_insert_node_rec($_, $item->id) for @{ $item->children || [] };
 434
 435   $self->js->jstree->open_node('#tree', '#fb-' . $item->id);
 436 }
 437
 438 sub action_ajax_paste {
 439   my ($self, %params) = @_;
 440
 441   my $copied = SL::Clipboard->new->get_entry(qr/^RequirementSpecItem$/);
 442
 443   if (!$copied) {
 444     return $self->js->error(t8("The clipboard does not contain anything that can be pasted here."))
 445                     ->render($self);
 446   }
 447
 448   $self->item($self->assign_requirement_spec_id_rec($copied->to_object));
 449   my $req_spec = SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load;
 450   $self->sections($req_spec->sections);
 451
 452   if (($self->item->item_type ne 'section') && !@{ $self->sections }) {
 453     return $self->js->error(t8("You cannot paste function blocks or sub function blocks if there is no section."))
 454                     ->render($self);
 455   }
 456
 457   $self->clicked_item($::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load : undef);
 458
 459   my ($new_parent_id, $insert_after) = $self->determine_paste_position;
 460
 461   # Store result in database.
 462   $self->item->update_attributes(parent_id => $new_parent_id);
 463   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 464
 465   # Update the tree: create the node for all pasted objects.
 466   $self->create_and_insert_node_rec($self->item, $new_parent_id, $insert_after);
 467
 468   # Pasting the very first section?
 469   if (!@{ $self->sections }) {
 470     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item);
 471     $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 472          ->html('#column-content', $html)
 473          ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 474   }
 475
 476   # Update the current view if required.
 477   $self->insert_new_item_in_section_view($self->js) if $self->is_item_visible;
 478
 479   $self->invalidate_version->render($self);
 480 }
 481
 482 #
 483 # filters
 484 #
 485
 486 sub check_auth {
 487   my ($self) = @_;
 488   $::auth->assert('sales_quotation_edit');
 489 }
 490
 491 sub load_requirement_spec_item {
 492   my ($self) = @_;
 493   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 494 }
 495
 496 #
 497 # helpers
 498 #
 499
 500 sub create_random_id {
 501   return join '-', Time::HiRes::gettimeofday();
 502 }
 503
 504 sub format_exception {
 505   return join "\n", (split m/\n/, $@)[0..4];
 506 }
 507
 508 sub init_complexities {
 509   my ($self) = @_;
 510
 511   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 512 }
 513
 514 sub init_risks {
 515   my ($self) = @_;
 516
 517   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 518 }
 519
 520 sub init_js {
 521   my ($self) = @_;
 522   $self->js(SL::ClientJS->new);
 523 }
 524
 525 sub replace_bottom {
 526   my ($self, $item_or_id) = @_;
 527
 528   my $item      = (ref($item_or_id) ? $item_or_id : SL::DB::RequirementSpecItem->new(id => $item_or_id))->load;
 529   my $id_prefix = $item->item_type eq 'function-block' ? '' : 'sub-';
 530   my $html      = $self->render('requirement_spec_item/_function_block_content_bottom', { output => 0 }, requirement_spec_item => $item, id_prefix => $id_prefix);
 531   return $self->js->replaceWith('#' . $id_prefix . 'function-block-content-bottom-' . $item->id, $html);
 532 }
 533
 534 sub render_list {
 535   my ($self, $item, $item_to_select) = @_;
 536
 537   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $item);
 538   $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 539        ->html('#column-content', $html);
 540   $self->select_node($item_to_select || $item);
 541 }
 542
 543 sub select_node {
 544   my ($self, $item) = @_;
 545
 546   $self->js
 547     ->val( '#current_content_type', $item->item_type)
 548     ->val( '#current_content_id',   $item->id)
 549     ->jstree->select_node('#tree', '#fb-' . $item->id);
 550 }
 551
 552 sub create_dependency_item {
 553   my $self = shift;
 554   [ $_[0]->id, $self->presenter->truncate(join(' ', grep { $_ } ($_[1], $_[0]->fb_number, $_[0]->description))) ];
 555 }
 556
 557 sub create_dependencies {
 558   my ($self) = @_;
 559
 560   return map { [ $_->fb_number . ' ' . $_->title,
 561                  [ map { ( $self->create_dependency_item($_),
 562                            map { $self->create_dependency_item($_, '->') } @{ $_->children_sorted })
 563                        } @{ $_->children_sorted } ] ]
 564              } @{ $self->item->requirement_spec->sections };
 565 }
 566
 567 sub ensure_section_is_shown {
 568   my ($self, %params) = @_;
 569
 570   return $self->js if $self->is_item_visible;
 571
 572   # Show section/item to edit if it is not visible.
 573   my $new_section = $self->item->section;
 574   my $html        = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $new_section);
 575
 576   return $self->set_function_blocks_tab_menu_class(class => 'section-context-menu')
 577     ->html('#column-content', $html)
 578     ->val('#current_content_type', 'section')
 579     ->val('#current_content_id',   $new_section->id)
 580     ->jstree->select_node('#tree', '#fb-' . $new_section->id);
 581 }
 582
 583 sub add_new_item_form {
 584   my ($self, %params) = @_;
 585
 586   for (qw(insert_position display_reference)) {
 587     croak "Missing parameter $_" if !$params{$_};
 588   }
 589   croak "Missing parameter insert_reference" if ($params{insert_position} eq 'insertAfter') && !$params{insert_reference};
 590
 591   my $id_base = join('_', 'new_function_block', Time::HiRes::gettimeofday(), int rand 1000000000000);
 592   my $html    = $self->render(
 593     'requirement_spec_item/_function_block_form',
 594     { output => 0 },
 595     DEPENDENCIES          => [ $self->create_dependencies ],
 596     SELECTED_DEPENDENCIES => [],
 597     requirement_spec_item => $self->item,
 598     id_base               => $id_base,
 599     insert_after          => $params{insert_position} eq 'insertAfter' ? $params{insert_reference} : undef,
 600   );
 601
 602   return $self->js
 603     ->action($params{insert_position}, $html, $params{display_reference})
 604     ->focus("#${id_base}_description");
 605 }
 606
 607 sub add_new_item_form_after_create {
 608   my ($self, %params) = @_;
 609
 610   my $created_item    = $self->item;
 611   my $is_section      = $created_item->item_type eq 'section';
 612
 613   $self->item(SL::DB::RequirementSpecItem->new(
 614     requirement_spec_id => $created_item->requirement_spec_id,
 615     parent_id           => $is_section ? $created_item->id : $created_item->parent_id,
 616     item_type           => $is_section ? 'function-block'  : $created_item->item_type,
 617   ));
 618
 619   $self->add_new_item_form(
 620     insert_reference  => $created_item->id,
 621     insert_position   => $is_section ? 'appendTo'      : 'insertAfter',
 622     display_reference => $is_section ? '#section-list' : '#' . $created_item->item_type . '-' . $created_item->id,
 623   );
 624 }
 625
 626 sub add_function_block {
 627   my ($self, $new_type) = @_;
 628
 629   my $clicked_id = $::form->{id} || ($self->visible_item ? $self->visible_item->id : undef);
 630
 631   die "Invalid new_type '$new_type'"               if $new_type !~ m/^(?:sub-)?function-block$/;
 632   die "Missing parameter 'id' and no visible item" if !$clicked_id;
 633   die "Missing parameter 'requirement_spec_id'"    if !$::form->{requirement_spec_id};
 634
 635   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $clicked_id)->load;
 636   my $clicked_type = $clicked_item->item_type;
 637
 638   die "Invalid clicked_type '$clicked_type'" if $clicked_type !~ m/^(?: section | (?:sub-)? function-block )$/x;
 639
 640   my $case = "${clicked_type}:${new_type}";
 641
 642   my ($insert_position, $insert_reference, $parent_id, $display_reference)
 643     = $case eq 'section:function-block'                ? ( 'appendTo',    $clicked_item->id,        $clicked_item->id,                '#section-list'                  )
 644     : $case eq 'function-block:function-block'         ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#function-block-'               )
 645     : $case eq 'function-block:sub-function-block'     ? ( 'appendTo'  ,  $clicked_item->id,        $clicked_item->id,                '#sub-function-block-container-' )
 646     : $case eq 'sub-function-block:function-block'     ? ( 'insertAfter', $clicked_item->parent_id, $clicked_item->parent->parent_id, '#function-block-'               )
 647     : $case eq 'sub-function-block:sub-function-block' ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#sub-function-block-'           )
 648     :                                                    die "Invalid combination of 'clicked_type (section)/new_type ($new_type)'";
 649
 650   $display_reference .= $insert_reference if $display_reference =~ m/-$/;
 651
 652   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $parent_id, item_type => $new_type));
 653
 654   $self->ensure_section_is_shown;
 655   $self->js->show('#sub-function-block-container-' . $parent_id) if $new_type eq 'sub-function-block';
 656   $self->add_new_item_form(insert_position => $insert_position, insert_reference => $insert_reference, display_reference => $display_reference);
 657
 658   $self->js->render($self);
 659 }
 660
 661 sub is_item_visible {
 662   my ($self, $item) = @_;
 663
 664   $item ||= $self->item;
 665   return $self->visible_section && ($self->visible_section->id == $item->section->id);
 666 }
 667
 668 sub invalidate_version {
 669   my ($self) = @_;
 670
 671   my $html   = $self->render('requirement_spec/_version', { output => 0 },
 672                              requirement_spec => SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id} || $self->item->requirement_spec_id)->load);
 673   return $self->js->html('#requirement_spec_version', $html);
 674 }
 675
 676 1;