SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24
  25 use SL::Helper::CreatePDF qw(:all);
  26 use SL::Helper::PrintOptions;
  27 use SL::Helper::ShippedQty;
  28 use SL::Helper::UserPreferences::PositionsScrollbar;
  29 use SL::Helper::UserPreferences::UpdatePositions;
  30
  31 use SL::Controller::Helper::GetModels;
  32
  33 use List::Util qw(first sum0);
  34 use List::UtilsBy qw(sort_by uniq_by);
  35 use List::MoreUtils qw(any none pairwise first_index);
  36 use English qw(-no_match_vars);
  37 use File::Spec;
  38 use Cwd;
  39 use Sort::Naturally;
  40
  41 use Rose::Object::MakeMethods::Generic
  42 (
  43  scalar => [ qw(item_ids_to_delete) ],
  44  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors search_cvpartnumber show_update_button) ],
  45 );
  46
  47
  48 # safety
  49 __PACKAGE__->run_before('check_auth');
  50
  51 __PACKAGE__->run_before('recalc',
  52                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  53                                      print send_email) ]);
  54
  55 __PACKAGE__->run_before('get_unalterable_data',
  56                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  57                                      print send_email) ]);
  58
  59 #
  60 # actions
  61 #
  62
  63 # add a new order
  64 sub action_add {
  65   my ($self) = @_;
  66
  67   $self->order->transdate(DateTime->now_local());
  68   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  69                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  70   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  71
  72
  73   $self->pre_render();
  74   $self->render(
  75     'order/form',
  76     title => $self->get_title_for('add'),
  77     %{$self->{template_args}}
  78   );
  79 }
  80
  81 # edit an existing order
  82 sub action_edit {
  83   my ($self) = @_;
  84
  85   if ($::form->{id}) {
  86     $self->load_order;
  87
  88   } else {
  89     # this is to edit an order from an unsaved order object
  90
  91     # set item ids to new fake id, to identify them as new items
  92     foreach my $item (@{$self->order->items_sorted}) {
  93       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  94     }
  95     # trigger rendering values for second row/longdescription as hidden,
  96     # because they are loaded only on demand. So we need to keep the values
  97     # from the source.
  98     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
  99     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 100   }
 101
 102   $self->recalc();
 103   $self->pre_render();
 104   $self->render(
 105     'order/form',
 106     title => $self->get_title_for('edit'),
 107     %{$self->{template_args}}
 108   );
 109 }
 110
 111 # edit a collective order (consisting of one or more existing orders)
 112 sub action_edit_collective {
 113   my ($self) = @_;
 114
 115   # collect order ids
 116   my @multi_ids = map {
 117     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 118   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 119
 120   # fall back to add if no ids are given
 121   if (scalar @multi_ids == 0) {
 122     $self->action_add();
 123     return;
 124   }
 125
 126   # fall back to save as new if only one id is given
 127   if (scalar @multi_ids == 1) {
 128     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 129     $self->action_save_as_new();
 130     return;
 131   }
 132
 133   # make new order from given orders
 134   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 135   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 136   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 137
 138   $self->action_edit();
 139 }
 140
 141 # delete the order
 142 sub action_delete {
 143   my ($self) = @_;
 144
 145   my $errors = $self->delete();
 146
 147   if (scalar @{ $errors }) {
 148     $self->js->flash('error', $_) foreach @{ $errors };
 149     return $self->js->render();
 150   }
 151
 152   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 153            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 154            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 155            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 156            : '';
 157   flash_later('info', $text);
 158
 159   my @redirect_params = (
 160     action => 'add',
 161     type   => $self->type,
 162   );
 163
 164   $self->redirect_to(@redirect_params);
 165 }
 166
 167 # save the order
 168 sub action_save {
 169   my ($self) = @_;
 170
 171   my $errors = $self->save();
 172
 173   if (scalar @{ $errors }) {
 174     $self->js->flash('error', $_) foreach @{ $errors };
 175     return $self->js->render();
 176   }
 177
 178   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 179            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 180            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 181            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 182            : '';
 183   flash_later('info', $text);
 184
 185   my @redirect_params = (
 186     action => 'edit',
 187     type   => $self->type,
 188     id     => $self->order->id,
 189   );
 190
 191   $self->redirect_to(@redirect_params);
 192 }
 193
 194 # save the order as new document an open it for edit
 195 sub action_save_as_new {
 196   my ($self) = @_;
 197
 198   my $order = $self->order;
 199
 200   if (!$order->id) {
 201     $self->js->flash('error', t8('This object has not been saved yet.'));
 202     return $self->js->render();
 203   }
 204
 205   # load order from db to check if values changed
 206   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 207
 208   my %new_attrs;
 209   # Lets assign a new number if the user hasn't changed the previous one.
 210   # If it has been changed manually then use it as-is.
 211   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 212                         ? ''
 213                         : trim($order->number);
 214
 215   # Clear transdate unless changed
 216   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 217                         ? DateTime->today_local
 218                         : $order->transdate;
 219
 220   # Set new reqdate unless changed
 221   if ($order->reqdate == $saved_order->reqdate) {
 222     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 223                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 224     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 225   } else {
 226     $new_attrs{reqdate} = $order->reqdate;
 227   }
 228
 229   # Update employee
 230   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 231
 232   # Create new record from current one
 233   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 234
 235   # no linked records on save as new
 236   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 237
 238   # save
 239   $self->action_save();
 240 }
 241
 242 # print the order
 243 #
 244 # This is called if "print" is pressed in the print dialog.
 245 # If PDF creation was requested and succeeded, the pdf is offered for download
 246 # via send_file (which uses ajax in this case).
 247 sub action_print {
 248   my ($self) = @_;
 249
 250   my $errors = $self->save();
 251
 252   if (scalar @{ $errors }) {
 253     $self->js->flash('error', $_) foreach @{ $errors };
 254     return $self->js->render();
 255   }
 256
 257   $self->js_reset_order_and_item_ids_after_save;
 258
 259   my $format      = $::form->{print_options}->{format};
 260   my $media       = $::form->{print_options}->{media};
 261   my $formname    = $::form->{print_options}->{formname};
 262   my $copies      = $::form->{print_options}->{copies};
 263   my $groupitems  = $::form->{print_options}->{groupitems};
 264
 265   # only pdf and opendocument by now
 266   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 267     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 268   }
 269
 270   # only screen or printer by now
 271   if (none { $media eq $_ } qw(screen printer)) {
 272     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 273   }
 274
 275   my $language;
 276   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 277
 278   # create a form for generate_attachment_filename
 279   my $form   = Form->new;
 280   $form->{$self->nr_key()}  = $self->order->number;
 281   $form->{type}             = $self->type;
 282   $form->{format}           = $format;
 283   $form->{formname}         = $formname;
 284   $form->{language}         = '_' . $language->template_code if $language;
 285   my $pdf_filename          = $form->generate_attachment_filename();
 286
 287   my $pdf;
 288   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 289                                                    formname   => $formname,
 290                                                    language   => $language,
 291                                                    groupitems => $groupitems });
 292   if (scalar @errors) {
 293     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 294   }
 295
 296   if ($media eq 'screen') {
 297     # screen/download
 298     $self->js->flash('info', t8('The PDF has been created'));
 299     $self->send_file(
 300       \$pdf,
 301       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 302       name         => $pdf_filename,
 303       js_no_render => 1,
 304     );
 305
 306   } elsif ($media eq 'printer') {
 307     # printer
 308     my $printer_id = $::form->{print_options}->{printer_id};
 309     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 310       copies  => $copies,
 311       content => $pdf,
 312     );
 313
 314     $self->js->flash('info', t8('The PDF has been printed'));
 315   }
 316
 317   # copy file to webdav folder
 318   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 319     my $webdav = SL::Webdav->new(
 320       type     => $self->type,
 321       number   => $self->order->number,
 322     );
 323     my $webdav_file = SL::Webdav::File->new(
 324       webdav   => $webdav,
 325       filename => $pdf_filename,
 326     );
 327     eval {
 328       $webdav_file->store(data => \$pdf);
 329       1;
 330     } or do {
 331       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 332     }
 333   }
 334   if ($self->order->number && $::instance_conf->get_doc_storage) {
 335     eval {
 336       SL::File->save(object_id     => $self->order->id,
 337                      object_type   => $self->type,
 338                      mime_type     => 'application/pdf',
 339                      source        => 'created',
 340                      file_type     => 'document',
 341                      file_name     => $pdf_filename,
 342                      file_contents => $pdf);
 343       1;
 344     } or do {
 345       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 346     }
 347   }
 348   $self->js->render;
 349 }
 350
 351 # open the email dialog
 352 sub action_show_email_dialog {
 353   my ($self) = @_;
 354
 355   my $cv_method = $self->cv;
 356
 357   if (!$self->order->$cv_method) {
 358     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 359                     ->render($self);
 360   }
 361
 362   my $email_form;
 363   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 364   $email_form->{to} ||= $self->order->$cv_method->email;
 365   $email_form->{cc}   = $self->order->$cv_method->cc;
 366   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 367   # Todo: get addresses from shipto, if any
 368
 369   my $form = Form->new;
 370   $form->{$self->nr_key()}  = $self->order->number;
 371   $form->{formname}         = $self->type;
 372   $form->{type}             = $self->type;
 373   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 374   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 375   $form->{format}           = 'pdf';
 376
 377   $email_form->{subject}             = $form->generate_email_subject();
 378   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 379   $email_form->{message}             = $form->generate_email_body();
 380   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 381
 382   my %files = $self->get_files_for_email_dialog();
 383   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 384                                   email_form  => $email_form,
 385                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 386                                   FILES       => \%files,
 387                                   is_customer => $self->cv eq 'customer',
 388   );
 389
 390   $self->js
 391       ->run('kivi.Order.show_email_dialog', $dialog_html)
 392       ->reinit_widgets
 393       ->render($self);
 394 }
 395
 396 # send email
 397 #
 398 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 399 sub action_send_email {
 400   my ($self) = @_;
 401
 402   my $errors = $self->save();
 403
 404   if (scalar @{ $errors }) {
 405     $self->js->run('kivi.Order.close_email_dialog');
 406     $self->js->flash('error', $_) foreach @{ $errors };
 407     return $self->js->render();
 408   }
 409
 410   $self->js_reset_order_and_item_ids_after_save;
 411
 412   my $email_form  = delete $::form->{email_form};
 413   my %field_names = (to => 'email');
 414
 415   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 416
 417   # for Form::cleanup which may be called in Form::send_email
 418   $::form->{cwd}    = getcwd();
 419   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 420
 421   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 422   $::form->{media}  = 'email';
 423
 424   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 425     my $language;
 426     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 427
 428     my $pdf;
 429     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 430                                                     format     => $::form->{print_options}->{format},
 431                                                     formname   => $::form->{print_options}->{formname},
 432                                                     language   => $language,
 433                                                     groupitems => $::form->{print_options}->{groupitems}});
 434     if (scalar @errors) {
 435       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 436     }
 437
 438     my $sfile = SL::SessionFile::Random->new(mode => "w");
 439     $sfile->fh->print($pdf);
 440     $sfile->fh->close;
 441
 442     $::form->{tmpfile} = $sfile->file_name;
 443     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 444   }
 445
 446   $::form->send_email(\%::myconfig, 'pdf');
 447
 448   # internal notes
 449   my $intnotes = $self->order->intnotes;
 450   $intnotes   .= "\n\n" if $self->order->intnotes;
 451   $intnotes   .= t8('[email]')                                                                                        . "\n";
 452   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 453   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 454   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 455   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 456   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 457   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 458
 459   $self->order->update_attributes(intnotes => $intnotes);
 460
 461   $self->js
 462       ->val('#order_intnotes', $intnotes)
 463       ->run('kivi.Order.close_email_dialog')
 464       ->flash('info', t8('The email has been sent.'))
 465       ->render($self);
 466 }
 467
 468 # open the periodic invoices config dialog
 469 #
 470 # If there are values in the form (i.e. dialog was opened before),
 471 # then use this values. Create new ones, else.
 472 sub action_show_periodic_invoices_config_dialog {
 473   my ($self) = @_;
 474
 475   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 476   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 477   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 478                                                    order_value_periodicity => 'p', # = same as periodicity
 479                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 480                                                    extend_automatically_by => 12,
 481                                                    active                  => 1,
 482                                                    email_subject           => GenericTranslations->get(
 483                                                                                 language_id      => $::form->{language_id},
 484                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 485                                                    email_body              => GenericTranslations->get(
 486                                                                                 language_id      => $::form->{language_id},
 487                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 488   );
 489   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 490   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 491
 492   $::form->get_lists(printers => "ALL_PRINTERS",
 493                      charts   => { key       => 'ALL_CHARTS',
 494                                    transdate => 'current_date' });
 495
 496   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 497
 498   if ($::form->{customer_id}) {
 499     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 500     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 501   }
 502
 503   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 504                 popup_dialog             => 1,
 505                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 506                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 507                 config                   => $config,
 508                 %$::form);
 509 }
 510
 511 # assign the values of the periodic invoices config dialog
 512 # as yaml in the hidden tag and set the status.
 513 sub action_assign_periodic_invoices_config {
 514   my ($self) = @_;
 515
 516   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 517
 518   my $config = { active                     => $::form->{active}       ? 1 : 0,
 519                  terminated                 => $::form->{terminated}   ? 1 : 0,
 520                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 521                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 522                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 523                  start_date_as_date         => $::form->{start_date_as_date},
 524                  end_date_as_date           => $::form->{end_date_as_date},
 525                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 526                  print                      => $::form->{print}      ? 1                         : 0,
 527                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 528                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 529                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 530                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 531                  send_email                 => $::form->{send_email} ? 1 : 0,
 532                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 533                  email_recipient_address    => $::form->{email_recipient_address},
 534                  email_sender               => $::form->{email_sender},
 535                  email_subject              => $::form->{email_subject},
 536                  email_body                 => $::form->{email_body},
 537                };
 538
 539   my $periodic_invoices_config = SL::YAML::Dump($config);
 540
 541   my $status = $self->get_periodic_invoices_status($config);
 542
 543   $self->js
 544     ->remove('#order_periodic_invoices_config')
 545     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 546     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 547     ->html('#periodic_invoices_status', $status)
 548     ->flash('info', t8('The periodic invoices config has been assigned.'))
 549     ->render($self);
 550 }
 551
 552 sub action_get_has_active_periodic_invoices {
 553   my ($self) = @_;
 554
 555   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 556   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 557
 558   my $has_active_periodic_invoices =
 559        $self->type eq sales_order_type()
 560     && $config
 561     && $config->active
 562     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 563     && $config->get_previous_billed_period_start_date;
 564
 565   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 566 }
 567
 568 # save the order and redirect to the frontend subroutine for a new
 569 # delivery order
 570 sub action_save_and_delivery_order {
 571   my ($self) = @_;
 572
 573   my $errors = $self->save();
 574
 575   if (scalar @{ $errors }) {
 576     $self->js->flash('error', $_) foreach @{ $errors };
 577     return $self->js->render();
 578   }
 579
 580   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 581            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 582            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 583            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 584            : '';
 585   flash_later('info', $text);
 586
 587   my @redirect_params = (
 588     controller => 'oe.pl',
 589     action     => 'oe_delivery_order_from_order',
 590     id         => $self->order->id,
 591   );
 592
 593   $self->redirect_to(@redirect_params);
 594 }
 595
 596 # save the order and redirect to the frontend subroutine for a new
 597 # invoice
 598 sub action_save_and_invoice {
 599   my ($self) = @_;
 600
 601   my $errors = $self->save();
 602
 603   if (scalar @{ $errors }) {
 604     $self->js->flash('error', $_) foreach @{ $errors };
 605     return $self->js->render();
 606   }
 607
 608   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 609            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 610            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 611            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 612            : '';
 613   flash_later('info', $text);
 614
 615   my @redirect_params = (
 616     controller => 'oe.pl',
 617     action     => 'oe_invoice_from_order',
 618     id         => $self->order->id,
 619   );
 620
 621   $self->redirect_to(@redirect_params);
 622 }
 623
 624 # workflow from sales quotation to sales order
 625 sub action_sales_order {
 626   $_[0]->workflow_sales_or_purchase_order();
 627 }
 628
 629 # workflow from rfq to purchase order
 630 sub action_purchase_order {
 631   $_[0]->workflow_sales_or_purchase_order();
 632 }
 633
 634 # workflow from purchase order to ap transaction
 635 sub action_save_and_ap_transaction {
 636   my ($self) = @_;
 637
 638   my $errors = $self->save();
 639
 640   if (scalar @{ $errors }) {
 641     $self->js->flash('error', $_) foreach @{ $errors };
 642     return $self->js->render();
 643   }
 644
 645   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 646            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 647            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 648            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 649            : '';
 650   flash_later('info', $text);
 651
 652   my @redirect_params = (
 653     controller => 'ap.pl',
 654     action     => 'add_from_purchase_order',
 655     id         => $self->order->id,
 656   );
 657
 658   $self->redirect_to(@redirect_params);
 659 }
 660
 661 # set form elements in respect to a changed customer or vendor
 662 #
 663 # This action is called on an change of the customer/vendor picker.
 664 sub action_customer_vendor_changed {
 665   my ($self) = @_;
 666
 667   setup_order_from_cv($self->order);
 668   $self->recalc();
 669
 670   my $cv_method = $self->cv;
 671
 672   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 673     $self->js->show('#cp_row');
 674   } else {
 675     $self->js->hide('#cp_row');
 676   }
 677
 678   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 679     $self->js->show('#shipto_row');
 680   } else {
 681     $self->js->hide('#shipto_row');
 682   }
 683
 684   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 685
 686   $self->js
 687     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 688     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 689     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 690     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 691     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 692     ->val(        '#order_currency_id',      $self->order->currency_id)
 693     ->val(        '#order_payment_id',       $self->order->payment_id)
 694     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 695     ->val(        '#order_intnotes',         $self->order->intnotes)
 696     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 697     ->focus(      '#order_' . $self->cv . '_id')
 698     ->run('kivi.Order.update_exchangerate');
 699
 700   $self->js_redisplay_amounts_and_taxes;
 701   $self->js_redisplay_cvpartnumbers;
 702   $self->js->render();
 703 }
 704
 705 # open the dialog for customer/vendor details
 706 sub action_show_customer_vendor_details_dialog {
 707   my ($self) = @_;
 708
 709   my $is_customer = 'customer' eq $::form->{vc};
 710   my $cv;
 711   if ($is_customer) {
 712     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 713   } else {
 714     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 715   }
 716
 717   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 718   $details{discount_as_percent} = $cv->discount_as_percent;
 719   $details{creditlimt}          = $cv->creditlimit_as_number;
 720   $details{business}            = $cv->business->description      if $cv->business;
 721   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 722   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 723   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 724   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 725
 726   foreach my $entry (@{ $cv->shipto }) {
 727     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 728   }
 729   foreach my $entry (@{ $cv->contacts }) {
 730     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 731   }
 732
 733   $_[0]->render('common/show_vc_details', { layout => 0 },
 734                 is_customer => $is_customer,
 735                 %details);
 736
 737 }
 738
 739 # called if a unit in an existing item row is changed
 740 sub action_unit_changed {
 741   my ($self) = @_;
 742
 743   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 744   my $item = $self->order->items_sorted->[$idx];
 745
 746   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 747   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 748
 749   $self->recalc();
 750
 751   $self->js
 752     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 753   $self->js_redisplay_line_values;
 754   $self->js_redisplay_amounts_and_taxes;
 755   $self->js->render();
 756 }
 757
 758 # add an item row for a new item entered in the input row
 759 sub action_add_item {
 760   my ($self) = @_;
 761
 762   my $form_attr = $::form->{add_item};
 763
 764   return unless $form_attr->{parts_id};
 765
 766   my $item = new_item($self->order, $form_attr);
 767
 768   $self->order->add_items($item);
 769
 770   $self->recalc();
 771
 772   $self->get_item_cvpartnumber($item);
 773
 774   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 775   my $row_as_html = $self->p->render('order/tabs/_row',
 776                                      ITEM => $item,
 777                                      ID   => $item_id,
 778                                      SELF => $self,
 779   );
 780
 781   if ($::form->{insert_before_item_id}) {
 782     $self->js
 783       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 784   } else {
 785     $self->js
 786       ->append('#row_table_id', $row_as_html);
 787   }
 788
 789   if ( $item->part->is_assortment ) {
 790     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 791     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 792       my $attr = { parts_id => $assortment_item->parts_id,
 793                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 794                    unit     => $assortment_item->unit,
 795                    description => $assortment_item->part->description,
 796                  };
 797       my $item = new_item($self->order, $attr);
 798
 799       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 800       $item->discount(1) unless $assortment_item->charge;
 801
 802       $self->order->add_items( $item );
 803       $self->recalc();
 804       $self->get_item_cvpartnumber($item);
 805       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 806       my $row_as_html = $self->p->render('order/tabs/_row',
 807                                          ITEM => $item,
 808                                          ID   => $item_id,
 809                                          SELF => $self,
 810       );
 811       if ($::form->{insert_before_item_id}) {
 812         $self->js
 813           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 814       } else {
 815         $self->js
 816           ->append('#row_table_id', $row_as_html);
 817       }
 818     };
 819   };
 820
 821   $self->js
 822     ->val('.add_item_input', '')
 823     ->run('kivi.Order.init_row_handlers')
 824     ->run('kivi.Order.renumber_positions')
 825     ->focus('#add_item_parts_id_name');
 826
 827   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 828
 829   $self->js_redisplay_amounts_and_taxes;
 830   $self->js->render();
 831 }
 832
 833 # open the dialog for entering multiple items at once
 834 sub action_show_multi_items_dialog {
 835   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 836                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 837 }
 838
 839 # update the filter results in the multi item dialog
 840 sub action_multi_items_update_result {
 841   my $max_count = 100;
 842
 843   $::form->{multi_items}->{filter}->{obsolete} = 0;
 844
 845   my $count = $_[0]->multi_items_models->count;
 846
 847   if ($count == 0) {
 848     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 849     $_[0]->render($text, { layout => 0 });
 850   } elsif ($count > $max_count) {
 851     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 852     $_[0]->render($text, { layout => 0 });
 853   } else {
 854     my $multi_items = $_[0]->multi_items_models->get;
 855     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 856                   multi_items => $multi_items);
 857   }
 858 }
 859
 860 # add item rows for multiple items at once
 861 sub action_add_multi_items {
 862   my ($self) = @_;
 863
 864   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 865   return $self->js->render() unless scalar @form_attr;
 866
 867   my @items;
 868   foreach my $attr (@form_attr) {
 869     my $item = new_item($self->order, $attr);
 870     push @items, $item;
 871     if ( $item->part->is_assortment ) {
 872       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 873         my $attr = { parts_id => $assortment_item->parts_id,
 874                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 875                      unit     => $assortment_item->unit,
 876                      description => $assortment_item->part->description,
 877                    };
 878         my $item = new_item($self->order, $attr);
 879
 880         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 881         $item->discount(1) unless $assortment_item->charge;
 882         push @items, $item;
 883       }
 884     }
 885   }
 886   $self->order->add_items(@items);
 887
 888   $self->recalc();
 889
 890   foreach my $item (@items) {
 891     $self->get_item_cvpartnumber($item);
 892     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 893     my $row_as_html = $self->p->render('order/tabs/_row',
 894                                        ITEM => $item,
 895                                        ID   => $item_id,
 896                                        SELF => $self,
 897     );
 898
 899     if ($::form->{insert_before_item_id}) {
 900       $self->js
 901         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 902     } else {
 903       $self->js
 904         ->append('#row_table_id', $row_as_html);
 905     }
 906   }
 907
 908   $self->js
 909     ->run('kivi.Order.close_multi_items_dialog')
 910     ->run('kivi.Order.init_row_handlers')
 911     ->run('kivi.Order.renumber_positions')
 912     ->focus('#add_item_parts_id_name');
 913
 914   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 915
 916   $self->js_redisplay_amounts_and_taxes;
 917   $self->js->render();
 918 }
 919
 920 # recalculate all linetotals, amounts and taxes and redisplay them
 921 sub action_recalc_amounts_and_taxes {
 922   my ($self) = @_;
 923
 924   $self->recalc();
 925
 926   $self->js_redisplay_line_values;
 927   $self->js_redisplay_amounts_and_taxes;
 928   $self->js->render();
 929 }
 930
 931 sub action_update_exchangerate {
 932   my ($self) = @_;
 933
 934   my $data = {
 935     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 936     currency_name => $self->order->currency->name,
 937     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 938   };
 939
 940   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 941 }
 942
 943 # redisplay item rows if they are sorted by an attribute
 944 sub action_reorder_items {
 945   my ($self) = @_;
 946
 947   my %sort_keys = (
 948     partnumber   => sub { $_[0]->part->partnumber },
 949     description  => sub { $_[0]->description },
 950     qty          => sub { $_[0]->qty },
 951     sellprice    => sub { $_[0]->sellprice },
 952     discount     => sub { $_[0]->discount },
 953     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 954   );
 955
 956   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 957
 958   my $method = $sort_keys{$::form->{order_by}};
 959   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 960   if ($::form->{sort_dir}) {
 961     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 962       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 963     } else {
 964       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 965     }
 966   } else {
 967     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 968       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 969     } else {
 970       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 971     }
 972   }
 973   $self->js
 974     ->run('kivi.Order.redisplay_items', \@to_sort)
 975     ->render;
 976 }
 977
 978 # show the popup to choose a price/discount source
 979 sub action_price_popup {
 980   my ($self) = @_;
 981
 982   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 983   my $item = $self->order->items_sorted->[$idx];
 984
 985   $self->render_price_dialog($item);
 986 }
 987
 988 # get the longdescription for an item if the dialog to enter/change the
 989 # longdescription was opened and the longdescription is empty
 990 #
 991 # If this item is new, get the longdescription from Part.
 992 # Otherwise get it from OrderItem.
 993 sub action_get_item_longdescription {
 994   my $longdescription;
 995
 996   if ($::form->{item_id}) {
 997     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 998   } elsif ($::form->{parts_id}) {
 999     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
1000   }
1001   $_[0]->render(\ $longdescription, { type => 'text' });
1002 }
1003
1004 # load the second row for one or more items
1005 #
1006 # This action gets the html code for all items second rows by rendering a template for
1007 # the second row and sets the html code via client js.
1008 sub action_load_second_rows {
1009   my ($self) = @_;
1010
1011   $self->recalc() if $self->order->is_sales; # for margin calculation
1012
1013   foreach my $item_id (@{ $::form->{item_ids} }) {
1014     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1015     my $item = $self->order->items_sorted->[$idx];
1016
1017     $self->js_load_second_row($item, $item_id, 0);
1018   }
1019
1020   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1021
1022   $self->js->render();
1023 }
1024
1025 # update description, notes and sellprice from master data
1026 sub action_update_row_from_master_data {
1027   my ($self) = @_;
1028
1029   foreach my $item_id (@{ $::form->{item_ids} }) {
1030     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1031     my $item = $self->order->items_sorted->[$idx];
1032
1033     $item->description($item->part->description);
1034     $item->longdescription($item->part->notes);
1035
1036     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1037
1038     my $price_src;
1039     if ($item->part->is_assortment) {
1040     # add assortment items with price 0, as the components carry the price
1041       $price_src = $price_source->price_from_source("");
1042       $price_src->price(0);
1043     } else {
1044       $price_src = $price_source->best_price
1045                  ? $price_source->best_price
1046                  : $price_source->price_from_source("");
1047       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1048       $price_src->price(0) if !$price_source->best_price;
1049     }
1050
1051
1052     $item->sellprice($price_src->price);
1053     $item->active_price_source($price_src);
1054
1055     $self->js
1056       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1057       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1058       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1059       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1060
1061     if ($self->search_cvpartnumber) {
1062       $self->get_item_cvpartnumber($item);
1063       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1064     }
1065   }
1066
1067   $self->recalc();
1068   $self->js_redisplay_line_values;
1069   $self->js_redisplay_amounts_and_taxes;
1070
1071   $self->js->render();
1072 }
1073
1074 sub js_load_second_row {
1075   my ($self, $item, $item_id, $do_parse) = @_;
1076
1077   if ($do_parse) {
1078     # Parse values from form (they are formated while rendering (template)).
1079     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1080     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1081     foreach my $var (@{ $item->cvars_by_config }) {
1082       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1083     }
1084     $item->parse_custom_variable_values;
1085   }
1086
1087   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1088
1089   $self->js
1090     ->html('#second_row_' . $item_id, $row_as_html)
1091     ->data('#second_row_' . $item_id, 'loaded', 1);
1092 }
1093
1094 sub js_redisplay_line_values {
1095   my ($self) = @_;
1096
1097   my $is_sales = $self->order->is_sales;
1098
1099   # sales orders with margins
1100   my @data;
1101   if ($is_sales) {
1102     @data = map {
1103       [
1104        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1105        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1106        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1107       ]} @{ $self->order->items_sorted };
1108   } else {
1109     @data = map {
1110       [
1111        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1112       ]} @{ $self->order->items_sorted };
1113   }
1114
1115   $self->js
1116     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1117 }
1118
1119 sub js_redisplay_amounts_and_taxes {
1120   my ($self) = @_;
1121
1122   if (scalar @{ $self->{taxes} }) {
1123     $self->js->show('#taxincluded_row_id');
1124   } else {
1125     $self->js->hide('#taxincluded_row_id');
1126   }
1127
1128   if ($self->order->taxincluded) {
1129     $self->js->hide('#subtotal_row_id');
1130   } else {
1131     $self->js->show('#subtotal_row_id');
1132   }
1133
1134   if ($self->order->is_sales) {
1135     my $is_neg = $self->order->marge_total < 0;
1136     $self->js
1137       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1138       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1139       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1140       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1141       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1142       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1143       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1144       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1145   }
1146
1147   $self->js
1148     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1149     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1150     ->remove('.tax_row')
1151     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1152 }
1153
1154 sub js_redisplay_cvpartnumbers {
1155   my ($self) = @_;
1156
1157   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1158
1159   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1160
1161   $self->js
1162     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1163 }
1164
1165 sub js_reset_order_and_item_ids_after_save {
1166   my ($self) = @_;
1167
1168   $self->js
1169     ->val('#id', $self->order->id)
1170     ->val('#converted_from_oe_id', '')
1171     ->val('#order_' . $self->nr_key(), $self->order->number);
1172
1173   my $idx = 0;
1174   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1175     next if !$self->order->items_sorted->[$idx]->id;
1176     next if $form_item_id !~ m{^new};
1177     $self->js
1178       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1179       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1180       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1181   } continue {
1182     $idx++;
1183   }
1184   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1185 }
1186
1187 #
1188 # helpers
1189 #
1190
1191 sub init_valid_types {
1192   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1193 }
1194
1195 sub init_type {
1196   my ($self) = @_;
1197
1198   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1199     die "Not a valid type for order";
1200   }
1201
1202   $self->type($::form->{type});
1203 }
1204
1205 sub init_cv {
1206   my ($self) = @_;
1207
1208   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1209          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1210          : die "Not a valid type for order";
1211
1212   return $cv;
1213 }
1214
1215 sub init_search_cvpartnumber {
1216   my ($self) = @_;
1217
1218   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1219   my $search_cvpartnumber;
1220   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1221   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1222
1223   return $search_cvpartnumber;
1224 }
1225
1226 sub init_show_update_button {
1227   my ($self) = @_;
1228
1229   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1230 }
1231
1232 sub init_p {
1233   SL::Presenter->get;
1234 }
1235
1236 sub init_order {
1237   $_[0]->make_order;
1238 }
1239
1240 # model used to filter/display the parts in the multi-items dialog
1241 sub init_multi_items_models {
1242   SL::Controller::Helper::GetModels->new(
1243     controller     => $_[0],
1244     model          => 'Part',
1245     with_objects   => [ qw(unit_obj) ],
1246     disable_plugin => 'paginated',
1247     source         => $::form->{multi_items},
1248     sorted         => {
1249       _default    => {
1250         by  => 'partnumber',
1251         dir => 1,
1252       },
1253       partnumber  => t8('Partnumber'),
1254       description => t8('Description')}
1255   );
1256 }
1257
1258 sub init_all_price_factors {
1259   SL::DB::Manager::PriceFactor->get_all;
1260 }
1261
1262 sub check_auth {
1263   my ($self) = @_;
1264
1265   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1266
1267   my $right   = $right_for->{ $self->type };
1268   $right    ||= 'DOES_NOT_EXIST';
1269
1270   $::auth->assert($right);
1271 }
1272
1273 # build the selection box for contacts
1274 #
1275 # Needed, if customer/vendor changed.
1276 sub build_contact_select {
1277   my ($self) = @_;
1278
1279   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1280     value_key  => 'cp_id',
1281     title_key  => 'full_name_dep',
1282     default    => $self->order->cp_id,
1283     with_empty => 1,
1284     style      => 'width: 300px',
1285   );
1286 }
1287
1288 # build the selection box for shiptos
1289 #
1290 # Needed, if customer/vendor changed.
1291 sub build_shipto_select {
1292   my ($self) = @_;
1293
1294   select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
1295     value_key  => 'shipto_id',
1296     title_key  => 'displayable_id',
1297     default    => $self->order->shipto_id,
1298     with_empty => 1,
1299     style      => 'width: 300px',
1300   );
1301 }
1302
1303 # render the info line for business
1304 #
1305 # Needed, if customer/vendor changed.
1306 sub build_business_info_row
1307 {
1308   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1309 }
1310
1311 # build the rows for displaying taxes
1312 #
1313 # Called if amounts where recalculated and redisplayed.
1314 sub build_tax_rows {
1315   my ($self) = @_;
1316
1317   my $rows_as_html;
1318   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1319     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1320   }
1321   return $rows_as_html;
1322 }
1323
1324
1325 sub render_price_dialog {
1326   my ($self, $record_item) = @_;
1327
1328   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1329
1330   $self->js
1331     ->run(
1332       'kivi.io.price_chooser_dialog',
1333       t8('Available Prices'),
1334       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1335     )
1336     ->reinit_widgets;
1337
1338 #   if (@errors) {
1339 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1340 #     $self->js->show('#dialog_flash_error');
1341 #   }
1342
1343   $self->js->render;
1344 }
1345
1346 sub load_order {
1347   my ($self) = @_;
1348
1349   return if !$::form->{id};
1350
1351   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1352 }
1353
1354 # load or create a new order object
1355 #
1356 # And assign changes from the form to this object.
1357 # If the order is loaded from db, check if items are deleted in the form,
1358 # remove them form the object and collect them for removing from db on saving.
1359 # Then create/update items from form (via make_item) and add them.
1360 sub make_order {
1361   my ($self) = @_;
1362
1363   # add_items adds items to an order with no items for saving, but they cannot
1364   # be retrieved via items until the order is saved. Adding empty items to new
1365   # order here solves this problem.
1366   my $order;
1367   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1368   $order ||= SL::DB::Order->new(orderitems  => [],
1369                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1370                                 currency_id => $::instance_conf->get_currency_id());
1371
1372   my $cv_id_method = $self->cv . '_id';
1373   if (!$::form->{id} && $::form->{$cv_id_method}) {
1374     $order->$cv_id_method($::form->{$cv_id_method});
1375     setup_order_from_cv($order);
1376   }
1377
1378   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1379   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1380
1381   $order->assign_attributes(%{$::form->{order}});
1382
1383   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1384     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1385     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1386   }
1387
1388   # remove deleted items
1389   $self->item_ids_to_delete([]);
1390   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1391     my $item = $order->orderitems->[$idx];
1392     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1393       splice @{$order->orderitems}, $idx, 1;
1394       push @{$self->item_ids_to_delete}, $item->id;
1395     }
1396   }
1397
1398   my @items;
1399   my $pos = 1;
1400   foreach my $form_attr (@{$form_orderitems}) {
1401     my $item = make_item($order, $form_attr);
1402     $item->position($pos);
1403     push @items, $item;
1404     $pos++;
1405   }
1406   $order->add_items(grep {!$_->id} @items);
1407
1408   return $order;
1409 }
1410
1411 # create or update items from form
1412 #
1413 # Make item objects from form values. For items already existing read from db.
1414 # Create a new item else. And assign attributes.
1415 sub make_item {
1416   my ($record, $attr) = @_;
1417
1418   my $item;
1419   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1420
1421   my $is_new = !$item;
1422
1423   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1424   # they cannot be retrieved via custom_variables until the order/orderitem is
1425   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1426   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1427
1428   $item->assign_attributes(%$attr);
1429   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1430   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1431   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1432
1433   return $item;
1434 }
1435
1436 # create a new item
1437 #
1438 # This is used to add one item
1439 sub new_item {
1440   my ($record, $attr) = @_;
1441
1442   my $item = SL::DB::OrderItem->new;
1443
1444   # Remove attributes where the user left or set the inputs empty.
1445   # So these attributes will be undefined and we can distinguish them
1446   # from zero later on.
1447   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1448     delete $attr->{$_} if $attr->{$_} eq '';
1449   }
1450
1451   $item->assign_attributes(%$attr);
1452
1453   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1454   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1455
1456   $item->unit($part->unit) if !$item->unit;
1457
1458   my $price_src;
1459   if ( $part->is_assortment ) {
1460     # add assortment items with price 0, as the components carry the price
1461     $price_src = $price_source->price_from_source("");
1462     $price_src->price(0);
1463   } elsif (defined $item->sellprice) {
1464     $price_src = $price_source->price_from_source("");
1465     $price_src->price($item->sellprice);
1466   } else {
1467     $price_src = $price_source->best_price
1468                ? $price_source->best_price
1469                : $price_source->price_from_source("");
1470     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1471     $price_src->price(0) if !$price_source->best_price;
1472   }
1473
1474   my $discount_src;
1475   if (defined $item->discount) {
1476     $discount_src = $price_source->discount_from_source("");
1477     $discount_src->discount($item->discount);
1478   } else {
1479     $discount_src = $price_source->best_discount
1480                   ? $price_source->best_discount
1481                   : $price_source->discount_from_source("");
1482     $discount_src->discount(0) if !$price_source->best_discount;
1483   }
1484
1485   my %new_attr;
1486   $new_attr{part}                   = $part;
1487   $new_attr{description}            = $part->description     if ! $item->description;
1488   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1489   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1490   $new_attr{sellprice}              = $price_src->price;
1491   $new_attr{discount}               = $discount_src->discount;
1492   $new_attr{active_price_source}    = $price_src;
1493   $new_attr{active_discount_source} = $discount_src;
1494   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1495   $new_attr{project_id}             = $record->globalproject_id;
1496   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1497
1498   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1499   # they cannot be retrieved via custom_variables until the order/orderitem is
1500   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1501   $new_attr{custom_variables} = [];
1502
1503   $item->assign_attributes(%new_attr);
1504
1505   return $item;
1506 }
1507
1508 sub setup_order_from_cv {
1509   my ($order) = @_;
1510
1511   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1512
1513   $order->intnotes($order->customervendor->notes);
1514
1515   if ($order->is_sales) {
1516     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1517     $order->taxincluded(defined($order->customer->taxincluded_checked)
1518                         ? $order->customer->taxincluded_checked
1519                         : $::myconfig{taxincluded_checked});
1520   }
1521
1522 }
1523
1524 # recalculate prices and taxes
1525 #
1526 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1527 sub recalc {
1528   my ($self) = @_;
1529
1530   my %pat = $self->order->calculate_prices_and_taxes();
1531
1532   $self->{taxes} = [];
1533   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1534     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1535
1536     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1537                                 netamount => $netamount,
1538                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1539   }
1540   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1541 }
1542
1543 # get data for saving, printing, ..., that is not changed in the form
1544 #
1545 # Only cvars for now.
1546 sub get_unalterable_data {
1547   my ($self) = @_;
1548
1549   foreach my $item (@{ $self->order->items }) {
1550     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1551     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1552     foreach my $var (@{ $item->cvars_by_config }) {
1553       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1554     }
1555     $item->parse_custom_variable_values;
1556   }
1557 }
1558
1559 # delete the order
1560 #
1561 # And remove related files in the spool directory
1562 sub delete {
1563   my ($self) = @_;
1564
1565   my $errors = [];
1566   my $db     = $self->order->db;
1567
1568   $db->with_transaction(
1569     sub {
1570       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1571       $self->order->delete;
1572       my $spool = $::lx_office_conf{paths}->{spool};
1573       unlink map { "$spool/$_" } @spoolfiles if $spool;
1574
1575       1;
1576   }) || push(@{$errors}, $db->error);
1577
1578   return $errors;
1579 }
1580
1581 # save the order
1582 #
1583 # And delete items that are deleted in the form.
1584 sub save {
1585   my ($self) = @_;
1586
1587   my $errors = [];
1588   my $db     = $self->order->db;
1589
1590   $db->with_transaction(sub {
1591     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1592     $self->order->save(cascade => 1);
1593
1594     # link records
1595     if ($::form->{converted_from_oe_id}) {
1596       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1597       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1598         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1599         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1600         $src->link_to_record($self->order);
1601       }
1602       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1603         my $idx = 0;
1604         foreach (@{ $self->order->items_sorted }) {
1605           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1606           next if !$from_id;
1607           SL::DB::RecordLink->new(from_table => 'orderitems',
1608                                   from_id    => $from_id,
1609                                   to_table   => 'orderitems',
1610                                   to_id      => $_->id
1611           )->save;
1612           $idx++;
1613         }
1614       }
1615     }
1616     1;
1617   }) || push(@{$errors}, $db->error);
1618
1619   return $errors;
1620 }
1621
1622 sub workflow_sales_or_purchase_order {
1623   my ($self) = @_;
1624
1625   # always save
1626   my $errors = $self->save();
1627
1628   if (scalar @{ $errors }) {
1629     $self->js->flash('error', $_) foreach @{ $errors };
1630     return $self->js->render();
1631   }
1632
1633   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1634                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1635                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1636                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1637                        : '';
1638
1639   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1640   $self->{converted_from_oe_id} = delete $::form->{id};
1641
1642   # set item ids to new fake id, to identify them as new items
1643   foreach my $item (@{$self->order->items_sorted}) {
1644     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1645   }
1646
1647   # change form type
1648   $::form->{type} = $destination_type;
1649   $self->type($self->init_type);
1650   $self->cv  ($self->init_cv);
1651   $self->check_auth;
1652
1653   $self->recalc();
1654   $self->get_unalterable_data();
1655   $self->pre_render();
1656
1657   # trigger rendering values for second row/longdescription as hidden,
1658   # because they are loaded only on demand. So we need to keep the values
1659   # from the source.
1660   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1661   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1662
1663   $self->render(
1664     'order/form',
1665     title => $self->get_title_for('edit'),
1666     %{$self->{template_args}}
1667   );
1668 }
1669
1670
1671 sub pre_render {
1672   my ($self) = @_;
1673
1674   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1675   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1676   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1677   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1678                                                                                               deleted => 0 ] ],
1679                                                                            sort_by => 'name');
1680   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1681                                                                                               deleted => 0 ] ],
1682                                                                            sort_by => 'name');
1683   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1684                                                                                                         obsolete => 0 ] ]);
1685   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1686   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1687   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1688   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1689   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1690
1691   my $print_form = Form->new('');
1692   $print_form->{type}        = $self->type;
1693   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1694   $print_form->{languages}   = SL::DB::Manager::Language->get_all_sorted;
1695   $print_form->{language_id} = $self->order->language_id;
1696   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1697     form => $print_form,
1698     options => {dialog_name_prefix => 'print_options.',
1699                 show_headers       => 1,
1700                 no_queue           => 1,
1701                 no_postscript      => 1,
1702                 no_opendocument    => 0,
1703                 no_html            => 1},
1704   );
1705
1706   foreach my $item (@{$self->order->orderitems}) {
1707     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1708     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1709     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1710   }
1711
1712   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1713     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1714     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1715   }
1716
1717   if ($self->order->number && $::instance_conf->get_webdav) {
1718     my $webdav = SL::Webdav->new(
1719       type     => $self->type,
1720       number   => $self->order->number,
1721     );
1722     my @all_objects = $webdav->get_all_objects;
1723     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1724                                                     type => t8('File'),
1725                                                     link => File::Spec->catfile($_->full_filedescriptor),
1726                                                 } } @all_objects;
1727   }
1728
1729   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1730
1731   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1732                                                          edit_periodic_invoices_config calculate_qty);
1733   $self->setup_edit_action_bar;
1734 }
1735
1736 sub setup_edit_action_bar {
1737   my ($self, %params) = @_;
1738
1739   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1740                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1741                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1742
1743   for my $bar ($::request->layout->get('actionbar')) {
1744     $bar->add(
1745       combobox => [
1746         action => [
1747           t8('Save'),
1748           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1749                                                     $::instance_conf->get_order_warn_no_deliverydate,
1750                                                                                                       ],
1751           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1752         ],
1753         action => [
1754           t8('Save as new'),
1755           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1756           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1757           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1758         ],
1759       ], # end of combobox "Save"
1760
1761       combobox => [
1762         action => [
1763           t8('Workflow'),
1764         ],
1765         action => [
1766           t8('Save and Sales Order'),
1767           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1768           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1769           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1770         ],
1771         action => [
1772           t8('Save and Purchase Order'),
1773           submit   => [ '#order_form', { action => "Order/purchase_order" } ],
1774           only_if  => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1775           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1776         ],
1777         action => [
1778           t8('Save and Delivery Order'),
1779           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1780                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1781                                                                                                                         ],
1782           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1783           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1784         ],
1785         action => [
1786           t8('Save and Invoice'),
1787           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1788           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1789         ],
1790         action => [
1791           t8('Save and AP Transaction'),
1792           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1793           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1794         ],
1795
1796       ], # end of combobox "Workflow"
1797
1798       combobox => [
1799         action => [
1800           t8('Export'),
1801         ],
1802         action => [
1803           t8('Save and print'),
1804           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1805         ],
1806         action => [
1807           t8('Save and E-mail'),
1808           call => [ 'kivi.Order.email', $::instance_conf->get_order_warn_duplicate_parts ],
1809         ],
1810         action => [
1811           t8('Download attachments of all parts'),
1812           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1813           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1814           only_if  => $::instance_conf->get_doc_storage,
1815         ],
1816       ], # end of combobox "Export"
1817
1818       action => [
1819         t8('Delete'),
1820         call     => [ 'kivi.Order.delete_order' ],
1821         confirm  => $::locale->text('Do you really want to delete this object?'),
1822         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1823         only_if  => $deletion_allowed,
1824       ],
1825     );
1826   }
1827 }
1828
1829 sub generate_pdf {
1830   my ($order, $pdf_ref, $params) = @_;
1831
1832   my @errors = ();
1833
1834   my $print_form = Form->new('');
1835   $print_form->{type}        = $order->type;
1836   $print_form->{formname}    = $params->{formname} || $order->type;
1837   $print_form->{format}      = $params->{format}   || 'pdf';
1838   $print_form->{media}       = $params->{media}    || 'file';
1839   $print_form->{groupitems}  = $params->{groupitems};
1840   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1841
1842   $order->language($params->{language});
1843   $order->flatten_to_form($print_form, format_amounts => 1);
1844
1845   my $template_ext;
1846   my $template_type;
1847   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1848     $template_ext  = 'odt';
1849     $template_type = 'OpenDocument';
1850   }
1851
1852   # search for the template
1853   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1854     name        => $print_form->{formname},
1855     extension   => $template_ext,
1856     email       => $print_form->{media} eq 'email',
1857     language    => $params->{language},
1858     printer_id  => $print_form->{printer_id},  # todo
1859   );
1860
1861   if (!defined $template_file) {
1862     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1863   }
1864
1865   return @errors if scalar @errors;
1866
1867   $print_form->throw_on_error(sub {
1868     eval {
1869       $print_form->prepare_for_printing;
1870
1871       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1872         format        => $print_form->{format},
1873         template_type => $template_type,
1874         template      => $template_file,
1875         variables     => $print_form,
1876         variable_content_types => {
1877           longdescription => 'html',
1878           partnotes       => 'html',
1879           notes           => 'html',
1880         },
1881       );
1882       1;
1883     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1884   });
1885
1886   return @errors;
1887 }
1888
1889 sub get_files_for_email_dialog {
1890   my ($self) = @_;
1891
1892   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1893
1894   return %files if !$::instance_conf->get_doc_storage;
1895
1896   if ($self->order->id) {
1897     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1898     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1899     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1900   }
1901
1902   my @parts =
1903     uniq_by { $_->{id} }
1904     map {
1905       +{ id         => $_->part->id,
1906          partnumber => $_->part->partnumber }
1907     } @{$self->order->items_sorted};
1908
1909   foreach my $part (@parts) {
1910     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
1911     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
1912   }
1913
1914   foreach my $key (keys %files) {
1915     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
1916   }
1917
1918   return %files;
1919 }
1920
1921 sub make_periodic_invoices_config_from_yaml {
1922   my ($yaml_config) = @_;
1923
1924   return if !$yaml_config;
1925   my $attr = SL::YAML::Load($yaml_config);
1926   return if 'HASH' ne ref $attr;
1927   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
1928 }
1929
1930
1931 sub get_periodic_invoices_status {
1932   my ($self, $config) = @_;
1933
1934   return                      if $self->type ne sales_order_type();
1935   return t8('not configured') if !$config;
1936
1937   my $active = ('HASH' eq ref $config)                           ? $config->{active}
1938              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
1939              :                                                     die "Cannot get status of periodic invoices config";
1940
1941   return $active ? t8('active') : t8('inactive');
1942 }
1943
1944 sub get_title_for {
1945   my ($self, $action) = @_;
1946
1947   return '' if none { lc($action)} qw(add edit);
1948
1949   # for locales:
1950   # $::locale->text("Add Sales Order");
1951   # $::locale->text("Add Purchase Order");
1952   # $::locale->text("Add Quotation");
1953   # $::locale->text("Add Request for Quotation");
1954   # $::locale->text("Edit Sales Order");
1955   # $::locale->text("Edit Purchase Order");
1956   # $::locale->text("Edit Quotation");
1957   # $::locale->text("Edit Request for Quotation");
1958
1959   $action = ucfirst(lc($action));
1960   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
1961        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
1962        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
1963        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
1964        : '';
1965 }
1966
1967 sub get_item_cvpartnumber {
1968   my ($self, $item) = @_;
1969
1970   return if !$self->search_cvpartnumber;
1971   return if !$self->order->customervendor;
1972
1973   if ($self->cv eq 'vendor') {
1974     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
1975     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
1976   } elsif ($self->cv eq 'customer') {
1977     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
1978     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
1979   }
1980 }
1981
1982 sub sales_order_type {
1983   'sales_order';
1984 }
1985
1986 sub purchase_order_type {
1987   'purchase_order';
1988 }
1989
1990 sub sales_quotation_type {
1991   'sales_quotation';
1992 }
1993
1994 sub request_quotation_type {
1995   'request_quotation';
1996 }
1997
1998 sub nr_key {
1999   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2000        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2001        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2002        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2003        : '';
2004 }
2005
2006 1;
2007
2008 __END__
2009
2010 =encoding utf-8
2011
2012 =head1 NAME
2013
2014 SL::Controller::Order - controller for orders
2015
2016 =head1 SYNOPSIS
2017
2018 This is a new form to enter orders, completely rewritten with the use
2019 of controller and java script techniques.
2020
2021 The aim is to provide the user a better experience and a faster workflow. Also
2022 the code should be more readable, more reliable and better to maintain.
2023
2024 =head2 Key Features
2025
2026 =over 4
2027
2028 =item *
2029
2030 One input row, so that input happens every time at the same place.
2031
2032 =item *
2033
2034 Use of pickers where possible.
2035
2036 =item *
2037
2038 Possibility to enter more than one item at once.
2039
2040 =item *
2041
2042 Item list in a scrollable area, so that the workflow buttons stay at
2043 the bottom.
2044
2045 =item *
2046
2047 Reordering item rows with drag and drop is possible. Sorting item rows is
2048 possible (by partnumber, description, qty, sellprice and discount for now).
2049
2050 =item *
2051
2052 No C<update> is necessary. All entries and calculations are managed
2053 with ajax-calls and the page only reloads on C<save>.
2054
2055 =item *
2056
2057 User can see changes immediately, because of the use of java script
2058 and ajax.
2059
2060 =back
2061
2062 =head1 CODE
2063
2064 =head2 Layout
2065
2066 =over 4
2067
2068 =item * C<SL/Controller/Order.pm>
2069
2070 the controller
2071
2072 =item * C<template/webpages/order/form.html>
2073
2074 main form
2075
2076 =item * C<template/webpages/order/tabs/basic_data.html>
2077
2078 Main tab for basic_data.
2079
2080 This is the only tab here for now. "linked records" and "webdav" tabs are
2081 reused from generic code.
2082
2083 =over 4
2084
2085 =item * C<template/webpages/order/tabs/_business_info_row.html>
2086
2087 For displaying information on business type
2088
2089 =item * C<template/webpages/order/tabs/_item_input.html>
2090
2091 The input line for items
2092
2093 =item * C<template/webpages/order/tabs/_row.html>
2094
2095 One row for already entered items
2096
2097 =item * C<template/webpages/order/tabs/_tax_row.html>
2098
2099 Displaying tax information
2100
2101 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
2102
2103 Dialog for entering more than one item at once
2104
2105 =item * C<template/webpages/order/tabs/_multi_items_result.html>
2106
2107 Results for the filter in the multi items dialog
2108
2109 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2110
2111 Dialog for selecting price and discount sources
2112
2113 =back
2114
2115 =item * C<js/kivi.Order.js>
2116
2117 java script functions
2118
2119 =back
2120
2121 =head1 TODO
2122
2123 =over 4
2124
2125 =item * testing
2126
2127 =item * credit limit
2128
2129 =item * more workflows (quotation, rfq)
2130
2131 =item * price sources: little symbols showing better price / better discount
2132
2133 =item * select units in input row?
2134
2135 =item * custom shipto address
2136
2137 =item * check for direct delivery (workflow sales order -> purchase order)
2138
2139 =item * language / part translations
2140
2141 =item * access rights
2142
2143 =item * display weights
2144
2145 =item * history
2146
2147 =item * mtime check
2148
2149 =item * optional client/user behaviour
2150
2151 (transactions has to be set - department has to be set -
2152  force project if enabled in client config - transport cost reminder)
2153
2154 =back
2155
2156 =head1 KNOWN BUGS AND CAVEATS
2157
2158 =over 4
2159
2160 =item *
2161
2162 Customer discount is not displayed as a valid discount in price source popup
2163 (this might be a bug in price sources)
2164
2165 (I cannot reproduce this (Bernd))
2166
2167 =item *
2168
2169 No indication that <shift>-up/down expands/collapses second row.
2170
2171 =item *
2172
2173 Inline creation of parts is not currently supported
2174
2175 =item *
2176
2177 Table header is not sticky in the scrolling area.
2178
2179 =item *
2180
2181 Sorting does not include C<position>, neither does reordering.
2182
2183 This behavior was implemented intentionally. But we can discuss, which behavior
2184 should be implemented.
2185
2186 =item *
2187
2188 C<show_multi_items_dialog> does not use the currently inserted string for
2189 filtering.
2190
2191 =back
2192
2193 =head1 To discuss / Nice to have
2194
2195 =over 4
2196
2197 =item *
2198
2199 How to expand/collapse second row. Now it can be done clicking the icon or
2200 <shift>-up/down.
2201
2202 =item *
2203
2204 Possibility to change longdescription in input row?
2205
2206 =item *
2207
2208 Possibility to select PriceSources in input row?
2209
2210 =item *
2211
2212 This controller uses a (changed) copy of the template for the PriceSource
2213 dialog. Maybe there could be used one code source.
2214
2215 =item *
2216
2217 Rounding-differences between this controller (PriceTaxCalculator) and the old
2218 form. This is not only a problem here, but also in all parts using the PTC.
2219 There exists a ticket and a patch. This patch should be testet.
2220
2221 =item *
2222
2223 An indicator, if the actual inputs are saved (like in an
2224 editor or on text processing application).
2225
2226 =item *
2227
2228 A warning when leaving the page without saveing unchanged inputs.
2229
2230
2231 =back
2232
2233 =head1 AUTHOR
2234
2235 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2236
2237 =cut