SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use English qw(-no_match_vars);
   6 use List::Util qw(min);
   7 use List::MoreUtils qw(pairwise any);
   8
   9 use SL::Helper::Csv;
  10
  11 use SL::DB;
  12 use SL::DB::BankAccount;
  13 use SL::DB::Customer;
  14 use SL::DB::Language;
  15 use SL::DB::PaymentTerm;
  16 use SL::DB::DeliveryTerm;
  17 use SL::DB::Vendor;
  18 use SL::DB::Contact;
  19 use SL::DB::History;
  20
  21 use parent qw(Rose::Object);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  26  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by delivery_terms_by all_bank_accounts all_vc vc_by vc_counts_by clone_methods) ],
  27 );
  28
  29 sub run {
  30   my ($self, %params) = @_;
  31
  32   $self->test_run($params{test});
  33
  34   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  35
  36   my $profile = $self->profile;
  37   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  38                                   encoding               => $self->controller->profile->get('charset'),
  39                                   profile                => [{ profile => $profile, class => $self->class, mapping => $self->controller->mappings_for_profile }],
  40                                   ignore_unknown_columns => 1,
  41                                   strict_profile         => 1,
  42                                   case_insensitive_header => 1,
  43                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  44                                  ));
  45
  46   $self->controller->track_progress(progress => 10);
  47
  48   my $old_numberformat      = $::myconfig{numberformat};
  49   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  50
  51   $self->csv->parse;
  52
  53   $self->controller->track_progress(progress => 50);
  54
  55   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  56
  57   return if ( !$self->csv->header || $self->csv->errors );
  58
  59   my $headers         = { headers => [ grep { $self->csv->dispatcher->is_known($_, 0) } @{ $self->csv->header } ] };
  60   $headers->{methods} = [ map { $_->{path} } @{ $self->csv->specs->[0] } ];
  61   $headers->{used}    = { map { ($_ => 1) }  @{ $headers->{headers} } };
  62   $self->controller->headers($headers);
  63   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  64   $self->controller->info_headers({ used => { }, headers => [ ] });
  65
  66   my $objects  = $self->csv->get_objects;
  67
  68   $self->controller->track_progress(progress => 70);
  69
  70   my @raw_data = @{ $self->csv->get_data };
  71
  72   $self->controller->track_progress(progress => 80);
  73
  74   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @$objects, @raw_data ]);
  75
  76   $self->controller->track_progress(progress => 90);
  77
  78   $self->check_objects;
  79   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  80     $self->check_std_duplicates();
  81     $self->check_duplicates();
  82   }
  83   $self->fix_field_lengths;
  84
  85   $self->controller->track_progress(progress => 100);
  86
  87   $::myconfig{numberformat} = $old_numberformat;
  88 }
  89
  90 sub add_columns {
  91   my ($self, @columns) = @_;
  92
  93   my $h = $self->controller->headers;
  94
  95   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  96     $h->{used}->{$column} = 1;
  97     push @{ $h->{methods} }, $column;
  98     push @{ $h->{headers} }, $column;
  99   }
 100 }
 101
 102 sub add_info_columns {
 103   my ($self, @columns) = @_;
 104
 105   my $h = $self->controller->info_headers;
 106
 107   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 108     $h->{used}->{ $column->{method} } = 1;
 109     push @{ $h->{methods} }, $column->{method};
 110     push @{ $h->{headers} }, $column->{header};
 111   }
 112 }
 113
 114 sub add_raw_data_columns {
 115   my ($self, @columns) = @_;
 116
 117   my $h = $self->controller->raw_data_headers;
 118
 119   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 120     $h->{used}->{$column} = 1;
 121     push @{ $h->{headers} }, $column;
 122   }
 123 }
 124
 125 sub add_cvar_raw_data_columns {
 126   my ($self) = @_;
 127
 128   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 129 }
 130
 131 sub init_all_cvar_configs {
 132   # Must be overridden by derived specialized importer classes.
 133   return [];
 134 }
 135
 136 sub init_cvar_columns {
 137   my ($self) = @_;
 138
 139   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 140 }
 141
 142 sub init_all_languages {
 143   my ($self) = @_;
 144
 145   return SL::DB::Manager::Language->get_all;
 146 }
 147
 148 sub init_all_bank_accounts {
 149   my ($self) = @_;
 150
 151   return SL::DB::Manager::BankAccount->get_all_sorted( query => [ obsolete => 0 ] );
 152 }
 153
 154 sub init_payment_terms_by {
 155   my ($self) = @_;
 156
 157   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 158   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 159 }
 160
 161 sub init_delivery_terms_by {
 162   my ($self) = @_;
 163
 164   my $all_delivery_terms = SL::DB::Manager::DeliveryTerm->get_all;
 165   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_delivery_terms } } ) } qw(id description) };
 166 }
 167
 168 sub init_all_vc {
 169   my ($self) = @_;
 170
 171   return { customers => SL::DB::Manager::Customer->get_all,
 172            vendors   => SL::DB::Manager::Vendor->get_all };
 173 }
 174
 175 sub init_clone_methods {
 176   {}
 177 }
 178
 179 sub force_allow_columns {
 180   return ();
 181 }
 182
 183 sub init_vc_by {
 184   my ($self)    = @_;
 185
 186   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 187   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 188                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 189   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 190                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 191   my %by_gln    = ( customers => { map { ( $_->gln            => $_ ) } @{ $self->all_vc->{customers} } },
 192                     vendors   => { map { ( $_->gln            => $_ ) } @{ $self->all_vc->{vendors}   } } );
 193
 194   return { id     => \%by_id,
 195            number => \%by_number,
 196            name   => \%by_name,
 197            gln    => \%by_gln };
 198 }
 199
 200 sub init_vc_counts_by {
 201   my ($self) = @_;
 202
 203   my $vc_counts_by;
 204
 205   $vc_counts_by->{number}->{customers}->{$_->customernumber}++ for @{ $self->all_vc->{customers} };
 206   $vc_counts_by->{number}->{vendors}->  {$_->vendornumber}++   for @{ $self->all_vc->{vendors} };
 207   $vc_counts_by->{name}->  {customers}->{$_->name}++           for @{ $self->all_vc->{customers} };
 208   $vc_counts_by->{name}->  {vendors}->  {$_->name}++           for @{ $self->all_vc->{vendors} };
 209   $vc_counts_by->{gln}->   {customers}->{$_->gln}++            for @{ $self->all_vc->{customers} };
 210   $vc_counts_by->{gln}->   {vendors}->  {$_->gln}++            for @{ $self->all_vc->{vendors} };
 211
 212   return $vc_counts_by;
 213 }
 214
 215 sub check_vc {
 216   my ($self, $entry, $id_column) = @_;
 217
 218   if ($entry->{object}->$id_column) {
 219     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 220   }
 221
 222   my $is_ambiguous;
 223   if (!$entry->{object}->$id_column) {
 224     my $vc = $entry->{raw_data}->{customernumber} && $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} };
 225     if ($vc && $self->vc_counts_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} } > 1) {
 226       $vc = undef;
 227       $is_ambiguous = 1;
 228     }
 229     $vc ||= $entry->{raw_data}->{vendornumber} && $self->vc_by->{number}->{vendors}->{ $entry->{raw_data}->{vendornumber} };
 230     if ($vc && $self->vc_counts_by->{number}->{vendors}->{ $entry->{raw_data}->{vendornumber} } > 1) {
 231       $vc = undef;
 232       $is_ambiguous = 1;
 233     }
 234
 235     $entry->{object}->$id_column($vc->id) if $vc;
 236   }
 237
 238   if (!$entry->{object}->$id_column) {
 239     my $vc = $entry->{raw_data}->{customer} && $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} };
 240     if ($vc && $self->vc_counts_by->{name}->{customers}->{ $entry->{raw_data}->{customer} } > 1) {
 241       $vc = undef;
 242       $is_ambiguous = 1;
 243     }
 244     $vc ||= $entry->{raw_data}->{vendor} && $self->vc_by->{name}->{vendors}->{ $entry->{raw_data}->{vendor} };
 245     if ($vc && $self->vc_counts_by->{name}->{vendors}->{ $entry->{raw_data}->{vendor} } > 1) {
 246       $vc = undef;
 247       $is_ambiguous = 1;
 248     }
 249
 250     $entry->{object}->$id_column($vc->id) if $vc;
 251   }
 252
 253   if (!$entry->{object}->$id_column) {
 254     my $vc = $entry->{raw_data}->{customer_gln} && $self->vc_by->{gln}->{customers}->{ $entry->{raw_data}->{customer_gln} };
 255     if ($vc && $self->vc_counts_by->{gln}->{customers}->{ $entry->{raw_data}->{customer_gln} } > 1) {
 256       $vc = undef;
 257       $is_ambiguous = 1;
 258     }
 259     $vc ||= $entry->{raw_data}->{vendor_gln} && $self->vc_by->{gln}->{vendors}->{ $entry->{raw_data}->{vendor_gln} };
 260     if ($vc && $self->vc_counts_by->{gln}->{vendors}->{ $entry->{raw_data}->{vendor_gln} } > 1) {
 261       $vc = undef;
 262       $is_ambiguous = 1;
 263     }
 264
 265     $entry->{object}->$id_column($vc->id) if $vc;
 266   }
 267
 268   if ($entry->{object}->$id_column) {
 269     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 270   } else {
 271     if ($is_ambiguous) {
 272       push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor is ambiguous');
 273     } else {
 274       push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 275     }
 276   }
 277 }
 278
 279 sub handle_cvars {
 280   my ($self, $entry) = @_;
 281
 282   my %type_to_column = ( text      => 'text_value',
 283                          textfield => 'text_value',
 284                          select    => 'text_value',
 285                          date      => 'timestamp_value_as_date',
 286                          timestamp => 'timestamp_value_as_date',
 287                          number    => 'number_value_as_number',
 288                          bool      => 'bool_value' );
 289
 290   my @cvars;
 291   my %changed_cvars;
 292   foreach my $config (@{ $self->all_cvar_configs }) {
 293     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 294     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 295     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 296
 297     my $new_cvar = SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 298
 299     push @cvars, $new_cvar;
 300     $changed_cvars{$config->name} = $new_cvar;
 301   }
 302
 303   # merge existing with new cvars. swap every existing with the imported one, push the rest
 304   if (@cvars) {
 305     my @orig_cvars = ($entry->{object_to_save} || $entry->{object})->custom_variables;
 306     for (@orig_cvars) {
 307       $_ = $changed_cvars{ $_->config->name } if $changed_cvars{ $_->config->name };
 308       delete $changed_cvars{ $_->config->name };
 309     }
 310     push @orig_cvars, values %changed_cvars;
 311
 312     $entry->{object}->custom_variables(\@orig_cvars);
 313   }
 314 }
 315
 316 sub init_profile {
 317   my ($self) = @_;
 318
 319   eval "require " . $self->class;
 320
 321   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 322   delete $unwanted{$_} for ($self->force_allow_columns);
 323
 324   my %profile;
 325   for my $col ($self->class->meta->columns) {
 326     next if $unwanted{$col};
 327
 328     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 329       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 330       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 331       :                                                                     $col->name;
 332
 333     $profile{$col} = $name;
 334   }
 335
 336   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 337
 338   \%profile;
 339 }
 340
 341 sub add_displayable_columns {
 342   my ($self, @columns) = @_;
 343
 344   my @cols       = @{ $self->controller->displayable_columns || [] };
 345   my %ex_col_map = map { $_->{name} => $_ } @cols;
 346
 347   foreach my $column (@columns) {
 348     if ($ex_col_map{ $column->{name} }) {
 349       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 350     } else {
 351       push @cols, $column;
 352     }
 353   }
 354
 355   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 356 }
 357
 358 sub setup_displayable_columns {
 359   my ($self) = @_;
 360
 361   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 362 }
 363
 364 sub add_cvar_columns_to_displayable_columns {
 365   my ($self) = @_;
 366
 367   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 368                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 369                                      @{ $self->all_cvar_configs });
 370 }
 371
 372 sub init_existing_objects {
 373   my ($self) = @_;
 374
 375   eval "require " . $self->class;
 376   $self->existing_objects($self->manager_class->get_all);
 377 }
 378
 379 sub init_class {
 380   die "class not set";
 381 }
 382
 383 sub init_manager_class {
 384   my ($self) = @_;
 385
 386   $self->class =~ m/^SL::DB::(.+)/;
 387   $self->manager_class("SL::DB::Manager::" . $1);
 388 }
 389
 390 sub is_multiplexed { 0 }
 391
 392 sub check_objects {
 393 }
 394
 395 sub check_duplicates {
 396 }
 397
 398 sub check_auth {
 399   $::auth->assert('config');
 400 }
 401
 402 sub check_std_duplicates {
 403   my $self = shift;
 404
 405   my $duplicates = {};
 406
 407   my $all_fields = $self->get_duplicate_check_fields();
 408
 409   foreach my $key (keys(%{ $all_fields })) {
 410     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 411       $duplicates->{$key} = {};
 412     }
 413   }
 414
 415   my @duplicates_keys = keys(%{ $duplicates });
 416
 417   if ( !scalar(@duplicates_keys) ) {
 418     return;
 419   }
 420
 421   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 422     foreach my $object (@{ $self->existing_objects }) {
 423       foreach my $key (@duplicates_keys) {
 424         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 425         $duplicates->{$key}->{$value} = 'db';
 426       }
 427     }
 428   }
 429
 430   foreach my $entry (@{ $self->controller->data }) {
 431     if ( @{ $entry->{errors} } ) {
 432       next;
 433     }
 434
 435     my $object = $entry->{object};
 436
 437     foreach my $key (@duplicates_keys) {
 438       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 439
 440       if ( exists($duplicates->{$key}->{$value}) ) {
 441         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 442         last;
 443       } else {
 444         $duplicates->{$key}->{$value} = 'csv';
 445       }
 446
 447     }
 448   }
 449
 450 }
 451
 452 sub get_duplicate_check_fields {
 453   return {};
 454 }
 455
 456 sub check_payment {
 457   my ($self, $entry) = @_;
 458
 459   my $object = $entry->{object};
 460
 461   # Check whether or not payment ID is valid.
 462   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 463     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 464     return 0;
 465   }
 466
 467   # Map name to ID if given.
 468   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 469     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 470
 471     if (!$terms) {
 472       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 473       return 0;
 474     }
 475
 476     $object->payment_id($terms->id);
 477
 478     # register payment_id for method copying later
 479     $self->clone_methods->{payment_id} = 1;
 480   }
 481
 482   return 1;
 483 }
 484
 485 sub check_delivery_term {
 486   my ($self, $entry) = @_;
 487
 488   my $object = $entry->{object};
 489
 490   # Check whether or not delivery term ID is valid.
 491   if ($object->delivery_term_id && !$self->delivery_terms_by->{id}->{ $object->delivery_term_id }) {
 492     push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 493     return 0;
 494   }
 495
 496   # Map name to ID if given.
 497   if (!$object->delivery_term_id && $entry->{raw_data}->{delivery_term}) {
 498     my $terms = $self->delivery_terms_by->{description}->{ $entry->{raw_data}->{delivery_term} };
 499
 500     if (!$terms) {
 501       push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 502       return 0;
 503     }
 504
 505     $object->delivery_term_id($terms->id);
 506
 507     # register delivery_term_id for method copying later
 508     $self->clone_methods->{delivery_term_id} = 1;
 509   }
 510
 511   return 1;
 512 }
 513
 514 sub save_objects {
 515   my ($self, %params) = @_;
 516
 517   my $data = $params{data} || $self->controller->data;
 518
 519   return unless $data->[0];
 520   return unless $data->[0]{object};
 521
 522   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 523
 524   my $last_index = $#$data;
 525   my $chunk_size = 100;      # one transaction and progress update every 100 objects
 526
 527   for my $chunk (0 .. $last_index / $chunk_size) {
 528     $self->controller->track_progress(progress => ($chunk_size * $chunk)/scalar(@$data) * 100); # scale from 45..95%;
 529     SL::DB->client->with_transaction(sub {
 530       foreach my $entry_index ($chunk_size * $chunk .. min( $last_index, $chunk_size * ($chunk + 1) - 1 )) {
 531         my $entry = $data->[$entry_index];
 532         next if @{ $entry->{errors} };
 533
 534         my $object = $entry->{object_to_save} || $entry->{object};
 535
 536         my $ret;
 537         if (!eval { $ret = $object->save(cascade => !!$self->save_with_cascade()); 1 }) {
 538           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $EVAL_ERROR);
 539         } elsif ( !$ret ) {
 540           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $object->db->error);
 541         } else {
 542           $self->_save_history($object);
 543           $self->controller->num_imported($self->controller->num_imported + 1);
 544         }
 545       }
 546       1;
 547     }) or do { die SL::DB->client->error };
 548   }
 549   $self->controller->track_progress(progress => 100);
 550 }
 551
 552 sub field_lengths {
 553   my ($self) = @_;
 554
 555   return map { $_->name => $_->length } grep { $_->type eq 'varchar' } @{$self->class->meta->columns};
 556 }
 557
 558 sub fix_field_lengths {
 559   my ($self) = @_;
 560
 561   my %field_lengths = $self->field_lengths;
 562   foreach my $entry (@{ $self->controller->data }) {
 563     next unless @{ $entry->{errors} };
 564     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 565   }
 566 }
 567
 568 sub clean_fields {
 569   my ($self, $illegal_chars, $object, @fields) = @_;
 570
 571   my @cleaned_fields;
 572   foreach my $field (grep { $object->can($_) } @fields) {
 573     my $value = $object->$field;
 574
 575     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 576
 577     $object->$field($value);
 578     push @cleaned_fields, $field;
 579   }
 580
 581   return @cleaned_fields;
 582 }
 583
 584 sub _save_history {
 585   my ($self, $object) = @_;
 586
 587   if (any { $self->controller->{type} && $_ eq $self->controller->{type} } qw(parts customers_vendors orders ar_transactions)) {
 588     my $snumbers = $self->controller->{type} eq 'parts'             ? 'partnumber_' . $object->partnumber
 589                  : $self->controller->{type} eq 'customers_vendors' ?
 590                      ($self->table eq 'customer' ? 'customernumber_' . $object->customernumber : 'vendornumber_' . $object->vendornumber)
 591                  : $self->controller->{type} eq 'orders'            ? 'ordnumber_' . $object->ordnumber
 592                  : $self->controller->{type} eq 'ar_transactions'   ? 'invnumber_' . $object->invnumber
 593                  : '';
 594
 595     my $what_done = $self->controller->{type} eq 'orders' ? 'sales_order'
 596                   : '';
 597
 598     SL::DB::History->new(
 599       trans_id    => $object->id,
 600       snumbers    => $snumbers,
 601       employee_id => $self->controller->{employee_id},
 602       addition    => 'SAVED',
 603       what_done   => $what_done,
 604     )->save();
 605   }
 606 }
 607
 608 1;