SL/Controller/CustomerVendor.pm

   1 package SL::Controller::CustomerVendor;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use List::MoreUtils qw(any);
   7
   8 use SL::JSON;
   9 use SL::DBUtils;
  10 use SL::Helper::Flash;
  11 use SL::Locale::String;
  12 use SL::Controller::Helper::GetModels;
  13 use SL::Controller::Helper::ReportGenerator;
  14 use SL::Controller::Helper::ParseFilter;
  15
  16 use SL::DB::Customer;
  17 use SL::DB::Vendor;
  18 use SL::DB::Business;
  19 use SL::DB::Employee;
  20 use SL::DB::Language;
  21 use SL::DB::TaxZone;
  22 use SL::DB::Note;
  23 use SL::DB::PaymentTerm;
  24 use SL::DB::Pricegroup;
  25 use SL::DB::Contact;
  26 use SL::DB::FollowUp;
  27 use SL::DB::FollowUpLink;
  28 use SL::DB::History;
  29 use SL::DB::Currency;
  30 use SL::DB::Invoice;
  31 use SL::DB::PurchaseInvoice;
  32 use SL::DB::Order;
  33
  34 use Data::Dumper;
  35
  36 use Rose::Object::MakeMethods::Generic (
  37   'scalar --get_set_init' => [ qw(customer_models vendor_models) ],
  38 );
  39
  40 # safety
  41 __PACKAGE__->run_before(
  42   sub {
  43     $::auth->assert('customer_vendor_edit');
  44   }
  45 );
  46 __PACKAGE__->run_before(
  47   '_instantiate_args',
  48   only => [
  49     'save',
  50     'save_and_ap_transaction',
  51     'save_and_ar_transaction',
  52     'save_and_close',
  53     'save_and_invoice',
  54     'save_and_order',
  55     'save_and_quotation',
  56     'save_and_rfq',
  57     'delete',
  58     'delete_contact',
  59     'delete_shipto',
  60   ]
  61 );
  62
  63 __PACKAGE__->run_before(
  64   '_load_customer_vendor',
  65   only => [
  66     'edit',
  67     'show',
  68     'update',
  69     'ajaj_get_shipto',
  70     'ajaj_get_contact',
  71   ]
  72 );
  73
  74 # make sure this comes after _load_customer_vendor
  75 __PACKAGE__->run_before(
  76   '_check_customer_vendor_all_edit',
  77   only => [
  78     'edit',
  79     'show',
  80     'update',
  81     'delete',
  82     'save',
  83     'save_and_ap_transaction',
  84     'save_and_ar_transaction',
  85     'save_and_close',
  86     'save_and_invoice',
  87     'save_and_order',
  88     'save_and_quotation',
  89     'save_and_rfq',
  90     'delete',
  91     'delete_contact',
  92     'delete_shipto',
  93   ]
  94 );
  95
  96 __PACKAGE__->run_before(
  97   '_create_customer_vendor',
  98   only => [
  99     'add',
 100   ]
 101 );
 102
 103 __PACKAGE__->run_before('normalize_name');
 104
 105
 106 sub action_add {
 107   my ($self) = @_;
 108
 109   $self->_pre_render();
 110   $self->{cv}->assign_attributes(hourly_rate => $::instance_conf->get_customer_hourly_rate) if $self->{cv}->is_customer;
 111
 112   $self->render(
 113     'customer_vendor/form',
 114     title => ($self->is_vendor() ? $::locale->text('Add Vendor') : $::locale->text('Add Customer')),
 115     %{$self->{template_args}}
 116   );
 117 }
 118
 119 sub action_edit {
 120   my ($self) = @_;
 121
 122   $self->_pre_render();
 123   $self->render(
 124     'customer_vendor/form',
 125     title => ($self->is_vendor() ? $::locale->text('Edit Vendor') : $::locale->text('Edit Customer')),
 126     %{$self->{template_args}}
 127   );
 128 }
 129
 130 sub action_show {
 131   my ($self) = @_;
 132
 133   if ($::request->type eq 'json') {
 134     my $cv_hash;
 135     if (!$self->{cv}) {
 136       # TODO error
 137     } else {
 138       $cv_hash          = $self->{cv}->as_tree;
 139       $cv_hash->{cvars} = $self->{cv}->cvar_as_hashref;
 140     }
 141
 142     $self->render(\ SL::JSON::to_json($cv_hash), { layout => 0, type => 'json', process => 0 });
 143   }
 144 }
 145
 146 sub _save {
 147   my ($self) = @_;
 148
 149   my @errors = $self->{cv}->validate;
 150   if (@errors) {
 151     flash('error', @errors);
 152     $self->_pre_render();
 153     $self->render(
 154       'customer_vendor/form',
 155       title => ($self->is_vendor() ? t8('Edit Vendor') : t8('Edit Customer')),
 156       %{$self->{template_args}}
 157     );
 158     $::dispatcher->end_request;
 159   }
 160
 161   my $db = $self->{cv}->db;
 162
 163   $db->with_transaction(sub {
 164     my $cvs_by_nr;
 165     if ( $self->is_vendor() ) {
 166       if ( $self->{cv}->vendornumber ) {
 167         $cvs_by_nr = SL::DB::Manager::Vendor->get_all(query => [vendornumber => $self->{cv}->vendornumber]);
 168       }
 169     } else {
 170       if ( $self->{cv}->customernumber ) {
 171         $cvs_by_nr = SL::DB::Manager::Customer->get_all(query => [customernumber => $self->{cv}->customernumber]);
 172       }
 173     }
 174
 175     foreach my $entry (@{$cvs_by_nr}) {
 176       if( $entry->id != $self->{cv}->id ) {
 177         my $msg =
 178           $self->is_vendor() ? $::locale->text('This vendor number is already in use.') : $::locale->text('This customer number is already in use.');
 179
 180         $::form->error($msg);
 181       }
 182     }
 183
 184     $self->{cv}->save(cascade => 1);
 185
 186     $self->{contact}->cp_cv_id($self->{cv}->id);
 187     if( $self->{contact}->cp_name ne '' || $self->{contact}->cp_givenname ne '' ) {
 188       $self->{contact}->save(cascade => 1);
 189     }
 190
 191     if( $self->{note}->subject ne '' && $self->{note}->body ne '' ) {
 192
 193       if ( !$self->{note_followup}->follow_up_date ) {
 194         $::form->error($::locale->text('Date missing!'));
 195       }
 196
 197       $self->{note}->trans_id($self->{cv}->id);
 198       $self->{note}->save();
 199
 200       $self->{note_followup}->save();
 201
 202       $self->{note_followup_link}->follow_up_id($self->{note_followup}->id);
 203       $self->{note_followup_link}->trans_id($self->{cv}->id);
 204       $self->{note_followup_link}->save();
 205
 206       SL::Helper::Flash::flash_later('info', $::locale->text('Follow-Up saved.'));
 207     }
 208
 209     $self->{shipto}->trans_id($self->{cv}->id);
 210     if(any { $self->{shipto}->$_ ne '' } qw(shiptoname shiptodepartment_1 shiptodepartment_2 shiptostreet shiptozipcode shiptocity shiptocountry shiptogln shiptocontact shiptophone shiptofax shiptoemail)) {
 211       $self->{shipto}->save(cascade => 1);
 212     }
 213
 214     my $snumbers = $self->is_vendor() ? 'vendornumber_'. $self->{cv}->vendornumber : 'customernumber_'. $self->{cv}->customernumber;
 215     SL::DB::History->new(
 216       trans_id => $self->{cv}->id,
 217       snumbers => $snumbers,
 218       employee_id => SL::DB::Manager::Employee->current->id,
 219       addition => 'SAVED',
 220     )->save();
 221
 222     if ( $::form->{delete_notes} ) {
 223       foreach my $note_id (@{ $::form->{delete_notes} }) {
 224         my $note = SL::DB::Note->new(id => $note_id)->load();
 225         if ( $note->follow_up ) {
 226           if ( $note->follow_up->follow_up_link ) {
 227             $note->follow_up->follow_up_link->delete(cascade => 'delete');
 228           }
 229           $note->follow_up->delete(cascade => 'delete');
 230         }
 231         $note->delete(cascade => 'delete');
 232       }
 233     }
 234
 235     1;
 236   }) || die($db->error);
 237
 238 }
 239
 240 sub action_save {
 241   my ($self) = @_;
 242
 243   $self->_save();
 244
 245   my @redirect_params = (
 246     action => 'edit',
 247     id     => $self->{cv}->id,
 248     db     => ($self->is_vendor() ? 'vendor' : 'customer'),
 249   );
 250
 251   if ( $self->{contact}->cp_id ) {
 252     push(@redirect_params, contact_id => $self->{contact}->cp_id);
 253   }
 254
 255   if ( $self->{shipto}->shipto_id ) {
 256     push(@redirect_params, shipto_id => $self->{shipto}->shipto_id);
 257   }
 258
 259   $self->redirect_to(@redirect_params);
 260 }
 261
 262 sub action_save_and_close {
 263   my ($self) = @_;
 264
 265   $self->_save();
 266
 267   my $msg = $self->is_vendor() ? $::locale->text('Vendor saved') : $::locale->text('Customer saved');
 268   $::form->redirect($msg);
 269 }
 270
 271 sub _transaction {
 272   my ($self, $script) = @_;
 273
 274   $::auth->assert('gl_transactions | ap_transactions | ar_transactions'.
 275                     '| invoice_edit         | vendor_invoice_edit | ' .
 276                  ' request_quotation_edit | sales_quotation_edit | sales_order_edit    | purchase_order_edit');
 277
 278   $self->_save();
 279
 280   my $name = $::form->escape($self->{cv}->name, 1);
 281   my $db = $self->is_vendor() ? 'vendor' : 'customer';
 282   my $action = 'add';
 283
 284   if ($::instance_conf->get_feature_experimental_order && 'oe.pl' eq $script) {
 285     $script = 'controller.pl';
 286     $action = 'Order/' . $action;
 287   }
 288
 289   my $url = $self->url_for(
 290     controller => $script,
 291     action     => $action,
 292     vc         => $db,
 293     $db .'_id' => $self->{cv}->id,
 294     $db        => $name,
 295     type       => $::form->{type},
 296     callback   => $::form->{callback},
 297   );
 298
 299   print $::form->redirect_header($url);
 300 }
 301
 302 sub action_save_and_ar_transaction {
 303   my ($self) = @_;
 304
 305   $main::auth->assert('ar_transactions');
 306
 307   $self->_transaction('ar.pl');
 308 }
 309
 310 sub action_save_and_ap_transaction {
 311   my ($self) = @_;
 312
 313   $main::auth->assert('ap_transactions');
 314
 315   $self->_transaction('ap.pl');
 316 }
 317
 318 sub action_save_and_invoice {
 319   my ($self) = @_;
 320
 321   if ( $self->is_vendor() ) {
 322     $::auth->assert('vendor_invoice_edit');
 323   } else {
 324     $::auth->assert('invoice_edit');
 325   }
 326
 327   $::form->{type} = 'invoice';
 328   $self->_transaction($self->is_vendor() ? 'ir.pl' : 'is.pl');
 329 }
 330
 331 sub action_save_and_order {
 332   my ($self) = @_;
 333
 334   if ( $self->is_vendor() ) {
 335     $::auth->assert('purchase_order_edit');
 336   } else {
 337     $::auth->assert('sales_order_edit');
 338   }
 339
 340   $::form->{type} = $self->is_vendor() ? 'purchase_order' : 'sales_order';
 341   $self->_transaction('oe.pl');
 342 }
 343
 344 sub action_save_and_rfq {
 345   my ($self) = @_;
 346
 347   $::auth->assert('request_quotation_edit');
 348
 349   $::form->{type} = 'request_quotation';
 350   $self->_transaction('oe.pl');
 351 }
 352
 353 sub action_save_and_quotation {
 354   my ($self) = @_;
 355
 356   $::auth->assert('sales_quotation_edit');
 357
 358   $::form->{type} = 'sales_quotation';
 359   $self->_transaction('oe.pl');
 360 }
 361
 362 sub action_delete {
 363   my ($self) = @_;
 364
 365   my $db = $self->{cv}->db;
 366
 367   if( !$self->is_orphaned() ) {
 368     $self->action_edit();
 369   } else {
 370
 371     $db->with_transaction(sub {
 372       $self->{cv}->delete(cascade => 1);
 373
 374       my $snumbers = $self->is_vendor() ? 'vendornumber_'. $self->{cv}->vendornumber : 'customernumber_'. $self->{cv}->customernumber;
 375       SL::DB::History->new(
 376         trans_id => $self->{cv}->id,
 377         snumbers => $snumbers,
 378         employee_id => SL::DB::Manager::Employee->current->id,
 379         addition => 'DELETED',
 380       )->save();
 381     }) || die($db->error);
 382
 383     my $msg = $self->is_vendor() ? $::locale->text('Vendor deleted!') : $::locale->text('Customer deleted!');
 384     $::form->redirect($msg);
 385   }
 386
 387 }
 388
 389
 390 sub action_delete_contact {
 391   my ($self) = @_;
 392
 393   my $db = $self->{contact}->db;
 394
 395   if ( !$self->{contact}->cp_id ) {
 396     SL::Helper::Flash::flash('error', $::locale->text('No contact selected to delete'));
 397   } else {
 398
 399     $db->with_transaction(sub {
 400       if ( $self->{contact}->used ) {
 401         $self->{contact}->detach();
 402         $self->{contact}->save();
 403         SL::Helper::Flash::flash('info', $::locale->text('Contact is in use and was flagged invalid.'));
 404       } else {
 405         $self->{contact}->delete(cascade => 1);
 406         SL::Helper::Flash::flash('info', $::locale->text('Contact deleted.'));
 407       }
 408
 409       1;
 410     }) || die($db->error);
 411
 412     $self->{contact} = $self->_new_contact_object;
 413   }
 414
 415   $self->action_edit();
 416 }
 417
 418 sub action_delete_shipto {
 419   my ($self) = @_;
 420
 421   my $db = $self->{shipto}->db;
 422
 423   if ( !$self->{shipto}->shipto_id ) {
 424     SL::Helper::Flash::flash('error', $::locale->text('No shipto selected to delete'));
 425   } else {
 426
 427     $db->with_transaction(sub {
 428       if ( $self->{shipto}->used ) {
 429         $self->{shipto}->detach();
 430         $self->{shipto}->save(cascade => 1);
 431         SL::Helper::Flash::flash('info', $::locale->text('Shipto is in use and was flagged invalid.'));
 432       } else {
 433         $self->{shipto}->delete(cascade => 1);
 434         SL::Helper::Flash::flash('info', $::locale->text('Shipto deleted.'));
 435       }
 436
 437       1;
 438     }) || die($db->error);
 439
 440     $self->{shipto} = SL::DB::Shipto->new();
 441   }
 442
 443   $self->action_edit();
 444 }
 445
 446
 447 sub action_search {
 448   my ($self) = @_;
 449
 450   my @url_params = (
 451     controller => 'ct.pl',
 452     action => 'search',
 453     db => $self->is_vendor() ? 'vendor' : 'customer',
 454   );
 455
 456   if ( $::form->{callback} ) {
 457     push(@url_params, callback => $::form->{callback});
 458   }
 459
 460   $self->redirect_to(@url_params);
 461 }
 462
 463
 464 sub action_search_contact {
 465   my ($self) = @_;
 466
 467   my $url = 'ct.pl?action=search_contact&db=customer';
 468
 469   if ( $::form->{callback} ) {
 470     $url .= '&callback='. $::form->escape($::form->{callback});
 471   }
 472
 473   print $::form->redirect_header($url);
 474 }
 475
 476 sub action_get_delivery {
 477   my ($self) = @_;
 478
 479   $::auth->assert('sales_all_edit');
 480
 481   my $dbh = $::form->get_standard_dbh();
 482
 483   my ($arap, $db, $qty_sign);
 484   if ( $self->is_vendor() ) {
 485     $arap = 'ap';
 486     $db = 'vendor';
 487     $qty_sign = ' * -1 AS qty';
 488   } else {
 489     $arap = 'ar';
 490     $db = 'customer';
 491     $qty_sign = '';
 492   }
 493
 494   my $where = ' WHERE 1=1';
 495   my @values;
 496
 497   if ( !$self->is_vendor() && $::form->{shipto_id} && $::form->{shipto_id} ne 'all' ) {
 498     $where .= " AND ${arap}.shipto_id = ?";
 499     push(@values, $::form->{shipto_id});
 500   } else {
 501     $where .= " AND ${arap}.${db}_id = ?";
 502     push(@values, $::form->{id});
 503   }
 504
 505   if ( $::form->{delivery_from} ) {
 506     $where .= " AND ${arap}.transdate >= ?";
 507     push(@values, conv_date($::form->{delivery_from}));
 508   }
 509
 510   if ( $::form->{delivery_to} ) {
 511     $where .= " AND ${arap}.transdate <= ?";
 512     push(@values, conv_date($::form->{delivery_to}));
 513   }
 514
 515   my $query =
 516     "SELECT
 517        s.shiptoname,
 518        i.qty ${qty_sign},
 519        ${arap}.id,
 520        ${arap}.transdate,
 521        ${arap}.invnumber,
 522        ${arap}.ordnumber,
 523        i.description,
 524        i.unit,
 525        i.sellprice,
 526        oe.id AS oe_id,
 527        invoice
 528      FROM ${arap}
 529
 530      LEFT JOIN shipto s
 531       ON ". ($arap eq 'ar' ? '(ar.shipto_id = s.shipto_id) ' : '(ap.id = s.trans_id) ') ."
 532
 533      LEFT JOIN invoice i
 534        ON ${arap}.id = i.trans_id
 535
 536      LEFT JOIN parts p
 537        ON p.id = i.parts_id
 538
 539      LEFT JOIN oe
 540        ON (oe.ordnumber = ${arap}.ordnumber AND NOT ${arap}.ordnumber = ''
 541            AND ". ($arap eq 'ar' ? 'oe.customer_id IS NOT NULL' : 'oe.vendor_id IS NOT NULL') ." )
 542
 543      ${where}
 544      ORDER BY ${arap}.transdate DESC LIMIT 15";
 545
 546   $self->{delivery} = selectall_hashref_query($::form, $dbh, $query, @values);
 547
 548   $self->render('customer_vendor/get_delivery', { layout => 0 });
 549 }
 550
 551 sub action_ajaj_get_shipto {
 552   my ($self) = @_;
 553
 554   my $data = {};
 555   $data->{shipto} = {
 556     map(
 557       {
 558         my $name = 'shipto'. $_;
 559         $name => $self->{shipto}->$name;
 560       }
 561       qw(_id name department_1 department_2 street zipcode city gln country contact phone fax email)
 562     )
 563   };
 564
 565   $data->{shipto_cvars} = $self->_prepare_cvar_configs_for_ajaj($self->{shipto}->cvars_by_config);
 566
 567   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 568 }
 569
 570 sub action_ajaj_get_contact {
 571   my ($self) = @_;
 572
 573   my $data;
 574
 575   $data->{contact} = {
 576     map(
 577       {
 578         my $name = 'cp_'. $_;
 579
 580         if ( $_ eq 'birthday' && $self->{contact}->$name ) {
 581           $name => $self->{contact}->$name->to_lxoffice;
 582         } else {
 583           $name => $self->{contact}->$name;
 584         }
 585       }
 586       qw(
 587         id gender abteilung title position givenname name email phone1 phone2 fax mobile1 mobile2
 588         satphone satfax project street zipcode city privatphone privatemail birthday main
 589       )
 590     )
 591   };
 592
 593   $data->{contact_cvars} = $self->_prepare_cvar_configs_for_ajaj($self->{contact}->cvars_by_config);
 594
 595   # avoid two or more main_cp
 596   my $has_main_cp = grep { $_->cp_main == 1 } @{ $self->{cv}->contacts };
 597   $data->{contact}->{disable_cp_main} = 1 if ($has_main_cp && !$data->{contact}->{cp_main});
 598
 599   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 600 }
 601
 602 sub action_ajaj_autocomplete {
 603   my ($self, %params) = @_;
 604
 605   my ($model, $manager, $number, $matches);
 606
 607   # first see if this is customer or vendor picking
 608   if ($::form->{type} eq 'customer') {
 609      $model   = $self->customer_models;
 610      $manager = 'SL::DB::Manager::Customer';
 611      $number  = 'customernumber';
 612   } elsif ($::form->{type} eq 'vendor')  {
 613      $model   = $self->vendor_models;
 614      $manager = 'SL::DB::Manager::Vendor';
 615      $number  = 'vendornumber';
 616   } else {
 617      die "unknown type $::form->{type}";
 618   }
 619
 620   # if someone types something, and hits enter, assume he entered the full name.
 621   # if something matches, treat that as sole match
 622   # unfortunately get_models can't do more than one per package atm, so we d it
 623   # the oldfashioned way.
 624   if ($::form->{prefer_exact}) {
 625     my $exact_matches;
 626     if (1 == scalar @{ $exact_matches = $manager->get_all(
 627       query => [
 628         obsolete => 0,
 629         (salesman_id => SL::DB::Manager::Employee->current->id) x !$::auth->assert('customer_vendor_all_edit', 1),
 630         or => [
 631           name    => { ilike => $::form->{filter}{'all:substr:multi::ilike'} },
 632           $number => { ilike => $::form->{filter}{'all:substr:multi::ilike'} },
 633         ]
 634       ],
 635       limit => 2,
 636     ) }) {
 637       $matches = $exact_matches;
 638     }
 639   }
 640
 641   $matches //= $model->get;
 642
 643   my @hashes = map {
 644    +{
 645      value       => $_->displayable_name,
 646      label       => $_->displayable_name,
 647      id          => $_->id,
 648      $number     => $_->$number,
 649      name        => $_->name,
 650      type        => $::form->{type},
 651      cvars       => { map { ($_->config->name => { value => $_->value_as_text, is_valid => $_->is_valid }) } @{ $_->cvars_by_config } },
 652     }
 653   } @{ $matches };
 654
 655   $self->render(\ SL::JSON::to_json(\@hashes), { layout => 0, type => 'json', process => 0 });
 656 }
 657
 658 sub action_test_page {
 659   $_[0]->render('customer_vendor/test_page');
 660 }
 661
 662 sub is_vendor {
 663   return $::form->{db} eq 'vendor';
 664 }
 665
 666 sub is_customer {
 667   return $::form->{db} eq 'customer';
 668 }
 669
 670 sub is_orphaned {
 671   my ($self) = @_;
 672
 673   if ( defined($self->{_is_orphaned}) ) {
 674     return $self->{_is_orphaned};
 675   }
 676
 677   my $arap      = $self->is_vendor ? 'ap' : 'ar';
 678   my $num_args  = 3;
 679
 680   my $cv = $self->is_vendor ? 'vendor' : 'customer';
 681
 682   my $query =
 683    'SELECT a.id
 684     FROM '. $arap .' AS a
 685     JOIN '. $cv .' ct ON (a.'. $cv .'_id = ct.id)
 686     WHERE ct.id = ?
 687
 688     UNION
 689
 690     SELECT a.id
 691     FROM oe a
 692     JOIN '. $cv .' ct ON (a.'. $cv .'_id = ct.id)
 693     WHERE ct.id = ?
 694
 695     UNION
 696
 697     SELECT a.id
 698     FROM delivery_orders a
 699     JOIN '. $cv .' ct ON (a.'. $cv .'_id = ct.id)
 700     WHERE ct.id = ?';
 701
 702
 703   if ( $self->is_vendor ) {
 704     $query .=
 705      ' UNION
 706       SELECT 1 FROM makemodel mm WHERE mm.make = ?';
 707     $num_args++;
 708   }
 709
 710   my ($dummy) = selectrow_query($::form, $::form->get_standard_dbh(), $query, (conv_i($self->{cv}->id)) x $num_args);
 711
 712   return $self->{_is_orphaned} = !$dummy;
 713 }
 714
 715 sub _copy_form_to_cvars {
 716   my ($self, %params) = @_;
 717
 718   foreach my $cvar (@{ $params{target}->cvars_by_config }) {
 719     my $value = $params{source}->{$cvar->config->name};
 720     $value    = $::form->parse_amount(\%::myconfig, $value) if $cvar->config->type eq 'number';
 721
 722     $cvar->value($value);
 723   }
 724 }
 725
 726 sub _instantiate_args {
 727   my ($self) = @_;
 728
 729   my $curr_employee = SL::DB::Manager::Employee->current;
 730
 731   if ( $::form->{cv}->{id} ) {
 732     if ( $self->is_vendor() ) {
 733       $self->{cv} = SL::DB::Vendor->new(id => $::form->{cv}->{id})->load();
 734     } else {
 735       $self->{cv} = SL::DB::Customer->new(id => $::form->{cv}->{id})->load();
 736     }
 737   } else {
 738     $self->{cv} = $self->_new_customer_vendor_object;
 739   }
 740   $self->{cv}->assign_attributes(%{$::form->{cv}});
 741
 742   if ( $self->is_customer() && $::form->{cv}->{taxincluded_checked} eq '' ) {
 743     $self->{cv}->taxincluded_checked(undef);
 744   }
 745
 746   $self->{cv}->hourly_rate($::instance_conf->get_customer_hourly_rate) if $self->is_customer && !$self->{cv}->hourly_rate;
 747
 748   if ( $::form->{note}->{id} ) {
 749     $self->{note} = SL::DB::Note->new(id => $::form->{note}->{id})->load();
 750     $self->{note_followup} = $self->{note}->follow_up;
 751     $self->{note_followup_link} = $self->{note_followup}->follow_up_link;
 752   } else {
 753     $self->{note} = SL::DB::Note->new();
 754     $self->{note_followup} = SL::DB::FollowUp->new();
 755     $self->{note_followup_link} = SL::DB::FollowUpLink->new();
 756   }
 757
 758   $self->{note}->assign_attributes(%{$::form->{note}});
 759   $self->{note}->created_by($curr_employee->id);
 760   $self->{note}->trans_module('ct');
 761
 762   $self->{note_followup}->assign_attributes(%{$::form->{note_followup}});
 763   $self->{note_followup}->note($self->{note});
 764   $self->{note_followup}->created_by($curr_employee->id);
 765
 766   $self->{note_followup_link}->trans_type($self->is_vendor() ? 'vendor' : 'customer');
 767   $self->{note_followup_link}->trans_info($self->{cv}->name);
 768
 769   if ( $::form->{shipto}->{shipto_id} ) {
 770     $self->{shipto} = SL::DB::Shipto->new(shipto_id => $::form->{shipto}->{shipto_id})->load();
 771   } else {
 772     $self->{shipto} = SL::DB::Shipto->new();
 773   }
 774   $self->{shipto}->assign_attributes(%{$::form->{shipto}});
 775   $self->{shipto}->module('CT');
 776
 777   if ( $::form->{contact}->{cp_id} ) {
 778     $self->{contact} = SL::DB::Contact->new(cp_id => $::form->{contact}->{cp_id})->load();
 779   } else {
 780     $self->{contact} = $self->_new_contact_object;
 781   }
 782   $self->{contact}->assign_attributes(%{$::form->{contact}});
 783
 784   $self->_copy_form_to_cvars(target => $self->{cv},      source => $::form->{cv_cvars});
 785   $self->_copy_form_to_cvars(target => $self->{contact}, source => $::form->{contact_cvars});
 786   $self->_copy_form_to_cvars(target => $self->{shipto},  source => $::form->{shipto_cvars});
 787 }
 788
 789 sub _load_customer_vendor {
 790   my ($self) = @_;
 791
 792   if ( $self->is_vendor() ) {
 793     $self->{cv} = SL::DB::Vendor->new(id => $::form->{id})->load();
 794   } else {
 795     $self->{cv} = SL::DB::Customer->new(id => $::form->{id})->load();
 796   }
 797
 798   if ( $::form->{note_id} ) {
 799     $self->{note} = SL::DB::Note->new(id => $::form->{note_id})->load();
 800     $self->{note_followup} = $self->{note}->follow_up;
 801     $self->{note_followup_link} = $self->{note_followup}->follow_up_link;
 802   } else {
 803     $self->{note} = SL::DB::Note->new();
 804     $self->{note_followup} = SL::DB::FollowUp->new();
 805     $self->{note_followup_link} = SL::DB::FollowUpLink->new();
 806   }
 807
 808   if ( $::form->{shipto_id} ) {
 809     $self->{shipto} = SL::DB::Shipto->new(shipto_id => $::form->{shipto_id})->load();
 810
 811     if ( $self->{shipto}->trans_id != $self->{cv}->id ) {
 812       die($::locale->text('Error'));
 813     }
 814   } else {
 815     $self->{shipto} = SL::DB::Shipto->new();
 816   }
 817
 818   if ( $::form->{contact_id} ) {
 819     $self->{contact} = SL::DB::Contact->new(cp_id => $::form->{contact_id})->load();
 820
 821     if ( $self->{contact}->cp_cv_id != $self->{cv}->id ) {
 822       die($::locale->text('Error'));
 823     }
 824   } else {
 825     $self->{contact} = $self->_new_contact_object;
 826   }
 827 }
 828
 829 sub _check_customer_vendor_all_edit {
 830   my ($self) = @_;
 831
 832   unless ($::auth->assert('customer_vendor_all_edit', 1)) {
 833     die($::locale->text("You don't have the rights to edit this customer.") . "\n")
 834       if $self->{cv}->is_customer and
 835          SL::DB::Manager::Employee->current->id != $self->{cv}->salesman_id;
 836   };
 837 };
 838
 839 sub _create_customer_vendor {
 840   my ($self) = @_;
 841
 842   $self->{cv} = $self->_new_customer_vendor_object;
 843   $self->{cv}->currency_id($::instance_conf->get_currency_id());
 844
 845   $self->{note} = SL::DB::Note->new();
 846
 847   $self->{note_followup} = SL::DB::FollowUp->new();
 848
 849   $self->{shipto} = SL::DB::Shipto->new();
 850
 851   $self->{contact} = $self->_new_contact_object;
 852 }
 853
 854 sub _pre_render {
 855   my ($self) = @_;
 856
 857   my $dbh = $::form->get_standard_dbh();
 858
 859   my $query;
 860
 861   $self->{all_business} = SL::DB::Manager::Business->get_all();
 862
 863   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 864
 865   $query =
 866     'SELECT DISTINCT(greeting)
 867      FROM customer
 868      WHERE greeting IS NOT NULL AND greeting != \'\'
 869      UNION
 870        SELECT DISTINCT(greeting)
 871        FROM vendor
 872        WHERE greeting IS NOT NULL AND greeting != \'\'
 873      ORDER BY greeting';
 874   $self->{all_greetings} = [
 875     map(
 876       { $_->{greeting}; }
 877       selectall_hashref_query($::form, $dbh, $query)
 878     )
 879   ];
 880
 881   $query =
 882     'SELECT DISTINCT(cp_title) AS title
 883      FROM contacts
 884      WHERE cp_title IS NOT NULL AND cp_title != \'\'
 885      ORDER BY cp_title';
 886   $self->{all_titles} = [
 887     map(
 888       { $_->{title}; }
 889       selectall_hashref_query($::form, $dbh, $query)
 890     )
 891   ];
 892
 893   $self->{all_currencies} = SL::DB::Manager::Currency->get_all();
 894
 895   $self->{all_languages} = SL::DB::Manager::Language->get_all();
 896
 897   $self->{all_taxzones} = SL::DB::Manager::TaxZone->get_all_sorted();
 898
 899   if ( $::instance_conf->get_vertreter() ) {
 900     $query =
 901       'SELECT id
 902        FROM business
 903        WHERE salesman';
 904     my $business_ids = [
 905       map(
 906         { $_->{id}; }
 907         selectall_hashref_query($::form, $dbh, $query)
 908       )
 909     ];
 910
 911     if ( $business_ids->[0] ) {
 912       $self->{all_salesman_customers} = SL::DB::Manager::Customer->get_all(query => [business_id => $business_ids]);
 913     } else {
 914       $self->{all_salesman_customers} = [];
 915     }
 916   } else {
 917     $self->{all_salesmen} = SL::DB::Manager::Employee->get_all(query => [ or => [ id => $self->{cv}->salesman_id,  deleted => 0 ] ]);
 918   }
 919
 920   $self->{all_payment_terms} = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id       => $self->{cv}->payment_id,
 921                                                                                                obsolete => 0 ] ]);
 922
 923   $self->{all_delivery_terms} = SL::DB::Manager::DeliveryTerm->get_all();
 924
 925   if ($self->{cv}->is_customer) {
 926     $self->{all_pricegroups} = SL::DB::Manager::Pricegroup->get_all_sorted(query => [ or => [ id => $self->{cv}->pricegroup_id, obsolete => 0 ] ]);
 927   }
 928
 929   $query =
 930     'SELECT DISTINCT(cp_abteilung) AS department
 931      FROM contacts
 932      WHERE cp_abteilung IS NOT NULL AND cp_abteilung != \'\'
 933      ORDER BY cp_abteilung';
 934   $self->{all_departments} = [
 935     map(
 936       { $_->{department}; }
 937       selectall_hashref_query($::form, $dbh, $query)
 938     )
 939   ];
 940
 941   $self->{contacts} = $self->{cv}->contacts;
 942   $self->{contacts} ||= [];
 943
 944   $self->{shiptos} = $self->{cv}->shipto;
 945   $self->{shiptos} ||= [];
 946
 947   $self->{notes} = SL::DB::Manager::Note->get_all(
 948     query => [
 949       trans_id => $self->{cv}->id,
 950       trans_module => 'ct',
 951     ],
 952     with_objects => ['follow_up'],
 953   );
 954
 955   if ( $self->is_vendor()) {
 956     $self->{open_items} = SL::DB::Manager::PurchaseInvoice->get_all_count(
 957       query => [
 958         vendor_id => $self->{cv}->id,
 959         paid => {lt_sql => 'amount'},
 960       ],
 961     );
 962   } else {
 963     $self->{open_items} = SL::DB::Manager::Invoice->get_all_count(
 964       query => [
 965         customer_id => $self->{cv}->id,
 966         paid => {lt_sql => 'amount'},
 967       ],
 968     );
 969   }
 970
 971   if ( $self->is_vendor() ) {
 972     $self->{open_orders} = SL::DB::Manager::Order->get_all_count(
 973       query => [
 974         vendor_id => $self->{cv}->id,
 975         closed => 'F',
 976       ],
 977     );
 978   } else {
 979     $self->{open_orders} = SL::DB::Manager::Order->get_all_count(
 980       query => [
 981         customer_id => $self->{cv}->id,
 982         closed => 'F',
 983       ],
 984     );
 985   }
 986   $self->{template_args} ||= {};
 987
 988   $::request->{layout}->add_javascripts('kivi.CustomerVendor.js');
 989   $::request->{layout}->add_javascripts('kivi.File.js');
 990   $::request->{layout}->add_javascripts('kivi.CustomerVendorTurnover.js');
 991
 992   $self->_setup_form_action_bar;
 993 }
 994
 995 sub _setup_form_action_bar {
 996   my ($self) = @_;
 997
 998   for my $bar ($::request->layout->get('actionbar')) {
 999     $bar->add(
1000       combobox => [
1001         action => [
1002           t8('Save'),
1003           submit    => [ '#form', { action => "CustomerVendor/save" } ],
1004           checks    => [ 'check_taxzone_and_ustid' ],
1005           accesskey => 'enter',
1006         ],
1007         action => [
1008           t8('Save and Close'),
1009           submit => [ '#form', { action => "CustomerVendor/save_and_close" } ],
1010           checks => [ 'check_taxzone_and_ustid' ],
1011         ],
1012       ], # end of combobox "Save"
1013
1014       combobox => [
1015         action => [ t8('Workflow') ],
1016         (action => [
1017           t8('Save and AP Transaction'),
1018           submit => [ '#form', { action => "CustomerVendor/save_and_ap_transaction" } ],
1019           checks => [ 'check_taxzone_and_ustid' ],
1020         ]) x !!$self->is_vendor,
1021         (action => [
1022           t8('Save and AR Transaction'),
1023           submit => [ '#form', { action => "CustomerVendor/save_and_ar_transaction" } ],
1024           checks => [ 'check_taxzone_and_ustid' ],
1025         ]) x !$self->is_vendor,
1026         action => [
1027           t8('Save and Invoice'),
1028           submit => [ '#form', { action => "CustomerVendor/save_and_invoice" } ],
1029           checks => [ 'check_taxzone_and_ustid' ],
1030         ],
1031         action => [
1032           t8('Save and Order'),
1033           submit => [ '#form', { action => "CustomerVendor/save_and_order" } ],
1034           checks => [ 'check_taxzone_and_ustid' ],
1035         ],
1036         (action => [
1037           t8('Save and RFQ'),
1038           submit => [ '#form', { action => "CustomerVendor/save_and_rfq" } ],
1039           checks => [ 'check_taxzone_and_ustid' ],
1040         ]) x !!$self->is_vendor,
1041         (action => [
1042           t8('Save and Quotation'),
1043           submit => [ '#form', { action => "CustomerVendor/save_and_quotation" } ],
1044           checks => [ 'check_taxzone_and_ustid' ],
1045         ]) x !$self->is_vendor,
1046       ], # end of combobox "Workflow"
1047
1048       action => [
1049         t8('Delete'),
1050         submit   => [ '#form', { action => "CustomerVendor/delete" } ],
1051         confirm  => t8('Do you really want to delete this object?'),
1052         disabled => !$self->{cv}->id    ? t8('This object has not been saved yet.')
1053                   : !$self->is_orphaned ? t8('This object has already been used.')
1054                   :                       undef,
1055       ],
1056
1057       'separator',
1058
1059       action => [
1060         t8('History'),
1061         call     => [ 'kivi.CustomerVendor.showHistoryWindow', $self->{cv}->id ],
1062         disabled => !$self->{cv}->id ? t8('This object has not been saved yet.') : undef,
1063       ],
1064     );
1065   }
1066 }
1067
1068 sub _prepare_cvar_configs_for_ajaj {
1069   my ($self, $cvars) = @_;
1070
1071   return {
1072     map {
1073       my $cvar   = $_;
1074       my $result = { type => $cvar->config->type };
1075
1076       if ($cvar->config->type eq 'number') {
1077         $result->{value} = $::form->format_amount(\%::myconfig, $cvar->value, -2);
1078
1079       } elsif ($result->{type} eq 'date') {
1080         $result->{value} = $cvar->value ? $cvar->value->to_kivitendo : undef;
1081
1082       } elsif ($result->{type} =~ m{customer|vendor|part}) {
1083         my $object       = $cvar->value;
1084         my $method       = $result->{type} eq 'part' ? 'description' : 'name';
1085
1086         $result->{id}    = int($cvar->number_value) || undef;
1087         $result->{value} = $object ? $object->$method // '' : '';
1088
1089       } else {
1090         $result->{value} = $cvar->value;
1091       }
1092
1093       ( $cvar->config->name => $result )
1094
1095     } grep { $_->is_valid } @{ $cvars }
1096   };
1097 }
1098
1099 sub normalize_name {
1100   my ($self) = @_;
1101
1102   # check if feature is enabled (select normalize_vc_names from defaults)
1103   return unless ($::instance_conf->get_normalize_vc_names);
1104
1105   return unless $self->{cv};
1106   my $name = $self->{cv}->name;
1107   $name =~ s/\s+$//;
1108   $name =~ s/^\s+//;
1109   $name =~ s/\s+/ /g;
1110   $self->{cv}->name($name);
1111 }
1112
1113 sub home_address_for_google_maps {
1114   my ($self)  = @_;
1115
1116   my $address = $::instance_conf->get_address // '';
1117   $address    =~ s{^\s+|\s+$|\r+}{}g;
1118   $address    =~ s{\n+}{,}g;
1119   $address    =~ s{\s+}{ }g;
1120
1121   return $address;
1122 }
1123
1124 sub init_customer_models {
1125   my ($self) = @_;
1126
1127   SL::Controller::Helper::GetModels->new(
1128     controller   => $self,
1129     model        => 'Customer',
1130     sorted => {
1131       _default  => {
1132         by => 'customernumber',
1133         dir  => 1,
1134       },
1135       customernumber => t8('Customer Number'),
1136     },
1137     query => [
1138      ( salesman_id => SL::DB::Manager::Employee->current->id) x !$::auth->assert('customer_vendor_all_edit', 1),
1139     ],
1140   );
1141 }
1142
1143 sub init_vendor_models {
1144   my ($self) = @_;
1145
1146   SL::Controller::Helper::GetModels->new(
1147     controller => $self,
1148     model      => 'Vendor',
1149     sorted => {
1150       _default  => {
1151         by => 'vendornumber',
1152         dir  => 1,
1153       },
1154       vendornumber => t8('Vendor Number'),
1155     },
1156   );
1157 }
1158
1159 sub _new_customer_vendor_object {
1160   my ($self) = @_;
1161
1162   my $class  = 'SL::DB::' . ($self->is_vendor ? 'Vendor' : 'Customer');
1163   return $class->new(
1164     contacts         => [],
1165     shipto           => [],
1166     custom_variables => [],
1167   );
1168 }
1169
1170 sub _new_contact_object {
1171   my ($self) = @_;
1172
1173   return SL::DB::Contact->new(custom_variables => []);
1174 }
1175
1176 1;