SL/PriceSource/PriceRules.pm

   1 package SL::PriceSource::PriceRules;
   2
   3 use strict;
   4 use parent qw(SL::PriceSource::Base);
   5
   6 use SL::PriceSource::Price;
   7 use SL::PriceSource::Discount;
   8 use SL::Locale::String;
   9 use SL::DB::PriceRule;
  10 use List::UtilsBy qw(min_by max_by);
  11
  12 sub name { 'price_rules' }
  13
  14 sub description { t8('Price Rule') }
  15
  16 sub available_rules {
  17   my ($self, %params) = @_;
  18
  19   $self->{available} ||= SL::DB::Manager::PriceRule->get_all_matching(record => $self->record, record_item => $self->record_item);
  20 }
  21
  22 sub available_price_rules {
  23   my $rules = $_[0]->available_rules;
  24   grep { $_->price_type != SL::DB::Manager::PriceRule::PRICE_DISCOUNT() } @$rules
  25 }
  26
  27 sub available_discount_rules {
  28   my $rules = $_[0]->available_rules;
  29   grep { $_->price_type == SL::DB::Manager::PriceRule::PRICE_DISCOUNT() } @$rules
  30 }
  31
  32 sub available_prices {
  33   my ($self, %params) = @_;
  34
  35   map { $self->make_price_from_rule($_) } $self->available_price_rules;
  36 }
  37
  38 sub available_discounts {
  39   my ($self, %params) = @_;
  40
  41   map { $self->make_discount_from_rule($_) } $self->available_discount_rules;
  42 }
  43
  44 sub price_from_source {
  45   my ($self, $source, $spec) = @_;
  46
  47   my $rule = SL::DB::Manager::PriceRule->find_by(id => $spec);
  48
  49   return SL::PriceSource::Discount->new(
  50     price_source => $self,
  51     missing      => t8('The price rule for this price does not exist anymore'),
  52   ) if !$rule;
  53
  54   if ($rule->price_type != SL::DB::Manager::PriceRule::PRICE_DISCOUNT()) {
  55     return $self->make_price_from_rule($rule);
  56   } else {
  57     return SL::PriceSource::Price->new(
  58       price_source => $self,
  59       invalid      => t8('The price rule is not a rule for prices'),
  60     );
  61   }
  62 }
  63
  64 sub discount_from_source {
  65   my ($self, $source, $spec) = @_;
  66
  67   my $rule = SL::DB::Manager::PriceRule->find_by(id => $spec);
  68
  69   return SL::PriceSource::Discount->new(
  70     price_source => $self,
  71     missing      => t8('The price rule for this discount does not exist anymore'),
  72   ) if !$rule;
  73
  74   if ($rule->price_type == SL::DB::Manager::PriceRule::PRICE_DISCOUNT()) {
  75     return $self->make_discount_from_rule($rule);
  76   } else {
  77     return SL::PriceSource::Discount->new(
  78       price_source => $self,
  79       invalid      => t8('The price rule is not a rule for discounts'),
  80     );
  81   }
  82 }
  83
  84 sub best_price {
  85   my ($self) = @_;
  86
  87   my @rules     = $self->available_price_rules;
  88
  89   return unless @rules;
  90
  91   my @max_prio  = max_by { $_->priority } @rules;
  92   my $min_price = min_by { $self->price_for_rule($_) } @max_prio;
  93
  94   $self->make_price_from_rule($min_price);
  95 }
  96
  97 sub best_discount {
  98   my ($self) = @_;
  99
 100   my @rules     = $self->available_discount_rules;
 101
 102   return unless @rules;
 103
 104   my @max_prio     = max_by { $_->priority } @rules;
 105   my $max_discount = max_by { $_->discount } @max_prio;
 106
 107   $self->make_discount_from_rule($max_discount);
 108 }
 109
 110 sub price_for_rule {
 111   my ($self, $rule) = @_;
 112   $rule->price_type != SL::DB::Manager::PriceRule::PRICE_NEW()
 113     ? (1 - $rule->reduction / 100) * ($rule->is_sales ? $self->part->sellprice : $self->part->lastcost)
 114     : $rule->price;
 115 }
 116
 117 sub make_price_from_rule {
 118   my ($self, $rule) = @_;
 119
 120   SL::PriceSource::Price->new(
 121     price        => $self->price_for_rule($rule),
 122     spec         => $rule->id,
 123     description  => $rule->name,
 124     priority     => $rule->priority,
 125     price_source => $self,
 126     (invalid      => t8('This Price Rule is no longer valid'))x!!$rule->obsolete,
 127   )
 128 }
 129
 130 sub make_discount_from_rule {
 131   my ($self, $rule) = @_;
 132
 133   SL::PriceSource::Discount->new(
 134     discount     => $rule->discount / 100,
 135     spec         => $rule->id,
 136     description  => $rule->name,
 137     priority     => $rule->priority,
 138     price_source => $self,
 139     (invalid      => t8('This Price Rule is no longer valid'))x!!$rule->obsolete,
 140   )
 141 }
 142
 143 1;