SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::Vendor;
  12
  13 use parent qw(Rose::Object);
  14
  15 use Rose::Object::MakeMethods::Generic
  16 (
  17  scalar                  => [ qw(controller file csv) ],
  18  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by all_vc vc_by) ],
  19 );
  20
  21 sub run {
  22   my ($self) = @_;
  23
  24   my $profile = $self->profile;
  25   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  26                                   encoding               => $self->controller->profile->get('charset'),
  27                                   class                  => $self->class,
  28                                   profile                => $profile,
  29                                   ignore_unknown_columns => 1,
  30                                   strict_profile         => 1,
  31                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  32                                  ));
  33
  34   my $old_numberformat      = $::myconfig{numberformat};
  35   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  36
  37   $self->csv->parse;
  38
  39   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  40
  41   return unless $self->csv->header;
  42
  43   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  44   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  45   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  46   $self->controller->headers($headers);
  47   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  48   $self->controller->info_headers({ used => { }, headers => [ ] });
  49
  50   my @objects  = $self->csv->get_objects;
  51   my @raw_data = @{ $self->csv->get_data };
  52   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  53
  54   $self->check_objects;
  55   $self->check_duplicates if $self->controller->profile->get('duplicates', 'no_check') ne 'no_check';
  56   $self->fix_field_lengths;
  57
  58   $::myconfig{numberformat} = $old_numberformat;
  59 }
  60
  61 sub add_columns {
  62   my ($self, @columns) = @_;
  63
  64   my $h = $self->controller->headers;
  65
  66   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  67     $h->{used}->{$column} = 1;
  68     push @{ $h->{methods} }, $column;
  69     push @{ $h->{headers} }, $column;
  70   }
  71 }
  72
  73 sub add_info_columns {
  74   my ($self, @columns) = @_;
  75
  76   my $h = $self->controller->info_headers;
  77
  78   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
  79     $h->{used}->{ $column->{method} } = 1;
  80     push @{ $h->{methods} }, $column->{method};
  81     push @{ $h->{headers} }, $column->{header};
  82   }
  83 }
  84
  85 sub add_raw_data_columns {
  86   my ($self, @columns) = @_;
  87
  88   my $h = $self->controller->raw_data_headers;
  89
  90   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  91     $h->{used}->{$column} = 1;
  92     push @{ $h->{headers} }, $column;
  93   }
  94 }
  95
  96 sub add_cvar_raw_data_columns {
  97   my ($self) = @_;
  98
  99   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 100 }
 101
 102 sub init_cvar_columns {
 103   my ($self) = @_;
 104
 105   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 106 }
 107
 108 sub init_all_languages {
 109   my ($self) = @_;
 110
 111   return SL::DB::Manager::Language->get_all;
 112 }
 113
 114 sub init_payment_terms_by {
 115   my ($self) = @_;
 116
 117   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 118   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 119 }
 120
 121 sub init_all_vc {
 122   my ($self) = @_;
 123
 124   return { customers => SL::DB::Manager::Customer->get_all,
 125            vendors   => SL::DB::Manager::Vendor->get_all };
 126 }
 127
 128 sub init_vc_by {
 129   my ($self)    = @_;
 130
 131   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 132   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 133                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 134   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 135                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 136
 137   return { id     => \%by_id,
 138            number => \%by_number,
 139            name   => \%by_name,   };
 140 }
 141
 142 sub check_vc {
 143   my ($self, $entry, $id_column) = @_;
 144
 145   if ($entry->{object}->$id_column) {
 146     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 147   }
 148
 149   if (!$entry->{object}->$id_column) {
 150     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 151           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 152     $entry->{object}->$id_column($vc->id) if $vc;
 153   }
 154
 155   if (!$entry->{object}->$id_column) {
 156     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 157           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 158     $entry->{object}->$id_column($vc->id) if $vc;
 159   }
 160
 161   if ($entry->{object}->$id_column) {
 162     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 163   } else {
 164     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 165   }
 166 }
 167
 168 sub handle_cvars {
 169   my ($self, $entry) = @_;
 170
 171   return unless $self->can('all_cvar_configs');
 172
 173   my %type_to_column = ( text      => 'text_value',
 174                          textfield => 'text_value',
 175                          select    => 'text_value',
 176                          date      => 'timestamp_value_as_date',
 177                          timestamp => 'timestamp_value_as_date',
 178                          number    => 'number_value_as_number',
 179                          bool      => 'bool_value' );
 180
 181   my @cvars;
 182   foreach my $config (@{ $self->all_cvar_configs }) {
 183     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 184     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 185     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 186
 187     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value);
 188   }
 189
 190   $entry->{object}->custom_variables(\@cvars);
 191 }
 192
 193 sub init_profile {
 194   my ($self) = @_;
 195
 196   eval "require " . $self->class;
 197
 198   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 199   my %profile;
 200   for my $col ($self->class->meta->columns) {
 201     next if $unwanted{$col};
 202
 203     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 204       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 205       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 206       :                                                                     $col->name;
 207
 208     $profile{$col} = $name;
 209   }
 210
 211   $self->profile(\%profile);
 212 }
 213
 214 sub add_displayable_columns {
 215   my ($self, @columns) = @_;
 216
 217   my @cols       = @{ $self->controller->displayable_columns || [] };
 218   my %ex_col_map = map { $_->{name} => $_ } @cols;
 219
 220   foreach my $column (@columns) {
 221     if ($ex_col_map{ $column->{name} }) {
 222       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 223     } else {
 224       push @cols, $column;
 225     }
 226   }
 227
 228   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 229 }
 230
 231 sub setup_displayable_columns {
 232   my ($self) = @_;
 233
 234   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 235 }
 236
 237 sub add_cvar_columns_to_displayable_columns {
 238   my ($self) = @_;
 239
 240   return unless $self->can('all_cvar_configs');
 241
 242   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 243                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 244                                      @{ $self->all_cvar_configs });
 245 }
 246
 247 sub init_existing_objects {
 248   my ($self) = @_;
 249
 250   eval "require " . $self->class;
 251   $self->existing_objects($self->manager_class->get_all);
 252 }
 253
 254 sub init_class {
 255   die "class not set";
 256 }
 257
 258 sub init_manager_class {
 259   my ($self) = @_;
 260
 261   $self->class =~ m/^SL::DB::(.+)/;
 262   $self->manager_class("SL::DB::Manager::" . $1);
 263 }
 264
 265 sub check_objects {
 266 }
 267
 268 sub check_duplicates {
 269 }
 270
 271 sub check_payment {
 272   my ($self, $entry) = @_;
 273
 274   my $object = $entry->{object};
 275
 276   # Check whether or not payment ID is valid.
 277   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 278     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 279     return 0;
 280   }
 281
 282   # Map name to ID if given.
 283   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 284     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 285
 286     if (!$terms) {
 287       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 288       return 0;
 289     }
 290
 291     $object->payment_id($terms->id);
 292   }
 293
 294   return 1;
 295 }
 296
 297 sub save_objects {
 298   my ($self, %params) = @_;
 299
 300   my $data = $params{data} || $self->controller->data;
 301
 302   foreach my $entry (@{ $data }) {
 303     next if @{ $entry->{errors} };
 304
 305     my $object = $entry->{object_to_save} || $entry->{object};
 306
 307     if (!$object->save) {
 308       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 309     } else {
 310       $self->controller->num_imported($self->controller->num_imported + 1);
 311     }
 312   }
 313 }
 314
 315 sub field_lengths {
 316   return ();
 317 }
 318
 319 sub fix_field_lengths {
 320   my ($self) = @_;
 321
 322   my %field_lengths = $self->field_lengths;
 323   foreach my $entry (@{ $self->controller->data }) {
 324     next unless @{ $entry->{errors} };
 325     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 326   }
 327 }
 328
 329 1;