SL/Controller/RecordLinks.pm

   1 package SL::Controller::RecordLinks;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::DB::Helper::Mappings;
  10 use SL::DB::Order;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::Invoice;
  13 use SL::DB::Letter;
  14 use SL::DB::PurchaseInvoice;
  15 use SL::DB::RecordLink;
  16 use SL::DB::RequirementSpec;
  17 use SL::DBUtils qw(like);
  18 use SL::JSON;
  19 use SL::Locale::String;
  20
  21 use Rose::Object::MakeMethods::Generic
  22 (
  23   scalar => [ qw(object object_model object_id link_type link_direction link_type_desc) ],
  24 );
  25
  26 __PACKAGE__->run_before('check_object_params', only => [ qw(ajax_list ajax_delete ajax_add_select_type ajax_add_filter ajax_add_list ajax_add_do) ]);
  27 __PACKAGE__->run_before('check_link_params',   only => [ qw(                                                           ajax_add_list ajax_add_do) ]);
  28
  29 my %link_type_defaults = (
  30   filter            => 'type_filter',
  31   project           => 'globalproject',
  32   description       => 'transaction_description',
  33   description_title => t8('Transaction description'),
  34   date              => 'transdate',
  35 );
  36
  37 my @link_type_specifics = (
  38   { title => t8('Requirement spec'),        type => 'requirement_spec',        model => 'RequirementSpec', number => 'id',           description => 'title',   description_title => t8('Title'),   date => undef, project => 'project', filter => 'working_copy_filter', },
  39   { title => t8('Sales quotation'),         type => 'sales_quotation',         model => 'Order',           number => 'quonumber', },
  40   { title => t8('Sales Order'),             type => 'sales_order',             model => 'Order',           number => 'ordnumber', },
  41   { title => t8('Sales delivery order'),    type => 'sales_delivery_order',    model => 'DeliveryOrder',   number => 'donumber',  },
  42   { title => t8('Sales Invoice'),           type => 'invoice',                 model => 'Invoice',         number => 'invnumber', },
  43   { title => t8('Request for Quotation'),   type => 'request_quotation',       model => 'Order',           number => 'quonumber', },
  44   { title => t8('Purchase Order'),          type => 'purchase_order',          model => 'Order',           number => 'ordnumber', },
  45   { title => t8('Purchase delivery order'), type => 'purchase_delivery_order', model => 'DeliveryOrder',   number => 'donumber',  },
  46   { title => t8('Purchase Invoice'),        type => 'purchase_invoice',        model => 'PurchaseInvoice', number => 'invnumber', },
  47   { title => t8('Letter'),                  type => 'letter',                  model => 'Letter',          number => 'letternumber', description => 'subject', description_title => t8('Subject'), date => 'date', project => undef },
  48 );
  49
  50 my @link_types = map { +{ %link_type_defaults, %{ $_ } } } @link_type_specifics;
  51
  52 #
  53 # actions
  54 #
  55
  56 sub action_ajax_list {
  57   my ($self) = @_;
  58
  59   eval {
  60     my $linked_records = $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1);
  61     push @{ $linked_records }, $self->object->sepa_export_items if $self->object->can('sepa_export_items');
  62     my $output         = SL::Presenter->get->grouped_record_list(
  63       $linked_records,
  64       with_columns      => [ qw(record_link_direction) ],
  65       edit_record_links => 1,
  66       object_model      => $self->object_model,
  67       object_id         => $self->object_id,
  68     );
  69     $self->render(\$output, { layout => 0, process => 0 });
  70
  71     1;
  72   } or do {
  73     $self->render('generic/error', { layout => 0 }, label_error => $@);
  74   };
  75 }
  76
  77 sub action_ajax_delete {
  78   my ($self) = @_;
  79
  80   foreach my $str (@{ $::form->{record_links_delete} || [] }) {
  81     my ($from_table, $from_id, $to_table, $to_id) = split m/__/, $str, 4;
  82     $from_id *= 1;
  83     $to_id   *= 1;
  84
  85     next if !$from_table || !$from_id || !$to_table || !$to_id;
  86
  87     SL::DB::Manager::RecordLink->delete_all(where => [
  88       from_table => $from_table,
  89       from_id    => $from_id,
  90       to_table   => $to_table,
  91       to_id      => $to_id,
  92     ]);
  93   }
  94
  95   $self->action_ajax_list;
  96 }
  97
  98 sub action_ajax_add_filter {
  99   my ($self) = @_;
 100
 101   my $presenter = $self->presenter;
 102
 103   my @link_type_select = map { [ $_->{type}, $_->{title} ] } @link_types;
 104   my @projects         = map { [ $_->id, $presenter->project($_, display => 'inline', style => 'both', no_link => 1) ] } @{ SL::DB::Manager::Project->get_all_sorted };
 105   my $is_sales         = $self->object->can('customer_id') && $self->object->customer_id;
 106
 107   $self->render(
 108     'record_links/add_filter',
 109     { layout          => 0 },
 110     is_sales          => $is_sales,
 111     DEFAULT_LINK_TYPE => $is_sales ? 'sales_quotation' : 'request_quotation',
 112     LINK_TYPES        => \@link_type_select,
 113     PROJECTS          => \@projects,
 114   );
 115 }
 116
 117 sub action_ajax_add_list {
 118   my ($self) = @_;
 119
 120   my $manager     = 'SL::DB::Manager::' . $self->link_type_desc->{model};
 121   my $vc          = $self->link_type =~ m/sales_|^invoice|requirement_spec|letter/ ? 'customer' : 'vendor';
 122   my $project     = $self->link_type_desc->{project};
 123   my $project_id  = "${project}_id";
 124   my $description = $self->link_type_desc->{description};
 125   my $filter      = $self->link_type_desc->{filter};
 126
 127   my @where = $filter && $manager->can($filter) ? $manager->$filter($self->link_type) : ();
 128   push @where, ("${vc}.${vc}number"     => { ilike => like($::form->{vc_number}) })               if $::form->{vc_number};
 129   push @where, ("${vc}.name"            => { ilike => like($::form->{vc_name}) })                 if $::form->{vc_name};
 130   push @where, ($description            => { ilike => like($::form->{transaction_description}) }) if $::form->{transaction_description};
 131   push @where, ($project_id             => $::form->{globalproject_id})                           if $::form->{globalproject_id} && $manager->can($project_id);
 132
 133   my @with_objects = ($vc);
 134   push @with_objects, $project if $manager->can($project_id);
 135
 136   my $objects = $manager->get_all_sorted(where => \@where, with_objects => \@with_objects);
 137   my $output  = $self->render(
 138     'record_links/add_list',
 139     { output => 0 },
 140     OBJECTS            => $objects,
 141     vc                 => $vc,
 142     number_column      => $self->link_type_desc->{number},
 143     description_column => $description,
 144     description_title  => $self->link_type_desc->{description_title},
 145     project_column     => $project,
 146     date_column        => $self->link_type_desc->{date},
 147   );
 148
 149   my %result = ( count => scalar(@{ $objects }), html => $output );
 150
 151   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 152 }
 153
 154 sub action_ajax_add_do {
 155   my ($self, %params) = @_;
 156
 157   my $object_side = $self->link_direction eq 'from' ? 'from' : 'to';
 158   my $link_side   = $object_side          eq 'from' ? 'to'   : 'from';
 159   my $link_table  = SL::DB::Helper::Mappings::get_table_for_package($self->link_type_desc->{model});
 160
 161   foreach my $link_id (@{ $::form->{link_id} || [] }) {
 162     # Check for existing reverse connections in order to avoid loops.
 163     my @props = (
 164       "${link_side}_table"   => $self->object->meta->table,
 165       "${link_side}_id"      => $self->object_id,
 166       "${object_side}_table" => $link_table,
 167       "${object_side}_id"    => $link_id,
 168     );
 169
 170     my $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 171     next if $existing;
 172
 173     # Check for existing connections in order to avoid duplicates.
 174     @props = (
 175       "${object_side}_table" => $self->object->meta->table,
 176       "${object_side}_id"    => $self->object_id,
 177       "${link_side}_table"   => $link_table,
 178       "${link_side}_id"      => $link_id,
 179     );
 180
 181     $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 182
 183     SL::DB::RecordLink->new(@props)->save if !$existing;
 184   }
 185
 186   $self->action_ajax_list;
 187 }
 188
 189
 190 #
 191 # filters
 192 #
 193
 194 sub check_object_params {
 195   my ($self) = @_;
 196
 197   my %models = map { ($_->{model} => 1 ) } @link_types;
 198
 199   $self->object_id(   $::form->{object_id});
 200   $self->object_model($::form->{object_model});
 201
 202   die "Invalid object_model or object_id" if !$self->object_id || !$models{$self->object_model};
 203
 204   my $model = 'SL::DB::' . $self->object_model;
 205   $self->object($model->new(id => $self->object_id)->load || die "Record not found");
 206
 207   return 1;
 208 }
 209
 210 sub check_link_params {
 211   my ($self) = @_;
 212
 213   $self->link_type(     $::form->{link_type});
 214   $self->link_type_desc((first { $_->{type} eq $::form->{link_type} } @link_types)                || die "Invalid link_type");
 215   $self->link_direction($::form->{link_direction} =~ m/^(?:from|to)$/ ? $::form->{link_direction} :  die "Invalid link_direction");
 216
 217   return 1;
 218 }
 219
 220 1;