SL/Controller/BankTransaction.pm

   1 package SL::Controller::BankTransaction;
   2
   3 # idee- möglichkeit bankdaten zu übernehmen in stammdaten
   4 # erst Kontenabgleich, um alle gl-Einträge wegzuhaben
   5 use strict;
   6
   7 use parent qw(SL::Controller::Base);
   8
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::ReportGenerator;
  12
  13 use SL::DB::BankTransaction;
  14 use SL::Helper::Flash;
  15 use SL::Locale::String;
  16 use SL::SEPA;
  17 use SL::DB::Invoice;
  18 use SL::DB::PurchaseInvoice;
  19 use SL::DB::RecordLink;
  20 use SL::JSON;
  21 use SL::DB::Chart;
  22 use SL::DB::AccTransaction;
  23 use SL::DB::Tax;
  24 use SL::DB::Draft;
  25 use SL::DB::BankAccount;
  26 use SL::DBUtils qw(like);
  27 use SL::Presenter;
  28 use List::Util qw(max);
  29
  30 use Rose::Object::MakeMethods::Generic
  31 (
  32  'scalar --get_set_init' => [ qw(models) ],
  33 );
  34
  35 __PACKAGE__->run_before('check_auth');
  36
  37
  38 #
  39 # actions
  40 #
  41
  42 sub action_search {
  43   my ($self) = @_;
  44
  45   my $bank_accounts = SL::DB::Manager::BankAccount->get_all_sorted( query => [ obsolete => 0 ] );
  46
  47   $self->render('bank_transactions/search',
  48                  BANK_ACCOUNTS => $bank_accounts);
  49 }
  50
  51 sub action_list_all {
  52   my ($self) = @_;
  53
  54   $self->make_filter_summary;
  55   $self->prepare_report;
  56
  57   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  58 }
  59
  60 sub action_list {
  61   my ($self) = @_;
  62
  63   if (!$::form->{filter}{bank_account}) {
  64     flash('error', t8('No bank account chosen!'));
  65     $self->action_search;
  66     return;
  67   }
  68
  69   my $sort_by = $::form->{sort_by} || 'transdate';
  70   $sort_by = 'transdate' if $sort_by eq 'proposal';
  71   $sort_by .= $::form->{sort_dir} ? ' DESC' : ' ASC';
  72
  73   my $fromdate = $::locale->parse_date_to_object($::form->{filter}->{fromdate});
  74   my $todate   = $::locale->parse_date_to_object($::form->{filter}->{todate});
  75   $todate->add( days => 1 ) if $todate;
  76
  77   my @where = ();
  78   push @where, (transdate => { ge => $fromdate }) if ($fromdate);
  79   push @where, (transdate => { lt => $todate })   if ($todate);
  80   my $bank_account = SL::DB::Manager::BankAccount->find_by( id => $::form->{filter}{bank_account} );
  81   # bank_transactions no younger than starting date,
  82   # including starting date (same search behaviour as fromdate)
  83   # but OPEN invoices to be matched may be from before
  84   if ( $bank_account->reconciliation_starting_date ) {
  85     push @where, (transdate => { ge => $bank_account->reconciliation_starting_date });
  86   };
  87
  88   my $bank_transactions = SL::DB::Manager::BankTransaction->get_all(where => [ amount => {ne => \'invoice_amount'},
  89                                                                                local_bank_account_id => $::form->{filter}{bank_account},
  90                                                                                @where ],
  91                                                                     with_objects => [ 'local_bank_account', 'currency' ],
  92                                                                     sort_by => $sort_by, limit => 10000);
  93
  94   my $all_open_ar_invoices = SL::DB::Manager::Invoice->get_all(where => [amount => { gt => \'paid' }], with_objects => 'customer');
  95   my $all_open_ap_invoices = SL::DB::Manager::PurchaseInvoice->get_all(where => [amount => { gt => \'paid' }], with_objects => 'vendor');
  96
  97   my @all_open_invoices;
  98   # filter out invoices with less than 1 cent outstanding
  99   push @all_open_invoices, grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ar_invoices };
 100   push @all_open_invoices, grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ap_invoices };
 101
 102   # try to match each bank_transaction with each of the possible open invoices
 103   # by awarding points
 104
 105   foreach my $bt (@{ $bank_transactions }) {
 106     next unless $bt->{remote_name};  # bank has no name, usually fees, use create invoice to assign
 107
 108     $bt->{remote_name} .= $bt->{remote_name_1} if $bt->{remote_name_1};
 109
 110     # try to match the current $bt to each of the open_invoices, saving the
 111     # results of get_agreement_with_invoice in $open_invoice->{agreement} and
 112     # $open_invoice->{rule_matches}.
 113
 114     # The values are overwritten each time a new bt is checked, so at the end
 115     # of each bt the likely results are filtered and those values are stored in
 116     # the arrays $bt->{proposals} and $bt->{rule_matches}, and the agreement
 117     # score is stored in $bt->{agreement}
 118
 119     foreach my $open_invoice (@all_open_invoices){
 120       ($open_invoice->{agreement}, $open_invoice->{rule_matches}) = $bt->get_agreement_with_invoice($open_invoice);
 121     };
 122
 123     $bt->{proposals} = [];
 124
 125     my $agreement = 15;
 126     my $min_agreement = 3; # suggestions must have at least this score
 127
 128     my $max_agreement = max map { $_->{agreement} } @all_open_invoices;
 129
 130     # add open_invoices with highest agreement into array $bt->{proposals}
 131     if ( $max_agreement >= $min_agreement ) {
 132       $bt->{proposals} = [ grep { $_->{agreement} == $max_agreement } @all_open_invoices ];
 133       $bt->{agreement} = $max_agreement; #scalar @{ $bt->{proposals} } ? $agreement + 1 : '';
 134
 135       # store the rule_matches in a separate array, so they can be displayed in template
 136       foreach ( @{ $bt->{proposals} } ) {
 137         push(@{$bt->{rule_matches}}, $_->{rule_matches});
 138       };
 139     };
 140   }  # finished one bt
 141   # finished all bt
 142
 143   # separate filter for proposals (second tab, agreement >= 5 and exactly one match)
 144   # to qualify as a proposal there has to be
 145   # * agreement >= 5  TODO: make threshold configurable in configuration
 146   # * there must be only one exact match
 147   # * depending on whether sales or purchase the amount has to have the correct sign (so Gutschriften don't work?)
 148   my $proposal_threshold = 5;
 149   my @proposals = grep { $_->{agreement} >= $proposal_threshold
 150                          and 1 == scalar @{ $_->{proposals} }
 151                          and (@{ $_->{proposals} }[0]->is_sales ? abs(@{ $_->{proposals} }[0]->amount - $_->amount) < 0.01  : abs(@{ $_->{proposals} }[0]->amount + $_->amount) < 0.01) } @{ $bank_transactions };
 152
 153   # sort bank transaction proposals by quality (score) of proposal
 154   $bank_transactions = [ sort { $a->{agreement} <=> $b->{agreement} } @{ $bank_transactions } ] if $::form->{sort_by} eq 'proposal' and $::form->{sort_dir} == 1;
 155   $bank_transactions = [ sort { $b->{agreement} <=> $a->{agreement} } @{ $bank_transactions } ] if $::form->{sort_by} eq 'proposal' and $::form->{sort_dir} == 0;
 156
 157
 158   $self->render('bank_transactions/list',
 159                 title             => t8('Bank transactions MT940'),
 160                 BANK_TRANSACTIONS => $bank_transactions,
 161                 PROPOSALS         => \@proposals,
 162                 bank_account      => $bank_account );
 163 }
 164
 165 sub action_assign_invoice {
 166   my ($self) = @_;
 167
 168   $self->{transaction} = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 169
 170   $self->render('bank_transactions/assign_invoice', { layout  => 0 },
 171                 title      => t8('Assign invoice'),);
 172 }
 173
 174 sub action_create_invoice {
 175   my ($self) = @_;
 176   my %myconfig = %main::myconfig;
 177
 178   $self->{transaction} = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 179   my $vendor_of_transaction = SL::DB::Manager::Vendor->find_by(account_number => $self->{transaction}->{remote_account_number});
 180
 181   my $use_vendor_filter = $self->{transaction}->{remote_account_number} && $vendor_of_transaction;
 182
 183   my $drafts = SL::DB::Manager::Draft->get_all(where => [ module => 'ap'] , with_objects => 'employee');
 184
 185   my @filtered_drafts;
 186
 187   foreach my $draft ( @{ $drafts } ) {
 188     my $draft_as_object = YAML::Load($draft->form);
 189     my $vendor = SL::DB::Manager::Vendor->find_by(id => $draft_as_object->{vendor_id});
 190     $draft->{vendor} = $vendor->name;
 191     $draft->{vendor_id} = $vendor->id;
 192     push @filtered_drafts, $draft;
 193   }
 194
 195   #Filter drafts
 196   @filtered_drafts = grep { $_->{vendor_id} == $vendor_of_transaction->id } @filtered_drafts if $use_vendor_filter;
 197
 198   my $all_vendors = SL::DB::Manager::Vendor->get_all();
 199
 200   $self->render('bank_transactions/create_invoice', { layout  => 0 },
 201       title      => t8('Create invoice'),
 202       DRAFTS     => \@filtered_drafts,
 203       vendor_id  => $use_vendor_filter ? $vendor_of_transaction->id : undef,
 204       vendor_name => $use_vendor_filter ? $vendor_of_transaction->name : undef,
 205       ALL_VENDORS => $all_vendors,
 206       limit      => $myconfig{vclimit},
 207       callback   => $self->url_for(action                => 'list',
 208                                    'filter.bank_account' => $::form->{filter}->{bank_account},
 209                                    'filter.todate'       => $::form->{filter}->{todate},
 210                                    'filter.fromdate'     => $::form->{filter}->{fromdate}),
 211       );
 212 }
 213
 214 sub action_ajax_payment_suggestion {
 215   my ($self) = @_;
 216
 217   # based on a BankTransaction ID and a Invoice or PurchaseInvoice ID passed via $::form,
 218   # create an HTML blob to be used by the js function add_invoices in templates/webpages/bank_transactions/list.html
 219   # and return encoded as JSON
 220
 221   my $bt = SL::DB::Manager::BankTransaction->find_by( id => $::form->{bt_id} );
 222   my $invoice = SL::DB::Manager::Invoice->find_by( id => $::form->{prop_id} );
 223   $invoice = SL::DB::Manager::PurchaseInvoice->find_by( id => $::form->{prop_id} ) unless $invoice;
 224
 225   die unless $bt and $invoice;
 226
 227   my @select_options = $invoice->get_payment_select_options_for_bank_transaction($::form->{bt_id});
 228
 229   my $html;
 230   $html .= SL::Presenter->input_tag('invoice_ids.' . $::form->{bt_id} . '[]', $::form->{prop_id} , type => 'hidden');
 231   # better in template code - but how to ajax this
 232   $html .= SL::Presenter->escape(t8('Invno.') . ': ' . $invoice->invnumber . ' ');
 233   $html .= SL::Presenter->escape(t8('Amount') . ': ' . $::form->format_amount(\%::myconfig, $invoice->open_amount, 2) . ' ');
 234   $html .= SL::Presenter->select_tag('invoice_skontos.' . $::form->{bt_id} . '[]', \@select_options,
 235                                               value_key => 'payment_type',
 236                                               title_key => 'display' ) if @select_options;
 237   $html .= '<a href=# onclick="delete_invoice(' . $::form->{bt_id} . ',' . $::form->{prop_id} . ');">x</a>';
 238   $html = SL::Presenter->html_tag('div', $html, id => $::form->{bt_id} . '.' . $::form->{prop_id});
 239
 240   $self->render(\ SL::JSON::to_json( { 'html' => $html } ), { layout => 0, type => 'json', process => 0 });
 241 };
 242
 243 sub action_filter_drafts {
 244   my ($self) = @_;
 245
 246   $self->{transaction} = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 247   my $vendor_of_transaction = SL::DB::Manager::Vendor->find_by(account_number => $self->{transaction}->{remote_account_number});
 248
 249   my $drafts = SL::DB::Manager::Draft->get_all(with_objects => 'employee');
 250
 251   my @filtered_drafts;
 252
 253   foreach my $draft ( @{ $drafts } ) {
 254     my $draft_as_object = YAML::Load($draft->form);
 255     next unless $draft_as_object->{vendor_id};  # we cannot filter for vendor name, if this is a gl draft
 256     my $vendor = SL::DB::Manager::Vendor->find_by(id => $draft_as_object->{vendor_id});
 257     $draft->{vendor} = $vendor->name;
 258     $draft->{vendor_id} = $vendor->id;
 259     push @filtered_drafts, $draft;
 260   }
 261
 262   my $vendor_name = $::form->{vendor};
 263   my $vendor_id = $::form->{vendor_id};
 264
 265   #Filter drafts
 266   @filtered_drafts = grep { $_->{vendor_id} == $vendor_id } @filtered_drafts if $vendor_id;
 267   @filtered_drafts = grep { $_->{vendor} =~ /$vendor_name/i } @filtered_drafts if $vendor_name;
 268
 269   my $output  = $self->render(
 270       'bank_transactions/filter_drafts',
 271       { output      => 0 },
 272       DRAFTS => \@filtered_drafts,
 273       );
 274
 275   my %result = ( count => 0, html => $output );
 276
 277   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 278 }
 279
 280 sub action_ajax_add_list {
 281   my ($self) = @_;
 282
 283   my @where_sale     = (amount => { ne => \'paid' });
 284   my @where_purchase = (amount => { ne => \'paid' });
 285
 286   if ($::form->{invnumber}) {
 287     push @where_sale,     (invnumber => { ilike => like($::form->{invnumber})});
 288     push @where_purchase, (invnumber => { ilike => like($::form->{invnumber})});
 289   }
 290
 291   if ($::form->{amount}) {
 292     push @where_sale,     (amount => $::form->parse_amount(\%::myconfig, $::form->{amount}));
 293     push @where_purchase, (amount => $::form->parse_amount(\%::myconfig, $::form->{amount}));
 294   }
 295
 296   if ($::form->{vcnumber}) {
 297     push @where_sale,     ('customer.customernumber' => { ilike => like($::form->{vcnumber})});
 298     push @where_purchase, ('vendor.vendornumber'     => { ilike => like($::form->{vcnumber})});
 299   }
 300
 301   if ($::form->{vcname}) {
 302     push @where_sale,     ('customer.name' => { ilike => like($::form->{vcname})});
 303     push @where_purchase, ('vendor.name'   => { ilike => like($::form->{vcname})});
 304   }
 305
 306   if ($::form->{transdatefrom}) {
 307     my $fromdate = $::locale->parse_date_to_object($::form->{transdatefrom});
 308     if ( ref($fromdate) eq 'DateTime' ) {
 309       push @where_sale,     ('transdate' => { ge => $fromdate});
 310       push @where_purchase, ('transdate' => { ge => $fromdate});
 311     };
 312   }
 313
 314   if ($::form->{transdateto}) {
 315     my $todate = $::locale->parse_date_to_object($::form->{transdateto});
 316     if ( ref($todate) eq 'DateTime' ) {
 317       $todate->add(days => 1);
 318       push @where_sale,     ('transdate' => { lt => $todate});
 319       push @where_purchase, ('transdate' => { lt => $todate});
 320     };
 321   }
 322
 323   my $all_open_ar_invoices = SL::DB::Manager::Invoice->get_all(where => \@where_sale, with_objects => 'customer');
 324   my $all_open_ap_invoices = SL::DB::Manager::PurchaseInvoice->get_all(where => \@where_purchase, with_objects => 'vendor');
 325
 326   my @all_open_invoices = @{ $all_open_ar_invoices };
 327   # add ap invoices, filtering out subcent open amounts
 328   push @all_open_invoices, grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ap_invoices };
 329
 330   @all_open_invoices = sort { $a->id <=> $b->id } @all_open_invoices;
 331
 332   my $output  = $self->render(
 333       'bank_transactions/add_list',
 334       { output      => 0 },
 335       INVOICES => \@all_open_invoices,
 336       );
 337
 338   my %result = ( count => 0, html => $output );
 339
 340   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 341 }
 342
 343 sub action_ajax_accept_invoices {
 344   my ($self) = @_;
 345
 346   my @selected_invoices;
 347   foreach my $invoice_id (@{ $::form->{invoice_id} || [] }) {
 348     my $invoice_object = SL::DB::Manager::Invoice->find_by(id => $invoice_id);
 349     $invoice_object ||= SL::DB::Manager::PurchaseInvoice->find_by(id => $invoice_id);
 350
 351     push @selected_invoices, $invoice_object;
 352   }
 353
 354   $self->render('bank_transactions/invoices', { layout => 0 },
 355                 INVOICES => \@selected_invoices,
 356                 bt_id    => $::form->{bt_id} );
 357 }
 358
 359 sub action_save_invoices {
 360   my ($self) = @_;
 361
 362   my $invoice_hash = delete $::form->{invoice_ids}; # each key (the bt line with a bt_id) contains an array of invoice_ids
 363   my $skonto_hash  = delete $::form->{invoice_skontos} || {}; # array containing the payment type, could be empty
 364
 365   # a bank_transaction may be assigned to several invoices, i.e. a customer
 366   # might pay several open invoices with one transaction
 367
 368   while ( my ($bt_id, $invoice_ids) = each(%$invoice_hash) ) {
 369     my $bank_transaction = SL::DB::Manager::BankTransaction->find_by(id => $bt_id);
 370     my $sign = $bank_transaction->amount < 0 ? -1 : 1;
 371     my $amount_of_transaction = $sign * $bank_transaction->amount;
 372
 373     my @invoices;
 374     foreach my $invoice_id (@{ $invoice_ids }) {
 375       push @invoices, (SL::DB::Manager::Invoice->find_by(id => $invoice_id) || SL::DB::Manager::PurchaseInvoice->find_by(id => $invoice_id));
 376     }
 377     @invoices = sort { return 1 if ($a->is_sales and $a->amount > 0);
 378                           return 1 if (!$a->is_sales and $a->amount < 0);
 379                           return -1; } @invoices                if $bank_transaction->amount > 0;
 380     @invoices = sort { return -1 if ($a->is_sales and $a->amount > 0);
 381                        return -1 if (!$a->is_sales and $a->amount < 0);
 382                        return 1; } @invoices                    if $bank_transaction->amount < 0;
 383
 384     my $max_invoices = scalar(@invoices);
 385     my $n_invoices   = 0;
 386
 387     foreach my $invoice (@invoices) {
 388
 389       $n_invoices++ ;
 390       # Check if bank_transaction already has a link to the invoice, may only be linked once per invoice
 391       # This might be caused by the user reloading a page and resending the form
 392       die t8("Bank transaction with id #1 has already been linked to #2.", $bank_transaction->id, $invoice->displayable_name)
 393         if _existing_record_link($bank_transaction, $invoice);
 394
 395       my $payment_type;
 396       if ( defined $skonto_hash->{"$bt_id"} ) {
 397         $payment_type = shift(@{ $skonto_hash->{"$bt_id"} });
 398       } else {
 399         $payment_type = 'without_skonto';
 400       };
 401       if ($amount_of_transaction == 0) {
 402         flash('warning',  $::locale->text('There are invoices which could not be paid by bank transaction #1 (Account number: #2, bank code: #3)!',
 403                                             $bank_transaction->purpose,
 404                                             $bank_transaction->remote_account_number,
 405                                             $bank_transaction->remote_bank_code));
 406         last;
 407       }
 408       # pay invoice or go to the next bank transaction if the amount is not sufficiently high
 409       if ($invoice->open_amount <= $amount_of_transaction && $n_invoices < $max_invoices) {
 410         # first calculate new bank transaction amount ...
 411         if ($invoice->is_sales) {
 412           $amount_of_transaction -= $sign * $invoice->open_amount;
 413           $bank_transaction->invoice_amount($bank_transaction->invoice_amount + $invoice->open_amount);
 414         } else {
 415           $amount_of_transaction += $sign * $invoice->open_amount;
 416           $bank_transaction->invoice_amount($bank_transaction->invoice_amount - $invoice->open_amount);
 417         }
 418         # ... and then pay the invoice
 419         $invoice->pay_invoice(chart_id     => $bank_transaction->local_bank_account->chart_id,
 420                               trans_id     => $invoice->id,
 421                               amount       => $invoice->open_amount,
 422                               payment_type => $payment_type,
 423                               transdate    => $bank_transaction->transdate->to_kivitendo);
 424       } else {
 425         $invoice->pay_invoice(chart_id     => $bank_transaction->local_bank_account->chart_id,
 426                               trans_id     => $invoice->id,
 427                               amount       => $amount_of_transaction,
 428                               payment_type => $payment_type,
 429                               transdate    => $bank_transaction->transdate->to_kivitendo);
 430         $bank_transaction->invoice_amount($bank_transaction->amount);
 431         $amount_of_transaction = 0;
 432       }
 433
 434       # Record a record link from the bank transaction to the invoice
 435       my @props = (
 436           from_table => 'bank_transactions',
 437           from_id    => $bt_id,
 438           to_table   => $invoice->is_sales ? 'ar' : 'ap',
 439           to_id      => $invoice->id,
 440           );
 441
 442       SL::DB::RecordLink->new(@props)->save;
 443
 444       # "close" a sepa_export_item if it exists
 445       # code duplicated in action_save_proposals!
 446       # currently only works, if there is only exactly one open sepa_export_item
 447       if ( my $seis = $invoice->find_sepa_export_items({ executed => 0 }) ) {
 448         if ( scalar @$seis == 1 ) {
 449           # moved the execution and the check for sepa_export into a method,
 450           # this isn't part of a transaction, though
 451           $seis->[0]->set_executed if $invoice->id == $seis->[0]->arap_id;
 452         };
 453       };
 454
 455     }
 456     $bank_transaction->save;
 457   }
 458
 459   $self->action_list();
 460 }
 461
 462 sub action_save_proposals {
 463   my ($self) = @_;
 464
 465   foreach my $bt_id (@{ $::form->{proposal_ids} }) {
 466     my $bt = SL::DB::Manager::BankTransaction->find_by(id => $bt_id);
 467
 468     my $arap = SL::DB::Manager::Invoice->find_by(id => $::form->{"proposed_invoice_$bt_id"});
 469     $arap    = SL::DB::Manager::PurchaseInvoice->find_by(id => $::form->{"proposed_invoice_$bt_id"}) if not defined $arap;
 470
 471     # check for existing record_link for that $bt and $arap
 472     # do this before any changes to $bt are made
 473     die t8("Bank transaction with id #1 has already been linked to #2.", $bt->id, $arap->displayable_name)
 474       if _existing_record_link($bt, $arap);
 475
 476     #mark bt as booked
 477     $bt->invoice_amount($bt->amount);
 478     $bt->save;
 479
 480     #pay invoice
 481     $arap->pay_invoice(chart_id  => $bt->local_bank_account->chart_id,
 482                        trans_id  => $arap->id,
 483                        amount    => $arap->amount,
 484                        transdate => $bt->transdate->to_kivitendo);
 485     $arap->save;
 486
 487     #create record link
 488     my @props = (
 489         from_table => 'bank_transactions',
 490         from_id    => $bt_id,
 491         to_table   => $arap->is_sales ? 'ar' : 'ap',
 492         to_id      => $arap->id,
 493         );
 494
 495     SL::DB::RecordLink->new(@props)->save;
 496
 497     # code duplicated in action_save_invoices!
 498     # "close" a sepa_export_item if it exists
 499     # currently only works, if there is only exactly one open sepa_export_item
 500     if ( my $seis = $arap->find_sepa_export_items({ executed => 0 }) ) {
 501       if ( scalar @$seis == 1 ) {
 502         # moved the execution and the check for sepa_export into a method,
 503         # this isn't part of a transaction, though
 504         $seis->[0]->set_executed if $arap->id == $seis->[0]->arap_id;
 505       };
 506     };
 507   }
 508
 509   flash('ok', t8('#1 proposal(s) saved.', scalar @{ $::form->{proposal_ids} }));
 510
 511   $self->action_list();
 512 }
 513
 514 #
 515 # filters
 516 #
 517
 518 sub check_auth {
 519   $::auth->assert('bank_transaction');
 520 }
 521
 522 #
 523 # helpers
 524 #
 525
 526 sub make_filter_summary {
 527   my ($self) = @_;
 528
 529   my $filter = $::form->{filter} || {};
 530   my @filter_strings;
 531
 532   my @filters = (
 533     [ $filter->{"transdate:date::ge"},  $::locale->text('Transdate')  . " " . $::locale->text('From Date') ],
 534     [ $filter->{"transdate:date::le"},  $::locale->text('Transdate')  . " " . $::locale->text('To Date')   ],
 535     [ $filter->{"valutadate:date::ge"}, $::locale->text('Valutadate') . " " . $::locale->text('From Date') ],
 536     [ $filter->{"valutadate:date::le"}, $::locale->text('Valutadate') . " " . $::locale->text('To Date')   ],
 537     [ $filter->{"amount:number"},       $::locale->text('Amount')                                          ],
 538     [ $filter->{"bank_account_id:integer"}, $::locale->text('Local bank account')                          ],
 539   );
 540
 541   for (@filters) {
 542     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 543   }
 544
 545   $self->{filter_summary} = join ', ', @filter_strings;
 546 }
 547
 548 sub prepare_report {
 549   my ($self)      = @_;
 550
 551   my $callback    = $self->models->get_callback;
 552
 553   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 554   $self->{report} = $report;
 555
 556   my @columns     = qw(local_bank_name transdate valudate remote_name remote_account_number remote_bank_code amount invoice_amount invoices currency purpose local_account_number local_bank_code id);
 557   my @sortable    = qw(local_bank_name transdate valudate remote_name remote_account_number remote_bank_code amount                                  purpose local_account_number local_bank_code);
 558
 559   my %column_defs = (
 560     transdate             => { sub => sub { $_[0]->transdate_as_date } },
 561     valutadate            => { sub => sub { $_[0]->valutadate_as_date } },
 562     remote_name           => { },
 563     remote_account_number => { },
 564     remote_bank_code      => { },
 565     amount                => { sub => sub { $_[0]->amount_as_number },
 566                                align => 'right' },
 567     invoice_amount        => { sub => sub { $_[0]->invoice_amount_as_number },
 568                                align => 'right' },
 569     invoices              => { sub => sub { $_[0]->linked_invoices } },
 570     currency              => { sub => sub { $_[0]->currency->name } },
 571     purpose               => { },
 572     local_account_number  => { sub => sub { $_[0]->local_bank_account->account_number } },
 573     local_bank_code       => { sub => sub { $_[0]->local_bank_account->bank_code } },
 574     local_bank_name       => { sub => sub { $_[0]->local_bank_account->name } },
 575     id                    => {},
 576   );
 577
 578   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 579
 580   $report->set_options(
 581     std_column_visibility => 1,
 582     controller_class      => 'BankTransaction',
 583     output_format         => 'HTML',
 584     top_info_text         => $::locale->text('Bank transactions'),
 585     title                 => $::locale->text('Bank transactions'),
 586     allow_pdf_export      => 1,
 587     allow_csv_export      => 1,
 588   );
 589   $report->set_columns(%column_defs);
 590   $report->set_column_order(@columns);
 591   $report->set_export_options(qw(list_all filter));
 592   $report->set_options_from_form;
 593   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 594   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 595
 596   my $bank_accounts = SL::DB::Manager::BankAccount->get_all_sorted();
 597
 598   $report->set_options(
 599     raw_top_info_text     => $self->render('bank_transactions/report_top',    { output => 0 }, BANK_ACCOUNTS => $bank_accounts),
 600     raw_bottom_info_text  => $self->render('bank_transactions/report_bottom', { output => 0 }),
 601   );
 602 }
 603
 604 sub _existing_record_link {
 605   my ($bt, $invoice) = @_;
 606
 607   # check whether a record link from banktransaction $bt already exists to
 608   # invoice $invoice, returns 1 if that is the case
 609
 610   die unless $bt->isa("SL::DB::BankTransaction") && ( $invoice->isa("SL::DB::Invoice") || $invoice->isa("SL::DB::PurchaseInvoice") );
 611
 612   my $linked_record_to_table = $invoice->is_sales ? 'Invoice' : 'PurchaseInvoice';
 613   my $linked_records = $bt->linked_records( direction => 'to', to => $linked_record_to_table, query => [ id => $invoice->id ]  );
 614
 615   return @$linked_records ? 1 : 0;
 616 };
 617
 618
 619 sub init_models {
 620   my ($self) = @_;
 621
 622   SL::Controller::Helper::GetModels->new(
 623     controller => $self,
 624     sorted => {
 625       _default => {
 626         by    => 'transdate',
 627         dir   => 0,   # 1 = ASC, 0 = DESC : default sort is newest at top
 628       },
 629       transdate             => t8('Transdate'),
 630       remote_name           => t8('Remote name'),
 631       amount                => t8('Amount'),
 632       invoice_amount        => t8('Assigned'),
 633       invoices              => t8('Linked invoices'),
 634       valutadate            => t8('Valutadate'),
 635       remote_account_number => t8('Remote account number'),
 636       remote_bank_code      => t8('Remote bank code'),
 637       currency              => t8('Currency'),
 638       purpose               => t8('Purpose'),
 639       local_account_number  => t8('Local account number'),
 640       local_bank_code       => t8('Local bank code'),
 641       local_bank_name       => t8('Bank account'),
 642     },
 643     with_objects => [ 'local_bank_account', 'currency' ],
 644   );
 645 }
 646
 647 1;