SL/Presenter/CustomerVendor.pm

   1 package SL::Presenter::CustomerVendor;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6
   7 use Exporter qw(import);
   8 our @EXPORT = qw(customer_vendor customer vendor customer_vendor_picker);
   9
  10 use Carp;
  11
  12 sub customer_vendor {
  13   my ($self, $customer_vendor, %params) = @_;
  14   return _customer_vendor($self, $customer_vendor, ref($customer_vendor) eq 'SL::DB::Customer' ? 'customer' : 'vendor', %params);
  15 }
  16
  17 sub customer {
  18   my ($self, $customer, %params) = @_;
  19   return _customer_vendor($self, $customer, 'customer', %params);
  20 }
  21
  22 sub vendor {
  23   my ($self, $vendor, %params) = @_;
  24   return _customer_vendor($self, $vendor, 'vendor', %params);
  25 }
  26
  27 sub _customer_vendor {
  28   my ($self, $cv, $type, %params) = @_;
  29
  30   $params{display} ||= 'inline';
  31
  32   croak "Unknown display type '$params{display}'" unless $params{display} =~ m/^(?:inline|table-cell)$/;
  33
  34   my $callback = $params{callback} ? '&callback=' . $::form->escape($params{callback}) : '';
  35
  36   my $text = join '', (
  37     $params{no_link} ? '' : '<a href="controller.pl?action=CustomerVendor/edit&amp;db=' . $type . '&amp;id=' . $self->escape($cv->id) . '">',
  38     $self->escape($cv->name),
  39     $params{no_link} ? '' : '</a>',
  40   );
  41   return $self->escaped_text($text);
  42 }
  43
  44 sub customer_vendor_picker {
  45   my ($self, $name, $value, %params) = @_;
  46
  47   croak 'Unknown "type" parameter' unless $params{type} =~ m{^(?:customer|vendor)$};
  48   croak 'Unknown value class'      if     $value && ref($value) && (ref($value) !~ m{^SL::DB::(?:Customer|Vendor)$});
  49
  50   if ($value && !ref $value) {
  51     my $class = $params{type} eq 'customer' ? 'SL::DB::Manager::Customer' : 'SL::DB::Manager::Vendor';
  52     $value    = $class->find_by(id => $value);
  53   }
  54
  55   my $id = delete($params{id}) || $self->name_to_id($name);
  56
  57   my @classes = $params{class} ? ($params{class}) : ();
  58   push @classes, 'customer_vendor_autocomplete';
  59
  60   my $ret =
  61     $self->input_tag($name, (ref $value && $value->can('id') ? $value->id : ''), class => "@classes", type => 'hidden', id => $id,
  62       'data-customer-vendor-picker-data' => JSON::to_json(\%params),
  63     ) .
  64     $self->input_tag("", ref $value  ? $value->displayable_name : '', id => "${id}_name", %params);
  65
  66   $::request->layout->add_javascripts('kivi.CustomerVendor.js');
  67   $::request->presenter->need_reinit_widgets($id);
  68
  69   $self->html_tag('span', $ret, class => 'customer_vendor_picker');
  70 }
  71
  72 1;
  73
  74 __END__
  75
  76 =pod
  77
  78 =encoding utf8
  79
  80 =head1 NAME
  81
  82 SL::Presenter::CustomerVendor - Presenter module for customer and
  83 vendor Rose::DB objects
  84
  85 =head1 SYNOPSIS
  86
  87   # Customers:
  88   my $customer = SL::DB::Manager::Customer->get_first;
  89   my $html     = SL::Presenter->get->customer($customer, display => 'inline');
  90
  91   # Vendors:
  92   my $vendor = SL::DB::Manager::Vendor->get_first;
  93   my $html   = SL::Presenter->get->vendor($customer, display => 'inline');
  94
  95 =head1 FUNCTIONS
  96
  97 =over 4
  98
  99 =item C<customer $object, %params>
 100
 101 Returns a rendered version (actually an instance of
 102 L<SL::Presenter::EscapedText>) of the customer object C<$object>.
 103
 104 C<%params> can include:
 105
 106 =over 2
 107
 108 =item * display
 109
 110 Either C<inline> (the default) or C<table-cell>. At the moment both
 111 representations are identical and produce the customer's name linked
 112 to the corresponding 'edit' action.
 113
 114 =item * no_link
 115
 116 If falsish (the default) then the customer's name will be linked to
 117 the "edit customer" dialog from the master data menu.
 118
 119 =back
 120
 121 =item C<vendor $object, %params>
 122
 123 Returns a rendered version (actually an instance of
 124 L<SL::Presenter::EscapedText>) of the vendor object C<$object>.
 125
 126 C<%params> can include:
 127
 128 =over 2
 129
 130 =item * display
 131
 132 Either C<inline> (the default) or C<table-cell>. At the moment both
 133 representations are identical and produce the vendor's name linked
 134 to the corresponding 'edit' action.
 135
 136 =item * no_link
 137
 138 If falsish (the default) then the vendor's name will be linked to
 139 the "edit vendor" dialog from the master data menu.
 140
 141 =back
 142
 143 =item C<customer_vendor $object, %params>
 144
 145 Returns a rendered version (actually an instance of
 146 L<SL::Presenter::EscapedText>) of the customer or vendor object
 147 C<$object> by calling either L</customer> or L</vendor> depending on
 148 C<$object>'s type. See the respective functions for available
 149 parameters.
 150
 151 =back
 152
 153 =head1 BUGS
 154
 155 Nothing here yet.
 156
 157 =head1 AUTHOR
 158
 159 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 160
 161 =cut