SL/Controller/Project.pm

   1 package SL::Controller::Project;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Clone qw(clone);
   8
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ParseFilter;
  11 use SL::Controller::Helper::ReportGenerator;
  12 use SL::CVar;
  13 use SL::DB::Customer;
  14 use SL::DB::DeliveryOrder;
  15 use SL::DB::Invoice;
  16 use SL::DB::Order;
  17 use SL::DB::Project;
  18 use SL::DB::ProjectType;
  19 use SL::DB::ProjectStatus;
  20 use SL::DB::PurchaseInvoice;
  21 use SL::DB::ProjectType;
  22 use SL::Helper::Flash;
  23 use SL::Locale::String;
  24
  25 use Rose::Object::MakeMethods::Generic
  26 (
  27  scalar => [ qw(project linked_records) ],
  28  'scalar --get_set_init' => [ qw(models customers project_types project_statuses) ],
  29 );
  30
  31 __PACKAGE__->run_before('check_auth');
  32 __PACKAGE__->run_before('load_project',        only => [ qw(edit update destroy) ]);
  33
  34 #
  35 # actions
  36 #
  37
  38 sub action_search {
  39   my ($self) = @_;
  40
  41   my %params;
  42
  43   $params{CUSTOM_VARIABLES}  = CVar->get_configs(module => 'Projects');
  44   ($params{CUSTOM_VARIABLES_FILTER_CODE}, $params{CUSTOM_VARIABLES_INCLUSION_CODE})
  45     = CVar->render_search_options(variables      => $params{CUSTOM_VARIABLES},
  46                                   include_prefix => 'l_',
  47                                   include_value  => 'Y');
  48
  49   $self->render('project/search', %params);
  50 }
  51
  52 sub action_list {
  53   my ($self) = @_;
  54
  55   $self->make_filter_summary;
  56
  57   $self->prepare_report;
  58
  59   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  60 }
  61
  62 sub action_new {
  63   my ($self) = @_;
  64
  65   $self->project(SL::DB::Project->new);
  66   $self->display_form(title    => $::locale->text('Create a new project'),
  67                       callback => $::form->{callback} || $self->url_for(action => 'new'));
  68 }
  69
  70 sub action_edit {
  71   my ($self) = @_;
  72
  73   $self->get_linked_records;
  74   $self->display_form(title    => $::locale->text('Edit project #1', $self->project->projectnumber),
  75                       callback => $::form->{callback} || $self->url_for(action => 'edit', id => $self->project->id));
  76 }
  77
  78 sub action_create {
  79   my ($self) = @_;
  80
  81   $self->project(SL::DB::Project->new);
  82   $self->create_or_update;
  83 }
  84
  85 sub action_update {
  86   my ($self) = @_;
  87   $self->create_or_update;
  88 }
  89
  90 sub action_destroy {
  91   my ($self) = @_;
  92
  93   if (eval { $self->project->delete; 1; }) {
  94     flash_later('info',  $::locale->text('The project has been deleted.'));
  95   } else {
  96     flash_later('error', $::locale->text('The project is in use and cannot be deleted.'));
  97   }
  98
  99   $self->redirect_to(action => 'search');
 100 }
 101
 102 #
 103 # filters
 104 #
 105
 106 sub check_auth {
 107   $::auth->assert('project_edit');
 108 }
 109
 110 #
 111 # helpers
 112 #
 113
 114 sub init_project_statuses { SL::DB::Manager::ProjectStatus->get_all_sorted }
 115 sub init_project_types    { SL::DB::Manager::ProjectType->get_all_sorted   }
 116
 117 sub init_customers {
 118   my ($self)      = @_;
 119   my @customer_id = $self->project && $self->project->customer_id ? (id => $self->project->customer_id) : ();
 120
 121   return SL::DB::Manager::Customer->get_all_sorted(where => [ or => [ obsolete => 0, obsolete => undef, @customer_id ]]);
 122 }
 123
 124 sub display_form {
 125   my ($self, %params) = @_;
 126
 127   $params{CUSTOM_VARIABLES}  = CVar->get_custom_variables(module => 'Projects', trans_id => $self->project->id);
 128
 129   if ($params{keep_cvars}) {
 130     for my $cvar (@{ $params{CUSTOM_VARIABLES} }) {
 131       $cvar->{value} = $::form->{"cvar_$cvar->{name}"} if $::form->{"cvar_$cvar->{name}"};
 132     }
 133   }
 134
 135   CVar->render_inputs(variables => $params{CUSTOM_VARIABLES}) if @{ $params{CUSTOM_VARIABLES} };
 136
 137   $self->render('project/form', %params);
 138 }
 139
 140 sub create_or_update {
 141   my $self   = shift;
 142   my $is_new = !$self->project->id;
 143   my $params = delete($::form->{project}) || { };
 144
 145   delete $params->{id};
 146   $self->project->assign_attributes(%{ $params });
 147
 148   my @errors = $self->project->validate;
 149
 150   if (@errors) {
 151     flash('error', @errors);
 152     $self->display_form(title    => $is_new ? $::locale->text('Create a new project') : $::locale->text('Edit project'),
 153                         callback => $::form->{callback},
 154                         keep_cvars => 1);
 155     return;
 156   }
 157
 158   $self->project->save;
 159
 160   CVar->save_custom_variables(
 161     dbh          => $self->project->db->dbh,
 162     module       => 'Projects',
 163     trans_id     => $self->project->id,
 164     variables    => $::form,
 165     always_valid => 1,
 166   );
 167
 168   flash_later('info', $is_new ? $::locale->text('The project has been created.') : $::locale->text('The project has been saved.'));
 169
 170   $self->redirect_to($::form->{callback} || (action => 'search'));
 171 }
 172
 173 sub load_project {
 174   my ($self) = @_;
 175   $self->project(SL::DB::Project->new(id => $::form->{id})->load);
 176 }
 177
 178 sub get_linked_records {
 179   my ($self) = @_;
 180
 181   $self->linked_records([
 182     map  { @{ $_ } }
 183     grep { $_      } (
 184       SL::DB::Manager::Order->          get_all(where => [ globalproject_id => $self->project->id ], with_objects => [ 'customer', 'vendor' ], sort_by => 'transdate ASC'),
 185       SL::DB::Manager::DeliveryOrder->  get_all(where => [ globalproject_id => $self->project->id ], with_objects => [ 'customer', 'vendor' ], sort_by => 'transdate ASC'),
 186       SL::DB::Manager::Invoice->        get_all(where => [ globalproject_id => $self->project->id ], with_objects => [ 'customer'           ], sort_by => 'transdate ASC'),
 187       SL::DB::Manager::PurchaseInvoice->get_all(where => [ globalproject_id => $self->project->id ], with_objects => [             'vendor' ], sort_by => 'transdate ASC'),
 188     )]);
 189 }
 190
 191 sub prepare_report {
 192   my ($self)      = @_;
 193
 194   my $callback    = $self->models->get_callback;
 195
 196   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 197   $self->{report} = $report;
 198
 199   my @columns     = qw(project_status customer projectnumber description active valid project_type);
 200   my @sortable    = qw(projectnumber description customer              project_type project_status);
 201
 202   my %column_defs = (
 203     projectnumber => { obj_link => sub { $self->url_for(action => 'edit', id => $_[0]->id, callback => $callback) } },
 204     description   => { obj_link => sub { $self->url_for(action => 'edit', id => $_[0]->id, callback => $callback) } },
 205     project_type  => { sub  => sub { $_[0]->project_type->description } },
 206     project_status => { sub  => sub { $_[0]->project_status->description }, text => t8('Status') },
 207     customer      => { raw_data  => sub { $_[0]->customer_id ? $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) : '' } },
 208     active        => { sub  => sub { $_[0]->active   ? $::locale->text('Active') : $::locale->text('Inactive') },
 209                        text => $::locale->text('Active') },
 210     valid         => { sub  => sub { $_[0]->valid    ? $::locale->text('Valid')  : $::locale->text('Invalid')  },
 211                        text => $::locale->text('Valid')  },
 212   );
 213
 214   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 215
 216   $report->set_options(
 217     std_column_visibility => 1,
 218     controller_class      => 'Project',
 219     output_format         => 'HTML',
 220     title                 => $::locale->text('Projects'),
 221     allow_pdf_export      => 1,
 222     allow_csv_export      => 1,
 223   );
 224   $report->set_columns(%column_defs);
 225   $report->set_column_order(@columns);
 226   $report->set_export_options(qw(list filter));
 227   $report->set_options_from_form;
 228   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 229   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 230   $report->set_options(
 231     raw_top_info_text     => $self->render('project/report_top',    { output => 0 }),
 232     raw_bottom_info_text  => $self->render('project/report_bottom', { output => 0 }),
 233   );
 234 }
 235
 236 sub init_models {
 237   my ($self) = @_;
 238
 239   SL::Controller::Helper::GetModels->new(
 240     controller => $self,
 241     sorted => {
 242       _default => {
 243         by    => 'projectnumber',
 244         dir   => 1,
 245       },
 246       customer      => t8('Customer'),
 247       description   => t8('Description'),
 248       projectnumber => t8('Project Number'),
 249       project_type  => t8('Project Type'),
 250     },
 251     with_objects => [ 'customer' ],
 252   );
 253 }
 254
 255 sub make_filter_summary {
 256   my ($self) = @_;
 257
 258   my $filter = $::form->{filter} || {};
 259   my @filter_strings;
 260
 261   my @filters = (
 262     [ $filter->{"projectnumber:substr::ilike"},  t8('Project Number') ],
 263     [ $filter->{"description:substr::ilike"},    t8('Description')    ],
 264     [ $filter->{customer}{"name:substr::ilike"}, t8('Customer')       ],
 265     [ $filter->{"project_type_id"},              t8('Project Type'),    sub { SL::DB::Manager::ProjectType->find_by(id => $filter->{"project_type_id"})->description }   ],
 266     [ $filter->{"project_status_id"},            t8('Project Status'),  sub { SL::DB::Manager::ProjectStatus->find_by(id => $filter->{"project_status_id"})->description } ],
 267   );
 268
 269   my @flags = (
 270     [ $filter->{active} eq 'active',    $::locale->text('Active')      ],
 271     [ $filter->{active} eq 'inactive',  $::locale->text('Inactive')    ],
 272     [ $filter->{valid}  eq 'valid',     $::locale->text('Valid')       ],
 273     [ $filter->{valid}  eq 'invalid',   $::locale->text('Invalid')     ],
 274     [ $filter->{orphaned},              $::locale->text('Orphaned')    ],
 275   );
 276
 277   for (@flags) {
 278     push @filter_strings, "$_->[1]" if $_->[0];
 279   }
 280   for (@filters) {
 281     push @filter_strings, "$_->[1]: " . ($_->[2] ? $_->[2]->() : $_->[0]) if $_->[0];
 282   }
 283
 284   $self->{filter_summary} = join ', ', @filter_strings;
 285 }
 286 1;