bin/mozilla/is.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # Inventory invoicing module
  31 #
  32 #======================================================================
  33
  34 use SL::FU;
  35 use SL::IS;
  36 use SL::PE;
  37 use SL::OE;
  38 use SL::DB::Default;
  39 use Data::Dumper;
  40 use SL::DBUtils;
  41 use List::Util qw(max sum);
  42
  43 require "bin/mozilla/io.pl";
  44 require "bin/mozilla/invoice_io.pl";
  45 require "bin/mozilla/arap.pl";
  46 require "bin/mozilla/drafts.pl";
  47
  48 use strict;
  49
  50 1;
  51
  52 # end of main
  53
  54 sub add {
  55   $main::lxdebug->enter_sub();
  56
  57   my $form     = $main::form;
  58   my $locale   = $main::locale;
  59
  60   $main::auth->assert('invoice_edit');
  61
  62   return $main::lxdebug->leave_sub() if (load_draft_maybe());
  63
  64   if ($form->{type} eq "credit_note") {
  65     $form->{title} = $locale->text('Add Credit Note');
  66
  67     if ($form->{storno}) {
  68       $form->{title} = $locale->text('Add Storno Credit Note');
  69     }
  70   } else {
  71     $form->{title} = $locale->text('Add Sales Invoice');
  72
  73   }
  74
  75
  76   $form->{callback} = "$form->{script}?action=add&type=$form->{type}" unless $form->{callback};
  77
  78   $form->{jsscript} = "date";
  79
  80   &invoice_links;
  81   &prepare_invoice;
  82   &display_form;
  83
  84   $main::lxdebug->leave_sub();
  85 }
  86
  87 sub edit {
  88   $main::lxdebug->enter_sub();
  89
  90   my $form     = $main::form;
  91   my $locale   = $main::locale;
  92
  93   $main::auth->assert('invoice_edit');
  94
  95   $form->{taxincluded_changed_by_user} = 1;
  96
  97   # show history button
  98   $form->{javascript} = qq|<script type="text/javascript" src="js/show_history.js"></script>|;
  99   #/show hhistory button
 100
 101   my ($language_id, $printer_id);
 102   if ($form->{print_and_post}) {
 103     $form->{action}   = "print";
 104     $form->{resubmit} = 1;
 105     $language_id = $form->{language_id};
 106     $printer_id = $form->{printer_id};
 107   }
 108
 109   &invoice_links;
 110   if ($form->{type} eq "credit_note") {
 111     $form->{title} = $locale->text('Edit Credit Note');
 112     $form->{title} = $locale->text('Edit Storno Credit Note') if $form->{storno};
 113   } else {
 114     $form->{title} = $locale->text('Edit Sales Invoice');
 115     $form->{title} = $locale->text('Edit Storno Invoice')     if $form->{storno};
 116   }
 117
 118   &prepare_invoice;
 119   if ($form->{print_and_post}) {
 120     $form->{language_id} = $language_id;
 121     $form->{printer_id} = $printer_id;
 122   }
 123
 124   &display_form;
 125
 126   $main::lxdebug->leave_sub();
 127 }
 128
 129 sub invoice_links {
 130   $main::lxdebug->enter_sub();
 131
 132   my $form     = $main::form;
 133   my %myconfig = %main::myconfig;
 134
 135   $main::auth->assert('invoice_edit');
 136
 137   $form->{vc} = 'customer';
 138
 139   # create links
 140   $form->{webdav}   = $::lx_office_conf{features}->{webdav};
 141
 142   $form->create_links("AR", \%myconfig, "customer");
 143
 144   if ($form->{all_customer}) {
 145     unless ($form->{customer_id}) {
 146       $form->{customer_id} = $form->{all_customer}->[0]->{id};
 147       $form->{salesman_id} = $form->{all_customer}->[0]->{salesman_id};
 148     }
 149   }
 150
 151   my $editing = $form->{id};
 152
 153   $form->backup_vars(qw(payment_id language_id taxzone_id salesman_id taxincluded currency cp_id intnotes id shipto_id));
 154
 155   IS->get_customer(\%myconfig, \%$form);
 156
 157   #quote all_customer Bug 133
 158   foreach my $ref (@{ $form->{all_customer} }) {
 159     $ref->{name} = $form->quote($ref->{name});
 160   }
 161
 162   $form->restore_vars(qw(id));
 163
 164   IS->retrieve_invoice(\%myconfig, \%$form);
 165   $form->restore_vars(qw(payment_id language_id taxzone_id currency intnotes cp_id shipto_id));
 166   $form->restore_vars(qw(taxincluded)) if $form->{id};
 167   $form->restore_vars(qw(salesman_id)) if $editing;
 168
 169
 170   # build vendor/customer drop down comatibility... don't ask
 171   if (@{ $form->{"all_customer"} }) {
 172     $form->{"selectcustomer"} = 1;
 173     $form->{customer}         = qq|$form->{customer}--$form->{"customer_id"}|;
 174   }
 175
 176   $form->{"oldcustomer"}  = $form->{customer};
 177
 178   if ($form->{"oldcustomer"} !~ m/--\d+$/ && $form->{"customer_id"}) {
 179     $form->{"oldcustomer"} .= qq|--$form->{"customer_id"}|
 180   }
 181
 182
 183 #  $form->{oldcustomer} = "$form->{customer}--$form->{customer_id}";
 184 #  $form->{selectcustomer} = 1;
 185
 186   $form->{employee} = "$form->{employee}--$form->{employee_id}";
 187
 188   # forex
 189   $form->{forex} = $form->{exchangerate};
 190   my $exchangerate = ($form->{exchangerate}) ? $form->{exchangerate} : 1;
 191
 192   foreach my $key (keys %{ $form->{AR_links} }) {
 193     foreach my $ref (@{ $form->{AR_links}{$key} }) {
 194       $form->{"select$key"} .= "<option>$ref->{accno}--$ref->{description}</option>\n";
 195     }
 196
 197     if ($key eq "AR_paid") {
 198       next unless $form->{acc_trans}{$key};
 199       for my $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 200         $form->{"AR_paid_$i"}      = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 201
 202         $form->{"acc_trans_id_$i"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 203         # reverse paid
 204         $form->{"paid_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{amount} * -1;
 205         $form->{"datepaid_$i"}     = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 206         $form->{"gldate_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 207         $form->{"exchangerate_$i"} = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 208         $form->{"forex_$i"}        = $form->{"exchangerate_$i"};
 209         $form->{"source_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{source};
 210         $form->{"memo_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 211
 212         $form->{paidaccounts} = $i;
 213       }
 214     } else {
 215       $form->{$key} = "$form->{acc_trans}{$key}->[0]->{accno}--$form->{acc_trans}{$key}->[0]->{description}";
 216     }
 217   }
 218
 219   $form->{paidaccounts} = 1 unless (exists $form->{paidaccounts});
 220
 221   $form->{AR} = $form->{AR_1} unless $form->{id};
 222
 223   $form->{locked} = ($form->datetonum($form->{invdate},  \%myconfig)
 224                   <= $form->datetonum($form->{closedto}, \%myconfig));
 225
 226   $main::lxdebug->leave_sub();
 227 }
 228
 229 sub prepare_invoice {
 230   $main::lxdebug->enter_sub();
 231
 232   my $form     = $main::form;
 233   my %myconfig = %main::myconfig;
 234
 235   $main::auth->assert('invoice_edit');
 236
 237   if ($form->{type} eq "credit_note") {
 238     $form->{type}     = "credit_note";
 239     $form->{formname} = "credit_note";
 240   } else {
 241     $form->{type}     = "invoice";
 242     $form->{formname} = "invoice";
 243   }
 244
 245   if ($form->{id}) {
 246
 247     my $i = 0;
 248
 249     foreach my $ref (@{ $form->{invoice_details} }) {
 250       $i++;
 251
 252       map { $form->{"${_}_$i"} = $ref->{$_} } keys %{$ref};
 253
 254       $form->{"discount_$i"}   = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100);
 255       my ($dec)                = ($form->{"sellprice_$i"} =~ /\.(\d+)/);
 256       $dec                     = length $dec;
 257       my $decimalplaces        = ($dec > 2) ? $dec : 2;
 258
 259       $form->{"sellprice_$i"}  = $form->format_amount(\%myconfig, $form->{"sellprice_$i"}, $decimalplaces);
 260       (my $dec_qty)            = ($form->{"qty_$i"} =~ /\.(\d+)/);
 261       $dec_qty                 = length $dec_qty;
 262
 263       $form->{"lastcost_$i"}  = $form->format_amount(\%myconfig, $form->{"lastcost_$i"}, $decimalplaces);
 264
 265       $form->{"qty_$i"}        = $form->format_amount(\%myconfig, $form->{"qty_$i"}, $dec_qty);
 266
 267       $form->{"sellprice_pg_$i"} = join ('--', $form->{"sellprice_$i"}, $form->{"pricegroup_id_$i"});
 268
 269       $form->{rowcount}        = $i;
 270
 271     }
 272
 273     # get pricegroups for parts
 274     IS->get_pricegroups_for_parts(\%myconfig, \%$form);
 275
 276     # Problem: set_pricegroup resets the sellprice of old invoices to the price
 277     # currently defined in the pricegroup, which is a problem if the price has
 278     # changed, as the old invoice gets the new price
 279     # set_pricegroup must never be called, when an old invoice is initially loaded
 280
 281     # set_pricegroup($_) for 1 .. $form->{rowcount};
 282   }
 283   $main::lxdebug->leave_sub();
 284 }
 285
 286 sub form_header {
 287   $main::lxdebug->enter_sub();
 288
 289   my $form     = $main::form;
 290   my %myconfig = %main::myconfig;
 291   my $locale   = $main::locale;
 292   my $cgi      = $::request->{cgi};
 293
 294   $main::auth->assert('invoice_edit');
 295
 296   my %TMPL_VAR = ();
 297   my @custom_hiddens;
 298
 299   $form->{employee_id} = $form->{old_employee_id} if $form->{old_employee_id};
 300   $form->{salesman_id} = $form->{old_salesman_id} if $form->{old_salesman_id};
 301
 302   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 303
 304   my @old_project_ids = ($form->{"globalproject_id"});
 305   map { push @old_project_ids, $form->{"project_id_$_"} if $form->{"project_id_$_"}; } 1..$form->{"rowcount"};
 306
 307   $form->get_lists("projects"      => { "key"    => "ALL_PROJECTS",
 308                                         "all"    => 0,
 309                                         "old_id" => \@old_project_ids },
 310                    "taxzones"      => "ALL_TAXZONES",
 311                    "currencies"    => "ALL_CURRENCIES",
 312                    "customers"     => "ALL_CUSTOMERS",
 313                    "departments"   => "all_departments",
 314                    "price_factors" => "ALL_PRICE_FACTORS");
 315
 316   $TMPL_VAR{ALL_EMPLOYEES}         = SL::DB::Manager::Employee->get_all(query => [ or => [ id => $::form->{employee_id},  deleted => 0 ] ]);
 317   $TMPL_VAR{ALL_SALESMEN}          = SL::DB::Manager::Employee->get_all(query => [ or => [ id => $::form->{salesman_id},  deleted => 0 ] ]);
 318   $TMPL_VAR{ALL_SHIPTO}            = SL::DB::Manager::Shipto->get_all(query => [
 319     or => [ trans_id  => $::form->{"$::form->{vc}_id"} * 1, and => [ shipto_id => $::form->{shipto_id} * 1, trans_id => undef ] ]
 320   ]);
 321   $TMPL_VAR{ALL_CONTACTS}          = SL::DB::Manager::Contact->get_all(query => [
 322     or => [
 323       cp_cv_id => $::form->{"$::form->{vc}_id"} * 1,
 324       and      => [
 325         cp_cv_id => undef,
 326         cp_id    => $::form->{cp_id} * 1
 327       ]
 328     ]
 329   ]);
 330   $TMPL_VAR{department_labels}     = sub { "$_[0]->{description}--$_[0]->{id}" };
 331
 332   # customer
 333   $TMPL_VAR{vc_keys} = sub { "$_[0]->{name}--$_[0]->{id}" };
 334   $TMPL_VAR{vclimit} = $myconfig{vclimit};
 335   $TMPL_VAR{vc_select} = "customer_or_vendor_selection_window('customer', '', 0, 0)";
 336   push @custom_hiddens, "customer_id";
 337   push @custom_hiddens, "oldcustomer";
 338   push @custom_hiddens, "selectcustomer";
 339
 340   # currencies and exchangerate
 341   my @values = map { $_       } @{ $form->{ALL_CURRENCIES} };
 342   my %labels = map { $_ => $_ } @{ $form->{ALL_CURRENCIES} };
 343   $form->{currency}            = $form->{defaultcurrency} unless $form->{currency};
 344   $form->{show_exchangerate}   = $form->{currency} ne $form->{defaultcurrency};
 345   $TMPL_VAR{currencies}        = NTI($::request->{cgi}->popup_menu('-name' => 'currency', '-default' => $form->{"currency"},
 346                                                       '-values' => \@values, '-labels' => \%labels,
 347                                                       '-onchange' => "document.getElementById('update_button').click();"
 348                                      )) if scalar @values;
 349   push @custom_hiddens, "forex";
 350   push @custom_hiddens, "exchangerate" if $form->{forex};
 351
 352   $TMPL_VAR{creditwarning} = ($form->{creditlimit} != 0) && ($form->{creditremaining} < 0) && !$form->{update};
 353   $TMPL_VAR{is_credit_remaining_negativ} = $form->{creditremaining} =~ /-/;
 354
 355   $::request->{layout}->focus('#customer');
 356
 357   my $follow_up_vc         =  $form->{customer};
 358   $follow_up_vc            =~ s/--\d*\s*$//;
 359   $TMPL_VAR{customer_name} = $follow_up_vc;
 360
 361 # set option selected
 362   foreach my $item (qw(AR)) {
 363     $form->{"select$item"} =~ s/ selected//;
 364     $form->{"select$item"} =~ s/option>\Q$form->{$item}\E/option selected>$form->{$item}/;
 365   }
 366
 367   $TMPL_VAR{is_type_credit_note} = $form->{type}   eq "credit_note";
 368   $TMPL_VAR{is_format_html}      = $form->{format} eq 'html';
 369   $TMPL_VAR{dateformat}          = $myconfig{dateformat};
 370   $TMPL_VAR{numberformat}        = $myconfig{numberformat};
 371
 372   # hiddens
 373   $TMPL_VAR{HIDDENS} = [qw(
 374     id action type media format queued printed emailed title vc discount
 375     title creditlimit creditremaining tradediscount business closedto locked shipped storno storno_id
 376     max_dunning_level dunning_amount
 377     shiptoname shiptostreet shiptozipcode shiptocity shiptocountry  shiptocontact shiptophone shiptofax
 378     shiptoemail shiptodepartment_1 shiptodepartment_2  shiptocp_gender message email subject cc bcc taxaccounts cursor_fokus
 379     convert_from_do_ids convert_from_oe_ids
 380   ), @custom_hiddens,
 381   map { $_.'_rate', $_.'_description', $_.'_taxnumber' } split / /, $form->{taxaccounts}];
 382
 383   $form->{jsscript} = 1;
 384   $::request->layout->use_stylesheet('presenter/record/record_list.css');
 385   $form->header();
 386
 387   print $form->parse_html_template("is/form_header", \%TMPL_VAR);
 388
 389   $main::lxdebug->leave_sub();
 390 }
 391
 392 sub form_footer {
 393   $main::lxdebug->enter_sub();
 394
 395   my $form     = $main::form;
 396   my %myconfig = %main::myconfig;
 397   my $locale   = $main::locale;
 398
 399   $main::auth->assert('invoice_edit');
 400
 401   $form->{invtotal}    = $form->{invsubtotal};
 402
 403   # note rows
 404   $form->{rows} = max 2,
 405     $form->numtextrows($form->{notes},    26, 8),
 406     $form->numtextrows($form->{intnotes}, 35, 8);
 407
 408
 409   # tax, total and subtotal calculations
 410   my ($tax, $subtotal);
 411   $form->{taxaccounts_array} = [ split(/ /, $form->{taxaccounts}) ];
 412
 413   if ( $form->{type} =~ /sales_(order|quotation)/ && $form->{vc} eq 'customer' && !$form->{taxincluded_changed_by_user} ) {
 414     my $query = '
 415       SELECT
 416         taxincluded_checked
 417       FROM
 418         customer
 419       WHERE
 420         id = ?';
 421     my $res = selectfirst_hashref_query($::form, $::form->get_standard_dbh(), $query, conv_i($::form->{customer_id}));
 422
 423     $form->{taxincluded} = ($res && defined($res->{taxincluded_checked})) ? $res->{taxincluded_checked} : $myconfig{taxincluded_checked};
 424   }
 425
 426   foreach my $item (@{ $form->{taxaccounts_array} }) {
 427     if ($form->{"${item}_base"}) {
 428       if ($form->{taxincluded}) {
 429         $form->{"${item}_total"} = $form->round_amount( ($form->{"${item}_base"} * $form->{"${item}_rate"}
 430                                                                                  / (1 + $form->{"${item}_rate"})), 2);
 431         $form->{"${item}_netto"} = $form->round_amount( ($form->{"${item}_base"} - $form->{"${item}_total"}), 2);
 432       } else {
 433         $form->{"${item}_total"} = $form->round_amount( $form->{"${item}_base"} * $form->{"${item}_rate"}, 2);
 434         $form->{invtotal} += $form->{"${item}_total"};
 435       }
 436     }
 437   }
 438
 439   # follow ups
 440   if ($form->{id}) {
 441     $form->{follow_ups}            = FU->follow_ups('trans_id' => $form->{id}) || [];
 442     $form->{follow_ups_unfinished} = ( sum map { $_->{due} * 1 } @{ $form->{follow_ups} } ) || 0;
 443   }
 444
 445   # payments
 446   my $totalpaid = 0;
 447   $form->{paidaccounts}++ if ($form->{"paid_$form->{paidaccounts}"});
 448   $form->{paid_indices} = [ 1 .. $form->{paidaccounts} ];
 449
 450   # Standard Konto für Umlaufvermögen
 451   my $accno_arap = IS->get_standard_accno_current_assets(\%myconfig, \%$form);
 452
 453   for my $i (1 .. $form->{paidaccounts}) {
 454     $form->{"changeable_$i"} = 1;
 455     if (SL::DB::Default->get->payments_changeable == 0) {
 456       # never
 457       $form->{"changeable_$i"} = ($form->{"acc_trans_id_$i"})? 0 : 1;
 458     } elsif (SL::DB::Default->get->payments_changeable == 2) {
 459       # on the same day
 460       $form->{"changeable_$i"} = (($form->{"gldate_$i"} eq '') ||
 461                                   ($form->current_date(\%myconfig) eq $form->{"gldate_$i"}));
 462     }
 463
 464     $form->{"selectAR_paid_$i"} = $form->{selectAR_paid};
 465     if (!$form->{"AR_paid_$i"}) {
 466       $form->{"selectAR_paid_$i"} =~ s/option>$accno_arap--(.*?)</option selected>$accno_arap--$1</;
 467     } else {
 468       $form->{"selectAR_paid_$i"} =~ s/option>\Q$form->{"AR_paid_$i"}\E/option selected>$form->{"AR_paid_$i"}/;
 469     }
 470
 471     $totalpaid += $form->{"paid_$i"};
 472   }
 473
 474   $form->{oldinvtotal} = $form->{invtotal};
 475
 476   print $form->parse_html_template('is/form_footer', {
 477     is_type_credit_note => ($form->{type} eq "credit_note"),
 478     totalpaid           => $totalpaid,
 479     paid_missing        => $form->{invtotal} - $totalpaid,
 480     print_options       => print_options(inline => 1),
 481     show_storno         => $form->{id} && !$form->{storno} && !IS->has_storno(\%myconfig, $form, "ar") && !$totalpaid,
 482     show_delete         => ($::instance_conf->get_is_changeable == 2)
 483                              ? ($form->current_date(\%myconfig) eq $form->{gldate})
 484                              : ($::instance_conf->get_is_changeable == 1),
 485   });
 486 ##print $form->parse_html_template('is/_payments'); # parser
 487 ##print $form->parse_html_template('webdav/_list'); # parser
 488
 489   $main::lxdebug->leave_sub();
 490 }
 491
 492 sub mark_as_paid {
 493   $main::lxdebug->enter_sub();
 494
 495   my $form     = $main::form;
 496   my %myconfig = %main::myconfig;
 497
 498   $main::auth->assert('invoice_edit');
 499
 500   &mark_as_paid_common(\%myconfig,"ar");
 501
 502   $main::lxdebug->leave_sub();
 503 }
 504
 505 sub update {
 506   $main::lxdebug->enter_sub();
 507
 508   my $form     = $main::form;
 509   my %myconfig = %main::myconfig;
 510
 511   $main::auth->assert('invoice_edit');
 512
 513   my ($recursive_call) = @_;
 514
 515   $form->{print_and_post} = 0         if $form->{second_run};
 516   my $taxincluded         = $form->{taxincluded} ? "checked" : '';
 517   $form->{update} = 1;
 518
 519   &check_name("customer");
 520
 521   $form->{taxincluded} ||= $taxincluded;
 522
 523   if (!$form->{forex}) {        # read exchangerate from input field (not hidden)
 524     $form->{exchangerate} = $form->parse_amount(\%myconfig, $form->{exchangerate}) unless $recursive_call;
 525   }
 526   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 527   $form->{exchangerate} = $form->{forex} if $form->{forex};
 528
 529   for my $i (1 .. $form->{paidaccounts}) {
 530     next unless $form->{"paid_$i"};
 531     map { $form->{"${_}_$i"} = $form->parse_amount(\%myconfig, $form->{"${_}_$i"}) } qw(paid exchangerate);
 532     if (!$form->{"forex_$i"}) {   #read exchangerate from input field (not hidden)
 533       $form->{exchangerate} = $form->{"exchangerate_$i"};
 534     }
 535     $form->{"forex_$i"}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy');
 536     $form->{"exchangerate_$i"} = $form->{"forex_$i"} if $form->{"forex_$i"};
 537   }
 538
 539   my $i            = $form->{rowcount};
 540   my $exchangerate = $form->{exchangerate} || 1;
 541
 542   # if last row empty, check the form otherwise retrieve new item
 543   if (   ($form->{"partnumber_$i"} eq "")
 544       && ($form->{"description_$i"} eq "")
 545       && ($form->{"partsgroup_$i"}  eq "")) {
 546
 547     $form->{creditremaining} += ($form->{oldinvtotal} - $form->{oldtotalpaid});
 548     &check_form;
 549
 550   } else {
 551
 552     IS->retrieve_item(\%myconfig, \%$form);
 553
 554     my $rows = scalar @{ $form->{item_list} };
 555
 556     # Falls kein Kundenrabatt vorhanden ist, den aktuellen Rabatt nicht mit 0% überschreiben,
 557     # da hier der Anwender schon manual einen Wert eingetragen haben könnte (analog zu qty) Bugfix: 1412
 558     if ($form->{customer_discount}){
 559       $form->{"discount_$i"} = $form->format_amount(\%myconfig, $form->{customer_discount} * 100);
 560     }
 561
 562     if ($rows) {
 563       $form->{"qty_$i"} = ($form->{"qty_$i"} * 1) ? $form->{"qty_$i"} : 1;
 564
 565       if ($rows > 1) {
 566
 567         select_item(mode => 'IS');
 568         ::end_of_request();
 569
 570       } else {
 571
 572         my $sellprice = $form->parse_amount(\%myconfig, $form->{"sellprice_$i"});
 573
 574         map { $form->{item_list}[$i]{$_} =~ s/\"/&quot;/g } qw(partnumber description unit);
 575         map { $form->{"${_}_$i"} = $form->{item_list}[0]{$_} } keys %{ $form->{item_list}[0] };
 576
 577         $form->{payment_id}    = $form->{"part_payment_id_$i"} if $form->{"part_payment_id_$i"} ne "";
 578         $form->{"discount_$i"} = 0                             if $form->{"not_discountable_$i"};
 579
 580         $form->{"marge_price_factor_$i"} = $form->{item_list}->[0]->{price_factor};
 581
 582         ($sellprice || $form->{"sellprice_$i"}) =~ /\.(\d+)/;
 583         my $decimalplaces = max 2, length $1;
 584
 585         if ($sellprice) {
 586           $form->{"sellprice_$i"} = $sellprice;
 587         } else {
 588           # if there is an exchange rate adjust sellprice
 589           $form->{"sellprice_$i"} *= (1 - $form->{tradediscount});
 590           $form->{"sellprice_$i"} /= $exchangerate;
 591         }
 592
 593         $form->{"listprice_$i"} /= $exchangerate;
 594
 595         my $amount = $form->{"sellprice_$i"} * $form->{"qty_$i"} * (1 - $form->{"discount_$i"} / 100);
 596         map { $form->{"${_}_base"} = 0 }                                 split / /, $form->{taxaccounts};
 597         map { $form->{"${_}_base"} += $amount }                          split / /, $form->{"taxaccounts_$i"};
 598         map { $amount += ($form->{"${_}_base"} * $form->{"${_}_rate"}) } split / /, $form->{"taxaccounts_$i"} if !$form->{taxincluded};
 599
 600         $form->{creditremaining} -= $amount;
 601
 602         map { $form->{"${_}_$i"} = $form->format_amount(\%myconfig, $form->{"${_}_$i"}, $decimalplaces) } qw(sellprice lastcost);
 603
 604         $form->{"qty_$i"} = $form->format_amount(\%myconfig, $form->{"qty_$i"});
 605
 606         # get pricegroups for parts
 607         IS->get_pricegroups_for_parts(\%myconfig, \%$form);
 608
 609         # build up html code for prices_$i
 610         &set_pricegroup($i);
 611       }
 612
 613       &display_form;
 614
 615     } else {
 616
 617       # ok, so this is a new part
 618       # ask if it is a part or service item
 619
 620       if (   $form->{"partsgroup_$i"}
 621           && ($form->{"partsnumber_$i"} eq "")
 622           && ($form->{"description_$i"} eq "")) {
 623         $form->{rowcount}--;
 624         $form->{"discount_$i"} = "";
 625         display_form();
 626
 627       } else {
 628         $form->{"id_$i"}   = 0;
 629         new_item();
 630       }
 631     }
 632   }
 633   $main::lxdebug->leave_sub();
 634 }
 635
 636 sub post_payment {
 637   $main::lxdebug->enter_sub();
 638
 639   my $form     = $main::form;
 640   my %myconfig = %main::myconfig;
 641   my $locale   = $main::locale;
 642
 643   $main::auth->assert('invoice_edit');
 644
 645   my $invdate = $form->datetonum($form->{invdate}, \%myconfig);
 646
 647   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 648   for my $i (1 .. $form->{paidaccounts}) {
 649     if ($form->{"paid_$i"}) {
 650       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 651
 652       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 653
 654
 655       if ($form->{currency} ne $form->{defaultcurrency}) {
 656         $form->{"exchangerate_$i"} = $form->{exchangerate}
 657           if ($invdate == $datepaid);
 658         $form->isblank("exchangerate_$i",
 659                        $locale->text('Exchangerate for payment missing!'));
 660       }
 661     }
 662   }
 663   # Abgeschlossene Zeiträume nur für den letzten (aktuellen) Zahlungseingang prüfen
 664   # Details s.a. Bug 1502
 665   # Das Problem ist jetzt, dass man Zahlungseingänge nachträglich ändern kann
 666   # Wobei dies für Installationen die sowieso nicht mit Bücherkontrolle arbeiten keinen
 667   # keinen Unterschied macht.
 668   # Optimal wäre, wenn gegen einen Zeitstempel des Zahlungsfelds geprüft würde ...
 669   # Das Problem hierbei ist, dass in IS.pm post_invoice IMMER alle Zahlungseingänge aus $form
 670   # erneut gespeichert werden. Prinzipiell wäre es besser NUR die Änderungen des Rechnungs-
 671   # belegs (neue Zahlung aber nichts anderes) zu speichern ...
 672   # Vielleicht könnte man ähnlich wie bei Rechnung löschen verfahren
 673   $form->error($locale->text('Cannot post payment for a closed period!'))
 674     if ($form->date_closed($form->{"datepaid_$form->{paidaccounts}"}, \%myconfig));
 675
 676   ($form->{AR})      = split /--/, $form->{AR};
 677   ($form->{AR_paid}) = split /--/, $form->{AR_paid};
 678   relink_accounts();
 679   $form->redirect($locale->text('Payment posted!'))
 680       if (IS->post_payment(\%myconfig, \%$form));
 681     $form->error($locale->text('Cannot post payment!'));
 682
 683
 684   $main::lxdebug->leave_sub();
 685 }
 686
 687 sub post {
 688   $main::lxdebug->enter_sub();
 689
 690   my $form     = $main::form;
 691   my %myconfig = %main::myconfig;
 692   my $locale   = $main::locale;
 693
 694   $main::auth->assert('invoice_edit');
 695
 696   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 697   $form->isblank("invdate",  $locale->text('Invoice Date missing!'));
 698   $form->isblank("customer", $locale->text('Customer missing!'));
 699   $form->error($locale->text('Cannot post invoice for a closed period!'))
 700         if ($form->date_closed($form->{"invdate"}, \%myconfig));
 701
 702   $form->{invnumber} =~ s/^\s*//g;
 703   $form->{invnumber} =~ s/\s*$//g;
 704
 705   # if oldcustomer ne customer redo form
 706   if (&check_name('customer')) {
 707     &update;
 708     ::end_of_request();
 709   }
 710
 711   if ($myconfig{mandatory_departments} && !$form->{department_id}) {
 712     $form->{saved_message} = $::locale->text('You have to specify a department.');
 713     update();
 714     exit;
 715   }
 716
 717   if ($form->{second_run}) {
 718     $form->{print_and_post} = 0;
 719   }
 720
 721   remove_emptied_rows();
 722   &validate_items;
 723
 724   my $closedto = $form->datetonum($form->{closedto}, \%myconfig);
 725   my $invdate  = $form->datetonum($form->{invdate},  \%myconfig);
 726
 727   $form->error($locale->text('Cannot post invoice for a closed period!'))
 728     if ($invdate <= $closedto);
 729
 730   $form->isblank("exchangerate", $locale->text('Exchangerate missing!'))
 731     if ($form->{currency} ne $form->{defaultcurrency});
 732
 733   for my $i (1 .. $form->{paidaccounts}) {
 734     if ($form->parse_amount(\%myconfig, $form->{"paid_$i"})) {
 735       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 736
 737       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 738
 739       $form->error($locale->text('Cannot post payment for a closed period!'))
 740         if ($form->date_closed($form->{"datepaid_$i"}, \%myconfig));
 741
 742       if ($form->{currency} ne $form->{defaultcurrency}) {
 743         $form->{"exchangerate_$i"} = $form->{exchangerate}
 744           if ($invdate == $datepaid);
 745         $form->isblank("exchangerate_$i",
 746                        $locale->text('Exchangerate for payment missing!'));
 747       }
 748     }
 749   }
 750
 751   ($form->{AR})        = split /--/, $form->{AR};
 752   ($form->{AR_paid})   = split /--/, $form->{AR_paid};
 753   $form->{storno}    ||= 0;
 754
 755   $form->{label} = $form->{type} eq 'credit_note' ? $locale->text('Credit Note') : $locale->text('Invoice');
 756
 757   $form->{id} = 0 if $form->{postasnew};
 758
 759   # get new invnumber in sequence if no invnumber is given or if posasnew was requested
 760   if ($form->{postasnew}) {
 761     if ($form->{type} eq "credit_note") {
 762       undef($form->{cnnumber});
 763     } else {
 764       undef($form->{invnumber});
 765     }
 766   }
 767
 768   relink_accounts();
 769   $form->error($locale->text('Cannot post invoice!'))
 770     unless IS->post_invoice(\%myconfig, \%$form);
 771   remove_draft() if $form->{remove_draft};
 772
 773   if(!exists $form->{addition}) {
 774     $form->{snumbers} =  'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
 775     $form->{addition} = $form->{print_and_post} ? "PRINTED AND POSTED" :
 776                         $form->{storno}         ? "STORNO"             :
 777                                                   "POSTED";
 778     $form->save_history;
 779   }
 780
 781   if (!$form->{no_redirect_after_post}) {
 782     $form->{action} = 'edit';
 783     $form->{script} = 'is.pl';
 784     $form->{saved_message} = $form->{label} . " $form->{invnumber} " . $locale->text('posted!');
 785     $form->{callback} = build_std_url(qw(action edit id saved_message));
 786     $form->redirect;
 787   }
 788
 789   $main::lxdebug->leave_sub();
 790 }
 791
 792 sub print_and_post {
 793   $main::lxdebug->enter_sub();
 794
 795   my $form     = $main::form;
 796
 797   $main::auth->assert('invoice_edit');
 798
 799   my $old_form                    = new Form;
 800   $form->{no_redirect_after_post} = 1;
 801   $form->{print_and_post}         = 1;
 802   &post();
 803
 804   &edit();
 805   $main::lxdebug->leave_sub();
 806
 807 }
 808
 809 sub use_as_new {
 810   $main::lxdebug->enter_sub();
 811
 812   my $form     = $main::form;
 813   my %myconfig = %main::myconfig;
 814
 815   $main::auth->assert('invoice_edit');
 816
 817   delete @{ $form }{qw(printed emailed queued invnumber invdate deliverydate id datepaid_1 gldate_1 acc_trans_id_1 source_1 memo_1 paid_1 exchangerate_1 AP_paid_1 storno locked)};
 818   $form->{paidaccounts} = 1;
 819   $form->{rowcount}--;
 820   $form->{invdate} = $form->current_date(\%myconfig);
 821   $form->{duedate} = $form->get_duedate(\%myconfig, $form->{invdate}) || $form->{invdate};
 822
 823   # remember pricegroups for "use as new"
 824   IS->get_pricegroups_for_parts(\%myconfig, \%$form);
 825   set_pricegroup($_) for 1 .. $form->{rowcount};
 826
 827   &display_form;
 828
 829   $main::lxdebug->leave_sub();
 830 }
 831
 832 sub storno {
 833   $main::lxdebug->enter_sub();
 834
 835   my $form     = $main::form;
 836   my %myconfig = %main::myconfig;
 837   my $locale   = $main::locale;
 838
 839   $main::auth->assert('invoice_edit');
 840
 841   if ($form->{storno}) {
 842     $form->error($locale->text('Cannot storno storno invoice!'));
 843   }
 844
 845   if (IS->has_storno(\%myconfig, $form, "ar")) {
 846     $form->error($locale->text("Invoice has already been storno'd!"));
 847   }
 848
 849   map({ my $key = $_; delete($form->{$key}) unless (grep({ $key eq $_ } qw(id login password type))); } keys(%{ $form }));
 850
 851   invoice_links();
 852   prepare_invoice();
 853   relink_accounts();
 854
 855   # Payments must not be recorded for the new storno invoice.
 856   $form->{paidaccounts} = 0;
 857   map { my $key = $_; delete $form->{$key} if grep { $key =~ /^$_/ } qw(datepaid_ gldate_ acc_trans_id_ source_ memo_ paid_ exchangerate_ AR_paid_) } keys %{ $form };
 858
 859   $form->{storno_id} = $form->{id};
 860   $form->{storno} = 1;
 861   $form->{id} = "";
 862   $form->{invnumber} = "Storno zu " . $form->{invnumber};
 863   $form->{rowcount}++;
 864
 865   post();
 866   $main::lxdebug->leave_sub();
 867 }
 868
 869 sub preview {
 870   $main::lxdebug->enter_sub();
 871
 872   my $form     = $main::form;
 873
 874   $main::auth->assert('invoice_edit');
 875
 876   $form->{preview} = 1;
 877   my $old_form = new Form;
 878   for (keys %$form) { $old_form->{$_} = $form->{$_} }
 879
 880   &print_form($old_form);
 881   $main::lxdebug->leave_sub();
 882
 883 }
 884
 885 sub delete {
 886   $main::lxdebug->enter_sub();
 887
 888   my $form     = $main::form;
 889   my $locale   = $main::locale;
 890
 891   $main::auth->assert('invoice_edit');
 892
 893   if ($form->{second_run}) {
 894     $form->{print_and_post} = 0;
 895   }
 896   $form->header;
 897
 898   print qq|
 899 <form method="post" action="$form->{script}">
 900 |;
 901
 902   # delete action variable
 903   map { delete $form->{$_} } qw(action header);
 904
 905   foreach my $key (keys %$form) {
 906     next if (($key eq 'login') || ($key eq 'password') || ('' ne ref $form->{$key}));
 907     $form->{$key} =~ s/\"/&quot;/g;
 908     print qq|<input type="hidden" name="$key" value="$form->{$key}">\n|;
 909   }
 910
 911   print qq|
 912 <h2 class="confirm">| . $locale->text('Confirm!') . qq|</h2>
 913
 914 <h4>|
 915     . $locale->text('Are you sure you want to delete Invoice Number')
 916     . qq| $form->{invnumber}
 917 </h4>
 918
 919 <p>
 920 <input name="action" class="submit" type="submit" value="|
 921     . $locale->text('Yes') . qq|">
 922 </form>
 923 |;
 924
 925   $main::lxdebug->leave_sub();
 926 }
 927
 928 sub credit_note {
 929   $main::lxdebug->enter_sub();
 930
 931   my $form     = $main::form;
 932   my %myconfig = %main::myconfig;
 933   my $locale   = $main::locale;
 934
 935   $main::auth->assert('invoice_edit');
 936
 937   $form->{transdate} = $form->{invdate} = $form->current_date(\%myconfig);
 938   $form->{duedate} =
 939     $form->current_date(\%myconfig, $form->{invdate}, $form->{terms} * 1);
 940
 941   $form->{id}     = '';
 942   $form->{rowcount}--;
 943   $form->{shipto} = 1;
 944
 945
 946   $form->{title}  = $locale->text('Add Credit Note');
 947   $form->{script} = 'is.pl';
 948
 949   # Bei Gutschriften bezug zur Rechnungsnummer
 950   $form->{invnumber_for_credit_note} = $form->{invnumber};
 951   # bo creates the id, reset it
 952   map { delete $form->{$_} }
 953     qw(id invnumber subject message cc bcc printed emailed queued);
 954   $form->{ $form->{vc} } =~ s/--.*//g;
 955   $form->{type} = "credit_note";
 956
 957
 958   map { $form->{"select$_"} = "" } ($form->{vc}, 'currency');
 959
 960 #  map { $form->{$_} = $form->parse_amount(\%myconfig, $form->{$_}) }
 961 #    qw(creditlimit creditremaining);
 962
 963   for my $i (1 .. $form->{rowcount}) {
 964     for (qw(listprice)) {
 965       $form->{"${_}_${i}"} = $form->parse_amount(\%myconfig, $form->{"${_}_${i}"}) if $form->{"${_}_${i}"};
 966     }
 967   }
 968
 969   my $currency = $form->{currency};
 970   &invoice_links;
 971
 972   $form->{currency}     = $currency;
 973   $form->{forex}        = $form->check_exchangerate( \%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 974   $form->{exchangerate} = $form->{forex} || '';
 975
 976   $form->{creditremaining} -= ($form->{oldinvtotal} - $form->{ordtotal});
 977
 978   # bei Gutschriften werden Zahlungseingänge aus Rechnung nicht übernommen
 979   for my $i (1 .. $form->{paidaccounts}) {
 980     delete $form->{"paid_$i"};
 981     delete $form->{"source_$i"};
 982     delete $form->{"memo_$i"};
 983     delete $form->{"datepaid_$i"};
 984     delete $form->{"gldate_$i"};
 985     delete $form->{"acc_trans_id_$i"};
 986     delete $form->{"AR_paid_$i"};
 987   };
 988   $form->{paidaccounts} = 1;
 989
 990   &prepare_invoice;
 991
 992
 993   &display_form;
 994
 995   $main::lxdebug->leave_sub();
 996 }
 997
 998 sub yes {
 999   $main::lxdebug->enter_sub();
1000
1001   my $form     = $main::form;
1002   my %myconfig = %main::myconfig;
1003   my $locale   = $main::locale;
1004
1005   $main::auth->assert('invoice_edit');
1006
1007   if (IS->delete_invoice(\%myconfig, \%$form)) {
1008     # saving the history
1009     if(!exists $form->{addition}) {
1010       $form->{snumbers} = 'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
1011       $form->{addition} = "DELETED";
1012       $form->save_history;
1013     }
1014     # /saving the history
1015     $form->redirect($locale->text('Invoice deleted!'));
1016   }
1017   $form->error($locale->text('Cannot delete invoice!'));
1018
1019   $main::lxdebug->leave_sub();
1020 }
1021
1022 sub e_mail {
1023   $main::lxdebug->enter_sub();
1024
1025   my $form     = $main::form;
1026
1027   $main::auth->assert('invoice_edit');
1028
1029   if (!$form->{id}) {
1030     $form->{no_redirect_after_post} = 1;
1031
1032     my $saved_form = save_form();
1033
1034     post();
1035
1036     restore_form($saved_form, 0, qw(id invnumber));
1037   }
1038
1039   edit_e_mail();
1040
1041   $main::lxdebug->leave_sub();
1042 }