SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::ParseFilter;
   9 use SL::Controller::Helper::ReportGenerator;
  10
  11 __PACKAGE__->run_before(sub { $::auth->assert('sales_order_edit'); });
  12
  13 sub action_list {
  14   my ($self) = @_;
  15   my %list_params = (
  16     sort_by  => $::form->{sort_by} || 'reqdate',
  17     sort_dir => $::form->{sort_dir},
  18     filter   => $::form->{filter},
  19     page     => $::form->{page},
  20   );
  21
  22   my $db_args = $self->setup_for_list(%list_params);
  23   $self->{pages} = SL::DB::Manager::OrderItem->paginate(%list_params, args => $db_args);
  24   $self->{flat_filter} = { map { $_->{key} => $_->{value} } $::form->flatten_variables('filter') };
  25   $self->make_filter_summary;
  26
  27   my $top    = $::form->parse_html_template('delivery_plan/report_top', { FORM => $::form, SELF => $self });
  28   my $bottom = $::form->parse_html_template('delivery_plan/report_bottom', { SELF => $self });
  29
  30   $self->prepare_report(
  31     report_generator_options => {
  32       raw_top_info_text    => $top,
  33       raw_bottom_info_text => $bottom,
  34       controller_class     => 'DeliveryPlan',
  35     },
  36     report_generator_export_options => [
  37       'list', qw(filter sort_by sort_dir),
  38     ],
  39     db_args => $db_args,
  40   );
  41
  42   $self->{orderitems} = SL::DB::Manager::OrderItem->get_all(%$db_args);
  43
  44   $self->list_objects;
  45 }
  46
  47 # private functions
  48
  49 sub setup_for_list {
  50   my ($self, %params) = @_;
  51   $self->{filter} = {};
  52   my %args = (
  53     parse_filter(
  54       $self->_pre_parse_filter($::form->{filter}, $self->{filter}),
  55       with_objects => [ 'order', 'order.customer', 'part' ],
  56       launder_to => $self->{filter},
  57     ),
  58     sort_by => $self->set_sort_params(%params),
  59     page    => $params{page},
  60   );
  61
  62   $args{query} = [ @{ $args{query} || [] },
  63     (
  64       'order.customer_id' => { gt => 0 },
  65       'order.closed' => 0,
  66       or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
  67
  68       # filter by shipped_qty < qty, read from innermost to outermost
  69       'id' => [ \"
  70         -- 3. resolve the desired information about those
  71         SELECT oi.id FROM (
  72           -- 2. slice only part, orderitem and both quantities from it
  73           SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
  74             -- 1. join orderitems and deliverorder items via record_links.
  75             --    also add customer data to filter for sales_orders
  76             SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
  77             FROM orderitems oi, oe, record_links rl, delivery_order_items doi
  78             WHERE
  79               oe.id = oi.trans_id AND
  80               oe.customer_id IS NOT NULL AND
  81               (oe.quotation = 'f' OR oe.quotation IS NULL) AND
  82               NOT oe.closed AND
  83               rl.from_id = oe.id AND
  84               rl.from_id = oi.trans_id AND
  85               oe.id = oi.trans_id AND
  86               rl.from_table = 'oe' AND
  87               rl.to_table = 'delivery_orders' AND
  88               rl.to_id = doi.delivery_order_id AND
  89               oi.parts_id = doi.parts_id
  90           ) tuples GROUP BY parts_id, trans_id, qty
  91         ) partials
  92         LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
  93         WHERE oi.qty > doi_qty
  94
  95         UNION ALL
  96
  97         -- 4. since the join over record_links fails for sales_orders wihtout any delivery order
  98         --    retrieve those without record_links at all
  99         SELECT oi.id FROM orderitems oi, oe
 100         WHERE
 101           oe.id = oi.trans_id AND
 102           oe.customer_id IS NOT NULL AND
 103           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 104           NOT oe.closed AND
 105           oi.trans_id NOT IN (
 106             SELECT from_id
 107             FROM record_links rl
 108             WHERE
 109               rl.from_table ='oe' AND
 110               rl.to_table = 'delivery_orders'
 111           )
 112       " ],
 113     )
 114   ];
 115
 116   return \%args;
 117 }
 118
 119 sub set_sort_params {
 120   my ($self, %params) = @_;
 121   my $sort_str;
 122   ($self->{sort_by}, $self->{sort_dir}, $sort_str) =
 123     SL::DB::Manager::OrderItem->make_sort_string(%params);
 124   return $sort_str;
 125 }
 126
 127 sub prepare_report {
 128   my ($self, %params) = @_;
 129
 130   my $objects  = $params{objects} || [];
 131   my $report = SL::ReportGenerator->new(\%::myconfig, $::form);
 132   $self->{report} = $report;
 133
 134   my @columns  = qw(reqdate customer ordnumber partnumber description qty shipped_qty);
 135   my @visible  = qw(reqdate partnumber description qty shipped_qty ordnumber customer);
 136   my @sortable = qw(reqdate partnumber description                 ordnumber customer);
 137
 138   my %column_defs = (
 139     reqdate                 => { text => $::locale->text('Reqdate'),
 140                                   sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date }},
 141     description             => { text => $::locale->text('Description'),
 142                                   sub => sub { $_[0]->description },
 143                              obj_link => sub { $self->link_to($_[0]->part) }},
 144     partnumber              => { text => $::locale->text('Part Number'),
 145                                   sub => sub { $_[0]->part->partnumber },
 146                              obj_link => sub { $self->link_to($_[0]->part) }},
 147     qty                     => { text => $::locale->text('Qty'),
 148                                   sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit }},
 149     missing                 => { text => $::locale->text('Missing qty'),
 150                                   sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit }},
 151     shipped_qty             => { text => $::locale->text('shipped'),
 152                                   sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit }},
 153     ordnumber               => { text => $::locale->text('Order'),
 154                                   sub => sub { $_[0]->order->ordnumber },
 155                              obj_link => sub { $self->link_to($_[0]->order) }},
 156     customer                => { text => $::locale->text('Customer'),
 157                                   sub => sub { $_[0]->order->customer->name },
 158                              obj_link => sub { $self->link_to($_[0]->order->customer) }},
 159   );
 160
 161
 162   for my $col (@sortable) {
 163     $column_defs{$col}{link} = $self->url_for(
 164       action   => 'list',
 165       sort_by  => $col,
 166       sort_dir => ($self->{sort_by} eq $col ? 1 - $self->{sort_dir} : $self->{sort_dir}),
 167       page     => $self->{pages}{cur},
 168       %{ $self->{flat_filter} },
 169     );
 170   }
 171
 172   map { $column_defs{$_}->{visible} = 1 } @visible;
 173
 174   $report->set_columns(%column_defs);
 175   $report->set_column_order(@columns);
 176   $report->set_options(allow_pdf_export => 1, allow_csv_export => 1);
 177   $report->set_sort_indicator(%params);
 178   $report->set_export_options(@{ $params{report_generator_export_options} || [] });
 179   $report->set_options(
 180     %{ $params{report_generator_options} || {} },
 181     output_format        => 'HTML',
 182     top_info_text        => $::locale->text('Delivery Plan for currently outstanding sales orders'),
 183     title                => $::locale->text('Delivery Plan'),
 184   );
 185   $report->set_options_from_form;
 186
 187   SL::DB::Manager::OrderItem->disable_paginating(args => $params{db_args}) if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 188
 189   $self->{report_data} = {
 190     column_defs => \%column_defs,
 191     columns     => \@columns,
 192     visible     => \@visible,
 193     sortable    => \@sortable,
 194   };
 195 }
 196
 197 sub list_objects {
 198   my ($self) = @_;
 199   my $column_defs = $self->{report_data}{column_defs};
 200   for my $obj (@{ $self->{orderitems} || [] }) {
 201     $self->{report}->add_data({
 202       map {
 203         $_ => {
 204           data => $column_defs->{$_}{sub} ? $column_defs->{$_}{sub}->($obj)
 205                 : $obj->can($_)           ? $obj->$_
 206                 :                           $obj->{$_},
 207           link => $column_defs->{$_}{obj_link} ? $column_defs->{$_}{obj_link}->($obj) : '',
 208         },
 209       } @{ $self->{report_data}{columns} || {} }
 210     });
 211   }
 212
 213   return $self->{report}->generate_with_headers;
 214 }
 215
 216 sub make_filter_summary {
 217   my ($self) = @_;
 218
 219   my $filter = $::form->{filter} || {};
 220   my @filter_strings;
 221
 222   my @filters = (
 223     [ $filter->{order}{"ordnumber:substr::ilike"}, $::locale->text('Number') ],
 224     [ $filter->{part}{"partnumber:substr::ilike"}, $::locale->text('Part Number') ],
 225     [ $filter->{"description:substr::ilike"}, $::locale->text('Part Description') ],
 226     [ $filter->{"reqdate:date::ge"}, $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 227     [ $filter->{"reqdate:date::le"}, $::locale->text('Delivery Date') . " " . $::locale->text('To Date') ],
 228     [ $filter->{"qty:number"}, $::locale->text('Quantity') ],
 229     [ $filter->{order}{customer}{"name:substr::ilike"}, $::locale->text('Customer') ],
 230     [ $filter->{order}{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number') ],
 231   );
 232
 233   my @flags = (
 234     [ $filter->{part}{type}{part}, $::locale->text('Parts') ],
 235     [ $filter->{part}{type}{service}, $::locale->text('Services') ],
 236     [ $filter->{part}{type}{assembly}, $::locale->text('Assemblies') ],
 237   );
 238
 239   for (@flags) {
 240     push @filter_strings, "$_->[1]" if $_->[0];
 241   }
 242   for (@filters) {
 243     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 244   }
 245
 246   $self->{filter_summary} = join ', ', @filter_strings;
 247 }
 248
 249 sub link_to {
 250   my ($self, $object, %params) = @_;
 251
 252   return unless $object;
 253   my $action = $params{action} || 'edit';
 254
 255   if ($object->isa('SL::DB::Order')) {
 256     my $type   = $object->type;
 257     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 258     my $id     = $object->id;
 259
 260     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 261   }
 262   if ($object->isa('SL::DB::Part')) {
 263     my $id     = $object->id;
 264     return "ic.pl?action=$action&id=$id";
 265   }
 266   if ($object->isa('SL::DB::Customer')) {
 267     my $id     = $object->id;
 268     return "ct.pl?action=$action&id=$id&db=customer";
 269   }
 270 }
 271
 272 # unfortunately ParseFilter can't handle compount filters.
 273 # so we clone the original filter (still need that for serializing)
 274 # rip out the options we know an replace them with the compound options.
 275 # ParseFilter will take care of the prefixing then.
 276 sub _pre_parse_filter {
 277   my ($self, $orig_filter, $launder_to) = @_;
 278
 279   return undef unless $orig_filter;
 280
 281   my $filter = clone($orig_filter);
 282   if ($filter->{part} && $filter->{part}{type}) {
 283     $launder_to->{part}{type} = delete $filter->{part}{type};
 284     my @part_filters = grep $_, map {
 285       $launder_to->{part}{type}{$_} ? SL::DB::Manager::Part->type_filter($_) : ()
 286     } qw(part service assembly);
 287
 288     push @{ $filter->{and} }, or => [ @part_filters ] if @part_filters;
 289   }
 290
 291   for my $op (qw(le ge)) {
 292     if ($filter->{"reqdate:date::$op"}) {
 293       $launder_to->{"reqdate_date__$op"} = delete $filter->{"reqdate:date::$op"};
 294       my $parsed_date = DateTime->from_lxoffice($launder_to->{"reqdate_date__$op"});
 295       push @{ $filter->{and} }, or => [
 296         'reqdate' => { $op => $parsed_date },
 297         and => [
 298           'reqdate' => undef,
 299           'order.reqdate' => { $op => $parsed_date },
 300         ]
 301       ] if $parsed_date;
 302     }
 303   }
 304
 305   if (my $style = delete $filter->{searchstyle}) {
 306     $self->{searchstyle}       = $style;
 307     $launder_to->{searchstyle} = $style;
 308   }
 309
 310   return $filter;
 311 }
 312
 313 1;