SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::HTML::Util;
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::AdditionalBillingAddress;
  18 use SL::DB::AuthUser;
  19 use SL::DB::History;
  20 use SL::DB::Order;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28 use SL::DB::RecordLink;
  29 use SL::DB::RequirementSpec;
  30 use SL::DB::Shipto;
  31 use SL::DB::Translation;
  32
  33 use SL::Helper::CreatePDF qw(:all);
  34 use SL::Helper::PrintOptions;
  35 use SL::Helper::ShippedQty;
  36 use SL::Helper::UserPreferences::PositionsScrollbar;
  37 use SL::Helper::UserPreferences::UpdatePositions;
  38
  39 use SL::Controller::Helper::GetModels;
  40
  41 use List::Util qw(first sum0);
  42 use List::UtilsBy qw(sort_by uniq_by);
  43 use List::MoreUtils qw(any none pairwise first_index);
  44 use English qw(-no_match_vars);
  45 use File::Spec;
  46 use Cwd;
  47 use Sort::Naturally;
  48
  49 use Rose::Object::MakeMethods::Generic
  50 (
  51  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  52  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  53 );
  54
  55
  56 # safety
  57 __PACKAGE__->run_before('check_auth');
  58
  59 __PACKAGE__->run_before('recalc',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 __PACKAGE__->run_before('get_unalterable_data',
  64                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  65                                      print send_email) ]);
  66
  67 #
  68 # actions
  69 #
  70
  71 # add a new order
  72 sub action_add {
  73   my ($self) = @_;
  74
  75   $self->order->transdate(DateTime->now_local());
  76   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  77                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  78
  79   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  80       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  81       && (!$self->order->reqdate)) {
  82     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  83   }
  84
  85
  86   $self->pre_render();
  87   $self->render(
  88     'order/form',
  89     title => $self->get_title_for('add'),
  90     %{$self->{template_args}}
  91   );
  92 }
  93
  94 # edit an existing order
  95 sub action_edit {
  96   my ($self) = @_;
  97
  98   if ($::form->{id}) {
  99     $self->load_order;
 100
 101   } else {
 102     # this is to edit an order from an unsaved order object
 103
 104     # set item ids to new fake id, to identify them as new items
 105     foreach my $item (@{$self->order->items_sorted}) {
 106       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 107     }
 108     # trigger rendering values for second row as hidden, because they
 109     # are loaded only on demand. So we need to keep the values from
 110     # the source.
 111     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 112   }
 113
 114   $self->recalc();
 115   $self->pre_render();
 116   $self->render(
 117     'order/form',
 118     title => $self->get_title_for('edit'),
 119     %{$self->{template_args}}
 120   );
 121 }
 122
 123 # edit a collective order (consisting of one or more existing orders)
 124 sub action_edit_collective {
 125   my ($self) = @_;
 126
 127   # collect order ids
 128   my @multi_ids = map {
 129     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 130   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 131
 132   # fall back to add if no ids are given
 133   if (scalar @multi_ids == 0) {
 134     $self->action_add();
 135     return;
 136   }
 137
 138   # fall back to save as new if only one id is given
 139   if (scalar @multi_ids == 1) {
 140     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 141     $self->action_save_as_new();
 142     return;
 143   }
 144
 145   # make new order from given orders
 146   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 147   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 148   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 149
 150   $self->action_edit();
 151 }
 152
 153 # delete the order
 154 sub action_delete {
 155   my ($self) = @_;
 156
 157   my $errors = $self->delete();
 158
 159   if (scalar @{ $errors }) {
 160     $self->js->flash('error', $_) foreach @{ $errors };
 161     return $self->js->render();
 162   }
 163
 164   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 165            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 166            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 167            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 168            : '';
 169   flash_later('info', $text);
 170
 171   my @redirect_params = (
 172     action => 'add',
 173     type   => $self->type,
 174   );
 175
 176   $self->redirect_to(@redirect_params);
 177 }
 178
 179 # save the order
 180 sub action_save {
 181   my ($self) = @_;
 182
 183   my $errors = $self->save();
 184
 185   if (scalar @{ $errors }) {
 186     $self->js->flash('error', $_) foreach @{ $errors };
 187     return $self->js->render();
 188   }
 189
 190   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 191            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 192            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 193            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 194            : '';
 195   flash_later('info', $text);
 196
 197   my @redirect_params = (
 198     action => 'edit',
 199     type   => $self->type,
 200     id     => $self->order->id,
 201   );
 202
 203   $self->redirect_to(@redirect_params);
 204 }
 205
 206 # save the order as new document an open it for edit
 207 sub action_save_as_new {
 208   my ($self) = @_;
 209
 210   my $order = $self->order;
 211
 212   if (!$order->id) {
 213     $self->js->flash('error', t8('This object has not been saved yet.'));
 214     return $self->js->render();
 215   }
 216
 217   # load order from db to check if values changed
 218   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 219
 220   my %new_attrs;
 221   # Lets assign a new number if the user hasn't changed the previous one.
 222   # If it has been changed manually then use it as-is.
 223   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 224                         ? ''
 225                         : trim($order->number);
 226
 227   # Clear transdate unless changed
 228   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 229                         ? DateTime->today_local
 230                         : $order->transdate;
 231
 232   # Set new reqdate unless changed if it is enabled in client config
 233   if ($order->reqdate == $saved_order->reqdate) {
 234     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 235                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 236
 237     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 238         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 239       $new_attrs{reqdate} = '';
 240     } else {
 241       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 242     }
 243   } else {
 244     $new_attrs{reqdate} = $order->reqdate;
 245   }
 246
 247   # Update employee
 248   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 249
 250   # Create new record from current one
 251   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 252
 253   # no linked records on save as new
 254   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 255
 256   # save
 257   $self->action_save();
 258 }
 259
 260 # print the order
 261 #
 262 # This is called if "print" is pressed in the print dialog.
 263 # If PDF creation was requested and succeeded, the pdf is offered for download
 264 # via send_file (which uses ajax in this case).
 265 sub action_print {
 266   my ($self) = @_;
 267
 268   my $errors = $self->save();
 269
 270   if (scalar @{ $errors }) {
 271     $self->js->flash('error', $_) foreach @{ $errors };
 272     return $self->js->render();
 273   }
 274
 275   $self->js_reset_order_and_item_ids_after_save;
 276
 277   my $format      = $::form->{print_options}->{format};
 278   my $media       = $::form->{print_options}->{media};
 279   my $formname    = $::form->{print_options}->{formname};
 280   my $copies      = $::form->{print_options}->{copies};
 281   my $groupitems  = $::form->{print_options}->{groupitems};
 282   my $printer_id  = $::form->{print_options}->{printer_id};
 283
 284   # only PDF, OpenDocument & HTML for now
 285   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 286     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 287   }
 288
 289   # only screen or printer by now
 290   if (none { $media eq $_ } qw(screen printer)) {
 291     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 292   }
 293
 294   # create a form for generate_attachment_filename
 295   my $form   = Form->new;
 296   $form->{$self->nr_key()}  = $self->order->number;
 297   $form->{type}             = $self->type;
 298   $form->{format}           = $format;
 299   $form->{formname}         = $formname;
 300   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 301   my $doc_filename          = $form->generate_attachment_filename();
 302
 303   my $doc;
 304   my @errors = $self->generate_doc(\$doc, { format     => $format,
 305                                             formname   => $formname,
 306                                             language   => $self->order->language,
 307                                             printer_id => $printer_id,
 308                                             groupitems => $groupitems });
 309   if (scalar @errors) {
 310     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 311   }
 312
 313   if ($media eq 'screen') {
 314     # screen/download
 315     $self->js->flash('info', t8('The document has been created.'));
 316     $self->send_file(
 317       \$doc,
 318       type         => SL::MIME->mime_type_from_ext($doc_filename),
 319       name         => $doc_filename,
 320       js_no_render => 1,
 321     );
 322
 323   } elsif ($media eq 'printer') {
 324     # printer
 325     my $printer_id = $::form->{print_options}->{printer_id};
 326     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 327       copies  => $copies,
 328       content => $doc,
 329     );
 330
 331     $self->js->flash('info', t8('The document has been printed.'));
 332   }
 333
 334   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 335   if (scalar @warnings) {
 336     $self->js->flash('warning', $_) for @warnings;
 337   }
 338
 339   $self->save_history('PRINTED');
 340
 341   $self->js
 342     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 343     ->render;
 344 }
 345 sub action_preview_pdf {
 346   my ($self) = @_;
 347
 348   my $errors = $self->save();
 349   if (scalar @{ $errors }) {
 350     $self->js->flash('error', $_) foreach @{ $errors };
 351     return $self->js->render();
 352   }
 353
 354   $self->js_reset_order_and_item_ids_after_save;
 355
 356   my $format      = 'pdf';
 357   my $media       = 'screen';
 358   my $formname    = $self->type;
 359
 360   # only pdf
 361   # create a form for generate_attachment_filename
 362   my $form   = Form->new;
 363   $form->{$self->nr_key()}  = $self->order->number;
 364   $form->{type}             = $self->type;
 365   $form->{format}           = $format;
 366   $form->{formname}         = $formname;
 367   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 368   my $pdf_filename          = $form->generate_attachment_filename();
 369
 370   my $pdf;
 371   my @errors = $self->generate_doc(\$pdf, { format     => $format,
 372                                             formname   => $formname,
 373                                             language   => $self->order->language,
 374                                           });
 375   if (scalar @errors) {
 376     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 377   }
 378   $self->save_history('PREVIEWED');
 379   $self->js->flash('info', t8('The PDF has been previewed'));
 380   # screen/download
 381   $self->send_file(
 382     \$pdf,
 383     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 384     name         => $pdf_filename,
 385     js_no_render => 0,
 386   );
 387 }
 388
 389 # open the email dialog
 390 sub action_save_and_show_email_dialog {
 391   my ($self) = @_;
 392
 393   my $errors = $self->save();
 394
 395   if (scalar @{ $errors }) {
 396     $self->js->flash('error', $_) foreach @{ $errors };
 397     return $self->js->render();
 398   }
 399
 400   my $cv_method = $self->cv;
 401
 402   if (!$self->order->$cv_method) {
 403     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 404                     ->render($self);
 405   }
 406
 407   my $email_form;
 408   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 409   $email_form->{to} ||= $self->order->$cv_method->email;
 410   $email_form->{cc}   = $self->order->$cv_method->cc;
 411   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 412   # Todo: get addresses from shipto, if any
 413
 414   my $form = Form->new;
 415   $form->{$self->nr_key()}  = $self->order->number;
 416   $form->{cusordnumber}     = $self->order->cusordnumber;
 417   $form->{formname}         = $self->type;
 418   $form->{type}             = $self->type;
 419   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 420   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 421   $form->{format}           = 'pdf';
 422   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 423
 424   $email_form->{subject}             = $form->generate_email_subject();
 425   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 426   $email_form->{message}             = $form->generate_email_body();
 427   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 428
 429   my %files = $self->get_files_for_email_dialog();
 430
 431   my @employees_with_email = grep {
 432     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 433     $user && !!trim($user->get_config_value('email'));
 434   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 435
 436   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 437                                   email_form    => $email_form,
 438                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 439                                   FILES         => \%files,
 440                                   is_customer   => $self->cv eq 'customer',
 441                                   ALL_EMPLOYEES => \@employees_with_email,
 442   );
 443
 444   $self->js
 445       ->run('kivi.Order.show_email_dialog', $dialog_html)
 446       ->reinit_widgets
 447       ->render($self);
 448 }
 449
 450 # send email
 451 #
 452 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 453 sub action_send_email {
 454   my ($self) = @_;
 455
 456   my $errors = $self->save();
 457
 458   if (scalar @{ $errors }) {
 459     $self->js->run('kivi.Order.close_email_dialog');
 460     $self->js->flash('error', $_) foreach @{ $errors };
 461     return $self->js->render();
 462   }
 463
 464   $self->js_reset_order_and_item_ids_after_save;
 465
 466   my $email_form  = delete $::form->{email_form};
 467   my %field_names = (to => 'email');
 468
 469   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 470
 471   # for Form::cleanup which may be called in Form::send_email
 472   $::form->{cwd}    = getcwd();
 473   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 474
 475   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 476   $::form->{media}  = 'email';
 477
 478   $::form->{attachment_policy} //= '';
 479
 480   # Is an old file version available?
 481   my $attfile;
 482   if ($::form->{attachment_policy} eq 'old_file') {
 483     $attfile = SL::File->get_all(object_id     => $self->order->id,
 484                                  object_type   => $self->type,
 485                                  file_type     => 'document',
 486                                  print_variant => $::form->{formname});
 487   }
 488
 489   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 490     my $doc;
 491     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 492                                              format     => $::form->{print_options}->{format},
 493                                              formname   => $::form->{print_options}->{formname},
 494                                              language   => $self->order->language,
 495                                              printer_id => $::form->{print_options}->{printer_id},
 496                                              groupitems => $::form->{print_options}->{groupitems}});
 497     if (scalar @errors) {
 498       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 499     }
 500
 501     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 502     if (scalar @warnings) {
 503       flash_later('warning', $_) for @warnings;
 504     }
 505
 506     my $sfile = SL::SessionFile::Random->new(mode => "w");
 507     $sfile->fh->print($doc);
 508     $sfile->fh->close;
 509
 510     $::form->{tmpfile} = $sfile->file_name;
 511     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 512   }
 513
 514   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 515   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 516
 517   # internal notes
 518   my $intnotes = $self->order->intnotes;
 519   $intnotes   .= "\n\n" if $self->order->intnotes;
 520   $intnotes   .= t8('[email]')                                                                                        . "\n";
 521   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 522   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 523   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 524   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 525   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 526   $intnotes   .= t8('Message')    . ": " . SL::HTML::Util->strip($::form->{message});
 527
 528   $self->order->update_attributes(intnotes => $intnotes);
 529
 530   $self->save_history('MAILED');
 531
 532   flash_later('info', t8('The email has been sent.'));
 533
 534   my @redirect_params = (
 535     action => 'edit',
 536     type   => $self->type,
 537     id     => $self->order->id,
 538   );
 539
 540   $self->redirect_to(@redirect_params);
 541 }
 542
 543 # open the periodic invoices config dialog
 544 #
 545 # If there are values in the form (i.e. dialog was opened before),
 546 # then use this values. Create new ones, else.
 547 sub action_show_periodic_invoices_config_dialog {
 548   my ($self) = @_;
 549
 550   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 551   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 552   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 553                                                    order_value_periodicity => 'p', # = same as periodicity
 554                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 555                                                    extend_automatically_by => 12,
 556                                                    active                  => 1,
 557                                                    email_subject           => GenericTranslations->get(
 558                                                                                 language_id      => $::form->{language_id},
 559                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 560                                                    email_body              => GenericTranslations->get(
 561                                                                                 language_id      => $::form->{language_id},
 562                                                                                 translation_type => "salutation_general")
 563                                                                             . GenericTranslations->get(
 564                                                                                 language_id      => $::form->{language_id},
 565                                                                                 translation_type => "salutation_punctuation_mark") . "\n\n"
 566                                                                             . GenericTranslations->get(
 567                                                                                 language_id      => $::form->{language_id},
 568                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 569   );
 570   # for older configs, replace email preset text if not yet set.
 571   $config->email_subject(GenericTranslations->get(
 572                                               language_id      => $::form->{language_id},
 573                                               translation_type =>"preset_text_periodic_invoices_email_subject")
 574                         ) unless $config->email_subject;
 575
 576   $config->email_body(GenericTranslations->get(
 577                                               language_id      => $::form->{language_id},
 578                                               translation_type => "salutation_general")
 579                     . GenericTranslations->get(
 580                                               language_id      => $::form->{language_id},
 581                                               translation_type => "salutation_punctuation_mark") . "\n\n"
 582                     . GenericTranslations->get(
 583                                               language_id      => $::form->{language_id},
 584                                               translation_type =>"preset_text_periodic_invoices_email_body")
 585                      ) unless $config->email_body;
 586
 587   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 588   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 589
 590   $::form->get_lists(printers => "ALL_PRINTERS",
 591                      charts   => { key       => 'ALL_CHARTS',
 592                                    transdate => 'current_date' });
 593
 594   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 595
 596   if ($::form->{customer_id}) {
 597     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 598     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 599     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 600     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 601     $config->send_email(0) if $::form->{postal_invoice};
 602   }
 603
 604   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 605                 popup_dialog             => 1,
 606                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 607                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 608                 config                   => $config,
 609                 %$::form);
 610 }
 611
 612 # assign the values of the periodic invoices config dialog
 613 # as yaml in the hidden tag and set the status.
 614 sub action_assign_periodic_invoices_config {
 615   my ($self) = @_;
 616
 617   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 618
 619   my $config = { active                     => $::form->{active}       ? 1 : 0,
 620                  terminated                 => $::form->{terminated}   ? 1 : 0,
 621                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 622                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 623                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 624                  start_date_as_date         => $::form->{start_date_as_date},
 625                  end_date_as_date           => $::form->{end_date_as_date},
 626                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 627                  print                      => $::form->{print}      ? 1                         : 0,
 628                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 629                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 630                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 631                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 632                  send_email                 => $::form->{send_email} ? 1 : 0,
 633                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 634                  email_recipient_address    => $::form->{email_recipient_address},
 635                  email_sender               => $::form->{email_sender},
 636                  email_subject              => $::form->{email_subject},
 637                  email_body                 => $::form->{email_body},
 638                };
 639
 640   my $periodic_invoices_config = SL::YAML::Dump($config);
 641
 642   my $status = $self->get_periodic_invoices_status($config);
 643
 644   $self->js
 645     ->remove('#order_periodic_invoices_config')
 646     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 647     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 648     ->html('#periodic_invoices_status', $status)
 649     ->flash('info', t8('The periodic invoices config has been assigned.'))
 650     ->render($self);
 651 }
 652
 653 sub action_get_has_active_periodic_invoices {
 654   my ($self) = @_;
 655
 656   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 657   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 658
 659   my $has_active_periodic_invoices =
 660        $self->type eq sales_order_type()
 661     && $config
 662     && $config->active
 663     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 664     && $config->get_previous_billed_period_start_date;
 665
 666   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 667 }
 668
 669 # save the order and redirect to the frontend subroutine for a new
 670 # delivery order
 671 sub action_save_and_delivery_order {
 672   my ($self) = @_;
 673
 674   $self->save_and_redirect_to(
 675     controller => 'oe.pl',
 676     action     => 'oe_delivery_order_from_order',
 677   );
 678 }
 679
 680 # save the order and redirect to the frontend subroutine for a new
 681 # invoice
 682 sub action_save_and_invoice {
 683   my ($self) = @_;
 684
 685   $self->save_and_redirect_to(
 686     controller => 'oe.pl',
 687     action     => 'oe_invoice_from_order',
 688   );
 689 }
 690
 691 sub action_save_and_invoice_for_advance_payment {
 692   my ($self) = @_;
 693
 694   $self->save_and_redirect_to(
 695     controller       => 'oe.pl',
 696     action           => 'oe_invoice_from_order',
 697     new_invoice_type => 'invoice_for_advance_payment',
 698   );
 699 }
 700
 701 sub action_save_and_final_invoice {
 702   my ($self) = @_;
 703
 704   $self->save_and_redirect_to(
 705     controller       => 'oe.pl',
 706     action           => 'oe_invoice_from_order',
 707     new_invoice_type => 'final_invoice',
 708   );
 709 }
 710
 711 # workflow from sales order to sales quotation
 712 sub action_sales_quotation {
 713   $_[0]->workflow_sales_or_request_for_quotation();
 714 }
 715
 716 # workflow from sales order to sales quotation
 717 sub action_request_for_quotation {
 718   $_[0]->workflow_sales_or_request_for_quotation();
 719 }
 720
 721 # workflow from sales quotation to sales order
 722 sub action_sales_order {
 723   $_[0]->workflow_sales_or_purchase_order();
 724 }
 725
 726 # workflow from rfq to purchase order
 727 sub action_purchase_order {
 728   $_[0]->workflow_sales_or_purchase_order();
 729 }
 730
 731 # workflow from purchase order to ap transaction
 732 sub action_save_and_ap_transaction {
 733   my ($self) = @_;
 734
 735   $self->save_and_redirect_to(
 736     controller => 'ap.pl',
 737     action     => 'add_from_purchase_order',
 738   );
 739 }
 740
 741 # set form elements in respect to a changed customer or vendor
 742 #
 743 # This action is called on an change of the customer/vendor picker.
 744 sub action_customer_vendor_changed {
 745   my ($self) = @_;
 746
 747   setup_order_from_cv($self->order);
 748   $self->recalc();
 749
 750   my $cv_method = $self->cv;
 751
 752   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 753     $self->js->show('#cp_row');
 754   } else {
 755     $self->js->hide('#cp_row');
 756   }
 757
 758   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 759     $self->js->show('#shipto_selection');
 760   } else {
 761     $self->js->hide('#shipto_selection');
 762   }
 763
 764   if ($cv_method eq 'customer') {
 765     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 766     $self->js->$show_hide('#billing_address_row');
 767   }
 768
 769   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 770
 771   $self->js
 772     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 773     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 774     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 775     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 776     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 777     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 778     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 779     ->val(        '#order_currency_id',        $self->order->currency_id)
 780     ->val(        '#order_payment_id',         $self->order->payment_id)
 781     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 782     ->val(        '#order_intnotes',           $self->order->intnotes)
 783     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 784     ->focus(      '#order_' . $self->cv . '_id')
 785     ->run('kivi.Order.update_exchangerate');
 786
 787   $self->js_redisplay_amounts_and_taxes;
 788   $self->js_redisplay_cvpartnumbers;
 789   $self->js->render();
 790 }
 791
 792 # open the dialog for customer/vendor details
 793 sub action_show_customer_vendor_details_dialog {
 794   my ($self) = @_;
 795
 796   my $is_customer = 'customer' eq $::form->{vc};
 797   my $cv;
 798   if ($is_customer) {
 799     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 800   } else {
 801     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 802   }
 803
 804   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 805   $details{discount_as_percent} = $cv->discount_as_percent;
 806   $details{creditlimt}          = $cv->creditlimit_as_number;
 807   $details{business}            = $cv->business->description      if $cv->business;
 808   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 809   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 810   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 811   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 812
 813   if ($is_customer) {
 814     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 815       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 816     }
 817   }
 818   foreach my $entry (@{ $cv->shipto }) {
 819     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 820   }
 821   foreach my $entry (@{ $cv->contacts }) {
 822     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 823   }
 824
 825   $_[0]->render('common/show_vc_details', { layout => 0 },
 826                 is_customer => $is_customer,
 827                 %details);
 828
 829 }
 830
 831 # called if a unit in an existing item row is changed
 832 sub action_unit_changed {
 833   my ($self) = @_;
 834
 835   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 836   my $item = $self->order->items_sorted->[$idx];
 837
 838   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 839   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 840
 841   $self->recalc();
 842
 843   $self->js
 844     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 845   $self->js_redisplay_line_values;
 846   $self->js_redisplay_amounts_and_taxes;
 847   $self->js->render();
 848 }
 849
 850 # add an item row for a new item entered in the input row
 851 sub action_add_item {
 852   my ($self) = @_;
 853
 854   delete $::form->{add_item}->{create_part_type};
 855
 856   my $form_attr = $::form->{add_item};
 857
 858   return unless $form_attr->{parts_id};
 859
 860   my $item = new_item($self->order, $form_attr);
 861
 862   $self->order->add_items($item);
 863
 864   $self->recalc();
 865
 866   $self->get_item_cvpartnumber($item);
 867
 868   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 869   my $row_as_html = $self->p->render('order/tabs/_row',
 870                                      ITEM => $item,
 871                                      ID   => $item_id,
 872                                      SELF => $self,
 873   );
 874
 875   if ($::form->{insert_before_item_id}) {
 876     $self->js
 877       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 878   } else {
 879     $self->js
 880       ->append('#row_table_id', $row_as_html);
 881   }
 882
 883   if ( $item->part->is_assortment ) {
 884     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 885     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 886       my $attr = { parts_id => $assortment_item->parts_id,
 887                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 888                    unit     => $assortment_item->unit,
 889                    description => $assortment_item->part->description,
 890                  };
 891       my $item = new_item($self->order, $attr);
 892
 893       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 894       $item->discount(1) unless $assortment_item->charge;
 895
 896       $self->order->add_items( $item );
 897       $self->recalc();
 898       $self->get_item_cvpartnumber($item);
 899       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 900       my $row_as_html = $self->p->render('order/tabs/_row',
 901                                          ITEM => $item,
 902                                          ID   => $item_id,
 903                                          SELF => $self,
 904       );
 905       if ($::form->{insert_before_item_id}) {
 906         $self->js
 907           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 908       } else {
 909         $self->js
 910           ->append('#row_table_id', $row_as_html);
 911       }
 912     };
 913   };
 914
 915   $self->js
 916     ->val('.add_item_input', '')
 917     ->run('kivi.Order.init_row_handlers')
 918     ->run('kivi.Order.renumber_positions')
 919     ->focus('#add_item_parts_id_name');
 920
 921   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 922
 923   $self->js_redisplay_amounts_and_taxes;
 924   $self->js->render();
 925 }
 926
 927 # add item rows for multiple items at once
 928 sub action_add_multi_items {
 929   my ($self) = @_;
 930
 931   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 932   return $self->js->render() unless scalar @form_attr;
 933
 934   my @items;
 935   foreach my $attr (@form_attr) {
 936     my $item = new_item($self->order, $attr);
 937     push @items, $item;
 938     if ( $item->part->is_assortment ) {
 939       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 940         my $attr = { parts_id => $assortment_item->parts_id,
 941                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 942                      unit     => $assortment_item->unit,
 943                      description => $assortment_item->part->description,
 944                    };
 945         my $item = new_item($self->order, $attr);
 946
 947         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 948         $item->discount(1) unless $assortment_item->charge;
 949         push @items, $item;
 950       }
 951     }
 952   }
 953   $self->order->add_items(@items);
 954
 955   $self->recalc();
 956
 957   foreach my $item (@items) {
 958     $self->get_item_cvpartnumber($item);
 959     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 960     my $row_as_html = $self->p->render('order/tabs/_row',
 961                                        ITEM => $item,
 962                                        ID   => $item_id,
 963                                        SELF => $self,
 964     );
 965
 966     if ($::form->{insert_before_item_id}) {
 967       $self->js
 968         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 969     } else {
 970       $self->js
 971         ->append('#row_table_id', $row_as_html);
 972     }
 973   }
 974
 975   $self->js
 976     ->run('kivi.Part.close_picker_dialogs')
 977     ->run('kivi.Order.init_row_handlers')
 978     ->run('kivi.Order.renumber_positions')
 979     ->focus('#add_item_parts_id_name');
 980
 981   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 982
 983   $self->js_redisplay_amounts_and_taxes;
 984   $self->js->render();
 985 }
 986
 987 # recalculate all linetotals, amounts and taxes and redisplay them
 988 sub action_recalc_amounts_and_taxes {
 989   my ($self) = @_;
 990
 991   $self->recalc();
 992
 993   $self->js_redisplay_line_values;
 994   $self->js_redisplay_amounts_and_taxes;
 995   $self->js->render();
 996 }
 997
 998 sub action_update_exchangerate {
 999   my ($self) = @_;
1000
1001   my $data = {
1002     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
1003     currency_name => $self->order->currency->name,
1004     exchangerate  => $self->order->daily_exchangerate_as_null_number,
1005   };
1006
1007   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
1008 }
1009
1010 # redisplay item rows if they are sorted by an attribute
1011 sub action_reorder_items {
1012   my ($self) = @_;
1013
1014   my %sort_keys = (
1015     partnumber   => sub { $_[0]->part->partnumber },
1016     description  => sub { $_[0]->description },
1017     qty          => sub { $_[0]->qty },
1018     sellprice    => sub { $_[0]->sellprice },
1019     discount     => sub { $_[0]->discount },
1020     cvpartnumber => sub { $_[0]->{cvpartnumber} },
1021   );
1022
1023   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1024
1025   my $method = $sort_keys{$::form->{order_by}};
1026   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
1027   if ($::form->{sort_dir}) {
1028     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1029       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
1030     } else {
1031       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
1032     }
1033   } else {
1034     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1035       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
1036     } else {
1037       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
1038     }
1039   }
1040   $self->js
1041     ->run('kivi.Order.redisplay_items', \@to_sort)
1042     ->render;
1043 }
1044
1045 # show the popup to choose a price/discount source
1046 sub action_price_popup {
1047   my ($self) = @_;
1048
1049   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1050   my $item = $self->order->items_sorted->[$idx];
1051
1052   $self->render_price_dialog($item);
1053 }
1054
1055 # save the order in a session variable and redirect to the part controller
1056 sub action_create_part {
1057   my ($self) = @_;
1058
1059   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1060
1061   my $callback     = $self->url_for(
1062     action       => 'return_from_create_part',
1063     type         => $self->type, # type is needed for check_auth on return
1064     previousform => $previousform,
1065   );
1066
1067   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1068
1069   my @redirect_params = (
1070     controller => 'Part',
1071     action     => 'add',
1072     part_type  => $::form->{add_item}->{create_part_type},
1073     callback   => $callback,
1074     show_abort => 1,
1075   );
1076
1077   $self->redirect_to(@redirect_params);
1078 }
1079
1080 sub action_return_from_create_part {
1081   my ($self) = @_;
1082
1083   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1084
1085   $::auth->restore_form_from_session(delete $::form->{previousform});
1086
1087   # set item ids to new fake id, to identify them as new items
1088   foreach my $item (@{$self->order->items_sorted}) {
1089     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1090   }
1091
1092   $self->recalc();
1093   $self->get_unalterable_data();
1094   $self->pre_render();
1095
1096   # trigger rendering values for second row/longdescription as hidden,
1097   # because they are loaded only on demand. So we need to keep the values
1098   # from the source.
1099   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1100   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1101
1102   $self->render(
1103     'order/form',
1104     title => $self->get_title_for('edit'),
1105     %{$self->{template_args}}
1106   );
1107
1108 }
1109
1110 # load the second row for one or more items
1111 #
1112 # This action gets the html code for all items second rows by rendering a template for
1113 # the second row and sets the html code via client js.
1114 sub action_load_second_rows {
1115   my ($self) = @_;
1116
1117   $self->recalc() if $self->order->is_sales; # for margin calculation
1118
1119   foreach my $item_id (@{ $::form->{item_ids} }) {
1120     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1121     my $item = $self->order->items_sorted->[$idx];
1122
1123     $self->js_load_second_row($item, $item_id, 0);
1124   }
1125
1126   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1127
1128   $self->js->render();
1129 }
1130
1131 # update description, notes and sellprice from master data
1132 sub action_update_row_from_master_data {
1133   my ($self) = @_;
1134
1135   foreach my $item_id (@{ $::form->{item_ids} }) {
1136     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1137     my $item  = $self->order->items_sorted->[$idx];
1138     my $texts = get_part_texts($item->part, $self->order->language_id);
1139
1140     $item->description($texts->{description});
1141     $item->longdescription($texts->{longdescription});
1142
1143     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1144
1145     my $price_src;
1146     if ($item->part->is_assortment) {
1147     # add assortment items with price 0, as the components carry the price
1148       $price_src = $price_source->price_from_source("");
1149       $price_src->price(0);
1150     } else {
1151       $price_src = $price_source->best_price
1152                  ? $price_source->best_price
1153                  : $price_source->price_from_source("");
1154       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1155       $price_src->price(0) if !$price_source->best_price;
1156     }
1157
1158
1159     $item->sellprice($price_src->price);
1160     $item->active_price_source($price_src);
1161
1162     $self->js
1163       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1164       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1165       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1166       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1167
1168     if ($self->search_cvpartnumber) {
1169       $self->get_item_cvpartnumber($item);
1170       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1171     }
1172   }
1173
1174   $self->recalc();
1175   $self->js_redisplay_line_values;
1176   $self->js_redisplay_amounts_and_taxes;
1177
1178   $self->js->render();
1179 }
1180
1181 sub js_load_second_row {
1182   my ($self, $item, $item_id, $do_parse) = @_;
1183
1184   if ($do_parse) {
1185     # Parse values from form (they are formated while rendering (template)).
1186     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1187     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1188     foreach my $var (@{ $item->cvars_by_config }) {
1189       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1190     }
1191     $item->parse_custom_variable_values;
1192   }
1193
1194   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1195
1196   $self->js
1197     ->html('#second_row_' . $item_id, $row_as_html)
1198     ->data('#second_row_' . $item_id, 'loaded', 1);
1199 }
1200
1201 sub js_redisplay_line_values {
1202   my ($self) = @_;
1203
1204   my $is_sales = $self->order->is_sales;
1205
1206   # sales orders with margins
1207   my @data;
1208   if ($is_sales) {
1209     @data = map {
1210       [
1211        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1212        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1213        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1214       ]} @{ $self->order->items_sorted };
1215   } else {
1216     @data = map {
1217       [
1218        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1219       ]} @{ $self->order->items_sorted };
1220   }
1221
1222   $self->js
1223     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1224 }
1225
1226 sub js_redisplay_amounts_and_taxes {
1227   my ($self) = @_;
1228
1229   if (scalar @{ $self->{taxes} }) {
1230     $self->js->show('#taxincluded_row_id');
1231   } else {
1232     $self->js->hide('#taxincluded_row_id');
1233   }
1234
1235   if ($self->order->taxincluded) {
1236     $self->js->hide('#subtotal_row_id');
1237   } else {
1238     $self->js->show('#subtotal_row_id');
1239   }
1240
1241   if ($self->order->is_sales) {
1242     my $is_neg = $self->order->marge_total < 0;
1243     $self->js
1244       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1245       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1246       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1247       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1248       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1249       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1250       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1251       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1252   }
1253
1254   $self->js
1255     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1256     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1257     ->remove('.tax_row')
1258     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1259 }
1260
1261 sub js_redisplay_cvpartnumbers {
1262   my ($self) = @_;
1263
1264   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1265
1266   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1267
1268   $self->js
1269     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1270 }
1271
1272 sub js_reset_order_and_item_ids_after_save {
1273   my ($self) = @_;
1274
1275   $self->js
1276     ->val('#id', $self->order->id)
1277     ->val('#converted_from_oe_id', '')
1278     ->val('#order_' . $self->nr_key(), $self->order->number);
1279
1280   my $idx = 0;
1281   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1282     next if !$self->order->items_sorted->[$idx]->id;
1283     next if $form_item_id !~ m{^new};
1284     $self->js
1285       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1286       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1287       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1288   } continue {
1289     $idx++;
1290   }
1291   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1292 }
1293
1294 #
1295 # helpers
1296 #
1297
1298 sub init_valid_types {
1299   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1300 }
1301
1302 sub init_type {
1303   my ($self) = @_;
1304
1305   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1306     die "Not a valid type for order";
1307   }
1308
1309   $self->type($::form->{type});
1310 }
1311
1312 sub init_cv {
1313   my ($self) = @_;
1314
1315   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1316          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1317          : die "Not a valid type for order";
1318
1319   return $cv;
1320 }
1321
1322 sub init_search_cvpartnumber {
1323   my ($self) = @_;
1324
1325   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1326   my $search_cvpartnumber;
1327   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1328   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1329
1330   return $search_cvpartnumber;
1331 }
1332
1333 sub init_show_update_button {
1334   my ($self) = @_;
1335
1336   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1337 }
1338
1339 sub init_p {
1340   SL::Presenter->get;
1341 }
1342
1343 sub init_order {
1344   $_[0]->make_order;
1345 }
1346
1347 sub init_all_price_factors {
1348   SL::DB::Manager::PriceFactor->get_all;
1349 }
1350
1351 sub init_part_picker_classification_ids {
1352   my ($self)    = @_;
1353   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1354
1355   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1356 }
1357
1358 sub check_auth {
1359   my ($self) = @_;
1360
1361   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1362
1363   my $right   = $right_for->{ $self->type };
1364   $right    ||= 'DOES_NOT_EXIST';
1365
1366   $::auth->assert($right);
1367 }
1368
1369 # build the selection box for contacts
1370 #
1371 # Needed, if customer/vendor changed.
1372 sub build_contact_select {
1373   my ($self) = @_;
1374
1375   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1376     value_key  => 'cp_id',
1377     title_key  => 'full_name_dep',
1378     default    => $self->order->cp_id,
1379     with_empty => 1,
1380     style      => 'width: 300px',
1381   );
1382 }
1383
1384 # build the selection box for the additional billing address
1385 #
1386 # Needed, if customer/vendor changed.
1387 sub build_billing_address_select {
1388   my ($self) = @_;
1389
1390   return '' if $self->cv ne 'customer';
1391
1392   select_tag('order.billing_address_id',
1393              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1394              value_key  => 'id',
1395              title_key  => 'displayable_id',
1396              default    => $self->order->billing_address_id,
1397              with_empty => 0,
1398              style      => 'width: 300px',
1399   );
1400 }
1401
1402 # build the selection box for shiptos
1403 #
1404 # Needed, if customer/vendor changed.
1405 sub build_shipto_select {
1406   my ($self) = @_;
1407
1408   select_tag('order.shipto_id',
1409              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1410              value_key  => 'shipto_id',
1411              title_key  => 'displayable_id',
1412              default    => $self->order->shipto_id,
1413              with_empty => 0,
1414              style      => 'width: 300px',
1415   );
1416 }
1417
1418 # build the inputs for the cusom shipto dialog
1419 #
1420 # Needed, if customer/vendor changed.
1421 sub build_shipto_inputs {
1422   my ($self) = @_;
1423
1424   my $content = $self->p->render('common/_ship_to_dialog',
1425                                  vc_obj      => $self->order->customervendor,
1426                                  cs_obj      => $self->order->custom_shipto,
1427                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1428                                  id_selector => '#order_shipto_id');
1429
1430   div_tag($content, id => 'shipto_inputs');
1431 }
1432
1433 # render the info line for business
1434 #
1435 # Needed, if customer/vendor changed.
1436 sub build_business_info_row
1437 {
1438   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1439 }
1440
1441 # build the rows for displaying taxes
1442 #
1443 # Called if amounts where recalculated and redisplayed.
1444 sub build_tax_rows {
1445   my ($self) = @_;
1446
1447   my $rows_as_html;
1448   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1449     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1450   }
1451   return $rows_as_html;
1452 }
1453
1454
1455 sub render_price_dialog {
1456   my ($self, $record_item) = @_;
1457
1458   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1459
1460   $self->js
1461     ->run(
1462       'kivi.io.price_chooser_dialog',
1463       t8('Available Prices'),
1464       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1465     )
1466     ->reinit_widgets;
1467
1468 #   if (@errors) {
1469 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1470 #     $self->js->show('#dialog_flash_error');
1471 #   }
1472
1473   $self->js->render;
1474 }
1475
1476 sub load_order {
1477   my ($self) = @_;
1478
1479   return if !$::form->{id};
1480
1481   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1482
1483   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1484   # You need a custom shipto object to call cvars_by_config to get the cvars.
1485   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1486
1487   return $self->order;
1488 }
1489
1490 # load or create a new order object
1491 #
1492 # And assign changes from the form to this object.
1493 # If the order is loaded from db, check if items are deleted in the form,
1494 # remove them form the object and collect them for removing from db on saving.
1495 # Then create/update items from form (via make_item) and add them.
1496 sub make_order {
1497   my ($self) = @_;
1498
1499   # add_items adds items to an order with no items for saving, but they cannot
1500   # be retrieved via items until the order is saved. Adding empty items to new
1501   # order here solves this problem.
1502   my $order;
1503   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1504   $order ||= SL::DB::Order->new(orderitems  => [],
1505                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1506                                 currency_id => $::instance_conf->get_currency_id(),);
1507
1508   my $cv_id_method = $self->cv . '_id';
1509   if (!$::form->{id} && $::form->{$cv_id_method}) {
1510     $order->$cv_id_method($::form->{$cv_id_method});
1511     setup_order_from_cv($order);
1512   }
1513
1514   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1515   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1516
1517   $order->assign_attributes(%{$::form->{order}});
1518
1519   $self->setup_custom_shipto_from_form($order, $::form);
1520
1521   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1522     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1523     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1524   }
1525
1526   # remove deleted items
1527   $self->item_ids_to_delete([]);
1528   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1529     my $item = $order->orderitems->[$idx];
1530     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1531       splice @{$order->orderitems}, $idx, 1;
1532       push @{$self->item_ids_to_delete}, $item->id;
1533     }
1534   }
1535
1536   my @items;
1537   my $pos = 1;
1538   foreach my $form_attr (@{$form_orderitems}) {
1539     my $item = make_item($order, $form_attr);
1540     $item->position($pos);
1541     push @items, $item;
1542     $pos++;
1543   }
1544   $order->add_items(grep {!$_->id} @items);
1545
1546   return $order;
1547 }
1548
1549 # create or update items from form
1550 #
1551 # Make item objects from form values. For items already existing read from db.
1552 # Create a new item else. And assign attributes.
1553 sub make_item {
1554   my ($record, $attr) = @_;
1555
1556   my $item;
1557   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1558
1559   my $is_new = !$item;
1560
1561   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1562   # they cannot be retrieved via custom_variables until the order/orderitem is
1563   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1564   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1565
1566   $item->assign_attributes(%$attr);
1567
1568   if ($is_new) {
1569     my $texts = get_part_texts($item->part, $record->language_id);
1570     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1571     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1572     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1573   }
1574
1575   return $item;
1576 }
1577
1578 # create a new item
1579 #
1580 # This is used to add one item
1581 sub new_item {
1582   my ($record, $attr) = @_;
1583
1584   my $item = SL::DB::OrderItem->new;
1585
1586   # Remove attributes where the user left or set the inputs empty.
1587   # So these attributes will be undefined and we can distinguish them
1588   # from zero later on.
1589   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1590     delete $attr->{$_} if $attr->{$_} eq '';
1591   }
1592
1593   $item->assign_attributes(%$attr);
1594
1595   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1596   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1597
1598   $item->unit($part->unit) if !$item->unit;
1599
1600   my $price_src;
1601   if ( $part->is_assortment ) {
1602     # add assortment items with price 0, as the components carry the price
1603     $price_src = $price_source->price_from_source("");
1604     $price_src->price(0);
1605   } elsif (defined $item->sellprice) {
1606     $price_src = $price_source->price_from_source("");
1607     $price_src->price($item->sellprice);
1608   } else {
1609     $price_src = $price_source->best_price
1610                ? $price_source->best_price
1611                : $price_source->price_from_source("");
1612     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1613     $price_src->price(0) if !$price_source->best_price;
1614   }
1615
1616   my $discount_src;
1617   if (defined $item->discount) {
1618     $discount_src = $price_source->discount_from_source("");
1619     $discount_src->discount($item->discount);
1620   } else {
1621     $discount_src = $price_source->best_discount
1622                   ? $price_source->best_discount
1623                   : $price_source->discount_from_source("");
1624     $discount_src->discount(0) if !$price_source->best_discount;
1625   }
1626
1627   my %new_attr;
1628   $new_attr{part}                   = $part;
1629   $new_attr{description}            = $part->description     if ! $item->description;
1630   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1631   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1632   $new_attr{sellprice}              = $price_src->price;
1633   $new_attr{discount}               = $discount_src->discount;
1634   $new_attr{active_price_source}    = $price_src;
1635   $new_attr{active_discount_source} = $discount_src;
1636   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1637   $new_attr{project_id}             = $record->globalproject_id;
1638   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1639
1640   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1641   # they cannot be retrieved via custom_variables until the order/orderitem is
1642   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1643   $new_attr{custom_variables} = [];
1644
1645   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1646
1647   $item->assign_attributes(%new_attr, %{ $texts });
1648
1649   return $item;
1650 }
1651
1652 sub setup_order_from_cv {
1653   my ($order) = @_;
1654
1655   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1656
1657   $order->intnotes($order->customervendor->notes);
1658
1659   return if !$order->is_sales;
1660
1661   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1662   $order->taxincluded(defined($order->customer->taxincluded_checked)
1663                       ? $order->customer->taxincluded_checked
1664                       : $::myconfig{taxincluded_checked});
1665
1666   my $address = $order->customer->default_billing_address;;
1667   $order->billing_address_id($address ? $address->id : undef);
1668 }
1669
1670 # setup custom shipto from form
1671 #
1672 # The dialog returns form variables starting with 'shipto' and cvars starting
1673 # with 'shiptocvar_'.
1674 # Mark it to be deleted if a shipto from master data is selected
1675 # (i.e. order has a shipto).
1676 # Else, update or create a new custom shipto. If the fields are empty, it
1677 # will not be saved on save.
1678 sub setup_custom_shipto_from_form {
1679   my ($self, $order, $form) = @_;
1680
1681   if ($order->shipto) {
1682     $self->is_custom_shipto_to_delete(1);
1683   } else {
1684     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1685
1686     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1687     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1688
1689     $custom_shipto->assign_attributes(%$shipto_attrs);
1690     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1691   }
1692 }
1693
1694 # recalculate prices and taxes
1695 #
1696 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1697 sub recalc {
1698   my ($self) = @_;
1699
1700   my %pat = $self->order->calculate_prices_and_taxes();
1701
1702   $self->{taxes} = [];
1703   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1704     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1705
1706     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1707                                 netamount => $netamount,
1708                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1709   }
1710   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1711 }
1712
1713 # get data for saving, printing, ..., that is not changed in the form
1714 #
1715 # Only cvars for now.
1716 sub get_unalterable_data {
1717   my ($self) = @_;
1718
1719   foreach my $item (@{ $self->order->items }) {
1720     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1721     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1722     foreach my $var (@{ $item->cvars_by_config }) {
1723       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1724     }
1725     $item->parse_custom_variable_values;
1726   }
1727 }
1728
1729 # delete the order
1730 #
1731 # And remove related files in the spool directory
1732 sub delete {
1733   my ($self) = @_;
1734
1735   my $errors = [];
1736   my $db     = $self->order->db;
1737
1738   $db->with_transaction(
1739     sub {
1740       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1741       $self->order->delete;
1742       my $spool = $::lx_office_conf{paths}->{spool};
1743       unlink map { "$spool/$_" } @spoolfiles if $spool;
1744
1745       $self->save_history('DELETED');
1746
1747       1;
1748   }) || push(@{$errors}, $db->error);
1749
1750   return $errors;
1751 }
1752
1753 # save the order
1754 #
1755 # And delete items that are deleted in the form.
1756 sub save {
1757   my ($self) = @_;
1758
1759   my $errors = [];
1760   my $db     = $self->order->db;
1761
1762   $db->with_transaction(sub {
1763     # delete custom shipto if it is to be deleted or if it is empty
1764     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1765       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1766       $self->order->custom_shipto(undef);
1767     }
1768
1769     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1770     $self->order->save(cascade => 1);
1771
1772     # link records
1773     if ($::form->{converted_from_oe_id}) {
1774       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1775
1776       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1777         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1778         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1779         $src->link_to_record($self->order);
1780       }
1781       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1782         my $idx = 0;
1783         foreach (@{ $self->order->items_sorted }) {
1784           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1785           next if !$from_id;
1786           SL::DB::RecordLink->new(from_table => 'orderitems',
1787                                   from_id    => $from_id,
1788                                   to_table   => 'orderitems',
1789                                   to_id      => $_->id
1790           )->save;
1791           $idx++;
1792         }
1793       }
1794
1795       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1796     }
1797
1798     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1799
1800     $self->save_history('SAVED');
1801
1802     1;
1803   }) || push(@{$errors}, $db->error);
1804
1805   return $errors;
1806 }
1807
1808 sub workflow_sales_or_request_for_quotation {
1809   my ($self) = @_;
1810
1811   # always save
1812   my $errors = $self->save();
1813
1814   if (scalar @{ $errors }) {
1815     $self->js->flash('error', $_) for @{ $errors };
1816     return $self->js->render();
1817   }
1818
1819   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1820
1821   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1822   $self->{converted_from_oe_id} = delete $::form->{id};
1823
1824   # set item ids to new fake id, to identify them as new items
1825   foreach my $item (@{$self->order->items_sorted}) {
1826     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1827   }
1828
1829   # change form type
1830   $::form->{type} = $destination_type;
1831   $self->type($self->init_type);
1832   $self->cv  ($self->init_cv);
1833   $self->check_auth;
1834
1835   $self->recalc();
1836   $self->get_unalterable_data();
1837   $self->pre_render();
1838
1839   # trigger rendering values for second row as hidden, because they
1840   # are loaded only on demand. So we need to keep the values from the
1841   # source.
1842   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1843
1844   $self->render(
1845     'order/form',
1846     title => $self->get_title_for('edit'),
1847     %{$self->{template_args}}
1848   );
1849 }
1850
1851 sub workflow_sales_or_purchase_order {
1852   my ($self) = @_;
1853
1854   # always save
1855   my $errors = $self->save();
1856
1857   if (scalar @{ $errors }) {
1858     $self->js->flash('error', $_) foreach @{ $errors };
1859     return $self->js->render();
1860   }
1861
1862   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1863                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1864                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1865                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1866                        : '';
1867
1868   # check for direct delivery
1869   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1870   my $custom_shipto;
1871   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1872       && $::form->{use_shipto} && $self->order->shipto) {
1873     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1874   }
1875
1876   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1877   $self->{converted_from_oe_id} = delete $::form->{id};
1878
1879   # set item ids to new fake id, to identify them as new items
1880   foreach my $item (@{$self->order->items_sorted}) {
1881     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1882   }
1883
1884   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1885     if ($::form->{use_shipto}) {
1886       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1887     } else {
1888       # remove any custom shipto if not wanted
1889       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1890     }
1891   }
1892
1893   # change form type
1894   $::form->{type} = $destination_type;
1895   $self->type($self->init_type);
1896   $self->cv  ($self->init_cv);
1897   $self->check_auth;
1898
1899   $self->recalc();
1900   $self->get_unalterable_data();
1901   $self->pre_render();
1902
1903   # trigger rendering values for second row as hidden, because they
1904   # are loaded only on demand. So we need to keep the values from the
1905   # source.
1906   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1907
1908   $self->render(
1909     'order/form',
1910     title => $self->get_title_for('edit'),
1911     %{$self->{template_args}}
1912   );
1913 }
1914
1915
1916 sub pre_render {
1917   my ($self) = @_;
1918
1919   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1920   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1921   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1922   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1923   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1924                                                                                               deleted => 0 ] ],
1925                                                                            sort_by => 'name');
1926   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1927                                                                                               deleted => 0 ] ],
1928                                                                            sort_by => 'name');
1929   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1930                                                                                                         obsolete => 0 ] ]);
1931   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1932   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1933   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1934   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1935   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1936
1937   my $print_form = Form->new('');
1938   $print_form->{type}        = $self->type;
1939   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1940   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1941     form => $print_form,
1942     options => {dialog_name_prefix => 'print_options.',
1943                 show_headers       => 1,
1944                 no_queue           => 1,
1945                 no_postscript      => 1,
1946                 no_opendocument    => 0,
1947                 no_html            => 0},
1948   );
1949
1950   foreach my $item (@{$self->order->orderitems}) {
1951     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1952     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1953     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1954   }
1955
1956   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1957     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1958     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1959     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1960     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
1961   }
1962
1963   if ($self->order->number && $::instance_conf->get_webdav) {
1964     my $webdav = SL::Webdav->new(
1965       type     => $self->type,
1966       number   => $self->order->number,
1967     );
1968     my @all_objects = $webdav->get_all_objects;
1969     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1970                                                     type => t8('File'),
1971                                                     link => File::Spec->catfile($_->full_filedescriptor),
1972                                                 } } @all_objects;
1973   }
1974
1975   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
1976       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
1977     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
1978   }
1979
1980   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1981
1982   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1983                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
1984   $self->setup_edit_action_bar;
1985 }
1986
1987 sub setup_edit_action_bar {
1988   my ($self, %params) = @_;
1989
1990   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1991                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1992                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1993
1994   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
1995   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
1996
1997   my $has_invoice_for_advance_payment;
1998   if ($self->order->id && $self->type eq sales_order_type()) {
1999     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2000     $has_invoice_for_advance_payment = any {'SL::DB::Invoice' eq ref $_ && "invoice_for_advance_payment" eq $_->type} @$lr;
2001   }
2002
2003   my $has_final_invoice;
2004   if ($self->order->id && $self->type eq sales_order_type()) {
2005     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2006     $has_final_invoice               = any {'SL::DB::Invoice' eq ref $_ && "final_invoice" eq $_->type} @$lr;
2007   }
2008
2009   for my $bar ($::request->layout->get('actionbar')) {
2010     $bar->add(
2011       combobox => [
2012         action => [
2013           t8('Save'),
2014           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2015                                                     $::instance_conf->get_order_warn_no_deliverydate,
2016           ],
2017           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2018                          @req_trans_cost_art, @req_cusordnumber,
2019           ],
2020         ],
2021         action => [
2022           t8('Save as new'),
2023           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
2024           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2025                          @req_trans_cost_art, @req_cusordnumber,
2026           ],
2027           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2028         ],
2029       ], # end of combobox "Save"
2030
2031       combobox => [
2032         action => [
2033           t8('Workflow'),
2034         ],
2035         action => [
2036           t8('Save and Quotation'),
2037           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
2038           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2039           only_if  => (any { $self->type eq $_ } (sales_order_type())),
2040         ],
2041         action => [
2042           t8('Save and RFQ'),
2043           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
2044           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
2045         ],
2046         action => [
2047           t8('Save and Sales Order'),
2048           submit   => [ '#order_form', { action => "Order/sales_order" } ],
2049           checks   => [ @req_trans_cost_art ],
2050           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
2051         ],
2052         action => [
2053           t8('Save and Purchase Order'),
2054           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
2055           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2056           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2057         ],
2058         action => [
2059           t8('Save and Delivery Order'),
2060           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2061                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2062                                                                                                                         ],
2063           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2064                          @req_trans_cost_art, @req_cusordnumber,
2065           ],
2066           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
2067         ],
2068         action => [
2069           t8('Save and Invoice'),
2070           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2071           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2072                          @req_trans_cost_art, @req_cusordnumber,
2073           ],
2074         ],
2075         action => [
2076           ($has_invoice_for_advance_payment ? t8('Save and Further Invoice for Advance Payment') : t8('Save and Invoice for Advance Payment')),
2077           call      => [ 'kivi.Order.save', 'save_and_invoice_for_advance_payment', $::instance_conf->get_order_warn_duplicate_parts ],
2078           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2079                          @req_trans_cost_art, @req_cusordnumber,
2080           ],
2081           disabled  => $has_final_invoice ? t8('This order has already a final invoice.')
2082                                           : undef,
2083           only_if   => (any { $self->type eq $_ } (sales_order_type())),
2084         ],
2085         action => [
2086           t8('Save and Final Invoice'),
2087           call      => [ 'kivi.Order.save', 'save_and_final_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2088           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2089                          @req_trans_cost_art, @req_cusordnumber,
2090           ],
2091           disabled  => $has_final_invoice ? t8('This order has already a final invoice.')
2092                                           : undef,
2093           only_if   => (any { $self->type eq $_ } (sales_order_type())) && $has_invoice_for_advance_payment,
2094         ],
2095         action => [
2096           t8('Save and AP Transaction'),
2097           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2098           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
2099         ],
2100
2101       ], # end of combobox "Workflow"
2102
2103       combobox => [
2104         action => [
2105           t8('Export'),
2106         ],
2107         action => [
2108           t8('Save and preview PDF'),
2109           call   => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2110                                                         $::instance_conf->get_order_warn_no_deliverydate,
2111                     ],
2112           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2113         ],
2114         action => [
2115           t8('Save and print'),
2116           call   => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2117                                                        $::instance_conf->get_order_warn_no_deliverydate,
2118                     ],
2119           checks => [ @req_trans_cost_art, @req_cusordnumber ],
2120         ],
2121         action => [
2122           t8('Save and E-mail'),
2123           id   => 'save_and_email_action',
2124           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2125                                                                      $::instance_conf->get_order_warn_no_deliverydate,
2126                   ],
2127           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2128         ],
2129         action => [
2130           t8('Download attachments of all parts'),
2131           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2132           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2133           only_if  => $::instance_conf->get_doc_storage,
2134         ],
2135       ], # end of combobox "Export"
2136
2137       action => [
2138         t8('Delete'),
2139         call     => [ 'kivi.Order.delete_order' ],
2140         confirm  => $::locale->text('Do you really want to delete this object?'),
2141         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2142         only_if  => $deletion_allowed,
2143       ],
2144
2145       combobox => [
2146         action => [
2147           t8('more')
2148         ],
2149         action => [
2150           t8('History'),
2151           call     => [ 'set_history_window', $self->order->id, 'id' ],
2152           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2153         ],
2154         action => [
2155           t8('Follow-Up'),
2156           call     => [ 'kivi.Order.follow_up_window' ],
2157           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2158           only_if  => $::auth->assert('productivity', 1),
2159         ],
2160       ], # end of combobox "more"
2161     );
2162   }
2163 }
2164
2165 sub generate_doc {
2166   my ($self, $doc_ref, $params) = @_;
2167
2168   my $order  = $self->order;
2169   my @errors = ();
2170
2171   my $print_form = Form->new('');
2172   $print_form->{type}        = $order->type;
2173   $print_form->{formname}    = $params->{formname} || $order->type;
2174   $print_form->{format}      = $params->{format}   || 'pdf';
2175   $print_form->{media}       = $params->{media}    || 'file';
2176   $print_form->{groupitems}  = $params->{groupitems};
2177   $print_form->{printer_id}  = $params->{printer_id};
2178   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2179
2180   $order->language($params->{language});
2181   $order->flatten_to_form($print_form, format_amounts => 1);
2182
2183   my $template_ext;
2184   my $template_type;
2185   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2186     $template_ext  = 'odt';
2187     $template_type = 'OpenDocument';
2188   } elsif ($print_form->{format} =~ m{html}i) {
2189     $template_ext  = 'html';
2190     $template_type = 'HTML';
2191   }
2192
2193   # search for the template
2194   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2195     name        => $print_form->{formname},
2196     extension   => $template_ext,
2197     email       => $print_form->{media} eq 'email',
2198     language    => $params->{language},
2199     printer_id  => $print_form->{printer_id},
2200   );
2201
2202   if (!defined $template_file) {
2203     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2204   }
2205
2206   return @errors if scalar @errors;
2207
2208   $print_form->throw_on_error(sub {
2209     eval {
2210       $print_form->prepare_for_printing;
2211
2212       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2213         format        => $print_form->{format},
2214         template_type => $template_type,
2215         template      => $template_file,
2216         variables     => $print_form,
2217         variable_content_types => {
2218           longdescription => 'html',
2219           partnotes       => 'html',
2220           notes           => 'html',
2221           $::form->get_variable_content_types_for_cvars,
2222         },
2223       );
2224       1;
2225     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2226   });
2227
2228   return @errors;
2229 }
2230
2231 sub get_files_for_email_dialog {
2232   my ($self) = @_;
2233
2234   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2235
2236   return %files if !$::instance_conf->get_doc_storage;
2237
2238   if ($self->order->id) {
2239     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2240     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2241     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2242     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2243   }
2244
2245   my @parts =
2246     uniq_by { $_->{id} }
2247     map {
2248       +{ id         => $_->part->id,
2249          partnumber => $_->part->partnumber }
2250     } @{$self->order->items_sorted};
2251
2252   foreach my $part (@parts) {
2253     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2254     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2255   }
2256
2257   foreach my $key (keys %files) {
2258     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2259   }
2260
2261   return %files;
2262 }
2263
2264 sub make_periodic_invoices_config_from_yaml {
2265   my ($yaml_config) = @_;
2266
2267   return if !$yaml_config;
2268   my $attr = SL::YAML::Load($yaml_config);
2269   return if 'HASH' ne ref $attr;
2270   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2271 }
2272
2273
2274 sub get_periodic_invoices_status {
2275   my ($self, $config) = @_;
2276
2277   return                      if $self->type ne sales_order_type();
2278   return t8('not configured') if !$config;
2279
2280   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2281              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2282              :                                                     die "Cannot get status of periodic invoices config";
2283
2284   return $active ? t8('active') : t8('inactive');
2285 }
2286
2287 sub get_title_for {
2288   my ($self, $action) = @_;
2289
2290   return '' if none { lc($action)} qw(add edit);
2291
2292   # for locales:
2293   # $::locale->text("Add Sales Order");
2294   # $::locale->text("Add Purchase Order");
2295   # $::locale->text("Add Quotation");
2296   # $::locale->text("Add Request for Quotation");
2297   # $::locale->text("Edit Sales Order");
2298   # $::locale->text("Edit Purchase Order");
2299   # $::locale->text("Edit Quotation");
2300   # $::locale->text("Edit Request for Quotation");
2301
2302   $action = ucfirst(lc($action));
2303   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2304        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2305        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2306        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2307        : '';
2308 }
2309
2310 sub get_item_cvpartnumber {
2311   my ($self, $item) = @_;
2312
2313   return if !$self->search_cvpartnumber;
2314   return if !$self->order->customervendor;
2315
2316   if ($self->cv eq 'vendor') {
2317     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2318     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2319   } elsif ($self->cv eq 'customer') {
2320     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2321     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2322   }
2323 }
2324
2325 sub get_part_texts {
2326   my ($part_or_id, $language_or_id, %defaults) = @_;
2327
2328   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2329   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2330   my $texts       = {
2331     description     => $defaults{description}     // $part->description,
2332     longdescription => $defaults{longdescription} // $part->notes,
2333   };
2334
2335   return $texts unless $language_id;
2336
2337   my $translation = SL::DB::Manager::Translation->get_first(
2338     where => [
2339       parts_id    => $part->id,
2340       language_id => $language_id,
2341     ]);
2342
2343   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2344   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2345
2346   return $texts;
2347 }
2348
2349 sub sales_order_type {
2350   'sales_order';
2351 }
2352
2353 sub purchase_order_type {
2354   'purchase_order';
2355 }
2356
2357 sub sales_quotation_type {
2358   'sales_quotation';
2359 }
2360
2361 sub request_quotation_type {
2362   'request_quotation';
2363 }
2364
2365 sub nr_key {
2366   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2367        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2368        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2369        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2370        : '';
2371 }
2372
2373 sub save_and_redirect_to {
2374   my ($self, %params) = @_;
2375
2376   my $errors = $self->save();
2377
2378   if (scalar @{ $errors }) {
2379     $self->js->flash('error', $_) foreach @{ $errors };
2380     return $self->js->render();
2381   }
2382
2383   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2384            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2385            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2386            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2387            : '';
2388   flash_later('info', $text);
2389
2390   $self->redirect_to(%params, id => $self->order->id);
2391 }
2392
2393 sub save_history {
2394   my ($self, $addition) = @_;
2395
2396   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2397   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2398
2399   SL::DB::History->new(
2400     trans_id    => $self->order->id,
2401     employee_id => SL::DB::Manager::Employee->current->id,
2402     what_done   => $self->order->type,
2403     snumbers    => $snumbers,
2404     addition    => $addition,
2405   )->save;
2406 }
2407
2408 sub store_doc_to_webdav_and_filemanagement {
2409   my ($self, $content, $filename, $variant) = @_;
2410
2411   my $order = $self->order;
2412   my @errors;
2413
2414   # copy file to webdav folder
2415   if ($order->number && $::instance_conf->get_webdav_documents) {
2416     my $webdav = SL::Webdav->new(
2417       type     => $order->type,
2418       number   => $order->number,
2419     );
2420     my $webdav_file = SL::Webdav::File->new(
2421       webdav   => $webdav,
2422       filename => $filename,
2423     );
2424     eval {
2425       $webdav_file->store(data => \$content);
2426       1;
2427     } or do {
2428       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2429     };
2430   }
2431   if ($order->id && $::instance_conf->get_doc_storage) {
2432     eval {
2433       SL::File->save(object_id     => $order->id,
2434                      object_type   => $order->type,
2435                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2436                      source        => 'created',
2437                      file_type     => 'document',
2438                      file_name     => $filename,
2439                      file_contents => $content,
2440                      print_variant => $variant);
2441       1;
2442     } or do {
2443       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2444     };
2445   }
2446
2447   return @errors;
2448 }
2449
2450 sub link_requirement_specs_linking_to_created_from_objects {
2451   my ($self, @converted_from_oe_ids) = @_;
2452
2453   return unless @converted_from_oe_ids;
2454
2455   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2456   foreach my $rs_order (@{ $rs_orders }) {
2457     SL::DB::RequirementSpecOrder->new(
2458       order_id            => $self->order->id,
2459       requirement_spec_id => $rs_order->requirement_spec_id,
2460       version_id          => $rs_order->version_id,
2461     )->save;
2462   }
2463 }
2464
2465 sub set_project_in_linked_requirement_specs {
2466   my ($self) = @_;
2467
2468   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2469   foreach my $rs_order (@{ $rs_orders }) {
2470     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2471
2472     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2473   }
2474 }
2475
2476 1;
2477
2478 __END__
2479
2480 =encoding utf-8
2481
2482 =head1 NAME
2483
2484 SL::Controller::Order - controller for orders
2485
2486 =head1 SYNOPSIS
2487
2488 This is a new form to enter orders, completely rewritten with the use
2489 of controller and java script techniques.
2490
2491 The aim is to provide the user a better experience and a faster workflow. Also
2492 the code should be more readable, more reliable and better to maintain.
2493
2494 =head2 Key Features
2495
2496 =over 4
2497
2498 =item *
2499
2500 One input row, so that input happens every time at the same place.
2501
2502 =item *
2503
2504 Use of pickers where possible.
2505
2506 =item *
2507
2508 Possibility to enter more than one item at once.
2509
2510 =item *
2511
2512 Item list in a scrollable area, so that the workflow buttons stay at
2513 the bottom.
2514
2515 =item *
2516
2517 Reordering item rows with drag and drop is possible. Sorting item rows is
2518 possible (by partnumber, description, qty, sellprice and discount for now).
2519
2520 =item *
2521
2522 No C<update> is necessary. All entries and calculations are managed
2523 with ajax-calls and the page only reloads on C<save>.
2524
2525 =item *
2526
2527 User can see changes immediately, because of the use of java script
2528 and ajax.
2529
2530 =back
2531
2532 =head1 CODE
2533
2534 =head2 Layout
2535
2536 =over 4
2537
2538 =item * C<SL/Controller/Order.pm>
2539
2540 the controller
2541
2542 =item * C<template/webpages/order/form.html>
2543
2544 main form
2545
2546 =item * C<template/webpages/order/tabs/basic_data.html>
2547
2548 Main tab for basic_data.
2549
2550 This is the only tab here for now. "linked records" and "webdav" tabs are
2551 reused from generic code.
2552
2553 =over 4
2554
2555 =item * C<template/webpages/order/tabs/_business_info_row.html>
2556
2557 For displaying information on business type
2558
2559 =item * C<template/webpages/order/tabs/_item_input.html>
2560
2561 The input line for items
2562
2563 =item * C<template/webpages/order/tabs/_row.html>
2564
2565 One row for already entered items
2566
2567 =item * C<template/webpages/order/tabs/_tax_row.html>
2568
2569 Displaying tax information
2570
2571 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2572
2573 Dialog for selecting price and discount sources
2574
2575 =back
2576
2577 =item * C<js/kivi.Order.js>
2578
2579 java script functions
2580
2581 =back
2582
2583 =head1 TODO
2584
2585 =over 4
2586
2587 =item * testing
2588
2589 =item * price sources: little symbols showing better price / better discount
2590
2591 =item * select units in input row?
2592
2593 =item * check for direct delivery (workflow sales order -> purchase order)
2594
2595 =item * access rights
2596
2597 =item * display weights
2598
2599 =item * mtime check
2600
2601 =item * optional client/user behaviour
2602
2603 (transactions has to be set - department has to be set -
2604  force project if enabled in client config)
2605
2606 =back
2607
2608 =head1 KNOWN BUGS AND CAVEATS
2609
2610 =over 4
2611
2612 =item *
2613
2614 Customer discount is not displayed as a valid discount in price source popup
2615 (this might be a bug in price sources)
2616
2617 (I cannot reproduce this (Bernd))
2618
2619 =item *
2620
2621 No indication that <shift>-up/down expands/collapses second row.
2622
2623 =item *
2624
2625 Inline creation of parts is not currently supported
2626
2627 =item *
2628
2629 Table header is not sticky in the scrolling area.
2630
2631 =item *
2632
2633 Sorting does not include C<position>, neither does reordering.
2634
2635 This behavior was implemented intentionally. But we can discuss, which behavior
2636 should be implemented.
2637
2638 =back
2639
2640 =head1 To discuss / Nice to have
2641
2642 =over 4
2643
2644 =item *
2645
2646 How to expand/collapse second row. Now it can be done clicking the icon or
2647 <shift>-up/down.
2648
2649 =item *
2650
2651 Possibility to select PriceSources in input row?
2652
2653 =item *
2654
2655 This controller uses a (changed) copy of the template for the PriceSource
2656 dialog. Maybe there could be used one code source.
2657
2658 =item *
2659
2660 Rounding-differences between this controller (PriceTaxCalculator) and the old
2661 form. This is not only a problem here, but also in all parts using the PTC.
2662 There exists a ticket and a patch. This patch should be testet.
2663
2664 =item *
2665
2666 An indicator, if the actual inputs are saved (like in an
2667 editor or on text processing application).
2668
2669 =item *
2670
2671 A warning when leaving the page without saveing unchanged inputs.
2672
2673
2674 =back
2675
2676 =head1 AUTHOR
2677
2678 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2679
2680 =cut