SL/DB/Invoice.pm

   1 package SL::DB::Invoice;
   2
   3 use strict;
   4
   5 use Carp;
   6 use List::Util qw(first sum);
   7
   8 use Rose::DB::Object::Helpers qw(has_loaded_related forget_related);
   9 use SL::DB::MetaSetup::Invoice;
  10 use SL::DB::Manager::Invoice;
  11 use SL::DB::Helper::Payment qw(:ALL);
  12 use SL::DB::Helper::AttrHTML;
  13 use SL::DB::Helper::AttrSorted;
  14 use SL::DB::Helper::FlattenToForm;
  15 use SL::DB::Helper::LinkedRecords;
  16 use SL::DB::Helper::PriceTaxCalculator;
  17 use SL::DB::Helper::PriceUpdater;
  18 use SL::DB::Helper::TransNumberGenerator;
  19 use SL::Locale::String qw(t8);
  20 use SL::DB::CustomVariable;
  21
  22 __PACKAGE__->meta->add_relationship(
  23   invoiceitems => {
  24     type         => 'one to many',
  25     class        => 'SL::DB::InvoiceItem',
  26     column_map   => { id => 'trans_id' },
  27     manager_args => {
  28       with_objects => [ 'part' ]
  29     }
  30   },
  31   storno_invoices => {
  32     type          => 'one to many',
  33     class         => 'SL::DB::Invoice',
  34     column_map    => { id => 'storno_id' },
  35   },
  36   sepa_export_items => {
  37     type            => 'one to many',
  38     class           => 'SL::DB::SepaExportItem',
  39     column_map      => { id => 'ar_id' },
  40     manager_args    => { with_objects => [ 'sepa_export' ] }
  41   },
  42   sepa_exports      => {
  43     type            => 'many to many',
  44     map_class       => 'SL::DB::SepaExportItem',
  45     map_from        => 'ar',
  46     map_to          => 'sepa_export',
  47   },
  48   custom_shipto     => {
  49     type            => 'one to one',
  50     class           => 'SL::DB::Shipto',
  51     column_map      => { id => 'trans_id' },
  52     query_args      => [ module => 'AR' ],
  53   },
  54   transactions   => {
  55     type         => 'one to many',
  56     class        => 'SL::DB::AccTransaction',
  57     column_map   => { id => 'trans_id' },
  58     manager_args => {
  59       with_objects => [ 'chart' ],
  60       sort_by      => 'acc_trans_id ASC',
  61     },
  62   },
  63 );
  64
  65 __PACKAGE__->meta->initialize;
  66
  67 __PACKAGE__->attr_html('notes');
  68 __PACKAGE__->attr_sorted('items');
  69
  70 __PACKAGE__->before_save('_before_save_set_invnumber');
  71
  72 # hooks
  73
  74 sub _before_save_set_invnumber {
  75   my ($self) = @_;
  76
  77   $self->create_trans_number if !$self->invnumber;
  78
  79   return 1;
  80 }
  81
  82 # methods
  83
  84 sub items { goto &invoiceitems; }
  85 sub add_items { goto &add_invoiceitems; }
  86 sub record_number { goto &invnumber; };
  87
  88 sub is_sales {
  89   # For compatibility with Order, DeliveryOrder
  90   croak 'not an accessor' if @_ > 1;
  91   return 1;
  92 }
  93
  94 # it is assumed, that ordnumbers are unique here.
  95 sub first_order_by_ordnumber {
  96   my $self = shift;
  97
  98   my $orders = SL::DB::Manager::Order->get_all(
  99     query => [
 100       ordnumber => $self->ordnumber,
 101
 102     ],
 103   );
 104
 105   return first { $_->is_type('sales_order') } @{ $orders };
 106 }
 107
 108 sub abschlag_percentage {
 109   my $self         = shift;
 110   my $order        = $self->first_order_by_ordnumber or return;
 111   my $order_amount = $order->netamount               or return;
 112   return $self->abschlag
 113     ? $self->netamount / $order_amount
 114     : undef;
 115 }
 116
 117 sub taxamount {
 118   my $self = shift;
 119   die 'not a setter method' if @_;
 120
 121   return ($self->amount || 0) - ($self->netamount || 0);
 122 }
 123
 124 __PACKAGE__->meta->make_attr_helpers(taxamount => 'numeric(15,5)');
 125
 126 sub closed {
 127   my ($self) = @_;
 128   return $self->paid >= $self->amount;
 129 }
 130
 131 sub _clone_orderitem_delivery_order_item_cvar {
 132   my ($cvar) = @_;
 133
 134   my $cloned = $_->clone_and_reset;
 135   $cloned->sub_module('invoice');
 136
 137   return $cloned;
 138 }
 139
 140 sub new_from {
 141   my ($class, $source, %params) = @_;
 142
 143   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) =~ m/^ SL::DB:: (?: Order | DeliveryOrder ) $/x;
 144   croak("Cannot create invoices for purchase records")           unless $source->customer_id;
 145
 146   require SL::DB::Employee;
 147
 148   my (@columns, @item_columns, $item_parent_id_column, $item_parent_column);
 149
 150   if (ref($source) eq 'SL::DB::Order') {
 151     @columns      = qw(quonumber delivery_customer_id delivery_vendor_id);
 152     @item_columns = qw(subtotal);
 153
 154     $item_parent_id_column = 'trans_id';
 155     $item_parent_column    = 'order';
 156
 157   } else {
 158     @columns      = qw(donumber);
 159
 160     $item_parent_id_column = 'delivery_order_id';
 161     $item_parent_column    = 'delivery_order';
 162   }
 163
 164   my $terms = $source->can('payment_id') ? $source->payment_terms : undef;
 165   $terms = $source->customer->payment_terms if !defined $terms && $source->customer;
 166
 167   my %args = ( map({ ( $_ => $source->$_ ) } qw(customer_id taxincluded shippingpoint shipvia notes intnotes salesman_id cusordnumber ordnumber department_id
 168                                                 cp_id language_id taxzone_id globalproject_id transaction_description currency_id delivery_term_id), @columns),
 169                transdate   => DateTime->today_local,
 170                gldate      => DateTime->today_local,
 171                duedate     => $terms ? $terms->calc_date(reference_date => DateTime->today_local) : DateTime->today_local,
 172                invoice     => 1,
 173                type        => 'invoice',
 174                storno      => 0,
 175                paid        => 0,
 176                employee_id => (SL::DB::Manager::Employee->current || SL::DB::Employee->new(id => $source->employee_id))->id,
 177             );
 178
 179   $args{payment_id} = ( $terms ? $terms->id : $source->payment_id);
 180
 181   if ($source->type =~ /_order$/) {
 182     $args{deliverydate} = $source->reqdate;
 183     $args{orddate}      = $source->transdate;
 184   } else {
 185     $args{quodate}      = $source->transdate;
 186   }
 187
 188   # Custom shipto addresses (the ones specific to the sales/purchase
 189   # record and not to the customer/vendor) are only linked from shipto
 190   # → ar. Meaning ar.shipto_id will not be filled in that
 191   # case.
 192   if (!$source->shipto_id && $source->id) {
 193     $args{custom_shipto} = $source->custom_shipto->clone($class) if $source->can('custom_shipto') && $source->custom_shipto;
 194
 195   } else {
 196     $args{shipto_id} = $source->shipto_id;
 197   }
 198
 199   my $invoice = $class->new(%args);
 200   $invoice->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 201   my $items   = delete($params{items}) || $source->items_sorted;
 202   my %item_parents;
 203
 204   my @items = map {
 205     my $source_item      = $_;
 206     my $source_item_id   = $_->$item_parent_id_column;
 207     my @custom_variables = map { _clone_orderitem_delivery_order_item_cvar($_) } @{ $source_item->custom_variables };
 208
 209     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 210     my $item_parent                  = $item_parents{$source_item_id};
 211     my $current_invoice_item =
 212       SL::DB::InvoiceItem->new(map({ ( $_ => $source_item->$_ ) }
 213                                    qw(parts_id description qty sellprice discount project_id serialnumber pricegroup_id transdate cusordnumber unit
 214                                       base_qty longdescription lastcost price_factor_id active_discount_source active_price_source), @item_columns),
 215                                deliverydate     => $source_item->reqdate,
 216                                fxsellprice      => $source_item->sellprice,
 217                                custom_variables => \@custom_variables,
 218                                ordnumber        => ref($item_parent) eq 'SL::DB::Order'         ? $item_parent->ordnumber : $source_item->ordnumber,
 219                                donumber         => ref($item_parent) eq 'SL::DB::DeliveryOrder' ? $item_parent->donumber  : $source_item->can('donumber') ? $source_item->donumber : '',
 220                              );
 221
 222     $current_invoice_item->{"converted_from_orderitems_id"}           = $_->{id} if ref($item_parent) eq 'SL::DB::Order';
 223     $current_invoice_item->{"converted_from_delivery_order_items_id"} = $_->{id} if ref($item_parent) eq 'SL::DB::DeliveryOrder';
 224     $current_invoice_item;
 225   } @{ $items };
 226
 227   @items = grep { $params{item_filter}->($_) } @items if $params{item_filter};
 228   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 229   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 230
 231   $invoice->invoiceitems(\@items);
 232
 233   return $invoice;
 234 }
 235
 236 sub post {
 237   my ($self, %params) = @_;
 238
 239   die "not an invoice" unless $self->invoice;
 240
 241   require SL::DB::Chart;
 242   if (!$params{ar_id}) {
 243     my $chart;
 244     if ($::instance_conf->get_ar_chart_id) {
 245       $chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_ar_chart_id);
 246     } else {
 247       $chart = SL::DB::Manager::Chart->get_all(query   => [ SL::DB::Manager::Chart->link_filter('AR') ],
 248                                                sort_by => 'id ASC',
 249                                                limit   => 1)->[0];
 250     };
 251     croak("No AR chart found and no parameter 'ar_id' given") unless $chart;
 252     $params{ar_id} = $chart->id;
 253   }
 254
 255   my $worker = sub {
 256     my %data = $self->calculate_prices_and_taxes;
 257
 258     $self->_post_create_assemblyitem_entries($data{assembly_items});
 259     $self->save;
 260
 261     $self->_post_add_acctrans($data{amounts_cogs});
 262     $self->_post_add_acctrans($data{amounts});
 263     $self->_post_add_acctrans($data{taxes});
 264
 265     $self->_post_add_acctrans({ $params{ar_id} => $self->amount * -1 });
 266
 267     $self->_post_update_allocated($data{allocated});
 268
 269     $self->_post_book_rounding($data{rounding});
 270   };
 271
 272   if ($self->db->in_transaction) {
 273     $worker->();
 274   } elsif (!$self->db->do_transaction($worker)) {
 275     $::lxdebug->message(LXDebug->WARN(), "convert_to_invoice failed: " . join("\n", (split(/\n/, $self->db->error))[0..2]));
 276     return undef;
 277   }
 278
 279   return $self;
 280 }
 281
 282 sub _post_add_acctrans {
 283   my ($self, $entries) = @_;
 284
 285   my $default_tax_id = SL::DB::Manager::Tax->find_by(taxkey => 0)->id;
 286   my $chart_link;
 287
 288   require SL::DB::AccTransaction;
 289   require SL::DB::Chart;
 290   while (my ($chart_id, $spec) = each %{ $entries }) {
 291     $spec = { taxkey => 0, tax_id => $default_tax_id, amount => $spec } unless ref $spec;
 292     $chart_link = SL::DB::Manager::Chart->find_by(id => $chart_id)->{'link'};
 293     $chart_link ||= '';
 294
 295     SL::DB::AccTransaction->new(trans_id   => $self->id,
 296                                 chart_id   => $chart_id,
 297                                 amount     => $spec->{amount},
 298                                 tax_id     => $spec->{tax_id},
 299                                 taxkey     => $spec->{taxkey},
 300                                 project_id => $self->globalproject_id,
 301                                 transdate  => $self->transdate,
 302                                 chart_link => $chart_link)->save;
 303   }
 304 }
 305
 306 sub _post_book_rounding {
 307   my ($self, $rounding) = @_;
 308
 309   my $tax_id = SL::DB::Manager::Tax->find_by(taxkey => 0)->id;
 310   my $rnd_accno = $rounding == 0 ? 0
 311                 : $rounding > 0  ? SL::DB::Default->get->rndgain_accno_id
 312                 :                  SL::DB::Default->get->rndloss_accno_id
 313   ;
 314   if ($rnd_accno != 0) {
 315     SL::DB::AccTransaction->new(trans_id   => $self->id,
 316                                 chart_id   => $rnd_accno,
 317                                 amount     => $rounding,
 318                                 tax_id     => $tax_id,
 319                                 taxkey     => 0,
 320                                 project_id => $self->globalproject_id,
 321                                 transdate  => $self->transdate,
 322                                 chart_link => $rnd_accno)->save;
 323   }
 324 }
 325
 326 sub add_ar_amount_row {
 327   my ($self, %params ) = @_;
 328
 329   # only allow this method for ar invoices (Debitorenbuchung)
 330   die "not an ar invoice" if $self->invoice and not $self->customer_id;
 331
 332   die "add_ar_amount_row needs a chart object as chart param" unless $params{chart} && $params{chart}->isa('SL::DB::Chart');
 333   die "chart must be an AR_amount chart" unless $params{chart}->link =~ /AR_amount/;
 334
 335   my $acc_trans = [];
 336
 337   my $roundplaces = 2;
 338   my ($netamount,$taxamount);
 339
 340   $netamount = $params{amount} * 1;
 341   my $tax = SL::DB::Manager::Tax->find_by(id => $params{tax_id}) || die "Can't find tax with id " . $params{tax_id};
 342
 343   if ( $tax and $tax->rate != 0 ) {
 344     ($netamount, $taxamount) = Form->calculate_tax($params{amount}, $tax->rate, $self->taxincluded, $roundplaces);
 345   };
 346   next unless $netamount; # netamount mustn't be zero
 347
 348   my $sign = $self->customer_id ? 1 : -1;
 349   my $acc = SL::DB::AccTransaction->new(
 350     amount     => $netamount * $sign,
 351     chart_id   => $params{chart}->id,
 352     chart_link => $params{chart}->link,
 353     transdate  => $self->transdate,
 354     taxkey     => $tax->taxkey,
 355     tax_id     => $tax->id,
 356     project_id => $params{project_id},
 357   );
 358
 359   $self->add_transactions( $acc );
 360   push( @$acc_trans, $acc );
 361
 362   if ( $taxamount ) {
 363      my $acc = SL::DB::AccTransaction->new(
 364        amount     => $taxamount * $sign,
 365        chart_id   => $tax->chart_id,
 366        chart_link => $tax->chart->link,
 367        transdate  => $self->transdate,
 368        taxkey     => $tax->taxkey,
 369        tax_id     => $tax->id,
 370      );
 371      $self->add_transactions( $acc );
 372      push( @$acc_trans, $acc );
 373   };
 374   return $acc_trans;
 375 };
 376
 377 sub create_ar_row {
 378   my ($self, %params) = @_;
 379   # to be called after adding all AR_amount rows, adds an AR row
 380
 381   # only allow this method for ar invoices (Debitorenbuchung)
 382   die if $self->invoice and not $self->customer_id;
 383   die "create_ar_row needs a chart object as a parameter" unless $params{chart} and ref($params{chart}) eq 'SL::DB::Chart';
 384
 385   my @transactions = @{$self->transactions};
 386   # die "invoice has no acc_transactions" unless scalar @transactions > 0;
 387   return 0 unless scalar @transactions > 0;
 388
 389   my $chart = $params{chart} || SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_ar_chart_id);
 390   die "illegal chart in create_ar_row" unless $chart;
 391
 392   die "receivables chart must have link 'AR'" unless $chart->link eq 'AR';
 393
 394   my $acc_trans = [];
 395
 396   # hardcoded entry for no tax: tax_id and taxkey should be 0
 397   my $tax = SL::DB::Manager::Tax->find_by(id => 0, taxkey => 0) || die "Can't find tax with id 0 and taxkey 0";
 398
 399   my $sign = $self->customer_id ? -1 : 1;
 400   my $acc = SL::DB::AccTransaction->new(
 401     amount     => $self->amount * $sign,
 402     chart_id   => $params{chart}->id,
 403     chart_link => $params{chart}->link,
 404     transdate  => $self->transdate,
 405     taxkey     => $tax->taxkey,
 406     tax_id     => $tax->id,
 407   );
 408   $self->add_transactions( $acc );
 409   push( @$acc_trans, $acc );
 410   return $acc_trans;
 411 };
 412
 413 sub validate_acc_trans {
 414   my ($self, %params) = @_;
 415   # should be able to check unsaved invoice objects with several acc_trans lines
 416
 417   die "validate_acc_trans can't check invoice object with empty transactions" unless $self->transactions;
 418
 419   my @transactions = @{$self->transactions};
 420   # die "invoice has no acc_transactions" unless scalar @transactions > 0;
 421   return 0 unless scalar @transactions > 0;
 422   return 0 unless $self->has_loaded_related('transactions');
 423   if ( $params{debug} ) {
 424     printf("starting validatation of invoice %s with trans_id %s and taxincluded %s\n", $self->invnumber, $self->id, $self->taxincluded);
 425     foreach my $acc ( @transactions ) {
 426       printf("chart: %s  amount: %s   tax_id: %s  link: %s\n", $acc->chart->accno, $acc->amount, $acc->tax_id, $acc->chart->link);
 427     };
 428   };
 429
 430   my $acc_trans_sum = sum map { $_->amount } @transactions;
 431
 432   unless ( $::form->round_amount($acc_trans_sum, 10) == 0 ) {
 433     my $string = "sum of acc_transactions isn't 0: $acc_trans_sum\n";
 434
 435     if ( $params{debug} ) {
 436       foreach my $trans ( @transactions ) {
 437           $string .= sprintf("  %s %s %s\n", $trans->chart->accno, $trans->taxkey, $trans->amount);
 438       };
 439     };
 440     return 0;
 441   };
 442
 443   # only use the first AR entry, so it also works for paid invoices
 444   my @ar_transactions = map { $_->amount } grep { $_->chart_link eq 'AR' } @transactions;
 445   my $ar_sum = $ar_transactions[0];
 446   # my $ar_sum = sum map { $_->amount } grep { $_->chart_link eq 'AR' } @transactions;
 447
 448   unless ( $::form->round_amount($ar_sum * -1,2) == $::form->round_amount($self->amount,2) ) {
 449     if ( $params{debug} ) {
 450       printf("debug: (ar_sum) %s = %s (amount)\n",  $::form->round_amount($ar_sum * -1,2) , $::form->round_amount($self->amount, 2) );
 451       foreach my $trans ( @transactions ) {
 452         printf("  %s %s %s %s\n", $trans->chart->accno, $trans->taxkey, $trans->amount, $trans->chart->link);
 453       };
 454     };
 455     die sprintf("sum of ar (%s) isn't equal to invoice amount (%s)", $::form->round_amount($ar_sum * -1,2), $::form->round_amount($self->amount,2));
 456   };
 457
 458   return 1;
 459 };
 460
 461 sub recalculate_amounts {
 462   my ($self, %params) = @_;
 463   # calculate and set amount and netamount from acc_trans objects
 464
 465   croak ("Can only recalculate amounts for ar transactions") if $self->invoice;
 466
 467   return undef unless $self->has_loaded_related('transactions');
 468
 469   my ($netamount, $taxamount);
 470
 471   my @transactions = @{$self->transactions};
 472
 473   foreach my $acc ( @transactions ) {
 474     $netamount += $acc->amount if $acc->chart->link =~ /AR_amount/;
 475     $taxamount += $acc->amount if $acc->chart->link =~ /AR_tax/;
 476   };
 477
 478   $self->amount($netamount+$taxamount);
 479   $self->netamount($netamount);
 480 };
 481
 482
 483 sub _post_create_assemblyitem_entries {
 484   my ($self, $assembly_entries) = @_;
 485
 486   my $items = $self->invoiceitems;
 487   my @new_items;
 488
 489   my $item_idx = 0;
 490   foreach my $item (@{ $items }) {
 491     next if $item->assemblyitem;
 492
 493     push @new_items, $item;
 494     $item_idx++;
 495
 496     foreach my $assembly_item (@{ $assembly_entries->[$item_idx] || [ ] }) {
 497       push @new_items, SL::DB::InvoiceItem->new(parts_id     => $assembly_item->{part},
 498                                                 description  => $assembly_item->{part}->description,
 499                                                 unit         => $assembly_item->{part}->unit,
 500                                                 qty          => $assembly_item->{qty},
 501                                                 allocated    => $assembly_item->{allocated},
 502                                                 sellprice    => 0,
 503                                                 fxsellprice  => 0,
 504                                                 assemblyitem => 't');
 505     }
 506   }
 507
 508   $self->invoiceitems(\@new_items);
 509 }
 510
 511 sub _post_update_allocated {
 512   my ($self, $allocated) = @_;
 513
 514   while (my ($invoice_id, $diff) = each %{ $allocated }) {
 515     SL::DB::Manager::InvoiceItem->update_all(set   => { allocated => { sql => "allocated + $diff" } },
 516                                              where => [ id        => $invoice_id ]);
 517   }
 518 }
 519
 520 sub invoice_type {
 521   my ($self) = @_;
 522
 523   return 'ar_transaction'     if !$self->invoice;
 524   return 'credit_note'        if $self->type eq 'credit_note' && $self->amount < 0 && !$self->storno;
 525   return 'invoice_storno'     if $self->type ne 'credit_note' && $self->amount < 0 &&  $self->storno;
 526   return 'credit_note_storno' if $self->type eq 'credit_note' && $self->amount > 0 &&  $self->storno;
 527   return 'invoice';
 528 }
 529
 530 sub displayable_state {
 531   my $self = shift;
 532
 533   return $self->closed ? $::locale->text('closed') : $::locale->text('open');
 534 }
 535
 536 sub displayable_type {
 537   my ($self) = @_;
 538
 539   return t8('AR Transaction')                         if $self->invoice_type eq 'ar_transaction';
 540   return t8('Credit Note')                            if $self->invoice_type eq 'credit_note';
 541   return t8('Invoice') . "(" . t8('Storno') . ")"     if $self->invoice_type eq 'invoice_storno';
 542   return t8('Credit Note') . "(" . t8('Storno') . ")" if $self->invoice_type eq 'credit_note_storno';
 543   return t8('Invoice');
 544 }
 545
 546 sub displayable_name {
 547   join ' ', grep $_, map $_[0]->$_, qw(displayable_type record_number);
 548 };
 549
 550 sub abbreviation {
 551   my ($self) = @_;
 552
 553   return t8('AR Transaction (abbreviation)')         if $self->invoice_type eq 'ar_transaction';
 554   return t8('Credit note (one letter abbreviation)') if $self->invoice_type eq 'credit_note';
 555   return t8('Invoice (one letter abbreviation)') . "(" . t8('Storno (one letter abbreviation)') . ")" if $self->invoice_type eq 'invoice_storno';
 556   return t8('Credit note (one letter abbreviation)') . "(" . t8('Storno (one letter abbreviation)') . ")"  if $self->invoice_type eq 'credit_note_storno';
 557   return t8('Invoice (one letter abbreviation)');
 558 }
 559
 560 sub date {
 561   goto &transdate;
 562 }
 563
 564 sub reqdate {
 565   goto &duedate;
 566 }
 567
 568 sub customervendor {
 569   goto &customer;
 570 }
 571
 572 sub link {
 573   my ($self) = @_;
 574
 575   my $html;
 576   $html   = SL::Presenter->get->sales_invoice($self, display => 'inline') if $self->invoice;
 577   $html   = SL::Presenter->get->ar_transaction($self, display => 'inline') if !$self->invoice;
 578
 579   return $html;
 580 }
 581
 582 1;
 583
 584 __END__
 585
 586 =pod
 587
 588 =encoding UTF-8
 589
 590 =head1 NAME
 591
 592 SL::DB::Invoice: Rose model for invoices (table "ar")
 593
 594 =head1 FUNCTIONS
 595
 596 =over 4
 597
 598 =item C<new_from $source, %params>
 599
 600 Creates a new C<SL::DB::Invoice> instance and copies as much
 601 information from C<$source> as possible. At the moment only sales
 602 orders and sales quotations are supported as sources.
 603
 604 The conversion copies order items into invoice items. Dates are copied
 605 as appropriate, e.g. the C<transdate> field from an order will be
 606 copied into the invoice's C<orddate> field.
 607
 608 C<%params> can include the following options:
 609
 610 =over 2
 611
 612 =item C<items>
 613
 614 An optional array reference of RDBO instances for the items to use. If
 615 missing then the method C<items_sorted> will be called on
 616 C<$source>. This option can be used to override the sorting, to
 617 exclude certain positions or to add additional ones.
 618
 619 =item C<skip_items_negative_qty>
 620
 621 If trueish then items with a negative quantity are skipped. Items with
 622 a quantity of 0 are not affected by this option.
 623
 624 =item C<skip_items_zero_qty>
 625
 626 If trueish then items with a quantity of 0 are skipped.
 627
 628 =item C<item_filter>
 629
 630 An optional code reference that is called for each item with the item
 631 as its sole parameter. Items for which the code reference returns a
 632 falsish value will be skipped.
 633
 634 =item C<attributes>
 635
 636 An optional hash reference. If it exists then it is passed to C<new>
 637 allowing the caller to set certain attributes for the new invoice.
 638 For example to set a different transdate (default is the current date),
 639 call the method like this:
 640
 641    my %params;
 642    $params{attributes}{transdate} = '28.08.2015';
 643    $invoice = SL::DB::Invoice->new_from($self, %params)->post || die;
 644
 645 =back
 646
 647 Amounts, prices and taxes are not
 648 calculated. L<SL::DB::Helper::PriceTaxCalculator::calculate_prices_and_taxes>
 649 can be used for this.
 650
 651 The object returned is not saved.
 652
 653 =item C<post %params>
 654
 655 Posts the invoice. Required parameters are:
 656
 657 =over 2
 658
 659 =item * C<ar_id>
 660
 661 The ID of the accounts receivable chart the invoice's amounts are
 662 posted to. If it is not set then the first chart configured for
 663 accounts receivables is used.
 664
 665 =back
 666
 667 This function implements several steps:
 668
 669 =over 2
 670
 671 =item 1. It calculates all prices, amounts and taxes by calling
 672 L<SL::DB::Helper::PriceTaxCalculator::calculate_prices_and_taxes>.
 673
 674 =item 2. A new and unique invoice number is created.
 675
 676 =item 3. All amounts for costs of goods sold are recorded in
 677 C<acc_trans>.
 678
 679 =item 4. All amounts for parts, services and assemblies are recorded
 680 in C<acc_trans> with their respective charts. This is determined by
 681 the part's buchungsgruppen.
 682
 683 =item 5. The total amount is posted to the accounts receivable chart
 684 and recorded in C<acc_trans>.
 685
 686 =item 6. Items in C<invoice> are updated according to their allocation
 687 status (regarding costs of goods sold). Will only be done if
 688 kivitendo is not configured to use Einnahmenüberschussrechnungen.
 689
 690 =item 7. The invoice and its items are saved.
 691
 692 =back
 693
 694 Returns C<$self> on success and C<undef> on failure. The whole process
 695 is run inside a transaction. If it fails then nothing is saved to or
 696 changed in the database. A new transaction is only started if none are
 697 active.
 698
 699 =item C<basic_info $field>
 700
 701 See L<SL::DB::Object::basic_info>.
 702
 703 =item C<recalculate_amounts %params>
 704
 705 Calculate and set amount and netamount from acc_trans objects by summing up the
 706 values of acc_trans objects with AR_amount and AR_tax link charts.
 707 amount and netamount are set to the calculated values.
 708
 709 =item C<validate_acc_trans>
 710
 711 Checks if the sum of all associated acc_trans objects is 0 and checks whether
 712 the amount of the AR acc_transaction matches the AR amount. Only the first AR
 713 line is checked, because the sum of all AR lines is 0 for paid invoices.
 714
 715 Returns 0 or 1.
 716
 717 Can be called with a debug parameter which writes debug info to STDOUT, which is
 718 useful in console mode or while writing tests.
 719
 720  my $ar = SL::DB::Manager::Invoice->get_first();
 721  $ar->validate_acc_trans(debug => 1);
 722
 723 =item C<create_ar_row %params>
 724
 725 Creates a new acc_trans entry for the receivable (AR) entry of an existing AR
 726 invoice object, which already has some income and tax acc_trans entries.
 727
 728 The acc_trans entry is also returned inside an array ref.
 729
 730 Mandatory params are
 731
 732 =over 2
 733
 734 =item * chart as an RDBO object, e.g. for bank. Must be a 'paid' chart.
 735
 736 =back
 737
 738 Currently the amount of the invoice object is used for the acc_trans amount.
 739 Use C<recalculate_amounts> before calling this method if amount isn't known
 740 yet or you didn't set it manually.
 741
 742 =item C<add_ar_amount_row %params>
 743
 744 Add a new entry for an existing AR invoice object. Creates an acc_trans entry,
 745 and also adds an acc_trans tax entry, if the tax has an associated tax chart.
 746 Also all acc_trans entries that were created are returned inside an array ref.
 747
 748 Mandatory params are
 749
 750 =over 2
 751
 752 =item * chart as an RDBO object, should be an income chart (link = AR_amount)
 753
 754 =item * tax_id
 755
 756 =item * amount
 757
 758 =back
 759
 760 =back
 761
 762 =head1 TODO
 763
 764  As explained in the new_from example, it is possible to set transdate to a new value.
 765  From a user / programm point of view transdate is more than holy and there should be
 766  some validity checker available for controller code. At least the same logic like in
 767  Form.pm from ar.pl should be available:
 768   # see old stuff ar.pl post
 769   #$form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 770   #  if ($form->date_max_future($transdate, \%myconfig));
 771   #$form->error($locale->text('Cannot post transaction for a closed period!')) if ($form->date_closed($form->{"transdate"}, \%myconfig));
 772
 773 =head1 AUTHOR
 774
 775 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 776
 777 =cut