SL/Controller/PriceRule.pm

   1 package SL::Controller::PriceRule;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::Controller::Helper::GetModels;
   8 use SL::Controller::Helper::ParseFilter;
   9 use SL::Controller::Helper::ReportGenerator;
  10 use SL::DB::PriceRule;
  11 use SL::DB::PriceRuleItem;
  12 use SL::DB::Pricegroup;
  13 use SL::DB::PartsGroup;
  14 use SL::DB::Business;
  15 use SL::Helper::Flash;
  16 use SL::Locale::String;
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20  'scalar --get_set_init' => [ qw(models price_rule vc pricegroups partsgroups businesses) ],
  21 );
  22
  23 # __PACKAGE__->run_before('check_auth');
  24 __PACKAGE__->run_before('add_javascripts');
  25
  26 #
  27 # actions
  28 #
  29
  30 sub action_list {
  31   my ($self) = @_;
  32
  33   $self->make_filter_summary;
  34
  35   my $price_rules = $self->models->get;
  36
  37   $self->prepare_report;
  38
  39   $self->report_generator_list_objects(report => $self->{report}, objects => $price_rules, $::form->{inline} ? (layout => 0, header => 0) : ());
  40 }
  41
  42 sub action_new {
  43   my ($self) = @_;
  44
  45   $self->price_rule(SL::DB::PriceRule->new);
  46   $self->price_rule->assign_attributes(%{ $::form->{price_rule} || {} });
  47   $self->display_form;
  48 }
  49
  50 sub action_edit {
  51   my ($self) = @_;
  52
  53   $self->display_form;
  54 }
  55
  56 sub action_create {
  57   my ($self) = @_;
  58
  59   $self->price_rule($self->price_rule->clone_and_reset_deep);
  60   $self->create_or_update;
  61 }
  62
  63 sub action_update {
  64   my ($self) = @_;
  65   $self->create_or_update;
  66 }
  67
  68  #TODO
  69 sub action_destroy {
  70   my ($self) = @_;
  71
  72   $self->price_rule->delete;
  73   flash_later('info',  $::locale->text('The price rule has been deleted.'));
  74
  75   $self->redirect_to($::form->{callback} || (action => 'list'));
  76 }
  77
  78 sub action_add_item_row {
  79   my ($self, %params) = @_;
  80
  81   my $item = SL::DB::PriceRuleItem->new(type => $::form->{type});
  82
  83   my $html = $self->render('price_rule/item', { output => 0 }, item => $item);
  84
  85   $self
  86     ->js
  87     ->before('#price_rule_new_items', $html)
  88     ->reinit_widgets
  89     ->render;
  90 }
  91
  92 sub action_price_type_help {
  93   $_[0]->render('price_rule/price_type_help', { layout => 0 });
  94 }
  95
  96 #
  97 # filters
  98 #
  99
 100 sub check_auth {
 101   $::auth->assert('price_rule_edit');
 102 }
 103
 104 #
 105 # helpers
 106 #
 107
 108 sub display_form {
 109   my ($self, %params) = @_;
 110   my $is_new  = !$self->price_rule->id;
 111   my $title   = $self->form_title(($is_new ? 'create' : 'edit'), $self->price_rule->type);
 112   $self->render('price_rule/form',
 113     title => $title,
 114     %params
 115   );
 116 }
 117
 118 sub form_title {
 119   my ($self, $action, $type) = @_;
 120
 121   return {
 122     edit => {
 123       customer => t8('Edit sales price rule'),
 124       vendor   => t8('Edit purchase price rule'),
 125       ''       => t8('Edit price rule'),
 126     },
 127     create => {
 128       customer => t8('Create a new sales price rule'),
 129       vendor   => t8('Create a new purchase price rule'),
 130       ''       => t8('Create a new price rule'),
 131     },
 132     list => {
 133       customer => t8('Sales Price Rules'),
 134       vendor   => t8('Purchase Price Rules'),
 135       ''       => t8('Price Rules'),
 136     },
 137   }->{$action}{$type};
 138 }
 139
 140 sub create_or_update {
 141   my $self   = shift;
 142   my $is_new = !$self->price_rule->id;
 143   my $params = delete($::form->{price_rule}) || { };
 144
 145   delete $params->{id};
 146   $self->price_rule->assign_attributes(%{ $params });
 147
 148   my @errors = $self->price_rule->validate;
 149
 150   if (@errors) {
 151     flash('error', @errors);
 152     $self->display_form(callback => $::form->{callback});
 153     return;
 154   }
 155
 156   $self->price_rule->save;
 157
 158   flash_later('info', $is_new ? $::locale->text('The price rule has been created.') : $::locale->text('The price rule has been saved.'));
 159
 160   $self->redirect_to($::form->{callback} || (action => 'list', 'filter.type' => $self->price_rule->type));
 161 }
 162
 163 sub prepare_report {
 164   my ($self)      = @_;
 165
 166   my $callback    = $self->models->get_callback;
 167
 168   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 169   $self->{report} = $report;
 170
 171   my @columns     = qw(name type priority price reduction discount items);
 172   my @sortable    = qw(name type priority price reduction discount      );
 173
 174   my %column_defs = (
 175     name          => { obj_link => sub { $self->url_for(action => 'edit', 'price_rule.id' => $_[0]->id, callback => $callback) } },
 176     priority      => { sub  => sub { $_[0]->priority_as_text } },
 177     price         => { sub  => sub { $_[0]->price_as_number } },
 178     reduction     => { sub  => sub { $_[0]->reduction_as_number } },
 179     discount      => { sub  => sub { $_[0]->discount_as_number } },
 180     obsolete      => { sub  => sub { $_[0]->obsolete_as_bool_yn } },
 181     items         => { sub  => sub { $_[0]->item_summary } },
 182   );
 183
 184   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 185
 186   if ( $report->{options}{output_format} =~ /^(pdf|csv)$/i ) {
 187     $self->models->disable_plugin('paginated');
 188   }
 189   $report->set_options(
 190     std_column_visibility => 1,
 191     controller_class      => 'PriceRule',
 192     output_format         => 'HTML',
 193     title                 => $self->form_title('list', $self->vc),
 194     allow_pdf_export      => !$::form->{inline},
 195     allow_csv_export      => !$::form->{inline},
 196   );
 197   $report->set_columns(%column_defs);
 198   $report->set_column_order(@columns);
 199   $report->set_export_options(qw(list filter));
 200   $report->set_options_from_form;
 201   $self->models->get_models_url_params(sub{ map { $_ => $::form->{$_} } qw(inline) });
 202   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 203   $report->set_options(
 204     raw_bottom_info_text  => $self->render('price_rule/report_bottom', { output => 0 }),
 205     raw_top_info_text     => $self->render('price_rule/report_top', { output => 0 }),
 206   );
 207 }
 208
 209 sub make_filter_summary {
 210   my ($self) = @_;
 211
 212   my $filter = $::form->{filter} || {};
 213   my @filter_strings;
 214
 215   my @filters = (
 216     [ $filter->{"name:substr::ilike"}, t8('Name')  ],
 217     [ $filter->{"price:number"},       t8('Price') ],
 218     [ $filter->{"discount:number"},    t8('Discount') ],
 219   );
 220
 221   for (@filters) {
 222     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 223   }
 224
 225   if ($filter->{has_item_type}) {
 226     push @filter_strings, sprintf "%s: %s", t8('Has item type'), join ', ', map {
 227       SL::DB::Manager::PriceRuleItem->get_type($_)->{description}
 228     } @{ $filter->{has_item_type} || [] };
 229   }
 230
 231   $self->{filter_summary} = join ', ', @filter_strings;
 232 }
 233
 234 sub all_price_rule_item_types {
 235   SL::DB::Manager::PriceRuleItem->get_all_types($_[0]->vc || $_[0]->price_rule->type);
 236 }
 237
 238 sub add_javascripts  {
 239   $::request->{layout}->add_javascripts(qw(kivi.PriceRule.js autocomplete_customer.js autocomplete_vendor.js autocomplete_part.js));
 240 }
 241
 242 sub init_price_rule {
 243   my ($self) = @_;
 244
 245   my $price_rule = $::form->{price_rule}{id} ? SL::DB::PriceRule->new(id => $::form->{price_rule}{id})->load : SL::DB::PriceRule->new;
 246
 247   my $items = delete $::form->{price_rule}{items};
 248
 249   $price_rule->assign_attributes(%{ $::form->{price_rule} || {} });
 250
 251   my %old_items = map { $_->id => $_ } $price_rule->items;
 252
 253   my @items;
 254   for my $raw_item (@$items) {
 255     my $item = $raw_item->{id} ? $old_items{ $raw_item->{id} } || SL::DB::PriceRuleItem->new(id => $raw_item->{id})->load : SL::DB::PriceRuleItem->new;
 256     $item->assign_attributes(%$raw_item);
 257     push @items, $item;
 258   }
 259
 260   $price_rule->items(@items) if @items;
 261
 262   $self->price_rule($price_rule);
 263 }
 264
 265 sub init_vc {
 266   $::form->{filter}{type};
 267 }
 268
 269 sub init_businesses {
 270   SL::DB::Manager::Business->get_all;
 271 }
 272
 273 sub init_pricegroups {
 274   SL::DB::Manager::Pricegroup->get_all;
 275 }
 276
 277 sub init_partsgroups {
 278   SL::DB::Manager::PartsGroup->get_all;
 279 }
 280
 281 sub all_price_types {
 282   SL::DB::Manager::PriceRule->all_price_types;
 283 }
 284
 285 sub init_models {
 286   my ($self) = @_;
 287
 288   SL::Controller::Helper::GetModels->new(
 289     controller => $self,
 290     sorted => {
 291       name     => t8('Name'),
 292       type     => t8('Type'),
 293       priority => t8('Priority'),
 294       price    => t8('Price'),
 295       discount => t8('Discount'),
 296       reduction => t8('Reduced Master Data'),
 297       obsolete => t8('Obsolete'),
 298       items    => t8('Rule Details'),
 299     },
 300   );
 301 }
 302
 303 1;