SL/Template/Simple.pm

   1 #====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #====================================================================
   8
   9 package SL::Template::Simple;
  10
  11 use strict;
  12
  13 use Scalar::Util qw(blessed);
  14
  15 # Parameters:
  16 #   1. The template's file name
  17 #   2. A reference to the Form object
  18 #   3. A reference to the myconfig hash
  19 #
  20 # Returns:
  21 #   A new template object
  22 sub new {
  23   my $type = shift;
  24   my $self = {};
  25
  26   bless($self, $type);
  27   $self->_init(@_);
  28
  29   return $self;
  30 }
  31
  32 sub _init {
  33   my ($self, %params) = @_;
  34
  35   $self->{$_} = $params{$_} for keys %params;
  36
  37   $self->{variable_content_types}        ||= {};
  38   $self->{variable_content_types}->{$_}    = lc $self->{variable_content_types}->{$_} for keys %{ $self->{variable_content_types} };
  39   $self->{default_variable_content_type}   = 'text';
  40
  41   $self->{error}     = undef;
  42   $self->{quot_re}   = '"';
  43
  44   $self->set_tag_style('<%', '%>');
  45 }
  46
  47 sub set_tag_style {
  48   my $self                    = shift;
  49   my $tag_start               = shift;
  50   my $tag_end                 = shift;
  51
  52   $self->{custom_tag_style}   = 1;
  53   $self->{tag_start}          = $tag_start;
  54   $self->{tag_end}            = $tag_end;
  55   $self->{tag_start_qm}       = quotemeta $tag_start;
  56   $self->{tag_end_qm}         = quotemeta $tag_end;
  57
  58   $self->{substitute_vars_re} = "$self->{tag_start_qm}(.+?)$self->{tag_end_qm}";
  59 }
  60
  61 sub set_use_template_toolkit {
  62   my $self                    = shift;
  63   my $value                   = shift;
  64
  65   $self->{use_template_toolkit} = $value;
  66 }
  67
  68 sub cleanup {
  69   my ($self) = @_;
  70 }
  71
  72 # Parameters:
  73 #   1. A typeglob for the file handle. The output will be written
  74 #      to this file handle.
  75 #
  76 # Returns:
  77 #   1 on success and undef or 0 if there was an error. In the latter case
  78 #   the calling function can retrieve the error message via $obj->get_error()
  79 sub parse {
  80   my $self = $_[0];
  81   local *OUT = $_[1];
  82
  83   print(OUT "Hallo!\n");
  84 }
  85
  86 sub get_error {
  87   my $self = shift;
  88
  89   return $self->{"error"};
  90 }
  91
  92 sub uses_temp_file {
  93   return 0;
  94 }
  95
  96 sub _get_loop_variable {
  97   my ($self, $var, $get_array, @indices) = @_;
  98   my $form      = $self->{form};
  99   my ($value, @methods);
 100
 101   if ($var =~ m/\./) {
 102     ($var, @methods) = split m/\./, $var;
 103   }
 104
 105   if (($get_array || @indices) && (ref $form->{TEMPLATE_ARRAYS} eq 'HASH') && (ref $form->{TEMPLATE_ARRAYS}->{$var} eq 'ARRAY')) {
 106     $value = $form->{TEMPLATE_ARRAYS}->{$var};
 107   } else {
 108     $value = $form->{$var};
 109   }
 110
 111   for (my $i = 0; $i < scalar(@indices); $i++) {
 112     last unless (ref($value) eq "ARRAY");
 113     $value = $value->[$indices[$i]];
 114   }
 115
 116   for my $part (@methods) {
 117     if (ref($value) =~ m/^(?:Form|HASH)$/) {
 118       $value = $value->{$part};
 119     } elsif (blessed($value) && $value->can($part)) {
 120       $value = $value->$part;
 121     } else {
 122       $value = '';
 123       last;
 124     }
 125   }
 126
 127   return $value;
 128 }
 129
 130 sub substitute_vars {
 131   my ($self, $text, @indices) = @_;
 132
 133   my $form = $self->{"form"};
 134
 135   while ($text =~ /$self->{substitute_vars_re}/) {
 136     my ($tag_pos, $tag_len) = ($-[0], $+[0] - $-[0]);
 137     my ($var, @option_list) = split(/\s+/, $1);
 138     my %options             = map { ($_ => 1) } @option_list;
 139
 140     my $value               = $self->_get_loop_variable($var, 0, @indices);
 141     $value                  = $form->parse_amount({ numberformat => $::myconfig{output_numberformat} || $::myconfig{numberformat} }, $value) if     $options{NOFORMAT};
 142     $value                  = $self->format_string($value, $var)                                                                             unless $options{NOESCAPE};
 143
 144     substr($text, $tag_pos, $tag_len, $value);
 145   }
 146
 147   return $text;
 148 }
 149
 150 sub _parse_block_if {
 151   $main::lxdebug->enter_sub();
 152
 153   my $self         = shift;
 154   my $contents     = shift;
 155   my $new_contents = shift;
 156   my $pos_if       = shift;
 157   my @indices      = @_;
 158
 159   $$new_contents .= $self->substitute_vars(substr($$contents, 0, $pos_if), @indices);
 160   substr($$contents, 0, $pos_if) = "";
 161
 162   if ($$contents !~ m/^$self->{tag_start_qm}if
 163                      \s*
 164                      (not\b|\!)?           # $1 -- Eventuelle Negierung
 165                      \s+
 166                      (\b.+?\b)             # $2 -- Name der zu überprüfenden Variablen
 167                      (                     # $3 -- Beginn des optionalen Vergleiches
 168                        \s*
 169                        ([!=])              # $4 -- Negierung des Vergleiches speichern
 170                        ([=~])              # $5 -- Art des Vergleiches speichern
 171                        \s*
 172                        (                   # $6 -- Gequoteter String oder Bareword
 173                          $self->{quot_re}
 174                          (.*?)(?<!\\)      # $7 -- Gequoteter String -- direkter Vergleich mit eq bzw. ne oder Patternmatching; Escapete Anführungs als Teil des Strings belassen
 175                          $self->{quot_re}
 176                        |
 177                          (\b.+?\b)         # $8 -- Bareword -- als Index für $form benutzen
 178                        )
 179                      )?
 180                      \s*
 181                      $self->{tag_end_qm}
 182                     /x) {
 183     $self->{"error"} = "Malformed $self->{tag_start}if$self->{tag_end}.";
 184     $main::lxdebug->leave_sub();
 185     return undef;
 186   }
 187
 188   my $not           = $1;
 189   my $var           = $2;
 190   my $comparison    = $3; # Optionaler Match um $4..$8
 191   my $operator_neg  = $4; # '=' oder '!' oder undef, wenn kein Vergleich erkannt
 192   my $operator_type = $5; # '=' oder '~' für Stringvergleich oder Regex
 193   my $quoted_word   = $7; # nur gültig, wenn quoted string angegeben (siehe unten); dann "value" aus <%if var == "value" %>
 194   my $bareword      = $8; # undef, falls quoted string angegeben wurde; andernfalls "othervar" aus <%if var == othervar %>
 195
 196   $not = !$not if ($operator_neg && $operator_neg eq '!');
 197
 198   substr($$contents, 0, length($&)) = "";
 199
 200   my $block;
 201   ($block, $$contents) = $self->find_end($$contents, 0, "$var $comparison", $not);
 202   if (!$block) {
 203     $self->{"error"} = "Unclosed $self->{tag_start}if$self->{tag_end}." unless ($self->{"error"});
 204     $main::lxdebug->leave_sub();
 205     return undef;
 206   }
 207
 208   my $value = $self->_get_loop_variable($var, 0, @indices);
 209   $value    = scalar(@{ $value }) if (ref($value) || '') eq 'ARRAY';
 210   my $hit   = 0;
 211
 212   if ($operator_type) {
 213     my $compare_to = $bareword ? $self->_get_loop_variable($bareword, 0, @indices) : $quoted_word;
 214     if ($operator_type eq '=') {
 215       $hit         = ($not && !($value eq $compare_to))     || (!$not && ($value eq $compare_to));
 216     } else {
 217       $hit         = ($not && !($value =~ m/$compare_to/i)) || (!$not && ($value =~ m/$compare_to/i));
 218     }
 219
 220   } else {
 221     $hit           = ($not && ! $value)                     || (!$not &&  $value);
 222   }
 223
 224   if ($hit) {
 225     my $new_text = $self->parse_block($block, @indices);
 226     if (!defined($new_text)) {
 227       $main::lxdebug->leave_sub();
 228       return undef;
 229     }
 230     $$new_contents .= $new_text;
 231   }
 232
 233   $main::lxdebug->leave_sub();
 234
 235   return 1;
 236 }
 237
 238 1;