SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use Rose::DB::Object::Helpers ();
   8
   9 use SL::DB::MetaSetup::DeliveryOrder;
  10 use SL::DB::Manager::DeliveryOrder;
  11 use SL::DB::Helper::FlattenToForm;
  12 use SL::DB::Helper::LinkedRecords;
  13 use SL::DB::Helper::TransNumberGenerator;
  14
  15 use List::Util qw(first);
  16
  17 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  18                                                     class        => 'SL::DB::DeliveryOrderItem',
  19                                                     column_map   => { id => 'delivery_order_id' },
  20                                                     manager_args => { with_objects => [ 'part' ] }
  21                                                   },
  22                                     custom_shipto => {
  23                                       type        => 'one to one',
  24                                       class       => 'SL::DB::Shipto',
  25                                       column_map  => { id => 'trans_id' },
  26                                       query_args  => [ module => 'DO' ],
  27                                     },
  28                                    );
  29
  30 __PACKAGE__->meta->initialize;
  31
  32 __PACKAGE__->before_save('_before_save_set_donumber');
  33
  34 # hooks
  35
  36 sub _before_save_set_donumber {
  37   my ($self) = @_;
  38
  39   $self->create_trans_number if !$self->donumber;
  40
  41   return 1;
  42 }
  43
  44 # methods
  45
  46 sub items { goto &orderitems; }
  47 sub add_items { goto &add_orderitems; }
  48
  49 sub items_sorted {
  50   my ($self) = @_;
  51
  52   return [ sort {$a->id <=> $b->id } @{ $self->items } ];
  53 }
  54
  55 sub sales_order {
  56   my $self   = shift;
  57   my %params = @_;
  58
  59
  60   require SL::DB::Order;
  61   my $orders = SL::DB::Manager::Order->get_all(
  62     query => [
  63       ordnumber => $self->ordnumber,
  64       @{ $params{query} || [] },
  65     ],
  66   );
  67
  68   return first { $_->is_type('sales_order') } @{ $orders };
  69 }
  70
  71 sub type {
  72   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  73 }
  74
  75 sub displayable_state {
  76   my ($self) = @_;
  77
  78   return join '; ',
  79     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  80     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  81 }
  82
  83 sub date {
  84   goto &transdate;
  85 }
  86
  87 sub _clone_orderitem_cvar {
  88   my ($cvar) = @_;
  89
  90   my $cloned = Rose::DB::Object::Helpers::clone_and_reset($_);
  91   $cloned->sub_module('delivery_order_items');
  92
  93   return $cloned;
  94 }
  95
  96 sub new_from {
  97   my ($class, $source, %params) = @_;
  98
  99   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
 100
 101   my ($item_parent_id_column, $item_parent_column);
 102
 103   if (ref($source) eq 'SL::DB::Order') {
 104     $item_parent_id_column = 'trans_id';
 105     $item_parent_column    = 'order';
 106   }
 107
 108   my $terms = $source->can('payment_id') && $source->payment_id ? $source->payment_terms->terms_netto : 0;
 109
 110   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber department_id employee_id globalproject_id intnotes language_id notes
 111                                                 ordnumber reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
 112                                              )),
 113                closed    => 0,
 114                is_sales  => !!$source->customer_id,
 115                delivered => 0,
 116                terms     => $terms,
 117                transdate => DateTime->today_local,
 118             );
 119
 120   # Custom shipto addresses (the ones specific to the sales/purchase
 121   # record and not to the customer/vendor) are only linked from
 122   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
 123   # will not be filled in that case. Therefore we have to return the
 124   # new shipto object as a separate object so that the caller can
 125   # save it, too.
 126   my $custom_shipto;
 127   if (!$source->shipto_id && $source->id) {
 128     my $old = $source->custom_shipto;
 129     if ($old) {
 130       $custom_shipto = SL::DB::Shipto->new(
 131         map  { +($_ => $old->$_) }
 132         grep { !m{^ (?: itime | mtime | shipto_id | trans_id ) $}x }
 133         map  { $_->name }
 134         @{ $old->meta->columns }
 135       );
 136       $custom_shipto->module('DO');
 137     }
 138
 139   } else {
 140     $args{shipto_id} = $source->shipto_id;
 141   }
 142
 143   my $delivery_order = $class->new(%args);
 144   $delivery_order->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 145   my $items          = delete($params{items}) || $source->items_sorted;
 146   my %item_parents;
 147
 148   my @items = map {
 149     my $source_item      = $_;
 150     my $source_item_id   = $_->$item_parent_id_column;
 151     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 152
 153     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 154     my $item_parent                  = $item_parents{$source_item_id};
 155
 156     SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 157                                          qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor parts_id price_factor price_factor_id
 158                                             project_id qty reqdate sellprice serialnumber transdate unit
 159                                          )),
 160                                    custom_variables => \@custom_variables,
 161                                    ordnumber        => ref($item_parent) eq 'SL::DB::Order' ? $item_parent->ordnumber : $source_item->ordnumber,
 162                                  );
 163
 164   } @{ $items };
 165
 166   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 167
 168   $delivery_order->items(\@items);
 169
 170   return ($delivery_order, $custom_shipto);
 171 }
 172
 173 1;
 174 __END__
 175
 176 =pod
 177
 178 =encoding utf8
 179
 180 =head1 NAME
 181
 182 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 183 "delivery_orders")
 184
 185 =head1 FUNCTIONS
 186
 187 =over 4
 188
 189 =item C<date>
 190
 191 An alias for C<transdate> for compatibility with other sales/purchase models.
 192
 193 =item C<displayable_state>
 194
 195 Returns a human-readable description of the state regarding being
 196 closed and delivered.
 197
 198 =item C<items>
 199
 200 An alias for C<deliver_orer_items> for compatibility with other
 201 sales/purchase models.
 202
 203 =item C<items_sorted>
 204
 205 Returns the delivery order items sorted by their ID (same order they
 206 appear in the frontend delivery order masks).
 207
 208 =item C<new_from $source, %params>
 209
 210 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 211 information from C<$source> as possible. At the moment only instances
 212 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 213 quotations and purchase orders) are supported as sources.
 214
 215 The conversion copies order items into delivery order items. Dates are copied
 216 as appropriate, e.g. the C<transdate> field will be set to the current date.
 217
 218 Returns one or two objects depending on the context. In list context
 219 the new delivery order instance and a shipto instance will be
 220 returned. In scalar instance only the delivery order instance is
 221 returned.
 222
 223 Custom shipto addresses (the ones specific to the sales/purchase
 224 record and not to the customer/vendor) are only linked from C<shipto>
 225 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 226 be filled in that case. That's why a separate shipto object is created
 227 and returned.
 228
 229 The objects returned are not saved.
 230
 231 C<%params> can include the following options:
 232
 233 =over 2
 234
 235 =item C<items>
 236
 237 An optional array reference of RDBO instances for the items to use. If
 238 missing then the method C<items_sorted> will be called on
 239 C<$source>. This option can be used to override the sorting, to
 240 exclude certain positions or to add additional ones.
 241
 242 =item C<skip_items_zero_qty>
 243
 244 If trueish then items with a quantity of 0 are skipped.
 245
 246 =item C<attributes>
 247
 248 An optional hash reference. If it exists then it is passed to C<new>
 249 allowing the caller to set certain attributes for the new delivery
 250 order.
 251
 252 =back
 253
 254 =item C<sales_order>
 255
 256 TODO: Describe sales_order
 257
 258 =item C<type>
 259
 260 Returns a stringdescribing this record's type: either
 261 C<sales_delivery_order> or C<purchase_delivery_order>.
 262
 263 =back
 264
 265 =head1 BUGS
 266
 267 Nothing here yet.
 268
 269 =head1 AUTHOR
 270
 271 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 272
 273 =cut