SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::DB::CsvImportReport;
   8 use SL::DB::Unit;
   9 use SL::DB::Helper::Paginated ();
  10 use SL::Helper::Flash;
  11 use SL::Locale::String;
  12 use SL::SessionFile;
  13 use SL::Controller::CsvImport::Contact;
  14 use SL::Controller::CsvImport::CustomerVendor;
  15 use SL::Controller::CsvImport::Part;
  16 use SL::Controller::CsvImport::Inventory;
  17 use SL::Controller::CsvImport::Shipto;
  18 use SL::Controller::CsvImport::Project;
  19 use SL::Controller::CsvImport::Order;
  20 use SL::JSON;
  21 use SL::BackgroundJob::CsvImport;
  22 use SL::System::TaskServer;
  23
  24 use List::MoreUtils qw(none);
  25 use List::Util qw(min);
  26
  27 use parent qw(SL::Controller::Base);
  28
  29 use Rose::Object::MakeMethods::Generic
  30 (
  31  scalar                  => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  32                                  import_status errors headers raw_data_headers info_headers data num_imported num_importable displayable_columns file all_taxzones) ],
  33  'scalar --get_set_init' => [ qw(worker task_server) ],
  34  'array'                 => [
  35    progress_tracker     => { },
  36    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  37  ],
  38 );
  39
  40 __PACKAGE__->run_before('check_auth');
  41 __PACKAGE__->run_before('ensure_form_structure');
  42 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  43 __PACKAGE__->run_before('load_all_profiles');
  44 __PACKAGE__->run_before('check_task_server');
  45
  46 __PACKAGE__->run_after('cleanup_reports');
  47
  48 #
  49 # actions
  50 #
  51
  52 sub action_new {
  53   my ($self) = @_;
  54
  55   $self->load_default_profile unless $self->profile;
  56   $self->render_inputs;
  57 }
  58
  59 sub action_test {
  60   my ($self) = @_;
  61   $self->test_and_import_deferred(test => 1);
  62 }
  63
  64 sub action_import {
  65   my $self = shift;
  66   $self->test_and_import_deferred(test => 0);
  67 }
  68
  69 sub action_save {
  70   my ($self) = @_;
  71
  72   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  73   $self->profile->save;
  74
  75   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  76   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  77 }
  78
  79 sub action_destroy {
  80   my $self = shift;
  81
  82   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  83   $profile->delete(cascade => 1);
  84
  85   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  86   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  87 }
  88
  89 sub action_result {
  90   my $self = shift;
  91
  92   # load resultobject
  93   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
  94
  95   my $data = $self->{background_job}->data_as_hash;
  96
  97   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
  98
  99   $self->profile($profile);
 100
 101   if ($data->{errors} and my $first_error =  $data->{errors}->[0]) {
 102     flash('error', $::locale->text('There was an error parsing the csv file: #1 in line #2.', $first_error->[2], $first_error->[0]));
 103   }
 104
 105   if ($data->{progress}{finished} || $data->{errors}) {
 106     $self->render('csv_import/_deferred_report', { layout => 0 });
 107   } else {
 108     if (!$self->task_server->is_running) {
 109       $self->task_server->start;
 110       $self->{status_text} = t8('Task Server is not running, starting it now. If this does not change, please check your task server config');
 111     } elsif (my $phase = $data->{progress}{phase}) {
 112       $self->{status_text} = "$data->{progress}{plan}{$phase} / $data->{progress}{num_phases} " . t8($phase);
 113     } else {
 114       $self->{status_text} = t8('Import not started yet, please wait...');
 115     }
 116
 117     $self->render('csv_import/_deferred_results', { layout => 0 });
 118   }
 119 }
 120
 121 sub action_download_sample {
 122   my $self = shift;
 123
 124   $self->profile_from_form;
 125   $self->setup_help;
 126
 127   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 128   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 129   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 130
 131   if ($self->worker->is_multiplexed) {
 132     foreach my $p (@{ $self->worker->profile }) {
 133       $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns->{$p->{row_ident}} } ]);
 134       $file->fh->print("\r\n");
 135     }
 136     foreach my $p (@{ $self->worker->profile }) {
 137       $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns->{$p->{row_ident}} } ]);
 138       $file->fh->print("\r\n");
 139     }
 140   } else {
 141     $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 142     $file->fh->print("\r\n");
 143     $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 144     $file->fh->print("\r\n");
 145   }
 146
 147   $file->fh->close;
 148
 149   $self->send_file($file->file_name, name => $file_name);
 150 }
 151
 152 sub action_report {
 153   my ($self, %params) = @_;
 154
 155   my $report_id = $params{report_id} || $::form->{id};
 156
 157   $self->{report}      = SL::DB::Manager::CsvImportReport->find_by(id => $report_id);
 158
 159   if (!$self->{report}) {
 160     $::form->error(t8('No report with id #1', $report_id));
 161   }
 162   my $num_rows         = $self->{report}->numrows;
 163   my $num_cols         = SL::DB::Manager::CsvImportReportRow->get_all_count(query => [ csv_import_report_id => $report_id, row => 0 ]);
 164
 165   # manual paginating, yuck
 166   my $page = $::form->{page} || 1;
 167   my $pages = {};
 168   $pages->{per_page}        = $::form->{per_page} || 20;
 169   $pages->{max}             = SL::DB::Helper::Paginated::ceil($num_rows, $pages->{per_page}) || 1;
 170   $pages->{page}             = $page < 1 ? 1
 171                             : $page > $pages->{max} ? $pages->{max}
 172                             : $page;
 173   $pages->{common}          = [ grep { $_->{visible} } @{ SL::DB::Helper::Paginated::make_common_pages($pages->{page}, $pages->{max}) } ];
 174
 175   $self->{report_numheaders} = $self->{report}->numheaders;
 176   my $first_row_header = 0;
 177   my $last_row_header  = $self->{report_numheaders} - 1;
 178   my $first_row_data   = $pages->{per_page} * ($pages->{page}-1) + $self->{report_numheaders};
 179   my $last_row_data    = min($pages->{per_page} * $pages->{page}, $num_rows) + $self->{report_numheaders} - 1;
 180   $self->{display_rows} = [
 181     $first_row_header
 182       ..
 183     $last_row_header,
 184     $first_row_data
 185       ..
 186     $last_row_data
 187   ];
 188
 189   my @query = (
 190     csv_import_report_id => $report_id,
 191     or => [
 192       and => [
 193         row => { ge => $first_row_header },
 194         row => { le => $last_row_header },
 195       ],
 196       and => [
 197         row => { ge => $first_row_data },
 198         row => { le => $last_row_data },
 199       ]
 200     ]
 201   );
 202
 203   my $rows             = SL::DB::Manager::CsvImportReportRow->get_all(query => \@query);
 204   my $status           = SL::DB::Manager::CsvImportReportStatus->get_all(query => \@query);
 205
 206   $self->{report_rows}   = $self->{report}->folded_rows(rows => $rows);
 207   $self->{report_status} = $self->{report}->folded_status(status => $status);
 208   $self->{pages} = $pages;
 209   $self->{base_url} = $self->url_for(action => 'report', id => $report_id, no_layout => $params{no_layout} || $::form->{no_layout} );
 210
 211   $self->render('csv_import/report', { layout => !($params{no_layout} || $::form->{no_layout}) });
 212 }
 213
 214
 215 #
 216 # filters
 217 #
 218
 219 sub check_auth {
 220   $::auth->assert('config');
 221 }
 222
 223 sub check_type {
 224   my ($self) = @_;
 225
 226   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts inventories customers_vendors addresses contacts projects orders);
 227   $self->type($::form->{profile}->{type});
 228 }
 229
 230 sub ensure_form_structure {
 231   my ($self, %params) = @_;
 232
 233   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 234   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 235 }
 236
 237 #
 238 # helpers
 239 #
 240
 241 sub render_inputs {
 242   my ($self, %params) = @_;
 243
 244   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 245                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 246                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 247                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 248                         [ 'CP1252',      'CP1252 (Windows)'      ],
 249                       ]);
 250
 251   my %char_map = $self->char_map;
 252
 253   foreach my $type (qw(sep quote escape)) {
 254     my $sub = "all_${type}_chars";
 255     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 256
 257     my $char = $self->profile->get($type . '_char');
 258     $sub     = "${type}_char";
 259     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 260   }
 261
 262   $self->file(SL::SessionFile->new($self->csv_file_name));
 263
 264   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 265             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 266             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 267             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 268             : $self->type eq 'inventories'       ? $::locale->text('CSV import: inventories')
 269             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 270             : $self->type eq 'orders'            ? $::locale->text('CSV import: orders')
 271             : die;
 272
 273   if ($self->{type} eq 'customers_vendors' or $self->{type} eq 'orders'  ) {
 274     $self->all_taxzones(SL::DB::Manager::TaxZone->get_all_sorted(query => [ obsolete => 0 ]));
 275   };
 276
 277   if ($self->{type} eq 'parts') {
 278     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 279     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 280   }
 281
 282   $self->setup_help;
 283
 284   $self->render('csv_import/form', title => $title);
 285 }
 286
 287 sub test_and_import_deferred {
 288   my ($self, %params) = @_;
 289
 290   $self->profile_from_form;
 291
 292   if ($::form->{file}) {
 293     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 294     $file->fh->print($::form->{file});
 295     $file->fh->close;
 296   }
 297
 298   my $file = SL::SessionFile->new($self->csv_file_name, mode => '<', encoding => $self->profile->get('charset'));
 299   if (!$file->fh) {
 300     flash('error', $::locale->text('No file has been uploaded yet.'));
 301     return $self->action_new;
 302   }
 303
 304   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 305     file        => $self->csv_file_name,
 306     profile     => $self->profile,
 307     type        => $self->profile->type,
 308     test        => $params{test},
 309     employee_id => SL::DB::Manager::Employee->current->id,
 310   )->save;
 311
 312   if ($self->task_server->is_running) {
 313     $self->task_server->wake_up;
 314   } else {
 315     $self->task_server->start;
 316   }
 317
 318   flash('info', $::locale->text('Your import is being processed.'));
 319
 320   $self->{deferred} = 1;
 321
 322   if ($::request->type eq 'json') {
 323     $self->render(\ SL::JSON::to_json($self->{background_job}->as_tree), { type => 'json' })
 324   } else {
 325     $self->render_inputs;
 326   }
 327 }
 328
 329 sub test_and_import {
 330   my ($self, %params) = @_;
 331
 332   my $file = SL::SessionFile->new(
 333     $self->csv_file_name,
 334     mode       => '<',
 335     encoding   => $self->profile->get('charset'),
 336     session_id => $params{session_id}
 337   );
 338
 339   $self->file($file);
 340
 341   my $worker = $self->worker();
 342
 343   $worker->run(%params);
 344
 345   return if $self->errors;
 346
 347   $self->num_imported(0);
 348   $worker->save_objects if !$params{test};
 349
 350   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 351   $self->import_status($params{test} ? 'tested' : 'imported');
 352
 353 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 354 }
 355
 356 sub load_default_profile {
 357   my ($self) = @_;
 358
 359   my $profile;
 360   if ($::form->{profile}->{id}) {
 361     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id}, login => $::myconfig{login});
 362   }
 363   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 364   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 365
 366   $self->profile($profile);
 367   $self->profile->set_defaults;
 368 }
 369
 370 sub load_all_profiles {
 371   my ($self, %params) = @_;
 372
 373   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 374     where => [
 375       type  => $self->type,
 376       login => $::myconfig{login},
 377       '!name'  => '',
 378     ],
 379   sort_by => 'name'));
 380 }
 381
 382 sub profile_from_form {
 383   my ($self, $existing_profile) = @_;
 384
 385   delete $::form->{profile}->{id};
 386
 387   my %char_map = $self->char_map;
 388   my @settings;
 389
 390   foreach my $type (qw(sep quote escape)) {
 391     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 392     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 393
 394     push @settings, { key => "${type}_char", value => $char };
 395   }
 396
 397   if ($self->type eq 'parts') {
 398     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 399   }
 400
 401   if ($self->type eq 'orders') {
 402     $::form->{settings}->{max_amount_diff} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{max_amount_diff});
 403   }
 404
 405   delete $::form->{profile}->{id};
 406   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 407   $self->profile->assign_attributes(%{ $::form->{profile} });
 408   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 409                            @settings);
 410   $self->profile->set_defaults;
 411 }
 412
 413 sub char_map {
 414   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 415                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 416                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 417                        ' '  => [ 'space',     $::locale->text('Space')     ],
 418                      },
 419            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 420                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 421                      },
 422            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 423                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 424                      },
 425          );
 426 }
 427
 428 sub save_report {
 429   my ($self, %params) = @_;
 430
 431   if ($self->worker->is_multiplexed) {
 432     return $self->save_report_multi(%params);
 433   } else {
 434     return $self->save_report_single(%params);
 435   }
 436 }
 437
 438 sub save_report_single {
 439   my ($self, %params) = @_;
 440
 441   $self->track_progress(phase => 'building report', progress => 0);
 442
 443   my $clone_profile = $self->profile->clone_and_reset_deep;
 444   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 445
 446   my $report = SL::DB::CsvImportReport->new(
 447     session_id => $params{session_id},
 448     profile    => $clone_profile,
 449     type       => $self->type,
 450     file       => '',
 451     numrows    => scalar @{ $self->data },
 452     numheaders => 1,
 453   );
 454
 455   $report->save(cascade => 1) or die $report->db->error;
 456
 457   my $dbh = $::form->get_standard_dbh;
 458   $dbh->begin_work;
 459
 460   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 461   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 462
 463   my $sth = $dbh->prepare($query);
 464   my $sth2 = $dbh->prepare($query2);
 465
 466   # save headers
 467   my (@headers, @info_methods, @raw_methods, @methods);
 468
 469   for my $i (0 .. $#{ $self->info_headers->{headers} }) {
 470     next unless         $self->info_headers->{used}->{ $self->info_headers->{methods}->[$i] };
 471     push @headers,      $self->info_headers->{headers}->[$i];
 472     push @info_methods, $self->info_headers->{methods}->[$i];
 473   }
 474   for my $i (0 .. $#{ $self->headers->{headers} }) {
 475     next unless         $self->headers->{used}->{ $self->headers->{headers}->[$i] };
 476     push @headers,      $self->headers->{headers}->[$i];
 477     push @methods,      $self->headers->{methods}->[$i];
 478   }
 479   for my $i (0 .. $#{ $self->raw_data_headers->{headers} }) {
 480     next unless         $self->raw_data_headers->{used}->{ $self->raw_data_headers->{headers}->[$i] };
 481     push @headers,      $self->raw_data_headers->{headers}->[$i];
 482     push @raw_methods,  $self->raw_data_headers->{headers}->[$i];
 483   }
 484
 485   $sth->execute($report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 486
 487   # col offsets
 488   my $o1 =       @info_methods;
 489   my $o2 = $o1 + @methods;
 490
 491   for my $row (0 .. $#{ $self->data }) {
 492     $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 493     my $data_row = $self->{data}[$row];
 494
 495     $sth->execute($report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 496     $sth->execute($report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 497     $sth->execute($report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 498
 499     $sth2->execute($report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 500     $sth2->execute($report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 501   }
 502
 503   $dbh->commit;
 504
 505   return $report->id;
 506 }
 507
 508 sub save_report_multi {
 509   my ($self, %params) = @_;
 510
 511   $self->track_progress(phase => 'building report', progress => 0);
 512
 513   my $clone_profile = $self->profile->clone_and_reset_deep;
 514   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 515
 516   my $report = SL::DB::CsvImportReport->new(
 517     session_id => $params{session_id},
 518     profile    => $clone_profile,
 519     type       => $self->type,
 520     file       => '',
 521     numrows    => scalar @{ $self->data },
 522     numheaders => scalar @{ $self->worker->profile },
 523   );
 524
 525   $report->save(cascade => 1) or die $report->db->error;
 526
 527   my $dbh = $::form->get_standard_dbh;
 528   $dbh->begin_work;
 529
 530   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 531   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 532
 533   my $sth = $dbh->prepare($query);
 534   my $sth2 = $dbh->prepare($query2);
 535
 536   # save headers
 537   my ($headers, $info_methods, $raw_methods, $methods);
 538
 539   for my $i (0 .. $#{ $self->worker->profile }) {
 540     my $row_ident = $self->worker->profile->[$i]->{row_ident};
 541
 542     for my $i (0 .. $#{ $self->info_headers->{$row_ident}->{headers} }) {
 543       next unless                            $self->info_headers->{$row_ident}->{used}->{ $self->info_headers->{$row_ident}->{methods}->[$i] };
 544       push @{ $headers->{$row_ident} },      $self->info_headers->{$row_ident}->{headers}->[$i];
 545       push @{ $info_methods->{$row_ident} }, $self->info_headers->{$row_ident}->{methods}->[$i];
 546     }
 547     for my $i (0 .. $#{ $self->headers->{$row_ident}->{headers} }) {
 548       next unless                       $self->headers->{$row_ident}->{used}->{ $self->headers->{$row_ident}->{headers}->[$i] };
 549       push @{ $headers->{$row_ident} }, $self->headers->{$row_ident}->{headers}->[$i];
 550       push @{ $methods->{$row_ident} }, $self->headers->{$row_ident}->{methods}->[$i];
 551     }
 552
 553     for my $i (0 .. $#{ $self->raw_data_headers->{$row_ident}->{headers} }) {
 554     next unless                           $self->raw_data_headers->{$row_ident}->{used}->{ $self->raw_data_headers->{$row_ident}->{headers}->[$i] };
 555     push @{ $headers->{$row_ident} },     $self->raw_data_headers->{$row_ident}->{headers}->[$i];
 556     push @{ $raw_methods->{$row_ident} }, $self->raw_data_headers->{$row_ident}->{headers}->[$i];
 557   }
 558
 559   }
 560
 561   for my $i (0 .. $#{ $self->worker->profile }) {
 562     my $row_ident = $self->worker->profile->[$i]->{row_ident};
 563     $sth->execute($report->id, $_, $i, $headers->{$row_ident}->[$_]) for 0 .. $#{ $headers->{$row_ident} };
 564   }
 565
 566   # col offsets
 567   my ($off1, $off2);
 568   for my $i (0 .. $#{ $self->worker->profile }) {
 569     my $row_ident = $self->worker->profile->[$i]->{row_ident};
 570     my $n_info_methods = $info_methods->{$row_ident} ? scalar @{ $info_methods->{$row_ident} } : 0;
 571     my $n_methods      = $methods->{$row_ident} ?      scalar @{ $methods->{$row_ident} }      : 0;
 572
 573     $off1->{$row_ident} = $n_info_methods;
 574     $off2->{$row_ident} = $off1->{$row_ident} + $n_methods;
 575   }
 576
 577   my $n_header_rows = scalar @{ $self->worker->profile };
 578
 579   for my $row (0 .. $#{ $self->data }) {
 580     $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 581     my $data_row = $self->{data}[$row];
 582     my $row_ident = $data_row->{raw_data}{datatype};
 583
 584     my $o1 = $off1->{$row_ident};
 585     my $o2 = $off2->{$row_ident};
 586
 587     $sth->execute($report->id,       $_, $row + $n_header_rows, $data_row->{info_data}{ $info_methods->{$row_ident}->[$_] }) for 0 .. $#{ $info_methods->{$row_ident} };
 588     $sth->execute($report->id, $o1 + $_, $row + $n_header_rows, $data_row->{object}->${ \ $methods->{$row_ident}->[$_] })    for 0 .. $#{ $methods->{$row_ident} };
 589     $sth->execute($report->id, $o2 + $_, $row + $n_header_rows, $data_row->{raw_data}{ $raw_methods->{$row_ident}->[$_] })   for 0 .. $#{ $raw_methods->{$row_ident} };
 590
 591     $sth2->execute($report->id, $row + $n_header_rows, 'information', $_) for @{ $data_row->{information} || [] };
 592     $sth2->execute($report->id, $row + $n_header_rows, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 593   }
 594
 595   $dbh->commit;
 596
 597   return $report->id;
 598 }
 599
 600 sub csv_file_name {
 601   my ($self) = @_;
 602   return "csv-import-" . $self->type . ".csv";
 603 }
 604
 605 sub init_worker {
 606   my $self = shift;
 607
 608   my @args = (controller => $self);
 609
 610   if ( $self->file() ) {
 611     push(@args, file => $self->file());
 612   }
 613
 614   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 615        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 616        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 617        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 618        : $self->{type} eq 'inventories'       ? SL::Controller::CsvImport::Inventory->new(@args)
 619        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 620        : $self->{type} eq 'orders'            ? SL::Controller::CsvImport::Order->new(@args)
 621        :                                        die "Program logic error";
 622 }
 623
 624 sub setup_help {
 625   my ($self) = @_;
 626
 627   $self->worker->setup_displayable_columns;
 628 }
 629
 630 sub track_progress {
 631   my ($self, %params) = @_;
 632
 633   for my $tracker ($self->progress_tracker) {
 634     $tracker->track_progress(%params);
 635   }
 636 }
 637
 638 sub init_task_server {
 639   SL::System::TaskServer->new;
 640 }
 641
 642 sub cleanup_reports {
 643   SL::DB::Manager::CsvImportReport->cleanup;
 644 }
 645
 646 sub check_task_server {
 647   return 1 if $_[0]->task_server->is_running;
 648
 649   flash('info', t8('The task server is not running at the moment but needed for this module'));
 650
 651   1;
 652 }
 653
 654 1;