SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use Rose::DB::Object::Helpers ();
   8
   9 use SL::DB::MetaSetup::DeliveryOrder;
  10 use SL::DB::Manager::DeliveryOrder;
  11 use SL::DB::Helper::FlattenToForm;
  12 use SL::DB::Helper::LinkedRecords;
  13 use SL::DB::Helper::TransNumberGenerator;
  14
  15 use List::Util qw(first);
  16
  17 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  18                                                     class        => 'SL::DB::DeliveryOrderItem',
  19                                                     column_map   => { id => 'delivery_order_id' },
  20                                                     manager_args => { with_objects => [ 'part' ] }
  21                                                   },
  22                                     custom_shipto => {
  23                                       type        => 'one to one',
  24                                       class       => 'SL::DB::Shipto',
  25                                       column_map  => { id => 'trans_id' },
  26                                       query_args  => [ module => 'DO' ],
  27                                     },
  28                                    );
  29
  30 __PACKAGE__->meta->initialize;
  31
  32 __PACKAGE__->before_save('_before_save_set_donumber');
  33
  34 # hooks
  35
  36 sub _before_save_set_donumber {
  37   my ($self) = @_;
  38
  39   $self->create_trans_number if !$self->donumber;
  40
  41   return 1;
  42 }
  43
  44 # methods
  45
  46 sub items { goto &orderitems; }
  47
  48 sub items_sorted {
  49   my ($self) = @_;
  50
  51   return [ sort {$a->id <=> $b->id } @{ $self->items } ];
  52 }
  53
  54 sub sales_order {
  55   my $self   = shift;
  56   my %params = @_;
  57
  58
  59   require SL::DB::Order;
  60   my $orders = SL::DB::Manager::Order->get_all(
  61     query => [
  62       ordnumber => $self->ordnumber,
  63       @{ $params{query} || [] },
  64     ],
  65   );
  66
  67   return first { $_->is_type('sales_order') } @{ $orders };
  68 }
  69
  70 sub type {
  71   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  72 }
  73
  74 sub displayable_state {
  75   my ($self) = @_;
  76
  77   return join '; ',
  78     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  79     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  80 }
  81
  82 sub date {
  83   goto &transdate;
  84 }
  85
  86 sub _clone_orderitem_cvar {
  87   my ($cvar) = @_;
  88
  89   my $cloned = Rose::DB::Object::Helpers::clone_and_reset($_);
  90   $cloned->sub_module('delivery_order_items');
  91
  92   return $cloned;
  93 }
  94
  95 sub new_from {
  96   my ($class, $source, %params) = @_;
  97
  98   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
  99
 100   my ($item_parent_id_column, $item_parent_column);
 101
 102   if (ref($source) eq 'SL::DB::Order') {
 103     $item_parent_id_column = 'trans_id';
 104     $item_parent_column    = 'order';
 105   }
 106
 107   my $terms = $source->can('payment_id') && $source->payment_id ? $source->payment_terms->terms_netto : 0;
 108
 109   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber department_id employee_id globalproject_id intnotes language_id notes
 110                                                 ordnumber reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
 111                                              )),
 112                closed    => 0,
 113                is_sales  => !!$source->customer_id,
 114                delivered => 0,
 115                terms     => $terms,
 116                transdate => DateTime->today_local,
 117             );
 118
 119   # Custom shipto addresses (the ones specific to the sales/purchase
 120   # record and not to the customer/vendor) are only linked from
 121   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
 122   # will not be filled in that case. Therefore we have to return the
 123   # new shipto object as a separate object so that the caller can
 124   # save it, too.
 125   my $custom_shipto;
 126   if (!$source->shipto_id && $source->id) {
 127     my $old = $source->custom_shipto;
 128     if ($old) {
 129       $custom_shipto = SL::DB::Shipto->new(
 130         map  { +($_ => $old->$_) }
 131         grep { !m{^ (?: itime | mtime | shipto_id | trans_id ) $}x }
 132         map  { $_->name }
 133         @{ $old->meta->columns }
 134       );
 135       $custom_shipto->module('DO');
 136     }
 137
 138   } else {
 139     $args{shipto_id} = $source->shipto_id;
 140   }
 141
 142   my $delivery_order = $class->new(%args, %{ $params{attributes} || {} });
 143   my $items          = delete($params{items}) || $source->items_sorted;
 144   my %item_parents;
 145
 146   my @items = map {
 147     my $source_item      = $_;
 148     my $source_item_id   = $_->$item_parent_id_column;
 149     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 150
 151     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 152     my $item_parent                  = $item_parents{$source_item_id};
 153
 154     SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 155                                          qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor parts_id price_factor price_factor_id
 156                                             project_id qty reqdate sellprice serialnumber transdate unit
 157                                          )),
 158                                    custom_variables => \@custom_variables,
 159                                    ordnumber        => ref($item_parent) eq 'SL::DB::Order' ? $item_parent->ordnumber : $source_item->ordnumber,
 160                                  );
 161
 162   } @{ $items };
 163
 164   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 165
 166   $delivery_order->items(\@items);
 167
 168   return ($delivery_order, $custom_shipto);
 169 }
 170
 171 1;
 172 __END__
 173
 174 =pod
 175
 176 =encoding utf8
 177
 178 =head1 NAME
 179
 180 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 181 "delivery_orders")
 182
 183 =head1 FUNCTIONS
 184
 185 =over 4
 186
 187 =item C<date>
 188
 189 An alias for C<transdate> for compatibility with other sales/purchase models.
 190
 191 =item C<displayable_state>
 192
 193 Returns a human-readable description of the state regarding being
 194 closed and delivered.
 195
 196 =item C<items>
 197
 198 An alias for C<deliver_orer_items> for compatibility with other
 199 sales/purchase models.
 200
 201 =item C<items_sorted>
 202
 203 Returns the delivery order items sorted by their ID (same order they
 204 appear in the frontend delivery order masks).
 205
 206 =item C<new_from $source, %params>
 207
 208 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 209 information from C<$source> as possible. At the moment only instances
 210 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 211 quotations and purchase orders) are supported as sources.
 212
 213 The conversion copies order items into delivery order items. Dates are copied
 214 as appropriate, e.g. the C<transdate> field will be set to the current date.
 215
 216 Returns one or two objects depending on the context. In list context
 217 the new delivery order instance and a shipto instance will be
 218 returned. In scalar instance only the delivery order instance is
 219 returned.
 220
 221 Custom shipto addresses (the ones specific to the sales/purchase
 222 record and not to the customer/vendor) are only linked from C<shipto>
 223 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 224 be filled in that case. That's why a separate shipto object is created
 225 and returned.
 226
 227 The objects returned are not saved.
 228
 229 C<%params> can include the following options:
 230
 231 =over 2
 232
 233 =item C<items>
 234
 235 An optional array reference of RDBO instances for the items to use. If
 236 missing then the method C<items_sorted> will be called on
 237 C<$source>. This option can be used to override the sorting, to
 238 exclude certain positions or to add additional ones.
 239
 240 =item C<skip_items_zero_qty>
 241
 242 If trueish then items with a quantity of 0 are skipped.
 243
 244 =item C<attributes>
 245
 246 An optional hash reference. If it exists then it is passed to C<new>
 247 allowing the caller to set certain attributes for the new delivery
 248 order.
 249
 250 =back
 251
 252 =item C<sales_order>
 253
 254 TODO: Describe sales_order
 255
 256 =item C<type>
 257
 258 Returns a stringdescribing this record's type: either
 259 C<sales_delivery_order> or C<purchase_delivery_order>.
 260
 261 =back
 262
 263 =head1 BUGS
 264
 265 Nothing here yet.
 266
 267 =head1 AUTHOR
 268
 269 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 270
 271 =cut